configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  49 dnl Create a new --with option that defaults to being disabled.
  50 dnl NAME is the base name of the option.  The shell variable with_NAME
  51 dnl   will be set to either the user's value (if the option is
  52 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  53 dnl   option is not specified).  Note that the shell variable name is
  54 dnl   constructed as autoconf does, by replacing non-alphanumeric
  55 dnl   characters with "_".
  56 dnl HELP-STRING is the help text for the option.
  57 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  58   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  59     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  60 ])dnl
  61
  62 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  63 dnl Create a new --with option that defaults to being enabled.  NAME
  64 dnl   is the base name of the option.  The shell variable with_NAME
  65 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  66 dnl   'yes' (if the option is not specified).  Note that the shell
  67 dnl   variable name is constructed as autoconf does, by replacing
  68 dnl   non-alphanumeric characters with "_".
  69 dnl HELP-STRING is the help text for the option.
  70 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  71   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  72    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  73 ])dnl
  74
  75 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  76 if test "$with_pop" = yes; then
  77    AC_DEFINE(MAIL_USE_POP)
  78 fi
  79 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  80
  81 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  82 if test "$with_kerberos" != no; then
  83    AC_DEFINE(KERBEROS)
  84 fi
  85 AH_TEMPLATE(KERBEROS,
  86             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  87
  88 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  89 if test "${with_kerberos5}" != no; then
  90   if test "${with_kerberos}" = no; then
  91     with_kerberos=yes
  92     AC_DEFINE(KERBEROS)
  93   fi
  94   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  95 fi
  96
  97 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  98 dnl FIXME hesiod support may not be present, so it seems like an error
  99 dnl to define, or at least use, this unconditionally.
 100 if test "$with_hesiod" != no; then
 101   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 102 fi
 103
 104 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 105 if test "$with_mmdf" != no; then
 106    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 107 fi
 108
 109 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 110 if test "$with_mail_unlink" != no; then
 111    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 112 fi
 113
 114 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 115     [string giving default POP mail host])],
 116     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 117
 118 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 119
 120 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 121 if test "$with_sync_input" = yes; then
 122    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 123 fi
 124
 125 dnl FIXME currently it is not the last.
 126 dnl This should be the last --with option, because --with-x is
 127 dnl added later on when we find the path of X, and it's best to
 128 dnl keep them together visually.
 129 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 130  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 131 [         case "${withval}" in
 132             y | ye | yes )      val=gtk ;;
 133             n | no )            val=no  ;;
 134             l | lu | luc | luci | lucid )       val=lucid ;;
 135             a | at | ath | athe | athen | athena )      val=athena ;;
 136             m | mo | mot | moti | motif )       val=motif ;;
 137             g | gt | gtk  )     val=gtk ;;
 138             gtk3  )     val=gtk3 ;;
 139             * )
 140 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 141 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 142 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 143             ;;
 144           esac
 145           with_x_toolkit=$val
 146 ])
 147
 148 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 149 if test "$with_wide_int" = yes; then
 150   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 151 fi
 152
 153 dnl _ON results in a '--without' option in the --help output, so
 154 dnl the help text should refer to "don't compile", etc.
 155 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 156 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 157 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 158 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 159 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 160 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 161 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 162 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 163
 164 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 165 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 166 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 167
 168 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 169 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 170 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 171 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 172
 173 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 174 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 175 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 176 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 177 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 178 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 179
 180 ## For the times when you want to build Emacs but don't have
 181 ## a suitable makeinfo, and can live without the manuals.
 182 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 183 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 184
 185 ## Makefile.in needs the cache file name.
 186 AC_SUBST(cache_file)
 187
 188 ## This is an option because I do not know if all info/man support
 189 ## compressed files, nor how to test if they do so.
 190 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 191 if test $with_compress_info = yes; then
 192    GZIP_INFO=yes
 193 else
 194    GZIP_INFO=
 195 fi
 196 AC_SUBST(GZIP_INFO)
 197
 198 AC_ARG_WITH([pkg-config-prog],dnl
 199 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 200                   [path to pkg-config for finding GTK and librsvg])])
 201 if test "X${with_pkg_config_prog}" != X; then
 202    if test "${with_pkg_config_prog}" != yes; then
 203       PKG_CONFIG="${with_pkg_config_prog}"
 204    fi
 205 fi
 206
 207 CRT_DIR=
 208 AC_ARG_WITH([crt-dir],dnl
 209 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 210 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 211 CRT_DIR="${with_crt_dir}"
 212
 213 AC_ARG_WITH(gameuser,dnl
 214 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 215 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 216   && gameuser="${with_gameuser}"
 217 test "X$gameuser" = X && gameuser=games
 218
 219 AC_ARG_WITH([gnustep-conf],dnl
 220 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 221 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 222   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 223 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 224      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 225
 226 AC_ARG_ENABLE(ns-self-contained,
 227 [AS_HELP_STRING([--disable-ns-self-contained],
 228                 [disable self contained build under NeXTstep])],
 229    EN_NS_SELF_CONTAINED=$enableval,
 230    EN_NS_SELF_CONTAINED=yes)
 231
 232 AC_ARG_ENABLE(asserts,
 233 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 234       USE_XASSERTS=$enableval,
 235       USE_XASSERTS=no)
 236
 237 AC_ARG_ENABLE(maintainer-mode,
 238 [AS_HELP_STRING([--disable-maintainer-mode],
 239                 [disable make rules and dependencies not useful (and sometimes
 240                  confusing) to the casual installer])],
 241       USE_MAINTAINER_MODE=$enableval,
 242       USE_MAINTAINER_MODE=yes)
 243 if test $USE_MAINTAINER_MODE = yes; then
 244   MAINT=
 245 else
 246   MAINT=#
 247 fi
 248 AC_SUBST(MAINT)
 249
 250 AC_ARG_ENABLE(locallisppath,
 251 [AS_HELP_STRING([--enable-locallisppath=PATH],
 252                 [directories Emacs should search for lisp files specific
 253                  to this site])],
 254 if test "${enableval}" = "no"; then
 255   locallisppath=
 256 elif test "${enableval}" != "yes"; then
 257   locallisppath=${enableval}
 258 fi)
 259
 260 AC_ARG_ENABLE(checking,
 261 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 262                 [enable expensive run-time checks.  With LIST,
 263                  enable only specific categories of checks.
 264                  Categories are: all,yes,no.
 265                  Flags are: stringbytes, stringoverrun, stringfreelist,
 266                  xmallocoverrun, conslist])],
 267 [ac_checking_flags="${enableval}"],[])
 268 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 269 for check in $ac_checking_flags
 270 do
 271         case $check in
 272         # these set all the flags to specific states
 273         yes)            ac_enable_checking=1 ;;
 274         no)             ac_enable_checking= ;
 275                         ac_gc_check_stringbytes= ;
 276                         ac_gc_check_string_overrun= ;
 277                         ac_gc_check_string_free_list= ;
 278                         ac_xmalloc_overrun= ;
 279                         ac_gc_check_cons_list= ;;
 280         all)            ac_enable_checking=1 ;
 281                         ac_gc_check_stringbytes=1 ;
 282                         ac_gc_check_string_overrun=1 ;
 283                         ac_gc_check_string_free_list=1 ;
 284                         ac_xmalloc_overrun=1 ;
 285                         ac_gc_check_cons_list=1 ;;
 286         # these enable particular checks
 287         stringbytes)    ac_gc_check_stringbytes=1 ;;
 288         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 289         stringfreelist) ac_gc_check_string_free_list=1 ;;
 290         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 291         conslist)       ac_gc_check_cons_list=1 ;;
 292         *)      AC_MSG_ERROR(unknown check category $check) ;;
 293         esac
 294 done
 295 IFS="$ac_save_IFS"
 296
 297 if test x$ac_enable_checking != x ; then
 298   AC_DEFINE(ENABLE_CHECKING, 1,
 299 [Enable expensive run-time checking of data types?])
 300 fi
 301 if test x$ac_gc_check_stringbytes != x ; then
 302   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 303 [Define this temporarily to hunt a bug.  If defined, the size of
 304    strings is redundantly recorded in sdata structures so that it can
 305    be compared to the sizes recorded in Lisp strings.])
 306 fi
 307 if test x$ac_gc_check_string_overrun != x ; then
 308   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 309 [Define this to check for short string overrun.])
 310 fi
 311 if test x$ac_gc_check_string_free_list != x ; then
 312   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 313 [Define this to check the string free list.])
 314 fi
 315 if test x$ac_xmalloc_overrun != x ; then
 316   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 317 [Define this to check for malloc buffer overrun.])
 318 fi
 319 if test x$ac_gc_check_cons_list != x ; then
 320   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 321 [Define this to check for errors in cons list.])
 322 fi
 323
 324 AC_ARG_ENABLE(use-lisp-union-type,
 325 [AS_HELP_STRING([--enable-use-lisp-union-type],
 326                 [use a union for the Lisp_Object data type.
 327                 This is only useful for development for catching certain types of bugs.])],
 328 if test "${enableval}" != "no"; then
 329    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 330    [Define this to use a lisp union for the Lisp_Object data type.])
 331 fi)
 332
 333
 334 AC_ARG_ENABLE(profiling,
 335 [AS_HELP_STRING([--enable-profiling],
 336                 [build emacs with profiling support.
 337                  This might not work on all platforms])],
 338 [ac_enable_profiling="${enableval}"],[])
 339 if test x$ac_enable_profiling != x ; then
 340    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 341 else
 342    PROFILING_CFLAGS=
 343 fi
 344 AC_SUBST(PROFILING_CFLAGS)
 345
 346 AC_ARG_ENABLE(autodepend,
 347 [AS_HELP_STRING([--enable-autodepend],
 348                 [automatically generate dependencies to .h-files.
 349                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 350                  found])],
 351 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 352
 353 #### Make srcdir absolute, if it isn't already.  It's important to
 354 #### avoid running the path through pwd unnecessarily, since pwd can
 355 #### give you automounter prefixes, which can go away.  We do all this
 356 #### so Emacs can find its files when run uninstalled.
 357 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 358 unset CDPATH
 359 case "${srcdir}" in
 360   /* ) ;;
 361   . )
 362     ## We may be able to use the $PWD environment variable to make this
 363     ## absolute.  But sometimes PWD is inaccurate.
 364     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 365     ## but that tested only for a well-formed and valid PWD,
 366     ## it did not object when PWD was well-formed and valid but just wrong.
 367     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 368     then
 369       srcdir="$PWD"
 370     else
 371       srcdir="`(cd ${srcdir}; pwd)`"
 372     fi
 373   ;;
 374   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 375 esac
 376
 377 #### Given the configuration name, set machfile and opsysfile to the
 378 #### names of the m/*.h and s/*.h files we should use.
 379
 380 ### Canonicalize the configuration name.
 381
 382 AC_CANONICAL_HOST
 383 canonical=$host
 384 configuration=${host_alias-${build_alias-$host}}
 385
 386 dnl This used to use changequote, but, apart from `changequote is evil'
 387 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 388 dnl the great gob of text.  Thus it's not processed for possible expansion.
 389 dnl Just make sure the brackets remain balanced.
 390 dnl
 391 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 392 dnl indicated by comments.
 393 dnl quotation begins
 394 [
 395
 396 ### If you add support for a new configuration, add code to this
 397 ### switch statement to recognize your configuration name and select
 398 ### the appropriate operating system and machine description files.
 399
 400 ### You would hope that you could choose an m/*.h file pretty much
 401 ### based on the machine portion of the configuration name, and an s/*.h
 402 ### file based on the operating system portion.  However, it turns out
 403 ### that each m/*.h file is pretty manufacturer-specific - for
 404 ### example mips.h is MIPS
 405 ### So we basically have to have a special case for each
 406 ### configuration name.
 407 ###
 408 ### As far as handling version numbers on operating systems is
 409 ### concerned, make sure things will fail in a fixable way.  If
 410 ### /etc/MACHINES doesn't say anything about version numbers, be
 411 ### prepared to handle anything reasonably.  If version numbers
 412 ### matter, be sure /etc/MACHINES says something about it.
 413
 414 machine='' opsys='' unported=no
 415 case "${canonical}" in
 416
 417   ## GNU/Linux and similar ports
 418   *-*-linux* )
 419     opsys=gnu-linux
 420     case ${canonical} in
 421       alpha*)   machine=alpha ;;
 422       s390x-*)  machine=ibms390x ;;
 423       powerpc*) machine=macppc ;;
 424       sparc*)   machine=sparc ;;
 425       ia64*)    machine=ia64 ;;
 426       m68k*)    machine=m68k ;;
 427       x86_64*)  machine=amdx86-64 ;;
 428     esac
 429   ;;
 430
 431   ## FreeBSD ports
 432   *-*-freebsd* )
 433     opsys=freebsd
 434     case "${canonical}" in
 435       alpha*)           machine=alpha ;;
 436       amd64-*|x86_64-*) machine=amdx86-64 ;;
 437       ia64-*)           machine=ia64 ;;
 438       i[3456]86-*)      machine=intel386 ;;
 439       powerpc-*)        machine=macppc ;;
 440       sparc-*)          machine=sparc ;;
 441       sparc64-*)        machine=sparc ;;
 442     esac
 443   ;;
 444
 445   ## FreeBSD kernel + glibc based userland
 446   *-*-kfreebsd*gnu* )
 447     opsys=gnu-kfreebsd
 448     case "${canonical}" in
 449       alpha*)           machine=alpha ;;
 450       amd64-*|x86_64-*) machine=amdx86-64 ;;
 451       ia64-*)           machine=ia64 ;;
 452       i[3456]86-*)      machine=intel386 ;;
 453       powerpc-*)        machine=macppc ;;
 454       sparc-*)          machine=sparc ;;
 455       sparc64-*)        machine=sparc ;;
 456     esac
 457   ;;
 458
 459   ## NetBSD ports
 460   *-*-netbsd* )
 461     opsys=netbsd
 462     case "${canonical}" in
 463       alpha*)      machine=alpha ;;
 464       x86_64-*)    machine=amdx86-64 ;;
 465       i[3456]86-*) machine=intel386 ;;
 466       m68k-*)      machine=m68k ;;
 467       powerpc-*)   machine=macppc ;;
 468       sparc*-)     machine=sparc ;;
 469     esac
 470   ;;
 471
 472   ## OpenBSD ports
 473   *-*-openbsd* )
 474     opsys=openbsd
 475     case "${canonical}" in
 476       alpha*)    machine=alpha ;;
 477       x86_64-*)  machine=amdx86-64 ;;
 478       i386-*)    machine=intel386 ;;
 479       powerpc-*) machine=macppc ;;
 480       sparc*)    machine=sparc ;;
 481     esac
 482   ;;
 483
 484   ## Apple Darwin / Mac OS X
 485   *-apple-darwin* )
 486     case "${canonical}" in
 487       i[3456]86-* )  machine=intel386 ;;
 488       powerpc-* )    machine=macppc ;;
 489       x86_64-* )     machine=amdx86-64 ;;
 490       * )            unported=yes ;;
 491     esac
 492     opsys=darwin
 493     ## Use fink packages if available.
 494     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 495 ##    if test -d /sw/include && test -d /sw/lib; then
 496 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 497 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 498 ##    fi
 499   ;;
 500
 501   ## HP 9000 series 700 and 800, running HP/UX
 502   hppa*-hp-hpux10.2* )
 503     opsys=hpux10-20
 504   ;;
 505   hppa*-hp-hpux1[1-9]* )
 506     opsys=hpux11
 507     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 508   ;;
 509
 510   ## IBM machines
 511   rs6000-ibm-aix4.[23]* )
 512     machine=ibmrs6000 opsys=aix4-2
 513   ;;
 514   powerpc-ibm-aix4.[23]*  )
 515     machine=ibmrs6000 opsys=aix4-2
 516   ;;
 517   rs6000-ibm-aix[56]* )
 518     machine=ibmrs6000 opsys=aix4-2
 519   ;;
 520   powerpc-ibm-aix[56]*  )
 521     machine=ibmrs6000 opsys=aix4-2
 522   ;;
 523
 524   ## Silicon Graphics machines
 525   ## Iris 4D
 526   mips-sgi-irix6.5 )
 527     opsys=irix6-5
 528     # Without defining _LANGUAGE_C, things get masked out in the headers
 529     # so that, for instance, grepping for `free' in stdlib.h fails and
 530     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 531     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 532   ;;
 533
 534   ## Suns
 535   *-sun-solaris* \
 536     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 537     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 538     case "${canonical}" in
 539       i[3456]86-*-* )     machine=intel386 ;;
 540       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 541       sparc* )          machine=sparc ;;
 542       * )               unported=yes ;;
 543     esac
 544     case "${canonical}" in
 545       *-sunos5.6* | *-solaris2.6* )
 546                 opsys=sol2-6
 547                 RANLIB="ar -ts"
 548                 ;;
 549       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 550                 opsys=sol2-6
 551                 emacs_check_sunpro_c=yes
 552                 ;;
 553       *-sunos5* | *-solaris* )
 554                 opsys=sol2-10
 555                 emacs_check_sunpro_c=yes
 556                 ;;
 557     esac
 558     ## Watch out for a compiler that we know will not work.
 559     case "${canonical}" in
 560      *-solaris* | *-sunos5* )
 561                 if [ "x$CC" = x/usr/ucb/cc ]; then
 562                   ## /usr/ucb/cc doesn't work;
 563                   ## we should find some other compiler that does work.
 564                   unset CC
 565                 fi
 566                 ;;
 567       *) ;;
 568     esac
 569   ;;
 570
 571   ## Intel 386 machines where we don't care about the manufacturer.
 572   i[3456]86-*-* )
 573     machine=intel386
 574     case "${canonical}" in
 575       *-cygwin )                opsys=cygwin ;;
 576       *-darwin* )               opsys=darwin ;;
 577       *-sysv4.2uw* )            opsys=unixware ;;
 578       *-sysv5uw* )              opsys=unixware ;;
 579       *-sysv5OpenUNIX* )        opsys=unixware ;;
 580       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 581     esac
 582   ;;
 583
 584   * )
 585     unported=yes
 586   ;;
 587 esac
 588
 589 ### If the code above didn't choose an operating system, just choose
 590 ### an operating system based on the configuration name.  You really
 591 ### only want to use this when you have no idea what the right
 592 ### operating system is; if you know what operating systems a machine
 593 ### runs, it's cleaner to make it explicit in the case statement
 594 ### above.
 595 if test x"${opsys}" = x; then
 596   case "${canonical}" in
 597     *-gnu* )                            opsys=gnu ;;
 598     * )
 599       unported=yes
 600     ;;
 601   esac
 602 fi
 603
 604 ]
 605 dnl quotation ends
 606
 607 if test $unported = yes; then
 608   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 609 Check `etc/MACHINES' for recognized configuration names.])
 610 fi
 611
 612 if test -n "$machine"; then
 613   machfile="m/${machine}.h"
 614 else
 615   machfile=
 616 fi
 617 opsysfile="s/${opsys}.h"
 618
 619
 620 #### Choose a compiler.
 621
 622 dnl Sets GCC=yes if using gcc.
 623 AC_PROG_CC
 624 AM_PROG_CC_C_O
 625
 626 if test x$GCC = xyes; then
 627   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 628 else
 629   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 630 fi
 631
 632 # Initialize gnulib right after choosing the compiler.
 633 gl_EARLY
 634
 635 AC_ARG_ENABLE([gcc-warnings],
 636   [AS_HELP_STRING([--enable-gcc-warnings],
 637                   [turn on lots of GCC warnings (for developers)])],
 638   [case $enableval in
 639      yes|no) ;;
 640      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 641    esac
 642    gl_gcc_warnings=$enableval],
 643   [gl_gcc_warnings=no]
 644 )
 645
 646 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 647 # ------------------------------------------------
 648 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 649 # Otherwise, run RUN-IF-NOT-FOUND.
 650 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 651   [AC_PREPROC_IFELSE(
 652     [AC_LANG_PROGRAM(
 653       [[
 654 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 655 /* ok */
 656 #else
 657 # error "your version of gcc is older than $1.$2"
 658 #endif
 659       ]]),
 660     ], [$3], [$4])
 661   ]
 662 )
 663
 664 # When compiling with GCC, prefer -isystem to -I when including system
 665 # include files, to avoid generating useless diagnostics for the files.
 666 if test "$gl_gcc_warnings" != yes; then
 667   isystem='-I'
 668 else
 669   isystem='-isystem '
 670
 671   # This, $nw, is the list of warnings we disable.
 672   nw=
 673
 674   case $with_x_toolkit in
 675     lucid | athena | motif)
 676        # Old toolkits mishandle 'const'.
 677        nw="$nw -Wwrite-strings"
 678        ;;
 679     *)
 680        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 681        ;;
 682   esac
 683   AC_SUBST([WERROR_CFLAGS])
 684
 685   nw="$nw -Waggregate-return"       # anachronistic
 686   nw="$nw -Wlong-long"              # C90 is anachronistic
 687   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 688   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 689   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 690   nw="$nw -Wcast-qual"              # Too many warnings for now
 691   nw="$nw -Wconversion"             # Too many warnings for now
 692   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 693   nw="$nw -Wsign-conversion"        # Too many warnings for now
 694   nw="$nw -Woverlength-strings"     # Not a problem these days
 695   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 696   nw="$nw -Wpadded"                 # Our structs are not padded
 697   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 698   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 699   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 700   nw="$nw -Wvla"                    # warnings in gettext.h
 701   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 702   nw="$nw -Wswitch-enum"            # Too many warnings for now
 703   nw="$nw -Wswitch-default"         # Too many warnings for now
 704   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 705   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 706
 707   # Emacs doesn't care about shadowing; see
 708   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 709   nw="$nw -Wshadow"
 710
 711   # The following lines should be removable at some point.
 712   nw="$nw -Wstack-protector"
 713   nw="$nw -Wstrict-overflow"
 714   nw="$nw -Wsuggest-attribute=const"
 715   nw="$nw -Wsuggest-attribute=pure"
 716
 717   gl_MANYWARN_ALL_GCC([ws])
 718   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 719   for w in $ws; do
 720     gl_WARN_ADD([$w])
 721   done
 722   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 723   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 724   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 725   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 726   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 727   gl_WARN_ADD([-Wno-format-nonliteral])
 728
 729   # In spite of excluding -Wlogical-op above, it is enabled, as of
 730   # gcc 4.5.0 20090517.
 731   gl_WARN_ADD([-Wno-logical-op])
 732
 733   gl_WARN_ADD([-fdiagnostics-show-option])
 734   gl_WARN_ADD([-funit-at-a-time])
 735
 736   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 737   AC_DEFINE([_FORTIFY_SOURCE], [2],
 738     [enable compile-time and run-time bounds-checking, and some warnings])
 739   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 740
 741   # We use a slightly smaller set of warning options for lib/.
 742   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 743   nw=
 744   nw="$nw -Wunused-macros"
 745
 746   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 747   AC_SUBST([GNULIB_WARN_CFLAGS])
 748 fi
 749
 750
 751
 752 dnl Some other nice autoconf tests.
 753 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 754 dnl AC_PROG_INSTALL
 755 dnl AC_PROG_MKDIR_P
 756 dnl if test "x$RANLIB" = x; then
 757 dnl   AC_PROG_RANLIB
 758 dnl fi
 759
 760 ## Although we're running on an amd64 kernel, we're actually compiling for
 761 ## the x86 architecture.  The user should probably have provided an
 762 ## explicit --build to `configure', but if everything else than the kernel
 763 ## is running in i386 mode, we can help them out.
 764 if test "$machine" = "amdx86-64"; then
 765   AC_CHECK_DECL([i386])
 766   if test "$ac_cv_have_decl_i386" = "yes"; then
 767     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 768     machine=intel386
 769     machfile="m/${machine}.h"
 770   fi
 771 fi
 772
 773 AC_PATH_PROG(INSTALL_INFO, install-info)
 774 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 775 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 776 dnl Don't use GZIP, which is used by gzip for additional parameters.
 777 AC_PATH_PROG(GZIP_PROG, gzip)
 778
 779
 780 ## Need makeinfo >= 4.7 (?) to build the manuals.
 781 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 782 dnl By this stage, configure has already checked for egrep and set EGREP,
 783 dnl or exited with an error if no egrep was found.
 784 if test "$MAKEINFO" != "no" && \
 785   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 786    MAKEINFO=no
 787 fi
 788
 789 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 790 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 791 ## therefore in the category of "special tools" not normally required, which
 792 ## configure does not have to check for (eg autoconf itself).
 793 ## In a Bazaar checkout on the other hand, the manuals are not included.
 794 ## So makeinfo is a requirement to build from Bazaar, and configure
 795 ## should test for it as it does for any other build requirement.
 796 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 797 ## with pre-built manuals, from a Bazaar checkout.
 798 HAVE_MAKEINFO=yes
 799
 800 if test "$MAKEINFO" = "no"; then
 801   MAKEINFO=makeinfo
 802   if test "x${with_makeinfo}" = "xno"; then
 803     HAVE_MAKEINFO=no
 804   elif test ! -e $srcdir/info/emacs; then
 805     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 806 source tree does not seem to have pre-built manuals in the `info' directory.
 807 Either install a suitable version of makeinfo, or re-run configure
 808 with the `--without-makeinfo' option to build without the manuals.] )
 809   fi
 810 fi
 811 AC_SUBST(HAVE_MAKEINFO)
 812
 813 dnl Just so that there is only a single place we need to edit.
 814 INFO_EXT=.info
 815 INFO_OPTS=--no-split
 816 AC_SUBST(INFO_EXT)
 817 AC_SUBST(INFO_OPTS)
 818
 819 dnl Add our options to ac_link now, after it is set up.
 820
 821 if test x$GCC = xyes; then
 822   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 823     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 824 else
 825   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 826     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 827 fi
 828
 829 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 830 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 831 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 832 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 833 dnl if not built to support GNU ld.
 834
 835 late_LDFLAGS=$LDFLAGS
 836 if test x$GCC = xyes; then
 837   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 838 else
 839   LDFLAGS="$LDFLAGS -znocombreloc"
 840 fi
 841
 842 AC_MSG_CHECKING([for -znocombreloc])
 843 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 844   [AC_MSG_RESULT(yes)],
 845   LDFLAGS=$late_LDFLAGS
 846   [AC_MSG_RESULT(no)])
 847
 848
 849 dnl The function dump-emacs will not be defined and temacs will do
 850 dnl (load "loadup") automatically unless told otherwise.
 851 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 852 case "$opsys" in
 853   your-opsys-here) CANNOT_DUMP=yes ;;
 854 esac
 855
 856 test "$CANNOT_DUMP" = "yes" && \
 857   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 858
 859 AC_SUBST(CANNOT_DUMP)
 860
 861
 862 UNEXEC_OBJ=unexelf.o
 863 case "$opsys" in
 864   # MSDOS uses unexcoff.o
 865   # MSWindows uses unexw32.o
 866   aix4-2)
 867    UNEXEC_OBJ=unexaix.o
 868    ;;
 869   cygwin)
 870    UNEXEC_OBJ=unexcw.o
 871    ;;
 872   darwin)
 873    UNEXEC_OBJ=unexmacosx.o
 874    ;;
 875   hpux10-20 | hpux11)
 876    UNEXEC_OBJ=unexhp9k800.o
 877    ;;
 878   sol2-10)
 879    # Use the Solaris dldump() function, called from unexsol.c, to dump
 880    # emacs, instead of the generic ELF dump code found in unexelf.c.
 881    # The resulting binary has a complete symbol table, and is better
 882    # for debugging and other observability tools (debuggers, pstack, etc).
 883    #
 884    # If you encounter a problem using dldump(), please consider sending
 885    # a message to the OpenSolaris tools-linking mailing list:
 886    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 887    #
 888    # It is likely that dldump() works with older Solaris too, but this has
 889    # not been tested, so for now this change is for Solaris 10 or newer.
 890    UNEXEC_OBJ=unexsol.o
 891    ;;
 892 esac
 893
 894 LD_SWITCH_SYSTEM=
 895 case "$opsys" in
 896   freebsd)
 897    ## Let `ld' find image libs and similar things in /usr/local/lib.
 898    ## The system compiler, GCC, has apparently been modified to not
 899    ## look there, contrary to what a stock GCC would do.
 900 ### It's not our place to do this.  See bug#10313#17.
 901 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 902       :
 903    ;;
 904
 905   gnu-linux)
 906    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 907    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 908    ;;
 909
 910   netbsd)
 911 ### It's not our place to do this.  See bug#10313#17.
 912 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 913       :
 914    ;;
 915
 916   openbsd)
 917    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 918    ## otherwise Emacs dumps core on elf systems.
 919    LD_SWITCH_SYSTEM="-Z"
 920    ;;
 921 esac
 922 AC_SUBST(LD_SWITCH_SYSTEM)
 923
 924 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 925
 926 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 927 ## which has not been defined yet.  When this was handled with cpp,
 928 ## it was expanded to null when configure sourced the s/*.h file.
 929 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 930 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 931 ## (or somesuch), but because it is supposed to go at the _front_
 932 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 933 ## Compare with the gnu-linux case below, which added to the end
 934 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 935 ## LD_SWITCH_SYSTEM_TEMACS.
 936 case "$opsys" in
 937   netbsd|openbsd)
 938    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 939 esac
 940
 941
 942 C_SWITCH_MACHINE=
 943 if test "$machine" = "alpha"; then
 944   AC_CHECK_DECL([__ELF__])
 945   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 946     ## With ELF, make sure that all common symbols get allocated to in the
 947     ## data section.  Otherwise, the dump of temacs may miss variables in
 948     ## the shared library that have been initialized.  For example, with
 949     ## GNU libc, __malloc_initialized would normally be resolved to the
 950     ## shared library's .bss section, which is fatal.
 951     if test "x$GCC" = "xyes"; then
 952       C_SWITCH_MACHINE="-fno-common"
 953     else
 954       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 955     fi
 956   else
 957     UNEXEC_OBJ=unexalpha.o
 958   fi
 959 fi
 960 AC_SUBST(C_SWITCH_MACHINE)
 961
 962 AC_SUBST(UNEXEC_OBJ)
 963
 964 C_SWITCH_SYSTEM=
 965 ## Some programs in src produce warnings saying certain subprograms
 966 ## are too complex and need a MAXMEM value greater than 2000 for
 967 ## additional optimization.  --nils@exp-math.uni-essen.de
 968 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 969   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 970 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 971 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 972 AC_SUBST(C_SWITCH_SYSTEM)
 973
 974
 975 LIBS_SYSTEM=
 976 case "$opsys" in
 977   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 978   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 979
 980   freebsd) LIBS_SYSTEM="-lutil" ;;
 981
 982   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 983
 984   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 985
 986   ## Motif needs -lgen.
 987   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 988 esac
 989 AC_SUBST(LIBS_SYSTEM)
 990
 991
 992 ### Make sure subsequent tests use flags consistent with the build flags.
 993
 994 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 995   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 996 else
 997   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 998 fi
 999
