lisp/dired-x.el

   1 ;;; dired-x.el --- extra Dired functionality  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1993-1994, 1997, 2001-2016 Free Software Foundation,
   4 ;; Inc.
   5
   6 ;; Author: Sebastian Kremer <sk@thp.uni-koeln.de>
   7 ;;      Lawrence R. Dodd <dodd@roebling.poly.edu>
   8 ;; Maintainer: Romain Francoise <rfrancoise@gnu.org>
   9 ;; Keywords: dired extensions files
  10 ;; Package: emacs
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; This is based on Sebastian Kremer's excellent dired-x.el (Dired Extra),
  30 ;; version 1.191, adapted for GNU Emacs.  See the `dired-x' info pages.
  31
  32 ;; USAGE: In your ~/.emacs,
  33 ;;
  34 ;; (add-hook 'dired-load-hook
  35 ;;           (lambda ()
  36 ;;                       (load "dired-x")
  37 ;;                       ;; Set global variables here.  For example:
  38 ;;                       ;; (setq dired-guess-shell-gnutar "gtar")
  39 ;;                       ))
  40 ;; (add-hook 'dired-mode-hook
  41 ;;           (lambda ()
  42 ;;                       ;; Set buffer-local variables here.  For example:
  43 ;;                       ;; (dired-omit-mode 1)
  44 ;;                       ))
  45 ;;
  46 ;; At load time dired-x.el will install itself and bind some dired keys.
  47 ;; Some dired.el and dired-aux.el functions have extra features if
  48 ;; dired-x is loaded.
  49
  50 ;; User customization: M-x customize-group RET dired-x RET.
  51
  52 ;; *Please* see the `dired-x' info pages for more details.
  53
  54 \f
  55 ;;; Code:
  56
  57 ;; This is a no-op if dired-x is being loaded via `dired-load-hook',
  58 ;; but maybe not if a dired-x function is being autoloaded.
  59 (require 'dired)
  60
  61 ;;; User-defined variables.
  62
  63 (defgroup dired-x nil
  64   "Extended directory editing (dired-x)."
  65   :group 'dired)
  66
  67 (defgroup dired-keys nil
  68   "Dired keys customizations."
  69   :prefix "dired-"
  70   :group 'dired-x)
  71
  72 (defcustom dired-bind-vm nil
  73   "Non-nil means \"V\" runs `dired-vm', otherwise \"V\" runs `dired-rmail'.
  74 RMAIL files in the old Babyl format (used before before Emacs 23.1)
  75 contain \"-*- rmail -*-\" at the top, so `dired-find-file'
  76 will run `rmail' on these files.  New RMAIL files use the standard
  77 mbox format, and so cannot be distinguished in this way."
  78   :type 'boolean
  79   :group 'dired-keys)
  80
  81 (defcustom dired-bind-jump t
  82   "Non-nil means bind `dired-jump' to C-x C-j, otherwise do not.
  83 Setting this variable directly after dired-x is loaded has no effect -
  84 use \\[customize]."
  85   :type 'boolean
  86   :set (lambda (sym val)
  87          (if (set sym val)
  88              (progn
  89                (define-key ctl-x-map "\C-j" 'dired-jump)
  90                (define-key ctl-x-4-map "\C-j" 'dired-jump-other-window))
  91            (if (eq 'dired-jump (lookup-key ctl-x-map "\C-j"))
  92                (define-key ctl-x-map "\C-j" nil))
  93            (if (eq 'dired-jump-other-window (lookup-key ctl-x-4-map "\C-j"))
  94                (define-key ctl-x-4-map "\C-j" nil))))
  95   :group 'dired-keys)
  96
  97 (defcustom dired-bind-man t
  98   "Non-nil means bind `dired-man' to \"N\" in Dired, otherwise do not.
  99 Setting this variable directly after dired-x is loaded has no effect -
 100 use \\[customize]."
 101   :type 'boolean
 102   :set (lambda (sym val)
 103          (if (set sym val)
 104              (define-key dired-mode-map "N" 'dired-man)
 105            (if (eq 'dired-man (lookup-key dired-mode-map "N"))
 106                (define-key dired-mode-map "N" nil))))
 107   :group 'dired-keys)
 108
 109 (defcustom dired-bind-info t
 110   "Non-nil means bind `dired-info' to \"I\" in Dired, otherwise do not.
 111 Setting this variable directly after dired-x is loaded has no effect -
 112 use \\[customize]."
 113   :type 'boolean
 114   :set (lambda (sym val)
 115          (if (set sym val)
 116              (define-key dired-mode-map "I" 'dired-info)
 117            (if (eq 'dired-info (lookup-key dired-mode-map "I"))
 118                (define-key dired-mode-map "I" nil))))
 119   :group 'dired-keys)
 120
 121 (defcustom dired-vm-read-only-folders nil
 122   "If non-nil, \\[dired-vm] will visit all folders read-only.
 123 If neither nil nor t, e.g. the symbol `if-file-read-only', only
 124 files not writable by you are visited read-only."
 125   :type '(choice (const :tag "off" nil)
 126                  (const :tag "on" t)
 127                  (other :tag "non-writable only" if-file-read-only))
 128   :group 'dired-x)
 129
 130 (defcustom dired-omit-size-limit 30000
 131   "Maximum size for the \"omitting\" feature.
 132 If nil, there is no maximum size."
 133   :type '(choice (const :tag "no maximum" nil) integer)
 134   :group 'dired-x)
 135
 136 ;; For backward compatibility
 137 (define-obsolete-variable-alias 'dired-omit-files-p 'dired-omit-mode "22.1")
 138 (define-minor-mode dired-omit-mode
 139   "Toggle omission of uninteresting files in Dired (Dired-Omit mode).
 140 With a prefix argument ARG, enable Dired-Omit mode if ARG is
 141 positive, and disable it otherwise.  If called from Lisp, enable
 142 the mode if ARG is omitted or nil.
 143
 144 Dired-Omit mode is a buffer-local minor mode.  When enabled in a
 145 Dired buffer, Dired does not list files whose filenames match
 146 regexp `dired-omit-files', nor files ending with extensions in
 147 `dired-omit-extensions'.
 148
 149 To enable omitting in every Dired buffer, you can put this in
 150 your init file:
 151
 152   (add-hook \\='dired-mode-hook (lambda () (dired-omit-mode)))
 153
 154 See Info node `(dired-x) Omitting Variables' for more information."
 155   :group 'dired-x
 156   (if dired-omit-mode
 157       ;; This will mention how many lines were omitted:
 158       (let ((dired-omit-size-limit nil)) (dired-omit-expunge))
 159     (revert-buffer)))
 160
 161 (put 'dired-omit-mode 'safe-local-variable 'booleanp)
 162
 163 (defcustom dired-omit-files "^\\.?#\\|^\\.$\\|^\\.\\.$"
 164   "Filenames matching this regexp will not be displayed.
 165 This only has effect when `dired-omit-mode' is t.  See interactive function
 166 `dired-omit-mode' (\\[dired-omit-mode]) and variable
 167 `dired-omit-extensions'.  The default is to omit  `.', `..', auto-save
 168 files and lock files."
 169   :type 'regexp
 170   :group 'dired-x)
 171
 172 (defcustom dired-omit-verbose t
 173   "When non-nil, show messages when omitting files.
 174 When nil, don't show messages."
 175   :version "24.1"
 176   :type 'boolean
 177   :group 'dired-x)
 178
 179 (defcustom dired-find-subdir nil           ; t is pretty near to DWIM...
 180   "If non-nil, Dired always finds a directory in a buffer of its own.
 181 If nil, Dired finds the directory as a subdirectory in some other buffer
 182 if it is present as one.
 183
 184 If there are several Dired buffers for a directory, the most recently
 185 used is chosen.
 186
 187 Dired avoids switching to the current buffer, so that if you have
 188 a normal and a wildcard buffer for the same directory, \\[dired] will
 189 toggle between those two."
 190   :type 'boolean
 191   :group 'dired-x)
 192
 193 (defcustom dired-enable-local-variables t
 194   "Control use of local-variables lists in Dired.
 195 This temporarily overrides the value of `enable-local-variables' when
 196 listing a directory.  See also `dired-local-variables-file'."
 197   :risky t
 198   :type '(choice (const :tag "Query Unsafe" t)
 199                  (const :tag "Safe Only" :safe)
 200                  (const :tag "Do all" :all)
 201                  (const :tag "Ignore" nil)
 202                  (other :tag "Query" other))
 203   :group 'dired-x)
 204
 205 (make-obsolete-variable 'dired-enable-local-variables
 206                         "use a standard `dir-locals-file' instead." "24.1")
 207
 208 (defcustom dired-guess-shell-gnutar
 209   (catch 'found
 210     (dolist (exe '("tar" "gtar"))
 211       (if (with-temp-buffer
 212             (ignore-errors (call-process exe nil t nil "--version"))
 213             (and (re-search-backward "GNU tar" nil t) t))
 214           (throw 'found exe))))
 215   "If non-nil, name of GNU tar executable.
 216 \(E.g., \"tar\" or \"gtar\").  The `z' switch will be used with it for
 217 compressed or gzip'ed tar files.  If you don't have GNU tar, set this
 218 to nil: a pipe using `zcat' or `gunzip -c' will be used."
 219   ;; Changed from system-type test to testing --version output.
 220   ;; Maybe test --help for -z instead?
 221   :version "24.1"
 222   :type '(choice (const :tag "Not GNU tar" nil)
 223                  (string :tag "Command name"))
 224   :group 'dired-x)
 225
 226 (defcustom dired-guess-shell-gzip-quiet t
 227   "Non-nil says pass -q to gzip overriding verbose GZIP environment."
 228   :type 'boolean
 229   :group 'dired-x)
 230
 231 (defcustom dired-guess-shell-znew-switches nil
 232   "If non-nil, then string of switches passed to `znew', example: \"-K\"."
 233   :type '(choice (const :tag "None" nil)
 234                  (string :tag "Switches"))
 235   :group 'dired-x)
 236
 237 (defcustom dired-clean-up-buffers-too t
 238   "Non-nil means offer to kill buffers visiting files and dirs deleted in Dired."
 239   :type 'boolean
 240   :group 'dired-x)
 241
 242 ;;; KEY BINDINGS.
 243
 244 (define-key dired-mode-map "\C-x\M-o" 'dired-omit-mode)
 245 (define-key dired-mode-map "*O" 'dired-mark-omitted)
 246 (define-key dired-mode-map "\M-(" 'dired-mark-sexp)
 247 (define-key dired-mode-map "*(" 'dired-mark-sexp)
 248 (define-key dired-mode-map "*." 'dired-mark-extension)
 249 (define-key dired-mode-map "\M-!" 'dired-smart-shell-command)
 250 (define-key dired-mode-map "\M-G" 'dired-goto-subdir)
 251 (define-key dired-mode-map "F" 'dired-do-find-marked-files)
 252 (define-key dired-mode-map "Y"  'dired-do-relsymlink)
 253 (define-key dired-mode-map "%Y" 'dired-do-relsymlink-regexp)
 254 (define-key dired-mode-map "V" 'dired-do-run-mail)
 255
 256 ;;; MENU BINDINGS
 257
 258 (require 'easymenu)
 259
 260 (let ((menu (lookup-key dired-mode-map [menu-bar])))
 261   (easy-menu-add-item menu '("Operate")
 262                       ["Find Files" dired-do-find-marked-files
 263                        :help "Find current or marked files"]
 264                       "Shell Command...")
 265   (easy-menu-add-item menu '("Operate")
 266                       ["Relative Symlink to..." dired-do-relsymlink
 267                        :visible (fboundp 'make-symbolic-link)
 268                        :help "Make relative symbolic links for current or \
 269 marked files"]
 270                       "Hardlink to...")
 271   (easy-menu-add-item menu '("Mark")
 272                       ["Flag Extension..." dired-flag-extension
 273                        :help "Flag files with a certain extension for deletion"]
 274                       "Mark Executables")
 275   (easy-menu-add-item menu '("Mark")
 276                       ["Mark Extension..." dired-mark-extension
 277                        :help "Mark files with a certain extension"]
 278                       "Unmark All")
 279   (easy-menu-add-item menu '("Mark")
 280                       ["Mark Omitted" dired-mark-omitted
 281                        :help "Mark files matching `dired-omit-files' \
 282 and `dired-omit-extensions'"]
 283                       "Unmark All")
 284   (easy-menu-add-item menu '("Regexp")
 285                       ["Relative Symlink..." dired-do-relsymlink-regexp
 286                        :visible (fboundp 'make-symbolic-link)
 287                        :help "Make relative symbolic links for files \
 288 matching regexp"]
 289                       "Hardlink...")
 290   (easy-menu-add-item menu '("Immediate")
 291                       ["Omit Mode" dired-omit-mode
 292                        :style toggle :selected dired-omit-mode
 293                        :help "Enable or disable omitting \"uninteresting\" \
 294 files"]
 295                       "Refresh"))
 296
 297 \f
 298 ;; Install into appropriate hooks.
 299
 300 (add-hook 'dired-mode-hook 'dired-extra-startup)
 301 (add-hook 'dired-after-readin-hook 'dired-omit-expunge)
 302
 303 (defun dired-extra-startup ()
 304   "Automatically put on `dired-mode-hook' to get extra Dired features:
 305 \\<dired-mode-map>
 306   \\[dired-do-run-mail]\t-- run mail on folder (see `dired-bind-vm')
 307   \\[dired-info]\t-- run info on file
 308   \\[dired-man]\t-- run man on file
 309   \\[dired-do-find-marked-files]\t-- visit all marked files simultaneously
 310   \\[dired-omit-mode]\t-- toggle omitting of files
 311   \\[dired-mark-sexp]\t-- mark by Lisp expression
 312
 313 To see the options you can set, use M-x customize-group RET dired-x RET.
 314 See also the functions:
 315   `dired-flag-extension'
 316   `dired-virtual'
 317   `dired-jump'
 318   `dired-man'
 319   `dired-vm'
 320   `dired-rmail'
 321   `dired-info'
 322   `dired-do-find-marked-files'"
 323   (interactive)
 324   ;; These must be done in each new dired buffer.
 325   (dired-hack-local-variables)
 326   (dired-omit-startup))
 327
 328 \f
 329 ;;; EXTENSION MARKING FUNCTIONS.
 330
 331 ;; Mark files with some extension.
 332 (defun dired-mark-extension (extension &optional marker-char)
 333   "Mark all files with a certain EXTENSION for use in later commands.
 334 A `.' is *not* automatically prepended to the string entered.
 335 EXTENSION may also be a list of extensions instead of a single one.
 336 Optional MARKER-CHAR is marker to use."
 337   (interactive "sMarking extension: \nP")
 338   (or (listp extension)
 339       (setq extension (list extension)))
 340   (dired-mark-files-regexp
 341    (concat ".";; don't match names with nothing but an extension
 342            "\\("
 343            (mapconcat 'regexp-quote extension "\\|")
 344            "\\)$")
 345    marker-char))
 346
 347 (defun dired-flag-extension (extension)
 348   "In Dired, flag all files with a certain EXTENSION for deletion.
 349 A `.' is *not* automatically prepended to the string entered."
 350   (interactive "sFlagging extension: ")
 351   (dired-mark-extension extension dired-del-marker))
 352
 353 ;; Define some unpopular file extensions.  Used for cleaning and omitting.
 354
 355 (defvar dired-patch-unclean-extensions
 356   '(".rej" ".orig")
 357   "List of extensions of dispensable files created by the `patch' program.")
 358
 359 (defvar dired-tex-unclean-extensions
 360   '(".toc" ".log" ".aux");; these are already in completion-ignored-extensions
 361   "List of extensions of dispensable files created by TeX.")
 362
 363 (defvar dired-latex-unclean-extensions
 364   '(".idx" ".lof" ".lot" ".glo")
 365   "List of extensions of dispensable files created by LaTeX.")
 366
 367 (defvar dired-bibtex-unclean-extensions
 368   '(".blg" ".bbl")
 369   "List of extensions of dispensable files created by BibTeX.")
 370
 371 (defvar dired-texinfo-unclean-extensions
 372   '(".cp" ".cps" ".fn" ".fns" ".ky" ".kys" ".pg" ".pgs"
 373     ".tp" ".tps" ".vr" ".vrs")
 374   "List of extensions of dispensable files created by texinfo.")
 375
 376 (defun dired-clean-patch ()
 377   "Flag dispensable files created by patch for deletion.
 378 See variable `dired-patch-unclean-extensions'."
 379   (interactive)
 380   (dired-flag-extension dired-patch-unclean-extensions))
 381
 382 (defun dired-clean-tex ()
 383   "Flag dispensable files created by [La]TeX etc. for deletion.
 384 See variables `dired-tex-unclean-extensions',
 385 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 386 `dired-texinfo-unclean-extensions'."
 387   (interactive)
 388   (dired-flag-extension (append dired-texinfo-unclean-extensions
 389                                 dired-latex-unclean-extensions
 390                                 dired-bibtex-unclean-extensions
 391                                 dired-tex-unclean-extensions)))
 392
 393 (defun dired-very-clean-tex ()
 394   "Flag dispensable files created by [La]TeX *and* \".dvi\" for deletion.
 395 See variables `dired-texinfo-unclean-extensions',
 396 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions' and
 397 `dired-texinfo-unclean-extensions'."
 398   (interactive)
 399   (dired-flag-extension (append dired-texinfo-unclean-extensions
 400                                 dired-latex-unclean-extensions
 401                                 dired-bibtex-unclean-extensions
 402                                 dired-tex-unclean-extensions
 403                                 (list ".dvi"))))
 404 \f
 405 (defvar tar-superior-buffer)
 406 ;;; JUMP.
 407
 408 ;;;###autoload
 409 (defun dired-jump (&optional other-window file-name)
 410   "Jump to Dired buffer corresponding to current buffer.
 411 If in a file, Dired the current directory and move to file's line.
 412 If in Dired already, pop up a level and goto old directory's line.
 413 In case the proper Dired file line cannot be found, refresh the dired
 414 buffer and try again.
 415 When OTHER-WINDOW is non-nil, jump to Dired buffer in other window.
 416 Interactively with prefix argument, read FILE-NAME and
 417 move to its line in dired."
 418   (interactive
 419    (list nil (and current-prefix-arg
 420                   (read-file-name "Jump to Dired file: "))))
 421   (if (bound-and-true-p tar-subfile-mode)
 422       (switch-to-buffer tar-superior-buffer)
 423     (let* ((file (or file-name buffer-file-name))
 424            (dir (if file (file-name-directory file) default-directory)))
 425       (if (and (eq major-mode 'dired-mode) (null file-name))
 426           (progn
 427             (setq dir (dired-current-directory))
 428             (dired-up-directory other-window)
 429             (unless (dired-goto-file dir)
 430               ;; refresh and try again
 431               (dired-insert-subdir (file-name-directory dir))
 432               (dired-goto-file dir)))
 433         (if other-window
 434             (dired-other-window dir)
 435           (dired dir))
 436         (if file
 437             (or (dired-goto-file file)
 438                 ;; refresh and try again
 439                 (progn
 440                   (dired-insert-subdir (file-name-directory file))
 441                   (dired-goto-file file))
 442                 ;; Toggle omitting, if it is on, and try again.
 443                 (when dired-omit-mode
 444                   (dired-omit-mode)
 445                   (dired-goto-file file))))))))
 446
 447 ;;;###autoload
 448 (defun dired-jump-other-window (&optional file-name)
 449   "Like \\[dired-jump] (`dired-jump') but in other window."
 450   (interactive
 451    (list (and current-prefix-arg
 452               (read-file-name "Jump to Dired file: "))))
 453   (dired-jump t file-name))
 454 \f
 455 ;;; OMITTING.
 456
 457 ;; Enhanced omitting of lines from directory listings.
 458 ;; Marked files are never omitted.
 459
 460 ;; should probably get rid of this and always use 'no-dir.
 461 ;; sk 28-Aug-1991 09:37
 462 (defvar dired-omit-localp 'no-dir
 463   "The LOCALP argument `dired-omit-expunge' passes to `dired-get-filename'.
 464 If it is `no-dir', omitting is much faster, but you can only match
 465 against the non-directory part of the file name.  Set it to nil if you
 466 need to match the entire file name.")
 467
 468 ;; \017=^O for Omit - other packages can chose other control characters.
 469 (defvar dired-omit-marker-char ?\017
 470   "Temporary marker used by Dired-Omit.
 471 Should never be used as marker by the user or other packages.")
 472
 473 (defun dired-omit-startup ()
 474   (or (assq 'dired-omit-mode minor-mode-alist)
 475       (setq minor-mode-alist
 476             (append '((dired-omit-mode
 477                        (:eval (if (eq major-mode 'dired-mode)
 478                                   " Omit" ""))))
 479                     minor-mode-alist))))
 480
 481 (defun dired-mark-omitted ()
 482   "Mark files matching `dired-omit-files' and `dired-omit-extensions'."
 483   (interactive)
 484   (let ((dired-omit-mode nil)) (revert-buffer)) ;; Show omitted files
 485   (dired-mark-unmarked-files (dired-omit-regexp) nil nil dired-omit-localp))
 486
 487 (defcustom dired-omit-extensions
 488   (append completion-ignored-extensions
 489           dired-latex-unclean-extensions
 490           dired-bibtex-unclean-extensions
 491           dired-texinfo-unclean-extensions)
 492   "If non-nil, a list of extensions (strings) to omit from Dired listings.
 493 Defaults to elements of `completion-ignored-extensions',
 494 `dired-latex-unclean-extensions', `dired-bibtex-unclean-extensions', and
 495 `dired-texinfo-unclean-extensions'.
 496
 497 See interactive function `dired-omit-mode' (\\[dired-omit-mode]) and
 498 variables `dired-omit-mode' and `dired-omit-files'."
 499   :type '(repeat string)
 500   :group 'dired-x)
 501
 502 (defun dired-omit-expunge (&optional regexp)
 503   "Erases all unmarked files matching REGEXP.
 504 Does nothing if global variable `dired-omit-mode' is nil, or if called
 505   non-interactively and buffer is bigger than `dired-omit-size-limit'.
 506 If REGEXP is nil or not specified, uses `dired-omit-files', and also omits
 507   filenames ending in `dired-omit-extensions'.
 508 If REGEXP is the empty string, this function is a no-op.
 509
 510 This functions works by temporarily binding `dired-marker-char' to
 511 `dired-omit-marker-char' and calling `dired-do-kill-lines'."
 512   (interactive "sOmit files (regexp): ")
 513   (if (and dired-omit-mode
 514            (or (called-interactively-p 'interactive)
 515                (not dired-omit-size-limit)
 516                (< (buffer-size) dired-omit-size-limit)
 517                (progn
 518                  (when dired-omit-verbose
 519                    (message "Not omitting: directory larger than %d characters."
 520                             dired-omit-size-limit))
 521                  (setq dired-omit-mode nil)
 522                  nil)))
 523       (let ((omit-re (or regexp (dired-omit-regexp)))
 524             (old-modified-p (buffer-modified-p))
 525             count)
 526         (or (string= omit-re "")
 527             (let ((dired-marker-char dired-omit-marker-char))
 528               (when dired-omit-verbose (message "Omitting..."))
 529               (if (dired-mark-unmarked-files omit-re nil nil dired-omit-localp)
 530                   (progn
 531                     (setq count (dired-do-kill-lines
 532                                  nil
 533                                  (if dired-omit-verbose "Omitted %d line%s." "")))
 534                     (force-mode-line-update))
 535                 (when dired-omit-verbose (message "(Nothing to omit)")))))
 536         ;; Try to preserve modified state of buffer.  So `%*' doesn't appear
 537         ;; in mode-line of omitted buffers.
 538         (set-buffer-modified-p (and old-modified-p
 539                                     (save-excursion
 540                                       (goto-char (point-min))
 541                                       (re-search-forward dired-re-mark nil t))))
 542         count)))
 543
 544 (defun dired-omit-regexp ()
 545   (concat (if dired-omit-files (concat "\\(" dired-omit-files "\\)") "")
 546           (if (and dired-omit-files dired-omit-extensions) "\\|" "")
 547           (if dired-omit-extensions
 548               (concat ".";; a non-extension part should exist
 549                       "\\("
 550                       (mapconcat 'regexp-quote dired-omit-extensions "\\|")
 551                       "\\)$")
 552             "")))
 553
 554 ;; Returns t if any work was done, nil otherwise.
 555 (defun dired-mark-unmarked-files (regexp msg &optional unflag-p localp)
 556   "Mark unmarked files matching REGEXP, displaying MSG.
 557 REGEXP is matched against the entire file name.  When called
 558 interactively, prompt for REGEXP.
 559 With prefix argument, unflag all those files.
 560 Optional fourth argument LOCALP is as in `dired-get-filename'."
 561   (interactive
 562    (list (read-regexp
 563           "Mark unmarked files matching regexp (default all): "
 564           nil 'dired-regexp-history)
 565          nil current-prefix-arg nil))
 566   (let ((dired-marker-char (if unflag-p ?\s dired-marker-char)))
 567     (dired-mark-if
 568      (and
 569       ;; not already marked
 570       (looking-at-p " ")
 571       ;; uninteresting
 572       (let ((fn (dired-get-filename localp t)))
 573         (and fn (string-match-p regexp fn))))
 574      msg)))
 575
 576 \f
 577 ;;; VIRTUAL DIRED MODE.
 578
 579 ;; For browsing `ls -lR' listings in a dired-like fashion.
 580
 581 (defalias 'virtual-dired 'dired-virtual)
 582 (defun dired-virtual (dirname &optional switches)
 583   "Put this buffer into Virtual Dired mode.
 584
 585 In Virtual Dired mode, all commands that do not actually consult the
 586 filesystem will work.
 587
 588 This is useful if you want to peruse and move around in an ls -lR
 589 output file, for example one you got from an ftp server.  With
 590 ange-ftp, you can even Dired a directory containing an ls-lR file,
 591 visit that file and turn on Virtual Dired mode.  But don't try to save
 592 this file, as dired-virtual indents the listing and thus changes the
 593 buffer.
 594
 595 If you have save a Dired buffer in a file you can use \\[dired-virtual] to
 596 resume it in a later session.
 597
 598 Type \\<dired-mode-map>\\[revert-buffer] \
 599 in the Virtual Dired buffer and answer `y' to convert
 600 the virtual to a real Dired buffer again.  You don't have to do this, though:
 601 you can relist single subdirs using \\[dired-do-redisplay]."
 602
 603   ;; DIRNAME is the top level directory of the buffer.  It will become
 604   ;; its `default-directory'.  If nil, the old value of
 605   ;; default-directory is used.
 606
 607   ;; Optional SWITCHES are the ls switches to use.
 608
 609   ;; Shell wildcards will be used if there already is a `wildcard'
 610   ;; line in the buffer (thus it is a saved Dired buffer), but there
 611   ;; is no other way to get wildcards.  Insert a `wildcard' line by
 612   ;; hand if you want them.
 613
 614   (interactive
 615    (list (read-string "Virtual Dired directory: " (dired-virtual-guess-dir))))
 616   (goto-char (point-min))
 617   (or (looking-at-p "  ")
 618       ;; if not already indented, do it now:
 619       (indent-region (point-min) (point-max) 2))
 620   (or dirname (setq dirname default-directory))
 621   (setq dirname (expand-file-name (file-name-as-directory dirname)))
 622   (setq default-directory dirname)      ; contains no wildcards
 623   (let ((wildcard (save-excursion
 624                     (goto-char (point-min))
 625                     (forward-line 1)
 626                     (and (looking-at "^  wildcard ")
 627                          (buffer-substring (match-end 0)
 628                                            (line-end-position))))))
 629   (if wildcard
 630         (setq dirname (expand-file-name wildcard default-directory))))
 631   ;; If raw ls listing (not a saved old dired buffer), give it a
 632   ;; decent subdir headerline:
 633   (goto-char (point-min))
 634   (or (looking-at-p dired-subdir-regexp)
 635       (insert "  "
 636               (directory-file-name (file-name-directory default-directory))
 637               ":\n"))
 638   (dired-mode dirname (or switches dired-listing-switches))
 639   (setq mode-name "Virtual Dired"
 640         revert-buffer-function 'dired-virtual-revert)
 641   (set (make-local-variable 'dired-subdir-alist) nil)
 642   (dired-build-subdir-alist)
 643   (goto-char (point-min))
 644   (dired-initial-position dirname))
 645
 646 (defun dired-virtual-guess-dir ()
 647   "Guess and return appropriate working directory of this buffer.
 648 The buffer is assumed to be in Dired or ls -lR format.  The guess is
 649 based upon buffer contents.  If nothing could be guessed, returns
 650 nil."
 651
 652   (let ((regexp "^\\(  \\)?\\([^ \n\r]*\\)\\(:\\)[\n\r]")
 653         (subexpr 2))
 654     (goto-char (point-min))
 655     (cond ((looking-at regexp)
 656            ;; If a saved dired buffer, look to which dir and
 657            ;; perhaps wildcard it belongs:
 658            (let ((dir (buffer-substring (match-beginning subexpr)
 659                                         (match-end subexpr))))
 660              (file-name-as-directory dir)))
 661           ;; Else no match for headerline found.  It's a raw ls listing.
 662           ;; In raw ls listings the directory does not have a headerline
 663           ;; try parent of first subdir, if any
 664           ((re-search-forward regexp nil t)
 665            (file-name-directory
 666             (directory-file-name
 667              (file-name-as-directory
 668               (buffer-substring (match-beginning subexpr)
 669                                 (match-end subexpr))))))
 670           (t                            ; if all else fails
 671            nil))))
 672
 673
 674 (defun dired-virtual-revert (&optional _arg _noconfirm)
 675   (if (not
 676        (y-or-n-p "Cannot revert a Virtual Dired buffer - switch to Real Dired mode? "))
 677       (error "Cannot revert a Virtual Dired buffer")
 678     (setq mode-name "Dired"
 679           revert-buffer-function 'dired-revert)
 680     (revert-buffer)))
 681
 682 ;; A zero-arg version of dired-virtual.
 683 (defun dired-virtual-mode ()
 684   "Put current buffer into Virtual Dired mode (see `dired-virtual').
 685 Useful on `magic-mode-alist' with the regexp
 686
 687   \"^  \\\\(/[^ /]+\\\\)+/?:$\"
 688
 689 to put saved Dired buffers automatically into Virtual Dired mode.
 690
 691 Also useful for `auto-mode-alist' like this:
 692
 693   (add-to-list \\='auto-mode-alist
 694                \\='(\"[^/]\\\\.dired\\\\\\='\" . dired-virtual-mode))"
 695   (interactive)
 696   (dired-virtual (dired-virtual-guess-dir)))
 697
 698 \f
 699 ;;; SMART SHELL.
 700
 701 ;; An Emacs buffer can have but one working directory, stored in the
 702 ;; buffer-local variable `default-directory'.  A Dired buffer may have
 703 ;; several subdirectories inserted, but still has but one working directory:
 704 ;; that of the top level Dired directory in that buffer.  For some commands
 705 ;; it is appropriate that they use the current Dired directory instead of
 706 ;; `default-directory', e.g., `find-file' and `compile'.  This is a general
 707 ;; mechanism is provided for special handling of the working directory in
 708 ;; special major modes.
 709
 710 (define-obsolete-variable-alias 'default-directory-alist
 711   'dired-default-directory-alist "24.1")
 712
 713 ;; It's easier to add to this alist than redefine function
 714 ;; default-directory while keeping the old information.
 715 (defconst dired-default-directory-alist
 716   '((dired-mode . (if (fboundp 'dired-current-directory)
 717                       (dired-current-directory)
 718                     default-directory)))
 719   "Alist of major modes and their opinion on `default-directory'.
 720 Each element has the form (MAJOR . EXPRESSION).
 721 The function `dired-default-directory' evaluates EXPRESSION to
 722 determine a default directory.")
 723
 724 (put 'dired-default-directory-alist 'risky-local-variable t) ; gets eval'd
 725 (make-obsolete-variable 'dired-default-directory-alist
 726                         "this feature is due to be removed." "24.1")
 727
 728 (defun dired-default-directory ()
 729   "Return the `dired-default-directory-alist' entry for the current major-mode.
 730 If none, return `default-directory'."
 731   ;; It looks like this was intended to be something of a "general"
 732   ;; feature, but it only ever seems to have been used in
 733   ;; dired-smart-shell-command, and doesn't seem worth keeping around.
 734   (declare (obsolete nil "24.1"))
 735   (or (eval (cdr (assq major-mode dired-default-directory-alist)))
 736       default-directory))
 737
 738 (defun dired-smart-shell-command (command &optional output-buffer error-buffer)
 739   "Like function `shell-command', but in the current Virtual Dired directory."
 740   (interactive
 741    (list
 742     (read-shell-command "Shell command: " nil nil
 743                         (cond
 744                          (buffer-file-name (file-relative-name buffer-file-name))
 745                          ((eq major-mode 'dired-mode) (dired-get-filename t t))))
 746     current-prefix-arg
 747     shell-command-default-error-buffer))
 748   (let ((default-directory (or (and (eq major-mode 'dired-mode)
 749                                     (dired-current-directory))
 750                                default-directory)))
 751     (shell-command command output-buffer error-buffer)))
 752
 753 \f
 754 ;;; LOCAL VARIABLES FOR DIRED BUFFERS.
 755
 756 ;; Brief Description  (This feature is obsolete as of Emacs 24.1)
 757 ;;
 758 ;; * `dired-extra-startup' is part of the `dired-mode-hook'.
 759 ;;
 760 ;; * `dired-extra-startup' calls `dired-hack-local-variables'
 761 ;;
 762 ;; * `dired-hack-local-variables' checks the value of
 763 ;;   `dired-local-variables-file'
 764 ;;
 765 ;; * Check if `dired-local-variables-file' is a non-nil string and is a
 766 ;;   filename found in the directory of the Dired Buffer being created.
 767 ;;
 768 ;; * If `dired-local-variables-file' satisfies the above, then temporarily
 769 ;;   include it in the Dired Buffer at the bottom.
 770 ;;
 771 ;; * Set `enable-local-variables' temporarily to the user variable
 772 ;;   `dired-enable-local-variables' and run `hack-local-variables' on the
 773 ;;   Dired Buffer.
 774
 775 (defcustom dired-local-variables-file (convert-standard-filename ".dired")
 776   "Filename, as string, containing local Dired buffer variables to be hacked.
 777 If this file found in current directory, then it will be inserted into dired
 778 buffer and `hack-local-variables' will be run.  See Info node
 779 `(emacs)File Variables' for more information on local variables.
 780 See also `dired-enable-local-variables'."
 781   :type 'file
 782   :group 'dired)
 783
 784 (make-obsolete-variable 'dired-local-variables-file 'dir-locals-file "24.1")
 785
 786 (defun dired-hack-local-variables ()
 787   "Evaluate local variables in `dired-local-variables-file' for Dired buffer."
 788   (declare (obsolete hack-dir-local-variables-non-file-buffer "24.1"))
 789   (and (stringp dired-local-variables-file)
 790        (file-exists-p dired-local-variables-file)
 791        (let ((opoint (point-max))
 792              (inhibit-read-only t)
 793              ;; In case user has `enable-local-variables' set to nil we
 794              ;; override it locally with dired's variable.
 795              (enable-local-variables dired-enable-local-variables))
 796          ;; Insert 'em.
 797          (save-excursion
 798            (goto-char opoint)
 799            (insert "\^L\n")
 800            (insert-file-contents dired-local-variables-file))
 801          ;; Hack 'em.
 802          (unwind-protect
 803              (let ((buffer-file-name dired-local-variables-file))
 804                (hack-local-variables))
 805            ;; Delete this stuff: `eobp' is used to find last subdir by dired.el.
 806            (delete-region opoint (point-max)))
 807          ;; Make sure that the mode line shows the proper information.
 808          (dired-sort-set-mode-line))))
 809
 810 ;; Does not seem worth a dedicated command.
 811 ;; See the more general features in files-x.el.
 812 (defun dired-omit-here-always ()
 813   "Create `dir-locals-file' setting `dired-omit-mode' to t in `dired-mode'.
 814 If in a Dired buffer, reverts it."
 815   (declare (obsolete add-dir-local-variable "24.1"))
 816   (interactive)
 817   (if (file-exists-p dired-local-variables-file)
 818       (error "Old-style dired-local-variables-file `./%s' found;
 819 replace it with a dir-locals-file `./%s.el'"
 820              dired-local-variables-file
 821              dir-locals-file))
 822   (if (dir-locals--all-files default-directory)
 823       (message "File `./%s' already exists."
 824                (car (dir-locals--all-files default-directory)))
 825     (add-dir-local-variable 'dired-mode 'subdirs nil)
 826     (add-dir-local-variable 'dired-mode 'dired-omit-mode t)
 827     ;; Run extra-hooks and revert directory.
 828     (when (derived-mode-p 'dired-mode)
 829       (hack-dir-local-variables-non-file-buffer)
 830       (dired-extra-startup)
 831       (dired-revert))))
 832
 833 \f
 834 ;;; GUESS SHELL COMMAND.
 835
 836 ;; Brief Description:
 837 ;;;
 838 ;; * `dired-do-shell-command' is bound to `!' by dired.el.
 839 ;;;
 840 ;; * `dired-guess-shell-command' provides smarter defaults for
 841 ;;;    dired-aux.el's `dired-read-shell-command'.
 842 ;;;
 843 ;; * `dired-guess-shell-command' calls `dired-guess-default' with list of
 844 ;;;    marked files.
 845 ;;;
 846 ;; * Parse `dired-guess-shell-alist-user' and
 847 ;;;   `dired-guess-shell-alist-default' (in that order) for the first REGEXP
 848 ;;;   that matches the first file in the file list.
 849 ;;;
 850 ;; * If the REGEXP matches all the entries of the file list then evaluate
 851 ;;;   COMMAND, which is either a string or a Lisp expression returning a
 852 ;;;   string.  COMMAND may be a list of commands.
 853 ;;;
 854 ;; * Return this command to `dired-guess-shell-command' which prompts user
 855 ;;;   with it.  The list of commands is put into the list of default values.
 856 ;;;   If a command is used successfully then it is stored permanently in
 857 ;;;   `dired-shell-command-history'.
 858
 859 ;; Guess what shell command to apply to a file.
 860 (defvar dired-shell-command-history nil
 861   "History list for commands that read dired-shell commands.")
 862
 863 ;; Default list of shell commands.
 864
 865 ;; NOTE: Use `gunzip -c' instead of `zcat' on `.gz' files.  Some do not
 866 ;; install GNU zip's version of zcat.
 867
 868 (autoload 'Man-support-local-filenames "man")
 869
 870 (defvar dired-guess-shell-alist-default
 871   (list
 872    (list "\\.tar\\'"
 873          '(if dired-guess-shell-gnutar
 874               (concat dired-guess-shell-gnutar " xvf")
 875             "tar xvf")
 876          ;; Extract files into a separate subdirectory
 877          '(if dired-guess-shell-gnutar
 878               (concat "mkdir " (file-name-sans-extension file)
 879                       "; " dired-guess-shell-gnutar " -C "
 880                       (file-name-sans-extension file) " -xvf")
 881             (concat "mkdir " (file-name-sans-extension file)
 882                     "; tar -C " (file-name-sans-extension file) " -xvf"))
 883          ;; List archive contents.
 884          '(if dired-guess-shell-gnutar
 885               (concat dired-guess-shell-gnutar " tvf")
 886             "tar tvf"))
 887
 888    ;; REGEXPS for compressed archives must come before the .Z rule to
 889    ;; be recognized:
 890    (list "\\.tar\\.Z\\'"
 891          ;; Untar it.
 892          '(if dired-guess-shell-gnutar
 893               (concat dired-guess-shell-gnutar " zxvf")
 894             (concat "zcat * | tar xvf -"))
 895          ;; Optional conversion to gzip format.
 896          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 897                   " " dired-guess-shell-znew-switches))
 898
 899    ;; gzip'ed archives
 900    (list "\\.t\\(ar\\.\\)?gz\\'"
 901          '(if dired-guess-shell-gnutar
 902               (concat dired-guess-shell-gnutar " zxvf")
 903             (concat "gunzip -qc * | tar xvf -"))
 904          ;; Extract files into a separate subdirectory
 905          '(if dired-guess-shell-gnutar
 906               (concat "mkdir " (file-name-sans-extension file)
 907                       "; " dired-guess-shell-gnutar " -C "
 908                       (file-name-sans-extension file) " -zxvf")
 909             (concat "mkdir " (file-name-sans-extension file)
 910                     "; gunzip -qc * | tar -C "
 911                     (file-name-sans-extension file) " -xvf -"))
 912          ;; Optional decompression.
 913          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q" ""))
 914          ;; List archive contents.
 915          '(if dired-guess-shell-gnutar
 916               (concat dired-guess-shell-gnutar " ztvf")
 917             (concat "gunzip -qc * | tar tvf -")))
 918
 919    ;; bzip2'ed archives
 920    (list "\\.t\\(ar\\.bz2\\|bz\\)\\'"
 921          "bunzip2 -c * | tar xvf -"
 922          ;; Extract files into a separate subdirectory
 923          '(concat "mkdir " (file-name-sans-extension file)
 924                   "; bunzip2 -c * | tar -C "
 925                   (file-name-sans-extension file) " -xvf -")
 926          ;; Optional decompression.
 927          "bunzip2")
 928
 929    ;; xz'ed archives
 930    (list "\\.t\\(ar\\.\\)?xz\\'"
 931          "unxz -c * | tar xvf -"
 932          ;; Extract files into a separate subdirectory
 933          '(concat "mkdir " (file-name-sans-extension file)
 934                   "; unxz -c * | tar -C "
 935                   (file-name-sans-extension file) " -xvf -")
 936          ;; Optional decompression.
 937          "unxz")
 938
 939    '("\\.shar\\.Z\\'" "zcat * | unshar")
 940    '("\\.shar\\.g?z\\'" "gunzip -qc * | unshar")
 941
 942    '("\\.e?ps\\'" "ghostview" "xloadimage" "lpr")
 943    (list "\\.e?ps\\.g?z\\'" "gunzip -qc * | ghostview -"
 944          ;; Optional decompression.
 945          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 946    (list "\\.e?ps\\.Z\\'" "zcat * | ghostview -"
 947          ;; Optional conversion to gzip format.
 948          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 949                   " " dired-guess-shell-znew-switches))
 950
 951    '("\\.patch\\'" "cat * | patch")
 952    (list "\\.patch\\.g?z\\'" "gunzip -qc * | patch"
 953          ;; Optional decompression.
 954          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 955    (list "\\.patch\\.Z\\'" "zcat * | patch"
 956          ;; Optional conversion to gzip format.
 957          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 958                   " " dired-guess-shell-znew-switches))
 959
 960    ;; The following four extensions are useful with dired-man ("N" key)
 961    ;; FIXME "man ./" does not work with dired-do-shell-command,
 962    ;; because there seems to be no way for us to modify the filename,
 963    ;; only the command.  Hmph.  `dired-man' works though.
 964    (list "\\.\\(?:[0-9]\\|man\\)\\'"
 965          '(let ((loc (Man-support-local-filenames)))
 966             (cond ((eq loc 'man-db) "man -l")
 967                   ((eq loc 'man) "man ./")
 968                   (t
 969                    "cat * | tbl | nroff -man -h | col -b"))))
 970    (list "\\.\\(?:[0-9]\\|man\\)\\.g?z\\'"
 971          '(let ((loc (Man-support-local-filenames)))
 972             (cond ((eq loc 'man-db)
 973                    "man -l")
 974                   ((eq loc 'man)
 975                    "man ./")
 976                   (t "gunzip -qc * | tbl | nroff -man -h | col -b")))
 977          ;; Optional decompression.
 978          '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
 979    (list "\\.[0-9]\\.Z\\'"
 980          '(let ((loc (Man-support-local-filenames)))
 981             (cond ((eq loc 'man-db) "man -l")
 982                   ((eq loc 'man) "man ./")
 983                   (t "zcat * | tbl | nroff -man -h | col -b")))
 984          ;; Optional conversion to gzip format.
 985          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
 986                   " " dired-guess-shell-znew-switches))
 987    '("\\.pod\\'" "perldoc" "pod2man * | nroff -man")
 988
 989    '("\\.dvi\\'" "xdvi" "dvips")        ; preview and printing
 990    '("\\.au\\'" "play")                 ; play Sun audiofiles
 991    '("\\.mpe?g\\'\\|\\.avi\\'" "xine -p")
 992    '("\\.ogg\\'" "ogg123")
 993    '("\\.mp3\\'" "mpg123")
 994    '("\\.wav\\'" "play")
 995    '("\\.uu\\'" "uudecode")             ; for uudecoded files
 996    '("\\.hqx\\'" "mcvert")
 997    '("\\.sh\\'" "sh")                   ; execute shell scripts
 998    '("\\.xbm\\'" "bitmap")              ; view X11 bitmaps
 999    '("\\.gp\\'" "gnuplot")
1000    '("\\.p[bgpn]m\\'" "xloadimage")
1001    '("\\.gif\\'" "xloadimage")          ; view gif pictures
1002    '("\\.tif\\'" "xloadimage")
1003    '("\\.png\\'" "display")             ; xloadimage 4.1 doesn't grok PNG
1004    '("\\.jpe?g\\'" "xloadimage")
1005    '("\\.fig\\'" "xfig")                ; edit fig pictures
1006    '("\\.out\\'" "xgraph")              ; for plotting purposes.
1007    '("\\.tex\\'" "latex" "tex")
1008    '("\\.texi\\(nfo\\)?\\'" "makeinfo" "texi2dvi")
1009    '("\\.pdf\\'" "xpdf")
1010    '("\\.doc\\'" "antiword" "strings")
1011    '("\\.rpm\\'" "rpm -qilp" "rpm -ivh")
1012    '("\\.dia\\'" "dia")
1013    '("\\.mgp\\'" "mgp")
1014
1015    ;; Some other popular archivers.
1016    (list "\\.zip\\'" "unzip" "unzip -l"
1017          ;; Extract files into a separate subdirectory
1018          '(concat "unzip" (if dired-guess-shell-gzip-quiet " -q")
1019                   " -d " (file-name-sans-extension file)))
1020    '("\\.zoo\\'" "zoo x//")
1021    '("\\.lzh\\'" "lharc x")
1022    '("\\.arc\\'" "arc x")
1023    '("\\.shar\\'" "unshar")
1024    '("\\.rar\\'" "unrar x")
1025    '("\\.7z\\'" "7z x")
1026
1027    ;; Compression.
1028    (list "\\.g?z\\'" '(concat "gunzip" (if dired-guess-shell-gzip-quiet " -q")))
1029    (list "\\.dz\\'" "dictunzip")
1030    (list "\\.bz2\\'" "bunzip2")
1031    (list "\\.xz\\'" "unxz")
1032    (list "\\.Z\\'" "uncompress"
1033          ;; Optional conversion to gzip format.
1034          '(concat "znew" (if dired-guess-shell-gzip-quiet " -q")
1035                   " " dired-guess-shell-znew-switches))
1036
1037    '("\\.sign?\\'" "gpg --verify"))
1038
1039   "Default alist used for shell command guessing.
1040 See `dired-guess-shell-alist-user'.")
1041
1042 (defcustom dired-guess-shell-alist-user nil
1043   "User-defined alist of rules for suggested commands.
1044 These rules take precedence over the predefined rules in the variable
1045 `dired-guess-shell-alist-default' (to which they are prepended).
1046
1047 Each element of this list looks like
1048
1049     (REGEXP COMMAND...)
1050
1051 where each COMMAND can either be a string or a Lisp expression that evaluates
1052 to a string.  This expression can access the file name as the variable `file'.
1053 If several COMMANDs are given, the first one will be the default
1054 and the rest will be added temporarily to the history and can be retrieved
1055 with \\[previous-history-element] (M-p) .
1056
1057 The variable `dired-guess-shell-case-fold-search' controls whether
1058 REGEXP is matched case-sensitively.
1059
1060 You can set this variable in your ~/.emacs.  For example, to add rules for
1061 `.foo' and `.bar' files, write
1062
1063  (setq dired-guess-shell-alist-user
1064         '((\"\\\\.foo\\\\'\" \"FOO-COMMAND\")
1065           (\"\\\\.bar\\\\'\"
1066            (if condition
1067               \"BAR-COMMAND-1\"
1068             \"BAR-COMMAND-2\"))))"
1069   :group 'dired-x
1070   :type '(alist :key-type regexp :value-type (repeat sexp)))
1071
1072 (defcustom dired-guess-shell-case-fold-search t
1073   "If non-nil, `dired-guess-shell-alist-default' and
1074 `dired-guess-shell-alist-user' are matched case-insensitively."
1075   :group 'dired-x
1076   :type 'boolean)
1077
1078 (defun dired-guess-default (files)
1079   "Return a shell command, or a list of commands, appropriate for FILES.
1080 See `dired-guess-shell-alist-user'."
1081
1082   (let* ((case-fold-search dired-guess-shell-case-fold-search)
1083          ;; Prepend the user's alist to the default alist.
1084          (alist (append dired-guess-shell-alist-user
1085                         dired-guess-shell-alist-default))
1086          (file (car files))
1087          (flist (cdr files))
1088          elt regexp cmds)
1089
1090     ;; Find the first match in the alist for first file in FILES.
1091     (while alist
1092       (setq elt (car alist)
1093             regexp (car elt)
1094             alist (cdr alist))
1095       (if (string-match-p regexp file)
1096           (setq cmds (cdr elt)
1097                 alist nil)))
1098
1099     ;; If more than one file, see if all of FILES match regular expression.
1100     (while (and flist
1101                 (string-match-p regexp (car flist)))
1102       (setq flist (cdr flist)))
1103
1104     ;; If flist is still non-nil, then do not guess since this means that not
1105     ;; all the files in FILES were matched by the regexp.
1106     (setq cmds (and (not flist) cmds))
1107
1108     ;; Return commands or nil if flist is still non-nil.
1109     ;; Evaluate the commands in order that any logical testing will be done.
1110     (if (cdr cmds)
1111         (delete-dups (mapcar (lambda (cmd) (eval cmd `((file . ,file)))) cmds))
1112       (eval (car cmds) `((file . ,file))))))            ; single command
1113
1114 (defun dired-guess-shell-command (prompt files)
1115   "Ask user with PROMPT for a shell command, guessing a default from FILES."
1116   (let ((default (dired-guess-default files))
1117         default-list val)
1118     (if (null default)
1119         ;; Nothing to guess
1120         (read-shell-command prompt nil 'dired-shell-command-history)
1121       (setq prompt (replace-regexp-in-string ": $" " " prompt))
1122       (if (listp default)
1123           ;; More than one guess
1124           (setq default-list default
1125                 default (car default)
1126                 prompt (concat
1127                         prompt
1128                         (format "{%d guesses} " (length default-list))))
1129         ;; Just one guess
1130         (setq default-list (list default)))
1131       ;; Put the first guess in the prompt but not in the initial value.
1132       (setq prompt (concat prompt (format "[%s]: " default)))
1133       ;; All guesses can be retrieved with M-n
1134       (setq val (read-shell-command prompt nil
1135                                     'dired-shell-command-history
1136                                     default-list))
1137       ;; If we got a return, then return default.
1138       (if (equal val "") default val))))
1139
1140 \f
1141 ;;; RELATIVE SYMBOLIC LINKS.
1142
1143 (declare-function make-symbolic-link "fileio.c")
1144
1145 (defvar dired-keep-marker-relsymlink ?S
1146   "See variable `dired-keep-marker-move'.")
1147
1148 (defun dired-make-relative-symlink (file1 file2 &optional ok-if-already-exists)
1149   "Make a symbolic link (pointing to FILE1) in FILE2.
1150 The link is relative (if possible), for example
1151
1152     \"/vol/tex/bin/foo\" \"/vol/local/bin/foo\"
1153
1154 results in
1155
1156     \"../../tex/bin/foo\" \"/vol/local/bin/foo\""
1157   (interactive "FRelSymLink: \nFRelSymLink %s: \np")
1158   (let (name1 name2 len1 len2 (index 0) sub)
1159     (setq file1 (expand-file-name file1)
1160           file2 (expand-file-name file2)
1161           len1 (length file1)
1162           len2 (length file2))
1163     ;; Find common initial file name components:
1164     (let (next)
1165       (while (and (setq next (string-match "/" file1 index))
1166                   (< (setq next (1+ next)) (min len1 len2))
1167                   ;; For the comparison, both substrings must end in
1168                   ;; `/', so NEXT is *one plus* the result of the
1169                   ;; string-match.
1170                   ;; E.g., consider the case of linking "/tmp/a/abc"
1171                   ;; to "/tmp/abc" erroneously giving "/tmp/a" instead
1172                   ;; of "/tmp/" as common initial component
1173                   (string-equal (substring file1 0 next)
1174                                 (substring file2 0 next)))
1175         (setq index next))
1176       (setq name2 file2
1177             sub (substring file1 0 index)
1178             name1 (substring file1 index)))
1179     (if (string-equal sub "/")
1180         ;; No common initial file name found
1181         (setq name1 file1)
1182       ;; Else they have a common parent directory
1183       (let ((tem (substring file2 index))
1184             (start 0)
1185             (count 0))
1186         ;; Count number of slashes we must compensate for ...
1187         (while (setq start (string-match "/" tem start))
1188           (setq count (1+ count)
1189                 start (1+ start)))
1190         ;; ... and prepend a "../" for each slash found:
1191         (dotimes (_ count)
1192           (setq name1 (concat "../" name1)))))
1193     (make-symbolic-link
1194      (directory-file-name name1)        ; must not link to foo/
1195                                         ; (trailing slash!)
1196      name2 ok-if-already-exists)))
1197
1198 (autoload 'dired-do-create-files "dired-aux")
1199
1200 ;;;###autoload
1201 (defun dired-do-relsymlink (&optional arg)
1202    "Relative symlink all marked (or next ARG) files into a directory.
1203 Otherwise make a relative symbolic link to the current file.
1204 This creates relative symbolic links like
1205
1206     foo -> ../bar/foo
1207
1208 not absolute ones like
1209
1210     foo -> /ugly/file/name/that/may/change/any/day/bar/foo
1211
1212 For absolute symlinks, use \\[dired-do-symlink]."
1213   (interactive "P")
1214   (dired-do-create-files 'relsymlink #'dired-make-relative-symlink
1215                            "RelSymLink" arg dired-keep-marker-relsymlink))
1216
1217 (autoload 'dired-mark-read-regexp "dired-aux")
1218 (autoload 'dired-do-create-files-regexp "dired-aux")
1219
1220 (defun dired-do-relsymlink-regexp (regexp newname &optional arg whole-name)
1221   "RelSymlink all marked files containing REGEXP to NEWNAME.
1222 See functions `dired-do-rename-regexp' and `dired-do-relsymlink'
1223 for more info."
1224   (interactive (dired-mark-read-regexp "RelSymLink"))
1225   (dired-do-create-files-regexp
1226    #'dired-make-relative-symlink
1227    "RelSymLink" arg regexp newname whole-name dired-keep-marker-relsymlink))
1228
1229 \f
1230 ;;; VISIT ALL MARKED FILES SIMULTANEOUSLY.
1231
1232 ;; Brief Description:
1233 ;;;
1234 ;; `dired-do-find-marked-files' is bound to `F' by dired-x.el.
1235 ;;;
1236 ;; * Use `dired-get-marked-files' to collect the marked files in the current
1237 ;;;   Dired Buffer into a list of filenames `FILE-LIST'.
1238 ;;;
1239 ;; * Pass FILE-LIST to `dired-simultaneous-find-file' all with
1240 ;;;   `dired-do-find-marked-files''s prefix argument NOSELECT.
1241 ;;;
1242 ;; * `dired-simultaneous-find-file' runs through FILE-LIST decrementing the
1243 ;;;   list each time.
1244 ;;;
1245 ;; * If NOSELECT is non-nil then just run `find-file-noselect' on each
1246 ;;;   element of FILE-LIST.
1247 ;;;
1248 ;; * If NOSELECT is nil then calculate the `size' of the window for each file
1249 ;;;   by dividing the `window-height' by length of FILE-LIST.  Thus, `size' is
1250 ;;;   cognizant of the window-configuration.
1251 ;;;
1252 ;; * If `size' is too small abort, otherwise run `find-file' on each element
1253 ;;;   of FILE-LIST giving each a window of height `size'.
1254
1255 (defun dired-do-find-marked-files (&optional noselect)
1256   "Find all marked files displaying all of them simultaneously.
1257 With optional NOSELECT just find files but do not select them.
1258
1259 The current window is split across all files marked, as evenly as possible.
1260 Remaining lines go to bottom-most window.  The number of files that can be
1261 displayed this way is restricted by the height of the current window and
1262 `window-min-height'.
1263
1264 To keep Dired buffer displayed, type \\[split-window-below] first.
1265 To display just marked files, type \\[delete-other-windows] first."
1266   (interactive "P")
1267   (dired-simultaneous-find-file (dired-get-marked-files) noselect))
1268
1269 (defun dired-simultaneous-find-file (file-list noselect)
1270   "Visit all files in FILE-LIST and display them simultaneously.
1271 The current window is split across all files in FILE-LIST, as evenly as
1272 possible.  Remaining lines go to the bottom-most window.  The number of
1273 files that can be displayed this way is restricted by the height of the
1274 current window and the variable `window-min-height'.  With non-nil
1275 NOSELECT the files are merely found but not selected."
1276   ;; We don't make this function interactive because it is usually too clumsy
1277   ;; to specify FILE-LIST interactively unless via dired.
1278   (let (size)
1279     (if noselect
1280         ;; Do not select the buffer.
1281         (find-file-noselect (car file-list))
1282       ;; We will have to select the buffer.  Calculate and check window size.
1283       (setq size (/ (window-height) (length file-list)))
1284       (or (<= window-min-height size)
1285           (error "Too many files to visit simultaneously.  Try C-u prefix"))
1286       (find-file (car file-list)))
1287     ;; Decrement.
1288     (dolist (file (cdr file-list))
1289       (if noselect
1290           ;; Do not select the buffer.
1291           (find-file-noselect file)
1292         ;; Vertically split off a window of desired size.  Upper window will
1293         ;; have SIZE lines.  Select lower (larger) window.  We split it again.
1294         (select-window (split-window nil size))
1295         (find-file file)))))
1296
1297 \f
1298 ;;; MISCELLANEOUS COMMANDS.
1299
1300 ;; Run man on files.
1301
1302 (declare-function Man-getpage-in-background "man" (topic))
1303
1304 (defvar manual-program) ; from man.el
1305
1306 (defun dired-man ()
1307   "Run `man' on this file."
1308 ;; Used also to say: "Display old buffer if buffer name matches filename."
1309 ;; but I have no idea what that means.
1310   (interactive)
1311   (require 'man)
1312   (let* ((file (dired-get-filename))
1313          (manual-program (replace-regexp-in-string "\\*" "%s"
1314                           (dired-guess-shell-command
1315                            "Man command: " (list file)))))
1316     (Man-getpage-in-background file)))
1317
1318 ;; Run Info on files.
1319
1320 (defun dired-info ()
1321   "Run `info' on this file."
1322   (interactive)
1323   (info (dired-get-filename)))
1324
1325 ;; Run mail on mail folders.
1326
1327 (declare-function vm-visit-folder "ext:vm" (folder &optional read-only))
1328 (defvar vm-folder-directory)
1329
1330 (defun dired-vm (&optional read-only)
1331   "Run VM on this file.
1332 With optional prefix argument, visits the folder read-only.
1333 Otherwise obeys the value of `dired-vm-read-only-folders'."
1334   (interactive "P")
1335   (let ((dir (dired-current-directory))
1336         (fil (dired-get-filename)))
1337     (vm-visit-folder fil (or read-only
1338                              (eq t dired-vm-read-only-folders)
1339                              (and dired-vm-read-only-folders
1340                                   (not (file-writable-p fil)))))
1341     ;; So that pressing `v' inside VM does prompt within current directory:
1342     (set (make-local-variable 'vm-folder-directory) dir)))
1343
1344 (defun dired-rmail ()
1345   "Run RMAIL on this file."
1346   (interactive)
1347   (rmail (dired-get-filename)))
1348
1349 (defun dired-do-run-mail ()
1350   "Visit the current file as a mailbox, using VM or RMAIL.
1351 Prompt for confirmation first; if the user says yes, call
1352 `dired-vm' if `dired-bind-vm' is non-nil, `dired-rmail'
1353 otherwise."
1354   (interactive)
1355   (let ((file (dired-get-filename t)))
1356     (if dired-bind-vm
1357         (if (y-or-n-p (format-message
1358                        "Visit `%s' as a mail folder with VM?" file))
1359             (dired-vm))
1360       ;; Read mail folder using rmail.
1361       (if (y-or-n-p (format-message
1362                      "Visit `%s' as a mailbox with RMAIL?" file))
1363           (dired-rmail)))))
1364
1365 \f
1366 ;;; MISCELLANEOUS INTERNAL FUNCTIONS.
1367
1368 ;; This should be a builtin
1369 (defun dired-buffer-more-recently-used-p (buffer1 buffer2)
1370   "Return t if BUFFER1 is more recently used than BUFFER2.
1371 Considers buffers closer to the car of `buffer-list' to be more recent."
1372   (and (not (equal buffer1 buffer2))
1373        (memq buffer1 (buffer-list))
1374        (not (memq buffer1 (memq buffer2 (buffer-list))))))
1375
1376 ;; Same thing as `dired-buffers-for-dir' of dired.el? - lrd 11/23/93
1377 ;; (defun dired-buffers-for-dir-exact (dir)
1378 ;; ;; Return a list of buffers that dired DIR (a directory or wildcard)
1379 ;; ;; at top level, or as subdirectory.
1380 ;; ;; Top level matches must match the wildcard part too, if any.
1381 ;; ;; The list is in reverse order of buffer creation, most recent last.
1382 ;; ;; As a side effect, killed dired buffers for DIR are removed from
1383 ;; ;; dired-buffers.
1384 ;;   (let ((alist dired-buffers) result elt)
1385 ;;     (while alist
1386 ;;       (setq elt (car alist)
1387 ;;             alist (cdr alist))
1388 ;;       (let ((buf (cdr elt)))
1389 ;;         (if (buffer-name buf)
1390 ;;             ;; Top level must match exactly against dired-directory in
1391 ;;             ;; case one of them is a wildcard.
1392 ;;             (if (or (equal dir (with-current-buffer buf dired-directory))
1393 ;;                     (assoc dir (with-current-buffer buf dired-subdir-alist)))
1394 ;;                 (setq result (cons buf result)))
1395 ;;           ;; else buffer is killed - clean up:
1396 ;;           (setq dired-buffers (delq elt dired-buffers)))))
1397 ;;     result))
1398
1399 \f
1400 ;; Needed if ls -lh is supported and also for GNU ls -ls.
1401 (defun dired-x--string-to-number (str)
1402   "Like `string-to-number' but recognize a trailing unit prefix.
1403 For example, 2K is expanded to 2048.0.  The caller should make
1404 sure that a trailing letter in STR is one of BKkMGTPEZY."
1405   (let* ((val (string-to-number str))
1406          (u (unless (zerop val)
1407               (aref str (1- (length str))))))
1408     (when (and u (> u ?9))
1409       (when (= u ?k)
1410         (setq u ?K))
1411       (let ((units '(?B ?K ?M ?G ?T ?P ?E ?Z ?Y)))
1412         (while (and units (/= (pop units) u))
1413           (setq val (* 1024.0 val)))))
1414     val))
1415
1416 ;; Does anyone use this? - lrd 6/29/93.
1417 ;; Apparently people do use it. - lrd 12/22/97.
1418
1419 (defun dired-mark-sexp (predicate &optional unflag-p)
1420   "Mark files for which PREDICATE returns non-nil.
1421 With a prefix arg, unmark or unflag those files instead.
1422
1423 PREDICATE is a lisp expression that can refer to the following symbols:
1424
1425     inode  [integer] the inode of the file (only for ls -i output)
1426     s      [integer] the size of the file for ls -s output
1427                      (usually in blocks or, with -k, in KByte)
1428     mode   [string]  file permission bits, e.g. \"-rw-r--r--\"
1429     nlink  [integer] number of links to file
1430     uid    [string]  owner
1431     gid    [string]  group  (If the gid is not displayed by ls,
1432                      this will still be set (to the same as uid))
1433     size   [integer] file size in bytes
1434     time   [string]  the time that ls displays, e.g. \"Feb 12 14:17\"
1435     name   [string]  the name of the file
1436     sym    [string]  if file is a symbolic link, the linked-to name, else \"\"
1437
1438 For example, use
1439
1440         (equal 0 size)
1441
1442 to mark all zero length files.
1443
1444 There's an ambiguity when a single integer not followed by a unit
1445 prefix precedes the file mode: It is then parsed as inode number
1446 and not as block size (this always works for GNU coreutils ls).
1447
1448 Another limitation is that the uid field is needed for the
1449 function to work correctly.  In particular, the field is not
1450 present for some values of `ls-lisp-emulation'.
1451
1452 This function operates only on the buffer content and does not
1453 refer at all to the underlying file system.  Contrast this with
1454 `find-dired', which might be preferable for the task at hand."
1455   ;; Using sym="" instead of nil avoids the trap of
1456   ;; (string-match "foo" sym) into which a user would soon fall.
1457   ;; Give `equal' instead of `=' in the example, as this works on
1458   ;; integers and strings.
1459   (interactive "xMark if (lisp expr): \nP")
1460   (message "%s" predicate)
1461   (let ((dired-marker-char (if unflag-p ?\040 dired-marker-char))
1462         inode s mode nlink uid gid size time name sym)
1463     (dired-mark-if
1464      (save-excursion
1465        (and
1466         ;; Sets vars
1467         ;;                inode s mode nlink uid gid size time name sym
1468
1469         ;; according to current file line.  Returns t for success, nil if
1470         ;; there is no file line.  Upon success, all variables are set, either
1471         ;; to nil or the appropriate value, so they need not be initialized.
1472         ;; Moves point within the current line.
1473         (dired-move-to-filename)
1474         (let ((mode-len 10) ; length of mode string
1475               ;; like in dired.el, but with subexpressions \1=inode, \2=s:
1476               ;; GNU ls -hs suffixes the block count with a unit and
1477               ;; prints it as a float, FreeBSD does neither.
1478               (dired-re-inode-size "\\=\\s *\\([0-9]+\\s +\\)?\
1479 \\(?:\\([0-9]+\\(?:\\.[0-9]*\\)?[BkKMGTPEZY]?\\)? ?\\)"))
1480           (beginning-of-line)
1481           (forward-char 2)
1482           (search-forward-regexp dired-re-inode-size nil t)
1483           ;; XXX Might be a size not followed by a unit prefix.
1484           ;; We could set s to inode if it were otherwise nil,
1485           ;; with a similar reasoning as below for setting gid to uid,
1486           ;; but it would be even more whimsical.
1487           (setq inode (when (match-string 1)
1488                         (string-to-number (match-string 1))))
1489           (setq s (when (match-string 2)
1490                     (dired-x--string-to-number (match-string 2))))
1491           (setq mode (buffer-substring (point) (+ mode-len (point))))
1492           (forward-char mode-len)
1493           ;; Skip any extended attributes marker ("." or "+").
1494           (or (looking-at " ")
1495               (forward-char 1))
1496           (setq nlink (read (current-buffer)))
1497           ;; Karsten Wenger <kw@cis.uni-muenchen.de> fixed uid.
1498           ;; Another issue is that GNU ls -n right-justifies numerical
1499           ;; UIDs and GIDs, while FreeBSD left-justifies them, so
1500           ;; don't rely on a specific whitespace layout.  Both of them
1501           ;; right-justify all other numbers, though.
1502           ;; XXX Return a number if the uid or gid seems to be
1503           ;; numerical?
1504           (setq uid (buffer-substring (progn
1505                                         (skip-chars-forward " \t")
1506                                         (point))
1507                                       (progn
1508                                         (skip-chars-forward "^ \t")
1509                                         (point))))
1510           (dired-move-to-filename)
1511           (save-excursion
1512             (setq time
1513                   ;; The regexp below tries to match from the last
1514                   ;; digit of the size field through a space after the
1515                   ;; date.  Also, dates may have different formats
1516                   ;; depending on file age, so the date column need
1517                   ;; not be aligned to the right.
1518                   (buffer-substring (save-excursion
1519                                       (skip-chars-backward " \t")
1520                                       (point))
1521                                     (progn
1522                                       (re-search-backward
1523                                        directory-listing-before-filename-regexp)
1524                                       (skip-chars-forward "^ \t")
1525                                       (1+ (point))))
1526                   size (dired-x--string-to-number
1527                         ;; We know that there's some kind of number
1528                         ;; before point because the regexp search
1529                         ;; above succeeded.  I don't think it's worth
1530                         ;; doing an extra check for leading garbage.
1531                         (buffer-substring (point)
1532                                           (progn
1533                                             (skip-chars-backward "^ \t")
1534                                             (point))))
1535                   ;; If no gid is displayed, gid will be set to uid
1536                   ;; but the user will then not reference it anyway in
1537                   ;; PREDICATE.
1538                   gid (buffer-substring (progn
1539                                           (skip-chars-backward " \t")
1540                                           (point))
1541                                         (progn
1542                                           (skip-chars-backward "^ \t")
1543                                           (point)))))
1544           (setq name (buffer-substring (point)
1545                                        (or
1546                                         (dired-move-to-end-of-filename t)
1547                                         (point)))
1548                 sym (if (looking-at " -> ")
1549                         (buffer-substring (progn (forward-char 4) (point))
1550                                           (line-end-position))
1551                       ""))
1552           t)
1553         (eval predicate
1554               `((inode . ,inode)
1555                 (s . ,s)
1556                 (mode . ,mode)
1557                 (nlink . ,nlink)
1558                 (uid . ,uid)
1559                 (gid . ,gid)
1560                 (size . ,size)
1561                 (time . ,time)
1562                 (name . ,name)
1563                 (sym . ,sym)))))
1564      (format "'%s file" predicate))))
1565
1566 \f
1567 ;;; FIND FILE AT POINT.
1568
1569 (defcustom dired-x-hands-off-my-keys t
1570   "Non-nil means don't remap `find-file' to `dired-x-find-file'.
1571 Similarly for `find-file-other-window' and `dired-x-find-file-other-window'.
1572 If you change this variable without using \\[customize] after `dired-x.el'
1573 is loaded then call \\[dired-x-bind-find-file]."
1574   :type 'boolean
1575   :initialize 'custom-initialize-default
1576   :set (lambda (symbol value)
1577          (set symbol value)
1578          (dired-x-bind-find-file))
1579   :group 'dired-x)
1580
1581 (defun dired-x-bind-find-file ()
1582   "Bind `dired-x-find-file' in place of `find-file' (or vice-versa).
1583 Similarly for `dired-x-find-file-other-window' and `find-file-other-window'.
1584 Binding direction based on `dired-x-hands-off-my-keys'."
1585   (interactive)
1586   (if (called-interactively-p 'interactive)
1587       (setq dired-x-hands-off-my-keys
1588             (not (y-or-n-p "Bind dired-x-find-file over find-file? "))))
1589   (define-key (current-global-map) [remap find-file]
1590     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file))
1591   (define-key (current-global-map) [remap find-file-other-window]
1592     (if (not dired-x-hands-off-my-keys) 'dired-x-find-file-other-window)))
1593
1594 ;; Now call it so binding is correct.  This could go in the :initialize
1595 ;; slot, but then dired-x-bind-find-file has to be defined before the
1596 ;; defcustom, and we get free variable warnings.
1597 (dired-x-bind-find-file)
1598
1599 (defun dired-x-find-file (filename)
1600   "Edit file FILENAME.
1601 Like `find-file', except that when called interactively with a
1602 prefix argument, it offers the filename near point as a default."
1603   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1604   (find-file filename))
1605
1606 (defun dired-x-find-file-other-window (filename)
1607   "Edit file FILENAME, in another window.
1608 Like `find-file-other-window', except that when called interactively with
1609 a prefix argument, when it offers the filename near point as a default."
1610   (interactive (list (dired-x-read-filename-at-point "Find file: ")))
1611   (find-file-other-window filename))
1612
1613 ;;; Internal functions.
1614
1615 ;; Fixme: This should probably use `thing-at-point'.  -- fx
1616 (defun dired-filename-at-point ()
1617   "Return the filename closest to point, expanded.
1618 Point should be in or after a filename."
1619   (save-excursion
1620     ;; First see if just past a filename.
1621     (or (eobp)                             ; why?
1622         (when (looking-at-p "[] \t\n[{}()]") ; whitespace or some parens
1623           (skip-chars-backward " \n\t\r({[]})")
1624           (or (bobp) (backward-char 1))))
1625     (let ((filename-chars "-.[:alnum:]_/:$+@")
1626           start prefix)
1627       (if (looking-at-p (format "[%s]" filename-chars))
1628           (progn
1629             (skip-chars-backward filename-chars)
1630             (setq start (point)
1631                   prefix
1632                   ;; This is something to do with ange-ftp filenames.
1633                   ;; It convert foo@bar to /foo@bar.
1634                   ;; But when does the former occur in dired buffers?
1635                   (and (string-match-p
1636                         "^\\w+@"
1637                         (buffer-substring start (line-end-position)))
1638                        "/"))
1639             (if (string-match-p "[/~]" (char-to-string (preceding-char)))
1640                 (setq start (1- start)))
1641             (skip-chars-forward filename-chars))
1642         (error "No file found around point!"))
1643       ;; Return string.
1644       (expand-file-name (concat prefix (buffer-substring start (point)))))))
1645
1646 (defun dired-x-read-filename-at-point (prompt)
1647   "Return filename prompting with PROMPT with completion.
1648 If `current-prefix-arg' is non-nil, uses name at point as guess."
1649   (if current-prefix-arg
1650       (let ((guess (dired-filename-at-point)))
1651         (read-file-name prompt
1652                         (file-name-directory guess)
1653                         guess
1654                         nil (file-name-nondirectory guess)))
1655     (read-file-name prompt default-directory)))
1656
1657 (define-obsolete-function-alias 'read-filename-at-point
1658   'dired-x-read-filename-at-point "24.1") ; is this even needed?
1659 \f
1660 ;;; BUG REPORTS
1661
1662 (define-obsolete-function-alias 'dired-x-submit-report 'report-emacs-bug "24.1")
1663
1664 \f
1665 ;; As Barry Warsaw would say: "This might be useful..."
1666 (provide 'dired-x)
1667
1668 ;; Local Variables:
1669 ;; byte-compile-dynamic: t
1670 ;; generated-autoload-file: "dired.el"
1671 ;; End:
1672
1673 ;;; dired-x.el ends here