lisp/mail/rmailkwd.el

   1 ;;; rmailkwd.el --- part of the "RMAIL" mail reader for Emacs
   2
   3 ;; Copyright (C) 1985, 1988, 1994, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008, 2009  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (require 'rmail)
  29
  30 ;; Global to all RMAIL buffers.  It exists for the sake of completion.
  31 ;; It is better to use strings with the label functions and let them
  32 ;; worry about making the label.
  33 (defvar rmail-label-obarray (make-vector 47 0)
  34   "Obarray of labels used by Rmail.
  35 `rmail-read-label' uses this to offer completion.")
  36
  37 ;; Initialize with the standard labels.
  38 (mapc (lambda (s) (intern (cadr s) rmail-label-obarray))
  39       rmail-attr-array)
  40
  41 (defun rmail-make-label (s)
  42   "Intern string S as a downcased symbol in `rmail-label-obarray'."
  43   (intern (downcase s) rmail-label-obarray))
  44 \f
  45 ;;;###autoload
  46 (defun rmail-add-label (label)
  47   "Add LABEL to labels associated with current RMAIL message.
  48 Completes (see `rmail-read-label') over known labels when reading.
  49 LABEL may be a symbol or string.  Only one label is allowed."
  50   (interactive (list (rmail-read-label "Add label")))
  51   (rmail-set-label label t))
  52
  53 ;;;###autoload
  54 (defun rmail-kill-label (label)
  55   "Remove LABEL from labels associated with current RMAIL message.
  56 Completes (see `rmail-read-label') over known labels when reading.
  57 LABEL may be a symbol or string.  Only one label is allowed."
  58   (interactive (list (rmail-read-label "Remove label")))
  59   (rmail-set-label label nil))
  60
  61 ;;;###autoload
  62 (defun rmail-read-label (prompt)
  63   "Read a label with completion, prompting with PROMPT.
  64 Completions are chosen from `rmail-label-obarray'.  The default
  65 is `rmail-last-label', if that is non-nil.  Updates `rmail-last-label'
  66 according to the choice made, and returns a symbol."
  67   (let* ((old nil)
  68          (result
  69           (progn
  70             ;; If the summary exists, we've already read all the
  71             ;; existing labels.  If not, read the ones in this message.
  72             (or (eq major-mode 'rmail-summary-mode)
  73                 (rmail-summary-exists)
  74                 (and (setq old (rmail-get-keywords))
  75                      (mapc 'rmail-make-label (split-string old ", "))))
  76             (completing-read (concat prompt
  77                                      (if rmail-last-label
  78                                          (concat " (default "
  79                                                  (symbol-name rmail-last-label)
  80                                                  "): ")
  81                                        ": "))
  82                              rmail-label-obarray
  83                              nil
  84                              nil))))
  85     (if (string= result "")
  86         rmail-last-label
  87       (setq rmail-last-label (rmail-make-label result)))))
  88
  89 (declare-function rmail-summary-update-line "rmailsum" (n))
  90
  91 (defun rmail-set-label (label state &optional msg)
  92   "Set LABEL as present or absent according to STATE in message MSG.
  93 LABEL may be a symbol or string."
  94   (or (stringp label) (setq label (symbol-name label)))
  95   (if (string-match "," label)
  96       (error "More than one label specified"))
  97   (with-current-buffer rmail-buffer
  98     (rmail-maybe-set-message-counters)
  99     (or msg (setq msg rmail-current-message))
 100     ;; Force recalculation of summary for this message.
 101     (aset rmail-summary-vector (1- msg) nil)
 102     (let (attr-index)
 103       ;; Is this label an attribute?
 104       (dotimes (i (length rmail-attr-array))
 105         (if (string= (cadr (aref rmail-attr-array i)) label)
 106             (setq attr-index i)))
 107       (if attr-index
 108           ;; If so, set it as an attribute.
 109           (rmail-set-attribute attr-index state msg)
 110         ;; Is this keyword already present in msg's keyword list?
 111         (let* ((header (rmail-get-keywords msg))
 112                (regexp (concat ", " (regexp-quote label) ","))
 113                (present (not (null
 114                               (string-match regexp (concat ", " header ","))))))
 115           ;; If current state is not correct,
 116           (unless (eq present state)
 117             ;; either add it or delete it.
 118             (rmail-set-header
 119              rmail-keyword-header msg
 120              (if state
 121                  ;; Add this keyword at the end.
 122                  (if (and header (not (string= header "")))
 123                      (concat header ", " label)
 124                    label)
 125                ;; Delete this keyword.
 126                (let ((before (substring header 0
 127                                         (max 0 (- (match-beginning 0) 2))))
 128                      (after (substring header
 129                                        (min (length header)
 130                                             (- (match-end 0) 1)))))
 131                  (cond ((string= before "")
 132                         ;; If before and after both empty, delete the header.
 133                         (unless (string= after "")
 134                           after))
 135                        ((string= after "")
 136                         before)
 137                        (t (concat before ", " after))))))))))
 138     (if (rmail-summary-exists)
 139         (rmail-select-summary (rmail-summary-update-line msg)))
 140     (if (= msg rmail-current-message)
 141         (rmail-display-labels))))
 142 \f
 143 ;; Motion on messages with keywords.
 144
 145 ;;;###autoload
 146 (defun rmail-previous-labeled-message (n labels)
 147   "Show previous message with one of the labels LABELS.
 148 LABELS should be a comma-separated list of label names.
 149 If LABELS is empty, the last set of labels specified is used.
 150 With prefix argument N moves backward N messages with these labels."
 151   (interactive "p\nsMove to previous msg with labels: ")
 152   (rmail-next-labeled-message (- n) labels))
 153
 154 (declare-function mail-comma-list-regexp "mail-utils" (labels))
 155
 156 ;;;###autoload
 157 (defun rmail-next-labeled-message (n labels)
 158   "Show next message with one of the labels LABELS.
 159 LABELS should be a comma-separated list of label names.
 160 If LABELS is empty, the last set of labels specified is used.
 161 With prefix argument N moves forward N messages with these labels."
 162   ;; FIXME show the default in the prompt.
 163   (interactive "p\nsMove to next msg with labels: ")
 164   (if (string= labels "")
 165       (setq labels rmail-last-multi-labels))
 166   (or labels
 167       (error "No labels to find have been specified previously"))
 168   (set-buffer rmail-buffer)
 169   (setq rmail-last-multi-labels labels)
 170   (rmail-maybe-set-message-counters)
 171   (let ((lastwin rmail-current-message)
 172         (current rmail-current-message)
 173         (regexp (concat " \\("
 174                         (mail-comma-list-regexp labels)
 175                         "\\)\\(,\\|\\'\\)")))
 176     (while (and (> n 0) (< current rmail-total-messages))
 177       (setq current (1+ current))
 178       (if (string-match regexp (rmail-get-labels current))
 179           (setq lastwin current n (1- n))))
 180     (while (and (< n 0) (> current 1))
 181       (setq current (1- current))
 182       (if (string-match regexp (rmail-get-labels current))
 183           (setq lastwin current n (1+ n))))
 184     (if (< n 0)
 185         (error "No previous message with labels %s" labels)
 186       (if (> n 0)
 187           (error "No following message with labels %s" labels)
 188         (rmail-show-message-1 lastwin)))))
 189
 190 (provide 'rmailkwd)
 191
 192 ;; Local Variables:
 193 ;; generated-autoload-file: "rmail.el"
 194 ;; End:
 195
 196 ;; arch-tag: 1149979c-8e47-4333-9629-cf3dc887a6a7
 197 ;;; rmailkwd.el ends here