lisp/gnus/gnus-util.el

   1 ;;; gnus-util.el --- utility functions for Gnus
   2 ;; Copyright (C) 1996, 1997, 1998, 1999, 2000
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Nothing in this file depends on any other parts of Gnus -- all
  28 ;; functions and macros in this file are utility functions that are
  29 ;; used by Gnus and may be used by any other package without loading
  30 ;; Gnus first.
  31
  32 ;;; Code:
  33
  34 (require 'custom)
  35 (eval-when-compile
  36   (require 'cl)
  37   ;; Fixme: this should be a gnus variable, not nnmail-.
  38   (defvar nnmail-pathname-coding-system))
  39 (require 'nnheader)
  40 (require 'time-date)
  41
  42 (eval-and-compile
  43   (autoload 'message-fetch-field "message")
  44   (autoload 'rmail-insert-rmail-file-header "rmail")
  45   (autoload 'rmail-count-new-messages "rmail")
  46   (autoload 'rmail-show-message "rmail"))
  47
  48 (defun gnus-boundp (variable)
  49   "Return non-nil if VARIABLE is bound and non-nil."
  50   (and (boundp variable)
  51        (symbol-value variable)))
  52
  53 (defmacro gnus-eval-in-buffer-window (buffer &rest forms)
  54   "Pop to BUFFER, evaluate FORMS, and then return to the original window."
  55   (let ((tempvar (make-symbol "GnusStartBufferWindow"))
  56         (w (make-symbol "w"))
  57         (buf (make-symbol "buf")))
  58     `(let* ((,tempvar (selected-window))
  59             (,buf ,buffer)
  60             (,w (get-buffer-window ,buf 'visible)))
  61        (unwind-protect
  62            (progn
  63              (if ,w
  64                  (progn
  65                    (select-window ,w)
  66                    (set-buffer (window-buffer ,w)))
  67                (pop-to-buffer ,buf))
  68              ,@forms)
  69          (select-window ,tempvar)))))
  70
  71 (put 'gnus-eval-in-buffer-window 'lisp-indent-function 1)
  72 (put 'gnus-eval-in-buffer-window 'edebug-form-spec '(form body))
  73
  74 (defmacro gnus-intern-safe (string hashtable)
  75   "Set hash value.  Arguments are STRING, VALUE, and HASHTABLE."
  76   `(let ((symbol (intern ,string ,hashtable)))
  77      (or (boundp symbol)
  78          (set symbol nil))
  79      symbol))
  80
  81 ;; Added by Geoffrey T. Dairiki <dairiki@u.washington.edu>.  A safe way
  82 ;; to limit the length of a string.  This function is necessary since
  83 ;; `(substr "abc" 0 30)' pukes with "Args out of range".
  84 (defsubst gnus-limit-string (str width)
  85   (if (> (length str) width)
  86       (substring str 0 width)
  87     str))
  88
  89 (defsubst gnus-functionp (form)
  90   "Return non-nil if FORM is funcallable."
  91   (or (and (symbolp form) (fboundp form))
  92       (and (listp form) (eq (car form) 'lambda))
  93       (byte-code-function-p form)))
  94
  95 (defsubst gnus-goto-char (point)
  96   (and point (goto-char point)))
  97
  98 (defmacro gnus-buffer-exists-p (buffer)
  99   `(let ((buffer ,buffer))
 100      (when buffer
 101        (funcall (if (stringp buffer) 'get-buffer 'buffer-name)
 102                 buffer))))
 103
 104 (defmacro gnus-kill-buffer (buffer)
 105   `(let ((buf ,buffer))
 106      (when (gnus-buffer-exists-p buf)
 107        (kill-buffer buf))))
 108
 109 (defalias 'gnus-point-at-bol
 110   (if (fboundp 'point-at-bol)
 111       'point-at-bol
 112     'line-beginning-position))
 113
 114 (defalias 'gnus-point-at-eol
 115   (if (fboundp 'point-at-eol)
 116       'point-at-eol
 117     'line-end-position))
 118
 119 (defun gnus-delete-first (elt list)
 120   "Delete by side effect the first occurrence of ELT as a member of LIST."
 121   (if (equal (car list) elt)
 122       (cdr list)
 123     (let ((total list))
 124       (while (and (cdr list)
 125                   (not (equal (cadr list) elt)))
 126         (setq list (cdr list)))
 127       (when (cdr list)
 128         (setcdr list (cddr list)))
 129       total)))
 130
 131 ;; Delete the current line (and the next N lines).
 132 (defmacro gnus-delete-line (&optional n)
 133   `(delete-region (progn (beginning-of-line) (point))
 134                   (progn (forward-line ,(or n 1)) (point))))
 135
 136 (defun gnus-byte-code (func)
 137   "Return a form that can be `eval'ed based on FUNC."
 138   (let ((fval (indirect-function func)))
 139     (if (byte-code-function-p fval)
 140         (let ((flist (append fval nil)))
 141           (setcar flist 'byte-code)
 142           flist)
 143       (cons 'progn (cddr fval)))))
 144
 145 (defun gnus-extract-address-components (from)
 146   (let (name address)
 147     ;; First find the address - the thing with the @ in it.  This may
 148     ;; not be accurate in mail addresses, but does the trick most of
 149     ;; the time in news messages.
 150     (when (string-match "\\b[^@ \t<>]+[!@][^@ \t<>]+\\b" from)
 151       (setq address (substring from (match-beginning 0) (match-end 0))))
 152     ;; Then we check whether the "name <address>" format is used.
 153     (and address
 154          ;; Linear white space is not required.
 155          (string-match (concat "[ \t]*<" (regexp-quote address) ">") from)
 156          (and (setq name (substring from 0 (match-beginning 0)))
 157               ;; Strip any quotes from the name.
 158               (string-match "\".*\"" name)
 159               (setq name (substring name 1 (1- (match-end 0))))))
 160     ;; If not, then "address (name)" is used.
 161     (or name
 162         (and (string-match "(.+)" from)
 163              (setq name (substring from (1+ (match-beginning 0))
 164                                    (1- (match-end 0)))))
 165         (and (string-match "()" from)
 166              (setq name address))
 167         ;; XOVER might not support folded From headers.
 168         (and (string-match "(.*" from)
 169              (setq name (substring from (1+ (match-beginning 0))
 170                                    (match-end 0)))))
 171     (list (if (string= name "") nil name) (or address from))))
 172
 173
 174 (defun gnus-fetch-field (field)
 175   "Return the value of the header FIELD of current article."
 176   (save-excursion
 177     (save-restriction
 178       (let ((case-fold-search t)
 179             (inhibit-point-motion-hooks t))
 180         (nnheader-narrow-to-headers)
 181         (message-fetch-field field)))))
 182
 183 (defun gnus-goto-colon ()
 184   (beginning-of-line)
 185   (search-forward ":" (gnus-point-at-eol) t))
 186
 187 (defun gnus-remove-text-with-property (prop)
 188   "Delete all text in the current buffer with text property PROP."
 189   (save-excursion
 190     (goto-char (point-min))
 191     (while (not (eobp))
 192       (while (get-text-property (point) prop)
 193         (delete-char 1))
 194       (goto-char (next-single-property-change (point) prop nil (point-max))))))
 195
 196 (defun gnus-newsgroup-directory-form (newsgroup)
 197   "Make hierarchical directory name from NEWSGROUP name."
 198   (let ((newsgroup (gnus-newsgroup-savable-name newsgroup))
 199         (len (length newsgroup))
 200         idx)
 201     ;; If this is a foreign group, we don't want to translate the
 202     ;; entire name.
 203     (if (setq idx (string-match ":" newsgroup))
 204         (aset newsgroup idx ?/)
 205       (setq idx 0))
 206     ;; Replace all occurrences of `.' with `/'.
 207     (while (< idx len)
 208       (when (= (aref newsgroup idx) ?.)
 209         (aset newsgroup idx ?/))
 210       (setq idx (1+ idx)))
 211     newsgroup))
 212
 213 (defun gnus-newsgroup-savable-name (group)
 214   ;; Replace any slashes in a group name (eg. an ange-ftp nndoc group)
 215   ;; with dots.
 216   (nnheader-replace-chars-in-string group ?/ ?.))
 217
 218 (defun gnus-string> (s1 s2)
 219   (not (or (string< s1 s2)
 220            (string= s1 s2))))
 221
 222 ;;; Time functions.
 223
 224 (defun gnus-file-newer-than (file date)
 225   (let ((fdate (nth 5 (file-attributes file))))
 226     (or (> (car fdate) (car date))
 227         (and (= (car fdate) (car date))
 228              (> (nth 1 fdate) (nth 1 date))))))
 229
 230 ;;; Keymap macros.
 231
 232 (defmacro gnus-local-set-keys (&rest plist)
 233   "Set the keys in PLIST in the current keymap."
 234   `(gnus-define-keys-1 (current-local-map) ',plist))
 235
 236 (defmacro gnus-define-keys (keymap &rest plist)
 237   "Define all keys in PLIST in KEYMAP."
 238   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist)))
 239
 240 (defmacro gnus-define-keys-safe (keymap &rest plist)
 241   "Define all keys in PLIST in KEYMAP without overwriting previous definitions."
 242   `(gnus-define-keys-1 (quote ,keymap) (quote ,plist) t))
 243
 244 (put 'gnus-define-keys 'lisp-indent-function 1)
 245 (put 'gnus-define-keys-safe 'lisp-indent-function 1)
 246 (put 'gnus-local-set-keys 'lisp-indent-function 1)
 247
 248 (defmacro gnus-define-keymap (keymap &rest plist)
 249   "Define all keys in PLIST in KEYMAP."
 250   `(gnus-define-keys-1 ,keymap (quote ,plist)))
 251
 252 (put 'gnus-define-keymap 'lisp-indent-function 1)
 253
 254 (defun gnus-define-keys-1 (keymap plist &optional safe)
 255   (when (null keymap)
 256     (error "Can't set keys in a null keymap"))
 257   (cond ((symbolp keymap)
 258          (setq keymap (symbol-value keymap)))
 259         ((keymapp keymap))
 260         ((listp keymap)
 261          (set (car keymap) nil)
 262          (define-prefix-command (car keymap))
 263          (define-key (symbol-value (caddr keymap)) (cadr keymap) (car keymap))
 264          (setq keymap (symbol-value (car keymap)))))
 265   (let (key)
 266     (while plist
 267       (when (symbolp (setq key (pop plist)))
 268         (setq key (symbol-value key)))
 269       (if (or (not safe)
 270               (eq (lookup-key keymap key) 'undefined))
 271           (define-key keymap key (pop plist))
 272         (pop plist)))))
 273
 274 (defun gnus-completing-read (default prompt &rest args)
 275   ;; Like `completing-read', except that DEFAULT is the default argument.
 276   (let* ((prompt (if default
 277                      (concat prompt " (default " default ") ")
 278                    (concat prompt " ")))
 279          (answer (apply 'completing-read prompt args)))
 280     (if (or (null answer) (zerop (length answer)))
 281         default
 282       answer)))
 283
 284 ;; Two silly functions to ensure that all `y-or-n-p' questions clear
 285 ;; the echo area.
 286 (defun gnus-y-or-n-p (prompt)
 287   (prog1
 288       (y-or-n-p prompt)
 289     (message "")))
 290
 291 (defun gnus-yes-or-no-p (prompt)
 292   (prog1
 293       (yes-or-no-p prompt)
 294     (message "")))
 295
 296 (defun gnus-dd-mmm (messy-date)
 297   "Return a string like DD-MMM from a big messy string."
 298   (condition-case ()
 299       (format-time-string "%d-%b" (safe-date-to-time messy-date))
 300     (error "  -   ")))
 301
 302 (defmacro gnus-date-get-time (date)
 303   "Convert DATE string to Emacs time.
 304 Cache the result as a text property stored in DATE."
 305   ;; Either return the cached value...
 306   `(let ((d ,date))
 307      (if (equal "" d)
 308          '(0 0)
 309        (or (get-text-property 0 'gnus-time d)
 310            ;; or compute the value...
 311            (let ((time (safe-date-to-time d)))
 312              ;; and store it back in the string.
 313              (put-text-property 0 1 'gnus-time time d)
 314              time)))))
 315
 316 (defsubst gnus-time-iso8601 (time)
 317   "Return a string of TIME in YYYYMMDDTHHMMSS format."
 318   (format-time-string "%Y%m%dT%H%M%S" time))
 319
 320 (defun gnus-date-iso8601 (date)
 321   "Convert the DATE to YYYYMMDDTHHMMSS."
 322   (condition-case ()
 323       (gnus-time-iso8601 (gnus-date-get-time date))
 324     (error "")))
 325
 326 (defun gnus-mode-string-quote (string)
 327   "Quote all \"%\"'s in STRING."
 328   (save-excursion
 329     (gnus-set-work-buffer)
 330     (insert string)
 331     (goto-char (point-min))
 332     (while (search-forward "%" nil t)
 333       (insert "%"))
 334     (buffer-string)))
 335
 336 ;; Make a hash table (default and minimum size is 256).
 337 ;; Optional argument HASHSIZE specifies the table size.
 338 (defun gnus-make-hashtable (&optional hashsize)
 339   (make-vector (if hashsize (max (gnus-create-hash-size hashsize) 256) 256) 0))
 340
 341 ;; Make a number that is suitable for hashing; bigger than MIN and
 342 ;; equal to some 2^x.  Many machines (such as sparcs) do not have a
 343 ;; hardware modulo operation, so they implement it in software.  On
 344 ;; many sparcs over 50% of the time to intern is spent in the modulo.
 345 ;; Yes, it's slower than actually computing the hash from the string!
 346 ;; So we use powers of 2 so people can optimize the modulo to a mask.
 347 (defun gnus-create-hash-size (min)
 348   (let ((i 1))
 349     (while (< i min)
 350       (setq i (* 2 i)))
 351     i))
 352
 353 (defcustom gnus-verbose 7
 354   "*Integer that says how verbose Gnus should be.
 355 The higher the number, the more messages Gnus will flash to say what
 356 it's doing.  At zero, Gnus will be totally mute; at five, Gnus will
 357 display most important messages; and at ten, Gnus will keep on
 358 jabbering all the time."
 359   :group 'gnus-start
 360   :type 'integer)
 361
 362 ;; Show message if message has a lower level than `gnus-verbose'.
 363 ;; Guideline for numbers:
 364 ;; 1 - error messages, 3 - non-serious error messages, 5 - messages
 365 ;; for things that take a long time, 7 - not very important messages
 366 ;; on stuff, 9 - messages inside loops.
 367 (defun gnus-message (level &rest args)
 368   (if (<= level gnus-verbose)
 369       (apply 'message args)
 370     ;; We have to do this format thingy here even if the result isn't
 371     ;; shown - the return value has to be the same as the return value
 372     ;; from `message'.
 373     (apply 'format args)))
 374
 375 (defun gnus-error (level &rest args)
 376   "Beep an error if LEVEL is equal to or less than `gnus-verbose'."
 377   (when (<= (floor level) gnus-verbose)
 378     (apply 'message args)
 379     (ding)
 380     (let (duration)
 381       (when (and (floatp level)
 382                  (not (zerop (setq duration (* 10 (- level (floor level)))))))
 383         (sit-for duration))))
 384   nil)
 385
 386 (defun gnus-split-references (references)
 387   "Return a list of Message-IDs in REFERENCES."
 388   (let ((beg 0)
 389         ids)
 390     (while (string-match "<[^>]+>" references beg)
 391       (push (substring references (match-beginning 0) (setq beg (match-end 0)))
 392             ids))
 393     (nreverse ids)))
 394
 395 (defsubst gnus-parent-id (references &optional n)
 396   "Return the last Message-ID in REFERENCES.
 397 If N, return the Nth ancestor instead."
 398   (when references
 399     (let ((ids (inline (gnus-split-references references))))
 400       (while (nthcdr (or n 1) ids)
 401         (setq ids (cdr ids)))
 402       (car ids))))
 403
 404 (defsubst gnus-buffer-live-p (buffer)
 405   "Say whether BUFFER is alive or not."
 406   (and buffer
 407        (get-buffer buffer)
 408        (buffer-name (get-buffer buffer))))
 409
 410 (defun gnus-horizontal-recenter ()
 411   "Recenter the current buffer horizontally."
 412   (if (< (current-column) (/ (window-width) 2))
 413       (set-window-hscroll (get-buffer-window (current-buffer) t) 0)
 414     (let* ((orig (point))
 415            (end (window-end (get-buffer-window (current-buffer) t)))
 416            (max 0))
 417       (when end
 418         ;; Find the longest line currently displayed in the window.
 419         (goto-char (window-start))
 420         (while (and (not (eobp))
 421                     (< (point) end))
 422           (end-of-line)
 423           (setq max (max max (current-column)))
 424           (forward-line 1))
 425         (goto-char orig)
 426         ;; Scroll horizontally to center (sort of) the point.
 427         (if (> max (window-width))
 428             (set-window-hscroll
 429              (get-buffer-window (current-buffer) t)
 430              (min (- (current-column) (/ (window-width) 3))
 431                   (+ 2 (- max (window-width)))))
 432           (set-window-hscroll (get-buffer-window (current-buffer) t) 0))
 433         max))))
 434
 435 (defun gnus-read-event-char ()
 436   "Get the next event."
 437   (let ((event (read-event)))
 438     ;; should be gnus-characterp, but this can't be called in XEmacs anyway
 439     (cons (and (numberp event) event) event)))
 440
 441 (defun gnus-sortable-date (date)
 442   "Make string suitable for sorting from DATE."
 443   (gnus-time-iso8601 (date-to-time date)))
 444
 445 (defun gnus-copy-file (file &optional to)
 446   "Copy FILE to TO."
 447   (interactive
 448    (list (read-file-name "Copy file: " default-directory)
 449          (read-file-name "Copy file to: " default-directory)))
 450   (unless to
 451     (setq to (read-file-name "Copy file to: " default-directory)))
 452   (when (file-directory-p to)
 453     (setq to (concat (file-name-as-directory to)
 454                      (file-name-nondirectory file))))
 455   (copy-file file to))
 456
 457 (defvar gnus-work-buffer " *gnus work*")
 458
 459 (defun gnus-set-work-buffer ()
 460   "Put point in the empty Gnus work buffer."
 461   (if (get-buffer gnus-work-buffer)
 462       (progn
 463         (set-buffer gnus-work-buffer)
 464         (erase-buffer))
 465     (set-buffer (gnus-get-buffer-create gnus-work-buffer))
 466     (kill-all-local-variables)
 467     (mm-enable-multibyte)))
 468
 469 (defmacro gnus-group-real-name (group)
 470   "Find the real name of a foreign newsgroup."
 471   `(let ((gname ,group))
 472      (if (string-match "^[^:]+:" gname)
 473          (substring gname (match-end 0))
 474        gname)))
 475
 476 (defun gnus-make-sort-function (funs)
 477   "Return a composite sort condition based on the functions in FUNC."
 478   (cond
 479    ;; Just a simple function.
 480    ((gnus-functionp funs) funs)
 481    ;; No functions at all.
 482    ((null funs) funs)
 483    ;; A list of functions.
 484    ((or (cdr funs)
 485         (listp (car funs)))
 486     `(lambda (t1 t2)
 487        ,(gnus-make-sort-function-1 (reverse funs))))
 488    ;; A list containing just one function.
 489    (t
 490     (car funs))))
 491
 492 (defun gnus-make-sort-function-1 (funs)
 493   "Return a composite sort condition based on the functions in FUNC."
 494   (let ((function (car funs))
 495         (first 't1)
 496         (last 't2))
 497     (when (consp function)
 498       (cond
 499        ;; Reversed spec.
 500        ((eq (car function) 'not)
 501         (setq function (cadr function)
 502               first 't2
 503               last 't1))
 504        ((gnus-functionp function)
 505         ;; Do nothing.
 506         )
 507        (t
 508         (error "Invalid sort spec: %s" function))))
 509     (if (cdr funs)
 510         `(or (,function ,first ,last)
 511              (and (not (,function ,last ,first))
 512                   ,(gnus-make-sort-function-1 (cdr funs))))
 513       `(,function ,first ,last))))
 514
 515 (defun gnus-turn-off-edit-menu (type)
 516   "Turn off edit menu in `gnus-TYPE-mode-map'."
 517   (define-key (symbol-value (intern (format "gnus-%s-mode-map" type)))
 518     [menu-bar edit] 'undefined))
 519
 520 (defun gnus-prin1 (form)
 521   "Use `prin1' on FORM in the current buffer.
 522 Bind `print-quoted' and `print-readably' to t while printing."
 523   (let ((print-quoted t)
 524         (print-readably t)
 525         (print-escape-multibyte nil)
 526         print-level print-length)
 527     (prin1 form (current-buffer))))
 528
 529 (defun gnus-prin1-to-string (form)
 530   "The same as `prin1', but bind `print-quoted' and `print-readably' to t."
 531   (let ((print-quoted t)
 532         (print-readably t))
 533     (prin1-to-string form)))
 534
 535 (defun gnus-make-directory (directory)
 536   "Make DIRECTORY (and all its parents) if it doesn't exist."
 537   (require 'nnmail)
 538   (let ((file-name-coding-system nnmail-pathname-coding-system))
 539     (when (and directory
 540                (not (file-exists-p directory)))
 541       (make-directory directory t)))
 542   t)
 543
 544 (defun gnus-write-buffer (file)
 545   "Write the current buffer's contents to FILE."
 546   ;; Make sure the directory exists.
 547   (gnus-make-directory (file-name-directory file))
 548   (let ((file-name-coding-system nnmail-pathname-coding-system))
 549     ;; Write the buffer.
 550     (write-region (point-min) (point-max) file nil 'quietly)))
 551
 552 (defun gnus-delete-file (file)
 553   "Delete FILE if it exists."
 554   (when (file-exists-p file)
 555     (delete-file file)))
 556
 557 (defun gnus-strip-whitespace (string)
 558   "Return STRING stripped of all whitespace."
 559   (while (string-match "[\r\n\t ]+" string)
 560     (setq string (replace-match "" t t string)))
 561   string)
 562
 563 (defsubst gnus-put-text-property-excluding-newlines (beg end prop val)
 564   "The same as `put-text-property', but don't put this prop on any newlines in the region."
 565   (save-match-data
 566     (save-excursion
 567       (save-restriction
 568         (goto-char beg)
 569         (while (re-search-forward gnus-emphasize-whitespace-regexp end 'move)
 570           (gnus-put-text-property beg (match-beginning 0) prop val)
 571           (setq beg (point)))
 572         (gnus-put-text-property beg (point) prop val)))))
 573
 574 (defun gnus-put-text-property-excluding-characters-with-faces (beg end
 575                                                                    prop val)
 576   "The same as `put-text-property', but don't put props on characters with the `gnus-face' property."
 577   (let ((b beg))
 578     (while (/= b end)
 579       (when (get-text-property b 'gnus-face)
 580         (setq b (next-single-property-change b 'gnus-face nil end)))
 581       (when (/= b end)
 582         (gnus-put-text-property
 583          b (setq b (next-single-property-change b 'gnus-face nil end))
 584          prop val)))))
 585
 586 ;;; Protected and atomic operations.  dmoore@ucsd.edu 21.11.1996
 587 ;;; The primary idea here is to try to protect internal datastructures
 588 ;;; from becoming corrupted when the user hits C-g, or if a hook or
 589 ;;; similar blows up.  Often in Gnus multiple tables/lists need to be
 590 ;;; updated at the same time, or information can be lost.
 591
 592 (defvar gnus-atomic-be-safe t
 593   "If t, certain operations will be protected from interruption by C-g.")
 594
 595 (defmacro gnus-atomic-progn (&rest forms)
 596   "Evaluate FORMS atomically, which means to protect the evaluation
 597 from being interrupted by the user.  An error from the forms themselves
 598 will return without finishing the operation.  Since interrupts from
 599 the user are disabled, it is recommended that only the most minimal
 600 operations are performed by FORMS.  If you wish to assign many
 601 complicated values atomically, compute the results into temporary
 602 variables and then do only the assignment atomically."
 603   `(let ((inhibit-quit gnus-atomic-be-safe))
 604      ,@forms))
 605
 606 (put 'gnus-atomic-progn 'lisp-indent-function 0)
 607
 608 (defmacro gnus-atomic-progn-assign (protect &rest forms)
 609   "Evaluate FORMS, but insure that the variables listed in PROTECT
 610 are not changed if anything in FORMS signals an error or otherwise
 611 non-locally exits.  The variables listed in PROTECT are updated atomically.
 612 It is safe to use gnus-atomic-progn-assign with long computations.
 613
 614 Note that if any of the symbols in PROTECT were unbound, they will be
 615 set to nil on a sucessful assignment.  In case of an error or other
 616 non-local exit, it will still be unbound."
 617   (let* ((temp-sym-map (mapcar (lambda (x) (list (make-symbol
 618                                                   (concat (symbol-name x)
 619                                                           "-tmp"))
 620                                                  x))
 621                                protect))
 622          (sym-temp-map (mapcar (lambda (x) (list (cadr x) (car x)))
 623                                temp-sym-map))
 624          (temp-sym-let (mapcar (lambda (x) (list (car x)
 625                                                  `(and (boundp ',(cadr x))
 626                                                        ,(cadr x))))
 627                                temp-sym-map))
 628          (sym-temp-let sym-temp-map)
 629          (temp-sym-assign (apply 'append temp-sym-map))
 630          (sym-temp-assign (apply 'append sym-temp-map))
 631          (result (make-symbol "result-tmp")))
 632     `(let (,@temp-sym-let
 633            ,result)
 634        (let ,sym-temp-let
 635          (setq ,result (progn ,@forms))
 636          (setq ,@temp-sym-assign))
 637        (let ((inhibit-quit gnus-atomic-be-safe))
 638          (setq ,@sym-temp-assign))
 639        ,result)))
 640
 641 (put 'gnus-atomic-progn-assign 'lisp-indent-function 1)
 642 ;(put 'gnus-atomic-progn-assign 'edebug-form-spec '(sexp body))
 643
 644 (defmacro gnus-atomic-setq (&rest pairs)
 645   "Similar to setq, except that the real symbols are only assigned when
 646 there are no errors.  And when the real symbols are assigned, they are
 647 done so atomically.  If other variables might be changed via side-effect,
 648 see gnus-atomic-progn-assign.  It is safe to use gnus-atomic-setq
 649 with potentially long computations."
 650   (let ((tpairs pairs)
 651         syms)
 652     (while tpairs
 653       (push (car tpairs) syms)
 654       (setq tpairs (cddr tpairs)))
 655     `(gnus-atomic-progn-assign ,syms
 656        (setq ,@pairs))))
 657
 658 ;(put 'gnus-atomic-setq 'edebug-form-spec '(body))
 659
 660
 661 ;;; Functions for saving to babyl/mail files.
 662
 663 (defvar rmail-default-rmail-file)
 664 (defun gnus-output-to-rmail (filename &optional ask)
 665   "Append the current article to an Rmail file named FILENAME."
 666   (require 'rmail)
 667   ;; Most of these codes are borrowed from rmailout.el.
 668   (setq filename (expand-file-name filename))
 669   (setq rmail-default-rmail-file filename)
 670   (let ((artbuf (current-buffer))
 671         (tmpbuf (get-buffer-create " *Gnus-output*")))
 672     (save-excursion
 673       (or (get-file-buffer filename)
 674           (file-exists-p filename)
 675           (if (or (not ask)
 676                   (gnus-yes-or-no-p
 677                    (concat "\"" filename "\" does not exist, create it? ")))
 678               (let ((file-buffer (create-file-buffer filename)))
 679                 (save-excursion
 680                   (set-buffer file-buffer)
 681                   (rmail-insert-rmail-file-header)
 682                   (let ((require-final-newline nil)
 683                         (coding-system-for-write mm-text-coding-system))
 684                     (gnus-write-buffer filename)))
 685                 (kill-buffer file-buffer))
 686             (error "Output file does not exist")))
 687       (set-buffer tmpbuf)
 688       (erase-buffer)
 689       (insert-buffer-substring artbuf)
 690       (gnus-convert-article-to-rmail)
 691       ;; Decide whether to append to a file or to an Emacs buffer.
 692       (let ((outbuf (get-file-buffer filename)))
 693         (if (not outbuf)
 694             (mm-append-to-file (point-min) (point-max) filename)
 695           ;; File has been visited, in buffer OUTBUF.
 696           (set-buffer outbuf)
 697           (let ((buffer-read-only nil)
 698                 (msg (and (boundp 'rmail-current-message)
 699                           (symbol-value 'rmail-current-message))))
 700             ;; If MSG is non-nil, buffer is in RMAIL mode.
 701             (when msg
 702               (widen)
 703               (narrow-to-region (point-max) (point-max)))
 704             (insert-buffer-substring tmpbuf)
 705             (when msg
 706               (goto-char (point-min))
 707               (widen)
 708               (search-backward "\n\^_")
 709               (narrow-to-region (point) (point-max))
 710               (rmail-count-new-messages t)
 711               (when (rmail-summary-exists)
 712                 (rmail-select-summary
 713                  (rmail-update-summary)))
 714               (rmail-count-new-messages t)
 715               (rmail-show-message msg))
 716             (save-buffer)))))
 717     (kill-buffer tmpbuf)))
 718
 719 (defun gnus-output-to-mail (filename &optional ask)
 720   "Append the current article to a mail file named FILENAME."
 721   (setq filename (expand-file-name filename))
 722   (let ((artbuf (current-buffer))
 723         (tmpbuf (get-buffer-create " *Gnus-output*")))
 724     (save-excursion
 725       ;; Create the file, if it doesn't exist.
 726       (when (and (not (get-file-buffer filename))
 727                  (not (file-exists-p filename)))
 728         (if (or (not ask)
 729                 (gnus-y-or-n-p
 730                  (concat "\"" filename "\" does not exist, create it? ")))
 731             (let ((file-buffer (create-file-buffer filename)))
 732               (save-excursion
 733                 (set-buffer file-buffer)
 734                 (let ((require-final-newline nil)
 735                       (coding-system-for-write mm-text-coding-system))
 736                   (gnus-write-buffer filename)))
 737               (kill-buffer file-buffer))
 738           (error "Output file does not exist")))
 739       (set-buffer tmpbuf)
 740       (erase-buffer)
 741       (insert-buffer-substring artbuf)
 742       (goto-char (point-min))
 743       (if (looking-at "From ")
 744           (forward-line 1)
 745         (insert "From nobody " (current-time-string) "\n"))
 746       (let (case-fold-search)
 747         (while (re-search-forward "^From " nil t)
 748           (beginning-of-line)
 749           (insert ">")))
 750       ;; Decide whether to append to a file or to an Emacs buffer.
 751       (let ((outbuf (get-file-buffer filename)))
 752         (if (not outbuf)
 753             (let ((buffer-read-only nil))
 754               (save-excursion
 755                 (goto-char (point-max))
 756                 (forward-char -2)
 757                 (unless (looking-at "\n\n")
 758                   (goto-char (point-max))
 759                   (unless (bolp)
 760                     (insert "\n"))
 761                   (insert "\n"))
 762                 (goto-char (point-max))
 763                 (mm-append-to-file (point-min) (point-max) filename)))
 764           ;; File has been visited, in buffer OUTBUF.
 765           (set-buffer outbuf)
 766           (let ((buffer-read-only nil))
 767             (goto-char (point-max))
 768             (unless (eobp)
 769               (insert "\n"))
 770             (insert "\n")
 771             (insert-buffer-substring tmpbuf)))))
 772     (kill-buffer tmpbuf)))
 773
 774 (defun gnus-convert-article-to-rmail ()
 775   "Convert article in current buffer to Rmail message format."
 776   (let ((buffer-read-only nil))
 777     ;; Convert article directly into Babyl format.
 778     (goto-char (point-min))
 779     (insert "\^L\n0, unseen,,\n*** EOOH ***\n")
 780     (while (search-forward "\n\^_" nil t) ;single char
 781       (replace-match "\n^_" t t))       ;2 chars: "^" and "_"
 782     (goto-char (point-max))
 783     (insert "\^_")))
 784
 785 (defun gnus-map-function (funs arg)
 786   "Applies the result of the first function in FUNS to the second, and so on.
 787 ARG is passed to the first function."
 788   (let ((myfuns funs))
 789     (while myfuns
 790       (setq arg (funcall (pop myfuns) arg)))
 791     arg))
 792
 793 (defun gnus-run-hooks (&rest funcs)
 794   "Does the same as `run-hooks', but saves excursion."
 795   (let ((buf (current-buffer)))
 796     (unwind-protect
 797         (apply 'run-hooks funcs)
 798       (set-buffer buf))))
 799
 800 ;;;
 801 ;;; .netrc and .authinforc parsing
 802 ;;;
 803
 804 (defun gnus-parse-netrc (file)
 805   "Parse FILE and return an list of all entries in the file."
 806   (when (file-exists-p file)
 807     (with-temp-buffer
 808       (let ((tokens '("machine" "default" "login"
 809                       "password" "account" "macdef" "force"
 810                       "port"))
 811             alist elem result pair)
 812         (insert-file-contents file)
 813         (goto-char (point-min))
 814         ;; Go through the file, line by line.
 815         (while (not (eobp))
 816           (narrow-to-region (point) (gnus-point-at-eol))
 817           ;; For each line, get the tokens and values.
 818           (while (not (eobp))
 819             (skip-chars-forward "\t ")
 820             ;; Skip lines that begin with a "#".
 821             (if (eq (char-after) ?#)
 822                 (goto-char (point-max))
 823               (unless (eobp)
 824                 (setq elem
 825                       (if (= (following-char) ?\")
 826                           (read (current-buffer))
 827                         (buffer-substring
 828                          (point) (progn (skip-chars-forward "^\t ")
 829                                         (point)))))
 830                 (cond
 831                  ((equal elem "macdef")
 832                   ;; We skip past the macro definition.
 833                   (widen)
 834                   (while (and (zerop (forward-line 1))
 835                               (looking-at "$")))
 836                   (narrow-to-region (point) (point)))
 837                  ((member elem tokens)
 838                   ;; Tokens that don't have a following value are ignored,
 839                   ;; except "default".
 840                   (when (and pair (or (cdr pair)
 841                                       (equal (car pair) "default")))
 842                     (push pair alist))
 843                   (setq pair (list elem)))
 844                  (t
 845                   ;; Values that haven't got a preceding token are ignored.
 846                   (when pair
 847                     (setcdr pair elem)
 848                     (push pair alist)
 849                     (setq pair nil)))))))
 850           (when alist
 851             (push (nreverse alist) result))
 852           (setq alist nil
 853                 pair nil)
 854           (widen)
 855           (forward-line 1))
 856         (nreverse result)))))
 857
 858 (defun gnus-netrc-machine (list machine &optional port defaultport)
 859   "Return the netrc values from LIST for MACHINE or for the default entry.
 860 If PORT specified, only return entries with matching port tokens.
 861 Entries without port tokens default to DEFAULTPORT."
 862   (let ((rest list)
 863         result)
 864     (while list
 865       (when (equal (cdr (assoc "machine" (car list))) machine)
 866         (push (car list) result))
 867       (pop list))
 868     (unless result
 869       ;; No machine name matches, so we look for default entries.
 870       (while rest
 871         (when (assoc "default" (car rest))
 872           (push (car rest) result))
 873         (pop rest)))
 874     (when result
 875       (setq result (nreverse result))
 876       (while (and result
 877                   (not (equal (or port defaultport "nntp")
 878                               (or (gnus-netrc-get (car result) "port")
 879                                   defaultport "nntp"))))
 880         (pop result))
 881       (car result))))
 882
 883 (defun gnus-netrc-get (alist type)
 884   "Return the value of token TYPE from ALIST."
 885   (cdr (assoc type alist)))
 886
 887 ;;; Various
 888
 889 (defvar gnus-group-buffer)              ; Compiler directive
 890 (defun gnus-alive-p ()
 891   "Say whether Gnus is running or not."
 892   (and (boundp 'gnus-group-buffer)
 893        (get-buffer gnus-group-buffer)
 894        (save-excursion
 895          (set-buffer gnus-group-buffer)
 896          (eq major-mode 'gnus-group-mode))))
 897
 898 (defun gnus-remove-duplicates (list)
 899   (let (new (tail list))
 900     (while tail
 901       (or (member (car tail) new)
 902           (setq new (cons (car tail) new)))
 903       (setq tail (cdr tail)))
 904     (nreverse new)))
 905
 906 (defun gnus-delete-if (predicate list)
 907   "Delete elements from LIST that satisfy PREDICATE."
 908   (let (out)
 909     (while list
 910       (unless (funcall predicate (car list))
 911         (push (car list) out))
 912       (pop list))
 913     (nreverse out)))
 914
 915 (defun gnus-delete-alist (key alist)
 916   "Delete all entries in ALIST that have a key eq to KEY."
 917   (let (entry)
 918     (while (setq entry (assq key alist))
 919       (setq alist (delq entry alist)))
 920     alist))
 921
 922 (defmacro gnus-pull (key alist &optional assoc-p)
 923   "Modify ALIST to be without KEY."
 924   (unless (symbolp alist)
 925     (error "Not a symbol: %s" alist))
 926   (let ((fun (if assoc-p 'assoc 'assq)))
 927     `(setq ,alist (delq (,fun ,key ,alist) ,alist))))
 928
 929 (defun gnus-globalify-regexp (re)
 930   "Returns a regexp that matches a whole line, iff RE matches a part of it."
 931   (concat (unless (string-match "^\\^" re) "^.*")
 932           re
 933           (unless (string-match "\\$$" re) ".*$")))
 934
 935 (defun gnus-set-window-start (&optional point)
 936   "Set the window start to POINT, or (point) if nil."
 937   (let ((win (get-buffer-window (current-buffer) t)))
 938     (when win
 939       (set-window-start win (or point (point))))))
 940
 941 (defun gnus-annotation-in-region-p (b e)
 942   (if (= b e)
 943       (eq (cadr (memq 'gnus-undeletable (text-properties-at b))) t)
 944     (text-property-any b e 'gnus-undeletable t)))
 945
 946 (defun gnus-or (&rest elems)
 947   "Return non-nil if any of the elements are non-nil."
 948   (catch 'found
 949     (while elems
 950       (when (pop elems)
 951         (throw 'found t)))))
 952
 953 (defun gnus-and (&rest elems)
 954   "Return non-nil if all of the elements are non-nil."
 955   (catch 'found
 956     (while elems
 957       (unless (pop elems)
 958         (throw 'found nil)))
 959     t))
 960
 961 (defun gnus-write-active-file (file hashtb &optional full-names)
 962   (let ((coding-system-for-write nnmail-active-file-coding-system))
 963     (with-temp-file file
 964       (mapatoms
 965        (lambda (sym)
 966          (when (and sym
 967                     (boundp sym)
 968                     (symbol-value sym))
 969            (insert (format "%S %d %d y\n"
 970                            (if full-names
 971                                sym
 972                              (intern (gnus-group-real-name (symbol-name sym))))
 973                            (or (cdr (symbol-value sym))
 974                                (car (symbol-value sym)))
 975                            (car (symbol-value sym))))))
 976        hashtb)
 977       (goto-char (point-max))
 978       (while (search-backward "\\." nil t)
 979         (delete-char 1)))))
 980
 981 (defun gnus-add-text-properties-when
 982   (property value start end properties &optional object)
 983   "Like `gnus-add-text-properties', only applied on where PROPERTY is VALUE."
 984   (let (point)
 985     (while (and start
 986                 (setq point (text-property-not-all start end property value)))
 987       (gnus-add-text-properties start point properties object)
 988       (setq start (text-property-any point end property value)))
 989     (if start
 990         (gnus-add-text-properties start end properties object))))
 991
 992 (defun gnus-remove-text-properties-when
 993   (property value start end properties &optional object)
 994   "Like `remove-text-properties', only applied on where PROPERTY is VALUE."
 995   (let (point)
 996     (while (and start
 997                 (setq point (text-property-not-all start end property value)))
 998       (remove-text-properties start point properties object)
 999       (setq start (text-property-any point end property value)))
1000     (if start
1001         (remove-text-properties start end properties object))
1002     t))
1003
1004 (provide 'gnus-util)
1005
1006 ;;; gnus-util.el ends here