lisp/finder.el

   1 ;;; finder.el --- topic & keyword-based code finder
   2
   3 ;; Copyright (C) 1992, 1997, 1998, 1999, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008  Free Software Foundation, Inc.
   5
   6 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   7 ;; Created: 16 Jun 1992
   8 ;; Version: 1.0
   9 ;; Keywords: help
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This mode uses the Keywords library header to provide code-finding
  29 ;; services by keyword.
  30 ;;
  31 ;; Things to do:
  32 ;;    1. Support multiple keywords per search.  This could be extremely hairy;
  33 ;; there doesn't seem to be any way to get completing-read to exit on
  34 ;; an EOL with no substring pending, which is what we'd want to end the loop.
  35 ;;    2. Search by string in synopsis line?
  36 ;;    3. Function to check finder-package-info for unknown keywords.
  37
  38 ;;; Code:
  39
  40 (require 'lisp-mnt)
  41 (require 'find-func)                    ;for find-library(-suffixes)
  42 ;; Use `load' rather than `require' so that it doesn't get loaded
  43 ;; during byte-compilation (at which point it might be missing).
  44 (load "finder-inf" t t)
  45
  46 ;; These are supposed to correspond to top-level customization groups,
  47 ;; says rms.
  48 (defvar finder-known-keywords
  49   '(
  50     (abbrev     . "abbreviation handling, typing shortcuts, macros")
  51     ;; Too specific:
  52     (bib        . "code related to the `bib' bibliography processor")
  53     (c          . "support for the C language and related languages")
  54     (calendar   . "calendar and time management support")
  55     (comm       . "communications, networking, remote access to files")
  56     (convenience . "convenience features for faster editing")
  57     (data       . "support for editing files of data")
  58     (docs       . "support for Emacs documentation")
  59     (emulations . "emulations of other editors")
  60     (extensions . "Emacs Lisp language extensions")
  61     (faces      . "support for multiple fonts")
  62     (files      . "support for editing and manipulating files")
  63     (frames     . "support for Emacs frames and window systems")
  64     (games      . "games, jokes and amusements")
  65     (hardware   . "support for interfacing with exotic hardware")
  66     (help       . "support for on-line help systems")
  67     (hypermedia . "support for links between text or other media types")
  68     (i18n       . "internationalization and alternate character-set support")
  69     (internal   . "code for Emacs internals, build process, defaults")
  70     (languages  . "specialized modes for editing programming languages")
  71     (lisp       . "Lisp support, including Emacs Lisp")
  72     (local      . "code local to your site")
  73     (maint      . "maintenance aids for the Emacs development group")
  74     (mail       . "modes for electronic-mail handling")
  75     (matching   . "various sorts of searching and matching")
  76     (mouse      . "mouse support")
  77     (multimedia . "images and sound support")
  78     (news       . "support for netnews reading and posting")
  79     (oop        . "support for object-oriented programming")
  80     (outlines   . "support for hierarchical outlining")
  81     (processes  . "process, subshell, compilation, and job control support")
  82     (terminals  . "support for terminal types")
  83     (tex        . "supporting code for the TeX formatter")
  84     (tools      . "programming tools")
  85     (unix       . "front-ends/assistants for, or emulators of, UNIX-like features")
  86 ;; Not a custom group and not currently useful.
  87 ;;    (vms      . "support code for vms")
  88     (wp         . "word processing")
  89     ))
  90
  91 (defvar finder-mode-map
  92   (let ((map (make-sparse-keymap)))
  93     (define-key map " " 'finder-select)
  94     (define-key map "f" 'finder-select)
  95     (define-key map [follow-link] 'mouse-face)
  96     (define-key map [mouse-2]   'finder-mouse-select)
  97     (define-key map "\C-m"      'finder-select)
  98     (define-key map "?" 'finder-summary)
  99     (define-key map "n" 'next-line)
 100     (define-key map "p" 'previous-line)
 101     (define-key map "q" 'finder-exit)
 102     (define-key map "d" 'finder-list-keywords)
 103     map))
 104
 105 (defvar finder-mode-syntax-table
 106   (let ((st (make-syntax-table emacs-lisp-mode-syntax-table)))
 107     (modify-syntax-entry ?\; ".   " st)
 108     st)
 109   "Syntax table used while in `finder-mode'.")
 110
 111 (defvar finder-font-lock-keywords
 112   '(("`\\([^'`]+\\)'" 1 font-lock-constant-face prepend))
 113   "Font-lock keywords for Finder mode.")
 114
 115 (defvar finder-headmark nil
 116   "Internal finder-mode variable, local in finder buffer.")
 117
 118 ;;; Code for regenerating the keyword list.
 119
 120 (defvar finder-package-info nil
 121   "Assoc list mapping file names to description & keyword lists.")
 122
 123 (defvar generated-finder-keywords-file "finder-inf.el"
 124   "The function `finder-compile-keywords' writes keywords into this file.")
 125
 126 ;; Skip autogenerated files, because they will never contain anything
 127 ;; useful, and because in parallel builds of Emacs they may get
 128 ;; modified while we are trying to read them.
 129 ;; http://lists.gnu.org/archive/html/emacs-pretest-bug/2007-01/msg00469.html
 130 (defvar finder-no-scan-regexp "\\(^\\.#\\|\\(loaddefs\\|cus-load\\|\
 131 finder-inf\\|esh-groups\\|subdirs\\)\\.el$\\)"
 132   "Regexp matching file names not to scan for keywords.")
 133
 134 (autoload 'autoload-rubric "autoload")
 135
 136 (defun finder-compile-keywords (&rest dirs)
 137   "Regenerate the keywords association list into `generated-finder-keywords-file'.
 138 Optional arguments DIRS are a list of Emacs Lisp directories to compile from;
 139 no arguments compiles from `load-path'."
 140   (save-excursion
 141     (find-file generated-finder-keywords-file)
 142     (setq buffer-undo-list t)
 143     (erase-buffer)
 144     (insert (autoload-rubric generated-finder-keywords-file
 145                              "keyword-to-package mapping"))
 146     (search-backward "\f")
 147     (insert "(setq finder-package-info '(\n")
 148     (let (processed summary keywords)
 149       (mapc
 150        (lambda (d)
 151          (when (file-exists-p (directory-file-name d))
 152            (message "Directory %s" d)
 153            (mapc
 154             (lambda (f)
 155               ;; FIXME should this not be using (expand-file-name f d)?
 156               (unless (or (member f processed)
 157                           (string-match finder-no-scan-regexp f))
 158                 (setq processed (cons f processed))
 159                 (with-temp-buffer
 160                   (insert-file-contents (expand-file-name f d))
 161                   (setq summary (lm-synopsis)
 162                         keywords (lm-keywords-list)))
 163                 (insert
 164                  (format "    (\"%s\"\n        "
 165                          (if (string-match "\\.\\(gz\\|Z\\)$" f)
 166                              (file-name-sans-extension f)
 167                            f)))
 168                 (prin1 summary (current-buffer))
 169                 (insert "\n        ")
 170                 (princ keywords (current-buffer))
 171                 (insert ")\n")))
 172             (directory-files d nil
 173                              ;; Allow compressed files also.  FIXME:
 174                              ;; generalize this, especially for
 175                              ;; MS-DOG-type filenames.
 176                              "^[^=].*\\.el\\(\\.\\(gz\\|Z\\)\\)?$"
 177                              ))))
 178        (or dirs load-path)))
 179     (insert "    ))\n")
 180     (eval-buffer)         ; so we get the new keyword list immediately
 181     (basic-save-buffer)))
 182
 183 (defun finder-compile-keywords-make-dist ()
 184   "Regenerate `finder-inf.el' for the Emacs distribution."
 185   (apply 'finder-compile-keywords command-line-args-left)
 186   (kill-emacs))
 187
 188 ;;; Now the retrieval code
 189
 190 (defun finder-insert-at-column (column &rest strings)
 191   "Insert, at column COLUMN, other args STRINGS."
 192   (if (>= (current-column) column) (insert "\n"))
 193   (move-to-column column t)
 194   (apply 'insert strings))
 195
 196 (defvar finder-help-echo nil)
 197
 198 (defun finder-mouse-face-on-line ()
 199   "Put `mouse-face' and `help-echo' properties on the previous line."
 200   (save-excursion
 201     (forward-line -1)
 202     ;; If finder-insert-at-column moved us to a new line, go back one more.
 203     (if (looking-at "[ \t]") (forward-line -1))
 204     (unless finder-help-echo
 205       (setq finder-help-echo
 206             (let* ((keys1 (where-is-internal 'finder-select
 207                                              finder-mode-map))
 208                    (keys (nconc (where-is-internal
 209                                  'finder-mouse-select finder-mode-map)
 210                                 keys1)))
 211               (concat (mapconcat 'key-description keys ", ")
 212                       ": select item"))))
 213     (add-text-properties
 214      (line-beginning-position) (line-end-position)
 215      '(mouse-face highlight
 216                   help-echo finder-help-echo))))
 217
 218 ;;;###autoload
 219 (defun finder-list-keywords ()
 220   "Display descriptions of the keywords in the Finder buffer."
 221   (interactive)
 222   (if (get-buffer "*Finder*")
 223       (pop-to-buffer "*Finder*")
 224     (pop-to-buffer (get-buffer-create "*Finder*"))
 225     (finder-mode)
 226     (setq buffer-read-only nil
 227           buffer-undo-list t)
 228     (erase-buffer)
 229     (mapc
 230      (lambda (assoc)
 231        (let ((keyword (car assoc)))
 232          (insert (symbol-name keyword))
 233          (finder-insert-at-column 14 (concat (cdr assoc) "\n"))
 234          (finder-mouse-face-on-line)))
 235      finder-known-keywords)
 236     (goto-char (point-min))
 237     (setq finder-headmark (point)
 238           buffer-read-only t)
 239     (set-buffer-modified-p nil)
 240     (balance-windows)
 241     (finder-summary)))
 242
 243 (defun finder-list-matches (key)
 244   (pop-to-buffer (set-buffer (get-buffer-create "*Finder Category*")))
 245   (finder-mode)
 246   (setq buffer-read-only nil
 247          buffer-undo-list t)
 248   (erase-buffer)
 249   (let ((id (intern key)))
 250     (insert
 251      "The following packages match the keyword `" key "':\n\n")
 252     (setq finder-headmark (point))
 253     (mapc
 254      (lambda (x)
 255        (when (memq id (cadr (cdr x)))
 256          (insert (car x))
 257          (finder-insert-at-column 16 (concat (cadr x) "\n"))
 258          (finder-mouse-face-on-line)))
 259      finder-package-info)
 260     (goto-char (point-min))
 261     (forward-line)
 262     (setq buffer-read-only t)
 263     (set-buffer-modified-p nil)
 264     (shrink-window-if-larger-than-buffer)
 265     (finder-summary)))
 266
 267 (define-button-type 'finder-xref 'action #'finder-goto-xref)
 268
 269 (defun finder-goto-xref (button)
 270   "Jump to a lisp file for the BUTTON at point."
 271   (let* ((file (button-get button 'xref))
 272          (lib (locate-library file)))
 273     (if lib (finder-commentary lib)
 274       (message "Unable to locate `%s'" file))))
 275
 276 ;;;###autoload
 277 (defun finder-commentary (file)
 278   "Display FILE's commentary section.
 279 FILE should be in a form suitable for passing to `locate-library'."
 280   (interactive
 281    (list
 282     (completing-read "Library name: "
 283                      (apply-partially 'locate-file-completion-table
 284                                       (or find-function-source-path load-path)
 285                                       (find-library-suffixes)))))
 286   (let ((str (lm-commentary (find-library-name file))))
 287     (or str (error "Can't find any Commentary section"))
 288     ;; This used to use *Finder* but that would clobber the
 289     ;; directory of categories.
 290     (delete-other-windows)
 291     (pop-to-buffer "*Finder-package*")
 292     (setq buffer-read-only nil
 293           buffer-undo-list t)
 294     (erase-buffer)
 295     (insert str)
 296     (goto-char (point-min))
 297     (delete-blank-lines)
 298     (goto-char (point-max))
 299     (delete-blank-lines)
 300     (goto-char (point-min))
 301     (while (re-search-forward "^;+ ?" nil t)
 302       (replace-match "" nil nil))
 303     (goto-char (point-min))
 304     (while (re-search-forward "\\<\\([-[:alnum:]]+\\.el\\)\\>" nil t)
 305       (if (locate-library (match-string 1))
 306           (make-text-button (match-beginning 1) (match-end 1)
 307                             'xref (match-string-no-properties 1)
 308                             'help-echo "Read this file's commentary"
 309                             :type 'finder-xref)))
 310     (goto-char (point-min))
 311     (setq buffer-read-only t)
 312     (set-buffer-modified-p nil)
 313     (shrink-window-if-larger-than-buffer)
 314     (finder-mode)
 315     (finder-summary)))
 316
 317 (defun finder-current-item ()
 318   (let ((key (save-excursion
 319                (beginning-of-line)
 320                (current-word))))
 321     (if (or (and finder-headmark (< (point) finder-headmark))
 322             (zerop (length key)))
 323         (error "No keyword or filename on this line")
 324       key)))
 325
 326 (defun finder-select ()
 327   "Select item on current line in a finder buffer."
 328   (interactive)
 329   (let ((key (finder-current-item)))
 330       (if (string-match "\\.el$" key)
 331           (finder-commentary key)
 332         (finder-list-matches key))))
 333
 334 (defun finder-mouse-select (event)
 335   "Select item in a finder buffer with the mouse."
 336   (interactive "e")
 337   (save-excursion
 338     (set-buffer (window-buffer (posn-window (event-start event))))
 339     (goto-char (posn-point (event-start event)))
 340     (finder-select)))
 341
 342 ;;;###autoload
 343 (defun finder-by-keyword ()
 344   "Find packages matching a given keyword."
 345   (interactive)
 346   (finder-list-keywords))
 347
 348 (define-derived-mode finder-mode nil "Finder"
 349   "Major mode for browsing package documentation.
 350 \\<finder-mode-map>
 351 \\[finder-select]       more help for the item on the current line
 352 \\[finder-exit] exit Finder mode and kill the Finder buffer."
 353   :syntax-table finder-mode-syntax-table
 354   (setq font-lock-defaults '(finder-font-lock-keywords nil nil
 355                              (("+-*/.<>=!?$%_&~^:@" . "w")) nil))
 356   (set (make-local-variable 'finder-headmark) nil))
 357
 358 (defun finder-summary ()
 359   "Summarize basic Finder commands."
 360   (interactive)
 361   (message "%s"
 362    (substitute-command-keys
 363     "\\<finder-mode-map>\\[finder-select] = select, \
 364 \\[finder-mouse-select] = select, \\[finder-list-keywords] = to \
 365 finder directory, \\[finder-exit] = quit, \\[finder-summary] = help")))
 366
 367 (defun finder-exit ()
 368   "Exit Finder mode.
 369 Delete the window and kill all Finder-related buffers."
 370   (interactive)
 371   (ignore-errors (delete-window))
 372   (dolist (buff '("*Finder*" "*Finder-package*" "*Finder Category*"))
 373     (and (get-buffer buff) (kill-buffer buff))))
 374
 375 \f
 376 (provide 'finder)
 377
 378 ;; arch-tag: ec85ff49-8cb8-41f5-a63f-9131d53ce2c5
 379 ;;; finder.el ends here