lisp/server.el

   1 ;;; server.el --- Lisp code for GNU Emacs running as server process.
   2
   3 ;; Copyright (C) 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
   6 ;; Keywords: processes
   7
   8 ;; Changes by peck@sun.com and by rms.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; This Lisp code is run in Emacs when it is to operate as
  29 ;;; a server for other processes.
  30
  31 ;;; Load this library and do M-x server-edit to enable Emacs as a server.
  32 ;;; Emacs runs the program ../arch-lib/emacsserver as a subprocess
  33 ;;; for communication with clients.  If there are no client buffers to edit,
  34 ;;; server-edit acts like (switch-to-buffer (other-buffer))
  35
  36 ;;; When some other program runs "the editor" to edit a file,
  37 ;;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  38 ;;; This program transmits the file names to Emacs through
  39 ;;; the server subprocess, and Emacs visits them and lets you edit them.
  40
  41 ;;; Note that any number of clients may dispatch files to emacs to be edited.
  42
  43 ;;; When you finish editing a Server buffer, again call server-edit
  44 ;;; to mark that buffer as done for the client and switch to the next
  45 ;;; Server buffer.  When all the buffers for a client have been edited
  46 ;;; and exited with server-edit, the client "editor" will return
  47 ;;; to the program that invoked it.
  48
  49 ;;; Your editing commands and Emacs's display output go to and from
  50 ;;; the terminal in the usual way.  Thus, server operation is possible
  51 ;;; only when Emacs can talk to the terminal at the time you invoke
  52 ;;; the client.  This is possible in four cases:
  53
  54 ;;; 1. On a window system, where Emacs runs in one window and the
  55 ;;; program that wants to use "the editor" runs in another.
  56
  57 ;;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  58 ;;; program that wants to use "the editor" runs on another.
  59
  60 ;;; 3. When the program that wants to use "the editor" is running
  61 ;;; as a subprocess of Emacs.
  62
  63 ;;; 4. On a system with job control, when Emacs is suspended, the program
  64 ;;; that wants to use "the editor" will stop and display
  65 ;;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  66 ;;; brought into the foreground for editing.  When done editing, Emacs is
  67 ;;; suspended again, and the client program is brought into the foreground.
  68
  69 ;;; The buffer local variable "server-buffer-clients" lists
  70 ;;; the clients who are waiting for this buffer to be edited.
  71 ;;; The global variable "server-clients" lists all the waiting clients,
  72 ;;; and which files are yet to be edited for each.
  73
  74 ;;; Code:
  75 \f
  76 (defvar server-program "emacsserver"
  77   "*The program to use as the edit server")
  78
  79 (defvar server-visit-hook nil
  80   "*List of hooks to call when switching to a buffer for the Emacs server.")
  81
  82 (defvar server-process nil
  83   "the current server process")
  84
  85 (defvar server-previous-string "")
  86
  87 (defvar server-clients nil
  88   "List of current server clients.
  89 Each element is (CLIENTID FILES...) where CLIENTID is a string
  90 that can be given to the server process to identify a client.
  91 When a buffer is marked as \"done\", it is removed from this list.")
  92
  93 (defvar server-buffer-clients nil
  94   "List of clientids for clients requesting editing of current buffer.")
  95 ;; Changing major modes should not erase this local.
  96 (put 'server-buffer-clients 'permanent-local t)
  97
  98 (defvar server-temp-file-regexp "^/tmp/Re\\|/draft$"
  99   "*Regexp which should match filenames of temporary files
 100 which are deleted and reused after each edit
 101 by the programs that invoke the emacs server.")
 102
 103 (make-variable-buffer-local 'server-buffer-clients)
 104 (put 'server-buffer-clients 'permanent-local t)
 105 (setq-default server-buffer-clients nil)
 106 (or (assq 'server-buffer-clients minor-mode-alist)
 107     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
 108
 109 ;; If a *server* buffer exists,
 110 ;; write STRING to it for logging purposes.
 111 (defun server-log (string)
 112   (if (get-buffer "*server*")
 113       (save-excursion
 114         (set-buffer "*server*")
 115         (goto-char (point-max))
 116         (insert string)
 117         (or (bobp) (newline)))))
 118
 119 (defun server-sentinel (proc msg)
 120   (cond ((eq (process-status proc) 'exit)
 121          (server-log (message "Server subprocess exited")))
 122         ((eq (process-status proc) 'signal)
 123          (server-log (message "Server subprocess killed")))))
 124
 125 ;;;###autoload
 126 (defun server-start (&optional leave-dead)
 127   "Allow this Emacs process to be a server for client processes.
 128 This starts a server communications subprocess through which
 129 client \"editors\" can send your editing commands to this Emacs job.
 130 To use the server, set up the program `etc/emacsclient' in the
 131 Emacs distribution as your standard \"editor\".
 132
 133 Prefix arg means just kill any existing server communications subprocess."
 134   (interactive "P")
 135   ;; kill it dead!
 136   (if server-process
 137       (progn
 138         (set-process-sentinel server-process nil)
 139         (condition-case () (delete-process server-process) (error nil))))
 140   (condition-case () (delete-file "~/.emacs_server") (error nil))
 141   ;; If we already had a server, clear out associated status.
 142   (while server-clients
 143     (let ((buffer (nth 1 (car server-clients))))
 144       (server-buffer-done buffer)))
 145   (if leave-dead
 146       nil
 147     (if server-process
 148         (server-log (message "Restarting server")))
 149     (setq server-process (start-process "server" nil server-program))
 150     (set-process-sentinel server-process 'server-sentinel)
 151     (set-process-filter server-process 'server-process-filter)
 152     (process-kill-without-query server-process)))
 153 \f
 154 ;Process a request from the server to edit some files.
 155 ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n"
 156 (defun server-process-filter (proc string)
 157   (server-log string)
 158   (setq string (concat server-previous-string string))
 159   (if (not (and (eq ?\n (aref string (1- (length string))))
 160                 (eq 0 (string-match "Client: " string))))
 161       ;; If input is not complete, save it for later.
 162       (setq server-previous-string string)
 163     ;; If it is complete, process it now, and discard what was saved.
 164     (setq string (substring string (match-end 0)))
 165     (setq server-previous-string "")
 166     (let ((client (list (substring string 0 (string-match " " string))))
 167           (files nil)
 168           (lineno 1))
 169       (setq string (substring string (match-end 0)))
 170       (while (string-match "[^ ]+ " string)
 171         (let ((arg
 172                (substring string (match-beginning 0) (1- (match-end 0)))))
 173           (setq string (substring string (match-end 0)))
 174           (if (string-match "\\`\\+[0-9]+\\'" arg)
 175               (setq lineno (read (substring arg 1)))
 176             (setq files
 177                   (cons (list arg lineno)
 178                         files))
 179             (setq lineno 1))))
 180       (server-visit-files files client)
 181       ;; CLIENT is now a list (CLIENTNUM BUFFERS...)
 182       (setq server-clients (cons client server-clients))
 183       (switch-to-buffer (nth 1 client))
 184       (message (substitute-command-keys
 185                 "When done with a buffer, type \\[server-edit].")))))
 186
 187 (defun server-visit-files (files client)
 188   "Finds FILES and returns the list CLIENT with the buffers nconc'd.
 189 FILES is an alist whose elements are (FILENAME LINENUMBER)."
 190   (let (client-record)
 191     (while files
 192       (save-excursion
 193         ;; If there is an existing buffer modified or the file is modified,
 194         ;; revert it.
 195         ;; If there is an existing buffer with deleted file, offer to write it.
 196         (let* ((filen (car (car files)))
 197                (obuf (get-file-buffer filen)))
 198           (if (and obuf (set-buffer obuf))
 199               (if (file-exists-p filen)
 200                   (if (or (not (verify-visited-file-modtime obuf))
 201                           (buffer-modified-p obuf))
 202                       (revert-buffer t nil))
 203                 (if (y-or-n-p
 204                      (concat "File no longer exists: "
 205                              filen
 206                              ", write buffer to file? "))
 207                     (write-file filen)))
 208             (set-buffer (find-file-noselect filen))
 209             (run-hooks 'server-visit-hook)))
 210         (goto-line (nth 1 (car files)))
 211         (setq server-buffer-clients (cons (car client) server-buffer-clients))
 212         (setq client-record (cons (current-buffer) client-record)))
 213         (setq files (cdr files)))
 214     (nconc client client-record)))
 215 \f
 216 (defun server-buffer-done (buffer)
 217   "Mark BUFFER as \"done\" for its client(s).
 218 Buries the buffer, and returns another server buffer
 219 as a suggestion for what to select next."
 220   (let ((running (eq (process-status server-process) 'run))
 221         (next-buffer nil)
 222         (old-clients server-clients))
 223     (while old-clients
 224       (let ((client (car old-clients)))
 225         (or next-buffer
 226             (setq next-buffer (nth 1 (memq buffer client))))
 227         (delq buffer client)
 228         ;; If client now has no pending buffers,
 229         ;; tell it that it is done, and forget it entirely.
 230         (if (cdr client) nil
 231           (if running
 232               (progn
 233                 (send-string server-process
 234                              (format "Close: %s Done\n" (car client)))
 235                 (server-log (format "Close: %s Done\n" (car client)))))
 236           (setq server-clients (delq client server-clients))))
 237       (setq old-clients (cdr old-clients)))
 238     (if (buffer-name buffer)
 239         (save-excursion
 240           (set-buffer buffer)
 241           (setq server-buffer-clients nil)))
 242     (bury-buffer buffer)
 243     next-buffer))
 244
 245 (defun server-temp-file-p (buffer)
 246   "Return non-nil if BUFFER contains a file considered temporary.
 247 These are files whose names suggest they are repeatedly
 248 reused to pass information to another program.
 249
 250 The variable `server-temp-file-regexp' controls which filenames
 251 are considered temporary."
 252   (and (buffer-file-name buffer)
 253        (string-match server-temp-file-regexp (buffer-file-name buffer))))
 254
 255 (defun server-done ()
 256   "Offer to save current buffer, mark it as \"done\" for clients.
 257 Then bury it, and return a suggested buffer to select next."
 258   (let ((buffer (current-buffer)))
 259     (if server-buffer-clients
 260         (progn
 261           (if (server-temp-file-p buffer)
 262               (progn (save-buffer)
 263                      (write-region (point-min) (point-max)
 264                                    (concat buffer-file-name "~"))
 265                      (kill-buffer buffer))
 266             (if (and (buffer-modified-p)
 267                      (y-or-n-p (concat "Save file " buffer-file-name "? ")))
 268                 (save-buffer buffer)))
 269           (server-buffer-done buffer)))))
 270 \f
 271 (defun server-edit (&optional arg)
 272   "Switch to next server editing buffer; say \"Done\" for current buffer.
 273 If a server buffer is current, it is marked \"done\" and optionally saved.
 274 When all of a client's buffers are marked as \"done\", the client is notified.
 275
 276 Temporary files such as MH <draft> files are always saved and backed up,
 277 no questions asked.  The variable `server-temp-file-regexp' controls
 278 which filenames are considered temporary.
 279
 280 If invoked with a prefix argument, or if there is no server process running,
 281 starts server process and that is all.  Invoked by \\[server-edit]."
 282
 283   (interactive "P")
 284   (if (or arg
 285           (not server-process)
 286           (memq (process-status server-process) '(signal exit)))
 287       (server-start nil)
 288     (server-switch-buffer (server-done))))
 289
 290 (defun server-switch-buffer (next-buffer)
 291   "Switch to another buffer, preferably one that has a client.
 292 Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it."
 293   (if next-buffer
 294       (if (and (bufferp next-buffer)
 295                (buffer-name next-buffer))
 296           (switch-to-buffer next-buffer)
 297         ;; If NEXT-BUFFER is a dead buffer,
 298         ;; remove the server records for it
 299         ;; and try the next surviving server buffer.
 300         (server-switch-buffer
 301          (server-buffer-done next-buffer)))
 302     (if server-clients
 303         (server-switch-buffer (nth 1 (car server-clients)))
 304       (switch-to-buffer (other-buffer)))))
 305
 306 (global-set-key "\C-x#" 'server-edit)
 307 \f
 308 (provide 'server)
 309
 310 ;;; server.el ends here