lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Morten Welinder <terra@diku.dk>
   6 ;; Keywords: archives msdog editing major-mode
   7 ;; Favourite-brand-of-beer: None, I hate beer.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  29 ;; to files whose name end in ".arc"
  30 ;;
  31 ;; This code does not decode any files internally, although it does
  32 ;; understand the directory level of the archives.  For this reason,
  33 ;; you should expect this code to need more fiddling than tar-mode.el
  34 ;; (although it at present has fewer bugs :-)  In particular, I have
  35 ;; not tested this under Ms-Dog myself.
  36 ;; -------------------------------------
  37 ;; INTERACTION: arc-mode.el should play together with
  38 ;;
  39 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  40 ;;                to you) are handled by doing all updates on a local
  41 ;;                copy.  When you make changes to a remote file the
  42 ;;                changes will first take effect when the archive buffer
  43 ;;                is saved.  You will be warned about this.
  44 ;;
  45 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  46 ;;                conversion.
  47 ;;
  48 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  49 ;; such this could be fixed (but wouldn't be useful) by declaring such
  50 ;; archives to be "remote".  For the members this is a general Emacs
  51 ;; problem that 19.29's file formats may fix.
  52 ;; -------------------------------------
  53 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  54 ;; structure for handling just about anything is in place.
  55 ;;
  56 ;;                        Arc     Lzh     Zip     Zoo
  57 ;;                        --------------------------------
  58 ;; View listing           Intern  Intern  Intern  Intern
  59 ;; Extract member         Y       Y       Y       Y
  60 ;; Save changed member    Y       Y       Y       Y
  61 ;; Add new member         N       N       N       N
  62 ;; Delete member          Y       Y       Y       Y
  63 ;; Rename member          Y       Y       N       N
  64 ;; Chmod                  -       Y       Y       -
  65 ;; Chown                  -       Y       -       -
  66 ;; Chgrp                  -       Y       -       -
  67 ;;
  68 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  69 ;; on the first released version of this package.
  70 ;;
  71 ;; This code is partly based on tar-mode.el from Emacs.
  72 ;; -------------------------------------
  73 ;; ARCHIVE STRUCTURES:
  74 ;; (This is mostly for myself.)
  75 ;;
  76 ;; ARC         A series of (header,file).  No interactions among members.
  77 ;;
  78 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  79 ;;             interaction among members.
  80 ;;
  81 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  82 ;;             which is a series of (cheader) followed by an end-of-
  83 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  84 ;;             links to c-d.  cheaders link to lheaders which are basically
  85 ;;             cut-down versions of the cheaders.
  86 ;;
  87 ;; ZOO         An archive header followed by a series of (header,file).
  88 ;;             Each member header points to the next.  The archive is
  89 ;;             terminated by a bogus header with a zero next link.
  90 ;; -------------------------------------
  91 ;; HOOKS: `foo' means one the the supported archive types.
  92 ;;
  93 ;; archive-mode-hook
  94 ;; archive-foo-mode-hook
  95 ;; archive-extract-hooks
  96
  97 ;;; Code:
  98
  99 ;; -------------------------------------------------------------------------
 100 ;; Section: Configuration.
 101
 102 (defgroup archive nil
 103   "Simple editing of archives."
 104   :group 'data)
 105
 106 (defgroup archive-arc nil
 107   "ARC-specific options to archive."
 108   :group 'archive)
 109
 110 (defgroup archive-lzh nil
 111   "LZH-specific options to archive."
 112   :group 'archive)
 113
 114 (defgroup archive-zip nil
 115   "ZIP-specific options to archive."
 116   :group 'archive)
 117
 118 (defgroup archive-zoo nil
 119   "ZOO-specific options to archive."
 120   :group 'archive)
 121
 122 (defcustom archive-tmpdir
 123   (make-temp-name
 124    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 125                      temporary-file-directory))
 126   "*Directory for temporary files made by arc-mode.el"
 127   :type 'directory
 128   :group 'archive)
 129
 130 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 131   "*Regexp recognizing archive files names that are not local.
 132 A non-local file is one whose file name is not proper outside Emacs.
 133 A local copy of the archive will be used when updating."
 134   :type 'regexp
 135   :group 'archive)
 136
 137 (defcustom archive-extract-hooks nil
 138   "*Hooks to run when an archive member has been extracted."
 139   :type 'hook
 140   :group 'archive)
 141 ;; ------------------------------
 142 ;; Arc archive configuration
 143
 144 ;; We always go via a local file since there seems to be no reliable way
 145 ;; to extract to stdout without junk getting added.
 146 (defcustom archive-arc-extract
 147   '("arc" "x")
 148   "*Program and its options to run in order to extract an arc file member.
 149 Extraction should happen to the current directory.  Archive and member
 150 name will be added."
 151   :type '(list (string :tag "Program")
 152                 (repeat :tag "Options"
 153                         :inline t
 154                         (string :format "%v")))
 155   :group 'archive-arc)
 156
 157 (defcustom archive-arc-expunge
 158   '("arc" "d")
 159   "*Program and its options to run in order to delete arc file members.
 160 Archive and member names will be added."
 161   :type '(list (string :tag "Program")
 162                 (repeat :tag "Options"
 163                         :inline t
 164                         (string :format "%v")))
 165   :group 'archive-arc)
 166
 167 (defcustom archive-arc-write-file-member
 168   '("arc" "u")
 169   "*Program and its options to run in order to update an arc file member.
 170 Archive and member name will be added."
 171   :type '(list (string :tag "Program")
 172                 (repeat :tag "Options"
 173                         :inline t
 174                         (string :format "%v")))
 175   :group 'archive-arc)
 176 ;; ------------------------------
 177 ;; Lzh archive configuration
 178
 179 (defcustom archive-lzh-extract
 180   '("lha" "pq")
 181   "*Program and its options to run in order to extract an lzh file member.
 182 Extraction should happen to standard output.  Archive and member name will
 183 be added."
 184   :type '(list (string :tag "Program")
 185                 (repeat :tag "Options"
 186                         :inline t
 187                         (string :format "%v")))
 188   :group 'archive-lzh)
 189
 190 (defcustom archive-lzh-expunge
 191   '("lha" "d")
 192   "*Program and its options to run in order to delete lzh file members.
 193 Archive and member names will be added."
 194   :type '(list (string :tag "Program")
 195                 (repeat :tag "Options"
 196                         :inline t
 197                         (string :format "%v")))
 198   :group 'archive-lzh)
 199
 200 (defcustom archive-lzh-write-file-member
 201   '("lha" "a")
 202   "*Program and its options to run in order to update an lzh file member.
 203 Archive and member name will be added."
 204   :type '(list (string :tag "Program")
 205                 (repeat :tag "Options"
 206                         :inline t
 207                         (string :format "%v")))
 208   :group 'archive-lzh)
 209 ;; ------------------------------
 210 ;; Zip archive configuration
 211
 212 (defcustom archive-zip-use-pkzip (memq system-type '(ms-dos windows-nt))
 213   "*If non-nil then pkzip option are used instead of zip options.
 214 Only set to true for msdog systems!"
 215   :type 'boolean
 216   :group 'archive-zip)
 217
 218 (defcustom archive-zip-extract
 219   (if archive-zip-use-pkzip '("pkunzip" "-e" "-o-") '("unzip" "-qq" "-c"))
 220   "*Program and its options to run in order to extract a zip file member.
 221 Extraction should happen to standard output.  Archive and member name will
 222 be added.  If `archive-zip-use-pkzip' is non-nil then this program is
 223 expected to extract to a file junking the directory part of the name."
 224   :type '(list (string :tag "Program")
 225                 (repeat :tag "Options"
 226                         :inline t
 227                         (string :format "%v")))
 228   :group 'archive-zip)
 229
 230 ;; For several reasons the latter behaviour is not desirable in general.
 231 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 232 ;; existent.  (3) It tends to do funny things with other systems' file
 233 ;; names.
 234
 235 (defcustom archive-zip-expunge
 236   (if archive-zip-use-pkzip '("pkzip" "-d") '("zip" "-d" "-q"))
 237   "*Program and its options to run in order to delete zip file members.
 238 Archive and member names will be added."
 239   :type '(list (string :tag "Program")
 240                 (repeat :tag "Options"
 241                         :inline t
 242                         (string :format "%v")))
 243   :group 'archive-zip)
 244
 245 (defcustom archive-zip-update
 246   (if archive-zip-use-pkzip '("pkzip" "-u" "-P") '("zip" "-q"))
 247   "*Program and its options to run in order to update a zip file member.
 248 Options should ensure that specified directory will be put into the zip
 249 file.  Archive and member name will be added."
 250   :type '(list (string :tag "Program")
 251                 (repeat :tag "Options"
 252                         :inline t
 253                         (string :format "%v")))
 254   :group 'archive-zip)
 255
 256 (defcustom archive-zip-update-case
 257   (if archive-zip-use-pkzip archive-zip-update '("zip" "-q" "-k"))
 258   "*Program and its options to run in order to update a case fiddled zip member.
 259 Options should ensure that specified directory will be put into the zip file.
 260 Archive and member name will be added."
 261   :type '(list (string :tag "Program")
 262                 (repeat :tag "Options"
 263                         :inline t
 264                         (string :format "%v")))
 265   :group 'archive-zip)
 266
 267 (defcustom archive-zip-case-fiddle t
 268   "*If non-nil then zip file members may be down-cased.
 269 This case fiddling will only happen for members created by a system
 270 that uses caseless file names."
 271   :type 'boolean
 272   :group 'archive-zip)
 273 ;; ------------------------------
 274 ;; Zoo archive configuration
 275
 276 (defcustom archive-zoo-extract
 277   '("zoo" "xpq")
 278   "*Program and its options to run in order to extract a zoo file member.
 279 Extraction should happen to standard output.  Archive and member name will
 280 be added."
 281   :type '(list (string :tag "Program")
 282                 (repeat :tag "Options"
 283                         :inline t
 284                         (string :format "%v")))
 285   :group 'archive-zoo)
 286
 287 (defcustom archive-zoo-expunge
 288   '("zoo" "DqPP")
 289   "*Program and its options to run in order to delete zoo file members.
 290 Archive and member names will be added."
 291   :type '(list (string :tag "Program")
 292                 (repeat :tag "Options"
 293                         :inline t
 294                         (string :format "%v")))
 295   :group 'archive-zoo)
 296
 297 (defcustom archive-zoo-write-file-member
 298   '("zoo" "a")
 299   "*Program and its options to run in order to update a zoo file member.
 300 Archive and member name will be added."
 301   :type '(list (string :tag "Program")
 302                 (repeat :tag "Options"
 303                         :inline t
 304                         (string :format "%v")))
 305   :group 'archive-zoo)
 306 ;; -------------------------------------------------------------------------
 307 ;; Section: Variables
 308
 309 (defvar archive-subtype nil "*Symbol describing archive type.")
 310 (defvar archive-file-list-start nil "*Position of first contents line.")
 311 (defvar archive-file-list-end nil "*Position just after last contents line.")
 312 (defvar archive-proper-file-start nil "*Position of real archive's start.")
 313 (defvar archive-read-only nil "*Non-nil if the archive is read-only on disk.")
 314 (defvar archive-local-name nil "*Name of local copy of remote archive.")
 315 (defvar archive-mode-map nil "*Local keymap for archive mode listings.")
 316 (defvar archive-file-name-indent nil "*Column where file names start.")
 317
 318 (defvar archive-remote nil "*Non-nil if the archive is outside file system.")
 319 (make-variable-buffer-local 'archive-remote)
 320 (put 'archive-remote 'permanent-local t)
 321
 322 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 323 (make-variable-buffer-local 'archive-member-coding-system)
 324
 325 (defvar archive-alternate-display nil
 326   "*Non-nil when alternate information is shown.")
 327 (make-variable-buffer-local 'archive-alternate-display)
 328 (put 'archive-alternate-display 'permanent-local t)
 329
 330 (defvar archive-superior-buffer nil "*In archive members, points to archive.")
 331 (put 'archive-superior-buffer 'permanent-local t)
 332
 333 (defvar archive-subfile-mode nil "*Non-nil in archive member buffers.")
 334 (make-variable-buffer-local 'archive-subfile-mode)
 335 (put 'archive-subfile-mode 'permanent-local t)
 336
 337 (defvar archive-files nil
 338   "Vector of file descriptors.
 339 Each descriptor is a vector of the form
 340  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 341 (make-variable-buffer-local 'archive-files)
 342
 343 (defvar archive-lemacs
 344   (string-match "\\(Lucid\\|Xemacs\\)" emacs-version)
 345   "*Non-nil when running under under Lucid Emacs or Xemacs.")
 346 ;; -------------------------------------------------------------------------
 347 ;; Section: Support functions.
 348
 349 (defsubst archive-name (suffix)
 350   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 351
 352 (defun archive-l-e (str &optional len)
 353   "Convert little endian string/vector to integer.
 354 Alternatively, first argument may be a buffer position in the current buffer
 355 in which case a second argument, length, should be supplied."
 356   (if (stringp str)
 357       (setq len (length str))
 358     (setq str (buffer-substring str (+ str len))))
 359   (let ((result 0)
 360         (i 0))
 361     (while (< i len)
 362       (setq i (1+ i)
 363             result (+ (ash result 8) (aref str (- len i)))))
 364     result))
 365
 366 (defun archive-int-to-mode (mode)
 367   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------"
 368   (let ((str (make-string 10 ?-)))
 369     (or (zerop (logand 16384 mode)) (aset str 0 ?d))
 370     (or (zerop (logand  8192 mode)) (aset str 0 ?c)) ; completeness
 371     (or (zerop (logand   256 mode)) (aset str 1 ?r))
 372     (or (zerop (logand   128 mode)) (aset str 2 ?w))
 373     (or (zerop (logand    64 mode)) (aset str 3 ?x))
 374     (or (zerop (logand    32 mode)) (aset str 4 ?r))
 375     (or (zerop (logand    16 mode)) (aset str 5 ?w))
 376     (or (zerop (logand     8 mode)) (aset str 6 ?x))
 377     (or (zerop (logand     4 mode)) (aset str 7 ?r))
 378     (or (zerop (logand     2 mode)) (aset str 8 ?w))
 379     (or (zerop (logand     1 mode)) (aset str 9 ?x))
 380     (or (zerop (logand  1024 mode)) (aset str 3 (if (zerop (logand 64 mode))
 381                                                     ?S ?s)))
 382     (or (zerop (logand  2048 mode)) (aset str 6 (if (zerop (logand  8 mode))
 383                                                     ?S ?s)))
 384     str))
 385
 386 (defun archive-calc-mode (oldmode newmode &optional error)
 387   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 388 NEWMODE may be an octal number including a leading zero in which case it
 389 will become the new mode.\n
 390 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 391 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 392 If optional third argument ERROR is non-nil an error will be signaled if
 393 the mode is invalid.  If ERROR is nil then nil will be returned."
 394   (cond ((string-match "^0[0-7]*$" newmode)
 395          (let ((result 0)
 396                (len (length newmode))
 397                (i 1))
 398            (while (< i len)
 399              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 400                    i (1+ i)))
 401            (logior (logand oldmode 65024) result)))
 402         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 403          (let ((who 0)
 404                (result oldmode)
 405                (op (aref newmode (match-beginning 2)))
 406                (bits 0)
 407                (i (match-beginning 3)))
 408            (while (< i (match-end 3))
 409              (let ((rwx (aref newmode i)))
 410                (setq bits (logior bits (cond ((= rwx ?r)  292)
 411                                              ((= rwx ?w)  146)
 412                                              ((= rwx ?x)   73)
 413                                              ((= rwx ?s) 3072)
 414                                              ((= rwx ?t)  512)))
 415                      i (1+ i))))
 416            (while (< who (match-end 1))
 417              (let* ((whoc (aref newmode who))
 418                     (whomask (cond ((= whoc ?a) 4095)
 419                                    ((= whoc ?u) 1472)
 420                                    ((= whoc ?g) 2104)
 421                                    ((= whoc ?o)    7))))
 422                (if (= op ?=)
 423                    (setq result (logand result (lognot whomask))))
 424                (if (= op ?-)
 425                    (setq result (logand result (lognot (logand whomask bits))))
 426                  (setq result (logior result (logand whomask bits)))))
 427              (setq who (1+ who)))
 428            result))
 429         (t
 430          (if error
 431              (error "Invalid mode specification: %s" newmode)))))
 432
 433 (defun archive-dosdate (date)
 434   "Stringify dos packed DATE record."
 435   (let ((year (+ 1980 (logand (ash date -9) 127)))
 436         (month (logand (ash date -5) 15))
 437         (day (logand date 31)))
 438     (if (or (> month 12) (< month 1))
 439         ""
 440       (format "%2d-%s-%d"
 441               day
 442               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 443                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 444               year))))
 445
 446 (defun archive-dostime (time)
 447   "Stringify dos packed TIME record."
 448   (let ((hour (logand (ash time -11) 31))
 449         (minute (logand (ash time -5) 53))
 450         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 451     (format "%02d:%02d:%02d" hour minute second)))
 452
 453 ;;(defun archive-unixdate (low high)
 454 ;;  "Stringify unix (LOW HIGH) date."
 455 ;;  (let ((str (current-time-string (cons high low))))
 456 ;;    (format "%s-%s-%s"
 457 ;;          (substring str 8 9)
 458 ;;          (substring str 4 7)
 459 ;;          (substring str 20 24))))
 460
 461 ;;(defun archive-unixtime (low high)
 462 ;;  "Stringify unix (LOW HIGH) time."
 463 ;;  (let ((str (current-time-string (cons high low))))
 464 ;;    (substring str 11 19)))
 465
 466 (defun archive-get-lineno ()
 467   (if (>= (point) archive-file-list-start)
 468       (count-lines archive-file-list-start
 469                    (save-excursion (beginning-of-line) (point)))
 470     0))
 471
 472 (defun archive-get-descr (&optional noerror)
 473   "Return the descriptor vector for file at point.
 474 Does not signal an error if optional second argument NOERROR is non-nil."
 475   (let ((no (archive-get-lineno)))
 476     (if (and (>= (point) archive-file-list-start)
 477              (< no (length archive-files)))
 478         (let ((item (aref archive-files no)))
 479           (if (vectorp item)
 480               item
 481             (if (not noerror)
 482                 (error "Entry is not a regular member of the archive"))))
 483       (if (not noerror)
 484           (error "Line does not describe a member of the archive")))))
 485 ;; -------------------------------------------------------------------------
 486 ;; Section: the mode definition
 487
 488 ;;;###autoload
 489 (defun archive-mode (&optional force)
 490   "Major mode for viewing an archive file in a dired-like way.
 491 You can move around using the usual cursor motion commands.
 492 Letters no longer insert themselves.
 493 Type `e' to pull a file out of the archive and into its own buffer;
 494 or click mouse-2 on the file's line in the archive mode buffer.
 495
 496 If you edit a sub-file of this archive (as with the `e' command) and
 497 save it, the contents of that buffer will be saved back into the
 498 archive.
 499
 500 \\{archive-mode-map}"
 501   ;; This is not interactive because you shouldn't be turning this
 502   ;; mode on and off.  You can corrupt things that way.
 503   (if (zerop (buffer-size))
 504       ;; At present we cannot create archives from scratch
 505       (funcall default-major-mode)
 506     (if (and (not force) archive-files) nil
 507       (let* ((type (archive-find-type))
 508              (typename (copy-sequence (symbol-name type))))
 509         (aset typename 0 (upcase (aref typename 0)))
 510         (kill-all-local-variables)
 511         (make-local-variable 'archive-subtype)
 512         (setq archive-subtype type)
 513
 514         ;; Buffer contains treated image of file before the file contents
 515         (make-local-variable 'revert-buffer-function)
 516         (setq revert-buffer-function 'archive-mode-revert)
 517         (auto-save-mode 0)
 518
 519         ;; Remote archives are not written by a hook.
 520         (if archive-remote nil
 521           (make-local-variable 'write-contents-hooks)
 522           (add-hook 'write-contents-hooks 'archive-write-file))
 523
 524         (make-local-variable 'require-final-newline)
 525         (setq require-final-newline nil)
 526         (make-local-variable 'local-enable-local-variables)
 527         (setq local-enable-local-variables nil)
 528
 529         ;; Prevent loss of data when saving the file.
 530         (make-local-variable 'file-precious-flag)
 531         (setq file-precious-flag t)
 532
 533         (make-local-variable 'archive-read-only)
 534         ;; Archives which are inside other archives and whose
 535         ;; names are invalid for this OS, can't be written.
 536         (setq archive-read-only
 537               (or (not (file-writable-p (buffer-file-name)))
 538                   (and archive-subfile-mode
 539                        (string-match file-name-invalid-regexp
 540                                      (aref archive-subfile-mode 0)))))
 541
 542         ;; Should we use a local copy when accessing from outside Emacs?
 543         (make-local-variable 'archive-local-name)
 544
 545         ;; An archive can contain another archive whose name is invalid
 546         ;; on local filesystem.  Treat such archives as remote.
 547         (or archive-remote
 548             (setq archive-remote
 549                   (or (string-match archive-remote-regexp (buffer-file-name))
 550                       (string-match file-name-invalid-regexp
 551                                     (buffer-file-name)))))
 552
 553         (setq major-mode 'archive-mode)
 554         (setq mode-name (concat typename "-Archive"))
 555         ;; Run archive-foo-mode-hook and archive-mode-hook
 556         (run-hooks (archive-name "mode-hook") 'archive-mode-hook)
 557         (use-local-map archive-mode-map))
 558
 559       (make-local-variable 'archive-proper-file-start)
 560       (make-local-variable 'archive-file-list-start)
 561       (make-local-variable 'archive-file-list-end)
 562       (make-local-variable 'archive-file-name-indent)
 563       (archive-summarize nil)
 564       (setq buffer-read-only t))))
 565
 566 ;; Archive mode is suitable only for specially formatted data.
 567 (put 'archive-mode 'mode-class 'special)
 568 ;; -------------------------------------------------------------------------
 569 ;; Section: Key maps
 570
 571 (if archive-mode-map nil
 572   (setq archive-mode-map (make-keymap))
 573   (suppress-keymap archive-mode-map)
 574   (define-key archive-mode-map " " 'archive-next-line)
 575   (define-key archive-mode-map "a" 'archive-alternate-display)
 576   ;;(define-key archive-mode-map "c" 'archive-copy)
 577   (define-key archive-mode-map "d" 'archive-flag-deleted)
 578   (define-key archive-mode-map "\C-d" 'archive-flag-deleted)
 579   (define-key archive-mode-map "e" 'archive-extract)
 580   (define-key archive-mode-map "f" 'archive-extract)
 581   (define-key archive-mode-map "\C-m" 'archive-extract)
 582   (define-key archive-mode-map "g" 'revert-buffer)
 583   (define-key archive-mode-map "h" 'describe-mode)
 584   (define-key archive-mode-map "m" 'archive-mark)
 585   (define-key archive-mode-map "n" 'archive-next-line)
 586   (define-key archive-mode-map "\C-n" 'archive-next-line)
 587   (define-key archive-mode-map [down] 'archive-next-line)
 588   (define-key archive-mode-map "o" 'archive-extract-other-window)
 589   (define-key archive-mode-map "p" 'archive-previous-line)
 590   (define-key archive-mode-map "q" 'quit-window)
 591   (define-key archive-mode-map "\C-p" 'archive-previous-line)
 592   (define-key archive-mode-map [up] 'archive-previous-line)
 593   (define-key archive-mode-map "r" 'archive-rename-entry)
 594   (define-key archive-mode-map "u" 'archive-unflag)
 595   (define-key archive-mode-map "\M-\C-?" 'archive-unmark-all-files)
 596   (define-key archive-mode-map "v" 'archive-view)
 597   (define-key archive-mode-map "x" 'archive-expunge)
 598   (define-key archive-mode-map "\177" 'archive-unflag-backwards)
 599   (define-key archive-mode-map "E" 'archive-extract-other-window)
 600   (define-key archive-mode-map "M" 'archive-chmod-entry)
 601   (define-key archive-mode-map "G" 'archive-chgrp-entry)
 602   (define-key archive-mode-map "O" 'archive-chown-entry)
 603
 604   (if archive-lemacs
 605       (progn
 606         ;; Not a nice "solution" but it'll have to do
 607         (define-key archive-mode-map "\C-xu" 'archive-undo)
 608         (define-key archive-mode-map "\C-_" 'archive-undo))
 609     (substitute-key-definition 'undo 'archive-undo
 610                                archive-mode-map global-map))
 611
 612   (define-key archive-mode-map
 613     (if archive-lemacs 'button2 [mouse-2]) 'archive-mouse-extract)
 614
 615   (if archive-lemacs
 616       ()                                ; out of luck
 617     ;; Get rid of the Edit menu bar item to save space.
 618     (define-key archive-mode-map [menu-bar edit] 'undefined)
 619
 620     (define-key archive-mode-map [menu-bar immediate]
 621       (cons "Immediate" (make-sparse-keymap "Immediate")))
 622     (define-key archive-mode-map [menu-bar immediate alternate]
 623       '("Alternate Display" . archive-alternate-display))
 624     (put 'archive-alternate-display 'menu-enable
 625          '(boundp (archive-name "alternate-display")))
 626     (define-key archive-mode-map [menu-bar immediate view]
 627       '("View This File" . archive-view))
 628     (define-key archive-mode-map [menu-bar immediate display]
 629       '("Display in Other Window" . archive-display-other-window))
 630     (define-key archive-mode-map [menu-bar immediate find-file-other-window]
 631       '("Find in Other Window" . archive-extract-other-window))
 632     (define-key archive-mode-map [menu-bar immediate find-file]
 633       '("Find This File" . archive-extract))
 634
 635     (define-key archive-mode-map [menu-bar mark]
 636       (cons "Mark" (make-sparse-keymap "Mark")))
 637     (define-key archive-mode-map [menu-bar mark unmark-all]
 638       '("Unmark All" . archive-unmark-all-files))
 639     (define-key archive-mode-map [menu-bar mark deletion]
 640       '("Flag" . archive-flag-deleted))
 641     (define-key archive-mode-map [menu-bar mark unmark]
 642       '("Unflag" . archive-unflag))
 643     (define-key archive-mode-map [menu-bar mark mark]
 644       '("Mark" . archive-mark))
 645
 646     (define-key archive-mode-map [menu-bar operate]
 647       (cons "Operate" (make-sparse-keymap "Operate")))
 648     (define-key archive-mode-map [menu-bar operate chown]
 649       '("Change Owner..." . archive-chown-entry))
 650     (put 'archive-chown-entry 'menu-enable
 651          '(fboundp (archive-name "chown-entry")))
 652     (define-key archive-mode-map [menu-bar operate chgrp]
 653       '("Change Group..." . archive-chgrp-entry))
 654     (put 'archive-chgrp-entry 'menu-enable
 655          '(fboundp (archive-name "chgrp-entry")))
 656     (define-key archive-mode-map [menu-bar operate chmod]
 657       '("Change Mode..." . archive-chmod-entry))
 658     (put 'archive-chmod-entry 'menu-enable
 659          '(fboundp (archive-name "chmod-entry")))
 660     (define-key archive-mode-map [menu-bar operate rename]
 661       '("Rename to..." . archive-rename-entry))
 662     (put 'archive-rename-entry 'menu-enable
 663          '(fboundp (archive-name "rename-entry")))
 664     ;;(define-key archive-mode-map [menu-bar operate copy]
 665     ;;  '("Copy to..." . archive-copy))
 666     (define-key archive-mode-map [menu-bar operate expunge]
 667       '("Expunge Marked Files" . archive-expunge))
 668   ))
 669
 670 (let* ((item1 '(archive-subfile-mode " Archive"))
 671        (items (list item1)))
 672   (or (member item1 minor-mode-alist)
 673       (setq minor-mode-alist (append items minor-mode-alist))))
 674 ;; -------------------------------------------------------------------------
 675 (defun archive-find-type ()
 676   (widen)
 677   (goto-char (point-min))
 678   ;; The funny [] here make it unlikely that the .elc file will be treated
 679   ;; as an archive by other software.
 680   (let (case-fold-search)
 681     (cond ((looking-at "[P]K\003\004") 'zip)
 682           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 683           ((looking-at "....................[\334]\247\304\375") 'zoo)
 684           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 685                 (string-match "\\.[aA][rR][cC]$"
 686                               (or buffer-file-name (buffer-name))))
 687            'arc)
 688           (t (error "Buffer format not recognized.")))))
 689 ;; -------------------------------------------------------------------------
 690 (defun archive-summarize (&optional shut-up)
 691   "Parse the contents of the archive file in the current buffer.
 692 Place a dired-like listing on the front;
 693 then narrow to it, so that only that listing
 694 is visible (and the real data of the buffer is hidden).
 695 Optional argument SHUT-UP, if non-nil, means don't print messages
 696 when parsing the archive."
 697   (widen)
 698   (set-buffer-multibyte nil)
 699   (let (buffer-read-only)
 700     (or shut-up
 701         (message "Parsing archive file..."))
 702     (buffer-disable-undo (current-buffer))
 703     (setq archive-files (funcall (archive-name "summarize")))
 704     (or shut-up
 705         (message "Parsing archive file...done."))
 706     (setq archive-proper-file-start (point-marker))
 707     (narrow-to-region (point-min) (point))
 708     (set-buffer-modified-p nil)
 709     (buffer-enable-undo))
 710   (goto-char archive-file-list-start)
 711   (archive-next-line 0))
 712
 713 (defun archive-resummarize ()
 714   "Recreate the contents listing of an archive."
 715   (let ((modified (buffer-modified-p))
 716         (no (archive-get-lineno))
 717         buffer-read-only)
 718     (widen)
 719     (delete-region (point-min) archive-proper-file-start)
 720     (archive-summarize t)
 721     (set-buffer-modified-p modified)
 722     (goto-char archive-file-list-start)
 723     (archive-next-line no)))
 724
 725 (defun archive-summarize-files (files)
 726   "Insert a description of a list of files annotated with proper mouse face."
 727   (setq archive-file-list-start (point-marker))
 728   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 729   ;; We don't want to do an insert for each element since that takes too
 730   ;; long when the archive -- which has to be moved in memory -- is large.
 731   (insert
 732    (apply
 733     (function concat)
 734     (mapcar
 735      (function
 736       (lambda (fil)
 737         ;; Using `concat' here copies the text also, so we can add
 738         ;; properties without problems.
 739         (let ((text (concat (aref fil 0) "\n")))
 740           (if archive-lemacs
 741               ()                        ; out of luck
 742             (put-text-property (aref fil 1) (aref fil 2)
 743                                'mouse-face 'highlight
 744                                text))
 745           text)))
 746      files)))
 747   (setq archive-file-list-end (point-marker)))
 748
 749 (defun archive-alternate-display ()
 750   "Toggle alternative display.
 751 To avoid very long lines some archive mode don't show all information.
 752 This function changes the set of information shown for each files."
 753   (interactive)
 754   (setq archive-alternate-display (not archive-alternate-display))
 755   (archive-resummarize))
 756 ;; -------------------------------------------------------------------------
 757 ;; Section: Local archive copy handling
 758
 759 (defun archive-unique-fname (fname dir)
 760   "Make sure a file FNAME can be created uniquely in directory DIR.
 761
 762 If FNAME can be uniquely created in DIR, it is returned unaltered.
 763 If FNAME is something our underlying filesystem can't grok, or if another
 764 file by that name already exists in DIR, a unique new name is generated
 765 using `make-temp-name', and the generated name is returned."
 766   (let ((fullname (expand-file-name fname dir))
 767         (alien (string-match file-name-invalid-regexp fname)))
 768     (if (or alien (file-exists-p fullname))
 769         (make-temp-name
 770          (expand-file-name
 771           (if (and (eq system-type 'ms-dos) (not (msdos-long-file-names)))
 772               "am"
 773             "arc-mode.")
 774           dir))
 775       fullname)))
 776
 777 (defun archive-maybe-copy (archive)
 778   (let ((coding-system-for-write 'no-conversion))
 779     (if archive-remote
 780         (let ((start (point-max))
 781               ;; Sometimes ARCHIVE is invalid while its actual name, as
 782               ;; recorded in its parent archive, is not.  For example, an
 783               ;; archive bar.zip inside another archive foo.zip gets a name
 784               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 785               ;; So use the actual name if available.
 786               (archive-name
 787                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 788                    archive)))
 789           (make-directory archive-tmpdir t)
 790           (setq archive-local-name
 791                 (archive-unique-fname archive-name archive-tmpdir))
 792           (save-restriction
 793             (widen)
 794             (write-region start (point-max) archive-local-name nil 'nomessage))
 795           archive-local-name)
 796       (if (buffer-modified-p) (save-buffer))
 797       archive)))
 798
 799 (defun archive-maybe-update (unchanged)
 800   (if archive-remote
 801       (let ((name archive-local-name)
 802             (modified (buffer-modified-p))
 803             (coding-system-for-read 'no-conversion)
 804             (lno (archive-get-lineno))
 805             buffer-read-only)
 806         (if unchanged nil
 807           (setq archive-files nil)
 808           (erase-buffer)
 809           (insert-file-contents name)
 810           (archive-mode t)
 811           (goto-char archive-file-list-start)
 812           (archive-next-line lno))
 813         (archive-delete-local name)
 814         (if (not unchanged)
 815             (message
 816              "Buffer `%s' must be saved for changes to take effect"
 817              (buffer-name (current-buffer))))
 818         (set-buffer-modified-p (or modified (not unchanged))))))
 819
 820 (defun archive-delete-local (name)
 821   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 822   (let ((again t)
 823         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 824     (condition-case nil
 825         (delete-file name)
 826       (error nil))
 827     (while again
 828       (setq name (directory-file-name (file-name-directory name)))
 829       (condition-case nil
 830           (delete-directory name)
 831         (error nil))
 832       (if (string= name top) (setq again nil)))))
 833 ;; -------------------------------------------------------------------------
 834 ;; Section: Member extraction
 835
 836 (defun archive-file-name-handler (op &rest args)
 837   (or (eq op 'file-exists-p)
 838       (let ((file-name-handler-alist nil))
 839         (apply op args))))
 840
 841 (defun archive-set-buffer-as-visiting-file (filename)
 842   "Set the current buffer as if it were visiting FILENAME."
 843   (save-excursion
 844     (goto-char (point-min))
 845     (let ((coding
 846            (or coding-system-for-read
 847                (and set-auto-coding-function
 848                     (save-excursion
 849                       (funcall set-auto-coding-function
 850                                filename (- (point-max) (point-min)))))
 851                ;; dos-w32.el defines find-operation-coding-system for
 852                ;; DOS/Windows systems which preserves the coding-system
 853                ;; of existing files.  We want it to act here as if the
 854                ;; extracted file existed.
 855                (let ((file-name-handler-alist
 856                       '(("" . archive-file-name-handler))))
 857                  (car (find-operation-coding-system 'insert-file-contents
 858                                                     filename t))))))
 859       (if (and (not coding-system-for-read)
 860                (not enable-multibyte-characters))
 861           (setq coding
 862                 (coding-system-change-text-conversion coding 'raw-text)))
 863       (if (and coding
 864                (not (eq coding 'no-conversion)))
 865           (decode-coding-region (point-min) (point-max) coding)
 866         (setq last-coding-system-used coding))
 867       (set-buffer-modified-p nil)
 868       (kill-local-variable 'buffer-file-coding-system)
 869       (after-insert-file-set-buffer-file-coding-system (- (point-max)
 870                                                           (point-min))))))
 871
 872 (defun archive-mouse-extract (event)
 873   "Extract a file whose name you click on."
 874   (interactive "e")
 875   (mouse-set-point event)
 876   (switch-to-buffer
 877    (save-excursion
 878      (archive-extract)
 879      (current-buffer))))
 880
 881 (defun archive-extract (&optional other-window-p)
 882   "In archive mode, extract this entry of the archive into its own buffer."
 883   (interactive)
 884   (let* ((view-p (eq other-window-p 'view))
 885          (descr (archive-get-descr))
 886          (ename (aref descr 0))
 887          (iname (aref descr 1))
 888          (archive-buffer (current-buffer))
 889          (arcdir default-directory)
 890          (archive (buffer-file-name))
 891          (arcname (file-name-nondirectory archive))
 892          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 893          (extractor (archive-name "extract"))
 894          ;; Members with file names which aren't valid for the
 895          ;; underlying filesystem, are treated as read-only.
 896          (read-only-p (or archive-read-only
 897                           view-p
 898                           (string-match file-name-invalid-regexp ename)))
 899          (buffer (get-buffer bufname))
 900          (just-created nil))
 901       (if buffer
 902           nil
 903         (setq archive (archive-maybe-copy archive))
 904         (setq buffer (get-buffer-create bufname))
 905         (setq just-created t)
 906         (save-excursion
 907           (set-buffer buffer)
 908           (setq buffer-file-name
 909                 (expand-file-name (concat arcname ":" iname)))
 910           (setq buffer-file-truename
 911                 (abbreviate-file-name buffer-file-name))
 912           ;; Set the default-directory to the dir of the superior buffer.
 913           (setq default-directory arcdir)
 914           (make-local-variable 'archive-superior-buffer)
 915           (setq archive-superior-buffer archive-buffer)
 916           (make-local-variable 'local-write-file-hooks)
 917           (add-hook 'local-write-file-hooks 'archive-write-file-member)
 918           (setq archive-subfile-mode descr)
 919           (if (and
 920                (null
 921                 (let (;; We may have to encode file name arguement for
 922                       ;; external programs.
 923                       (coding-system-for-write
 924                        (and enable-multibyte-characters
 925                             file-name-coding-system))
 926                       ;; We read an archive member by no-conversion at
 927                       ;; first, then decode appropriately by calling
 928                       ;; archive-set-buffer-as-visiting-file later.
 929                       (coding-system-for-read 'no-conversion))
 930                   (condition-case err
 931                       (if (fboundp extractor)
 932                           (funcall extractor archive ename)
 933                         (archive-*-extract archive ename
 934                                            (symbol-value extractor)))
 935                     (error
 936                      (ding (message "%s" (error-message-string err)))
 937                      nil))))
 938                just-created)
 939               (progn
 940                 (set-buffer-modified-p nil)
 941                 (kill-buffer buffer))
 942             (archive-set-buffer-as-visiting-file ename)
 943             (goto-char (point-min))
 944             (rename-buffer bufname)
 945             (setq buffer-read-only read-only-p)
 946             (setq buffer-undo-list nil)
 947             (set-buffer-modified-p nil)
 948             (setq buffer-saved-size (buffer-size))
 949             (normal-mode)
 950             ;; Just in case an archive occurs inside another archive.
 951             (if (eq major-mode 'archive-mode)
 952                 (progn
 953                   (setq archive-remote t)
 954                   (if read-only-p (setq archive-read-only t))
 955                   ;; We will write out the archive ourselves if it is
 956                   ;; part of another archive.
 957                   (remove-hook 'write-contents-hooks 'archive-write-file t)))
 958             (run-hooks 'archive-extract-hooks)
 959             (if archive-read-only
 960                 (message "Note: altering this archive is not implemented."))))
 961         (archive-maybe-update t))
 962       (or (not (buffer-name buffer))
 963           (progn
 964             (if view-p
 965                 (view-buffer buffer (and just-created 'kill-buffer))
 966               (if (eq other-window-p 'display)
 967                   (display-buffer buffer)
 968                 (if other-window-p
 969                     (switch-to-buffer-other-window buffer)
 970                   (switch-to-buffer buffer))))))))
 971
 972 (defun archive-*-extract (archive name command)
 973   (let* ((default-directory (file-name-as-directory archive-tmpdir))
 974          (tmpfile (expand-file-name (file-name-nondirectory name)
 975                                     default-directory))
 976          exit-status success)
 977     (make-directory (directory-file-name default-directory) t)
 978     (setq exit-status
 979           (apply 'call-process
 980                  (car command)
 981                  nil
 982                  nil
 983                  nil
 984                  (append (cdr command) (list archive name))))
 985     (cond ((and (numberp exit-status) (= exit-status 0))
 986            (if (not (file-exists-p tmpfile))
 987                (ding (message "`%s': no such file or directory" tmpfile))
 988              (insert-file-contents tmpfile)
 989              (setq success t)))
 990           ((numberp exit-status)
 991            (ding
 992             (message "`%s' exited with status %d" (car command) exit-status)))
 993           ((stringp exit-status)
 994            (ding (message "`%s' aborted: %s" (car command) exit-status)))
 995           (t
 996            (ding (message "`%s' failed" (car command)))))
 997     (archive-delete-local tmpfile)
 998     success))
 999
1000 (defun archive-extract-by-stdout (archive name command)
1001   (apply 'call-process
1002          (car command)
1003          nil
1004          t
1005          nil
1006          (append (cdr command) (list archive name))))
1007
1008 (defun archive-extract-other-window ()
1009   "In archive mode, find this member in another window."
1010   (interactive)
1011   (archive-extract t))
1012
1013 (defun archive-display-other-window ()
1014   "In archive mode, display this member in another window."
1015   (interactive)
1016   (archive-extract 'display))
1017
1018 (defun archive-view ()
1019   "In archive mode, view the member on this line."
1020   (interactive)
1021   (archive-extract 'view))
1022
1023 (defun archive-add-new-member (arcbuf name)
1024   "Add current buffer to the archive in ARCBUF naming it NAME."
1025   (interactive
1026    (list (get-buffer
1027           (read-buffer "Buffer containing archive: "
1028                        ;; Find first archive buffer and suggest that
1029                        (let ((bufs (buffer-list)))
1030                          (while (and bufs (not (eq (save-excursion
1031                                                      (set-buffer (car bufs))
1032                                                      major-mode)
1033                                                    'archive-mode)))
1034                            (setq bufs (cdr bufs)))
1035                          (if bufs
1036                              (car bufs)
1037                            (error "There are no archive buffers")))
1038                        t))
1039          (read-string "File name in archive: "
1040                       (if buffer-file-name
1041                           (file-name-nondirectory buffer-file-name)
1042                         ""))))
1043   (save-excursion
1044     (set-buffer arcbuf)
1045     (or (eq major-mode 'archive-mode)
1046         (error "Buffer is not an archive buffer"))
1047     (if archive-read-only
1048         (error "Archive is read-only")))
1049   (if (eq arcbuf (current-buffer))
1050       (error "An archive buffer cannot be added to itself"))
1051   (if (string= name "")
1052       (error "Archive members may not be given empty names"))
1053   (let ((func (save-excursion (set-buffer arcbuf)
1054                               (archive-name "add-new-member")))
1055         (membuf (current-buffer)))
1056     (if (fboundp func)
1057         (save-excursion
1058           (set-buffer arcbuf)
1059           (funcall func buffer-file-name membuf name))
1060       (error "Adding a new member is not supported for this archive type"))))
1061 ;; -------------------------------------------------------------------------
1062 ;; Section: IO stuff
1063
1064 (defun archive-write-file-member ()
1065   (save-excursion
1066     (save-restriction
1067       (message "Updating archive...")
1068       (widen)
1069       (let ((writer  (save-excursion (set-buffer archive-superior-buffer)
1070                                      (archive-name "write-file-member")))
1071             (archive (save-excursion (set-buffer archive-superior-buffer)
1072                                      (archive-maybe-copy (buffer-file-name)))))
1073         (if (fboundp writer)
1074             (funcall writer archive archive-subfile-mode)
1075           (archive-*-write-file-member archive
1076                                        archive-subfile-mode
1077                                        (symbol-value writer)))
1078         (set-buffer-modified-p nil)
1079         (message "Updating archive...done"))
1080       (set-buffer archive-superior-buffer)
1081       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1082   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1083   ;; won't reset the coding-system of this archive member.
1084   (if (local-variable-p 'archive-member-coding-system)
1085       (setq last-coding-system-used archive-member-coding-system))
1086   t)
1087
1088 (defun archive-*-write-file-member (archive descr command)
1089   (let* ((ename (aref descr 0))
1090          (tmpfile (expand-file-name ename archive-tmpdir))
1091          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1092          (default-directory (file-name-as-directory top)))
1093     (unwind-protect
1094         (progn
1095           (make-directory (file-name-directory tmpfile) t)
1096           ;; If the member is itself an archive, write it without
1097           ;; the dired-like listing we created.
1098           (if (eq major-mode 'archive-mode)
1099               (archive-write-file tmpfile)
1100             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1101           ;; basic-save-buffer needs last-coding-system-used to have
1102           ;; the value used to write the file, so save it before any
1103           ;; further processing clobbers it (we restore it in
1104           ;; archive-write-file-member, above).
1105           (setq archive-member-coding-system last-coding-system-used)
1106           (if (aref descr 3)
1107               ;; Set the file modes, but make sure we can read it.
1108               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1109           (if enable-multibyte-characters
1110               (setq ename
1111                     (encode-coding-string ename file-name-coding-system)))
1112           (let ((exitcode (apply 'call-process
1113                                  (car command)
1114                                  nil
1115                                  nil
1116                                  nil
1117                                  (append (cdr command) (list archive ename)))))
1118             (if (equal exitcode 0)
1119                 nil
1120               (error "Updating was unsuccessful (%S)" exitcode))))
1121       (archive-delete-local tmpfile))))
1122
1123 (defun archive-write-file (&optional file)
1124   (save-excursion
1125     (let ((coding-system-for-write 'no-conversion))
1126       (write-region archive-proper-file-start (point-max)
1127                     (or file buffer-file-name) nil t)
1128       (set-buffer-modified-p nil))
1129     t))
1130 ;; -------------------------------------------------------------------------
1131 ;; Section: Marking and unmarking.
1132
1133 (defun archive-flag-deleted (p &optional type)
1134   "In archive mode, mark this member to be deleted from the archive.
1135 With a prefix argument, mark that many files."
1136   (interactive "p")
1137   (or type (setq type ?D))
1138   (beginning-of-line)
1139   (let ((sign (if (>= p 0) +1 -1))
1140         (modified (buffer-modified-p))
1141         buffer-read-only)
1142     (while (not (zerop p))
1143       (if (archive-get-descr t)
1144           (progn
1145             (delete-char 1)
1146             (insert type)))
1147       (forward-line sign)
1148       (setq p (- p sign)))
1149     (set-buffer-modified-p modified))
1150   (archive-next-line 0))
1151
1152 (defun archive-unflag (p)
1153   "In archive mode, un-mark this member if it is marked to be deleted.
1154 With a prefix argument, un-mark that many files forward."
1155   (interactive "p")
1156   (archive-flag-deleted p ? ))
1157
1158 (defun archive-unflag-backwards (p)
1159   "In archive mode, un-mark this member if it is marked to be deleted.
1160 With a prefix argument, un-mark that many members backward."
1161   (interactive "p")
1162   (archive-flag-deleted (- p) ? ))
1163
1164 (defun archive-unmark-all-files ()
1165   "Remove all marks."
1166   (interactive)
1167   (let ((modified (buffer-modified-p))
1168         buffer-read-only)
1169     (save-excursion
1170       (goto-char archive-file-list-start)
1171       (while (< (point) archive-file-list-end)
1172         (or (= (following-char) ? )
1173             (progn (delete-char 1) (insert ? )))
1174         (forward-line 1)))
1175     (set-buffer-modified-p modified)))
1176
1177 (defun archive-mark (p)
1178   "In archive mode, mark this member for group operations.
1179 With a prefix argument, mark that many members.
1180 Use \\[archive-unmark-all-files] to remove all marks."
1181   (interactive "p")
1182   (archive-flag-deleted p ?*))
1183
1184 (defun archive-get-marked (mark &optional default)
1185   (let (files)
1186     (save-excursion
1187       (goto-char archive-file-list-start)
1188       (while (< (point) archive-file-list-end)
1189         (if (= (following-char) mark)
1190             (setq files (cons (archive-get-descr) files)))
1191         (forward-line 1)))
1192     (or (nreverse files)
1193         (and default
1194              (list (archive-get-descr))))))
1195 ;; -------------------------------------------------------------------------
1196 ;; Section: Operate
1197
1198 (defun archive-next-line (p)
1199   (interactive "p")
1200   (forward-line p)
1201   (or (eobp)
1202       (forward-char archive-file-name-indent)))
1203
1204 (defun archive-previous-line (p)
1205   (interactive "p")
1206   (archive-next-line (- p)))
1207
1208 (defun archive-chmod-entry (new-mode)
1209   "Change the protection bits associated with all marked or this member.
1210 The new protection bits can either be specified as an octal number or
1211 as a relative change like \"g+rw\" as for chmod(2)"
1212   (interactive "sNew mode (octal or relative): ")
1213   (if archive-read-only (error "Archive is read-only"))
1214   (let ((func (archive-name "chmod-entry")))
1215     (if (fboundp func)
1216         (progn
1217           (funcall func new-mode (archive-get-marked ?* t))
1218           (archive-resummarize))
1219       (error "Setting mode bits is not supported for this archive type"))))
1220
1221 (defun archive-chown-entry (new-uid)
1222   "Change the owner of all marked or this member."
1223   (interactive "nNew uid: ")
1224   (if archive-read-only (error "Archive is read-only"))
1225   (let ((func (archive-name "chown-entry")))
1226     (if (fboundp func)
1227         (progn
1228           (funcall func new-uid (archive-get-marked ?* t))
1229           (archive-resummarize))
1230       (error "Setting owner is not supported for this archive type"))))
1231
1232 (defun archive-chgrp-entry (new-gid)
1233   "Change the group of all marked or this member."
1234   (interactive "nNew gid: ")
1235   (if archive-read-only (error "Archive is read-only"))
1236   (let ((func (archive-name "chgrp-entry")))
1237     (if (fboundp func)
1238         (progn
1239           (funcall func new-gid (archive-get-marked ?* t))
1240           (archive-resummarize))
1241       (error "Setting group is not supported for this archive type"))))
1242
1243 (defun archive-expunge ()
1244   "Do the flagged deletions."
1245   (interactive)
1246   (let (files)
1247     (save-excursion
1248       (goto-char archive-file-list-start)
1249       (while (< (point) archive-file-list-end)
1250         (if (= (following-char) ?D)
1251             (setq files (cons (aref (archive-get-descr) 0) files)))
1252         (forward-line 1)))
1253     (setq files (nreverse files))
1254     (and files
1255          (or (not archive-read-only)
1256              (error "Archive is read-only"))
1257          (or (yes-or-no-p (format "Really delete %d member%s? "
1258                                   (length files)
1259                                   (if (null (cdr files)) "" "s")))
1260              (error "Operation aborted"))
1261          (let ((archive (archive-maybe-copy (buffer-file-name)))
1262                (expunger (archive-name "expunge")))
1263            (if (fboundp expunger)
1264                (funcall expunger archive files)
1265              (archive-*-expunge archive files (symbol-value expunger)))
1266            (archive-maybe-update nil)
1267            (if archive-remote
1268                (archive-resummarize)
1269              (revert-buffer))))))
1270
1271 (defun archive-*-expunge (archive files command)
1272   (apply 'call-process
1273          (car command)
1274          nil
1275          nil
1276          nil
1277          (append (cdr command) (cons archive files))))
1278
1279 (defun archive-rename-entry (newname)
1280   "Change the name associated with this entry in the tar file."
1281   (interactive "sNew name: ")
1282   (if archive-read-only (error "Archive is read-only"))
1283   (if (string= newname "")
1284       (error "Archive members may not be given empty names"))
1285   (let ((func (archive-name "rename-entry"))
1286         (descr (archive-get-descr)))
1287     (if (fboundp func)
1288         (progn
1289           (funcall func (buffer-file-name)
1290                    (if enable-multibyte-characters
1291                        (encode-coding-string newname file-name-coding-system)
1292                      newname)
1293                    descr)
1294           (archive-resummarize))
1295       (error "Renaming is not supported for this archive type"))))
1296
1297 ;; Revert the buffer and recompute the dired-like listing.
1298 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1299   (let ((no (archive-get-lineno)))
1300     (setq archive-files nil)
1301     (let ((revert-buffer-function nil)
1302           (coding-system-for-read 'no-conversion))
1303       (set-buffer-multibyte nil)
1304       (revert-buffer t t))
1305     (archive-mode)
1306     (goto-char archive-file-list-start)
1307     (archive-next-line no)))
1308
1309 (defun archive-undo ()
1310   "Undo in an archive buffer.
1311 This doesn't recover lost files, it just undoes changes in the buffer itself."
1312   (interactive)
1313   (let (buffer-read-only)
1314     (undo)))
1315 ;; -------------------------------------------------------------------------
1316 ;; Section: Arc Archives
1317
1318 (defun archive-arc-summarize ()
1319   (let ((p 1)
1320         (totalsize 0)
1321         (maxlen 8)
1322         files
1323         visual)
1324     (while (and (< (+ p 29) (point-max))
1325                 (= (char-after p) ?\C-z)
1326                 (> (char-after (1+ p)) 0))
1327       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1328              (fnlen   (or (string-match "\0" namefld) 13))
1329              (efnname (substring namefld 0 fnlen))
1330              (csize   (archive-l-e (+ p 15) 4))
1331              (moddate (archive-l-e (+ p 19) 2))
1332              (modtime (archive-l-e (+ p 21) 2))
1333              (ucsize  (archive-l-e (+ p 25) 4))
1334              (fiddle  (string= efnname (upcase efnname)))
1335              (ifnname (if fiddle (downcase efnname) efnname))
1336              (text    (format "  %8d  %-11s  %-8s  %s"
1337                               ucsize
1338                               (archive-dosdate moddate)
1339                               (archive-dostime modtime)
1340                               ifnname)))
1341         (setq maxlen (max maxlen fnlen)
1342               totalsize (+ totalsize ucsize)
1343               visual (cons (vector text
1344                                    (- (length text) (length ifnname))
1345                                    (length text))
1346                            visual)
1347               files (cons (vector efnname ifnname fiddle nil (1- p))
1348                           files)
1349               p (+ p 29 csize))))
1350     (goto-char (point-min))
1351     (let ((dash (concat "- --------  -----------  --------  "
1352                         (make-string maxlen ?-)
1353                         "\n")))
1354       (insert "M   Length  Date         Time      File\n"
1355               dash)
1356       (archive-summarize-files (nreverse visual))
1357       (insert dash
1358               (format "  %8d                         %d file%s"
1359                       totalsize
1360                       (length files)
1361                       (if (= 1 (length files)) "" "s"))
1362               "\n"))
1363     (apply 'vector (nreverse files))))
1364
1365 (defun archive-arc-rename-entry (archive newname descr)
1366   (if (string-match "[:\\\\/]" newname)
1367       (error "File names in arc files may not contain a path"))
1368   (if (> (length newname) 12)
1369       (error "File names in arc files are limited to 12 characters"))
1370   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1371                                          (length newname))))
1372         buffer-read-only)
1373     (save-restriction
1374       (save-excursion
1375         (widen)
1376         (set-buffer-multibyte nil)
1377         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1378         (delete-char 13)
1379         (insert name)))))
1380 ;; -------------------------------------------------------------------------
1381 ;; Section: Lzh Archives
1382
1383 (defun archive-lzh-summarize ()
1384   (let ((p 1)
1385         (totalsize 0)
1386         (maxlen 8)
1387         files
1388         visual)
1389     (while (progn (goto-char p)
1390                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1391       (let* ((hsize   (char-after p))
1392              (csize   (archive-l-e (+ p 7) 4))
1393              (ucsize  (archive-l-e (+ p 11) 4))
1394              (modtime (archive-l-e (+ p 15) 2))
1395              (moddate (archive-l-e (+ p 17) 2))
1396              (hdrlvl  (char-after (+ p 20)))
1397              (fnlen   (char-after (+ p 21)))
1398              (efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen))))
1399                         (if file-name-coding-system
1400                             (decode-coding-string str file-name-coding-system)
1401                           (string-as-multibyte str))))
1402              (fiddle  (string= efnname (upcase efnname)))
1403              (ifnname (if fiddle (downcase efnname) efnname))
1404              (width (string-width ifnname))
1405              (p2      (+ p 22 fnlen))
1406              (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1407              mode modestr uid gid text path prname
1408              )
1409         (if (= hdrlvl 0)
1410             (setq mode    (if (= creator ?U) (archive-l-e (+ p2 8) 2) ?\666)
1411                   uid     (if (= creator ?U) (archive-l-e (+ p2 10) 2))
1412                   gid     (if (= creator ?U) (archive-l-e (+ p2 12) 2)))
1413           (if (= creator ?U)
1414               (let* ((p3 (+ p2 3))
1415                      (hsize (archive-l-e p3 2))
1416                      (etype (char-after (+ p3 2))))
1417                 (while (not (= hsize 0))
1418                   (cond
1419                    ((= etype 2) (let ((i (+ p3 3)))
1420                                   (while (< i (+ p3 hsize))
1421                                     (setq path (concat path
1422                                                        (if (= (char-after i)
1423                                                               255)
1424                                                            "/"
1425                                                          (char-to-string
1426                                                           (char-after i)))))
1427                                     (setq i (1+ i)))))
1428                    ((= etype 80) (setq mode (archive-l-e (+ p3 3) 2)))
1429                    ((= etype 81) (progn (setq uid (archive-l-e (+ p3 3) 2))
1430                                         (setq gid (archive-l-e (+ p3 5) 2))))
1431                    )
1432                   (setq p3 (+ p3 hsize))
1433                   (setq hsize (archive-l-e p3 2))
1434                   (setq etype (char-after (+ p3 2)))))))
1435         (setq prname (if path (concat path ifnname) ifnname))
1436         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1437         (setq text    (if archive-alternate-display
1438                           (format "  %8d  %5S  %5S  %s"
1439                                   ucsize
1440                                   (or uid "?")
1441                                   (or gid "?")
1442                                   ifnname)
1443                         (format "  %10s  %8d  %-11s  %-8s  %s"
1444                                 modestr
1445                                 ucsize
1446                                 (archive-dosdate moddate)
1447                                 (archive-dostime modtime)
1448                                 ifnname)))
1449         (setq maxlen (max maxlen width)
1450               totalsize (+ totalsize ucsize)
1451               visual (cons (vector text
1452                                    (- (length text) (length ifnname))
1453                                    (length text))
1454                            visual)
1455               files (cons (vector prname ifnname fiddle mode (1- p))
1456                           files)
1457               p (+ p hsize 2 csize))))
1458     (goto-char (point-min))
1459     (set-buffer-multibyte default-enable-multibyte-characters)
1460     (let ((dash (concat (if archive-alternate-display
1461                             "- --------  -----  -----  "
1462                           "- ----------  --------  -----------  --------  ")
1463                         (make-string maxlen ?-)
1464                         "\n"))
1465           (header (if archive-alternate-display
1466                        "M   Length    Uid    Gid  File\n"
1467                     "M   Filemode    Length  Date         Time      File\n"))
1468           (sumline (if archive-alternate-display
1469                        "  %8d                %d file%s"
1470                      "              %8d                         %d file%s")))
1471       (insert header dash)
1472       (archive-summarize-files (nreverse visual))
1473       (insert dash
1474               (format sumline
1475                       totalsize
1476                       (length files)
1477                       (if (= 1 (length files)) "" "s"))
1478               "\n"))
1479     (apply 'vector (nreverse files))))
1480
1481 (defconst archive-lzh-alternate-display t)
1482
1483 (defun archive-lzh-extract (archive name)
1484   (archive-extract-by-stdout archive name archive-lzh-extract))
1485
1486 (defun archive-lzh-resum (p count)
1487   (let ((sum 0))
1488     (while (> count 0)
1489       (setq count (1- count)
1490             sum (+ sum (char-after p))
1491             p (1+ p)))
1492     (logand sum 255)))
1493
1494 (defun archive-lzh-rename-entry (archive newname descr)
1495   (save-restriction
1496     (save-excursion
1497       (widen)
1498       (set-buffer-multibyte nil)
1499       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1500              (oldhsize (char-after p))
1501              (oldfnlen (char-after (+ p 21)))
1502              (newfnlen (length newname))
1503              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1504              buffer-read-only)
1505         (if (> newhsize 255)
1506             (error "The file name is too long"))
1507         (goto-char (+ p 21))
1508         (delete-char (1+ oldfnlen))
1509         (insert newfnlen newname)
1510         (goto-char p)
1511         (delete-char 2)
1512         (insert newhsize (archive-lzh-resum p newhsize))))))
1513
1514 (defun archive-lzh-ogm (newval files errtxt ofs)
1515   (save-restriction
1516     (save-excursion
1517       (widen)
1518       (set-buffer-multibyte nil)
1519       (while files
1520         (let* ((fil (car files))
1521                (p (+ archive-proper-file-start (aref fil 4)))
1522                (hsize   (char-after p))
1523                (fnlen   (char-after (+ p 21)))
1524                (p2      (+ p 22 fnlen))
1525                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1526                buffer-read-only)
1527           (if (= creator ?U)
1528               (progn
1529                 (or (numberp newval)
1530                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1531                 (goto-char (+ p2 ofs))
1532                 (delete-char 2)
1533                 (insert (logand newval 255) (lsh newval -8))
1534                 (goto-char (1+ p))
1535                 (delete-char 1)
1536                 (insert (archive-lzh-resum (1+ p) hsize)))
1537             (message "Member %s does not have %s field"
1538                      (aref fil 1) errtxt)))
1539         (setq files (cdr files))))))
1540
1541 (defun archive-lzh-chown-entry (newuid files)
1542   (archive-lzh-ogm newuid files "an uid" 10))
1543
1544 (defun archive-lzh-chgrp-entry (newgid files)
1545   (archive-lzh-ogm newgid files "a gid" 12))
1546
1547 (defun archive-lzh-chmod-entry (newmode files)
1548   (archive-lzh-ogm
1549    ;; This should work even though newmode will be dynamically accessed.
1550    (function (lambda (old) (archive-calc-mode old newmode t)))
1551    files "a unix-style mode" 8))
1552 ;; -------------------------------------------------------------------------
1553 ;; Section: Zip Archives
1554
1555 (defun archive-zip-summarize ()
1556   (goto-char (- (point-max) (- 22 18)))
1557   (search-backward-regexp "[P]K\005\006")
1558   (let ((p (1+ (archive-l-e (+ (point) 16) 4)))
1559         (maxlen 8)
1560         (totalsize 0)
1561         files
1562         visual)
1563     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1564       (let* ((creator (char-after (+ p 5)))
1565              (method  (archive-l-e (+ p 10) 2))
1566              (modtime (archive-l-e (+ p 12) 2))
1567              (moddate (archive-l-e (+ p 14) 2))
1568              (ucsize  (archive-l-e (+ p 24) 4))
1569              (fnlen   (archive-l-e (+ p 28) 2))
1570              (exlen   (archive-l-e (+ p 30) 2))
1571              (fclen   (archive-l-e (+ p 32) 2))
1572              (lheader (archive-l-e (+ p 42) 4))
1573              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1574                         (if file-name-coding-system
1575                             (decode-coding-string str file-name-coding-system)
1576                           (string-as-multibyte str))))
1577              (isdir   (and (= ucsize 0)
1578                            (string= (file-name-nondirectory efnname) "")))
1579              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1580                              (archive-l-e (+ p 40) 2))
1581                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1582                              (logior ?\444
1583                                      (if isdir (logior 16384 ?\111) 0)
1584                                      (if (zerop
1585                                           (logand 1 (char-after (+ p 38))))
1586                                          ?\222 0)))
1587                             (t nil)))
1588              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1589              (fiddle  (and archive-zip-case-fiddle
1590                            (not (not (memq creator '(0 2 4 5 9))))
1591                            (string= (upcase efnname) efnname)))
1592              (ifnname (if fiddle (downcase efnname) efnname))
1593              (width (string-width ifnname))
1594              (text    (format "  %10s  %8d  %-11s  %-8s  %s"
1595                               modestr
1596                               ucsize
1597                               (archive-dosdate moddate)
1598                               (archive-dostime modtime)
1599                               ifnname)))
1600         (setq maxlen (max maxlen width)
1601               totalsize (+ totalsize ucsize)
1602               visual (cons (vector text
1603                                    (- (length text) (length ifnname))
1604                                    (length text))
1605                            visual)
1606               files (cons (if isdir
1607                               nil
1608                             (vector efnname ifnname fiddle mode
1609                                     (list (1- p) lheader)))
1610                           files)
1611               p (+ p 46 fnlen exlen fclen))))
1612     (goto-char (point-min))
1613     (let ((dash (concat "- ----------  --------  -----------  --------  "
1614                         (make-string maxlen ?-)
1615                         "\n")))
1616       (insert "M Filemode      Length  Date         Time      File\n"
1617               dash)
1618       (archive-summarize-files (nreverse visual))
1619       (insert dash
1620               (format "              %8d                         %d file%s"
1621                       totalsize
1622                       (length files)
1623                       (if (= 1 (length files)) "" "s"))
1624               "\n"))
1625     (apply 'vector (nreverse files))))
1626
1627 (defun archive-zip-extract (archive name)
1628   (if archive-zip-use-pkzip
1629       (archive-*-extract archive name archive-zip-extract)
1630     (archive-extract-by-stdout archive name archive-zip-extract)))
1631
1632 (defun archive-zip-write-file-member (archive descr)
1633   (archive-*-write-file-member
1634    archive
1635    descr
1636    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1637
1638 (defun archive-zip-chmod-entry (newmode files)
1639   (save-restriction
1640     (save-excursion
1641       (widen)
1642       (set-buffer-multibyte nil)
1643       (while files
1644         (let* ((fil (car files))
1645                (p (+ archive-proper-file-start (car (aref fil 4))))
1646                (creator (char-after (+ p 5)))
1647                (oldmode (aref fil 3))
1648                (newval  (archive-calc-mode oldmode newmode t))
1649                buffer-read-only)
1650           (cond ((memq creator '(2 3)) ; Unix + VMS
1651                  (goto-char (+ p 40))
1652                  (delete-char 2)
1653                  (insert (logand newval 255) (lsh newval -8)))
1654                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1655                  (goto-char (+ p 38))
1656                  (insert (logior (logand (char-after (point)) 254)
1657                                  (logand (logxor 1 (lsh newval -7)) 1)))
1658                  (delete-char 1))
1659                 (t (message "Don't know how to change mode for this member"))))
1660         (setq files (cdr files))))))
1661 ;; -------------------------------------------------------------------------
1662 ;; Section: Zoo Archives
1663
1664 (defun archive-zoo-summarize ()
1665   (let ((p (1+ (archive-l-e 25 4)))
1666         (maxlen 8)
1667         (totalsize 0)
1668         files
1669         visual)
1670     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1671                 (> (archive-l-e (+ p 6) 4) 0))
1672       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1673              (moddate (archive-l-e (+ p 14) 2))
1674              (modtime (archive-l-e (+ p 16) 2))
1675              (ucsize  (archive-l-e (+ p 20) 4))
1676              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1677              (dirtype (char-after (+ p 4)))
1678              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1679              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1680              (fnlen   (or (string-match "\0" namefld) 13))
1681              (efnname (let ((str
1682                              (concat
1683                               (if (> ldirlen 0)
1684                                   (concat (buffer-substring
1685                                            (+ p 58 lfnlen)
1686                                            (+ p 58 lfnlen ldirlen -1))
1687                                           "/")
1688                                 "")
1689                               (if (> lfnlen 0)
1690                                   (buffer-substring (+ p 58)
1691                                                     (+ p 58 lfnlen -1))
1692                                 (substring namefld 0 fnlen)))))
1693                         (if file-name-coding-system
1694                             (decode-coding-string str file-name-coding-system)
1695                           (string-as-multibyte str))))
1696              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1697              (ifnname (if fiddle (downcase efnname) efnname))
1698              (width (string-width ifnname))
1699              (text    (format "  %8d  %-11s  %-8s  %s"
1700                               ucsize
1701                               (archive-dosdate moddate)
1702                               (archive-dostime modtime)
1703                               ifnname)))
1704         (setq maxlen (max maxlen (length width))
1705               totalsize (+ totalsize ucsize)
1706               visual (cons (vector text
1707                                    (- (length text) (length ifnname))
1708                                    (length text))
1709                            visual)
1710               files (cons (vector efnname ifnname fiddle nil (1- p))
1711                           files)
1712               p next)))
1713     (goto-char (point-min))
1714     (let ((dash (concat "- --------  -----------  --------  "
1715                         (make-string maxlen ?-)
1716                         "\n")))
1717       (insert "M   Length  Date         Time      File\n"
1718               dash)
1719       (archive-summarize-files (nreverse visual))
1720       (insert dash
1721               (format "  %8d                         %d file%s"
1722                       totalsize
1723                       (length files)
1724                       (if (= 1 (length files)) "" "s"))
1725               "\n"))
1726     (apply 'vector (nreverse files))))
1727
1728 (defun archive-zoo-extract (archive name)
1729   (archive-extract-by-stdout archive name archive-zoo-extract))
1730 ;; -------------------------------------------------------------------------
1731 ;; This line was a mistake; it is kept now for compatibility.
1732 ;; rms  15 Oct 98
1733 (provide 'archive-mode)
1734
1735 (provide 'arc-mode)
1736
1737 ;; arc-mode.el ends here.