lisp/delsel.el

   1 ;;; delsel.el --- delete selection if you insert
   2
   3 ;; Copyright (C) 1992, 1997, 1998, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Author: Matthieu Devin <devin@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 14 Jul 92
   9 ;; Keywords: convenience emulations
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This file makes the active region be pending delete, meaning that
  31 ;; text inserted while the region is active will replace the region contents.
  32 ;; This is a popular behavior of personal computers text editors.
  33
  34 ;; Interface:
  35
  36 ;; Commands which will delete the selection need a 'delete-selection
  37 ;; property on their symbols; commands which insert text but don't
  38 ;; have this property won't delete the selction.  It can be one of
  39 ;; the values:
  40 ;;  'yank
  41 ;;      For commands which do a yank; ensures the region about to be
  42 ;;      deleted isn't yanked.
  43 ;;  'supersede
  44 ;;      Delete the active region and ignore the current command,
  45 ;;      i.e. the command will just delete the region.
  46 ;;  'kill
  47 ;;      `kill-region' is used on the selection, rather than
  48 ;;      `delete-region'.  (Text selected with the mouse will typically
  49 ;;      be yankable anyhow.)
  50 ;;  non-nil
  51 ;;      The normal case: delete the active region prior to executing
  52 ;;      the command which will insert replacement text.
  53
  54 ;;; Code:
  55
  56 ;;;###autoload
  57 (defalias 'pending-delete-mode 'delete-selection-mode)
  58
  59 ;;;###autoload
  60 (define-minor-mode delete-selection-mode
  61   "Toggle Delete Selection mode.
  62 With prefix ARG, turn Delete Selection mode on if and only if ARG is
  63 positive.
  64
  65 When Delete Selection mode is enabled, Transient Mark mode is also
  66 enabled and typed text replaces the selection if the selection is
  67 active.  Otherwise, typed text is just inserted at point regardless of
  68 any selection."
  69   :global t :group 'editing-basics
  70   (if (not delete-selection-mode)
  71       (remove-hook 'pre-command-hook 'delete-selection-pre-hook)
  72     (add-hook 'pre-command-hook 'delete-selection-pre-hook)
  73     (transient-mark-mode t)))
  74
  75 (defun delete-active-region (&optional killp)
  76   (if killp
  77       (kill-region (point) (mark))
  78     (delete-region (point) (mark)))
  79   t)
  80
  81 (defun delete-selection-pre-hook ()
  82   (when (and delete-selection-mode transient-mark-mode mark-active
  83              (not buffer-read-only))
  84     (let ((type (and (symbolp this-command)
  85                      (get this-command 'delete-selection))))
  86       (condition-case data
  87           (cond ((eq type 'kill)
  88                  (delete-active-region t))
  89                 ((eq type 'yank)
  90                  ;; Before a yank command, make sure we don't yank the
  91                  ;; head of the kill-ring that really comes from the
  92                  ;; currently active region we are going to delete.
  93                  ;; That would make yank a no-op.
  94                  (when (and (string= (buffer-substring-no-properties (point) (mark))
  95                                      (car kill-ring))
  96                             (mouse-region-match))
  97                    (current-kill 1))
  98                  (delete-active-region))
  99                 ((eq type 'supersede)
 100                  (let ((empty-region (= (point) (mark))))
 101                    (delete-active-region)
 102                    (unless empty-region
 103                      (setq this-command 'ignore))))
 104                 (type
 105                  (delete-active-region)
 106                  (if (and overwrite-mode (eq this-command 'self-insert-command))
 107                    (let ((overwrite-mode nil))
 108                      (self-insert-command (prefix-numeric-value current-prefix-arg))
 109                      (setq this-command 'ignore)))))
 110         (file-supersession
 111          ;; If ask-user-about-supersession-threat signals an error,
 112          ;; stop safe_run_hooks from clearing out pre-command-hook.
 113          (and (eq inhibit-quit 'pre-command-hook)
 114               (setq inhibit-quit 'delete-selection-dummy))
 115          (signal 'file-supersession (cdr data)))))))
 116
 117 (put 'self-insert-command 'delete-selection t)
 118 (put 'self-insert-iso 'delete-selection t)
 119
 120 (put 'yank 'delete-selection 'yank)
 121 (put 'clipboard-yank 'delete-selection 'yank)
 122 (put 'insert-register 'delete-selection t)
 123
 124 (put 'delete-backward-char 'delete-selection 'supersede)
 125 (put 'backward-delete-char-untabify 'delete-selection 'supersede)
 126 (put 'delete-char 'delete-selection 'supersede)
 127
 128 (put 'newline-and-indent 'delete-selection t)
 129 (put 'newline 'delete-selection t)
 130 (put 'open-line 'delete-selection 'kill)
 131
 132 ;; This is very useful for cancelling a selection in the minibuffer without
 133 ;; aborting the minibuffer.
 134 (defun minibuffer-keyboard-quit ()
 135   "Abort recursive edit.
 136 In Delete Selection mode, if the mark is active, just deactivate it;
 137 then it takes a second \\[keyboard-quit] to abort the minibuffer."
 138   (interactive)
 139   (if (and delete-selection-mode transient-mark-mode mark-active)
 140       (setq deactivate-mark t)
 141     (abort-recursive-edit)))
 142
 143 (define-key minibuffer-local-map "\C-g" 'minibuffer-keyboard-quit)
 144 (define-key minibuffer-local-ns-map "\C-g" 'minibuffer-keyboard-quit)
 145 (define-key minibuffer-local-completion-map "\C-g" 'minibuffer-keyboard-quit)
 146 (define-key minibuffer-local-must-match-map "\C-g" 'minibuffer-keyboard-quit)
 147 (define-key minibuffer-local-isearch-map "\C-g" 'minibuffer-keyboard-quit)
 148
 149 (defun delsel-unload-hook ()
 150   (define-key minibuffer-local-map "\C-g" 'abort-recursive-edit)
 151   (define-key minibuffer-local-ns-map "\C-g" 'abort-recursive-edit)
 152   (define-key minibuffer-local-completion-map "\C-g" 'abort-recursive-edit)
 153   (define-key minibuffer-local-must-match-map "\C-g" 'abort-recursive-edit)
 154   (define-key minibuffer-local-isearch-map "\C-g" 'abort-recursive-edit))
 155
 156 (add-hook 'delsel-unload-hook 'delsel-unload-hook)
 157
 158 (provide 'delsel)
 159
 160 ;;; arch-tag: 1e388890-1b50-4ed0-9347-763b1343b6ed
 161 ;;; delsel.el ends here