lisp/net/network-stream.el

   1 ;;; network-stream.el --- open network processes, possibly with encryption
   2
   3 ;; Copyright (C) 2010-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This library provides the function `open-network-stream', which provides a
  26 ;; higher-level interface for opening TCP network processes than the built-in
  27 ;; function `make-network-process'.  In addition to plain connections, it
  28 ;; supports TLS/SSL and STARTTLS connections.
  29
  30 ;; Usage example:
  31
  32 ;; (open-network-stream
  33 ;;  "*nnimap*" buffer address port
  34 ;;  :type 'network
  35 ;;  :capability-command "1 CAPABILITY\r\n"
  36 ;;  :success " OK "
  37 ;;  :starttls-function
  38 ;;  (lambda (capabilities)
  39 ;;    (if (not (string-match "STARTTLS" capabilities))
  40 ;;        nil
  41 ;;      "1 STARTTLS\r\n")))
  42
  43 ;;; Code:
  44
  45 (require 'tls)
  46 (require 'starttls)
  47 (require 'auth-source)
  48
  49 (autoload 'gnutls-negotiate "gnutls")
  50 (autoload 'open-gnutls-stream "gnutls")
  51
  52 ;;;###autoload
  53 (defun open-network-stream (name buffer host service &rest parameters)
  54   "Open a TCP connection to HOST, optionally with encryption.
  55 Normally, return a network process object; with a non-nil
  56 :return-list parameter, return a list instead (see below).
  57 Input and output work as for subprocesses; `delete-process'
  58 closes it.
  59
  60 NAME is the name for the process.  It is modified if necessary to
  61  make it unique.
  62 BUFFER is a buffer or buffer name to associate with the process.
  63  Process output goes at end of that buffer.  BUFFER may be nil,
  64  meaning that the process is not associated with any buffer.
  65 HOST is the name or IP address of the host to connect to.
  66 SERVICE is the name of the service desired, or an integer specifying
  67  a port number to connect to.
  68
  69 The remaining PARAMETERS should be a sequence of keywords and
  70 values:
  71
  72 :type specifies the connection type, one of the following:
  73   nil or `network'
  74              -- Begin with an ordinary network connection, and if
  75                 the parameters :success and :capability-command
  76                 are also supplied, try to upgrade to an encrypted
  77                 connection via STARTTLS.  Even if that
  78                 fails (e.g. if HOST does not support TLS), retain
  79                 an unencrypted connection.
  80   `plain'    -- An ordinary, unencrypted network connection.
  81   `starttls' -- Begin with an ordinary connection, and try
  82                 upgrading via STARTTLS.  If that fails for any
  83                 reason, drop the connection; in that case the
  84                 returned object is a killed process.
  85   `tls'      -- A TLS connection.
  86   `ssl'      -- Equivalent to `tls'.
  87   `shell'    -- A shell connection.
  88
  89 :return-list specifies this function's return value.
  90   If omitted or nil, return a process object.  A non-nil means to
  91   return (PROC . PROPS), where PROC is a process object and PROPS
  92   is a plist of connection properties, with these keywords:
  93    :greeting -- the greeting returned by HOST (a string), or nil.
  94    :capabilities -- a string representing HOST's capabilities,
  95                     or nil if none could be found.
  96    :type -- the resulting connection type; `plain' (unencrypted)
  97             or `tls' (TLS-encrypted).
  98
  99 :end-of-command specifies a regexp matching the end of a command.
 100
 101 :end-of-capability specifies a regexp matching the end of the
 102   response to the command specified for :capability-command.
 103   It defaults to the regexp specified for :end-of-command.
 104
 105 :success specifies a regexp matching a message indicating a
 106   successful STARTTLS negotiation.  For instance, the default
 107   should be \"^3\" for an NNTP connection.
 108
 109 :capability-command specifies a command used to query the HOST
 110   for its capabilities.  For instance, for IMAP this should be
 111   \"1 CAPABILITY\\r\\n\".
 112
 113 :starttls-function specifies a function for handling STARTTLS.
 114   This function should take one parameter, the response to the
 115   capability command, and should return the command to switch on
 116   STARTTLS if the server supports STARTTLS, and nil otherwise.
 117
 118 :always-query-capabilities says whether to query the server for
 119   capabilities, even if we're doing a `plain' network connection.
 120
 121 :client-certificate should either be a list where the first
 122   element is the certificate key file name, and the second
 123   element is the certificate file name itself, or `t', which
 124   means that `auth-source' will be queried for the key and the
 125   certificate.  This parameter will only be used when doing TLS
 126   or STARTTLS connections.
 127
 128 :use-starttls-if-possible is a boolean that says to do opportunistic
 129 STARTTLS upgrades even if Emacs doesn't have built-in TLS functionality.
 130
 131 :nogreeting is a boolean that can be used to inhibit waiting for
 132 a greeting from the server.
 133
 134 :nowait is a boolean that says the connection should be made
 135   asynchronously, if possible."
 136   (unless (featurep 'make-network-process)
 137     (error "Emacs was compiled without networking support"))
 138   (let ((type (plist-get parameters :type))
 139         (return-list (plist-get parameters :return-list)))
 140     (if (and (not return-list)
 141              (or (eq type 'plain)
 142                  (and (memq type '(nil network))
 143                       (not (and (plist-get parameters :success)
 144                                 (plist-get parameters :capability-command))))))
 145         ;; The simplest case: wrapper around `make-network-process'.
 146         (make-network-process :name name :buffer buffer
 147                               :host host :service service
 148                               :nowait (plist-get parameters :nowait))
 149       (let ((work-buffer (or buffer
 150                              (generate-new-buffer " *stream buffer*")))
 151             (fun (cond ((and (eq type 'plain)
 152                              (not (plist-get parameters
 153                                              :always-query-capabilities)))
 154                         'network-stream-open-plain)
 155                        ((memq type '(nil network starttls plain))
 156                         'network-stream-open-starttls)
 157                        ((memq type '(tls ssl)) 'network-stream-open-tls)
 158                        ((eq type 'shell) 'network-stream-open-shell)
 159                        (t (error "Invalid connection type %s" type))))
 160             result)
 161         (unwind-protect
 162             (setq result (funcall fun name work-buffer host service parameters))
 163           (unless buffer
 164             (and (processp (car result))
 165                  (set-process-buffer (car result) nil))
 166             (kill-buffer work-buffer)))
 167         (if return-list
 168             (list (car result)
 169                   :greeting     (nth 1 result)
 170                   :capabilities (nth 2 result)
 171                   :type         (nth 3 result)
 172                   :error        (nth 4 result))
 173           (car result))))))
 174
 175 (defun network-stream-certificate (host service parameters)
 176   (let ((spec (plist-get :client-certificate parameters)))
 177     (cond
 178      ((listp spec)
 179       ;; Either nil or a list with a key/certificate pair.
 180       spec)
 181      ((eq spec t)
 182       (let* ((auth-info
 183               (car (auth-source-search :max 1
 184                                        :host host
 185                                        :port service)))
 186              (key (plist-get auth-info :key))
 187              (cert (plist-get auth-info :cert)))
 188         (and key cert
 189              (list key cert)))))))
 190
 191 ;;;###autoload
 192 (defalias 'open-protocol-stream 'open-network-stream)
 193
 194 (defun network-stream-open-plain (name buffer host service parameters)
 195   (let ((start (with-current-buffer buffer (point)))
 196         (stream (make-network-process :name name :buffer buffer
 197                                       :host host :service service
 198                                       :nowait (plist-get parameters :nowait))))
 199     (list stream
 200           (network-stream-get-response stream start
 201                                        (plist-get parameters :end-of-command))
 202           nil
 203           'plain)))
 204
 205 (defun network-stream-open-starttls (name buffer host service parameters)
 206   (let* ((start (with-current-buffer buffer (point)))
 207          (require-tls    (eq (plist-get parameters :type) 'starttls))
 208          (starttls-function  (plist-get parameters :starttls-function))
 209          (success-string     (plist-get parameters :success))
 210          (capability-command (plist-get parameters :capability-command))
 211          (eoc                (plist-get parameters :end-of-command))
 212          (eo-capa            (or (plist-get parameters :end-of-capability)
 213                                  eoc))
 214          ;; Return (STREAM GREETING CAPABILITIES RESULTING-TYPE)
 215          (stream (make-network-process :name name :buffer buffer
 216                                        :host host :service service))
 217          (greeting (and (not (plist-get parameters :nogreeting))
 218                         (network-stream-get-response stream start eoc)))
 219          (capabilities (network-stream-command stream capability-command
 220                                                eo-capa))
 221          (resulting-type 'plain)
 222          (builtin-starttls (and (fboundp 'gnutls-available-p)
 223                                 (gnutls-available-p)))
 224          starttls-available starttls-command error)
 225
 226     ;; First check whether the server supports STARTTLS at all.
 227     (when (and capabilities success-string starttls-function)
 228       (setq starttls-command
 229             (funcall starttls-function capabilities)))
 230     ;; If we have built-in STARTTLS support, try to upgrade the
 231     ;; connection.
 232     (when (and starttls-command
 233                (setq starttls-available
 234                      (or builtin-starttls
 235                          (and (or require-tls
 236                                   (plist-get parameters :use-starttls-if-possible))
 237                               (starttls-available-p))))
 238                (not (eq (plist-get parameters :type) 'plain)))
 239       ;; If using external STARTTLS, drop this connection and start
 240       ;; anew with `starttls-open-stream'.
 241       (unless builtin-starttls
 242         (delete-process stream)
 243         (setq start (with-current-buffer buffer (point-max)))
 244         (let* ((starttls-extra-arguments
 245                 (if (or require-tls
 246                         (member "--insecure" starttls-extra-arguments))
 247                     starttls-extra-arguments
 248                   ;; For opportunistic TLS upgrades, we don't really
 249                   ;; care about the identity of the peer.
 250                   (cons "--insecure" starttls-extra-arguments)))
 251                (starttls-extra-args starttls-extra-args)
 252                (cert (network-stream-certificate host service parameters)))
 253           ;; There are client certificates requested, so add them to
 254           ;; the command line.
 255           (when cert
 256             (setq starttls-extra-arguments
 257                   (nconc (list "--x509keyfile" (expand-file-name (nth 0 cert))
 258                                "--x509certfile" (expand-file-name (nth 1 cert)))
 259                          starttls-extra-arguments)
 260                   starttls-extra-args
 261                   (nconc (list "--key-file" (expand-file-name (nth 0 cert))
 262                                "--cert-file" (expand-file-name (nth 1 cert)))
 263                          starttls-extra-args)))
 264           (setq stream (starttls-open-stream name buffer host service)))
 265         (network-stream-get-response stream start eoc)
 266         ;; Requery capabilities for protocols that require it; i.e.,
 267         ;; EHLO for SMTP.
 268         (when (plist-get parameters :always-query-capabilities)
 269           (network-stream-command stream capability-command eo-capa)))
 270       (when (let ((response
 271                    (network-stream-command stream starttls-command eoc)))
 272               (and response (string-match success-string response)))
 273         ;; The server said it was OK to begin STARTTLS negotiations.
 274         (if builtin-starttls
 275             (let ((cert (network-stream-certificate host service parameters)))
 276               (condition-case nil
 277                   (gnutls-negotiate :process stream :hostname host
 278                                     :keylist (and cert (list cert)))
 279                 ;; If we get a gnutls-specific error (for instance if
 280                 ;; the certificate the server gives us is completely
 281                 ;; syntactically invalid), then close the connection
 282                 ;; and possibly (further down) try to create a
 283                 ;; non-encrypted connection.
 284                 (gnutls-error
 285                  (delete-process stream))))
 286           (unless (starttls-negotiate stream)
 287             (delete-process stream)))
 288         (if (memq (process-status stream) '(open run))
 289             (setq resulting-type 'tls)
 290           ;; We didn't successfully negotiate STARTTLS; if TLS
 291           ;; isn't demanded, reopen an unencrypted connection.
 292           (unless require-tls
 293             (setq stream
 294                   (make-network-process :name name :buffer buffer
 295                                         :host host :service service))
 296             (network-stream-get-response stream start eoc)))
 297         ;; Re-get the capabilities, which may have now changed.
 298         (setq capabilities
 299               (network-stream-command stream capability-command eo-capa))))
 300
 301     ;; If TLS is mandatory, close the connection if it's unencrypted.
 302     (when (and require-tls
 303                ;; ... but Emacs wasn't able to -- either no built-in
 304                ;; support, or no gnutls-cli installed.
 305                (eq resulting-type 'plain))
 306       (setq error
 307             (if (or (null starttls-command)
 308                     starttls-available)
 309                 "Server does not support TLS"
 310               ;; See `starttls-available-p'.  If this predicate
 311               ;; changes to allow running under Windows, the error
 312               ;; message below should be amended.
 313               (if (memq system-type '(windows-nt ms-dos))
 314                   (concat "Emacs does not support TLS")
 315                 (concat "Emacs does not support TLS, and no external `"
 316                         (if starttls-use-gnutls
 317                             starttls-gnutls-program
 318                           starttls-program)
 319                         "' program was found"))))
 320       (delete-process stream)
 321       (setq stream nil))
 322     ;; Return value:
 323     (list stream greeting capabilities resulting-type error)))
 324
 325 (defun network-stream-command (stream command eoc)
 326   (when command
 327     (let ((start (with-current-buffer (process-buffer stream) (point-max))))
 328       (process-send-string stream command)
 329       (network-stream-get-response stream start eoc))))
 330
 331 (defun network-stream-get-response (stream start end-of-command)
 332   (when end-of-command
 333     (with-current-buffer (process-buffer stream)
 334       (save-excursion
 335         (goto-char start)
 336         (while (and (memq (process-status stream) '(open run))
 337                     (not (re-search-forward end-of-command nil t)))
 338           (accept-process-output stream 0 50)
 339           (goto-char start))
 340         ;; Return the data we got back, or nil if the process died.
 341         (unless (= start (point))
 342           (buffer-substring start (point)))))))
 343
 344 (defun network-stream-open-tls (name buffer host service parameters)
 345   (with-current-buffer buffer
 346     (let* ((start (point-max))
 347            (use-builtin-gnutls (and (fboundp 'gnutls-available-p)
 348                                     (gnutls-available-p)))
 349            (stream
 350             (funcall (if use-builtin-gnutls
 351                          'open-gnutls-stream
 352                        'open-tls-stream)
 353                      name buffer host service))
 354            (eoc (plist-get parameters :end-of-command)))
 355       (if (null stream)
 356           (list nil nil nil 'plain)
 357         ;; If we're using tls.el, we have to delete the output from
 358         ;; openssl/gnutls-cli.
 359         (when (and (null use-builtin-gnutls)
 360                    eoc)
 361           (network-stream-get-response stream start eoc)
 362           (goto-char (point-min))
 363           (when (re-search-forward eoc nil t)
 364             (goto-char (match-beginning 0))
 365             (delete-region (point-min) (line-beginning-position))))
 366         (let* ((capability-command (plist-get parameters :capability-command)))
 367           (list stream
 368                 (network-stream-get-response stream start eoc)
 369                 (network-stream-command stream capability-command eoc)
 370                 'tls))))))
 371
 372 (defun network-stream-open-shell (name buffer host service parameters)
 373   (require 'format-spec)
 374   (let* ((capability-command (plist-get parameters :capability-command))
 375          (eoc                (plist-get parameters :end-of-command))
 376          (start (with-current-buffer buffer (point)))
 377          (stream (let ((process-connection-type nil))
 378                    (start-process name buffer shell-file-name
 379                                   shell-command-switch
 380                                   (format-spec
 381                                    (plist-get parameters :shell-command)
 382                                    (format-spec-make
 383                                     ?s host
 384                                     ?p service))))))
 385     (list stream
 386           (network-stream-get-response stream start eoc)
 387           (network-stream-command stream capability-command
 388                                   (or (plist-get parameters :end-of-capability)
 389                                       eoc))
 390           'plain)))
 391
 392 (provide 'network-stream)
 393
 394 ;;; network-stream.el ends here