lisp/register.el

   1 ;;; register.el --- register commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package of functions emulates and somewhat extends the venerable
  28 ;; TECO's `register' feature, which permits you to save various useful
  29 ;; pieces of buffer state to named variables.  The entry points are
  30 ;; documented in the Emacs user's manual.
  31
  32 ;;; Code:
  33
  34 (defvar register-alist nil
  35   "Alist of elements (NAME . CONTENTS), one for each Emacs register.
  36 NAME is a character (a number).  CONTENTS is a string, number, marker or list.
  37 A list of strings represents a rectangle.
  38 A list of the form (file . NAME) represents the file named NAME.
  39 A list of the form (file-query NAME POSITION) represents position POSITION
  40  in the file named NAME, but query before visiting it.
  41 A list of the form (WINDOW-CONFIGURATION POSITION)
  42  represents a saved window configuration plus a saved value of point.
  43 A list of the form (FRAME-CONFIGURATION POSITION)
  44  represents a saved frame configuration plus a saved value of point.")
  45
  46 (defun get-register (reg)
  47   "Return contents of Emacs register named REG, or nil if none."
  48   (cdr (assq reg register-alist)))
  49
  50 (defun set-register (register value)
  51   "Set contents of Emacs register named REGISTER to VALUE.  Returns VALUE.
  52 See the documentation of the variable `register-alist' for possible VALUE."
  53   (let ((aelt (assq register register-alist)))
  54     (if aelt
  55         (setcdr aelt value)
  56       (setq aelt (cons register value))
  57       (setq register-alist (cons aelt register-alist)))
  58     value))
  59
  60 (defun point-to-register (register &optional arg)
  61   "Store current location of point in register REGISTER.
  62 With prefix argument, store current frame configuration.
  63 Use \\[jump-to-register] to go to that location or restore that configuration.
  64 Argument is a character, naming the register."
  65   (interactive "cPoint to register: \nP")
  66   (set-register register
  67                 (if arg (list (current-frame-configuration) (point-marker))
  68                   (point-marker))))
  69
  70 (defun window-configuration-to-register (register &optional arg)
  71   "Store the window configuration of the selected frame in register REGISTER.
  72 Use \\[jump-to-register] to restore the configuration.
  73 Argument is a character, naming the register."
  74   (interactive "cWindow configuration to register: \nP")
  75   ;; current-window-configuration does not include the value
  76   ;; of point in the current buffer, so record that separately.
  77   (set-register register (list (current-window-configuration) (point-marker))))
  78
  79 (defun frame-configuration-to-register (register &optional arg)
  80   "Store the window configuration of all frames in register REGISTER.
  81 Use \\[jump-to-register] to restore the configuration.
  82 Argument is a character, naming the register."
  83   (interactive "cFrame configuration to register: \nP")
  84   ;; current-frame-configuration does not include the value
  85   ;; of point in the current buffer, so record that separately.
  86   (set-register register (list (current-frame-configuration) (point-marker))))
  87
  88 (defalias 'register-to-point 'jump-to-register)
  89 (defun jump-to-register (register &optional delete)
  90   "Move point to location stored in a register.
  91 If the register contains a file name, find that file.
  92  \(To put a file name in a register, you must use `set-register'.)
  93 If the register contains a window configuration (one frame) or a frame
  94 configuration (all frames), restore that frame or all frames accordingly.
  95 First argument is a character, naming the register.
  96 Optional second arg non-nil (interactively, prefix argument) says to
  97 delete any existing frames that the frame configuration doesn't mention.
  98 \(Otherwise, these frames are iconified.)"
  99   (interactive "cJump to register: \nP")
 100   (let ((val (get-register register)))
 101     (cond
 102      ((and (consp val) (frame-configuration-p (car val)))
 103       (set-frame-configuration (car val) (not delete))
 104       (goto-char (cadr val)))
 105      ((and (consp val) (window-configuration-p (car val)))
 106       (set-window-configuration (car val))
 107       (goto-char (cadr val)))
 108      ((markerp val)
 109       (or (marker-buffer val)
 110           (error "That register's buffer no longer exists"))
 111       (switch-to-buffer (marker-buffer val))
 112       (goto-char val))
 113      ((and (consp val) (eq (car val) 'file))
 114       (find-file (cdr val)))
 115      ((and (consp val) (eq (car val) 'file-query))
 116       (or (find-buffer-visiting (nth 1 val))
 117           (y-or-n-p (format "Visit file %s again? " (nth 1 val)))
 118           (error "Register access aborted"))
 119       (find-file (nth 1 val))
 120       (goto-char (nth 2 val)))
 121      (t
 122       (error "Register doesn't contain a buffer position or configuration")))))
 123
 124 ;; Turn markers into file-query references when a buffer is killed.
 125 (defun register-swap-out ()
 126   (and buffer-file-name
 127        (let ((tail register-alist))
 128          (while tail
 129            (and (markerp (cdr (car tail)))
 130                 (eq (marker-buffer (cdr (car tail))) (current-buffer))
 131                 (setcdr (car tail)
 132                         (list 'file-query
 133                               buffer-file-name
 134                               (marker-position (cdr (car tail))))))
 135            (setq tail (cdr tail))))))
 136
 137 (add-hook 'kill-buffer-hook 'register-swap-out)
 138
 139 (defun number-to-register (number register)
 140   "Store a number in a register.
 141 Two args, NUMBER and REGISTER (a character, naming the register).
 142 If NUMBER is nil, a decimal number is read from the buffer starting
 143 at point, and point moves to the end of that number.
 144 Interactively, NUMBER is the prefix arg (none means nil)."
 145   (interactive "P\ncNumber to register: ")
 146   (set-register register
 147                 (if number
 148                     (prefix-numeric-value number)
 149                   (if (looking-at "\\s-*-?[0-9]+")
 150                       (progn
 151                         (goto-char (match-end 0))
 152                         (string-to-int (match-string 0)))
 153                     0))))
 154
 155 (defun increment-register (number register)
 156   "Add NUMBER to the contents of register REGISTER.
 157 Interactively, NUMBER is the prefix arg."
 158   (interactive "p\ncIncrement register: ")
 159   (or (numberp (get-register register))
 160       (error "Register does not contain a number"))
 161   (set-register register (+ number (get-register register))))
 162
 163 (defun view-register (register)
 164   "Display what is contained in register named REGISTER.
 165 The Lisp value REGISTER is a character."
 166   (interactive "cView register: ")
 167   (let ((val (get-register register)))
 168     (if (null val)
 169         (message "Register %s is empty" (single-key-description register))
 170       (with-output-to-temp-buffer "*Output*"
 171         (describe-register-1 register t)))))
 172
 173 (defun list-registers ()
 174   "Display a list of nonempty registers saying briefly what they contain."
 175   (interactive)
 176   (let ((list (copy-sequence register-alist)))
 177     (setq list (sort list (lambda (a b) (< (car a) (car b)))))
 178     (with-output-to-temp-buffer "*Output*"
 179       (dolist (elt list)
 180         (when (get-register (car elt))
 181           (describe-register-1 (car elt))
 182           (terpri))))))
 183
 184 (defun describe-register-1 (register &optional verbose)
 185   (princ "Register ")
 186   (princ (single-key-description register))
 187   (princ " contains ")
 188   (let ((val (get-register register)))
 189     (cond
 190      ((numberp val)
 191       (princ val))
 192
 193      ((markerp val)
 194       (let ((buf (marker-buffer val)))
 195         (if (null buf)
 196             (princ "a marker in no buffer")
 197           (princ "a buffer position:\n    buffer ")
 198           (princ (buffer-name buf))
 199           (princ ", position ")
 200           (princ (marker-position val)))))
 201
 202      ((and (consp val) (window-configuration-p (car val)))
 203       (princ "a window configuration."))
 204
 205      ((and (consp val) (frame-configuration-p (car val)))
 206       (princ "a frame configuration."))
 207
 208      ((and (consp val) (eq (car val) 'file))
 209       (princ "the file ")
 210       (prin1 (cdr val))
 211       (princ "."))
 212
 213      ((and (consp val) (eq (car val) 'file-query))
 214       (princ "a file-query reference:\n    file ")
 215       (prin1 (car (cdr val)))
 216       (princ ",\n    position ")
 217       (princ (car (cdr (cdr val))))
 218       (princ "."))
 219
 220      ((consp val)
 221       (if verbose
 222           (progn
 223             (princ "the rectangle:\n")
 224             (while val
 225               (princ "    ")
 226               (princ (car val))
 227               (terpri)
 228               (setq val (cdr val))))
 229         (princ "a rectangle starting with ")
 230         (princ (car val))))
 231
 232      ((stringp val)
 233       (setq val
 234             (remove-list-of-text-properties 0 (length val)
 235                                             yank-excluded-properties val))
 236       (if verbose
 237           (progn
 238             (princ "the text:\n")
 239             (princ val))
 240         (princ "text starting with\n    ")
 241         (string-match "[^ \t\n].\\{,20\\}" val)
 242         (princ (match-string 0 val))))
 243      (t
 244       (princ "Garbage:\n")
 245       (if verbose (prin1 val))))))
 246
 247 (defun insert-register (register &optional arg)
 248   "Insert contents of register REGISTER.  (REGISTER is a character.)
 249 Normally puts point before and mark after the inserted text.
 250 If optional second arg is non-nil, puts mark before and point after.
 251 Interactively, second arg is non-nil if prefix arg is supplied."
 252   (interactive "*cInsert register: \nP")
 253   (push-mark)
 254   (let ((val (get-register register)))
 255     (cond
 256      ((consp val)
 257       (insert-rectangle val))
 258      ((stringp val)
 259       (insert-for-yank val))
 260      ((numberp val)
 261       (princ val (current-buffer)))
 262      ((and (markerp val) (marker-position val))
 263       (princ (marker-position val) (current-buffer)))
 264      (t
 265       (error "Register does not contain text"))))
 266   (if (not arg) (exchange-point-and-mark)))
 267
 268 (defun copy-to-register (register start end &optional delete-flag)
 269   "Copy region into register REGISTER.  With prefix arg, delete as well.
 270 Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
 271 START and END are buffer positions indicating what to copy."
 272   (interactive "cCopy to register: \nr\nP")
 273   (set-register register (buffer-substring start end))
 274   (if delete-flag (delete-region start end)))
 275
 276 (defun append-to-register (register start end &optional delete-flag)
 277   "Append region to text in register REGISTER.
 278 With prefix arg, delete as well.
 279 Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
 280 START and END are buffer positions indicating what to append."
 281   (interactive "cAppend to register: \nr\nP")
 282   (or (stringp (get-register register))
 283       (error "Register does not contain text"))
 284   (set-register register (concat (get-register register)
 285                             (buffer-substring start end)))
 286   (if delete-flag (delete-region start end)))
 287
 288 (defun prepend-to-register (register start end &optional delete-flag)
 289   "Prepend region to text in register REGISTER.
 290 With prefix arg, delete as well.
 291 Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
 292 START and END are buffer positions indicating what to prepend."
 293   (interactive "cPrepend to register: \nr\nP")
 294   (or (stringp (get-register register))
 295       (error "Register does not contain text"))
 296   (set-register register (concat (buffer-substring start end)
 297                             (get-register register)))
 298   (if delete-flag (delete-region start end)))
 299
 300 (defun copy-rectangle-to-register (register start end &optional delete-flag)
 301   "Copy rectangular region into register REGISTER.
 302 With prefix arg, delete as well.
 303 Called from program, takes four args: REGISTER, START, END and DELETE-FLAG.
 304 START and END are buffer positions giving two corners of rectangle."
 305   (interactive "cCopy rectangle to register: \nr\nP")
 306   (set-register register
 307                 (if delete-flag
 308                     (delete-extract-rectangle start end)
 309                   (extract-rectangle start end))))
 310
 311 ;;; register.el ends here