lisp/net/telnet.el

   1 ;;; telnet.el --- run a telnet session from within an Emacs buffer
   2
   3 ;; Copyright (C) 1985, 1988, 1992, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: William F. Schelter
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix, comm
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This mode is intended to be used for telnet or rsh to a remote host;
  29 ;; `telnet' and `rsh' are the two entry points.  Multiple telnet or rsh
  30 ;; sessions are supported.
  31 ;;
  32 ;; Normally, input is sent to the remote telnet/rsh line-by-line, as you
  33 ;; type RET or LFD.  C-c C-c sends a C-c to the remote immediately;
  34 ;; C-c C-z sends C-z immediately.  C-c C-q followed by any character
  35 ;; sends that character immediately.
  36 ;;
  37 ;; All RET characters are filtered out of the output coming back from the
  38 ;; remote system.  The mode tries to do other useful translations based
  39 ;; on what it sees coming back from the other system before the password
  40 ;; query.  It knows about UNIX, ITS, TOPS-20 and Explorer systems.
  41 ;;
  42 ;; You can use the global telnet-host-properties to associate a telnet
  43 ;; program and login name with each host you regularly telnet to.
  44
  45 ;;; Code:
  46
  47 ;; to do fix software types for lispm:
  48 ;; to eval current expression.  Also to try to send escape keys correctly.
  49 ;; essentially we'll want the rubout-handler off.
  50
  51 ;; filter is simplistic but should be okay for typical shell usage.
  52 ;; needs hacking if it is going to deal with asynchronous output in a sane
  53 ;; manner
  54
  55 (require 'comint)
  56
  57 (defvar telnet-host-properties ()
  58   "Specify which telnet program to use for particular hosts.
  59 Each element has the form (HOSTNAME PROGRAM [LOGIN-NAME])
  60 HOSTNAME says which machine the element applies to.
  61 PROGRAM says which program to run, to talk to that machine.
  62 LOGIN-NAME, which is optional, says what to log in as on that machine.")
  63
  64 (defvar telnet-new-line "\r")
  65 (defvar telnet-mode-map nil)
  66 (defvar telnet-prompt-pattern "^[^#$%>\n]*[#$%>] *")
  67 (defvar telnet-replace-c-g nil)
  68 (make-variable-buffer-local
  69  (defvar telnet-remote-echoes t
  70    "True if the telnet process will echo input."))
  71 (make-variable-buffer-local
  72  (defvar telnet-interrupt-string "\C-c" "String sent by C-c."))
  73
  74 (defvar telnet-count 0
  75   "Number of output strings from telnet process while looking for password.")
  76 (make-variable-buffer-local 'telnet-count)
  77
  78 (defvar telnet-program "telnet"
  79   "Program to run to open a telnet connection.")
  80
  81 (defvar telnet-initial-count -50
  82   "Initial value of `telnet-count'.  Should be set to the negative of the
  83 number of terminal writes telnet will make setting up the host connection.")
  84
  85 (defvar telnet-maximum-count 4
  86   "Maximum value `telnet-count' can have.
  87 After this many passes, we stop looking for initial setup data.
  88 Should be set to the number of terminal writes telnet will make
  89 rejecting one login and prompting again for a username and password.")
  90
  91 (defun telnet-interrupt-subjob ()
  92   (interactive)
  93   "Interrupt the program running through telnet on the remote host."
  94   (send-string nil telnet-interrupt-string))
  95
  96 (defun telnet-c-z ()
  97   (interactive)
  98   (send-string nil "\C-z"))
  99
 100 (defun send-process-next-char ()
 101   (interactive)
 102   (send-string nil
 103                (char-to-string
 104                 (let ((inhibit-quit t))
 105                   (prog1 (read-char)
 106                     (setq quit-flag nil))))))
 107
 108 ; initialization on first load.
 109 (if telnet-mode-map
 110     nil
 111   (setq telnet-mode-map (nconc (make-sparse-keymap) comint-mode-map))
 112   (define-key telnet-mode-map "\C-m" 'telnet-send-input)
 113 ;  (define-key telnet-mode-map "\C-j" 'telnet-send-input)
 114   (define-key telnet-mode-map "\C-c\C-q" 'send-process-next-char)
 115   (define-key telnet-mode-map "\C-c\C-c" 'telnet-interrupt-subjob)
 116   (define-key telnet-mode-map "\C-c\C-z" 'telnet-c-z))
 117
 118 ;;maybe should have a flag for when have found type
 119 (defun telnet-check-software-type-initialize (string)
 120   "Tries to put correct initializations in.  Needs work."
 121   (let ((case-fold-search t))
 122     (cond ((string-match "unix" string)
 123          (setq telnet-prompt-pattern comint-prompt-regexp)
 124          (setq telnet-new-line "\n"))
 125         ((string-match "tops-20" string) ;;maybe add telnet-replace-c-g
 126          (setq telnet-prompt-pattern  "[@>]*"))
 127         ((string-match "its" string)
 128          (setq telnet-prompt-pattern  "^[^*>\n]*[*>] *"))
 129         ((string-match "explorer" string)  ;;explorer telnet needs work
 130          (setq telnet-replace-c-g ?\n))))
 131   (setq comint-prompt-regexp telnet-prompt-pattern))
 132
 133 (defun telnet-initial-filter (proc string)
 134   ;For reading up to and including password; also will get machine type.
 135   (save-current-buffer
 136     (set-buffer (process-buffer proc))
 137     (let ((case-fold-search t))
 138       (cond ((string-match "No such host" string)
 139              (kill-buffer (process-buffer proc))
 140              (error "No such host"))
 141             ((string-match "passw" string)
 142              (telnet-filter proc string)
 143              (setq telnet-count 0)
 144              (send-string proc (concat (comint-read-noecho "Password: " t)
 145                                        telnet-new-line))
 146              (clear-this-command-keys))
 147             (t (telnet-check-software-type-initialize string)
 148                (telnet-filter proc string)
 149                (cond ((> telnet-count telnet-maximum-count)
 150                       (set-process-filter proc 'telnet-filter))
 151                      (t (setq telnet-count (1+ telnet-count)))))))))
 152
 153 ;; Identical to comint-simple-send, except that it sends telnet-new-line
 154 ;; instead of "\n".
 155 (defun telnet-simple-send (proc string)
 156   (comint-send-string proc string)
 157   (if comint-input-sender-no-newline
 158       (if (not (string-equal string ""))
 159           (process-send-eof))
 160     (comint-send-string proc telnet-new-line)))
 161
 162 (defun telnet-filter (proc string)
 163   (save-excursion
 164     (set-buffer (process-buffer proc))
 165     (let* ((last-insertion (marker-position (process-mark proc)))
 166            (delta (- (point) last-insertion))
 167            (ie (and comint-last-input-end
 168                     (marker-position comint-last-input-end)))
 169            (w (get-buffer-window (current-buffer)))
 170            (ws (and w (window-start w))))
 171       (goto-char last-insertion)
 172       (insert-before-markers string)
 173       (set-marker comint-last-output-start last-insertion)
 174       (set-marker (process-mark proc) (point))
 175       (if ws (set-window-start w ws t))
 176       (if ie (set-marker comint-last-input-end ie))
 177       (while (progn (skip-chars-backward "^\C-m" last-insertion)
 178                     (> (point) last-insertion))
 179         (delete-region (1- (point)) (point)))
 180       (goto-char (process-mark proc))
 181       (and telnet-replace-c-g
 182            (subst-char-in-region last-insertion (point) ?\C-g
 183                                  telnet-replace-c-g t))
 184       ;; If point is after the insertion place, move it
 185       ;; along with the text.
 186       (if (> delta 0)
 187           (goto-char (+ (process-mark proc) delta))))))
 188
 189 (defun telnet-send-input ()
 190   (interactive)
 191 ;  (comint-send-input telnet-new-line telnet-remote-echoes)
 192   (comint-send-input)
 193   (if telnet-remote-echoes
 194       (delete-region comint-last-input-start
 195                      comint-last-input-end)))
 196
 197 ;;;###autoload (add-hook 'same-window-regexps "\\*telnet-.*\\*\\(\\|<[0-9]+>\\)")
 198
 199 ;;;###autoload
 200 (defun telnet (host)
 201   "Open a network login connection to host named HOST (a string).
 202 Communication with HOST is recorded in a buffer `*PROGRAM-HOST*'
 203 where PROGRAM is the telnet program being used.  This program
 204 is controlled by the contents of the global variable `telnet-host-properties',
 205 falling back on the value of the global variable `telnet-program'.
 206 Normally input is edited in Emacs and sent a line at a time."
 207   (interactive "sOpen connection to host: ")
 208   (let* ((comint-delimiter-argument-list '(?\  ?\t))
 209          (properties (cdr (assoc host telnet-host-properties)))
 210          (telnet-program (if properties (car properties) telnet-program))
 211          (name (concat telnet-program "-" (comint-arguments host 0 nil) ))
 212          (buffer (get-buffer (concat "*" name "*")))
 213          (telnet-options (if (cdr properties) (cons "-l" (cdr properties))))
 214          process)
 215     (if (and buffer (get-buffer-process buffer))
 216         (pop-to-buffer (concat "*" name "*"))
 217       (pop-to-buffer
 218        (apply 'make-comint name telnet-program nil telnet-options))
 219       (setq process (get-buffer-process (current-buffer)))
 220       (set-process-filter process 'telnet-initial-filter)
 221       ;; Don't send the `open' cmd till telnet is ready for it.
 222       (accept-process-output process)
 223       (erase-buffer)
 224       (send-string process (concat "open " host "\n"))
 225       (telnet-mode)
 226       (setq comint-input-sender 'telnet-simple-send)
 227       (setq telnet-count telnet-initial-count))))
 228
 229 (put 'telnet-mode 'mode-class 'special)
 230
 231 (defun telnet-mode ()
 232   "This mode is for using telnet (or rsh) from a buffer to another host.
 233 It has most of the same commands as comint-mode.
 234 There is a variable ``telnet-interrupt-string'' which is the character
 235 sent to try to stop execution of a job on the remote host.
 236 Data is sent to the remote host when RET is typed.
 237
 238 \\{telnet-mode-map}
 239 "
 240   (interactive)
 241   (comint-mode)
 242   (setq major-mode 'telnet-mode
 243         mode-name "Telnet"
 244         comint-prompt-regexp telnet-prompt-pattern)
 245   (use-local-map telnet-mode-map)
 246   (run-hooks 'telnet-mode-hook))
 247
 248 ;;;###autoload (add-hook 'same-window-regexps "\\*rsh-[^-]*\\*\\(\\|<[0-9]*>\\)")
 249
 250 ;;;###autoload
 251 (defun rsh (host)
 252   "Open a network login connection to host named HOST (a string).
 253 Communication with HOST is recorded in a buffer `*rsh-HOST*'.
 254 Normally input is edited in Emacs and sent a line at a time."
 255   (interactive "sOpen rsh connection to host: ")
 256   (require 'shell)
 257   (let ((name (concat "rsh-" host )))
 258     (pop-to-buffer (make-comint name remote-shell-program nil host))
 259     (set-process-filter (get-process name) 'telnet-initial-filter)
 260     (telnet-mode)
 261     (setq telnet-count -16)))
 262
 263 (provide 'telnet)
 264
 265 ;;; telnet.el ends here