lisp/image.el

   1 ;;; image.el --- image API
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005, 2006, 2007, 2008, 2009 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: multimedia
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28
  29 (defgroup image ()
  30   "Image support."
  31   :group 'multimedia)
  32
  33
  34 (defconst image-type-header-regexps
  35   `(("\\`/[\t\n\r ]*\\*.*XPM.\\*/" . xpm)
  36     ("\\`P[1-6][[:space:]]+\\(?:#.*[[:space:]]+\\)*[0-9]+[[:space:]]+[0-9]+" . pbm)
  37     ("\\`GIF8[79]a" . gif)
  38     ("\\`\x89PNG\r\n\x1a\n" . png)
  39     ("\\`[\t\n\r ]*#define \\([a-z0-9_]+\\)_width [0-9]+\n\
  40 #define \\1_height [0-9]+\n\\(\
  41 #define \\1_x_hot [0-9]+\n\
  42 #define \\1_y_hot [0-9]+\n\\)?\
  43 static \\(unsigned \\)?char \\1_bits" . xbm)
  44     ("\\`\\(?:MM\0\\*\\|II\\*\0\\)" . tiff)
  45     ("\\`[\t\n\r ]*%!PS" . postscript)
  46     ("\\`\xff\xd8" . jpeg)    ; used to be (image-jpeg-p . jpeg)
  47     (,(let* ((incomment-re "\\(?:[^-]\\|-[^-]\\)")
  48              (comment-re (concat "\\(?:!--" incomment-re "*-->[ \t\r\n]*<\\)")))
  49         (concat "\\(?:<\\?xml[ \t\r\n]+[^>]*>\\)?[ \t\r\n]*<"
  50                 comment-re "*"
  51                 "\\(?:!DOCTYPE[ \t\r\n]+[^>]*>[ \t\r\n]*<[ \t\r\n]*" comment-re "*\\)?"
  52                 "[Ss][Vv][Gg]"))
  53      . svg)
  54     )
  55   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
  56 When the first bytes of an image file match REGEXP, it is assumed to
  57 be of image type IMAGE-TYPE if IMAGE-TYPE is a symbol.  If not a symbol,
  58 IMAGE-TYPE must be a pair (PREDICATE . TYPE).  PREDICATE is called
  59 with one argument, a string containing the image data.  If PREDICATE returns
  60 a non-nil value, TYPE is the image's type.")
  61
  62 (defconst image-type-file-name-regexps
  63   '(("\\.png\\'" . png)
  64     ("\\.gif\\'" . gif)
  65     ("\\.jpe?g\\'" . jpeg)
  66     ("\\.bmp\\'" . bmp)
  67     ("\\.xpm\\'" . xpm)
  68     ("\\.pbm\\'" . pbm)
  69     ("\\.xbm\\'" . xbm)
  70     ("\\.ps\\'" . postscript)
  71     ("\\.tiff?\\'" . tiff)
  72     ("\\.svgz?\\'" . svg)
  73     )
  74   "Alist of (REGEXP . IMAGE-TYPE) pairs used to identify image files.
  75 When the name of an image file match REGEXP, it is assumed to
  76 be of image type IMAGE-TYPE.")
  77
  78 ;; We rely on `auto-mode-alist' to detect xbm and xpm files, instead
  79 ;; of content autodetection.  Their contents are just C code, so it is
  80 ;; easy to generate false matches.
  81 (defvar image-type-auto-detectable
  82   '((pbm . t)
  83     (xbm . nil)
  84     (bmp . maybe)
  85     (gif . maybe)
  86     (png . maybe)
  87     (xpm . nil)
  88     (jpeg . maybe)
  89     (tiff . maybe)
  90     (svg . maybe)
  91     (postscript . nil))
  92   "Alist of (IMAGE-TYPE . AUTODETECT) pairs used to auto-detect image files.
  93 \(See `image-type-auto-detected-p').
  94
  95 AUTODETECT can be
  96  - t      always auto-detect.
  97  - nil    never auto-detect.
  98  - maybe  auto-detect only if the image type is available
  99             (see `image-type-available-p').")
 100
 101 (defcustom image-load-path
 102   (list (file-name-as-directory (expand-file-name "images" data-directory))
 103         'data-directory 'load-path)
 104   "List of locations in which to search for image files.
 105 If an element is a string, it defines a directory to search.
 106 If an element is a variable symbol whose value is a string, that
 107 value defines a directory to search.
 108 If an element is a variable symbol whose value is a list, the
 109 value is used as a list of directories to search."
 110   :type '(repeat (choice directory variable))
 111   :initialize 'custom-initialize-delay)
 112
 113
 114 (defun image-load-path-for-library (library image &optional path no-error)
 115   "Return a suitable search path for images used by LIBRARY.
 116
 117 It searches for IMAGE in `image-load-path' (excluding
 118 \"`data-directory'/images\") and `load-path', followed by a path
 119 suitable for LIBRARY, which includes \"../../etc/images\" and
 120 \"../etc/images\" relative to the library file itself, and then
 121 in \"`data-directory'/images\".
 122
 123 Then this function returns a list of directories which contains
 124 first the directory in which IMAGE was found, followed by the
 125 value of `load-path'.  If PATH is given, it is used instead of
 126 `load-path'.
 127
 128 If NO-ERROR is non-nil and a suitable path can't be found, don't
 129 signal an error.  Instead, return a list of directories as before,
 130 except that nil appears in place of the image directory.
 131
 132 Here is an example that uses a common idiom to provide
 133 compatibility with versions of Emacs that lack the variable
 134 `image-load-path':
 135
 136     ;; Shush compiler.
 137     (defvar image-load-path)
 138
 139     (let* ((load-path (image-load-path-for-library \"mh-e\" \"mh-logo.xpm\"))
 140            (image-load-path (cons (car load-path)
 141                                   (when (boundp 'image-load-path)
 142                                     image-load-path))))
 143       (mh-tool-bar-folder-buttons-init))"
 144   (unless library (error "No library specified"))
 145   (unless image   (error "No image specified"))
 146   (let (image-directory image-directory-load-path)
 147     ;; Check for images in image-load-path or load-path.
 148     (let ((img image)
 149           (dir (or
 150                 ;; Images in image-load-path.
 151                 (image-search-load-path image)
 152                 ;; Images in load-path.
 153                 (locate-library image)))
 154           parent)
 155       ;; Since the image might be in a nested directory (for
 156       ;; example, mail/attach.pbm), adjust `image-directory'
 157       ;; accordingly.
 158       (when dir
 159         (setq dir (file-name-directory dir))
 160         (while (setq parent (file-name-directory img))
 161           (setq img (directory-file-name parent)
 162                 dir (expand-file-name "../" dir))))
 163       (setq image-directory-load-path dir))
 164
 165     ;; If `image-directory-load-path' isn't Emacs' image directory,
 166     ;; it's probably a user preference, so use it. Then use a
 167     ;; relative setting if possible; otherwise, use
 168     ;; `image-directory-load-path'.
 169     (cond
 170      ;; User-modified image-load-path?
 171      ((and image-directory-load-path
 172            (not (equal image-directory-load-path
 173                        (file-name-as-directory
 174                         (expand-file-name "images" data-directory)))))
 175       (setq image-directory image-directory-load-path))
 176      ;; Try relative setting.
 177      ((let (library-name d1ei d2ei)
 178         ;; First, find library in the load-path.
 179         (setq library-name (locate-library library))
 180         (if (not library-name)
 181             (error "Cannot find library %s in load-path" library))
 182         ;; And then set image-directory relative to that.
 183         (setq
 184          ;; Go down 2 levels.
 185          d2ei (file-name-as-directory
 186                (expand-file-name
 187                 (concat (file-name-directory library-name) "../../etc/images")))
 188          ;; Go down 1 level.
 189          d1ei (file-name-as-directory
 190                (expand-file-name
 191                 (concat (file-name-directory library-name) "../etc/images"))))
 192         (setq image-directory
 193               ;; Set it to nil if image is not found.
 194               (cond ((file-exists-p (expand-file-name image d2ei)) d2ei)
 195                     ((file-exists-p (expand-file-name image d1ei)) d1ei)))))
 196      ;; Use Emacs' image directory.
 197      (image-directory-load-path
 198       (setq image-directory image-directory-load-path))
 199      (no-error
 200       (message "Could not find image %s for library %s" image library))
 201      (t
 202       (error "Could not find image %s for library %s" image library)))
 203
 204     ;; Return an augmented `path' or `load-path'.
 205     (nconc (list image-directory)
 206            (delete image-directory (copy-sequence (or path load-path))))))
 207
 208
 209 (defun image-jpeg-p (data)
 210   "Value is non-nil if DATA, a string, consists of JFIF image data.
 211 We accept the tag Exif because that is the same format."
 212   (setq data (ignore-errors (string-to-unibyte data)))
 213   (when (and data (string-match-p "\\`\xff\xd8" data))
 214     (catch 'jfif
 215       (let ((len (length data)) (i 2))
 216         (while (< i len)
 217           (when (/= (aref data i) #xff)
 218             (throw 'jfif nil))
 219           (setq i (1+ i))
 220           (when (>= (+ i 2) len)
 221             (throw 'jfif nil))
 222           (let ((nbytes (+ (lsh (aref data (+ i 1)) 8)
 223                            (aref data (+ i 2))))
 224                 (code (aref data i)))
 225             (when (and (>= code #xe0) (<= code #xef))
 226               ;; APP0 LEN1 LEN2 "JFIF\0"
 227               (throw 'jfif
 228                      (string-match-p "JFIF\\|Exif"
 229                                      (substring data i (min (+ i nbytes) len)))))
 230             (setq i (+ i 1 nbytes))))))))
 231
 232
 233 ;;;###autoload
 234 (defun image-type-from-data (data)
 235   "Determine the image type from image data DATA.
 236 Value is a symbol specifying the image type or nil if type cannot
 237 be determined."
 238   (let ((types image-type-header-regexps)
 239         type)
 240     (while types
 241       (let ((regexp (car (car types)))
 242             (image-type (cdr (car types))))
 243         (if (or (and (symbolp image-type)
 244                      (string-match-p regexp data))
 245                 (and (consp image-type)
 246                      (funcall (car image-type) data)
 247                      (setq image-type (cdr image-type))))
 248             (setq type image-type
 249                   types nil)
 250           (setq types (cdr types)))))
 251     type))
 252
 253
 254 ;;;###autoload
 255 (defun image-type-from-buffer ()
 256   "Determine the image type from data in the current buffer.
 257 Value is a symbol specifying the image type or nil if type cannot
 258 be determined."
 259   (let ((types image-type-header-regexps)
 260         type
 261         (opoint (point)))
 262     (goto-char (point-min))
 263     (while types
 264       (let ((regexp (car (car types)))
 265             (image-type (cdr (car types)))
 266             data)
 267         (if (or (and (symbolp image-type)
 268                      (looking-at-p regexp))
 269                 (and (consp image-type)
 270                      (funcall (car image-type)
 271                               (or data
 272                                   (setq data
 273                                         (buffer-substring
 274                                          (point-min)
 275                                          (min (point-max)
 276                                               (+ (point-min) 256))))))
 277                      (setq image-type (cdr image-type))))
 278             (setq type image-type
 279                   types nil)
 280           (setq types (cdr types)))))
 281     (goto-char opoint)
 282     type))
 283
 284
 285 ;;;###autoload
 286 (defun image-type-from-file-header (file)
 287   "Determine the type of image file FILE from its first few bytes.
 288 Value is a symbol specifying the image type, or nil if type cannot
 289 be determined."
 290   (unless (or (file-readable-p file)
 291               (file-name-absolute-p file))
 292     (setq file (image-search-load-path file)))
 293   (and file
 294        (file-readable-p file)
 295        (with-temp-buffer
 296          (set-buffer-multibyte nil)
 297          (insert-file-contents-literally file nil 0 256)
 298          (image-type-from-buffer))))
 299
 300
 301 ;;;###autoload
 302 (defun image-type-from-file-name (file)
 303   "Determine the type of image file FILE from its name.
 304 Value is a symbol specifying the image type, or nil if type cannot
 305 be determined."
 306   (assoc-default file image-type-file-name-regexps 'string-match-p))
 307
 308
 309 ;;;###autoload
 310 (defun image-type (source &optional type data-p)
 311   "Determine and return image type.
 312 SOURCE is an image file name or image data.
 313 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 314 or nil, try to determine the image type from its first few bytes
 315 of image data.  If that doesn't work, and SOURCE is a file name,
 316 use its file extension as image type.
 317 Optional DATA-P non-nil means SOURCE is a string containing image data."
 318   (when (and (not data-p) (not (stringp source)))
 319     (error "Invalid image file name `%s'" source))
 320   (unless type
 321     (setq type (if data-p
 322                    (image-type-from-data source)
 323                  (or (image-type-from-file-header source)
 324                      (image-type-from-file-name source))))
 325     (or type (error "Cannot determine image type")))
 326   (or (memq type (and (boundp 'image-types) image-types))
 327       (error "Invalid image type `%s'" type))
 328   type)
 329
 330
 331 (defvar image-library-alist)
 332
 333 ;;;###autoload
 334 (defun image-type-available-p (type)
 335   "Return non-nil if image type TYPE is available.
 336 Image types are symbols like `xbm' or `jpeg'."
 337   (and (fboundp 'init-image-library)
 338        (init-image-library type image-library-alist)))
 339
 340
 341 ;;;###autoload
 342 (defun image-type-auto-detected-p ()
 343   "Return t if the current buffer contains an auto-detectable image.
 344 This function is intended to be used from `magic-fallback-mode-alist'.
 345
 346 The buffer is considered to contain an auto-detectable image if
 347 its beginning matches an image type in `image-type-header-regexps',
 348 and that image type is present in `image-type-auto-detectable' with a
 349 non-nil value.  If that value is non-nil, but not t, then the image type
 350 must be available."
 351   (let* ((type (image-type-from-buffer))
 352          (auto (and type (cdr (assq type image-type-auto-detectable)))))
 353     (and auto
 354          (or (eq auto t) (image-type-available-p type)))))
 355
 356
 357 ;;;###autoload
 358 (defun create-image (file-or-data &optional type data-p &rest props)
 359   "Create an image.
 360 FILE-OR-DATA is an image file name or image data.
 361 Optional TYPE is a symbol describing the image type.  If TYPE is omitted
 362 or nil, try to determine the image type from its first few bytes
 363 of image data.  If that doesn't work, and FILE-OR-DATA is a file name,
 364 use its file extension as image type.
 365 Optional DATA-P non-nil means FILE-OR-DATA is a string containing image data.
 366 Optional PROPS are additional image attributes to assign to the image,
 367 like, e.g. `:mask MASK'.
 368 Value is the image created, or nil if images of type TYPE are not supported.
 369
 370 Images should not be larger than specified by `max-image-size'.
 371
 372 Image file names that are not absolute are searched for in the
 373 \"images\" sub-directory of `data-directory' and
 374 `x-bitmap-file-path' (in that order)."
 375   ;; It is x_find_image_file in image.c that sets the search path.
 376   (setq type (image-type file-or-data type data-p))
 377   (when (image-type-available-p type)
 378     (append (list 'image :type type (if data-p :data :file) file-or-data)
 379             props)))
 380
 381
 382 ;;;###autoload
 383 (defun put-image (image pos &optional string area)
 384   "Put image IMAGE in front of POS in the current buffer.
 385 IMAGE must be an image created with `create-image' or `defimage'.
 386 IMAGE is displayed by putting an overlay into the current buffer with a
 387 `before-string' STRING that has a `display' property whose value is the
 388 image.  STRING is defaulted if you omit it.
 389 POS may be an integer or marker.
 390 AREA is where to display the image.  AREA nil or omitted means
 391 display it in the text area, a value of `left-margin' means
 392 display it in the left marginal area, a value of `right-margin'
 393 means display it in the right marginal area."
 394   (unless string (setq string "x"))
 395   (let ((buffer (current-buffer)))
 396     (unless (eq (car-safe image) 'image)
 397       (error "Not an image: %s" image))
 398     (unless (or (null area) (memq area '(left-margin right-margin)))
 399       (error "Invalid area %s" area))
 400     (setq string (copy-sequence string))
 401     (let ((overlay (make-overlay pos pos buffer))
 402           (prop (if (null area) image (list (list 'margin area) image))))
 403       (put-text-property 0 (length string) 'display prop string)
 404       (overlay-put overlay 'put-image t)
 405       (overlay-put overlay 'before-string string))))
 406
 407
 408 ;;;###autoload
 409 (defun insert-image (image &optional string area slice)
 410   "Insert IMAGE into current buffer at point.
 411 IMAGE is displayed by inserting STRING into the current buffer
 412 with a `display' property whose value is the image.  STRING is
 413 defaulted if you omit it.
 414 AREA is where to display the image.  AREA nil or omitted means
 415 display it in the text area, a value of `left-margin' means
 416 display it in the left marginal area, a value of `right-margin'
 417 means display it in the right marginal area.
 418 SLICE specifies slice of IMAGE to insert.  SLICE nil or omitted
 419 means insert whole image.  SLICE is a list (X Y WIDTH HEIGHT)
 420 specifying the X and Y positions and WIDTH and HEIGHT of image area
 421 to insert.  A float value 0.0 - 1.0 means relative to the width or
 422 height of the image; integer values are taken as pixel values."
 423   ;; Use a space as least likely to cause trouble when it's a hidden
 424   ;; character in the buffer.
 425   (unless string (setq string " "))
 426   (unless (eq (car-safe image) 'image)
 427     (error "Not an image: %s" image))
 428   (unless (or (null area) (memq area '(left-margin right-margin)))
 429     (error "Invalid area %s" area))
 430   (if area
 431       (setq image (list (list 'margin area) image))
 432     ;; Cons up a new spec equal but not eq to `image' so that
 433     ;; inserting it twice in a row (adjacently) displays two copies of
 434     ;; the image.  Don't try to avoid this by looking at the display
 435     ;; properties on either side so that we DTRT more often with
 436     ;; cut-and-paste.  (Yanking killed image text next to another copy
 437     ;; of it loses anyway.)
 438     (setq image (cons 'image (cdr image))))
 439   (let ((start (point)))
 440     (insert string)
 441     (add-text-properties start (point)
 442                          `(display ,(if slice
 443                                         (list (cons 'slice slice) image)
 444                                       image) rear-nonsticky (display)))))
 445
 446
 447 ;;;###autoload
 448 (defun insert-sliced-image (image &optional string area rows cols)
 449   "Insert IMAGE into current buffer at point.
 450 IMAGE is displayed by inserting STRING into the current buffer
 451 with a `display' property whose value is the image.  STRING is
 452 defaulted if you omit it.
 453 AREA is where to display the image.  AREA nil or omitted means
 454 display it in the text area, a value of `left-margin' means
 455 display it in the left marginal area, a value of `right-margin'
 456 means display it in the right marginal area.
 457 The image is automatically split into ROWS x COLS slices."
 458   (unless string (setq string " "))
 459   (unless (eq (car-safe image) 'image)
 460     (error "Not an image: %s" image))
 461   (unless (or (null area) (memq area '(left-margin right-margin)))
 462     (error "Invalid area %s" area))
 463   (if area
 464       (setq image (list (list 'margin area) image))
 465     ;; Cons up a new spec equal but not eq to `image' so that
 466     ;; inserting it twice in a row (adjacently) displays two copies of
 467     ;; the image.  Don't try to avoid this by looking at the display
 468     ;; properties on either side so that we DTRT more often with
 469     ;; cut-and-paste.  (Yanking killed image text next to another copy
 470     ;; of it loses anyway.)
 471     (setq image (cons 'image (cdr image))))
 472   (let ((x 0.0) (dx (/ 1.0001 (or cols 1)))
 473          (y 0.0) (dy (/ 1.0001 (or rows 1))))
 474     (while (< y 1.0)
 475       (while (< x 1.0)
 476         (let ((start (point)))
 477           (insert string)
 478           (add-text-properties start (point)
 479                                `(display ,(list (list 'slice x y dx dy) image)
 480                                          rear-nonsticky (display)))
 481           (setq x (+ x dx))))
 482       (setq x 0.0
 483             y (+ y dy))
 484       (insert (propertize "\n" 'line-height t)))))
 485
 486
 487
 488 ;;;###autoload
 489 (defun remove-images (start end &optional buffer)
 490   "Remove images between START and END in BUFFER.
 491 Remove only images that were put in BUFFER with calls to `put-image'.
 492 BUFFER nil or omitted means use the current buffer."
 493   (unless buffer
 494     (setq buffer (current-buffer)))
 495   (let ((overlays (overlays-in start end)))
 496     (while overlays
 497       (let ((overlay (car overlays)))
 498         (when (overlay-get overlay 'put-image)
 499           (delete-overlay overlay)))
 500       (setq overlays (cdr overlays)))))
 501
 502 (defun image-search-load-path (file &optional path)
 503   (unless path
 504     (setq path image-load-path))
 505   (let (element found filename)
 506     (while (and (not found) (consp path))
 507       (setq element (car path))
 508       (cond
 509        ((stringp element)
 510         (setq found
 511               (file-readable-p
 512                (setq filename (expand-file-name file element)))))
 513        ((and (symbolp element) (boundp element))
 514         (setq element (symbol-value element))
 515         (cond
 516          ((stringp element)
 517           (setq found
 518                 (file-readable-p
 519                  (setq filename (expand-file-name file element)))))
 520          ((consp element)
 521           (if (setq filename (image-search-load-path file element))
 522               (setq found t))))))
 523       (setq path (cdr path)))
 524     (if found filename)))
 525
 526 ;;;###autoload
 527 (defun find-image (specs)
 528   "Find an image, choosing one of a list of image specifications.
 529
 530 SPECS is a list of image specifications.
 531
 532 Each image specification in SPECS is a property list.  The contents of
 533 a specification are image type dependent.  All specifications must at
 534 least contain the properties `:type TYPE' and either `:file FILE' or
 535 `:data DATA', where TYPE is a symbol specifying the image type,
 536 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 537 string containing the actual image data.  The specification whose TYPE
 538 is supported, and FILE exists, is used to construct the image
 539 specification to be returned.  Return nil if no specification is
 540 satisfied.
 541
 542 The image is looked for in `image-load-path'.
 543
 544 Image files should not be larger than specified by `max-image-size'."
 545   (let (image)
 546     (while (and specs (null image))
 547       (let* ((spec (car specs))
 548              (type (plist-get spec :type))
 549              (data (plist-get spec :data))
 550              (file (plist-get spec :file))
 551              found)
 552         (when (image-type-available-p type)
 553           (cond ((stringp file)
 554                  (if (setq found (image-search-load-path file))
 555                      (setq image
 556                            (cons 'image (plist-put (copy-sequence spec)
 557                                                    :file found)))))
 558                 ((not (null data))
 559                  (setq image (cons 'image spec)))))
 560         (setq specs (cdr specs))))
 561     image))
 562
 563
 564 ;;;###autoload
 565 (defmacro defimage (symbol specs &optional doc)
 566   "Define SYMBOL as an image.
 567
 568 SPECS is a list of image specifications.  DOC is an optional
 569 documentation string.
 570
 571 Each image specification in SPECS is a property list.  The contents of
 572 a specification are image type dependent.  All specifications must at
 573 least contain the properties `:type TYPE' and either `:file FILE' or
 574 `:data DATA', where TYPE is a symbol specifying the image type,
 575 e.g. `xbm', FILE is the file to load the image from, and DATA is a
 576 string containing the actual image data.  The first image
 577 specification whose TYPE is supported, and FILE exists, is used to
 578 define SYMBOL.
 579
 580 Example:
 581
 582    (defimage test-image ((:type xpm :file \"~/test1.xpm\")
 583                          (:type xbm :file \"~/test1.xbm\")))"
 584   (declare (doc-string 3))
 585   `(defvar ,symbol (find-image ',specs) ,doc))
 586
 587
 588 (provide 'image)
 589
 590 ;; arch-tag: 8e76a07b-eb48-4f3e-a7a0-1a7ba9f096b3
 591 ;;; image.el ends here