1000 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1001 AC_DEFUN([AC_TYPE_SIZE_T])
1002 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1003 AC_DEFUN([AC_TYPE_UID_T])
1004
1005 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1006 AC_SYS_LARGEFILE
1007
1008
1009 LIB_MATH=-lm
1010 LIB_STANDARD=
1011 START_FILES=
1012
1013 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1014 case $opsys in
1015   cygwin )
1016     LIB_MATH=
1017     START_FILES='pre-crt0.o'
1018     ;;
1019   darwin )
1020     ## Adding -lm confuses the dynamic linker, so omit it.
1021     LIB_MATH=
1022     START_FILES='pre-crt0.o'
1023     ;;
1024   freebsd )
1025     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1026     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1027     ;;
1028   gnu-linux | gnu-kfreebsd )
1029     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1030     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1031     ;;
1032   hpux10-20 | hpux11 )
1033     LIB_STANDARD=-lc
1034     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1035     ;;
1036   dnl NB this may be adjusted below.
1037   netbsd | openbsd )
1038     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1039     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1040     ;;
1041 esac
1042
1043 AC_SUBST(LIB_MATH)
1044 AC_SUBST(START_FILES)
1045
1046 dnl Not all platforms use crtn.o files.  Check if the current one does.
1047 crt_files=
1048
1049 for file in x $LIB_STANDARD $START_FILES; do
1050   case "$file" in
1051     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1052   esac
1053 done
1054
1055 if test "x$crt_files" != x; then
1056
1057   ## If user specified a crt-dir, use that unconditionally.
1058   crt_gcc=no
1059
1060   if test "X$CRT_DIR" = "X"; then
1061
1062     CRT_DIR=/usr/lib            # default
1063
1064     case "$canonical" in
1065       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1066       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1067       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1068       ## For anything else (eg /usr/lib32), it is up the user to specify
1069       ## the location (bug#5655).
1070       ## Test for crtn.o, not just the directory, because sometimes the
1071       ## directory exists but does not have the relevant files (bug#1287).
1072       ## FIXME better to test for binary compatibility somehow.
1073       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1074       ;;
1075
1076       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1077     esac
1078
1079     case "$opsys" in
1080       hpux10-20) CRT_DIR=/lib ;;
1081     esac
1082
1083     test "x${GCC}" = xyes && crt_gcc=yes
1084
1085   fi                            # CRT_DIR = ""
1086
1087   crt_missing=
1088
1089   for file in $crt_files; do
1090
1091     ## If we're using gcc, try to determine it automatically by asking
1092     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1093     ## system-dependent default from above.]
1094     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1095
1096        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1097        case "$crt_file" in
1098          */*)
1099            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1100            ;;
1101        esac
1102     fi
1103
1104     dnl We expect all the files to be in a single directory, so after the
1105     dnl first there is no point asking gcc.
1106     crt_gcc=no
1107
1108     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1109   done                          # $crt_files
1110
1111   test "x$crt_missing" = x || \
1112     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1113 Try using the --with-crt-dir option.])
1114
1115 fi                              # crt_files != ""
1116
1117 AC_SUBST(CRT_DIR)
1118
1119 case $opsys in
1120   netbsd | openbsd )
1121     if test -f $CRT_DIR/crti.o; then
1122
1123         test -f $CRT_DIR/crtn.o || \
1124           AC_MSG_ERROR([Required file not found: crtn.o])
1125
1126         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1127         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1128     fi
1129     ;;
1130 esac
1131
1132
1133 dnl This function definition taken from Gnome 2.0
1134 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1135 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1136 dnl also defines GSTUFF_PKG_ERRORS on error
1137 AC_DEFUN([PKG_CHECK_MODULES], [
1138   succeeded=no
1139
1140   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1141
1142   if test "$PKG_CONFIG" = "no" ; then
1143      ifelse([$4], , [AC_MSG_ERROR([
1144       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1145   else
1146      PKG_CONFIG_MIN_VERSION=0.9.0
1147      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1148         AC_MSG_CHECKING(for $2)
1149
1150         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1151            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1152            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1153             edit_cflags="
1154               s,///*,/,g
1155               s/^/ /
1156               s/ -I/ $isystem/g
1157               s/^ //
1158             "
1159             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1160             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1161             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1162             succeeded=yes
1163         else
1164             AC_MSG_RESULT(no)
1165             $1_CFLAGS=""
1166             $1_LIBS=""
1167             ## If we have a custom action on failure, don't print errors, but
1168             ## do set a variable so people can do so.
1169             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1170             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1171         fi
1172
1173         AC_SUBST($1_CFLAGS)
1174         AC_SUBST($1_LIBS)
1175      else
1176         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1177         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1178      fi
1179   fi
1180
1181   if test $succeeded = yes; then
1182      ifelse([$3], , :, [$3])
1183   else
1184      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1185   fi
1186 ])
1187
1188
1189 if test "${with_sound}" != "no"; then
1190   # Sound support for GNU/Linux and the free BSDs.
1191   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1192     have_sound_header=yes)
1193   # Emulation library used on NetBSD.
1194   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1195   AC_SUBST(LIBSOUND)
1196
1197   ALSA_REQUIRED=1.0.0
1198   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1199   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1200   if test $HAVE_ALSA = yes; then
1201     SAVE_CFLAGS="$CFLAGS"
1202     SAVE_LIBS="$LIBS"
1203     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1204     LIBS="$ALSA_LIBS $LIBS"
1205     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1206                     emacs_alsa_normal=yes,
1207                     emacs_alsa_normal=no)
1208     if test "$emacs_alsa_normal" != yes; then
1209       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1210                      [[snd_lib_error_set_handler (0);]])],
1211                      emacs_alsa_subdir=yes,
1212                      emacs_alsa_subdir=no)
1213       if test "$emacs_alsa_subdir" != yes; then
1214         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1215       fi
1216       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1217     fi
1218
1219     CFLAGS="$SAVE_CFLAGS"
1220     LIBS="$SAVE_LIBS"
1221     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1222     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1223     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1224   fi
1225
1226   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1227   dnl compiles only on the specified platforms.  For others, it
1228   dnl probably doesn't make sense to try.
1229   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1230      case "$opsys" in
1231        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1232        gnu-linux|freebsd|netbsd)
1233          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1234          ;;
1235      esac
1236   fi
1237
1238   AC_SUBST(CFLAGS_SOUND)
1239 fi
1240
1241 dnl checks for header files
1242 AC_CHECK_HEADERS(sys/select.h sys/time.h unistd.h utime.h \
1243   linux/version.h sys/systeminfo.h \
1244   stdio_ext.h fcntl.h coff.h pty.h sys/mman.h \
1245   sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1246   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1247
1248 AC_MSG_CHECKING(if personality LINUX32 can be set)
1249 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1250                emacs_cv_personality_linux32=yes,
1251                emacs_cv_personality_linux32=no)
1252 AC_MSG_RESULT($emacs_cv_personality_linux32)
1253
1254 if test $emacs_cv_personality_linux32 = yes; then
1255   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1256             [Define to 1 if personality LINUX32 can be set.])
1257 fi
1258
1259 dnl On Solaris 8 there's a compilation warning for term.h because
1260 dnl it doesn't define `bool'.
1261 AC_CHECK_HEADERS(term.h, , , -)
1262 AC_HEADER_TIME
1263 AC_CHECK_DECLS([sys_siglist])
1264 if test $ac_cv_have_decl_sys_siglist != yes; then
1265   # For Tru64, at least:
1266   AC_CHECK_DECLS([__sys_siglist])
1267   if test $ac_cv_have_decl___sys_siglist = yes; then
1268     AC_DEFINE(sys_siglist, __sys_siglist,
1269               [Define to any substitute for sys_siglist.])
1270   fi
1271 fi
1272 AC_HEADER_SYS_WAIT
1273
1274 dnl Some systems have utime.h but don't declare the struct anyplace.
1275 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1276 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1277 #include <sys/time.h>
1278 #include <time.h>
1279 #else
1280 #ifdef HAVE_SYS_TIME_H
1281 #include <sys/time.h>
1282 #else
1283 #include <time.h>
1284 #endif
1285 #endif
1286 #ifdef HAVE_UTIME_H
1287 #include <utime.h>
1288 #endif]], [[static struct utimbuf x; x.actime = x.modtime;]])],
1289   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1290 if test $emacs_cv_struct_utimbuf = yes; then
1291   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1292 fi
1293
1294 dnl Check for speed_t typedef.
1295 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1296   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1297     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1298 if test $emacs_cv_speed_t = yes; then
1299   AC_DEFINE(HAVE_SPEED_T, 1,
1300            [Define to 1 if `speed_t' is declared by <termios.h>.])
1301 fi
1302
1303 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1304 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef TIME_WITH_SYS_TIME
1305 #include <sys/time.h>
1306 #include <time.h>
1307 #else
1308 #ifdef HAVE_SYS_TIME_H
1309 #include <sys/time.h>
1310 #else
1311 #include <time.h>
1312 #endif
1313 #endif]], [[static struct timeval x; x.tv_sec = x.tv_usec;]])],
1314   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1315 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1316 if test $emacs_cv_struct_timeval = yes; then
1317   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1318 fi
1319
1320 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1321 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1322 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1323   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1324 HAVE_EXCEPTION=$emacs_cv_struct_exception
1325 if test $emacs_cv_struct_exception != yes; then
1326   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1327 fi
1328
1329 AC_CHECK_HEADERS(sys/socket.h)
1330 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1331 #if HAVE_SYS_SOCKET_H
1332 #include <sys/socket.h>
1333 #endif])
1334 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1335 #if HAVE_SYS_SOCKET_H
1336 #include <sys/socket.h>
1337 #endif])
1338 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1339 #if HAVE_SYS_SOCKET_H
1340 #include <sys/socket.h>
1341 #endif])
1342 AC_CHECK_FUNCS(getifaddrs freeifaddrs)
1343
1344 dnl checks for structure members
1345 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1346                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1347                   struct ifreq.ifr_addr,
1348                   struct ifreq.ifr_addr.sa_len], , ,
1349                  [AC_INCLUDES_DEFAULT
1350 #if HAVE_SYS_SOCKET_H
1351 #include <sys/socket.h>
1352 #endif
1353 #if HAVE_NET_IF_H
1354 #include <net/if.h>
1355 #endif])
1356
1357 dnl checks for compiler characteristics
1358
1359 dnl Testing __STDC__ to determine prototype support isn't good enough.
1360 dnl DEC C, for instance, doesn't define it with default options, and
1361 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1362 dnl and void *.
1363 AC_C_PROTOTYPES
1364 AC_C_VOLATILE
1365 AC_C_CONST
1366 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1367   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [[void * foo;]])],
1368                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1369 if test $emacs_cv_void_star = yes; then
1370   AC_DEFINE(POINTER_TYPE, void)
1371 else
1372   AC_DEFINE(POINTER_TYPE, char)
1373 fi
1374 AH_TEMPLATE(POINTER_TYPE,
1375             [Define as `void' if your compiler accepts `void *'; otherwise
1376              define as `char'.])dnl
1377
1378 dnl Check for endianness.
1379 AC_C_BIGENDIAN
1380
1381 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1382   [emacs_cv_attribute_aligned],
1383   [AC_COMPILE_IFELSE(
1384      [AC_LANG_PROGRAM(
1385         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1386         [[]])],
1387      [emacs_cv_attribute_aligned=yes],
1388      [emacs_cv_attribute_aligned=no])])
1389 if test $emacs_cv_attribute_aligned = yes; then
1390   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1391     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1392 fi
1393
1394 dnl check for Make feature
1395 AC_PROG_MAKE_SET
1396
1397 DEPFLAGS=
1398 MKDEPDIR=":"
1399 deps_frag=deps.mk
1400 dnl check for GNU Make if we have GCC and autodepend is on.
1401 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1402    AC_MSG_CHECKING([whether we are using GNU Make])
1403    HAVE_GNU_MAKE=no
1404    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1405    if test "x$testval" != x; then
1406       HAVE_GNU_MAKE=yes
1407    else
1408       ac_enable_autodepend=no
1409    fi
1410    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1411    if test $HAVE_GNU_MAKE = yes; then
1412       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1413       SAVE_CFLAGS="$CFLAGS"
1414       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1415       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1416       CFLAGS="$SAVE_CFLAGS"
1417       test -f deps.d || ac_enable_autodepend=no
1418       rm -rf deps.d
1419       AC_MSG_RESULT([$ac_enable_autodepend])
1420    fi
1421    if test $ac_enable_autodepend = yes; then
1422       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1423       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1424       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1425       deps_frag=autodeps.mk
1426    fi
1427 fi
1428 deps_frag=$srcdir/src/$deps_frag
1429 AC_SUBST(MKDEPDIR)
1430 AC_SUBST(DEPFLAGS)
1431 AC_SUBST_FILE(deps_frag)
1432
1433
1434 lisp_frag=$srcdir/src/lisp.mk
1435 AC_SUBST_FILE(lisp_frag)
1436
1437
1438 dnl checks for operating system services
1439 AC_SYS_LONG_FILE_NAMES
1440
1441 #### Choose a window system.
1442
1443 AC_PATH_X
1444 if test "$no_x" = yes; then
1445   window_system=none
1446 else
1447   window_system=x11
1448 fi
1449
1450 LD_SWITCH_X_SITE_RPATH=
1451 if test "${x_libraries}" != NONE; then
1452   if test -n "${x_libraries}"; then
1453     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1454     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1455   fi
1456   x_default_search_path=""
1457   x_search_path=${x_libraries}
1458   if test -z "${x_search_path}"; then
1459     x_search_path=/usr/lib
1460   fi
1461   for x_library in `echo ${x_search_path}: | \
1462                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1463     x_search_path="\
1464 ${x_library}/X11/%L/%T/%N%C%S:\
1465 ${x_library}/X11/%l/%T/%N%C%S:\
1466 ${x_library}/X11/%T/%N%C%S:\
1467 ${x_library}/X11/%L/%T/%N%S:\
1468 ${x_library}/X11/%l/%T/%N%S:\
1469 ${x_library}/X11/%T/%N%S"
1470     if test x"${x_default_search_path}" = x; then
1471       x_default_search_path=${x_search_path}
1472     else
1473       x_default_search_path="${x_search_path}:${x_default_search_path}"
1474     fi
1475   done
1476 fi
1477 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1478
1479 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1480   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1481 fi
1482
1483 if test x"${x_includes}" = x; then
1484   bitmapdir=/usr/include/X11/bitmaps
1485 else
1486   # accumulate include directories that have X11 bitmap subdirectories
1487   bmd_acc="dummyval"
1488   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1489     if test -d "${bmd}/X11/bitmaps"; then
1490       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1491     fi
1492     if test -d "${bmd}/bitmaps"; then
1493       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1494     fi
1495   done
1496   if test ${bmd_acc} != "dummyval"; then
1497     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1498   fi
1499 fi
1500
1501 HAVE_NS=no
1502 NS_IMPL_COCOA=no
1503 NS_IMPL_GNUSTEP=no
1504 tmp_CPPFLAGS="$CPPFLAGS"
1505 tmp_CFLAGS="$CFLAGS"
1506 CPPFLAGS="$CPPFLAGS -x objective-c"
1507 CFLAGS="$CFLAGS -x objective-c"
1508 TEMACS_LDFLAGS2="\${LDFLAGS}"
1509 GNU_OBJC_CFLAGS=
1510 if test "${with_ns}" != no; then
1511   if test "${opsys}" = darwin; then
1512      NS_IMPL_COCOA=yes
1513      ns_appdir=`pwd`/nextstep/Emacs.app
1514      ns_appbindir=${ns_appdir}/Contents/MacOS
1515      ns_appresdir=${ns_appdir}/Contents/Resources
1516      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1517   elif test -f $GNUSTEP_CONFIG_FILE; then
1518      NS_IMPL_GNUSTEP=yes
1519      ns_appdir=`pwd`/nextstep/Emacs.app
1520      ns_appbindir=${ns_appdir}
1521      ns_appresdir=${ns_appdir}/Resources
1522      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1523      dnl FIXME sourcing this several times in subshells seems inefficient.
1524      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1525      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1526      dnl I seemed to need these as well with GNUstep-startup 0.25.
1527      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1528      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1529      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1530        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1531      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1532        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1533      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1534      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1535      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1536      LIB_STANDARD=
1537      START_FILES=
1538      TEMACS_LDFLAGS2=
1539      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1540      dnl If they had chosen to either define it or not, we could have
1541      dnl just used AC_CHECK_DECL here.
1542      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1543        emacs_cv_objc_exceptions,
1544 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1545 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1546 1;
1547 #else
1548 fail;
1549 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1550      if test $emacs_cv_objc_exceptions = yes; then
1551        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1552        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1553          [Define if GNUstep uses ObjC exceptions.])
1554        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1555      fi
1556   fi
1557
1558   dnl This is only used while we test the NS headers, it gets reset below.
1559   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1560
1561   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1562                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1563   files are missing or cannot be compiled.])])
1564   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1565                                      [NSInteger i;])],
1566                     ns_have_nsinteger=yes,
1567                     ns_have_nsinteger=no)
1568   if test $ns_have_nsinteger = yes; then
1569     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1570   fi
1571 fi
1572 AC_SUBST(TEMACS_LDFLAGS2)
1573
1574 INSTALL_ARCH_INDEP_EXTRA=install-etc
1575 LEIM_INSTALLDIR="\${install_prefix}/leim"
1576 ns_self_contained=no
1577 ns_frag=/dev/null
1578 NS_OBJ=
1579 NS_OBJC_OBJ=
1580 if test "${HAVE_NS}" = yes; then
1581   if test "$with_toolkit_scroll_bars" = "no"; then
1582     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1583   fi
1584
1585   window_system=nextstep
1586   with_xft=no
1587   # set up packaging dirs
1588   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1589      ns_self_contained=yes
1590      prefix=${ns_appresdir}
1591      exec_prefix=${ns_appbindir}
1592      dnl This one isn't really used, only archlibdir is.
1593      libexecdir="\${ns_appbindir}/libexec"
1594      archlibdir="\${ns_appbindir}/libexec"
1595      docdir="\${ns_appresdir}/etc"
1596      etcdir="\${ns_appresdir}/etc"
1597      dnl FIXME maybe set datarootdir instead.
1598      dnl That would also get applications, icons, man.
1599      infodir="\${ns_appresdir}/info"
1600      mandir="\${ns_appresdir}/man"
1601      lispdir="\${ns_appresdir}/lisp"
1602      LEIM_INSTALLDIR="\${ns_appresdir}/leim"
1603      INSTALL_ARCH_INDEP_EXTRA=
1604   fi
1605   ns_frag=$srcdir/src/ns.mk
1606   NS_OBJ="fontset.o fringe.o image.o"
1607   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1608 fi
1609 CFLAGS="$tmp_CFLAGS"
1610 CPPFLAGS="$tmp_CPPFLAGS"
1611 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1612 AC_SUBST(LEIM_INSTALLDIR)
1613 AC_SUBST(ns_self_contained)
1614 AC_SUBST(NS_OBJ)
1615 AC_SUBST(NS_OBJC_OBJ)
1616 AC_SUBST(LIB_STANDARD)
1617 AC_SUBST_FILE(ns_frag)
1618
1619 case "${window_system}" in
1620   x11 )
1621     HAVE_X_WINDOWS=yes
1622     HAVE_X11=yes
1623     case "${with_x_toolkit}" in
1624       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1625       motif ) USE_X_TOOLKIT=MOTIF ;;
1626       gtk ) with_gtk=yes
1627 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1628 dnl USE_X_TOOLKIT is set.
1629             USE_X_TOOLKIT=none ;;
1630       gtk3 ) with_gtk3=yes
1631              USE_X_TOOLKIT=none ;;
1632       no ) USE_X_TOOLKIT=none ;;
1633 dnl If user did not say whether to use a toolkit, make this decision later:
1634 dnl use the toolkit if we have gtk, or X11R5 or newer.
1635       * ) USE_X_TOOLKIT=maybe ;;
1636     esac
1637   ;;
1638   nextstep | none )
1639     HAVE_X_WINDOWS=no
1640     HAVE_X11=no
1641     USE_X_TOOLKIT=none
1642   ;;
1643 esac
1644
1645 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1646    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1647    if test "$HAVE_XSERVER" = true ||
1648       test -n "$DISPLAY" ||
1649       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1650         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1651 were found.  You should install the relevant development files for X
1652 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1653 sure you have development files for image handling, i.e.
1654 tiff, gif, jpeg, png and xpm.
1655 If you are sure you want Emacs compiled without X window support, pass
1656   --without-x
1657 to configure.])
1658    fi
1659 fi
1660
1661 ### If we're using X11, we should use the X menu package.
1662 HAVE_MENUS=no
1663 case ${HAVE_X11} in
1664   yes ) HAVE_MENUS=yes ;;
1665 esac
1666
1667 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1668 # Assume not, until told otherwise.
1669 GNU_MALLOC=yes
1670
1671 AC_CACHE_CHECK(
1672   [whether malloc is Doug Lea style],
1673   [emacs_cv_var_doug_lea_malloc],
1674   [AC_LINK_IFELSE(
1675      [AC_LANG_PROGRAM(
1676         [[#include <malloc.h>
1677           static void hook (void) {}]],
1678         [[malloc_set_state (malloc_get_state ());
1679           __after_morecore_hook = hook;
1680           __malloc_initialize_hook = hook;]])],
1681      [emacs_cv_var_doug_lea_malloc=yes],
1682      [emacs_cv_var_doug_lea_malloc=no])])
1683 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1684
1685
1686 dnl See comments in aix4-2.h about maybe using system malloc there.
1687 system_malloc=no
1688 case "$opsys" in
1689   ## darwin ld insists on the use of malloc routines in the System framework.
1690   darwin|sol2-10) system_malloc=yes ;;
1691 esac
1692
1693 if test "${system_malloc}" = "yes"; then
1694   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1695   GNU_MALLOC=no
1696   GNU_MALLOC_reason="
1697     (The GNU allocators don't work with this system configuration.)"
1698   GMALLOC_OBJ=
1699   VMLIMIT_OBJ=
1700 else
1701   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1702   VMLIMIT_OBJ=vm-limit.o
1703 fi
1704 AC_SUBST(GMALLOC_OBJ)
1705 AC_SUBST(VMLIMIT_OBJ)
1706
1707 if test "$doug_lea_malloc" = "yes" ; then
1708   if test "$GNU_MALLOC" = yes ; then
1709     GNU_MALLOC_reason="
1710       (Using Doug Lea's new malloc from the GNU C Library.)"
1711   fi
1712   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1713             [Define to 1 if you are using the GNU C Library.])
1714
1715   ## Use mmap directly for allocating larger buffers.
1716   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1717   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1718   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1719   case "$opsys" in
1720     gnu*) REL_ALLOC=no ;;
1721   esac
1722 fi
1723
1724 if test x"${REL_ALLOC}" = x; then
1725   REL_ALLOC=${GNU_MALLOC}
1726 fi
1727
1728 use_mmap_for_buffers=no
1729 case "$opsys" in
1730   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1731 esac
1732
1733 AC_FUNC_MMAP
1734 if test $use_mmap_for_buffers = yes; then
1735   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1736   REL_ALLOC=no
1737 fi
1738
1739 LIBS="$LIBS_SYSTEM $LIBS"
1740
1741 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1742 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1743 AC_CHECK_LIB(dnet, dnet_ntoa)
1744 dnl This causes -lresolv to get used in subsequent tests,
1745 dnl which causes failures on some systems such as HPUX 9.
1746 dnl AC_CHECK_LIB(resolv, gethostbyname)
1747
1748 dnl FIXME replace main with a function we actually want from this library.
1749 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1750
1751 dnl Check if pthreads is available.
1752 LIB_PTHREAD=
1753 AC_CHECK_HEADERS(pthread.h)
1754 if test "$ac_cv_header_pthread_h"; then
1755   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1756   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1757   dnl testing for pthread_self if Emacs uses gmalloc.c.
1758   if test "$GMALLOC_OBJ" = gmalloc.o; then
1759     emacs_pthread_function=pthread_atfork
1760   else
1761     emacs_pthread_function=pthread_self
1762   fi
1763   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1764 fi
1765 if test "$HAVE_PTHREAD" = yes; then
1766   case "${canonical}" in
1767     *-hpux*) ;;
1768     *) LIB_PTHREAD="-lpthread"
1769        LIBS="$LIB_PTHREAD $LIBS" ;;
1770   esac
1771   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1772 fi
1773 AC_SUBST([LIB_PTHREAD])
1774
1775 AC_CHECK_LIB(pthreads, cma_open)
1776
1777 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1778 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1779 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1780 ## added to LIBS in configure would never contain the pthreads part,
1781 ## but the value used in Makefiles might.  FIXME?
1782 ##
1783 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1784 ## be harmless on older versions of X where it happens to exist.
1785 test "$opsys" = "aix4-2" && \
1786   test $ac_cv_lib_pthreads_cma_open = yes && \
1787   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1788
1789 dnl Check for need for bigtoc support on IBM AIX
1790
1791 case ${host_os} in
1792 aix*)
1793   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1794     case $GCC in
1795     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1796     *) gdb_cv_bigtoc=-bbigtoc ;;
1797     esac
1798
1799     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1800     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1801   ])
1802   ;;
1803 esac
1804
1805 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1806 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1807 # REAL_CPPFLAGS later on.
1808
1809 REAL_CFLAGS="$CFLAGS"
1810 REAL_CPPFLAGS="$CPPFLAGS"
1811
1812 if test "${HAVE_X11}" = "yes"; then
1813   DEFS="$C_SWITCH_X_SITE $DEFS"
1814   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1815   LIBS="-lX11 $LIBS"
1816   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1817   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1818
1819   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1820   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1821   # but it's more convenient here to set LD_RUN_PATH since this
1822   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1823   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1824     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1825     export LD_RUN_PATH
1826   fi
1827
1828   if test "${opsys}" = "gnu-linux"; then
1829     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1830     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1831      [[XOpenDisplay ("foo");]])],
1832      [xgnu_linux_first_failure=no],
1833      [xgnu_linux_first_failure=yes])
1834     if test "${xgnu_linux_first_failure}" = "yes"; then
1835       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1836       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1837       OLD_CPPFLAGS="$CPPFLAGS"
1838       OLD_LIBS="$LIBS"
1839       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1840       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1841       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1842       LIBS="$LIBS -b i486-linuxaout"
1843       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1844        [[XOpenDisplay ("foo");]])],
1845        [xgnu_linux_second_failure=no],
1846        [xgnu_linux_second_failure=yes])
1847       if test "${xgnu_linux_second_failure}" = "yes"; then
1848         # If we get the same failure with -b, there is no use adding -b.
1849         # So take it out.  This plays safe.
1850         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1851         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1852         CPPFLAGS="$OLD_CPPFLAGS"
1853         LIBS="$OLD_LIBS"
1854         AC_MSG_RESULT(no)
1855       else
1856         AC_MSG_RESULT(yes)
1857       fi
1858     else
1859       AC_MSG_RESULT(no)
1860     fi
1861   fi
1862
1863   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1864   # header files included from there.
1865   AC_MSG_CHECKING(for Xkb)
1866   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1867 #include <X11/XKBlib.h>]],
1868         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1869         emacs_xkb=yes, emacs_xkb=no)
1870   AC_MSG_RESULT($emacs_xkb)
1871   if test $emacs_xkb = yes; then
1872     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1873   fi
1874
1875   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1876 XScreenNumberOfScreen)
1877 fi
1878
1879 if test "${window_system}" = "x11"; then
1880   AC_MSG_CHECKING(X11 version 6)
1881   AC_CACHE_VAL(emacs_cv_x11_version_6,
1882   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1883 [[#if XlibSpecificationRelease < 6
1884 fail;
1885 #endif
1886 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1887   if test $emacs_cv_x11_version_6 = yes; then
1888     AC_MSG_RESULT(6 or newer)
1889     AC_DEFINE(HAVE_X11R6, 1,
1890               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1891     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1892     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1893     ## XIM support.
1894     case "$opsys" in
1895       sol2-*) : ;;
1896       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1897            [Define if you have usable X11R6-style XIM support.])
1898          ;;
1899     esac
1900   else
1901     AC_MSG_RESULT(before 6)
1902   fi
1903 fi
1904
1905
1906 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1907 HAVE_RSVG=no
1908 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1909   if test "${with_rsvg}" != "no"; then
1910     RSVG_REQUIRED=2.11.0
1911     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1912
1913     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1914     AC_SUBST(RSVG_CFLAGS)
1915     AC_SUBST(RSVG_LIBS)
1916
1917     if test $HAVE_RSVG = yes; then
1918       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1919       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1920       LIBS="$RSVG_LIBS $LIBS"
1921     fi
1922   fi
1923 fi
1924
1925 HAVE_IMAGEMAGICK=no
1926 if test "${HAVE_X11}" = "yes"; then
1927   if test "${with_imagemagick}" != "no"; then
1928     ## 6.2.8 is the earliest version known to work, but earlier versions
1929     ## might work - let us know if you find one.
1930     ## 6.0.7 does not work.  See bug#7955.
1931     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1932     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1933     AC_SUBST(IMAGEMAGICK_CFLAGS)
1934     AC_SUBST(IMAGEMAGICK_LIBS)
1935
1936     if test $HAVE_IMAGEMAGICK = yes; then
1937       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1938       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1939       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1940       AC_CHECK_FUNCS(MagickExportImagePixels)
1941     fi
1942   fi
1943 fi
1944
1945
1946 HAVE_GTK=no
1947 GTK_OBJ=
1948 if test "${with_gtk3}" = "yes"; then
1949   GLIB_REQUIRED=2.28
1950   GTK_REQUIRED=3.0
1951   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1952
1953   dnl Checks for libraries.
1954   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1955   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1956      AC_MSG_ERROR($GTK_PKG_ERRORS)
1957   fi
1958   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1959   GTK_OBJ=emacsgtkfixed.o
1960 fi
1961
1962 if test "$pkg_check_gtk" != "yes"; then
1963   HAVE_GTK=no
1964 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1965   GLIB_REQUIRED=2.10
1966   GTK_REQUIRED=2.10
1967   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1968
1969   dnl Checks for libraries.
1970   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1971   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1972      AC_MSG_ERROR($GTK_PKG_ERRORS)
1973   fi
1974 fi
1975 fi
1976
1977 if test x"$pkg_check_gtk" = xyes; then
1978
1979   AC_SUBST(GTK_CFLAGS)
1980   AC_SUBST(GTK_LIBS)
1981   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1982   CFLAGS="$CFLAGS $GTK_CFLAGS"
1983   LIBS="$GTK_LIBS $LIBS"
1984   dnl Try to compile a simple GTK program.
1985   GTK_COMPILES=no
1986   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1987   if test "${GTK_COMPILES}" != "yes"; then
1988     if test "$USE_X_TOOLKIT" != "maybe"; then
1989       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1990     fi
1991   else
1992     HAVE_GTK=yes
1993     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1994     GTK_OBJ="gtkutil.o $GTK_OBJ"
1995     USE_X_TOOLKIT=none
1996     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1997       :
1998     else
1999       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2000        closing open displays.  This is no problem if you just use
2001        one display, but if you use more than one and close one of them
2002        Emacs may crash.]])
2003       sleep 3
2004     fi
2005   fi
2006
2007 fi
2008 AC_SUBST(GTK_OBJ)
2009
2010
2011 if test "${HAVE_GTK}" = "yes"; then
2012
2013   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2014   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2015   if test "$with_toolkit_scroll_bars" != no; then
2016     with_toolkit_scroll_bars=yes
2017   fi
2018
2019   dnl  Check if we have the old file selection dialog declared and
2020   dnl  in the link library.  In 2.x it may be in the library,
2021   dnl  but not declared if deprecated featured has been selected out.
2022   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2023   HAVE_GTK_FILE_SELECTION=no
2024   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2025                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2026 #include <gtk/gtk.h>])
2027   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2028     AC_CHECK_FUNCS(gtk_file_selection_new)
2029   fi
2030
2031
2032   dnl Check for functions introduced in 2.14 and later.
2033   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2034                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2035                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2036                  gtk_orientable_set_orientation \
2037                  gtk_window_set_has_resize_grip)
2038 fi
2039
2040 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2041 dnl other platforms.
2042 HAVE_DBUS=no
2043 DBUS_OBJ=
2044 if test "${with_dbus}" = "yes"; then
2045    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2046    if test "$HAVE_DBUS" = yes; then
2047      LIBS="$LIBS $DBUS_LIBS"
2048      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2049      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2050      dnl dbus_validate_* have been introduced in D-Bus 1.5.12.
2051      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2052                     dbus_validate_bus_name \
2053                     dbus_validate_path \
2054                     dbus_validate_interface \
2055                     dbus_validate_member)
2056      DBUS_OBJ=dbusbind.o
2057    fi
2058 fi
2059 AC_SUBST(DBUS_OBJ)
2060
2061 dnl GSettings has been tested under GNU/Linux only.
2062 HAVE_GSETTINGS=no
2063 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2064    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2065    if test "$HAVE_GSETTINGS" = "yes"; then
2066       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2067       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2068       SETTINGS_LIBS="$GSETTINGS_LIBS"
2069    fi
2070 fi
2071
2072 dnl GConf has been tested under GNU/Linux only.
2073 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2074 HAVE_GCONF=no
2075 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2076    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2077    if test "$HAVE_GCONF" = yes; then
2078       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2079       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2080       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2081       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2082    fi
2083 fi
2084
2085 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2086     SAVE_CFLAGS="$CFLAGS"
2087     SAVE_LIBS="$LIBS"
2088     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2089     LIBS="$SETTINGS_LIBS $LIBS"
2090     AC_CHECK_FUNCS([g_type_init])
2091     CFLAGS="$SAVE_CFLAGS"
2092     LIBS="$SAVE_LIBS"
2093 fi
2094 AC_SUBST(SETTINGS_CFLAGS)
2095 AC_SUBST(SETTINGS_LIBS)
2096
2097
2098 dnl SELinux is available for GNU/Linux only.
2099 HAVE_LIBSELINUX=no
2100 LIBSELINUX_LIBS=
2101 if test "${with_selinux}" = "yes"; then
2102    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2103    if test "$HAVE_LIBSELINUX" = yes; then
2104       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2105       LIBSELINUX_LIBS=-lselinux
2106    fi
2107 fi
2108 AC_SUBST(LIBSELINUX_LIBS)
2109
2110 HAVE_GNUTLS=no
2111 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2112 if test "${with_gnutls}" = "yes" ; then
2113   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2114   if test "${HAVE_GNUTLS}" = "yes"; then
2115     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2116   fi
2117
2118   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2119   LIBS="$LIBGNUTLS_LIBS $LIBS"
2120   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2121
2122   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2123     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2124   fi
2125 fi
2126
2127 AC_SUBST(LIBGNUTLS_LIBS)
2128 AC_SUBST(LIBGNUTLS_CFLAGS)
2129
2130 dnl Do not put whitespace before the #include statements below.
2131 dnl Older compilers (eg sunos4 cc) choke on it.
2132 HAVE_XAW3D=no
2133 LUCID_LIBW=
2134 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2135   if test "$with_xaw3d" != no; then
2136     AC_MSG_CHECKING(for xaw3d)
2137     AC_CACHE_VAL(emacs_cv_xaw3d,
2138     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2139 #include <X11/Intrinsic.h>
2140 #include <X11/Xaw3d/Simple.h>]],
2141       [[]])],
2142       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2143                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2144       emacs_cv_xaw3d=no)])
2145   else
2146     emacs_cv_xaw3d=no
2147   fi
2148   if test $emacs_cv_xaw3d = yes; then
2149     AC_MSG_RESULT([yes; using Lucid toolkit])
2150     USE_X_TOOLKIT=LUCID
2151     HAVE_XAW3D=yes
2152     LUCID_LIBW=-lXaw3d
2153     AC_DEFINE(HAVE_XAW3D, 1,
2154               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2155   else
2156     AC_MSG_RESULT(no)
2157     AC_MSG_CHECKING(for libXaw)
2158     AC_CACHE_VAL(emacs_cv_xaw,
2159     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2160 #include <X11/Intrinsic.h>
2161 #include <X11/Xaw/Simple.h>]],
2162       [[]])],
2163       emacs_cv_xaw=yes,
2164       emacs_cv_xaw=no)])
2165     if test $emacs_cv_xaw = yes; then
2166       AC_MSG_RESULT([yes; using Lucid toolkit])
2167       USE_X_TOOLKIT=LUCID
2168       LUCID_LIBW=-lXaw
2169     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2170       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2171     else
2172       AC_MSG_ERROR([No X toolkit could be found.
2173 If you are sure you want Emacs compiled without an X toolkit, pass
2174   --with-x-toolkit=no
2175 to configure.  Otherwise, install the development libraries for the toolkit
2176 that you want to use (e.g. Gtk+) and re-run configure.])
2177     fi
2178   fi
2179 fi
2180
2181 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2182
2183 LIBXTR6=
2184 if test "${USE_X_TOOLKIT}" != "none"; then
2185   AC_MSG_CHECKING(X11 toolkit version)
2186   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2187   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2188 [[#if XtSpecificationRelease < 6
2189 fail;
2190 #endif
2191 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2192   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2193   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2194     AC_MSG_RESULT(6 or newer)
2195     AC_DEFINE(HAVE_X11XTR6, 1,
2196               [Define to 1 if you have the X11R6 or newer version of Xt.])
2197     LIBXTR6="-lSM -lICE"
2198     case "$opsys" in
2199       ## Use libw.a along with X11R6 Xt.
2200       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2201     esac
2202   else
2203     AC_MSG_RESULT(before 6)
2204   fi
2205
2206 dnl If using toolkit, check whether libXmu.a exists.
2207 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2208   OLDLIBS="$LIBS"
2209   if test x$HAVE_X11XTR6 = xyes; then
2210     LIBS="-lXt -lSM -lICE $LIBS"
2211   else
2212     LIBS="-lXt $LIBS"
2213   fi
2214   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2215   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2216 fi
2217 AC_SUBST(LIBXTR6)
2218
2219 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2220 dnl Why not just test for libxmu in the normal way?
2221 LIBXMU=-lXmu
2222 case $opsys in
2223   ## These systems don't supply Xmu.
2224   hpux* | aix4-2 )
2225     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2226     ;;
2227 esac
2228 AC_SUBST(LIBXMU)
2229
2230 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2231 if test "${HAVE_X11}" = "yes"; then
2232   if test "${USE_X_TOOLKIT}" != "none"; then
2233     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2234   fi
2235 fi
2236
2237 LIBXP=
2238 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2239   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2240   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2241     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2242 int x = 5;
2243 #else
2244 Motif version prior to 2.1.
2245 #endif]])],
2246     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2247   if test $emacs_cv_motif_version_2_1 = yes; then
2248     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2249   else
2250     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2251     # We put this in CFLAGS temporarily to precede other -I options
2252     # that might be in CFLAGS temporarily.
2253     # We put this in CPPFLAGS where it precedes the other -I options.
2254     OLD_CPPFLAGS=$CPPFLAGS
2255     OLD_CFLAGS=$CFLAGS
2256     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2257     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2258     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2259       [[int x = 5;]])],
2260       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2261     if test $emacs_cv_lesstif = yes; then
2262       # Make sure this -I option remains in CPPFLAGS after it is set
2263       # back to REAL_CPPFLAGS.
2264       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2265       # have those other -I options anyway.  Ultimately, having this
2266       # directory ultimately in CPPFLAGS will be enough.
2267       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2268       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2269     else
2270       CFLAGS=$OLD_CFLAGS
2271       CPPFLAGS=$OLD_CPPFLAGS
2272     fi
2273   fi
2274   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2275     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2276 fi
2277
2278 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2279 dnl using Motif or Xaw3d is available, and unless
2280 dnl --with-toolkit-scroll-bars=no was specified.
2281
2282 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2283             [Define to 1 if we should use toolkit scroll bars.])dnl
2284 USE_TOOLKIT_SCROLL_BARS=no
2285 if test "${with_toolkit_scroll_bars}" != "no"; then
2286   if test "${USE_X_TOOLKIT}" != "none"; then
2287     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2288       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2289       HAVE_XAW3D=no
2290       USE_TOOLKIT_SCROLL_BARS=yes
2291     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2292       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2293       USE_TOOLKIT_SCROLL_BARS=yes
2294     fi
2295   elif test "${HAVE_GTK}" = "yes"; then
2296     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2297     USE_TOOLKIT_SCROLL_BARS=yes
2298   elif test "${HAVE_NS}" = "yes"; then
2299     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2300     USE_TOOLKIT_SCROLL_BARS=yes
2301   fi
2302 fi
2303
2304 dnl See if XIM is available.
2305 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2306           #include <X11/Xlib.h>
2307           #include <X11/Xresource.h>]],
2308          [[XIMProc  callback;]])],
2309          [HAVE_XIM=yes
2310          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2311          HAVE_XIM=no)
2312
2313 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2314
2315 if test "${with_xim}" != "no"; then
2316   AC_DEFINE(USE_XIM, 1,
2317             [Define to 1 if we should use XIM, if it is available.])
2318 fi
2319
2320
2321 if test "${HAVE_XIM}" != "no"; then
2322   late_CFLAGS=$CFLAGS
2323   if test "$GCC" = yes; then
2324     CFLAGS="$CFLAGS --pedantic-errors"
2325   fi
2326   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2327 #include <X11/Xlib.h>
2328 #include <X11/Xresource.h>]],
2329 [[Display *display;
2330 XrmDatabase db;
2331 char *res_name;
2332 char *res_class;
2333 XIMProc  callback;
2334 XPointer *client_data;
2335 #ifndef __GNUC__
2336 /* If we're not using GCC, it's probably not XFree86, and this is
2337    probably right, but we can't use something like --pedantic-errors.  */
2338 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2339                                            char*, XIMProc, XPointer*);
2340 #endif
2341 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2342    client_data);]])],
2343     [emacs_cv_arg6_star=yes])
2344   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2345          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2346 either XPointer or XPointer*.])dnl
2347   if test "$emacs_cv_arg6_star" = yes; then
2348     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2349   else
2350     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2351   fi
2352   CFLAGS=$late_CFLAGS
2353 fi
2354
2355 ### Start of font-backend (under any platform) section.
2356 # (nothing here yet -- this is a placeholder)
2357 ### End of font-backend (under any platform) section.
2358
2359 ### Start of font-backend (under X11) section.
2360 if test "${HAVE_X11}" = "yes"; then
2361    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2362
2363    ## Use -lXft if available, unless `--with-xft=no'.
2364    HAVE_XFT=maybe
2365     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2366       with_xft="no";
2367     fi
2368     if test "x${with_xft}" != "xno"; then
2369
2370       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2371       ## Because xftfont.c uses XRenderQueryExtension, we also
2372       ## need to link to -lXrender.
2373       HAVE_XRENDER=no
2374       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2375       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2376         OLD_CPPFLAGS="$CPPFLAGS"
2377         OLD_CFLAGS="$CFLAGS"
2378         OLD_LIBS="$LIBS"
2379         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2380         CFLAGS="$CFLAGS $XFT_CFLAGS"
2381         XFT_LIBS="-lXrender $XFT_LIBS"
2382         LIBS="$XFT_LIBS $LIBS"
2383         AC_CHECK_HEADER(X11/Xft/Xft.h,
2384           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2385
2386         if test "${HAVE_XFT}" = "yes"; then
2387           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2388             AC_SUBST(XFT_LIBS)
2389           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2390         else
2391           CPPFLAGS="$OLD_CPPFLAGS"
2392           CFLAGS="$OLD_CFLAGS"
2393           LIBS="$OLD_LIBS"
2394         fi                        # "${HAVE_XFT}" = "yes"
2395       fi                          # "$HAVE_XFT" != no
2396     fi                            # "x${with_xft}" != "xno"
2397
2398     ## We used to allow building with FreeType and without Xft.
2399     ## However, the ftx font backend driver is not in good shape.
2400     if test "$HAVE_XFT" != "yes"; then
2401        dnl For the "Does Emacs use" message at the end.
2402        HAVE_XFT=no
2403        HAVE_FREETYPE=no
2404     else
2405        dnl Strict linkers fail with
2406        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2407        dnl if -lfreetype is not specified.
2408        dnl The following is needed to set FREETYPE_LIBS.
2409        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2410                          HAVE_FREETYPE=no)
2411
2412        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2413     fi
2414
2415     HAVE_LIBOTF=no
2416     if test "${HAVE_FREETYPE}" = "yes"; then
2417       AC_DEFINE(HAVE_FREETYPE, 1,
2418                 [Define to 1 if using the freetype and fontconfig libraries.])
2419       if test "${with_libotf}" != "no"; then
2420         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2421                           HAVE_LIBOTF=no)
2422         if test "$HAVE_LIBOTF" = "yes"; then
2423           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2424           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2425                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2426                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2427           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2428             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2429                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2430           fi
2431         fi
2432       fi
2433     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2434     dnl Does the new font backend require it, or can it work without it?
2435     fi
2436
2437     HAVE_M17N_FLT=no
2438     if test "${HAVE_LIBOTF}" = yes; then
2439       if test "${with_m17n_flt}" != "no"; then
2440         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2441         if test "$HAVE_M17N_FLT" = "yes"; then
2442           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2443         fi
2444       fi
2445     fi
2446 else
2447     HAVE_XFT=no
2448     HAVE_FREETYPE=no
2449     HAVE_LIBOTF=no
2450     HAVE_M17N_FLT=no
2451 fi
2452
2453 ### End of font-backend (under X11) section.
2454
2455 AC_SUBST(FREETYPE_CFLAGS)
2456 AC_SUBST(FREETYPE_LIBS)
2457 AC_SUBST(FONTCONFIG_CFLAGS)
2458 AC_SUBST(FONTCONFIG_LIBS)
2459 AC_SUBST(LIBOTF_CFLAGS)
2460 AC_SUBST(LIBOTF_LIBS)
2461 AC_SUBST(M17N_FLT_CFLAGS)
2462 AC_SUBST(M17N_FLT_LIBS)
2463
2464 ### Use -lXpm if available, unless `--with-xpm=no'.
2465 HAVE_XPM=no
2466 LIBXPM=
2467 if test "${HAVE_X11}" = "yes"; then
2468   if test "${with_xpm}" != "no"; then
2469     AC_CHECK_HEADER(X11/xpm.h,
2470       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2471     if test "${HAVE_XPM}" = "yes"; then
2472       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2473       AC_EGREP_CPP(no_return_alloc_pixels,
2474       [#include "X11/xpm.h"
2475 #ifndef XpmReturnAllocPixels
2476 no_return_alloc_pixels
2477 #endif
2478       ], HAVE_XPM=no, HAVE_XPM=yes)
2479
2480       if test "${HAVE_XPM}" = "yes"; then
2481         AC_MSG_RESULT(yes)
2482       else
2483         AC_MSG_RESULT(no)
2484       fi
2485     fi
2486   fi
2487
2488   if test "${HAVE_XPM}" = "yes"; then
2489     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2490     LIBXPM=-lXpm
2491   fi
2492 fi
2493 AC_SUBST(LIBXPM)
2494
2495 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2496 HAVE_JPEG=no
2497 LIBJPEG=
2498 if test "${HAVE_X11}" = "yes"; then
2499   if test "${with_jpeg}" != "no"; then
2500     dnl Checking for jpeglib.h can lose because of a redefinition of
2501     dnl  HAVE_STDLIB_H.
2502     AC_CHECK_HEADER(jerror.h,
2503       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2504   fi
2505
2506   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2507   if test "${HAVE_JPEG}" = "yes"; then
2508     AC_DEFINE(HAVE_JPEG)
2509     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2510         [#include <jpeglib.h>
2511          version=JPEG_LIB_VERSION
2512 ],
2513         [AC_DEFINE(HAVE_JPEG)],
2514         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2515         HAVE_JPEG=no])
2516   fi
2517   if test "${HAVE_JPEG}" = "yes"; then
2518     LIBJPEG=-ljpeg
2519   fi
2520 fi
2521 AC_SUBST(LIBJPEG)
2522
2523 ### Use -lpng if available, unless `--with-png=no'.
2524 HAVE_PNG=no
2525 LIBPNG=
2526 if test "${HAVE_X11}" = "yes"; then
2527   if test "${with_png}" != "no"; then
2528     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2529     # in /usr/include/libpng.
2530     AC_CHECK_HEADERS(png.h libpng/png.h)
2531     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2532       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2533     fi
2534   fi
2535
2536   if test "${HAVE_PNG}" = "yes"; then
2537     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2538     LIBPNG="-lpng -lz -lm"
2539   fi
2540 fi
2541 AC_SUBST(LIBPNG)
2542
2543 ### Use -ltiff if available, unless `--with-tiff=no'.
2544 HAVE_TIFF=no
2545 LIBTIFF=
2546 if test "${HAVE_X11}" = "yes"; then
2547   if test "${with_tiff}" != "no"; then
2548     AC_CHECK_HEADER(tiffio.h,
2549       [tifflibs="-lz -lm"
2550       # At least one tiff package requires the jpeg library.
2551       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2552       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2553   fi
2554
2555   if test "${HAVE_TIFF}" = "yes"; then
2556     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2557     dnl FIXME -lz -lm, as per libpng?
2558     LIBTIFF=-ltiff
2559   fi
2560 fi
2561 AC_SUBST(LIBTIFF)
2562
2563 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2564 HAVE_GIF=no
2565 LIBGIF=
2566 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2567   AC_CHECK_HEADER(gif_lib.h,
2568 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2569 # Earlier versions can crash Emacs.
2570     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2571
2572   if test "$HAVE_GIF" = yes; then
2573     LIBGIF=-lgif
2574   elif test "$HAVE_GIF" = maybe; then
2575 # If gif_lib.h but no libgif, try libungif.
2576     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2577     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2578   fi
2579
2580   if test "${HAVE_GIF}" = "yes"; then
2581     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2582   fi
2583 fi
2584 AC_SUBST(LIBGIF)
2585
2586 dnl Check for required libraries.
2587 if test "${HAVE_X11}" = "yes"; then
2588   MISSING=""
2589   WITH_NO=""
2590   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2591     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2592   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2593     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2594   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2595     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2596   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2597     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2598   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2599     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2600
2601   if test "X${MISSING}" != X; then
2602     AC_MSG_ERROR([The following required libraries were not found:
2603     $MISSING
2604 Maybe some development libraries/packages are missing?
2605 If you don't want to link with them give
2606     $WITH_NO
2607 as options to configure])
2608   fi
2609 fi
2610
2611 ### Use -lgpm if available, unless `--with-gpm=no'.
2612 HAVE_GPM=no
2613 LIBGPM=
2614 if test "${with_gpm}" != "no"; then
2615   AC_CHECK_HEADER(gpm.h,
2616     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2617
2618   if test "${HAVE_GPM}" = "yes"; then
2619     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2620     LIBGPM=-lgpm
2621   fi
2622 fi
2623 AC_SUBST(LIBGPM)
2624
2625 dnl Check for malloc/malloc.h on darwin
2626 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2627
2628 GNUSTEP_CFLAGS=
2629 ### Use NeXTstep API to implement GUI.
2630 if test "${HAVE_NS}" = "yes"; then
2631   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2632   if test "${NS_IMPL_COCOA}" = "yes"; then
2633     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2634   fi
2635   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2636     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2637     # See also .m.o rule in Makefile.in */
2638     # FIXME: are all these flags really needed?  Document here why.  */
2639     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2640     ## Extra CFLAGS applied to src/*.m files.
2641     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2642   fi
2643   # We also have mouse menus.
2644   HAVE_MENUS=yes
2645   OTHER_FILES=ns-app
2646 fi
2647
2648
2649 ### Use session management (-lSM -lICE) if available
2650 HAVE_X_SM=no
2651 LIBXSM=
2652 if test "${HAVE_X11}" = "yes"; then
2653   AC_CHECK_HEADER(X11/SM/SMlib.h,
2654     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2655
2656   if test "${HAVE_X_SM}" = "yes"; then
2657     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2658     LIBXSM="-lSM -lICE"
2659     case "$LIBS" in
2660       *-lSM*) ;;
2661       *)      LIBS="$LIBXSM $LIBS" ;;
2662     esac
2663   fi
2664 fi
2665 AC_SUBST(LIBXSM)
2666
2667 ### Use libxml (-lxml2) if available
2668 HAVE_LIBXML2=no
2669 if test "${with_xml2}" != "no"; then
2670   ### I'm not sure what the version number should be, so I just guessed.
2671   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2672   if test "${HAVE_LIBXML2}" = "yes"; then
2673     LIBS="$LIBXML2_LIBS $LIBS"
2674     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2675     if test "${HAVE_LIBXML2}" = "yes"; then
2676       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2677     else
2678       LIBXML2_LIBS=""
2679       LIBXML2_CFLAGS=""
2680     fi
2681   fi
2682 fi
2683 AC_SUBST(LIBXML2_LIBS)
2684 AC_SUBST(LIBXML2_CFLAGS)
2685
2686 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2687 AC_CACHE_CHECK(whether netdb declares h_errno,
2688                emacs_cv_netdb_declares_h_errno,
2689 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2690   [[return h_errno;]])],
2691   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2692 if test $emacs_cv_netdb_declares_h_errno = yes; then
2693   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2694 fi
2695
2696 # fmod, logb, and frexp are found in -lm on most systems.
2697 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2698 AC_CHECK_LIB(m, sqrt)
2699
2700 # Check for mail-locking functions in a "mail" library.  Probably this should
2701 # have the same check as for liblockfile below.
2702 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2703 if test $have_mail = yes; then
2704   LIBS_MAIL=-lmail
2705   LIBS="$LIBS_MAIL $LIBS"
2706   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2707 else
2708   LIBS_MAIL=
2709 fi
2710 dnl Debian, at least:
2711 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2712 if test $have_lockfile = yes; then
2713    LIBS_MAIL=-llockfile
2714    LIBS="$LIBS_MAIL $LIBS"
2715    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2716 else
2717 # If we have the shared liblockfile, assume we must use it for mail
2718 # locking (e.g. Debian).  If we couldn't link against liblockfile
2719 # (no liblockfile.a installed), ensure that we don't need to.
2720   dnl This works for files generally, not just executables.
2721   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2722   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2723                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2724   if test $ac_cv_prog_liblockfile = yes; then
2725     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2726 This probably means that movemail could lose mail.
2727 There may be a `development' package to install containing liblockfile.])
2728   fi
2729 fi
2730 AC_CHECK_FUNCS(touchlock)
2731 AC_CHECK_HEADERS(maillock.h)
2732 AC_SUBST(LIBS_MAIL)
2733
2734 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2735 ## interlock access to the mail spool.  The alternative is a lock file named
2736 ## /usr/spool/mail/$USER.lock.
2737 mail_lock=no
2738 case "$opsys" in
2739   aix4-2) mail_lock="lockf" ;;
2740
2741   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2742
2743   ## On GNU/Linux systems, both methods are used by various mail programs.
2744   ## I assume most people are using newer mailers that have heard of flock.
2745   ## Change this if you need to.
2746   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2747   ## configure gets the right answers, and that means *NOT* using flock.
2748   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2749   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2750   ## Debian maintainer hasn't provided a clean fix for Emacs.
2751   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2752   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2753   ## correct logic.  -- fx
2754   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2755   ## liblockfile is a Free Software replacement for libmail, used on
2756   ## Debian systems and elsewhere. -rfr.
2757   gnu-*)
2758     mail_lock="flock"
2759     if test $have_mail = yes || test $have_lockfile = yes; then
2760       test $ac_cv_header_maillock_h = yes && mail_lock=no
2761     fi
2762     ;;
2763 esac
2764
2765 BLESSMAIL_TARGET=
2766 case "$mail_lock" in
2767   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2768
2769   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2770
2771   *) BLESSMAIL_TARGET="need-blessmail" ;;
2772 esac
2773 AC_SUBST(BLESSMAIL_TARGET)
2774
2775
2776 AC_CHECK_FUNCS(gethostname \
2777 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2778 random lrand48 logb frexp fmod rint cbrt setsid \
2779 strerror fpathconf select euidaccess getpagesize tzset setlocale \
2780 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2781 __fpending strsignal setitimer \
2782 sendto recvfrom getsockname getpeername \
2783 gai_strerror mkstemp getline getdelim fsync sync \
2784 difftime posix_memalign \
2785 getpwent endpwent getgrent endgrent \
2786 cfmakeraw cfsetspeed copysign __executable_start)
2787
2788 dnl Cannot use AC_CHECK_FUNCS
2789 AC_CACHE_CHECK([for __builtin_unwind_init],
2790                emacs_cv_func___builtin_unwind_init,
2791 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2792                 emacs_cv_func___builtin_unwind_init=yes,
2793                 emacs_cv_func___builtin_unwind_init=no)])
2794 if test $emacs_cv_func___builtin_unwind_init = yes; then
2795   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2796             [Define to 1 if you have the `__builtin_unwind_init' function.])
2797 fi
2798
2799 AC_CHECK_HEADERS(sys/un.h)
2800
2801 AC_FUNC_FSEEKO
2802
2803 AC_FUNC_GETPGRP
2804
2805 # UNIX98 PTYs.
2806 AC_CHECK_FUNCS(grantpt)
2807
2808 # PTY-related GNU extensions.
2809 AC_CHECK_FUNCS(getpt)
2810
2811 # Check this now, so that we will NOT find the above functions in ncurses.
2812 # That is because we have not set up to link ncurses in lib-src.
2813 # It's better to believe a function is not available
2814 # than to expect to find it in ncurses.
2815 # Also we need tputs and friends to be able to build at all.
2816 AC_MSG_CHECKING([for library containing tputs])
2817 # Run a test program that contains a call to tputs, a call that is
2818 # never executed.  This tests whether a pre-'main' dynamic linker
2819 # works with the library.  It's too much trouble to actually call
2820 # tputs in the test program, due to portability hassles.  When
2821 # cross-compiling, assume the test program will run if it links.
2822 AC_DEFUN([tputs_link_source], [
2823   AC_LANG_SOURCE(
2824      [[extern void tputs (const char *, int, int (*)(int));
2825        int main (int argc, char **argv)
2826        {
2827           if (argc == 10000)
2828             tputs (argv[0], 0, 0);
2829           return 0;
2830        }]])
2831 ])
2832 # Maybe curses should be tried earlier?
2833 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2834 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2835   OLIBS=$LIBS
2836   if test -z "$tputs_library"; then
2837     LIBS_TERMCAP=
2838     msg='none required'
2839   else
2840     LIBS_TERMCAP=-l$tputs_library
2841     msg=$LIBS_TERMCAP
2842     LIBS="$LIBS_TERMCAP $LIBS"
2843   fi
2844   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2845     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2846   LIBS=$OLIBS
2847   if test "X$msg" != Xno; then
2848     break
2849   fi
2850 done
2851 AC_MSG_RESULT([$msg])
2852 if test "X$msg" = Xno; then
2853   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2854 The following libraries were tried (in order):
2855   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2856 Please try installing whichever of these libraries is most appropriate
2857 for your system, together with its header files.
2858 For example, a libncurses-dev(el) or similar package.])
2859 fi
2860
2861 ## Use termcap instead of terminfo?
2862 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2863 TERMINFO=yes
2864 ## FIXME?  In the cases below where we unconditionally set
2865 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2866 ## if that was found above to have tputs.
2867 ## Should we use the gnu* logic everywhere?
2868 case "$opsys" in
2869   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2870   ##  The ncurses library has been moved out of the System framework in
2871   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2872   ##  option to use it.
2873   darwin) LIBS_TERMCAP="-lncurses" ;;
2874
2875   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2876
2877   freebsd)
2878     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2879     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2880     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2881 [[#if __FreeBSD_version < 400000
2882 fail;
2883 #endif
2884 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2885
2886     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2887
2888     if test $emacs_cv_freebsd_terminfo = yes; then
2889       LIBS_TERMCAP="-lncurses"
2890     else
2891       TERMINFO=no
2892       LIBS_TERMCAP="-ltermcap"
2893     fi
2894     ;;
2895
2896   netbsd)
2897     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2898       TERMINFO=no
2899       LIBS_TERMCAP="-ltermcap"
2900     fi
2901     ;;
2902
2903   openbsd) LIBS_TERMCAP="-lncurses" ;;
2904
2905   ## hpux: Make sure we get select from libc rather than from libcurses
2906   ##  because libcurses on HPUX 10.10 has a broken version of select.
2907   ##  We used to use -lc -lcurses, but this may be cleaner.
2908   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2909   # set that way, now it uses the default).  Isn't this a contradiction?
2910   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2911
2912 esac
2913
2914 TERMCAP_OBJ=tparam.o
2915 if test $TERMINFO = yes; then
2916   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2917   TERMCAP_OBJ=terminfo.o
2918 fi
2919 AC_SUBST(LIBS_TERMCAP)
2920 AC_SUBST(TERMCAP_OBJ)
2921
2922
2923 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2924 resolv=no
2925 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2926 #include <arpa/nameser.h>
2927 #include <resolv.h>]],
2928     [[return res_init();]])],
2929     have_res_init=yes, have_res_init=no)
2930 if test "$have_res_init" = no; then
2931   OLIBS="$LIBS"
2932   LIBS="$LIBS -lresolv"
2933   AC_MSG_CHECKING(for res_init with -lresolv)
2934   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2935 #include <arpa/nameser.h>
2936 #include <resolv.h>]],
2937     [[return res_init();]])],
2938     have_res_init=yes, have_res_init=no)
2939   AC_MSG_RESULT($have_res_init)
2940   if test "$have_res_init" = yes ; then
2941     resolv=yes
2942   fi
2943   LIBS="$OLIBS"
2944 fi
2945
2946 if test "$have_res_init" = yes; then
2947   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2948 fi
2949
2950 # Do we need the Hesiod library to provide the support routines?
2951 LIBHESIOD=
2952 if test "$with_hesiod" != no ; then
2953   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2954   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2955      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2956                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2957   if test "$resolv" = yes ; then
2958     RESOLVLIB=-lresolv
2959   else
2960     RESOLVLIB=
2961   fi
2962   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2963         hesiod=yes, :, $RESOLVLIB)])
2964
2965   if test x"$hesiod" = xyes; then
2966     AC_DEFINE(HAVE_LIBHESIOD, 1,
2967               [Define to 1 if you have the hesiod library (-lhesiod).])
2968     LIBHESIOD=-lhesiod
2969   fi
2970 fi
2971 AC_SUBST(LIBHESIOD)
2972
2973 # Do we need libresolv (due to res_init or Hesiod)?
2974 if test "$resolv" = yes ; then
2975   AC_DEFINE(HAVE_LIBRESOLV, 1,
2976             [Define to 1 if you have the resolv library (-lresolv).])
2977   LIBRESOLV=-lresolv
2978 else
2979   LIBRESOLV=
2980 fi
2981 AC_SUBST(LIBRESOLV)
2982
2983 # These tell us which Kerberos-related libraries to use.
2984 COM_ERRLIB=
2985 CRYPTOLIB=
2986 KRB5LIB=
2987 DESLIB=
2988 KRB4LIB=
2989
2990 if test "${with_kerberos}" != no; then
2991   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2992   if test $have_com_err = yes; then
2993     COM_ERRLIB=-lcom_err
2994     LIBS="$COM_ERRLIB $LIBS"
2995     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2996   fi
2997   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2998   if test $have_crypto = yes; then
2999     CRYPTOLIB=-lcrypto
3000     LIBS="$CRYPTOLIB $LIBS"
3001     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3002   fi
3003   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3004   if test $have_k5crypto = yes; then
3005     CRYPTOLIB=-lk5crypto
3006     LIBS="$CRYPTOLIB $LIBS"
3007     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3008   fi
3009   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3010   if test $have_krb5=yes; then
3011     KRB5LIB=-lkrb5
3012     LIBS="$KRB5LIB $LIBS"
3013     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3014   fi
3015   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3016   if test "${with_kerberos5}" = no; then
3017     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3018     if test $have_des425 = yes; then
3019       DESLIB=-ldes425
3020       LIBS="$DESLIB $LIBS"
3021       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3022     else
3023       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3024       if test $have_des = yes; then
3025         DESLIB=-ldes
3026         LIBS="$DESLIB $LIBS"
3027         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3028       fi
3029     fi
3030     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3031     if test $have_krb4 = yes; then
3032       KRB4LIB=-lkrb4
3033       LIBS="$KRB4LIB $LIBS"
3034       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3035     else
3036       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3037       if test $have_krb = yes; then
3038         KRB4LIB=-lkrb
3039         LIBS="$KRB4LIB $LIBS"
3040         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3041       fi
3042     fi
3043   fi
3044
3045   if test "${with_kerberos5}" != no; then
3046     AC_CHECK_HEADERS(krb5.h,
3047       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3048                         [#include <krb5.h>])])
3049   else
3050     AC_CHECK_HEADERS(des.h,,
3051                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3052                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3053     AC_CHECK_HEADERS(krb.h,,
3054                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3055                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3056   fi
3057   AC_CHECK_HEADERS(com_err.h)
3058 fi
3059
3060 AC_SUBST(COM_ERRLIB)
3061 AC_SUBST(CRYPTOLIB)
3062 AC_SUBST(KRB5LIB)
3063 AC_SUBST(DESLIB)
3064 AC_SUBST(KRB4LIB)
3065
3066 AC_MSG_CHECKING(whether localtime caches TZ)
3067 AC_CACHE_VAL(emacs_cv_localtime_cache,
3068 [if test x$ac_cv_func_tzset = xyes; then
3069 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3070 char TZ_GMT0[] = "TZ=GMT0";
3071 char TZ_PST8[] = "TZ=PST8";
3072 main()
3073 {
3074   time_t now = time ((time_t *) 0);
3075   int hour_GMT0, hour_unset;
3076   if (putenv (TZ_GMT0) != 0)
3077     exit (1);
3078   hour_GMT0 = localtime (&now)->tm_hour;
3079   unsetenv("TZ");
3080   hour_unset = localtime (&now)->tm_hour;
3081   if (putenv (TZ_PST8) != 0)
3082     exit (1);
3083   if (localtime (&now)->tm_hour == hour_GMT0)
3084     exit (1);
3085   unsetenv("TZ");
3086   if (localtime (&now)->tm_hour != hour_unset)
3087     exit (1);
3088   exit (0);
3089 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3090 [# If we have tzset, assume the worst when cross-compiling.
3091 emacs_cv_localtime_cache=yes])
3092 else
3093         # If we lack tzset, report that localtime does not cache TZ,
3094         # since we can't invalidate the cache if we don't have tzset.
3095         emacs_cv_localtime_cache=no
3096 fi])dnl
3097 AC_MSG_RESULT($emacs_cv_localtime_cache)
3098 if test $emacs_cv_localtime_cache = yes; then
3099   AC_DEFINE(LOCALTIME_CACHE, 1,
3100             [Define to 1 if localtime caches TZ.])
3101 fi
3102
3103 if test "x$HAVE_TIMEVAL" = xyes; then
3104   AC_CHECK_FUNCS(gettimeofday)
3105   if test $ac_cv_func_gettimeofday = yes; then
3106     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
3107                    emacs_cv_gettimeofday_two_arguments,
3108     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3109 #ifdef TIME_WITH_SYS_TIME
3110 #include <sys/time.h>
3111 #include <time.h>
3112 #else
3113 #ifdef HAVE_SYS_TIME_H
3114 #include <sys/time.h>
3115 #else
3116 #include <time.h>
3117 #endif
3118 #endif]],
3119       [[struct timeval time;
3120        gettimeofday (&time, 0);]])],
3121       emacs_cv_gettimeofday_two_arguments=yes,
3122       emacs_cv_gettimeofday_two_arguments=no)])
3123     if test $emacs_cv_gettimeofday_two_arguments = no; then
3124       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
3125                 [Define to 1 if gettimeofday accepts only one argument.])
3126     fi
3127   fi
3128 fi
3129
3130 ok_so_far=yes
3131 AC_CHECK_FUNC(socket, , ok_so_far=no)
3132 if test $ok_so_far = yes; then
3133   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3134 fi
3135 if test $ok_so_far = yes; then
3136   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3137 fi
3138 if test $ok_so_far = yes; then
3139 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3140   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3141             [Define to 1 if you have inet sockets.])
3142 fi
3143
3144 if test -f /usr/lpp/X11/bin/smt.exp; then
3145   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3146             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3147 fi
3148
3149 AC_MSG_CHECKING(whether system supports dynamic ptys)
3150 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3151   AC_MSG_RESULT(yes)
3152   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3153 else
3154   AC_MSG_RESULT(no)
3155 fi
3156
3157 AC_FUNC_FORK
3158
3159 AC_CHECK_FUNCS(snprintf)
3160
3161 dnl Adapted from Haible's version.
3162 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3163   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3164     [[char* cs = nl_langinfo(CODESET);]])],
3165     emacs_cv_langinfo_codeset=yes,
3166     emacs_cv_langinfo_codeset=no)
3167   ])
3168 if test $emacs_cv_langinfo_codeset = yes; then
3169   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3170     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3171 fi
3172
3173 AC_TYPE_MBSTATE_T
3174
3175 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3176   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3177                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3178 if test "$emacs_cv_c_restrict_arr" = yes; then
3179   AC_DEFINE(__restrict_arr, __restrict,
3180     [Define to compiler's equivalent of C99 restrict keyword in array
3181      declarations.  Define as empty for no equivalent.])
3182 fi
3183
3184 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3185 dnl how the tty code is related to POSIX and/or other versions of termios.
3186 dnl The following looks like a useful start.
3187 dnl
3188 dnl AC_SYS_POSIX_TERMIOS
3189 dnl if test $ac_cv_sys_posix_termios = yes; then
3190 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3191 dnl                                and macros for terminal control.])
3192 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3193 dnl fi
3194
3195 # Set up the CFLAGS for real compilation, so we can substitute it.
3196 CFLAGS="$REAL_CFLAGS"
3197 CPPFLAGS="$REAL_CPPFLAGS"
3198
3199 ## Hack to detect a buggy GCC version.
3200 if test "x$GCC" = xyes \
3201    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3202    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3203    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3204    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3205 fi
3206
3207 version=$PACKAGE_VERSION
3208
3209 ### Specify what sort of things we'll be editing into Makefile and config.h.
3210 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3211 AC_SUBST(version)
3212 AC_SUBST(configuration)
3213 ## Unused?
3214 AC_SUBST(canonical)
3215 AC_SUBST(srcdir)
3216 AC_SUBST(prefix)
3217 AC_SUBST(exec_prefix)
3218 AC_SUBST(bindir)
3219 AC_SUBST(datadir)
3220 AC_SUBST(sharedstatedir)
3221 AC_SUBST(libexecdir)
3222 AC_SUBST(mandir)
3223 AC_SUBST(infodir)
3224 AC_SUBST(lispdir)
3225 AC_SUBST(locallisppath)
3226 AC_SUBST(lisppath)
3227 AC_SUBST(x_default_search_path)
3228 AC_SUBST(etcdir)
3229 AC_SUBST(archlibdir)
3230 AC_SUBST(docdir)
3231 AC_SUBST(bitmapdir)
3232 AC_SUBST(gamedir)
3233 AC_SUBST(gameuser)
3234 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3235 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3236 ## end of LIBX_BASE, but nothing ever set it.
3237 AC_SUBST(LD_SWITCH_X_SITE)
3238 AC_SUBST(C_SWITCH_X_SITE)
3239 AC_SUBST(GNUSTEP_CFLAGS)
3240 AC_SUBST(CFLAGS)
3241 ## Used in lwlib/Makefile.in.
3242 AC_SUBST(X_TOOLKIT_TYPE)
3243 if test -n "${machfile}"; then
3244   M_FILE="\$(srcdir)/${machfile}"
3245 else
3246   M_FILE=
3247 fi
3248 S_FILE="\$(srcdir)/${opsysfile}"
3249 AC_SUBST(M_FILE)
3250 AC_SUBST(S_FILE)
3251 AC_SUBST(ns_appdir)
3252 AC_SUBST(ns_appbindir)
3253 AC_SUBST(ns_appresdir)
3254 AC_SUBST(ns_appsrc)
3255 AC_SUBST(GNU_OBJC_CFLAGS)
3256 AC_SUBST(OTHER_FILES)
3257
3258 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3259                    [Define to the canonical Emacs configuration name.])
3260 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3261                    [Define to the options passed to configure.])
3262 if test -n "$machfile"; then
3263   AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3264                      [Define to the used machine dependent file.])
3265 fi
3266 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3267                    [Define to the used os dependent file.])
3268
3269 XMENU_OBJ=
3270 XOBJ=
3271 FONT_OBJ=
3272 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3273   AC_DEFINE(HAVE_X_WINDOWS, 1,
3274             [Define to 1 if you want to use the X window system.])
3275   XMENU_OBJ=xmenu.o
3276   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3277   FONT_OBJ=xfont.o
3278   if test "$HAVE_XFT" = "yes"; then
3279     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3280   elif test "$HAVE_FREETYPE" = "yes"; then
3281     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3282   fi
3283   AC_SUBST(FONT_OBJ)
3284 fi
3285 AC_SUBST(XMENU_OBJ)
3286 AC_SUBST(XOBJ)
3287 AC_SUBST(FONT_OBJ)
3288
3289 WIDGET_OBJ=
3290 MOTIF_LIBW=
3291 if test "${USE_X_TOOLKIT}" != "none" ; then
3292   WIDGET_OBJ=widget.o
3293   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3294   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3295     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3296   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3297     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3298     MOTIF_LIBW=-lXm
3299     case "$opsys" in
3300       gnu-linux)
3301         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3302         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3303         ;;
3304
3305       unixware)
3306         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3307         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3308         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3309         ;;
3310
3311       aix4-2)
3312         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3313         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3314         ;;
3315     esac
3316     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3317   fi
3318 fi
3319 AC_SUBST(WIDGET_OBJ)
3320
3321 TOOLKIT_LIBW=
3322 case "$USE_X_TOOLKIT" in
3323   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3324   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3325   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3326 esac
3327 AC_SUBST(TOOLKIT_LIBW)
3328
3329 if test "$USE_X_TOOLKIT" = "none"; then
3330   LIBXT_OTHER="\$(LIBXSM)"
3331   OLDXMENU_TARGET="really-oldXMenu"
3332 else
3333   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3334   OLDXMENU_TARGET="really-lwlib"
3335 fi
3336 AC_SUBST(LIBXT_OTHER)
3337
3338 ## The X Menu stuff is present in the X10 distribution, but missing
3339 ## from X11.  If we have X10, just use the installed library;
3340 ## otherwise, use our own copy.
3341 if test "${HAVE_X11}" = "yes" ; then
3342   AC_DEFINE(HAVE_X11, 1,
3343             [Define to 1 if you want to use version 11 of X windows.
3344              Otherwise, Emacs expects to use version 10.])
3345
3346   if test "$USE_X_TOOLKIT" = "none"; then
3347     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3348   else
3349     OLDXMENU="\${lwlibdir}/liblw.a"
3350   fi
3351   LIBXMENU="\$(OLDXMENU)"
3352   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3353   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3354 else
3355   ## For a syntactically valid Makefile; not actually used for anything.
3356   ## See comments in src/Makefile.in.
3357   OLDXMENU=nothing
3358   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3359   if test "${HAVE_X_WINDOWS}" = "yes"; then
3360     LIBXMENU="-lXMenu"
3361   else
3362     LIBXMENU=
3363   fi
3364   LIBX_OTHER=
3365   OLDXMENU_DEPS=
3366 fi
3367
3368 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3369   OLDXMENU_TARGET=
3370   OLDXMENU=nothing
3371   LIBXMENU=
3372   OLDXMENU_DEPS=
3373 fi
3374
3375 AC_SUBST(OLDXMENU_TARGET)
3376 AC_SUBST(OLDXMENU)
3377 AC_SUBST(LIBXMENU)
3378 AC_SUBST(LIBX_OTHER)
3379 AC_SUBST(OLDXMENU_DEPS)
3380
3381 if test "${HAVE_MENUS}" = "yes" ; then
3382   AC_DEFINE(HAVE_MENUS, 1,
3383             [Define to 1 if you have mouse menus.
3384              (This is automatic if you use X, but the option to specify it remains.)
3385              It is also defined with other window systems that support xmenu.c.])
3386 fi
3387
3388 if test "${GNU_MALLOC}" = "yes" ; then
3389   AC_DEFINE(GNU_MALLOC, 1,
3390             [Define to 1 if you want to use the GNU memory allocator.])
3391 fi
3392
3393 RALLOC_OBJ=
3394 if test "${REL_ALLOC}" = "yes" ; then
3395   AC_DEFINE(REL_ALLOC, 1,
3396             [Define REL_ALLOC if you want to use the relocating allocator for
3397              buffer space.])
3398
3399   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3400 fi
3401 AC_SUBST(RALLOC_OBJ)
3402
3403 if test "$opsys" = "cygwin"; then
3404   CYGWIN_OBJ="sheap.o"
3405   ## Cygwin differs because of its unexec().
3406   PRE_ALLOC_OBJ=
3407   POST_ALLOC_OBJ=lastfile.o
3408 else
3409   CYGWIN_OBJ=
3410   PRE_ALLOC_OBJ=lastfile.o
3411   POST_ALLOC_OBJ=
3412 fi
3413 AC_SUBST(CYGWIN_OBJ)
3414 AC_SUBST(PRE_ALLOC_OBJ)
3415 AC_SUBST(POST_ALLOC_OBJ)
3416
3417 # Configure gnulib here, now that we know LIBS.
3418 gl_ASSERT_NO_GNULIB_POSIXCHECK
3419 gl_ASSERT_NO_GNULIB_TESTS
3420 gl_INIT
3421
3422 case "$opsys" in
3423   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3424
3425   darwin)
3426    ## The -headerpad option tells ld (see man page) to leave room at the
3427    ## end of the header for adding load commands.  Needed for dumping.
3428    ## 0x690 is the total size of 30 segment load commands (at 56
3429    ## each); under Cocoa 31 commands are required.
3430    if test "$HAVE_NS" = "yes"; then
3431      libs_nsgui="-framework AppKit"
3432      headerpad_extra=6C8
3433    else
3434      libs_nsgui=
3435      headerpad_extra=690
3436    fi
3437    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3438
3439    ## This is here because src/Makefile.in did some extra fiddling around
3440    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3441    ##   #ifndef LD_SWITCH_SYSTEM
3442    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3443    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3444    ## not using gcc, darwin system not on an alpha (ie darwin, since
3445    ## darwin + alpha does not occur).
3446    ## Because this was done in src/Makefile.in, the resulting part of
3447    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3448    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3449    ## rather than LD_SWITCH_SYSTEM.
3450    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3451      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3452    ;;
3453
3454   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3455   ## find X at run-time.
3456   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3457   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3458   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3459   ## had different values in configure (in ac_link) and src/Makefile.in.
3460   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3461   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3462
3463   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3464 esac
3465
3466 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3467   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3468 fi
3469
3470 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3471
3472
3473 LD_FIRSTFLAG=
3474 ORDINARY_LINK=
3475 case "$opsys" in
3476   ## gnu: GNU needs its own crt0.
3477   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3478
3479   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3480   ## library search parth, i.e. it won't search /usr/lib for libc and
3481   ## friends.  Using -nostartfiles instead avoids this problem, and
3482   ## will also work on earlier NetBSD releases.
3483   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3484
3485   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3486   ##   MkLinux/LinuxPPC needs this.
3487   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3488   gnu-*)
3489     case "$machine" in
3490       macppc|ibms390x) LD_FIRSTFLAG="-nostdlib" ;;
3491     esac
3492     ;;
3493 esac
3494
3495
3496 if test "x$ORDINARY_LINK" = "xyes"; then
3497
3498   LD_FIRSTFLAG=""
3499   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3500
3501 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3502 ## freebsd, gnu-* not on macppc|ibms390x.
3503 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3504
3505   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3506   ## places that are difficult to figure out at make time.  Fortunately,
3507   ## these same versions allow you to pass arbitrary flags on to the
3508   ## linker, so there is no reason not to use it as a linker.
3509   ##
3510   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3511   ## searching for libraries in its internal directories, so we have to
3512   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3513   LD_FIRSTFLAG="-nostdlib"
3514 fi
3515
3516 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3517 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3518
3519 AC_SUBST(LD_FIRSTFLAG)
3520
3521
3522 ## FIXME? The logic here is not precisely the same as that above.
3523 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3524 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3525 LIB_GCC=
3526 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3527
3528   case "$opsys" in
3529     freebsd|netbsd|openbsd) LIB_GCC= ;;
3530
3531     gnu-*)
3532       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3533       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3534       case $host_cpu in
3535       arm*)
3536         LIB_GCC="-lgcc_s"
3537         ;;
3538       *)
3539         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3540         ## immediately undefine it again and redefine it to empty.
3541         ## Was the C_SWITCH_X_SITE part really necessary?
3542 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3543         LIB_GCC=
3544         ;;
3545       esac
3546       ;;
3547
3548     ## Ask GCC where to find libgcc.a.
3549     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3550   esac
3551 fi                              dnl if $GCC
3552 AC_SUBST(LIB_GCC)
3553
3554
3555 ## If we're using X11/GNUstep, define some consequences.
3556 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3557   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3558   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3559 fi
3560
3561
3562 AH_TOP([/* GNU Emacs site configuration template file.
3563
3564 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3565   Free Software Foundation, Inc.
3566
3567 This file is part of GNU Emacs.
3568
3569 GNU Emacs is free software: you can redistribute it and/or modify
3570 it under the terms of the GNU General Public License as published by
3571 the Free Software Foundation, either version 3 of the License, or
3572 (at your option) any later version.
3573
3574 GNU Emacs is distributed in the hope that it will be useful,
3575 but WITHOUT ANY WARRANTY; without even the implied warranty of
3576 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3577 GNU General Public License for more details.
3578
3579 You should have received a copy of the GNU General Public License
3580 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3581
3582
3583 /* No code in Emacs #includes config.h twice, but some bits of code
3584    intended to work with other packages as well (like gmalloc.c)
3585    think they can include it as many times as they like.  */
3586 #ifndef EMACS_CONFIG_H
3587 #define EMACS_CONFIG_H
3588 ])dnl
3589
3590 AH_BOTTOM([
3591 /* On AIX 3 this must be included before any other include file.  */
3592 #include <alloca.h>
3593 #if ! HAVE_ALLOCA
3594 # error "alloca not available on this machine"
3595 #endif
3596
3597 /* Define AMPERSAND_FULL_NAME if you use the convention
3598    that & in the full name stands for the login id.  */
3599 /* Turned on June 1996 supposing nobody will mind it.  */
3600 #define AMPERSAND_FULL_NAME
3601
3602 /* `subprocesses' should be defined if you want to
3603    have code for asynchronous subprocesses
3604    (as used in M-x compile and M-x shell).
3605    Only MSDOS does not support this (it overrides
3606    this in its config_opsysfile below).  */
3607
3608 #define subprocesses
3609
3610 /* Include the os and machine dependent files.  */
3611 #include config_opsysfile
3612 #ifdef config_machfile
3613 # include config_machfile
3614 #endif
3615
3616 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3617    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3618   (There is probably a better place to do this, but right now the
3619    Cocoa side does this in s/darwin.h and we cannot parallel this
3620    exactly since GNUstep is multi-OS.  */
3621 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3622 #  define SYSTEM_PURESIZE_EXTRA 30000
3623 #endif
3624
3625 #ifdef emacs /* Don't do this for lib-src.  */
3626 /* Tell regex.c to use a type compatible with Emacs.  */
3627 #define RE_TRANSLATE_TYPE Lisp_Object
3628 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3629 #ifdef make_number
3630 /* If make_number is a macro, use it.  */
3631 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3632 #else
3633 /* If make_number is a function, avoid it.  */
3634 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3635 #endif
3636 #endif
3637
3638 /* These default definitions are good for almost all machines.
3639    Any exceptions should override them in m/MACHINE.h.
3640    They must be usable in preprocessor conditionals.  */
3641
3642 #ifndef BITS_PER_CHAR
3643 #define BITS_PER_CHAR 8
3644 #endif
3645
3646 #ifndef BITS_PER_SHORT
3647 #define BITS_PER_SHORT 16
3648 #endif
3649
3650 #ifndef BITS_PER_INT
3651 #define BITS_PER_INT 32
3652 #endif
3653
3654 #ifndef BITS_PER_LONG
3655 #ifdef _LP64
3656 #define BITS_PER_LONG 64
3657 #else
3658 #define BITS_PER_LONG 32
3659 #endif
3660 #endif
3661
3662 #if !defined BITS_PER_LONG_LONG && HAVE_LONG_LONG_INT
3663 #define BITS_PER_LONG_LONG 64
3664 #endif
3665
3666 /* Define if the compiler supports function prototypes.  It may do so but
3667    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3668 #undef PROTOTYPES
3669
3670 #include <string.h>
3671 #include <stdlib.h>
3672
3673 #if defined __GNUC__ && (__GNUC__ > 2 \
3674                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3675 #define NO_RETURN       __attribute__ ((__noreturn__))
3676 #else
3677 #define NO_RETURN       /* nothing */
3678 #endif
3679
3680 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3681 #define NO_INLINE __attribute__((noinline))
3682 #else
3683 #define NO_INLINE
3684 #endif
3685
3686 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3687 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3688 #else
3689 #define EXTERNALLY_VISIBLE
3690 #endif
3691
3692 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3693 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3694 #else
3695 # define ATTRIBUTE_FORMAT(spec) /* empty */
3696 #endif
3697
3698 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3699 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3700    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3701 #else
3702 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3703    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3704 #endif
3705
3706 /* Some versions of GNU/Linux define noinline in their headers.  */
3707 #ifdef noinline
3708 #undef noinline
3709 #endif
3710
3711 /* These won't be used automatically yet.  We also need to know, at least,
3712    that the stack is continuous.  */
3713 #ifdef __GNUC__
3714 #  ifndef GC_SETJMP_WORKS
3715   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3716 #    define GC_SETJMP_WORKS 1
3717 #  endif
3718 #endif
3719
3720 #endif /* EMACS_CONFIG_H */
3721
3722 /*
3723 Local Variables:
3724 mode: c
3725 End:
3726 */
3727 ])dnl
3728
3729 #### Report on what we decided to do.
3730 #### Report GTK as a toolkit, even if it doesn't use Xt.
3731 #### It makes printing result more understandable as using GTK sets
3732 #### toolkit_scroll_bars to yes by default.
3733 if test "${HAVE_GTK}" = "yes"; then
3734   USE_X_TOOLKIT=GTK
3735 fi
3736
3737 and_machfile=
3738 if test -n "$machfile"; then
3739   and_machfile=" and \`${machfile}'"
3740 fi
3741
3742 echo "
3743 Configured for \`${canonical}'.
3744
3745   Where should the build process find the source code?    ${srcdir}
3746   What operating system and machine description files should Emacs use?
3747         \`${opsysfile}'${and_machfile}
3748   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3749   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3750   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3751   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3752   What window system should Emacs use?                    ${window_system}
3753   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3754
3755 if test -n "${x_includes}"; then
3756 echo "  Where do we find X Windows header files?                ${x_includes}"
3757 else
3758 echo "  Where do we find X Windows header files?                Standard dirs"
3759 fi
3760 if test -n "${x_libraries}"; then
3761 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3762 else
3763 echo "  Where do we find X Windows libraries?                   Standard dirs"
3764 fi
3765
3766 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3767 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3768 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3769 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3770 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3771 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3772 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3773 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3774
3775 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3776 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3777 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3778 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3779 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3780 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3781 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3782
3783 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3784 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3785 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3786 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3787
3788 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3789 echo
3790
3791 if test -n "${EMACSDATA}"; then
3792    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3793 fi
3794 if test -n "${EMACSDOC}"; then
3795    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3796 fi
3797
3798 if test $USE_XASSERTS = yes; then
3799    echo "  Compiling with asserts turned on."
3800    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3801 fi
3802
3803 echo
3804
3805 if test "$HAVE_NS" = "yes"; then
3806    echo
3807    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3808 The installed application will go to nextstep/Emacs.app and can be
3809 run or moved from there."
3810    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3811       echo "The application will be fully self-contained."
3812     else
3813       echo "The lisp resources for the application will be installed under ${prefix}.
3814 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3815 to run if these resources are not installed."
3816    fi
3817    echo
3818 fi
3819
3820 if test "${opsys}" = "cygwin"; then
3821   case `uname -r` in
3822     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3823            echo
3824            ;;
3825   esac
3826 fi
3827
3828 # Remove any trailing slashes in these variables.
3829 [test "${prefix}" != NONE &&
3830   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3831 test "${exec_prefix}" != NONE &&
3832   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3833
3834 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3835 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3836 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3837 dnl (else you get "no `Makefile.am' found for any configure output").
3838 dnl This will work, but you get a config.status that is not quite right
3839 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3840 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3841 dnl it seems better to just live with the duplication.
3842 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3843
3844 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3845        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3846        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3847        leim/Makefile])
3848
3849 dnl test/ is not present in release tarfiles.
3850 opt_makefile=test/automated/Makefile
3851
3852 if test -f $srcdir/${opt_makefile}.in; then
3853   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3854   dnl Again, it's best not to use a variable.  Though you can add
3855   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3856   AC_CONFIG_FILES([test/automated/Makefile])
3857 fi
3858
3859
3860 dnl admin/ may or may not be present.
3861 opt_makefile=admin/unidata/Makefile
3862
3863 if test -f $srcdir/${opt_makefile}.in; then
3864   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3865   AC_CONFIG_FILES([admin/unidata/Makefile])
3866 fi
3867
3868
3869 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3870
3871 AC_SUBST(SUBDIR_MAKEFILES_IN)
3872
3873 dnl Make the necessary directories, if they don't exist.
3874 AC_CONFIG_COMMANDS([mkdirs], [
3875 for dir in etc lisp ; do
3876   test -d ${dir} || mkdir ${dir}
3877 done
3878 ])
3879
3880 dnl You might wonder (I did) why epaths.h is generated by running make,
3881 dnl rather than just letting configure generate it from epaths.in.
3882 dnl One reason is that the various paths are not fully expanded (see above);
3883 dnl eg gamedir=${prefix}/var/games/emacs.
3884 dnl Secondly, the GNU Coding standards require that one should be able
3885 dnl to run `make prefix=/some/where/else' and override the values set
3886 dnl by configure.  This also explains the `move-if-change' test and
3887 dnl the use of force in the `epaths-force' rule in Makefile.in.
3888 AC_CONFIG_COMMANDS([epaths], [
3889 echo creating src/epaths.h
3890 ${MAKE-make} epaths-force
3891 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3892
3893 AC_CONFIG_COMMANDS([gdbinit], [
3894 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3895   echo creating src/.gdbinit
3896   echo source $srcdir/src/.gdbinit > src/.gdbinit
3897 fi
3898 ])
3899
3900 AC_OUTPUT
3901
3902 dnl configure.in ends here