lisp/emacs-lisp/debug.el

   1 ;;; debug.el --- debuggers and related commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, tools, maint
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a major mode documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (defgroup debugger nil
  32   "Debuggers and related commands for Emacs."
  33   :prefix "debugger-"
  34   :group 'debug)
  35
  36 (defcustom debugger-mode-hook nil
  37   "*Hooks run when `debugger-mode' is turned on."
  38   :type 'hook
  39   :group 'debugger
  40   :version "20.3")
  41
  42
  43 (defcustom debug-function-list nil
  44   "List of functions currently set for debug on entry."
  45   :type '(repeat function)
  46   :group 'debugger)
  47
  48 (defcustom debugger-step-after-exit nil
  49   "Non-nil means \"single-step\" after the debugger exits."
  50   :type 'boolean
  51   :group 'debugger)
  52
  53 (defvar debugger-value nil
  54   "This is the value for the debugger to return, when it returns.")
  55
  56 (defvar debugger-old-buffer nil
  57   "This is the buffer that was current when the debugger was entered.")
  58
  59 (defvar debugger-outer-match-data)
  60 (defvar debugger-outer-load-read-function)
  61 (defvar debugger-outer-overriding-local-map)
  62 (defvar debugger-outer-overriding-terminal-local-map)
  63 (defvar debugger-outer-track-mouse)
  64 (defvar debugger-outer-last-command)
  65 (defvar debugger-outer-this-command)
  66 (defvar debugger-outer-unread-command-char)
  67 (defvar debugger-outer-unread-command-events)
  68 (defvar debugger-outer-unread-post-input-method-events)
  69 (defvar debugger-outer-last-input-event)
  70 (defvar debugger-outer-last-command-event)
  71 (defvar debugger-outer-last-nonmenu-event)
  72 (defvar debugger-outer-last-event-frame)
  73 (defvar debugger-outer-standard-input)
  74 (defvar debugger-outer-standard-output)
  75 (defvar debugger-outer-inhibit-redisplay)
  76 (defvar debugger-outer-cursor-in-echo-area)
  77
  78 ;;;###autoload
  79 (setq debugger 'debug)
  80 ;;;###autoload
  81 (defun debug (&rest debugger-args)
  82   "Enter debugger.  To return, type \\<debugger-mode-map>`\\[debugger-continue]'.
  83 Arguments are mainly for use when this is called from the internals
  84 of the evaluator.
  85
  86 You may call with no args, or you may pass nil as the first arg and
  87 any other args you like.  In that case, the list of args after the
  88 first will be printed into the backtrace buffer."
  89   (interactive)
  90   (message "Entering debugger...")
  91   (let (debugger-value
  92         (debug-on-error nil)
  93         (debug-on-quit nil)
  94         (debugger-buffer (let ((default-major-mode 'fundamental-mode))
  95                            (get-buffer-create "*Backtrace*")))
  96         (debugger-old-buffer (current-buffer))
  97         (debugger-step-after-exit nil)
  98         ;; Don't keep reading from an executing kbd macro!
  99         (executing-kbd-macro nil)
 100         ;; Save the outer values of these vars for the `e' command
 101         ;; before we replace the values.
 102         (debugger-outer-match-data (match-data))
 103         (debugger-outer-load-read-function load-read-function)
 104         (debugger-outer-overriding-local-map overriding-local-map)
 105         (debugger-outer-overriding-terminal-local-map
 106          overriding-terminal-local-map)
 107         (debugger-outer-track-mouse track-mouse)
 108         (debugger-outer-last-command last-command)
 109         (debugger-outer-this-command this-command)
 110         (debugger-outer-unread-command-char unread-command-char)
 111         (debugger-outer-unread-command-events unread-command-events)
 112         (debugger-outer-unread-post-input-method-events
 113          unread-post-input-method-events)
 114         (debugger-outer-last-input-event last-input-event)
 115         (debugger-outer-last-command-event last-command-event)
 116         (debugger-outer-last-nonmenu-event last-nonmenu-event)
 117         (debugger-outer-last-event-frame last-event-frame)
 118         (debugger-outer-standard-input standard-input)
 119         (debugger-outer-standard-output standard-output)
 120         (debugger-outer-inhibit-redisplay inhibit-redisplay)
 121         (debugger-outer-cursor-in-echo-area cursor-in-echo-area))
 122     ;; Set this instead of binding it, so that `q'
 123     ;; will not restore it.
 124     (setq overriding-terminal-local-map nil)
 125     ;; Don't let these magic variables affect the debugger itself.
 126     (let ((last-command nil) this-command track-mouse
 127           (unread-command-char -1) unread-command-events
 128           unread-post-input-method-events
 129           last-input-event last-command-event last-nonmenu-event
 130           last-event-frame
 131           overriding-local-map
 132           load-read-function
 133           ;; If we are inside a minibuffer, allow nesting
 134           ;; so that we don't get an error from the `e' command.
 135           (enable-recursive-minibuffers
 136            (or enable-recursive-minibuffers (> (minibuffer-depth) 0)))
 137           (standard-input t) (standard-output t)
 138           inhibit-redisplay
 139           (cursor-in-echo-area nil))
 140       (unwind-protect
 141           (save-excursion
 142             (save-window-excursion
 143               (pop-to-buffer debugger-buffer)
 144               (setq buffer-read-only nil)
 145               (erase-buffer)
 146               (set-buffer-multibyte nil)
 147               (let ((standard-output (current-buffer))
 148                     (print-escape-newlines t)
 149                     (print-length 50))
 150                 (backtrace))
 151               (goto-char (point-min))
 152               (debugger-mode)
 153               (delete-region (point)
 154                              (progn
 155                                (search-forward "\n  debug(")
 156                                (forward-line 1)
 157                                (point)))
 158               (debugger-reenable)
 159               ;; lambda is for debug-on-call when a function call is next.
 160               ;; debug is for debug-on-entry function called.
 161               (cond ((memq (car debugger-args) '(lambda debug))
 162                      (insert "Entering:\n")
 163                      (if (eq (car debugger-args) 'debug)
 164                          (progn
 165                            ;; Skip the frames for backtrace-debug, byte-code,
 166                            ;; and debug.
 167                            (backtrace-debug 3 t)
 168                            (delete-char 1)
 169                            (insert ?*)
 170                            (beginning-of-line))))
 171                     ;; Exiting a function.
 172                     ((eq (car debugger-args) 'exit)
 173                      (insert "Return value: ")
 174                      (setq debugger-value (nth 1 debugger-args))
 175                      (prin1 debugger-value (current-buffer))
 176                      (insert ?\n)
 177                      (delete-char 1)
 178                      (insert ? )
 179                      (beginning-of-line))
 180                     ;; Debugger entered for an error.
 181                     ((eq (car debugger-args) 'error)
 182                      (insert "Signaling: ")
 183                      (prin1 (nth 1 debugger-args) (current-buffer))
 184                      (insert ?\n))
 185                     ;; debug-on-call, when the next thing is an eval.
 186                     ((eq (car debugger-args) t)
 187                      (insert "Beginning evaluation of function call form:\n"))
 188                     ;; User calls debug directly.
 189                     (t
 190                      (prin1 (if (eq (car debugger-args) 'nil)
 191                                 (cdr debugger-args) debugger-args)
 192                             (current-buffer))
 193                      (insert ?\n)))
 194               (message "")
 195               (let ((inhibit-trace t)
 196                     (standard-output nil)
 197                     (buffer-read-only t))
 198                 (message "")
 199                 ;; Make sure we unbind buffer-read-only in the right buffer.
 200                 (save-excursion
 201                   (recursive-edit)))))
 202         ;; Kill or at least neuter the backtrace buffer, so that users
 203         ;; don't try to execute debugger commands in an invalid context.
 204         (if (get-buffer-window debugger-buffer 'visible)
 205             ;; Still visible despite the save-window-excursion?  Maybe it
 206             ;; it's in a pop-up frame.  It would be annoying to delete and
 207             ;; recreate it every time the debugger stops, so instead we'll
 208             ;; erase it but leave it visible.
 209             (save-excursion
 210               (set-buffer debugger-buffer)
 211               (erase-buffer)
 212               (fundamental-mode))
 213           (kill-buffer debugger-buffer))
 214         (set-match-data debugger-outer-match-data)))
 215     ;; Put into effect the modified values of these variables
 216     ;; in case the user set them with the `e' command.
 217     (setq load-read-function debugger-outer-load-read-function)
 218     (setq overriding-local-map debugger-outer-overriding-local-map)
 219     (setq overriding-terminal-local-map
 220           debugger-outer-overriding-terminal-local-map)
 221     (setq track-mouse debugger-outer-track-mouse)
 222     (setq last-command debugger-outer-last-command)
 223     (setq this-command debugger-outer-this-command)
 224     (setq unread-command-char debugger-outer-unread-command-char)
 225     (setq unread-command-events debugger-outer-unread-command-events)
 226     (setq unread-post-input-method-events
 227           debugger-outer-unread-post-input-method-events)
 228     (setq last-input-event debugger-outer-last-input-event)
 229     (setq last-command-event debugger-outer-last-command-event)
 230     (setq last-nonmenu-event debugger-outer-last-nonmenu-event)
 231     (setq last-event-frame debugger-outer-last-event-frame)
 232     (setq standard-input debugger-outer-standard-input)
 233     (setq standard-output debugger-outer-standard-output)
 234     (setq inhibit-redisplay debugger-outer-inhibit-redisplay)
 235     (setq cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 236     (setq debug-on-next-call debugger-step-after-exit)
 237     debugger-value))
 238 \f
 239 (defun debugger-step-through ()
 240   "Proceed, stepping through subexpressions of this expression.
 241 Enter another debugger on next entry to eval, apply or funcall."
 242   (interactive)
 243   (setq debugger-step-after-exit t)
 244   (message "Proceeding, will debug on next eval or call.")
 245   (exit-recursive-edit))
 246
 247 (defun debugger-continue ()
 248   "Continue, evaluating this expression without stopping."
 249   (interactive)
 250   (message "Continuing.")
 251   (exit-recursive-edit))
 252
 253 (defun debugger-return-value (val)
 254   "Continue, specifying value to return.
 255 This is only useful when the value returned from the debugger
 256 will be used, such as in a debug on exit from a frame."
 257   (interactive "XReturn value (evaluated): ")
 258   (setq debugger-value val)
 259   (princ "Returning " t)
 260   (prin1 debugger-value)
 261   (exit-recursive-edit))
 262
 263 (defun debugger-jump ()
 264   "Continue to exit from this frame, with all debug-on-entry suspended."
 265   (interactive)
 266   ;; Compensate for the two extra stack frames for debugger-jump.
 267   (let ((debugger-frame-offset (+ debugger-frame-offset 2)))
 268     (debugger-frame))
 269   ;; Turn off all debug-on-entry functions
 270   ;; but leave them in the list.
 271   (let ((list debug-function-list))
 272     (while list
 273       (fset (car list)
 274             (debug-on-entry-1 (car list) (symbol-function (car list)) nil))
 275       (setq list (cdr list))))
 276   (message "Continuing through this frame")
 277   (exit-recursive-edit))
 278
 279 (defun debugger-reenable ()
 280   "Turn all debug-on-entry functions back on."
 281   (let ((list debug-function-list))
 282     (while list
 283       (or (consp (symbol-function (car list)))
 284           (debug-convert-byte-code (car list)))
 285       (fset (car list)
 286             (debug-on-entry-1 (car list) (symbol-function (car list)) t))
 287       (setq list (cdr list)))))
 288
 289 (defun debugger-frame-number ()
 290   "Return number of frames in backtrace before the one point points at."
 291   (save-excursion
 292     (beginning-of-line)
 293     (let ((opoint (point))
 294           (count 0))
 295       (goto-char (point-min))
 296       (if (or (equal (buffer-substring (point) (+ (point) 6))
 297                      "Signal")
 298               (equal (buffer-substring (point) (+ (point) 6))
 299                      "Return"))
 300           (progn
 301             (search-forward ":")
 302             (forward-sexp 1)))
 303       (forward-line 1)
 304       (while (progn
 305                (forward-char 2)
 306                (if (= (following-char) ?\()
 307                    (forward-sexp 1)
 308                  (forward-sexp 2))
 309                (forward-line 1)
 310                (<= (point) opoint))
 311         (setq count (1+ count)))
 312       count)))
 313
 314 ;; Chosen empirically to account for all the frames
 315 ;; that will exist when debugger-frame is called
 316 ;; within the first one that appears in the backtrace buffer.
 317 ;; Assumes debugger-frame is called from a key;
 318 ;; will be wrong if it is called with Meta-x.
 319 (defconst debugger-frame-offset 8 "")
 320
 321 (defun debugger-frame ()
 322   "Request entry to debugger when this frame exits.
 323 Applies to the frame whose line point is on in the backtrace."
 324   (interactive)
 325   (beginning-of-line)
 326   (let ((level (debugger-frame-number)))
 327     (backtrace-debug (+ level debugger-frame-offset) t))
 328   (if (= (following-char) ? )
 329       (let ((buffer-read-only nil))
 330         (delete-char 1)
 331         (insert ?*)))
 332   (beginning-of-line))
 333
 334 (defun debugger-frame-clear ()
 335   "Do not enter debugger when this frame exits.
 336 Applies to the frame whose line point is on in the backtrace."
 337   (interactive)
 338   (beginning-of-line)
 339   (let ((level (debugger-frame-number)))
 340     (backtrace-debug (+ level debugger-frame-offset) nil))
 341   (if (= (following-char) ?*)
 342       (let ((buffer-read-only nil))
 343         (delete-char 1)
 344         (insert ? )))
 345   (beginning-of-line))
 346
 347
 348
 349 (put 'debugger-env-macro 'lisp-indent-function 0)
 350 (defmacro debugger-env-macro (&rest body)
 351   "Run BODY in original environment."
 352   (`
 353    (save-excursion
 354      (if (null (buffer-name debugger-old-buffer))
 355          ;; old buffer deleted
 356          (setq debugger-old-buffer (current-buffer)))
 357      (set-buffer debugger-old-buffer)
 358      (let ((load-read-function debugger-outer-load-read-function)
 359            (overriding-terminal-local-map
 360             debugger-outer-overriding-terminal-local-map)
 361            (overriding-local-map debugger-outer-overriding-local-map)
 362            (track-mouse debugger-outer-track-mouse)
 363            (last-command debugger-outer-last-command)
 364            (this-command debugger-outer-this-command)
 365            (unread-command-char debugger-outer-unread-command-char)
 366            (unread-command-events debugger-outer-unread-command-events)
 367            (unread-post-input-method-events
 368             debugger-outer-unread-post-input-method-events)
 369            (last-input-event debugger-outer-last-input-event)
 370            (last-command-event debugger-outer-last-command-event)
 371            (last-nonmenu-event debugger-outer-last-nonmenu-event)
 372            (last-event-frame debugger-outer-last-event-frame)
 373            (standard-input debugger-outer-standard-input)
 374            (standard-output debugger-outer-standard-output)
 375            (inhibit-redisplay debugger-outer-inhibit-redisplay)
 376            (cursor-in-echo-area debugger-outer-cursor-in-echo-area))
 377        (set-match-data debugger-outer-match-data)
 378        (prog1 (progn (,@ body))
 379          (setq debugger-outer-match-data (match-data))
 380          (setq debugger-outer-load-read-function load-read-function)
 381          (setq debugger-outer-overriding-terminal-local-map
 382                overriding-terminal-local-map)
 383          (setq debugger-outer-overriding-local-map overriding-local-map)
 384          (setq debugger-outer-track-mouse track-mouse)
 385          (setq debugger-outer-last-command last-command)
 386          (setq debugger-outer-this-command this-command)
 387          (setq debugger-outer-unread-command-char unread-command-char)
 388          (setq debugger-outer-unread-command-events unread-command-events)
 389          (setq debugger-outer-unread-post-input-method-events
 390                unread-post-input-method-events)
 391          (setq debugger-outer-last-input-event last-input-event)
 392          (setq debugger-outer-last-command-event last-command-event)
 393          (setq debugger-outer-last-nonmenu-event last-nonmenu-event)
 394          (setq debugger-outer-last-event-frame last-event-frame)
 395          (setq debugger-outer-standard-input standard-input)
 396          (setq debugger-outer-standard-output standard-output)
 397          (setq debugger-outer-inhibit-redisplay inhibit-redisplay)
 398          (setq debugger-outer-cursor-in-echo-area cursor-in-echo-area)
 399          )))))
 400
 401 (defun debugger-eval-expression (exp)
 402   "Eval an expression, in an environment like that outside the debugger."
 403   (interactive
 404    (list (read-from-minibuffer "Eval: "
 405                                nil read-expression-map t
 406                                'read-expression-history)))
 407   (debugger-env-macro (eval-expression exp)))
 408 \f
 409 (defvar debugger-mode-map nil)
 410 (if debugger-mode-map
 411     nil
 412   (let ((loop ? ))
 413     (setq debugger-mode-map (make-keymap))
 414     (suppress-keymap debugger-mode-map)
 415     (define-key debugger-mode-map "-" 'negative-argument)
 416     (define-key debugger-mode-map "b" 'debugger-frame)
 417     (define-key debugger-mode-map "c" 'debugger-continue)
 418     (define-key debugger-mode-map "j" 'debugger-jump)
 419     (define-key debugger-mode-map "r" 'debugger-return-value)
 420     (define-key debugger-mode-map "u" 'debugger-frame-clear)
 421     (define-key debugger-mode-map "d" 'debugger-step-through)
 422     (define-key debugger-mode-map "l" 'debugger-list-functions)
 423     (define-key debugger-mode-map "h" 'describe-mode)
 424     (define-key debugger-mode-map "q" 'top-level)
 425     (define-key debugger-mode-map "e" 'debugger-eval-expression)
 426     (define-key debugger-mode-map " " 'next-line)
 427     (define-key debugger-mode-map "R" 'debugger-record-expression)
 428     ))
 429
 430
 431 (defcustom debugger-record-buffer "*Debugger-record*"
 432   "*Buffer name for expression values, for \\[debugger-record-expression]."
 433   :type 'string
 434   :group 'debugger
 435   :version "20.3")
 436
 437 (defun debugger-record-expression  (exp)
 438   "Display a variable's value and record it in `*Backtrace-record*' buffer."
 439   (interactive
 440    (list (read-from-minibuffer
 441           "Record Eval: "
 442           nil
 443           read-expression-map t
 444           'read-expression-history)))
 445   (let* ((buffer (get-buffer-create debugger-record-buffer))
 446          (standard-output buffer))
 447     (princ (format "Debugger Eval (%s): " exp))
 448     (princ (debugger-eval-expression exp))
 449     (terpri))
 450
 451   (with-current-buffer (get-buffer debugger-record-buffer)
 452     (save-excursion
 453       (forward-line -1)
 454       (message
 455        (buffer-substring (point) (progn (end-of-line) (point)))))))
 456
 457 (put 'debugger-mode 'mode-class 'special)
 458
 459 (defun debugger-mode ()
 460   "Mode for backtrace buffers, selected in debugger.
 461 \\<debugger-mode-map>
 462 A line starts with `*' if exiting that frame will call the debugger.
 463 Type \\[debugger-frame] or \\[debugger-frame-clear] to set or remove the `*'.
 464
 465 When in debugger due to frame being exited,
 466 use the \\[debugger-return-value] command to override the value
 467 being returned from that frame.
 468
 469 Use \\[debug-on-entry] and \\[cancel-debug-on-entry] to control
 470 which functions will enter the debugger when called.
 471
 472 Complete list of commands:
 473 \\{debugger-mode-map}"
 474   (kill-all-local-variables)
 475   (setq major-mode 'debugger-mode)
 476   (setq mode-name "Debugger")
 477   (setq truncate-lines t)
 478   (set-syntax-table emacs-lisp-mode-syntax-table)
 479   (use-local-map debugger-mode-map)
 480   (run-hooks 'debugger-mode-hook))
 481 \f
 482 ;;;###autoload
 483 (defun debug-on-entry (function)
 484   "Request FUNCTION to invoke debugger each time it is called.
 485 If you tell the debugger to continue, FUNCTION's execution proceeds.
 486 This works by modifying the definition of FUNCTION,
 487 which must be written in Lisp, not predefined.
 488 Use \\[cancel-debug-on-entry] to cancel the effect of this command.
 489 Redefining FUNCTION also cancels it."
 490   (interactive "aDebug on entry (to function): ")
 491   (debugger-reenable)
 492   ;; Handle a function that has been aliased to some other function.
 493   (if (symbolp (symbol-function function))
 494       (fset function `(lambda (&rest debug-on-entry-args)
 495                         (apply ',(symbol-function function)
 496                                debug-on-entry-args))))
 497   (if (subrp (symbol-function function))
 498       (error "Function %s is a primitive" function))
 499   (or (consp (symbol-function function))
 500       (debug-convert-byte-code function))
 501   (or (consp (symbol-function function))
 502       (error "Definition of %s is not a list" function))
 503   (fset function (debug-on-entry-1 function (symbol-function function) t))
 504   (or (memq function debug-function-list)
 505       (setq debug-function-list (cons function debug-function-list)))
 506   function)
 507
 508 ;;;###autoload
 509 (defun cancel-debug-on-entry (&optional function)
 510   "Undo effect of \\[debug-on-entry] on FUNCTION.
 511 If argument is nil or an empty string, cancel for all functions."
 512   (interactive
 513    (list (let ((name
 514                 (completing-read "Cancel debug on entry (to function): "
 515                                  ;; Make an "alist" of the functions
 516                                  ;; that now have debug on entry.
 517                                  (mapcar 'list
 518                                          (mapcar 'symbol-name
 519                                                  debug-function-list))
 520                                  nil t nil)))
 521            (if name (intern name)))))
 522   (debugger-reenable)
 523   (if (and function (not (string= function "")))
 524       (progn
 525         (fset function
 526               (debug-on-entry-1 function (symbol-function function) nil))
 527         (setq debug-function-list (delq function debug-function-list))
 528         function)
 529     (message "Cancelling debug-on-entry for all functions")
 530     (mapcar 'cancel-debug-on-entry debug-function-list)))
 531
 532 (defun debug-convert-byte-code (function)
 533   (let ((defn (symbol-function function)))
 534     (if (not (consp defn))
 535         ;; Assume a compiled code object.
 536         (let* ((contents (append defn nil))
 537                (body
 538                 (list (list 'byte-code (nth 1 contents)
 539                             (nth 2 contents) (nth 3 contents)))))
 540           (if (nthcdr 5 contents)
 541               (setq body (cons (list 'interactive (nth 5 contents)) body)))
 542           (if (nth 4 contents)
 543               ;; Use `documentation' here, to get the actual string,
 544               ;; in case the compiled function has a reference
 545               ;; to the .elc file.
 546               (setq body (cons (documentation function) body)))
 547           (fset function (cons 'lambda (cons (car contents) body)))))))
 548
 549 (defun debug-on-entry-1 (function defn flag)
 550   (if (subrp defn)
 551       (error "%s is a built-in function" function)
 552     (if (eq (car defn) 'macro)
 553         (debug-on-entry-1 function (cdr defn) flag)
 554       (or (eq (car defn) 'lambda)
 555           (error "%s not user-defined Lisp function" function))
 556       (let (tail prec)
 557         (if (stringp (car (nthcdr 2 defn)))
 558             (setq tail (nthcdr 3 defn)
 559                   prec (list (car defn) (car (cdr defn))
 560                              (car (cdr (cdr defn)))))
 561           (setq tail (nthcdr 2 defn)
 562                 prec (list (car defn) (car (cdr defn)))))
 563         (if (eq flag (equal (car tail) '(debug 'debug)))
 564             defn
 565           (if flag
 566               (nconc prec (cons '(debug 'debug) tail))
 567             (nconc prec (cdr tail))))))))
 568
 569 (defun debugger-list-functions ()
 570   "Display a list of all the functions now set to debug on entry."
 571   (interactive)
 572   (with-output-to-temp-buffer "*Help*"
 573     (if (null debug-function-list)
 574         (princ "No debug-on-entry functions now\n")
 575       (princ "Functions set to debug on entry:\n\n")
 576       (let ((list debug-function-list))
 577         (while list
 578           (prin1 (car list))
 579           (terpri)
 580           (setq list (cdr list))))
 581       (princ "Note: if you have redefined a function, then it may no longer\n")
 582       (princ "be set to debug on entry, even if it is in the list."))
 583     (save-excursion
 584       (set-buffer standard-output)
 585       (help-mode))))
 586
 587 (provide 'debug)
 588
 589 ;;; debug.el ends here