lisp/cus-face.el

   1 ;;; cus-face.el --- customization support for faces
   2 ;;
   3 ;; Copyright (C) 1996-1997, 1999-2014 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: help, faces
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25 ;;
  26 ;; See `custom.el'.
  27
  28 ;;; Code:
  29
  30 (defalias 'custom-facep 'facep)
  31
  32 ;;; Declaring a face.
  33
  34 (defun custom-declare-face (face spec doc &rest args)
  35   "Like `defface', but with FACE evaluated as a normal argument."
  36   (unless (get face 'face-defface-spec)
  37     (face-spec-set face (purecopy spec) 'face-defface-spec)
  38     (push (cons 'defface face) current-load-list)
  39     (when doc
  40       (set-face-documentation face (purecopy doc)))
  41     (custom-handle-all-keywords face args 'custom-face)
  42     (run-hooks 'custom-define-hook))
  43   face)
  44
  45 ;;; Face attributes.
  46
  47 (defconst custom-face-attributes
  48   '((:family
  49      (string :tag "Font Family"
  50              :help-echo "Font family or fontset alias name."))
  51
  52     (:foundry
  53      (string :tag "Font Foundry"
  54              :help-echo "Font foundry name."))
  55
  56     (:width
  57      (choice :tag "Width"
  58              :help-echo "Font width."
  59              :value normal              ; default
  60              (const :tag "compressed" condensed)
  61              (const :tag "condensed" condensed)
  62              (const :tag "demiexpanded" semi-expanded)
  63              (const :tag "expanded" expanded)
  64              (const :tag "extracondensed" extra-condensed)
  65              (const :tag "extraexpanded" extra-expanded)
  66              (const :tag "medium" normal)
  67              (const :tag "narrow" condensed)
  68              (const :tag "normal" normal)
  69              (const :tag "regular" normal)
  70              (const :tag "semicondensed" semi-condensed)
  71              (const :tag "semiexpanded" semi-expanded)
  72              (const :tag "ultracondensed" ultra-condensed)
  73              (const :tag "ultraexpanded" ultra-expanded)
  74              (const :tag "wide" extra-expanded)))
  75
  76     (:height
  77      (choice :tag "Height"
  78              :help-echo "Face's font height."
  79              :value 1.0                 ; default
  80              (integer :tag "Height in 1/10 pt")
  81              (number :tag "Scale" 1.0)))
  82
  83     (:weight
  84      (choice :tag "Weight"
  85              :help-echo "Font weight."
  86              :value normal              ; default
  87              (const :tag "black" ultra-bold)
  88              (const :tag "bold" bold)
  89              (const :tag "book" semi-light)
  90              (const :tag "demibold" semi-bold)
  91              (const :tag "extralight" extra-light)
  92              (const :tag "extrabold" extra-bold)
  93              (const :tag "heavy" extra-bold)
  94              (const :tag "light" light)
  95              (const :tag "medium" normal)
  96              (const :tag "normal" normal)
  97              (const :tag "regular" normal)
  98              (const :tag "semibold" semi-bold)
  99              (const :tag "semilight" semi-light)
 100              (const :tag "ultralight" ultra-light)
 101              (const :tag "ultrabold" ultra-bold)
 102              (const :tag "thin" thin)))
 103
 104     (:slant
 105      (choice :tag "Slant"
 106              :help-echo "Font slant."
 107              :value normal              ; default
 108              (const :tag "italic" italic)
 109              (const :tag "oblique" oblique)
 110              (const :tag "normal" normal)
 111              (const :tag "roman" roman)))
 112
 113     (:underline
 114      (choice :tag "Underline"
 115              :help-echo "Control text underlining."
 116              (const :tag "Off" nil)
 117              (list :tag "On"
 118                    :value (:color foreground-color :style line)
 119                    (const :format "" :value :color)
 120                    (choice :tag "Color"
 121                            (const :tag "Foreground Color" foreground-color)
 122                            color)
 123                    (const :format "" :value :style)
 124                    (choice :tag "Style"
 125                            (const :tag "Line" line)
 126                            (const :tag "Wave" wave))))
 127      ;; filter to make value suitable for customize
 128      (lambda (real-value)
 129        (and real-value
 130             (let ((color
 131                    (or (and (consp real-value) (plist-get real-value :color))
 132                        (and (stringp real-value) real-value)
 133                        'foreground-color))
 134                   (style
 135                    (or (and (consp real-value) (plist-get real-value :style))
 136                        'line)))
 137               (list :color color :style style))))
 138      ;; filter to make customized-value suitable for storing
 139      (lambda (cus-value)
 140        (and cus-value
 141             (let ((color (plist-get cus-value :color))
 142                   (style (plist-get cus-value :style)))
 143               (cond ((eq style 'line)
 144                      ;; Use simple value for default style
 145                      (if (eq color 'foreground-color) t color))
 146                     (t
 147                      `(:color ,color :style ,style)))))))
 148
 149     (:overline
 150      (choice :tag "Overline"
 151              :help-echo "Control text overlining."
 152              (const :tag "Off" nil)
 153              (const :tag "On" t)
 154              (color :tag "Colored")))
 155
 156     (:strike-through
 157      (choice :tag "Strike-through"
 158              :help-echo "Control text strike-through."
 159              (const :tag "Off" nil)
 160              (const :tag "On" t)
 161              (color :tag "Colored")))
 162
 163     (:box
 164      ;; Fixme: this can probably be done better.
 165      (choice :tag "Box around text"
 166              :help-echo "Control box around text."
 167              (const :tag "Off" nil)
 168              (list :tag "Box"
 169                    :value (:line-width 2 :color "grey75" :style released-button)
 170                    (const :format "" :value :line-width)
 171                    (integer :tag "Width")
 172                    (const :format "" :value :color)
 173                    (choice :tag "Color" (const :tag "*" nil) color)
 174                    (const :format "" :value :style)
 175                    (choice :tag "Style"
 176                            (const :tag "Raised" released-button)
 177                            (const :tag "Sunken" pressed-button)
 178                            (const :tag "None" nil))))
 179      ;; filter to make value suitable for customize
 180      (lambda (real-value)
 181        (and real-value
 182             (let ((lwidth
 183                    (or (and (consp real-value)
 184                             (plist-get real-value :line-width))
 185                        (and (integerp real-value) real-value)
 186                        1))
 187                   (color
 188                    (or (and (consp real-value) (plist-get real-value :color))
 189                        (and (stringp real-value) real-value)
 190                        nil))
 191                   (style
 192                    (and (consp real-value) (plist-get real-value :style))))
 193               (list :line-width lwidth :color color :style style))))
 194      ;; filter to make customized-value suitable for storing
 195      (lambda (cus-value)
 196        (and cus-value
 197             (let ((lwidth (plist-get cus-value :line-width))
 198                   (color (plist-get cus-value :color))
 199                   (style (plist-get cus-value :style)))
 200               (cond ((and (null color) (null style))
 201                      lwidth)
 202                     ((and (null lwidth) (null style))
 203                      ;; actually can't happen, because LWIDTH is always an int
 204                      color)
 205                     (t
 206                      ;; Keep as a plist, but remove null entries
 207                      (nconc (and lwidth `(:line-width ,lwidth))
 208                             (and color  `(:color ,color))
 209                             (and style  `(:style ,style)))))))))
 210
 211     (:inverse-video
 212      (choice :tag "Inverse-video"
 213              :help-echo "Control whether text should be in inverse-video."
 214              (const :tag "Off" nil)
 215              (const :tag "On" t)))
 216
 217     (:foreground
 218      (color :tag "Foreground"
 219             :help-echo "Set foreground color (name or #RRGGBB hex spec)."))
 220
 221     (:background
 222      (color :tag "Background"
 223             :help-echo "Set background color (name or #RRGGBB hex spec)."))
 224
 225     (:stipple
 226      (choice :tag "Stipple"
 227              :help-echo "Background bit-mask"
 228              (const :tag "None" nil)
 229              (file :tag "File"
 230                    :help-echo "Name of bitmap file."
 231                    :must-match t)))
 232
 233     (:inherit
 234      (repeat :tag "Inherit"
 235              :help-echo "List of faces to inherit attributes from."
 236              (face :Tag "Face" default))
 237      ;; filter to make value suitable for customize
 238      (lambda (real-value)
 239        (cond ((or (null real-value) (eq real-value 'unspecified))
 240               nil)
 241              ((symbolp real-value)
 242               (list real-value))
 243              (t
 244               real-value)))
 245      ;; filter to make customized-value suitable for storing
 246      (lambda (cus-value)
 247        (if (and (consp cus-value) (null (cdr cus-value)))
 248            (car cus-value)
 249          cus-value))))
 250
 251   "Alist of face attributes.
 252
 253 The elements are of the form (KEY TYPE PRE-FILTER POST-FILTER),
 254 where KEY is the name of the attribute, TYPE is a widget type for
 255 editing the attribute, PRE-FILTER is a function to make the attribute's
 256 value suitable for the customization widget, and POST-FILTER is a
 257 function to make the customized value suitable for storing.  PRE-FILTER
 258 and POST-FILTER are optional.
 259
 260 The PRE-FILTER should take a single argument, the attribute value as
 261 stored, and should return a value for customization (using the
 262 customization type TYPE).
 263
 264 The POST-FILTER should also take a single argument, the value after
 265 being customized, and should return a value suitable for setting the
 266 given face attribute.")
 267
 268 (defun custom-face-attributes-get (face frame)
 269   "For FACE on FRAME, return an alternating list describing its attributes.
 270 The list has the form (KEYWORD VALUE KEYWORD VALUE...).
 271 Each keyword should be listed in `custom-face-attributes'.
 272
 273 If FRAME is nil, use the global defaults for FACE."
 274   (let ((attrs custom-face-attributes)
 275         plist)
 276     (while attrs
 277       (let* ((attribute (car (car attrs)))
 278              (value (face-attribute face attribute frame)))
 279         (setq attrs (cdr attrs))
 280         (unless (or (eq value 'unspecified)
 281                     (and (null value) (memq attribute '(:inherit))))
 282           (setq plist (cons attribute (cons value plist))))))
 283     plist))
 284
 285 ;;; Initializing.
 286
 287 (defun custom-set-faces (&rest args)
 288   "Apply a list of face specs for user customizations.
 289 This works by calling `custom-theme-set-faces' for the `user'
 290 theme, a special theme referring to settings made via Customize.
 291 The arguments should be a list where each entry has the form:
 292
 293   (FACE SPEC [NOW [COMMENT]])
 294
 295 See the documentation of `custom-theme-set-faces' for details."
 296   (apply 'custom-theme-set-faces 'user args))
 297
 298 (defun custom-theme-set-faces (theme &rest args)
 299   "Apply a list of face specs associated with theme THEME.
 300 THEME should be a theme name (a symbol).  The special theme named
 301 `user' refers to user settings applied via Customize.
 302
 303 The remaining ARGS should be a list where each entry is a list of
 304 the form:
 305
 306   (FACE SPEC [NOW [COMMENT]])
 307
 308 FACE should be a face name (a symbol).  If FACE is a face alias,
 309 the setting refers to the parent face.
 310
 311 SPEC should be a face spec.  For details, see `defface'.
 312
 313 NOW, if present and non-nil, forces the face settings to take
 314 immediate effect in the Emacs display; in particular, FACE is
 315 initialized as a face if it is not yet one.  If NOW is omitted or
 316 nil, the caller is responsible for making the settings take
 317 effect later, by calling `custom-theme-recalc-face' or
 318 `face-spec-recalc'.
 319
 320 COMMENT is a string comment about FACE.
 321
 322 This function works by calling `custom-push-theme' to record each
 323 SPEC in each FACE's `theme-face' property, and in THEME's
 324 `theme-settings' property.  If FACE has not already been
 325 customized, it also stores SPEC in the `saved-face' property.
 326
 327 If THEME has a non-nil `theme-immediate' property, this is
 328 equivalent to providing the NOW argument to all faces in the
 329 argument list."
 330   (custom-check-theme theme)
 331   (let ((immediate (get theme 'theme-immediate)))
 332     (dolist (entry args)
 333       (unless (listp entry)
 334         (error "Incompatible Custom theme spec"))
 335       (let ((face (car entry))
 336             (spec (nth 1 entry)))
 337         ;; If FACE is actually an alias, customize the face it
 338         ;; is aliased to.
 339         (if (get face 'face-alias)
 340             (setq face (get face 'face-alias)))
 341         (if custom--inhibit-theme-enable
 342             ;; Just update theme settings.
 343             (custom-push-theme 'theme-face face theme 'set spec)
 344           ;; Update theme settings and set the face spec.
 345           (let ((now (nth 2 entry))
 346                 (comment (nth 3 entry))
 347                 (oldspec (get face 'theme-face)))
 348             (when (not (and oldspec (eq 'user (caar oldspec))))
 349               (put face 'saved-face spec)
 350               (put face 'saved-face-comment comment))
 351             (custom-push-theme 'theme-face face theme 'set spec)
 352             (when (or now immediate)
 353               (put face 'force-face (if now 'rogue 'immediate)))
 354             (when (or now immediate (facep face))
 355               (put face 'face-comment comment)
 356               (face-spec-set face spec t))))))))
 357
 358 ;; XEmacs compatibility function.  In XEmacs, when you reset a Custom
 359 ;; Theme, you have to specify the theme to reset it to.  We just apply
 360 ;; the next theme.
 361 (defun custom-theme-reset-faces (theme &rest args)
 362   "Reset the specs in THEME of some faces to their specs in other themes.
 363 Each of the arguments ARGS has this form:
 364
 365     (FACE IGNORED)
 366
 367 This means reset FACE.  The argument IGNORED is ignored."
 368   (custom-check-theme theme)
 369   (dolist (arg args)
 370     (custom-push-theme 'theme-face (car arg) theme 'reset)))
 371
 372 (defun custom-reset-faces (&rest args)
 373   "Reset the specs of some faces to their specs in specified themes.
 374 This creates settings in the `user' theme.
 375
 376 Each of the arguments ARGS has this form:
 377
 378     (FACE FROM-THEME)
 379
 380 This means reset FACE to its value in FROM-THEME."
 381   (apply 'custom-theme-reset-faces 'user args))
 382
 383 ;;; The End.
 384
 385 (provide 'cus-face)
 386
 387 ;;; cus-face.el ends here