lisp/version.el

   1 ;;; version.el --- record version number of Emacs
   2
   3 ;; Copyright (C) 1985, 1992, 1994-1995, 1999-2015 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (defconst emacs-major-version
  30   (progn (string-match "^[0-9]+" emacs-version)
  31          (string-to-number (match-string 0 emacs-version)))
  32   "Major version number of this version of Emacs.
  33 This variable first existed in version 19.23.")
  34
  35 (defconst emacs-minor-version
  36   (progn (string-match "^[0-9]+\\.\\([0-9]+\\)" emacs-version)
  37          (string-to-number (match-string 1 emacs-version)))
  38   "Minor version number of this version of Emacs.
  39 This variable first existed in version 19.23.")
  40
  41 (defconst emacs-build-time (current-time)
  42   "Time at which Emacs was dumped out.")
  43
  44 (defconst emacs-build-system (system-name)
  45   "Name of the system on which Emacs was built.")
  46
  47 (defvar motif-version-string)
  48 (defvar gtk-version-string)
  49 (defvar ns-version-string)
  50
  51 (defun emacs-version (&optional here)
  52   "Return string describing the version of Emacs that is running.
  53 If optional argument HERE is non-nil, insert string at point.
  54 Don't use this function in programs to choose actions according
  55 to the system configuration; look at `system-configuration' instead."
  56   (interactive "P")
  57   (let ((version-string
  58          (format (if (not (called-interactively-p 'interactive))
  59                      "GNU Emacs %s (%s%s%s%s)\n of %s on %s"
  60                    "GNU Emacs %s (%s%s%s%s) of %s on %s")
  61                  emacs-version
  62                  system-configuration
  63                  (cond ((featurep 'motif)
  64                         (concat ", " (substring motif-version-string 4)))
  65                        ((featurep 'gtk)
  66                         (concat ", GTK+ Version " gtk-version-string))
  67                        ((featurep 'x-toolkit) ", X toolkit")
  68                        ((featurep 'ns)
  69                         (format ", NS %s" ns-version-string))
  70                        (t ""))
  71                  (if (featurep 'cairo)
  72                      (format ", cairo version %s" cairo-version-string)
  73                    "")
  74                  (if (and (boundp 'x-toolkit-scroll-bars)
  75                           (memq x-toolkit-scroll-bars '(xaw xaw3d)))
  76                      (format ", %s scroll bars"
  77                              (capitalize (symbol-name x-toolkit-scroll-bars)))
  78                    "")
  79                  (format-time-string "%Y-%m-%d" emacs-build-time)
  80                  emacs-build-system)))
  81     (if here
  82         (insert version-string)
  83       (if (called-interactively-p 'interactive)
  84           (message "%s" version-string)
  85         version-string))))
  86
  87 ;; We hope that this alias is easier for people to find.
  88 (defalias 'version 'emacs-version)
  89
  90 ;; Set during dumping, this is a defvar so that it can be setq'd.
  91 (defvar emacs-repository-version nil
  92   "String giving the repository revision from which this Emacs was built.
  93 Value is nil if Emacs was not built from a repository checkout,
  94 or if we could not determine the revision.")
  95
  96 (define-obsolete-variable-alias 'emacs-bzr-version
  97                                 'emacs-repository-version "24.4")
  98
  99 (define-obsolete-function-alias 'emacs-bzr-get-version
 100                                 'emacs-repository-get-version "24.4")
 101
 102 (defun emacs-repository-get-version (&optional dir external)
 103   "Try to return as a string the repository revision of the Emacs sources.
 104 The format of the returned string is dependent on the VCS in use.
 105 Value is nil if the sources do not seem to be under version
 106 control, or if we could not determine the revision.  Note that
 107 this reports on the current state of the sources, which may not
 108 correspond to the running Emacs.
 109
 110 Optional argument DIR is a directory to use instead of
 111 `source-directory'.  Optional argument EXTERNAL is ignored and is
 112 retained for compatibility."
 113   (or dir (setq dir source-directory))
 114   (cond ((file-directory-p (expand-file-name ".git" dir))
 115          (message "Waiting for git...")
 116          (with-temp-buffer
 117            (let ((default-directory (file-name-as-directory dir)))
 118              (and (eq 0
 119                       (condition-case nil
 120                           (call-process "git" nil '(t nil) nil "rev-parse"
 121                                         "HEAD")
 122                         (error nil)))
 123                   (not (zerop (buffer-size)))
 124                   (replace-regexp-in-string "\n" "" (buffer-string))))))))
 125
 126 ;; We put version info into the executable in the form that `ident' uses.
 127 (purecopy (concat "\n$Id: " (subst-char-in-string ?\n ?\s (emacs-version))
 128                   " $\n"))
 129
 130 ;;; version.el ends here