lisp/xt-mouse.el

   1 ;;; xt-mouse.el --- support the mouse when emacs run in an xterm
   2
   3 ;; Copyright (C) 1994, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   7 ;; Keywords: mouse, terminals
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Enable mouse support when running inside an xterm.
  29
  30 ;; This is actually useful when you are running X11 locally, but is
  31 ;; working on remote machine over a modem line or through a gateway.
  32
  33 ;; It works by translating xterm escape codes into generic emacs mouse
  34 ;; events so it should work with any package that uses the mouse.
  35
  36 ;; You don't have to turn off xterm mode to use the normal xterm mouse
  37 ;; functionality, it is still available by holding down the SHIFT key
  38 ;; when you press the mouse button.
  39
  40 ;;; Todo:
  41
  42 ;; Support multi-click -- somehow.
  43
  44 ;;; Code:
  45
  46 (define-key function-key-map "\e[M" 'xterm-mouse-translate)
  47
  48 (defvar xterm-mouse-last)
  49
  50 ;; Mouse events symbols must have an 'event-kind property with
  51 ;; the value 'mouse-click.
  52 (dolist (event-type '(mouse-1 mouse-2 mouse-3))
  53   (put event-type 'event-kind 'mouse-click))
  54
  55 (defun xterm-mouse-translate (event)
  56   "Read a click and release event from XTerm."
  57   (save-excursion
  58     (save-window-excursion
  59       (deactivate-mark)
  60       (let* ((xterm-mouse-last)
  61              (down (xterm-mouse-event))
  62              (down-command (nth 0 down))
  63              (down-data (nth 1 down))
  64              (down-where (nth 1 down-data))
  65              (down-binding (key-binding (if (symbolp down-where)
  66                                             (vector down-where down-command)
  67                                           (vector down-command))))
  68              (is-click (string-match "^mouse" (symbol-name (car down)))))
  69
  70         (unless is-click
  71           (unless (and (eq (read-char) ?\e)
  72                        (eq (read-char) ?\[)
  73                        (eq (read-char) ?M))
  74             (error "Unexpected escape sequence from XTerm")))
  75
  76         (let* ((click (if is-click down (xterm-mouse-event)))
  77                (click-command (nth 0 click))
  78                (click-data (nth 1 click))
  79                (click-where (nth 1 click-data)))
  80           (if (memq down-binding '(nil ignore))
  81               (if (and (symbolp click-where)
  82                        (consp click-where))
  83                   (vector (list click-where click-data) click)
  84                 (vector click))
  85             (setq unread-command-events
  86                   (if (eq down-where click-where)
  87                       (list click)
  88                     (list
  89                      ;; Cheat `mouse-drag-region' with move event.
  90                      (list 'mouse-movement click-data)
  91                      ;; Generate a drag event.
  92                      (if (symbolp down-where)
  93                          0
  94                        (list (intern (format "drag-mouse-%d"
  95                                              (+ 1 xterm-mouse-last)))
  96                              down-data click-data)))))
  97             (if (and (symbolp down-where)
  98                      (consp down-where))
  99                 (vector (list down-where down-data) down)
 100               (vector down))))))))
 101
 102 (defvar xterm-mouse-x 0
 103   "Position of last xterm mouse event relative to the frame.")
 104
 105 (defvar xterm-mouse-y 0
 106   "Position of last xterm mouse event relative to the frame.")
 107
 108 ;; Indicator for the xterm-mouse mode.
 109
 110 (defun xterm-mouse-position-function (pos)
 111   "Bound to `mouse-position-function' in XTerm mouse mode."
 112   (setcdr pos (cons xterm-mouse-x xterm-mouse-y))
 113   pos)
 114
 115 ;; read xterm sequences above ascii 127 (#x7f)
 116 (defun xterm-mouse-event-read ()
 117   (let ((c (read-char)))
 118     (if (< c 0)
 119         (+ c #x8000000 128)
 120       c)))
 121
 122 (defun xterm-mouse-event ()
 123   "Convert XTerm mouse event to Emacs mouse event."
 124   (let* ((type (- (xterm-mouse-event-read) #o40))
 125          (x (- (xterm-mouse-event-read) #o40 1))
 126          (y (- (xterm-mouse-event-read) #o40 1))
 127          (mouse (intern
 128                  ;; For buttons > 3, the release-event looks
 129                  ;; differently (see xc/programs/xterm/button.c,
 130                  ;; function EditorButton), and there seems to come in
 131                  ;; a release-event only, no down-event.
 132                  (cond ((>= type 64)
 133                         (format "mouse-%d" (- type 60)))
 134                        ((= type 3)
 135                         (format "mouse-%d" (+ 1 xterm-mouse-last)))
 136                        (t
 137                         (setq xterm-mouse-last type)
 138                         (format "down-mouse-%d" (+ 1 type))))))
 139          (w (window-at x y))
 140          (ltrb (window-edges w))
 141          (left (nth 0 ltrb))
 142          (top (nth 1 ltrb)))
 143
 144     (setq xterm-mouse-x x
 145           xterm-mouse-y y)
 146     (setq
 147      last-input-event
 148      (if w
 149          (list mouse (posn-at-x-y (- x left) (- y top) w t))
 150        (list mouse
 151              (append (list nil 'menu-bar) (nthcdr 2 (posn-at-x-y x y w t))))))))
 152
 153 ;;;###autoload
 154 (define-minor-mode xterm-mouse-mode
 155   "Toggle XTerm mouse mode.
 156 With prefix arg, turn XTerm mouse mode on iff arg is positive.
 157
 158 Turn it on to use Emacs mouse commands, and off to use xterm mouse commands.
 159 This works in terminal emulators compatible with xterm.  It only
 160 works for simple uses of the mouse.  Basically, only non-modified
 161 single clicks are supported.  When turned on, the normal xterm
 162 mouse functionality for such clicks is still available by holding
 163 down the SHIFT key while pressing the mouse button."
 164   :global t :group 'mouse
 165   (if xterm-mouse-mode
 166       ;; Turn it on
 167       (unless window-system
 168         (setq mouse-position-function #'xterm-mouse-position-function)
 169         (turn-on-xterm-mouse-tracking))
 170     ;; Turn it off
 171     (turn-off-xterm-mouse-tracking 'force)
 172     (setq mouse-position-function nil)))
 173
 174 (defun turn-on-xterm-mouse-tracking ()
 175   "Enable Emacs mouse tracking in xterm."
 176   (if xterm-mouse-mode
 177       (send-string-to-terminal "\e[?1000h")))
 178
 179 (defun turn-off-xterm-mouse-tracking (&optional force)
 180   "Disable Emacs mouse tracking in xterm."
 181   (if (or force xterm-mouse-mode)
 182       (send-string-to-terminal "\e[?1000l")))
 183
 184 ;; Restore normal mouse behaviour outside Emacs.
 185 (add-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
 186 (add-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
 187 (add-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
 188
 189 (provide 'xt-mouse)
 190
 191 ;;; arch-tag: 84962d4e-fae9-4c13-a9d7-ef4925a4ac03
 192 ;;; xt-mouse.el ends here