lisp/midnight.el

   1 ;;; midnight.el --- run something every midnight, e.g., kill old buffers
   2
   3 ;; Copyright (C) 1998, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009, 2010, 2011 Free Software Foundation, Inc.
   5
   6 ;; Author: Sam Steingold <sds@usa.net>
   7 ;; Maintainer: Sam Steingold <sds@usa.net>
   8 ;; Created: 1998-05-18
   9 ;; Keywords: utilities
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; To use the file, put (require 'midnight) into your .emacs.  Then, at
  29 ;; midnight, Emacs will run the normal hook `midnight-hook'.  You can
  30 ;; put whatever you like there, say, `calendar'; by default there is
  31 ;; only one function there - `clean-buffer-list'. It will kill the
  32 ;; buffers matching `clean-buffer-list-kill-buffer-names' and
  33 ;; `clean-buffer-list-kill-regexps' and the buffers which where last
  34 ;; displayed more than `clean-buffer-list-delay-general' days ago,
  35 ;; keeping `clean-buffer-list-kill-never-buffer-names' and
  36 ;; `clean-buffer-list-kill-never-regexps'.
  37
  38 ;;; Code:
  39
  40 (eval-when-compile
  41  (require 'cl))
  42
  43 (require 'timer)
  44
  45 (defgroup midnight nil
  46   "Run something every day at midnight."
  47   :group 'calendar
  48   :version "20.3")
  49
  50 (defvar midnight-timer nil
  51   "Timer running the `midnight-hook' `midnight-delay' seconds after midnight.
  52 Use `cancel-timer' to stop it and `midnight-delay-set' to change
  53 the time when it is run.")
  54
  55 (defcustom midnight-mode nil
  56   "Non-nil means run `midnight-hook' at midnight.
  57 Setting this variable outside customize has no effect;
  58 call `cancel-timer' or `timer-activate' on `midnight-timer' instead."
  59   :type 'boolean
  60   :group 'midnight
  61   :require 'midnight
  62   :initialize 'custom-initialize-default
  63   :set (lambda (symb val)
  64          (set symb val) (require 'midnight)
  65          (if val (timer-activate midnight-timer)
  66              (cancel-timer midnight-timer))))
  67
  68 ;;; time conversion
  69
  70 (defun midnight-time-float (num)
  71   "Convert the float number of seconds since epoch to the list of 3 integers."
  72   (let* ((div (ash 1 16)) (1st (floor num div)))
  73     (list 1st (floor (- num (* (float div) 1st)))
  74           (round (* 10000000 (mod num 1))))))
  75
  76 (defun midnight-buffer-display-time (&optional buffer)
  77   "Return the time-stamp of BUFFER, or current buffer, as float."
  78   (with-current-buffer (or buffer (current-buffer))
  79     (when buffer-display-time (float-time buffer-display-time))))
  80
  81 ;;; clean-buffer-list stuff
  82
  83 (defcustom clean-buffer-list-delay-general 3
  84   "The number of days before any buffer becomes eligible for autokilling.
  85 The autokilling is done by `clean-buffer-list' when is it in `midnight-hook'.
  86 Currently displayed and/or modified (unsaved) buffers, as well as buffers
  87 matching `clean-buffer-list-kill-never-buffer-names' and
  88 `clean-buffer-list-kill-never-regexps' are excluded."
  89   :type 'integer
  90   :group 'midnight)
  91
  92 (defcustom clean-buffer-list-delay-special 3600
  93   "The number of seconds before some buffers become eligible for autokilling.
  94 Buffers matched by `clean-buffer-list-kill-regexps' and
  95 `clean-buffer-list-kill-buffer-names' are killed if they were last
  96 displayed more than this many seconds ago."
  97   :type 'integer
  98   :group 'midnight)
  99
 100 (defcustom clean-buffer-list-kill-regexps nil
 101   "List of regexps saying which buffers will be killed at midnight.
 102 If buffer name matches a regexp in the list and the buffer was not displayed
 103 in the last `clean-buffer-list-delay-special' seconds, it is killed by
 104 `clean-buffer-list' when is it in `midnight-hook'.
 105 If a member of the list is a cons, its `car' is the regexp and its `cdr' is
 106 the number of seconds to use instead of `clean-buffer-list-delay-special'.
 107 See also `clean-buffer-list-kill-buffer-names',
 108 `clean-buffer-list-kill-never-regexps' and
 109 `clean-buffer-list-kill-never-buffer-names'."
 110   :type '(repeat (regexp :tag "Regexp matching Buffer Name"))
 111   :group 'midnight)
 112
 113 (defcustom clean-buffer-list-kill-buffer-names
 114     '("*Help*" "*Apropos*" "*Man " "*Buffer List*" "*Compile-Log*" "*info*"
 115       "*vc*" "*vc-diff*" "*diff*")
 116   "List of strings saying which buffers will be killed at midnight.
 117 Buffers with names in this list, which were not displayed in the last
 118 `clean-buffer-list-delay-special' seconds, are killed by `clean-buffer-list'
 119 when is it in `midnight-hook'.
 120 If a member of the list is a cons, its `car' is the name and its `cdr' is
 121 the number of seconds to use instead of `clean-buffer-list-delay-special'.
 122 See also `clean-buffer-list-kill-regexps',
 123 `clean-buffer-list-kill-never-regexps' and
 124 `clean-buffer-list-kill-never-buffer-names'."
 125   :type '(repeat (string :tag "Buffer Name"))
 126   :group 'midnight)
 127
 128 (defcustom clean-buffer-list-kill-never-buffer-names
 129     '("*scratch*" "*Messages*" "*server*")
 130   "List of buffer names which will never be killed by `clean-buffer-list'.
 131 See also `clean-buffer-list-kill-never-regexps'.
 132 Note that this does override `clean-buffer-list-kill-regexps' and
 133 `clean-buffer-list-kill-buffer-names' so a buffer matching any of these
 134 two lists will NOT be killed if it is also present in this list."
 135   :type '(repeat (string :tag "Buffer Name"))
 136   :group 'midnight)
 137
 138 (defcustom clean-buffer-list-kill-never-regexps '("^ \\*Minibuf-.*\\*$")
 139   "List of regexp saying which buffers will never be killed at midnight.
 140 See also `clean-buffer-list-kill-never-buffer-names'.
 141 Killing is done by `clean-buffer-list'.
 142 Note that this does override `clean-buffer-list-kill-regexps' and
 143 `clean-buffer-list-kill-buffer-names' so a buffer matching any of these
 144 two lists will NOT be killed if it also matches anything in this list."
 145   :type '(repeat (regexp :tag "Regexp matching Buffer Name"))
 146   :group 'midnight)
 147
 148 (defun midnight-find (el ls test &optional key)
 149   "A stopgap solution to the absence of `find' in ELisp."
 150   (dolist (rr ls)
 151     (when (funcall test (if key (funcall key rr) rr) el)
 152       (return rr))))
 153
 154 (defun clean-buffer-list-delay (name)
 155   "Return the delay, in seconds, before killing a buffer named NAME.
 156 Uses `clean-buffer-list-kill-buffer-names', `clean-buffer-list-kill-regexps'
 157 `clean-buffer-list-delay-general' and `clean-buffer-list-delay-special'.
 158 Autokilling is done by `clean-buffer-list'."
 159   (or (assoc-default name clean-buffer-list-kill-buffer-names 'string=
 160                      clean-buffer-list-delay-special)
 161       (assoc-default name clean-buffer-list-kill-regexps 'string-match
 162                      clean-buffer-list-delay-special)
 163       (* clean-buffer-list-delay-general 24 60 60)))
 164
 165 ;;;###autoload
 166 (defun clean-buffer-list ()
 167   "Kill old buffers that have not been displayed recently.
 168 The relevant variables are `clean-buffer-list-delay-general',
 169 `clean-buffer-list-delay-special', `clean-buffer-list-kill-buffer-names',
 170 `clean-buffer-list-kill-never-buffer-names',
 171 `clean-buffer-list-kill-regexps' and
 172 `clean-buffer-list-kill-never-regexps'.
 173 While processing buffers, this procedure displays messages containing
 174 the current date/time, buffer name, how many seconds ago it was
 175 displayed (can be nil if the buffer was never displayed) and its
 176 lifetime, i.e., its \"age\" when it will be purged."
 177   (interactive)
 178   (let ((tm (float-time)) bts (ts (format-time-string "%Y-%m-%d %T"))
 179         delay cbld bn)
 180     (dolist (buf (buffer-list))
 181       (when (buffer-live-p buf)
 182         (setq bts (midnight-buffer-display-time buf) bn (buffer-name buf)
 183               delay (if bts (- tm bts) 0) cbld (clean-buffer-list-delay bn))
 184         (message "[%s] `%s' [%s %d]" ts bn (if bts (round delay)) cbld)
 185         (unless (or (midnight-find bn clean-buffer-list-kill-never-regexps
 186                                    'string-match)
 187                     (midnight-find bn clean-buffer-list-kill-never-buffer-names
 188                                    'string-equal)
 189                     (get-buffer-process buf)
 190                     (and (buffer-file-name buf) (buffer-modified-p buf))
 191                     (get-buffer-window buf 'visible) (< delay cbld))
 192           (message "[%s] killing `%s'" ts bn)
 193           (kill-buffer buf))))))
 194
 195 ;;; midnight hook
 196
 197 (defvar midnight-period (* 24 60 60)
 198   "The number of seconds in a day--the delta for `midnight-timer'.")
 199
 200 (defcustom midnight-hook '(clean-buffer-list)
 201   "The hook run `midnight-delay' seconds after midnight every day.
 202 The default value is `clean-buffer-list'."
 203   :type 'hook
 204   :group 'midnight)
 205
 206 (defun midnight-next ()
 207   "Return the number of seconds till the next midnight."
 208   (multiple-value-bind (sec min hrs)
 209       (values-list (decode-time))
 210     (- (* 24 60 60) (* 60 60 hrs) (* 60 min) sec)))
 211
 212 ;;;###autoload
 213 (defun midnight-delay-set (symb tm)
 214   "Modify `midnight-timer' according to `midnight-delay'.
 215 Sets the first argument SYMB (which must be symbol `midnight-delay')
 216 to its second argument TM."
 217   (assert (eq symb 'midnight-delay) t
 218           "Invalid argument to `midnight-delay-set': `%s'")
 219   (set symb tm)
 220   (when (timerp midnight-timer) (cancel-timer midnight-timer))
 221   (setq midnight-timer
 222         (run-at-time (if (numberp tm) (+ (midnight-next) tm) tm)
 223                      midnight-period 'run-hooks 'midnight-hook)))
 224
 225 (defcustom midnight-delay 3600
 226   "The number of seconds after the midnight when the `midnight-timer' is run.
 227 You should set this variable before loading midnight.el, or
 228 set it by calling `midnight-delay-set', or use `custom'.
 229 If you wish, you can use a string instead, it will be passed as the
 230 first argument to `run-at-time'."
 231   :type 'sexp
 232   :set 'midnight-delay-set
 233   :group 'midnight)
 234
 235 (provide 'midnight)
 236
 237 ;; arch-tag: a5979be9-2890-46a3-ba84-791f0a4a6e80
 238 ;;; midnight.el ends here