lisp/delsel.el

   1 ;;; delsel.el --- delete selection if you insert
   2
   3 ;; Copyright (C) 1992, 1997-1998, 2001-2013 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Author: Matthieu Devin <devin@lucid.com>
   7 ;; Maintainer: FSF
   8 ;; Created: 14 Jul 92
   9 ;; Keywords: convenience emulations
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This file makes the active region be pending delete, meaning that
  29 ;; text inserted while the region is active will replace the region contents.
  30 ;; This is a popular behavior of personal computers text editors.
  31
  32 ;; Interface:
  33
  34 ;; Commands which will delete the selection need a 'delete-selection
  35 ;; property on their symbols; commands which insert text but don't
  36 ;; have this property won't delete the selection.  It can be one of
  37 ;; the values:
  38 ;;  'yank
  39 ;;      For commands which do a yank; ensures the region about to be
  40 ;;      deleted isn't yanked.
  41 ;;  'supersede
  42 ;;      Delete the active region and ignore the current command,
  43 ;;      i.e. the command will just delete the region.
  44 ;;  'kill
  45 ;;      `kill-region' is used on the selection, rather than
  46 ;;      `delete-region'.  (Text selected with the mouse will typically
  47 ;;      be yankable anyhow.)
  48 ;;  t
  49 ;;      The normal case: delete the active region prior to executing
  50 ;;      the command which will insert replacement text.
  51 ;;  <function>
  52 ;;      For commands which need to dynamically determine this behaviour.
  53 ;;      The function should return one of the above values or nil.
  54
  55 ;;; Code:
  56
  57 ;;;###autoload
  58 (defalias 'pending-delete-mode 'delete-selection-mode)
  59
  60 ;;;###autoload
  61 (define-minor-mode delete-selection-mode
  62   "Toggle Delete Selection mode.
  63 With a prefix argument ARG, enable Delete Selection mode if ARG
  64 is positive, and disable it otherwise.  If called from Lisp,
  65 enable the mode if ARG is omitted or nil.
  66
  67 When Delete Selection mode is enabled, Transient Mark mode is also
  68 enabled and typed text replaces the selection if the selection is
  69 active.  Otherwise, typed text is just inserted at point regardless of
  70 any selection."
  71   :global t :group 'editing-basics
  72   (if (not delete-selection-mode)
  73       (remove-hook 'pre-command-hook 'delete-selection-pre-hook)
  74     (add-hook 'pre-command-hook 'delete-selection-pre-hook)
  75     (transient-mark-mode t)))
  76
  77 (defun delete-active-region (&optional killp)
  78   "Delete the active region.
  79 If KILLP in not-nil, the active region is killed instead of deleted."
  80   (if killp
  81       (kill-region (point) (mark))
  82     (delete-region (point) (mark)))
  83   t)
  84
  85 (defun delete-selection-helper (type)
  86   "Delete selection according to TYPE:
  87  `yank'
  88      For commands which do a yank; ensures the region about to be
  89      deleted isn't yanked.
  90  `supersede'
  91      Delete the active region and ignore the current command,
  92      i.e. the command will just delete the region.
  93  `kill'
  94      `kill-region' is used on the selection, rather than
  95      `delete-region'.  (Text selected with the mouse will typically
  96      be yankable anyhow.)
  97  t
  98      The normal case: delete the active region prior to executing
  99      the command which will insert replacement text.
 100  FUNCTION
 101      For commands which need to dynamically determine this behaviour.
 102      FUNCTION should take no argument and return one of the above values or nil."
 103   (condition-case data
 104       (cond ((eq type 'kill)
 105              (delete-active-region t))
 106             ((eq type 'yank)
 107              ;; Before a yank command, make sure we don't yank the
 108              ;; head of the kill-ring that really comes from the
 109              ;; currently active region we are going to delete.
 110              ;; That would make yank a no-op.
 111              (when (and (string= (buffer-substring-no-properties
 112                                   (point) (mark))
 113                                  (car kill-ring))
 114                         (fboundp 'mouse-region-match)
 115                         (mouse-region-match))
 116                (current-kill 1))
 117              (delete-active-region))
 118             ((eq type 'supersede)
 119              (let ((empty-region (= (point) (mark))))
 120                (delete-active-region)
 121                (unless empty-region
 122                  (setq this-command 'ignore))))
 123             ((functionp type) (delete-selection-helper (funcall type)))
 124             (type
 125              (delete-active-region)
 126              (if (and overwrite-mode
 127                       (eq this-command 'self-insert-command))
 128                  (let ((overwrite-mode nil))
 129                    (self-insert-command
 130                     (prefix-numeric-value current-prefix-arg))
 131                    (setq this-command 'ignore)))))
 132     ;; If ask-user-about-supersession-threat signals an error,
 133     ;; stop safe_run_hooks from clearing out pre-command-hook.
 134     (file-supersession (message "%s" (cadr data)) (ding))
 135     (text-read-only
 136      ;; This signal may come either from `delete-active-region' or
 137      ;; `self-insert-command' (when `overwrite-mode' is non-nil).
 138      ;; To avoid clearing out `pre-command-hook' we handle this case
 139      ;; by issuing a simple message.  Note, however, that we do not
 140      ;; handle all related problems: When read-only text ends before
 141      ;; the end of the region, the latter is not deleted but any
 142      ;; subsequent insertion will succeed.  We could avoid this case
 143      ;; by doing a (setq this-command 'ignore) here.  This would,
 144      ;; however, still not handle the case where read-only text ends
 145      ;; precisely where the region starts: In that case the deletion
 146      ;; would succeed but the subsequent insertion would fail with a
 147      ;; text-read-only error.  To handle that case we would have to
 148      ;; investigate text properties at both ends of the region and
 149      ;; skip the deletion when inserting text is forbidden there.
 150      (message "Text is read-only") (ding))))
 151
 152 (defun delete-selection-pre-hook ()
 153   "Function run before commands that delete selections are executed.
 154 Commands which will delete the selection need a `delete-selection'
 155 property on their symbol; commands which insert text but don't
 156 have this property won't delete the selection.
 157 See `delete-selection-helper'."
 158   (when (and delete-selection-mode (use-region-p)
 159              (not buffer-read-only))
 160     (delete-selection-helper (and (symbolp this-command)
 161                                   (get this-command 'delete-selection)))))
 162
 163 (put 'self-insert-command 'delete-selection
 164      (lambda ()
 165        (not (run-hook-with-args-until-success
 166              'self-insert-uses-region-functions))))
 167
 168 (put 'yank 'delete-selection 'yank)
 169 (put 'clipboard-yank 'delete-selection 'yank)
 170 (put 'insert-register 'delete-selection t)
 171
 172 (put 'newline-and-indent 'delete-selection t)
 173 (put 'newline 'delete-selection t)
 174 (put 'open-line 'delete-selection 'kill)
 175
 176 ;; This is very useful for canceling a selection in the minibuffer without
 177 ;; aborting the minibuffer.
 178 (defun minibuffer-keyboard-quit ()
 179   "Abort recursive edit.
 180 In Delete Selection mode, if the mark is active, just deactivate it;
 181 then it takes a second \\[keyboard-quit] to abort the minibuffer."
 182   (interactive)
 183   (if (and delete-selection-mode transient-mark-mode mark-active)
 184       (setq deactivate-mark t)
 185     (abort-recursive-edit)))
 186
 187 (define-key minibuffer-local-map "\C-g" 'minibuffer-keyboard-quit)
 188 (define-key minibuffer-local-ns-map "\C-g" 'minibuffer-keyboard-quit)
 189 (define-key minibuffer-local-completion-map "\C-g" 'minibuffer-keyboard-quit)
 190 (define-key minibuffer-local-must-match-map "\C-g" 'minibuffer-keyboard-quit)
 191 (define-key minibuffer-local-isearch-map "\C-g" 'minibuffer-keyboard-quit)
 192
 193 (defun delsel-unload-function ()
 194   "Unload the Delete Selection library."
 195   (define-key minibuffer-local-map "\C-g" 'abort-recursive-edit)
 196   (define-key minibuffer-local-ns-map "\C-g" 'abort-recursive-edit)
 197   (define-key minibuffer-local-completion-map "\C-g" 'abort-recursive-edit)
 198   (define-key minibuffer-local-must-match-map "\C-g" 'abort-recursive-edit)
 199   (define-key minibuffer-local-isearch-map "\C-g" 'abort-recursive-edit)
 200   (dolist (sym '(self-insert-command self-insert-iso yank clipboard-yank
 201                  insert-register delete-backward-char backward-delete-char-untabify
 202                  delete-char newline-and-indent newline open-line))
 203     (put sym 'delete-selection nil))
 204   ;; continue standard unloading
 205   nil)
 206
 207 (provide 'delsel)
 208
 209 ;;; delsel.el ends here