lisp/gnus/yenc.el

   1 ;;; yenc.el --- elisp native yenc decoder
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Jesper Harder <harder@ifa.au.dk>
   6 ;; Keywords: yenc news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Functions for decoding yenc encoded messages.
  28 ;;
  29 ;; Limitations:
  30 ;;
  31 ;; * Does not handle multipart messages.
  32 ;; * No support for external decoders.
  33 ;; * Doesn't check the crc32 checksum (if present).
  34
  35 ;;; Code:
  36
  37 (eval-when-compile (require 'cl))
  38
  39 (defconst yenc-begin-line
  40   "^=ybegin.*$")
  41
  42 (defconst yenc-decoding-vector
  43   [214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230
  44        231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247
  45        248 249 250 251 252 253 254 255 0 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15
  46        16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38
  47        39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61
  48        62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84
  49        85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105
  50        106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122
  51        123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139
  52        140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156
  53        157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173
  54        174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190
  55        191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207
  56        208 209 210 211 212 213])
  57
  58 (defun yenc-first-part-p ()
  59   "Say whether the buffer contains the first part of a yEnc file."
  60   (save-excursion
  61     (goto-char (point-min))
  62     (re-search-forward "^=ybegin part=1 " nil t)))
  63
  64 (defun yenc-last-part-p ()
  65   "Say whether the buffer contains the last part of a yEnc file."
  66   (save-excursion
  67     (goto-char (point-min))
  68     (let (total-size end-size)
  69       (when (re-search-forward "^=ybegin.*size=\\([0-9]+\\)" nil t)
  70         (setq total-size (match-string 1)))
  71       (when (re-search-forward "^=ypart.*end=\\([0-9]+\\)" nil t)
  72         (setq end-size (match-string 1)))
  73       (and total-size
  74            end-size
  75            (string= total-size end-size)))))
  76
  77 ;;;###autoload
  78 (defun yenc-decode-region (start end)
  79   "Yenc decode region between START and END using an internal decoder."
  80   (interactive "r")
  81   (let (work-buffer)
  82     (unwind-protect
  83         (save-excursion
  84           (goto-char start)
  85           (when (re-search-forward yenc-begin-line end t)
  86             (let ((first (match-end 0))
  87                   (header-alist (yenc-parse-line (match-string 0)))
  88                   bytes last footer-alist char)
  89               (when (re-search-forward "^=ypart.*$" end t)
  90                 (setq first (match-end 0)))
  91               (when (re-search-forward "^=yend.*$" end t)
  92                 (setq last (match-beginning 0))
  93                 (setq footer-alist (yenc-parse-line (match-string 0)))
  94                 (let (default-enable-multibyte-characters)
  95                   (setq work-buffer (generate-new-buffer " *yenc-work*")))
  96                 (while (< first last)
  97                   (setq char (char-after first))
  98                   (cond ((or (eq char ?\r)
  99                              (eq char ?\n)))
 100                         ((eq char ?=)
 101                          (setq char (char-after (incf first)))
 102                          (with-current-buffer work-buffer
 103                            (insert-char (mod (- char 106) 256) 1)))
 104                         (t
 105                          (with-current-buffer work-buffer
 106                            ;;(insert-char (mod (- char 42) 256) 1)
 107                            (insert-char (aref yenc-decoding-vector char) 1))))
 108                   (incf first))
 109                 (setq bytes (buffer-size work-buffer))
 110                 (unless (and (= (cdr (assq 'size header-alist)) bytes)
 111                              (= (cdr (assq 'size footer-alist)) bytes))
 112                   (message "Warning: Size mismatch while decoding."))
 113                 (goto-char start)
 114                 (delete-region start end)
 115                 (insert-buffer-substring work-buffer))))
 116           (and work-buffer (kill-buffer work-buffer))))))
 117
 118 ;;;###autoload
 119 (defun yenc-extract-filename ()
 120   "Extract file name from an yenc header."
 121   (save-excursion
 122     (when (re-search-forward yenc-begin-line nil t)
 123       (cdr (assoc 'name (yenc-parse-line (match-string 0)))))))
 124
 125 (defun yenc-parse-line (str)
 126   "Extract file name and size from STR."
 127   (let (result name)
 128     (when (string-match "^=y.*size=\\([0-9]+\\)" str)
 129       (push (cons 'size (string-to-number (match-string 1 str))) result))
 130     (when (string-match "^=y.*name=\\(.*\\)$" str)
 131       (setq name (match-string 1 str))
 132       ;; Remove trailing white space
 133       (when (string-match " +$" name)
 134         (setq name (substring name 0 (match-beginning 0))))
 135       (push (cons 'name name) result))
 136     result))
 137
 138 (provide 'yenc)
 139
 140 ;; arch-tag: 74df17e8-6fa8-4071-9f7d-54d548d79d9a
 141 ;;; yenc.el ends here