lisp/org/org-jsinfo.el

   1 ;;; org-jsinfo.el --- Support for org-info.js Javascript in Org HTML export
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;; Version: 6.33x
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file implements the support for Sebastian Rose's Javascript
  30 ;; org-info.js to display an org-mode file exported to HTML in an
  31 ;; Info-like way, or using folding similar to the outline structure
  32 ;; org org-mode itself.
  33
  34 ;; Documentation for using this module is in the Org manual. The script
  35 ;; itself is documented by Sebastian Rose in a file distributed with
  36 ;; the script.  FIXME: Accurate pointers!
  37
  38 ;; Org-mode loads this module by default - if this is not what you want,
  39 ;; configure the variable `org-modules'.
  40
  41 ;;; Code:
  42
  43 (require 'org-exp)
  44 (require 'org-html)
  45
  46 (add-to-list 'org-export-inbuffer-options-extra '("INFOJS_OPT" :infojs-opt))
  47 (add-hook 'org-export-options-filters 'org-infojs-handle-options)
  48
  49 (defgroup org-infojs nil
  50   "Options specific for using org-info.js in HTML export of Org-mode files."
  51   :tag "Org Export HTML INFOJS"
  52   :group 'org-export-html)
  53
  54 (defcustom org-export-html-use-infojs 'when-configured
  55   "Should Sebastian Rose's Java Script org-info.js be linked into HTML files?
  56 This option can be nil or t to never or always use the script.  It can
  57 also be the symbol `when-configured', meaning that the script will be
  58 linked into the export file if and only if there is a \"#+INFOJS_OPT:\"
  59 line in the buffer.  See also the variable `org-infojs-options'."
  60   :group 'org-export-html
  61   :group 'org-infojs
  62   :type '(choice
  63           (const :tag "Never" nil)
  64           (const :tag "When configured in buffer" when-configured)
  65           (const :tag "Always" t)))
  66
  67 (defconst org-infojs-opts-table
  68   '((path PATH "http://orgmode.org/org-info.js")
  69     (view VIEW "info")
  70     (toc TOC :table-of-contents)
  71     (ftoc FIXED_TOC "0")
  72     (tdepth TOC_DEPTH "max")
  73     (sdepth SECTION_DEPTH "max")
  74     (mouse MOUSE_HINT "underline")
  75     (buttons VIEW_BUTTONS "0")
  76     (ltoc LOCAL_TOC "1")
  77     (up LINK_UP :link-up)
  78     (home LINK_HOME :link-home))
  79   "JavaScript options, long form for script, default values.")
  80
  81 (defvar org-infojs-options)
  82 (when (and (boundp 'org-infojs-options)
  83            (assq 'runs org-infojs-options))
  84   (setq org-infojs-options (delq (assq 'runs org-infojs-options)
  85                                  org-infojs-options)))
  86
  87 (defcustom org-infojs-options
  88   (mapcar (lambda (x) (cons (car x) (nth 2 x)))
  89           org-infojs-opts-table)
  90   "Options settings for the INFOJS Javascript.
  91 Each of the options must have an entry in `org-export-html/infojs-opts-table'.
  92 The value can either be a string that will be passed to the script, or
  93 a property.  This property is then assumed to be a property that is defined
  94 by the Export/Publishing setup of Org.
  95 The `sdepth' and `tdepth' parameters can also be set to \"max\", which
  96 means to use the maximum value consistent with other options."
  97   :group 'org-infojs
  98   :type
  99   `(set :greedy t :inline t
 100         ,@(mapcar
 101            (lambda (x)
 102              (list 'cons (list 'const (car x))
 103                    '(choice
 104                             (symbol :tag "Publishing/Export property")
 105                             (string :tag "Value"))))
 106            org-infojs-opts-table)))
 107
 108 (defcustom org-infojs-template
 109   "<script type=\"text/javascript\" src=\"%SCRIPT_PATH\"></script>
 110 <script type=\"text/javascript\" >
 111 <!--/*--><![CDATA[/*><!--*/
 112 %MANAGER_OPTIONS
 113 org_html_manager.setup();  // activate after the parameters are set
 114 /*]]>*///-->
 115 </script>"
 116   "The template for the export style additions when org-info.js is used.
 117 Option settings will replace the %MANAGER-OPTIONS cookie."
 118   :group 'org-infojs
 119   :type 'string)
 120
 121 (defun org-infojs-handle-options (exp-plist)
 122   "Analyze JavaScript options in INFO-PLIST and modify EXP-PLIST accordingly."
 123   (if (or (not org-export-html-use-infojs)
 124           (and (eq org-export-html-use-infojs 'when-configured)
 125                (or (not (plist-get exp-plist :infojs-opt))
 126                    (string-match "\\<view:nil\\>"
 127                                  (plist-get exp-plist :infojs-opt)))))
 128       ;; We do not want to use the script
 129       exp-plist
 130     ;; We do want to use the script, set it up
 131     (let ((template org-infojs-template)
 132         (ptoc (plist-get exp-plist :table-of-contents))
 133         (hlevels (plist-get exp-plist :headline-levels))
 134         tdepth sdepth s v e opt var val table default)
 135     (setq sdepth hlevels
 136           tdepth hlevels)
 137     (if (integerp ptoc) (setq tdepth (min ptoc tdepth)))
 138     (setq v (plist-get exp-plist :infojs-opt)
 139           table org-infojs-opts-table)
 140     (while (setq e (pop table))
 141       (setq opt (car e) var (nth 1 e)
 142             default (cdr (assoc opt org-infojs-options)))
 143       (and (symbolp default) (not (memq default '(t nil)))
 144            (setq default (plist-get exp-plist default)))
 145       (if (and v (string-match (format " %s:\\(\\S-+\\)" opt) v))
 146           (setq val (match-string 1 v))
 147         (setq val default))
 148       (cond
 149        ((eq opt 'path)
 150         (and (string-match "%SCRIPT_PATH" template)
 151              (setq template (replace-match val t t template))))
 152        ((eq opt 'sdepth)
 153         (if (integerp (read val))
 154             (setq sdepth (min (read val) hlevels))))
 155        ((eq opt 'tdepth)
 156         (if (integerp (read val))
 157             (setq tdepth (min (read val) hlevels))))
 158        (t
 159         (setq val
 160               (cond
 161                ((or (eq val t) (equal val "t")) "1")
 162                ((or (eq val nil) (equal val "nil")) "0")
 163                ((stringp val) val)
 164                (t (format "%s" val))))
 165         (push (cons var val) s))))
 166
 167     ;; Now we set the depth of the *generated* TOC to SDEPTH, because the
 168     ;; toc will actually determine the splitting.  How much of the toc will
 169     ;; actually be displayed is governed by the TDEPTH option.
 170     (setq exp-plist (plist-put exp-plist :table-of-contents sdepth))
 171
 172     ;; The table of contents should not show more sections then we generate
 173     (setq tdepth (min tdepth sdepth))
 174     (push (cons "TOC_DEPTH" tdepth) s)
 175
 176     (setq s (mapconcat
 177              (lambda (x) (format "org_html_manager.set(\"%s\", \"%s\");"
 178                                  (car x) (cdr x)))
 179              s "\n"))
 180     (when (and s (> (length s) 0))
 181       (and (string-match "%MANAGER_OPTIONS" template)
 182            (setq s (replace-match s t t template))
 183            (setq exp-plist
 184                  (plist-put
 185                   exp-plist :style-extra
 186                   (concat (or (plist-get exp-plist :style-extra) "") "\n" s)))))
 187     ;; This script absolutely needs the table of contents, to we change that
 188     ;; setting
 189     (if (not (plist-get exp-plist :table-of-contents))
 190         (setq exp-plist (plist-put exp-plist :table-of-contents t)))
 191     ;; Return the modified property list
 192     exp-plist)))
 193
 194 (defun org-infojs-options-inbuffer-template ()
 195   (format "#+INFOJS_OPT: view:%s toc:%s ltoc:%s mouse:%s buttons:%s path:%s"
 196           (if (eq t org-export-html-use-infojs) (cdr (assoc 'view org-infojs-options)) nil)
 197           (let ((a (cdr (assoc 'toc org-infojs-options))))
 198             (cond ((memq a '(nil t)) a)
 199                   (t (plist-get (org-infile-export-plist) :table-of-contents))))
 200           (if (equal (cdr (assoc 'ltoc org-infojs-options)) "1") t nil)
 201           (cdr (assoc 'mouse org-infojs-options))
 202           (cdr (assoc 'buttons org-infojs-options))
 203           (cdr (assoc 'path org-infojs-options))))
 204
 205 (provide 'org-infojs)
 206 (provide 'org-jsinfo)
 207
 208 ;; arch-tag: c71d1d85-3337-4817-a066-725e74ac9eac
 209
 210 ;;; org-jsinfo.el ends here