lisp/font-core.el

   1 ;;; font-core.el --- Core interface to font-lock
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: languages, faces
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Code:
  25
  26 ;; This variable is used by mode packages that support Font Lock mode by
  27 ;; defining their own keywords to use for `font-lock-keywords'.  (The mode
  28 ;; command should make it buffer-local and set it to provide the set up.)
  29 (defvar font-lock-defaults nil
  30   "Defaults for Font Lock mode specified by the major mode.
  31 Defaults should be of the form:
  32
  33  (KEYWORDS [KEYWORDS-ONLY [CASE-FOLD [SYNTAX-ALIST [SYNTAX-BEGIN ...]]]])
  34
  35 KEYWORDS may be a symbol (a variable or function whose value is the keywords to
  36 use for fontification) or a list of symbols.  If KEYWORDS-ONLY is non-nil,
  37 syntactic fontification (strings and comments) is not performed.
  38 If CASE-FOLD is non-nil, the case of the keywords is ignored when fontifying.
  39 If SYNTAX-ALIST is non-nil, it should be a list of cons pairs of the form
  40 \(CHAR-OR-STRING . STRING) used to set the local Font Lock syntax table, for
  41 keyword and syntactic fontification (see `modify-syntax-entry').
  42
  43 If SYNTAX-BEGIN is non-nil, it should be a function with no args used to move
  44 backwards outside any enclosing syntactic block, for syntactic fontification.
  45 Typical values are `beginning-of-line' (i.e., the start of the line is known to
  46 be outside a syntactic block), or `beginning-of-defun' for programming modes or
  47 `backward-paragraph' for textual modes (i.e., the mode-dependent function is
  48 known to move outside a syntactic block).  If nil, the beginning of the buffer
  49 is used as a position outside of a syntactic block, in the worst case.
  50
  51 These item elements are used by Font Lock mode to set the variables
  52 `font-lock-keywords', `font-lock-keywords-only',
  53 `font-lock-keywords-case-fold-search', `font-lock-syntax-table' and
  54 `font-lock-beginning-of-syntax-function', respectively.
  55
  56 Further item elements are alists of the form (VARIABLE . VALUE) and are in no
  57 particular order.  Each VARIABLE is made buffer-local before set to VALUE.
  58
  59 Currently, appropriate variables include `font-lock-mark-block-function'.
  60 If this is non-nil, it should be a function with no args used to mark any
  61 enclosing block of text, for fontification via \\[font-lock-fontify-block].
  62 Typical values are `mark-defun' for programming modes or `mark-paragraph' for
  63 textual modes (i.e., the mode-dependent function is known to put point and mark
  64 around a text block relevant to that mode).
  65
  66 Other variables include that for syntactic keyword fontification,
  67 `font-lock-syntactic-keywords' and those for buffer-specialized fontification
  68 functions, `font-lock-fontify-buffer-function',
  69 `font-lock-unfontify-buffer-function', `font-lock-fontify-region-function',
  70 `font-lock-unfontify-region-function', and `font-lock-inhibit-thing-lock'.")
  71 (make-variable-buffer-local 'font-lock-defaults)
  72
  73 (defvar font-lock-defaults-alist nil
  74   "Alist of fall-back Font Lock defaults for major modes.
  75
  76 Each item should be a list of the form:
  77
  78  (MAJOR-MODE . FONT-LOCK-DEFAULTS)
  79
  80 where MAJOR-MODE is a symbol and FONT-LOCK-DEFAULTS is a list of default
  81 settings.  See the variable `font-lock-defaults', which takes precedence.")
  82 (make-obsolete-variable 'font-lock-defaults-alist 'font-lock-defaults "21.1")
  83
  84 (defvar font-lock-function 'font-lock-default-function
  85   "A function which is called when `font-lock-mode' is toggled.
  86 It will be passed one argument, which is the current value of
  87 `font-lock-mode'.")
  88
  89 ;; The mode for which font-lock was initialized, or nil if none.
  90 (defvar font-lock-mode-major-mode)
  91 (define-minor-mode font-lock-mode
  92   "Toggle Font Lock mode.
  93 With arg, turn Font Lock mode off if and only if arg is a non-positive
  94 number; if arg is nil, toggle Font Lock mode; anything else turns Font
  95 Lock on.
  96 \(Font Lock is also known as \"syntax highlighting\".)
  97
  98 When Font Lock mode is enabled, text is fontified as you type it:
  99
 100  - Comments are displayed in `font-lock-comment-face';
 101  - Strings are displayed in `font-lock-string-face';
 102  - Certain other expressions are displayed in other faces according to the
 103    value of the variable `font-lock-keywords'.
 104
 105 To customize the faces (colors, fonts, etc.) used by Font Lock for
 106 fontifying different parts of buffer text, use \\[customize-face].
 107
 108 You can enable Font Lock mode in any major mode automatically by turning on in
 109 the major mode's hook.  For example, put in your ~/.emacs:
 110
 111  (add-hook 'c-mode-hook 'turn-on-font-lock)
 112
 113 Alternatively, you can use Global Font Lock mode to automagically turn on Font
 114 Lock mode in buffers whose major mode supports it and whose major mode is one
 115 of `font-lock-global-modes'.  For example, put in your ~/.emacs:
 116
 117  (global-font-lock-mode t)
 118
 119 Where major modes support different levels of fontification, you can use
 120 the variable `font-lock-maximum-decoration' to specify which level you
 121 generally prefer.  When you turn Font Lock mode on/off the buffer is
 122 fontified/defontified, though fontification occurs only if the buffer is
 123 less than `font-lock-maximum-size'.
 124
 125 To add your own highlighting for some major mode, and modify the highlighting
 126 selected automatically via the variable `font-lock-maximum-decoration', you can
 127 use `font-lock-add-keywords'.
 128
 129 To fontify a buffer, without turning on Font Lock mode and regardless of buffer
 130 size, you can use \\[font-lock-fontify-buffer].
 131
 132 To fontify a block (the function or paragraph containing point, or a number of
 133 lines around point), perhaps because modification on the current line caused
 134 syntactic change on other lines, you can use \\[font-lock-fontify-block].
 135
 136 See the variable `font-lock-defaults-alist' for the Font Lock mode default
 137 settings.  You can set your own default settings for some mode, by setting a
 138 buffer local value for `font-lock-defaults', via its mode hook.
 139
 140 The above is the default behavior of `font-lock-mode'; you may specify
 141 your own function which is called when `font-lock-mode' is toggled via
 142 `font-lock-function'. "
 143   nil nil nil
 144   ;; Don't turn on Font Lock mode if we don't have a display (we're running a
 145   ;; batch job) or if the buffer is invisible (the name starts with a space).
 146   (when (or noninteractive (eq (aref (buffer-name) 0) ?\s))
 147     (setq font-lock-mode nil))
 148   (funcall font-lock-function font-lock-mode)
 149   ;; Arrange to unfontify this buffer if we change major mode later.
 150   (if font-lock-mode
 151       (add-hook 'change-major-mode-hook 'font-lock-change-mode nil t)
 152     (remove-hook 'change-major-mode-hook 'font-lock-change-mode t))
 153   (when font-lock-mode
 154     (setq font-lock-mode-major-mode major-mode)))
 155
 156 ;; Get rid of fontification for the old major mode.
 157 ;; We do this when changing major modes.
 158 (defun font-lock-change-mode ()
 159   (font-lock-mode -1))
 160
 161 (defun font-lock-defontify ()
 162   "Clear out all `font-lock-face' properties in current buffer.
 163 A major mode that uses `font-lock-face' properties might want to put
 164 this function onto `change-major-mode-hook'."
 165   (let ((modp (buffer-modified-p))
 166         (inhibit-read-only t))
 167     (save-restriction
 168       (widen)
 169       (remove-list-of-text-properties (point-min) (point-max)
 170                                       '(font-lock-face)))
 171     (restore-buffer-modified-p modp)))
 172
 173 (defvar font-lock-set-defaults)
 174 (defun font-lock-default-function (mode)
 175   ;; Turn on Font Lock mode.
 176   (when mode
 177     (set (make-local-variable 'char-property-alias-alist)
 178          (copy-tree char-property-alias-alist))
 179     ;; Add `font-lock-face' as an alias for the `face' property.
 180     (let ((elt (assq 'face char-property-alias-alist)))
 181       (if elt
 182           (unless (memq 'font-lock-face (cdr elt))
 183             (setcdr elt (nconc (cdr elt) (list 'font-lock-face))))
 184         (push (list 'face 'font-lock-face) char-property-alias-alist))))
 185   ;; Turn off Font Lock mode.
 186   (unless mode
 187     ;; Remove `font-lock-face' as an alias for the `face' property.
 188     (set (make-local-variable 'char-property-alias-alist)
 189          (copy-tree char-property-alias-alist))
 190     (let ((elt (assq 'face char-property-alias-alist)))
 191       (when elt
 192         (setcdr elt (remq 'font-lock-face (cdr elt)))
 193         (when (null (cdr elt))
 194           (setq char-property-alias-alist
 195                 (delq elt char-property-alias-alist))))))
 196
 197   ;; Only do hard work if the mode has specified stuff in
 198   ;; `font-lock-defaults'.
 199   (when (or font-lock-defaults
 200             (if (boundp 'font-lock-keywords) font-lock-keywords)
 201             (with-no-warnings
 202               (cdr (assq major-mode font-lock-defaults-alist)))
 203             (and mode
 204                  (boundp 'font-lock-set-defaults)
 205                  font-lock-set-defaults
 206                  font-lock-mode-major-mode
 207                  (not (eq font-lock-mode-major-mode major-mode))))
 208     (font-lock-mode-internal mode)))
 209
 210 (defun turn-on-font-lock ()
 211   "Turn on Font Lock mode (only if the terminal can display it)."
 212   (unless font-lock-mode
 213     (font-lock-mode)))
 214
 215 ;;; Global Font Lock mode.
 216
 217 ;; A few people have hassled in the past for a way to make it easier to turn on
 218 ;; Font Lock mode, without the user needing to know for which modes s/he has to
 219 ;; turn it on, perhaps the same way hilit19.el/hl319.el does.  I've always
 220 ;; balked at that way, as I see it as just re-moulding the same problem in
 221 ;; another form.  That is; some person would still have to keep track of which
 222 ;; modes (which may not even be distributed with Emacs) support Font Lock mode.
 223 ;; The list would always be out of date.  And that person might have to be me.
 224
 225 ;; Implementation.
 226 ;;
 227 ;; In a previous discussion the following hack came to mind.  It is a gross
 228 ;; hack, but it generally works.  We use the convention that major modes start
 229 ;; by calling the function `kill-all-local-variables', which in turn runs
 230 ;; functions on the hook variable `change-major-mode-hook'.  We attach our
 231 ;; function `font-lock-change-major-mode' to that hook.  Of course, when this
 232 ;; hook is run, the major mode is in the process of being changed and we do not
 233 ;; know what the final major mode will be.  So, `font-lock-change-major-mode'
 234 ;; only (a) notes the name of the current buffer, and (b) adds our function
 235 ;; `turn-on-font-lock-if-desired' to the hook variables
 236 ;; `after-change-major-mode-hook' and `post-command-hook' (for modes
 237 ;; that do not yet run `after-change-major-mode-hook').  By the time
 238 ;; the functions on the first of these hooks to be run are run, the new major
 239 ;; mode is assumed to be in place.  This way we get a Font Lock function run
 240 ;; when a major mode is turned on, without knowing major modes or their hooks.
 241 ;;
 242 ;; Naturally this requires that major modes run `kill-all-local-variables'
 243 ;; and `after-change-major-mode-hook', as they are supposed to.  For modes
 244 ;; that do not run `after-change-major-mode-hook' yet, `post-command-hook'
 245 ;; takes care of things if the mode is set directly or indirectly by
 246 ;; an interactive command; however, problems can occur if the mode is
 247 ;; set by a timer or process: in that case, proper handling of Font Lock mode
 248 ;; may be delayed until the next interactive command.
 249
 250 ;; User interface.
 251 ;;
 252 ;; Although Global Font Lock mode is a pseudo-mode, I think that the user
 253 ;; interface should conform to the usual Emacs convention for modes, i.e., a
 254 ;; command to toggle the feature (`global-font-lock-mode') with a variable for
 255 ;; finer control of the mode's behaviour (`font-lock-global-modes').
 256 ;;
 257 ;; The feature should not be enabled by loading font-lock.el, since other
 258 ;; mechanisms for turning on Font Lock mode, such as M-x font-lock-mode RET or
 259 ;; (add-hook 'c-mode-hook 'turn-on-font-lock), would cause Font Lock mode to be
 260 ;; turned on everywhere.  That would not be intuitive or informative because
 261 ;; loading a file tells you nothing about the feature or how to control it.  It
 262 ;; would also be contrary to the Principle of Least Surprise.  sm.
 263
 264 (defcustom font-lock-global-modes t
 265   "*Modes for which Font Lock mode is automagically turned on.
 266 Global Font Lock mode is controlled by the command `global-font-lock-mode'.
 267 If nil, means no modes have Font Lock mode automatically turned on.
 268 If t, all modes that support Font Lock mode have it automatically turned on.
 269 If a list, it should be a list of `major-mode' symbol names for which Font Lock
 270 mode should be automatically turned on.  The sense of the list is negated if it
 271 begins with `not'.  For example:
 272  (c-mode c++-mode)
 273 means that Font Lock mode is turned on for buffers in C and C++ modes only."
 274   :type '(choice (const :tag "none" nil)
 275                  (const :tag "all" t)
 276                  (set :menu-tag "mode specific" :tag "modes"
 277                       :value (not)
 278                       (const :tag "Except" not)
 279                       (repeat :inline t (symbol :tag "mode"))))
 280   :group 'font-lock)
 281
 282 (defun turn-on-font-lock-if-desired ()
 283   (when (cond ((eq font-lock-global-modes t)
 284                t)
 285               ((eq (car-safe font-lock-global-modes) 'not)
 286                (not (memq major-mode (cdr font-lock-global-modes))))
 287               (t (memq major-mode (cdr font-lock-global-modes))))
 288     (let (inhibit-quit)
 289       (turn-on-font-lock))))
 290
 291 (define-globalized-minor-mode global-font-lock-mode
 292   font-lock-mode turn-on-font-lock-if-desired
 293   :extra-args (dummy)
 294   :initialize 'custom-initialize-safe-default
 295   :init-value (not (or noninteractive emacs-basic-display))
 296   :group 'font-lock
 297   :version "22.1")
 298
 299 ;;; End of Global Font Lock mode.
 300
 301 (provide 'font-core)
 302
 303 ;; arch-tag: f8c286e1-02f7-41d9-b89b-1b67780aed71
 304 ;;; font-core.el ends here