lisp/gnus/sieve-mode.el

   1 ;;; sieve-mode.el --- Sieve code editing commands for Emacs
   2
   3 ;; Copyright (C) 2001-2015 Free Software Foundation, Inc.
   4
   5 ;; Author: Simon Josefsson <simon@josefsson.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; This file contain editing mode functions and font-lock support for
  25 ;; editing Sieve scripts.  It sets up C-mode with support for
  26 ;; sieve-style #-comments and a lightly hacked syntax table.  It was
  27 ;; strongly influenced by awk-mode.el.
  28 ;;
  29 ;; Put something similar to the following in your .emacs to use this file:
  30 ;;
  31 ;; (load "~/lisp/sieve")
  32 ;; (setq auto-mode-alist (cons '("\\.siv\\'" . sieve-mode) auto-mode-alist))
  33 ;;
  34 ;; References:
  35 ;;
  36 ;; RFC 3028,
  37 ;; "Sieve: A Mail Filtering Language",
  38 ;; by Tim Showalter.
  39 ;;
  40 ;; Release history:
  41 ;;
  42 ;; 2001-03-02 version 1.0 posted to gnu.emacs.sources
  43 ;;            version 1.1 change file extension into ".siv" (official one)
  44 ;;                        added keymap and menubar to hook into sieve-manage
  45 ;; 2001-10-31 version 1.2 committed to Oort Gnus
  46
  47 ;;; Code:
  48
  49 (autoload 'sieve-manage "sieve")
  50 (autoload 'sieve-upload "sieve")
  51 (eval-when-compile
  52   (require 'font-lock))
  53
  54 (defgroup sieve nil
  55   "Sieve."
  56   :group 'languages)
  57
  58 (defcustom sieve-mode-hook nil
  59   "Hook run in sieve mode buffers."
  60   :group 'sieve
  61   :type 'hook)
  62
  63 ;; Font-lock
  64
  65 (defvar sieve-control-commands-face 'sieve-control-commands
  66   "Face name used for Sieve Control Commands.")
  67
  68 (defface sieve-control-commands
  69   '((((type tty) (class color)) (:foreground "blue" :weight light))
  70     (((class grayscale) (background light)) (:foreground "LightGray" :bold t))
  71     (((class grayscale) (background dark)) (:foreground "DimGray" :bold t))
  72     (((class color) (background light)) (:foreground "Orchid"))
  73     (((class color) (background dark)) (:foreground "LightSteelBlue"))
  74     (t (:bold t)))
  75   "Face used for Sieve Control Commands."
  76   :group 'sieve)
  77 ;; backward-compatibility alias
  78 (put 'sieve-control-commands-face 'face-alias 'sieve-control-commands)
  79 (put 'sieve-control-commands-face 'obsolete-face "22.1")
  80
  81 (defvar sieve-action-commands-face 'sieve-action-commands
  82   "Face name used for Sieve Action Commands.")
  83
  84 (defface sieve-action-commands
  85   '((((type tty) (class color)) (:foreground "blue" :weight bold))
  86     (((class color) (background light)) (:foreground "Blue"))
  87     (((class color) (background dark)) (:foreground "LightSkyBlue"))
  88     (t (:inverse-video t :bold t)))
  89   "Face used for Sieve Action Commands."
  90   :group 'sieve)
  91 ;; backward-compatibility alias
  92 (put 'sieve-action-commands-face 'face-alias 'sieve-action-commands)
  93 (put 'sieve-action-commands-face 'obsolete-face "22.1")
  94
  95 (defvar sieve-test-commands-face 'sieve-test-commands
  96   "Face name used for Sieve Test Commands.")
  97
  98 (defface sieve-test-commands
  99   '((((type tty) (class color)) (:foreground "magenta"))
 100     (((class grayscale) (background light))
 101      (:foreground "LightGray" :bold t :underline t))
 102     (((class grayscale) (background dark))
 103      (:foreground "Gray50" :bold t :underline t))
 104     (((class color) (background light)) (:foreground "CadetBlue"))
 105     (((class color) (background dark)) (:foreground "Aquamarine"))
 106     (t (:bold t :underline t)))
 107   "Face used for Sieve Test Commands."
 108   :group 'sieve)
 109 ;; backward-compatibility alias
 110 (put 'sieve-test-commands-face 'face-alias 'sieve-test-commands)
 111 (put 'sieve-test-commands-face 'obsolete-face "22.1")
 112
 113 (defvar sieve-tagged-arguments-face 'sieve-tagged-arguments
 114   "Face name used for Sieve Tagged Arguments.")
 115
 116 (defface sieve-tagged-arguments
 117   '((((type tty) (class color)) (:foreground "cyan" :weight bold))
 118     (((class grayscale) (background light)) (:foreground "LightGray" :bold t))
 119     (((class grayscale) (background dark)) (:foreground "DimGray" :bold t))
 120     (((class color) (background light)) (:foreground "Purple"))
 121     (((class color) (background dark)) (:foreground "Cyan"))
 122     (t (:bold t)))
 123   "Face used for Sieve Tagged Arguments."
 124   :group 'sieve)
 125 ;; backward-compatibility alias
 126 (put 'sieve-tagged-arguments-face 'face-alias 'sieve-tagged-arguments)
 127 (put 'sieve-tagged-arguments-face 'obsolete-face "22.1")
 128
 129
 130 (defconst sieve-font-lock-keywords
 131   (eval-when-compile
 132     (list
 133      ;; control commands
 134      (cons (regexp-opt '("require" "if" "else" "elsif" "stop")
 135                        'words)
 136            'sieve-control-commands-face)
 137      ;; action commands
 138      (cons (regexp-opt '("fileinto" "redirect" "reject" "keep" "discard")
 139                        'words)
 140            'sieve-action-commands-face)
 141      ;; test commands
 142      (cons (regexp-opt '("address" "allof" "anyof" "exists" "false"
 143                          "true" "header" "not" "size" "envelope")
 144                        'words)
 145            'sieve-test-commands-face)
 146      (cons "\\Sw+:\\sw+"
 147            'sieve-tagged-arguments-face))))
 148
 149 ;; Syntax table
 150
 151 (defvar sieve-mode-syntax-table nil
 152   "Syntax table in use in sieve-mode buffers.")
 153
 154 (if sieve-mode-syntax-table
 155     ()
 156   (setq sieve-mode-syntax-table (make-syntax-table))
 157   (modify-syntax-entry ?\\ "\\" sieve-mode-syntax-table)
 158   (modify-syntax-entry ?\n ">   " sieve-mode-syntax-table)
 159   (modify-syntax-entry ?\f ">   " sieve-mode-syntax-table)
 160   (modify-syntax-entry ?\# "<   " sieve-mode-syntax-table)
 161   (modify-syntax-entry ?/ "." sieve-mode-syntax-table)
 162   (modify-syntax-entry ?* "." sieve-mode-syntax-table)
 163   (modify-syntax-entry ?+ "." sieve-mode-syntax-table)
 164   (modify-syntax-entry ?- "." sieve-mode-syntax-table)
 165   (modify-syntax-entry ?= "." sieve-mode-syntax-table)
 166   (modify-syntax-entry ?% "." sieve-mode-syntax-table)
 167   (modify-syntax-entry ?< "." sieve-mode-syntax-table)
 168   (modify-syntax-entry ?> "." sieve-mode-syntax-table)
 169   (modify-syntax-entry ?& "." sieve-mode-syntax-table)
 170   (modify-syntax-entry ?| "." sieve-mode-syntax-table)
 171   (modify-syntax-entry ?_ "_" sieve-mode-syntax-table)
 172   (modify-syntax-entry ?\' "\"" sieve-mode-syntax-table))
 173
 174 ;; Key map definition
 175
 176 (defvar sieve-mode-map
 177   (let ((map (make-sparse-keymap)))
 178     (define-key map "\C-c\C-l" 'sieve-upload)
 179     (define-key map "\C-c\C-c" 'sieve-upload-and-kill)
 180     (define-key map "\C-c\C-m" 'sieve-manage)
 181     map)
 182   "Key map used in sieve mode.")
 183
 184 ;; Menu definition
 185
 186 (defvar sieve-mode-menu nil
 187   "Menubar used in sieve mode.")
 188
 189 ;; Code for Sieve editing mode.
 190 (autoload 'easy-menu-add-item "easymenu")
 191
 192 ;;;###autoload
 193 (define-derived-mode sieve-mode c-mode "Sieve"
 194   "Major mode for editing Sieve code.
 195 This is much like C mode except for the syntax of comments.  Its keymap
 196 inherits from C mode's and it has the same variables for customizing
 197 indentation.  It has its own abbrev table and its own syntax table.
 198
 199 Turning on Sieve mode runs `sieve-mode-hook'."
 200   (set (make-local-variable 'paragraph-start) (concat "$\\|" page-delimiter))
 201   (set (make-local-variable 'paragraph-separate) paragraph-start)
 202   (set (make-local-variable 'comment-start) "#")
 203   (set (make-local-variable 'comment-end) "")
 204   ;;(set (make-local-variable 'comment-start-skip) "\\(^\\|\\s-\\);?#+ *")
 205   (set (make-local-variable 'comment-start-skip) "#+ *")
 206   (unless (featurep 'xemacs)
 207     (set (make-local-variable 'font-lock-defaults)
 208          '(sieve-font-lock-keywords nil nil ((?_ . "w")))))
 209   (easy-menu-add-item nil nil sieve-mode-menu))
 210
 211 ;; Menu
 212
 213 (easy-menu-define sieve-mode-menu sieve-mode-map
 214   "Sieve Menu."
 215   '("Sieve"
 216     ["Upload script" sieve-upload t]
 217     ["Manage scripts on server" sieve-manage t]))
 218
 219 (provide 'sieve-mode)
 220
 221 ;; sieve-mode.el ends here