lisp/compare-w.el

   1 ;;; compare-w.el --- compare text between windows for Emacs.
   2
   3 ;; Copyright (C) 1986, 1989 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; This package provides one entry point, compare-windows.  It compares
  26 ;; text starting from point in two adjacent windows, advancing point
  27 ;; until it finds a difference.  Option variables permit you to ignore
  28 ;; whitespace differences, or case differences, or both.
  29
  30 ;;; Code:
  31
  32 (defvar compare-windows-whitespace " \t\n"
  33   "*String of characters considered whitespace for \\[compare-windows].
  34 Changes in whitespace are optionally ignored.
  35
  36 The value of `compare-windows-whitespace' may instead be a function; this
  37 function is called in each buffer, with point at the current scanning point.
  38 The function's job is to categorize any whitespace around (including before)
  39 point; it should also advance past any whitespace.
  40
  41 The function is passed one argument, the point where `compare-windows'
  42 was originally called; it should not consider any text before that point.
  43 If the function returns the same value for both buffers, then the
  44 whitespace is considered to match, and is skipped.")
  45
  46 (defvar compare-ignore-case nil
  47   "*Non-nil means \\[compare-windows] ignores case differences.")
  48
  49 ;;;###autoload
  50 (defun compare-windows (ignore-whitespace)
  51   "Compare text in current window with text in next window.
  52 Compares the text starting at point in each window,
  53 moving over text in each one as far as they match.
  54
  55 A prefix arg means ignore changes in whitespace.
  56 The variable `compare-windows-whitespace' controls how whitespace is skipped.
  57 If `compare-ignore-case' is non-nil, changes in case are also ignored."
  58   (interactive "P")
  59   (let* (p1 p2 maxp1 maxp2 b1 b2 w2
  60             success size
  61             (opoint1 (point))
  62             opoint2
  63             (skip-whitespace (if ignore-whitespace
  64                                  compare-windows-whitespace))
  65             (skip-whitespace-regexp (concat "[" skip-whitespace "]+")))
  66     (setq p1 (point) b1 (current-buffer))
  67     (setq w2 (next-window (selected-window)))
  68     (if (eq w2 (selected-window))
  69         (error "No other window"))
  70     (setq p2 (window-point w2)
  71           b2 (window-buffer w2))
  72     (setq opoint2 p2)
  73     (setq maxp1 (point-max))
  74     (save-excursion
  75       (set-buffer b2)
  76       (setq maxp2 (point-max)))
  77
  78     (setq success t)
  79     (while success
  80       (setq success nil)
  81       ;; if interrupted, show how far we've gotten
  82       (goto-char p1)
  83       (set-window-point w2 p2)
  84
  85       ;; If both buffers have whitespace next to point,
  86       ;; optionally skip over it.
  87
  88       (and skip-whitespace
  89            (save-excursion
  90              (let (p1a p2a w1 w2 result1 result2)
  91                (if (stringp skip-whitespace)
  92                    (progn
  93                      (if (not (eobp))
  94                          (skip-chars-backward skip-whitespace opoint1))
  95                      (and (looking-at skip-whitespace-regexp)
  96                           (setq p1a (match-end 0) result1 t)))
  97                  (setq result1 (funcall skip-whitespace opoint1))
  98                  (setq p1a (point)))
  99                (set-buffer b2)
 100                (goto-char p2)
 101                (if (stringp skip-whitespace)
 102                    (progn
 103                      (if (not (eobp))
 104                          (skip-chars-backward skip-whitespace opoint2))
 105                      (and (looking-at skip-whitespace-regexp)
 106                           (setq p2a (match-end 0) result2 t)))
 107                  (setq result2 (funcall skip-whitespace opoint2))
 108                  (setq p2a (point)))
 109                (and result1 result2 (eq result1 result2)
 110                     (setq p1 p1a
 111                           p2 p2a)))))
 112
 113       ;; Try advancing comparing 1000 chars at a time.
 114       ;; When that fails, go 500 chars at a time, and so on.
 115       (let ((size 1000)
 116             success-1
 117             (case-fold-search compare-ignore-case))
 118         (while (> size 0)
 119           (setq success-1 t)
 120           ;; Try comparing SIZE chars at a time, repeatedly, till that fails.
 121           (while success-1
 122             (setq size (min size (- maxp1 p1) (- maxp2 p2)))
 123             (setq success-1
 124                   (and (> size 0)
 125                        (= 0 (compare-buffer-substrings b2 p2 (+ size p2)
 126                                                        b1 p1 (+ size p1)))))
 127             (if success-1
 128                 (setq p1 (+ p1 size) p2 (+ p2 size)
 129                       success t)))
 130           ;; If SIZE chars don't match, try fewer.
 131           (setq size (/ size 2)))))
 132
 133     (goto-char p1)
 134     (set-window-point w2 p2)
 135     (if (= (point) opoint1)
 136         (ding))))
 137
 138 (provide 'compare-w)
 139
 140 ;;; compare-w.el ends here