lisp/complete.el

   1 ;;; complete.el --- partial completion mechanism plus other goodies
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993, 1999 Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Gillespie <daveg@synaptics.com>
   6 ;; Keywords: abbrev convenience
   7 ;; Special thanks to Hallvard Furuseth for his many ideas and contributions.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Extended completion for the Emacs minibuffer.
  29 ;;
  30 ;; The basic idea is that the command name or other completable text is
  31 ;; divided into words and each word is completed separately, so that
  32 ;; "M-x p-b" expands to "M-x print-buffer".  If the entry is ambiguous
  33 ;; each word is completed as much as possible and then the cursor is
  34 ;; left at the first position where typing another letter will resolve
  35 ;; the ambiguity.
  36 ;;
  37 ;; Word separators for this purpose are hyphen, space, and period.
  38 ;; These would most likely occur in command names, Info menu items,
  39 ;; and file names, respectively.  But all word separators are treated
  40 ;; alike at all times.
  41 ;;
  42 ;; This completion package replaces the old-style completer's key
  43 ;; bindings for TAB, SPC, RET, and `?'.  The old completer is still
  44 ;; available on the Meta versions of those keys.  If you set
  45 ;; PC-meta-flag to nil, the old completion keys will be left alone
  46 ;; and the partial completer will use the Meta versions of the keys.
  47
  48
  49 ;; Usage:  M-x partial-completion-mode.  During completable minibuffer entry,
  50 ;;
  51 ;;     TAB    means to do a partial completion;
  52 ;;     SPC    means to do a partial complete-word;
  53 ;;     RET    means to do a partial complete-and-exit;
  54 ;;     ?      means to do a partial completion-help.
  55 ;;
  56 ;; If you set PC-meta-flag to nil, then TAB, SPC, RET, and ? perform
  57 ;; original Emacs completions, and M-TAB etc. do partial completion.
  58 ;; To do this, put the command,
  59 ;;
  60 ;;       (setq PC-meta-flag nil)
  61 ;;
  62 ;; in your .emacs file.  To load partial completion automatically, put
  63 ;;
  64 ;;       (partial-completion-mode t)
  65 ;;
  66 ;; in your .emacs file, too.  Things will be faster if you byte-compile
  67 ;; this file when you install it.
  68 ;;
  69 ;; As an extra feature, in cases where RET would not normally
  70 ;; complete (such as `C-x b'), the M-RET key will always do a partial
  71 ;; complete-and-exit.  Thus `C-x b f.c RET' will select or create a
  72 ;; buffer called "f.c", but `C-x b f.c M-RET' will select the existing
  73 ;; buffer whose name matches that pattern (perhaps "filing.c").
  74 ;; (PC-meta-flag does not affect this behavior; M-RET used to be
  75 ;; undefined in this situation.)
  76 ;;
  77 ;; The regular M-TAB (lisp-complete-symbol) command also supports
  78 ;; partial completion in this package.
  79
  80 ;; File name completion does not do partial completion of directories
  81 ;; on the path, e.g., "/u/b/f" will not complete to "/usr/bin/foo",
  82 ;; but you can put *'s in the path to accomplish this:  "/u*/b*/f".
  83 ;; Stars are required for performance reasons.
  84
  85 ;; In addition, this package includes a feature for accessing include
  86 ;; files.  For example, `C-x C-f <sys/time.h> RET' reads the file
  87 ;; /usr/include/sys/time.h.  The variable PC-include-file-path is a
  88 ;; list of directories in which to search for include files.  Completion
  89 ;; is supported in include file names.
  90
  91
  92 ;;; Code:
  93
  94 (defgroup partial-completion nil
  95   "Partial Completion of items."
  96   :prefix "pc-"
  97   :group 'minibuffer
  98   :group 'convenience)
  99
 100 (defcustom partial-completion-mode nil
 101   "Toggle Partial Completion mode.
 102 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 103 nil) is enhanced so that if some string is divided into words and each word is
 104 delimited by a character in `PC-word-delimiters', partial words are completed
 105 as much as possible and `*' characters are treated likewise in file names.
 106 This variable should be set only with \\[customize], which is equivalent
 107 to using the function `partial-completion-mode'."
 108   :set (lambda (symbol value)
 109          (partial-completion-mode (or value 0)))
 110   :initialize 'custom-initialize-default
 111   :type 'boolean
 112   :group 'partial-completion
 113   :require 'complete)
 114
 115 (defcustom PC-first-char 'find-file
 116   "*Control how the first character of a string is to be interpreted.
 117 If nil, the first character of a string is not taken literally if it is a word
 118 delimiter, so that \".e\" matches \"*.e*\".
 119 If t, the first character of a string is always taken literally even if it is a
 120 word delimiter, so that \".e\" matches \".e*\".
 121 If non-nil and non-t, the first character is taken literally only for file name
 122 completion."
 123   :type '(choice (const :tag "delimiter" nil)
 124                  (const :tag "literal" t)
 125                  (other :tag "find-file" find-file))
 126   :group 'partial-completion)
 127
 128 (defcustom PC-meta-flag t
 129   "*If non-nil, TAB means PC completion and M-TAB means normal completion.
 130 Otherwise, TAB means normal completion and M-TAB means Partial Completion."
 131   :type 'boolean
 132   :group 'partial-completion)
 133
 134 (defcustom PC-word-delimiters "-_. "
 135   "*A string of characters treated as word delimiters for completion.
 136 Some arcane rules:
 137 If `]' is in this string, it must come first.
 138 If `^' is in this string, it must not come first.
 139 If `-' is in this string, it must come first or right after `]'.
 140 In other words, if S is this string, then `[S]' must be a legal Emacs regular
 141 expression (not containing character ranges like `a-z')."
 142   :type 'string
 143   :group 'partial-completion)
 144
 145 (defcustom PC-include-file-path '("/usr/include" "/usr/local/include")
 146   "*A list of directories in which to look for include files.
 147 If nil, means use the colon-separated path in the variable $INCPATH instead."
 148   :type '(repeat directory)
 149   :group 'partial-completion)
 150
 151 (defcustom PC-disable-includes nil
 152   "*If non-nil, include-file support in \\[find-file] is disabled."
 153   :type 'boolean
 154   :group 'partial-completion)
 155
 156 (defvar PC-default-bindings t
 157   "If non-nil, default partial completion key bindings are suppressed.")
 158 \f
 159 (defvar PC-old-read-file-name-internal nil)
 160
 161 ;;;###autoload
 162 (defun partial-completion-mode (&optional arg)
 163   "Toggle Partial Completion mode.
 164 With prefix ARG, turn Partial Completion mode on if ARG is positive.
 165
 166 When Partial Completion mode is enabled, TAB (or M-TAB if `PC-meta-flag' is
 167 nil) is enhanced so that if some string is divided into words and each word is
 168 delimited by a character in `PC-word-delimiters', partial words are completed
 169 as much as possible.
 170
 171 For example, M-x p-c-m expands to M-x partial-completion-mode since no other
 172 command begins with that sequence of characters, and
 173 \\[find-file] f_b.c TAB might complete to foo_bar.c if that file existed and no
 174 other file in that directory begin with that sequence of characters.
 175
 176 Unless `PC-disable-includes' is non-nil, the \"<...>\" sequence is interpreted
 177 specially in \\[find-file].  For example,
 178 \\[find-file] <sys/time.h> RET finds the file /usr/include/sys/time.h.
 179 See also the variable `PC-include-file-path'."
 180   (interactive "P")
 181   (let ((on-p (if arg
 182                   (> (prefix-numeric-value arg) 0)
 183                 (not partial-completion-mode))))
 184     ;; Deal with key bindings...
 185     (PC-bindings on-p)
 186     ;; Deal with include file feature...
 187     (cond ((not on-p)
 188            (remove-hook 'find-file-not-found-hooks 'PC-look-for-include-file))
 189           ((not PC-disable-includes)
 190            (add-hook 'find-file-not-found-hooks 'PC-look-for-include-file)))
 191     ;; ... with some underhand redefining.
 192     (cond ((and (not on-p) (functionp PC-old-read-file-name-internal))
 193            (fset 'read-file-name-internal PC-old-read-file-name-internal))
 194           ((and (not PC-disable-includes) (not PC-old-read-file-name-internal))
 195            (setq PC-old-read-file-name-internal
 196                  (symbol-function 'read-file-name-internal))
 197            (fset 'read-file-name-internal
 198                  'PC-read-include-file-name-internal)))
 199     ;; Finally set the mode variable.
 200     (setq partial-completion-mode on-p)))
 201
 202 (defun PC-bindings (bind)
 203   (let ((completion-map minibuffer-local-completion-map)
 204         (must-match-map minibuffer-local-must-match-map))
 205     (cond ((not bind)
 206            ;; These bindings are the default bindings.  It would be better to
 207            ;; restore the previous bindings.
 208            (define-key completion-map "\t"      'minibuffer-complete)
 209            (define-key completion-map " "       'minibuffer-complete-word)
 210            (define-key completion-map "?"       'minibuffer-completion-help)
 211
 212            (define-key must-match-map "\t"      'minibuffer-complete)
 213            (define-key must-match-map " "       'minibuffer-complete-word)
 214            (define-key must-match-map "\r"      'minibuffer-complete-and-exit)
 215            (define-key must-match-map "\n"      'minibuffer-complete-and-exit)
 216            (define-key must-match-map "?"       'minibuffer-completion-help)
 217
 218            (define-key global-map "\e\t"        'complete-symbol))
 219           (PC-default-bindings
 220            (define-key completion-map "\t"      'PC-complete)
 221            (define-key completion-map " "       'PC-complete-word)
 222            (define-key completion-map "?"       'PC-completion-help)
 223
 224            (define-key completion-map "\e\t"    'PC-complete)
 225            (define-key completion-map "\e "     'PC-complete-word)
 226            (define-key completion-map "\e\r"    'PC-force-complete-and-exit)
 227            (define-key completion-map "\e\n"    'PC-force-complete-and-exit)
 228            (define-key completion-map "\e?"     'PC-completion-help)
 229
 230            (define-key must-match-map "\t"      'PC-complete)
 231            (define-key must-match-map " "       'PC-complete-word)
 232            (define-key must-match-map "\r"      'PC-complete-and-exit)
 233            (define-key must-match-map "\n"      'PC-complete-and-exit)
 234            (define-key must-match-map "?"       'PC-completion-help)
 235
 236            (define-key must-match-map "\e\t"    'PC-complete)
 237            (define-key must-match-map "\e "     'PC-complete-word)
 238            (define-key must-match-map "\e\r"    'PC-complete-and-exit)
 239            (define-key must-match-map "\e\n"    'PC-complete-and-exit)
 240            (define-key must-match-map "\e?"     'PC-completion-help)
 241
 242            (define-key global-map "\e\t"        'PC-lisp-complete-symbol)))))
 243
 244 ;; Because the `partial-completion-mode' option is defined before the
 245 ;; `partial-completion-mode' command and its callee, we give the former a
 246 ;; default `:initialize' keyword value.  Otherwise, the `:set' keyword value
 247 ;; would be called to initialise the variable value, and that would call the
 248 ;; as-yet undefined `partial-completion-mode' function.
 249 ;; Since the default `:initialize' keyword value (obviously) does not turn on
 250 ;; Partial Completion Mode, we do that here, once the `partial-completion-mode'
 251 ;; function and its callee are defined.
 252 (when partial-completion-mode
 253   (partial-completion-mode t))
 254 \f
 255 (defun PC-complete ()
 256   "Like minibuffer-complete, but allows \"b--di\"-style abbreviations.
 257 For example, \"M-x b--di\" would match `byte-recompile-directory', or any
 258 name which consists of three or more words, the first beginning with \"b\"
 259 and the third beginning with \"di\".
 260
 261 The pattern \"b--d\" is ambiguous for `byte-recompile-directory' and
 262 `beginning-of-defun', so this would produce a list of completions
 263 just like when normal Emacs completions are ambiguous.
 264
 265 Word-delimiters for the purposes of Partial Completion are \"-\", \"_\",
 266 \".\", and SPC."
 267   (interactive)
 268   (if (PC-was-meta-key)
 269       (minibuffer-complete)
 270     ;; If the previous command was not this one,
 271     ;; never scroll, always retry completion.
 272     (or (eq last-command this-command)
 273         (setq minibuffer-scroll-window nil))
 274     (let ((window minibuffer-scroll-window))
 275       ;; If there's a fresh completion window with a live buffer,
 276       ;; and this command is repeated, scroll that window.
 277       (if (and window (window-buffer window)
 278                (buffer-name (window-buffer window)))
 279           (save-excursion
 280             (set-buffer (window-buffer window))
 281             (if (pos-visible-in-window-p (point-max) window)
 282                 (set-window-start window (point-min) nil)
 283               (scroll-other-window)))
 284         (PC-do-completion nil)))))
 285
 286
 287 (defun PC-complete-word ()
 288   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 289 See `PC-complete' for details.
 290 This can be bound to other keys, like `-' and `.', if you wish."
 291   (interactive)
 292   (if (eq (PC-was-meta-key) PC-meta-flag)
 293       (if (eq last-command-char ? )
 294           (minibuffer-complete-word)
 295         (self-insert-command 1))
 296     (self-insert-command 1)
 297     (if (eobp)
 298         (PC-do-completion 'word))))
 299
 300
 301 (defun PC-complete-space ()
 302   "Like `minibuffer-complete-word', but allows \"b--di\"-style abbreviations.
 303 See `PC-complete' for details.
 304 This is suitable for binding to other keys which should act just like SPC."
 305   (interactive)
 306   (if (eq (PC-was-meta-key) PC-meta-flag)
 307       (minibuffer-complete-word)
 308     (insert " ")
 309     (if (eobp)
 310         (PC-do-completion 'word))))
 311
 312
 313 (defun PC-complete-and-exit ()
 314   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 315 See `PC-complete' for details."
 316   (interactive)
 317   (if (eq (PC-was-meta-key) PC-meta-flag)
 318       (minibuffer-complete-and-exit)
 319     (PC-do-complete-and-exit)))
 320
 321 (defun PC-force-complete-and-exit ()
 322   "Like `minibuffer-complete-and-exit', but allows \"b--di\"-style abbreviations.
 323 See `PC-complete' for details."
 324   (interactive)
 325   (let ((minibuffer-completion-confirm nil))
 326     (PC-do-complete-and-exit)))
 327
 328 (defun PC-do-complete-and-exit ()
 329   (if (= (buffer-size) 0)  ; Duplicate the "bug" that Info-menu relies on...
 330       (exit-minibuffer)
 331     (let ((flag (PC-do-completion 'exit)))
 332       (and flag
 333            (if (or (eq flag 'complete)
 334                    (not minibuffer-completion-confirm))
 335                (exit-minibuffer)
 336              (PC-temp-minibuffer-message " [Confirm]"))))))
 337
 338
 339 (defun PC-completion-help ()
 340   "Like `minibuffer-completion-help', but allows \"b--di\"-style abbreviations.
 341 See `PC-complete' for details."
 342   (interactive)
 343   (if (eq (PC-was-meta-key) PC-meta-flag)
 344       (minibuffer-completion-help)
 345     (PC-do-completion 'help)))
 346
 347 (defun PC-was-meta-key ()
 348   (or (/= (length (this-command-keys)) 1)
 349       (let ((key (aref (this-command-keys) 0)))
 350         (if (integerp key)
 351             (>= key 128)
 352           (not (null (memq 'meta (event-modifiers key))))))))
 353
 354
 355 (defvar PC-ignored-extensions 'empty-cache)
 356 (defvar PC-delims 'empty-cache)
 357 (defvar PC-ignored-regexp nil)
 358 (defvar PC-word-failed-flag nil)
 359 (defvar PC-delim-regex nil)
 360 (defvar PC-ndelims-regex nil)
 361 (defvar PC-delims-list nil)
 362
 363 (defvar PC-completion-as-file-name-predicate
 364   (function
 365    (lambda ()
 366      (memq minibuffer-completion-table
 367            '(read-file-name-internal read-directory-name-internal))))
 368    "A function testing whether a minibuffer completion now will work filename-style.
 369 The function takes no arguments, and typically looks at the value
 370 of `minibuffer-completion-table' and the minibuffer contents.")
 371
 372 (defun PC-do-completion (&optional mode beg end)
 373   (or beg (setq beg (point-min)))
 374   (or end (setq end (point-max)))
 375   (let* ((table minibuffer-completion-table)
 376          (pred minibuffer-completion-predicate)
 377          (filename (funcall PC-completion-as-file-name-predicate))
 378          (dirname nil)
 379          dirlength
 380          (str (buffer-substring beg end))
 381          (incname (and filename (string-match "<\\([^\"<>]*\\)>?$" str)))
 382          (ambig nil)
 383          basestr
 384          regex
 385          p offset
 386          (poss nil)
 387          helpposs
 388          (case-fold-search completion-ignore-case))
 389
 390     ;; Check if buffer contents can already be considered complete
 391     (if (and (eq mode 'exit)
 392              (PC-is-complete-p str table pred))
 393         'complete
 394
 395       ;; Record how many characters at the beginning are not included
 396       ;; in completion.
 397       (setq dirlength
 398             (if filename
 399                 (length (file-name-directory str))
 400               0))
 401
 402       ;; Do substitutions in directory names
 403       (and filename
 404            (not (equal str (setq p (substitute-in-file-name str))))
 405            (progn
 406              (delete-region beg end)
 407              (insert p)
 408              (setq str p end (+ beg (length str)))))
 409
 410       ;; Prepare various delimiter strings
 411       (or (equal PC-word-delimiters PC-delims)
 412           (setq PC-delims PC-word-delimiters
 413                 PC-delim-regex (concat "[" PC-delims "]")
 414                 PC-ndelims-regex (concat "[^" PC-delims "]*")
 415                 PC-delims-list (append PC-delims nil)))
 416
 417       ;; Look for wildcard expansions in directory name
 418       (and filename
 419            (string-match "\\*.*/" str)
 420            (let ((pat str)
 421                  files)
 422              (setq p (1+ (string-match "/[^/]*\\'" pat)))
 423              (while (setq p (string-match PC-delim-regex pat p))
 424                (setq pat (concat (substring pat 0 p)
 425                                  "*"
 426                                  (substring pat p))
 427                      p (+ p 2)))
 428              (setq files (PC-expand-many-files (concat pat "*")))
 429              (if files
 430                  (let ((dir (file-name-directory (car files)))
 431                        (p files))
 432                    (while (and (setq p (cdr p))
 433                                (equal dir (file-name-directory (car p)))))
 434                    (if p
 435                        (setq filename nil table nil pred nil
 436                              ambig t)
 437                      (delete-region beg end)
 438                      (setq str (concat dir (file-name-nondirectory str)))
 439                      (insert str)
 440                      (setq end (+ beg (length str)))))
 441                (setq filename nil table nil pred nil))))
 442
 443       ;; Strip directory name if appropriate
 444       (if filename
 445           (if incname
 446               (setq basestr (substring str incname)
 447                     dirname (substring str 0 incname))
 448             (setq basestr (file-name-nondirectory str)
 449                   dirname (file-name-directory str))
 450             ;; Make sure str is consistent with its directory and basename
 451             ;; parts.  This is important on DOZe'NT systems when str only
 452             ;; includes a drive letter, like in "d:".
 453             (setq str (concat dirname basestr)))
 454         (setq basestr str))
 455
 456       ;; Convert search pattern to a standard regular expression
 457       (setq regex (regexp-quote basestr)
 458             offset (if (and (> (length regex) 0)
 459                             (not (eq (aref basestr 0) ?\*))
 460                             (or (eq PC-first-char t)
 461                                 (and PC-first-char filename))) 1 0)
 462             p offset)
 463       (while (setq p (string-match PC-delim-regex regex p))
 464         (if (eq (aref regex p) ? )
 465             (setq regex (concat (substring regex 0 p)
 466                                 PC-ndelims-regex
 467                                 PC-delim-regex
 468                                 (substring regex (1+ p)))
 469                   p (+ p (length PC-ndelims-regex) (length PC-delim-regex)))
 470           (let ((bump (if (memq (aref regex p)
 471                                 '(?$ ?^ ?\. ?* ?+ ?? ?[ ?] ?\\))
 472                           -1 0)))
 473             (setq regex (concat (substring regex 0 (+ p bump))
 474                                 PC-ndelims-regex
 475                                 (substring regex (+ p bump)))
 476                   p (+ p (length PC-ndelims-regex) 1)))))
 477       (setq p 0)
 478       (if filename
 479           (while (setq p (string-match "\\\\\\*" regex p))
 480             (setq regex (concat (substring regex 0 p)
 481                                 "[^/]*"
 482                                 (substring regex (+ p 2))))))
 483       ;;(setq the-regex regex)
 484       (setq regex (concat "\\`" regex))
 485
 486       ;; Find an initial list of possible completions
 487       (if (not (setq p (string-match (concat PC-delim-regex
 488                                              (if filename "\\|\\*" ""))
 489                                      str
 490                                      (+ (length dirname) offset))))
 491
 492           ;; Minibuffer contains no hyphens -- simple case!
 493           (setq poss (all-completions str
 494                                       table
 495                                       pred))
 496
 497         ;; Use all-completions to do an initial cull.  This is a big win,
 498         ;; since all-completions is written in C!
 499         (let ((compl (all-completions (substring str 0 p)
 500                                       table
 501                                       pred)))
 502           (setq p compl)
 503           (while p
 504             (and (string-match regex (car p))
 505                  (progn
 506                    (set-text-properties 0 (length (car p)) '() (car p))
 507                    (setq poss (cons (car p) poss))))
 508             (setq p (cdr p)))))
 509
 510       ;; Now we have a list of possible completions
 511       (cond
 512
 513        ;; No valid completions found
 514        ((null poss)
 515         (if (and (eq mode 'word)
 516                  (not PC-word-failed-flag))
 517             (let ((PC-word-failed-flag t))
 518               (delete-backward-char 1)
 519               (PC-do-completion 'word))
 520           (beep)
 521           (PC-temp-minibuffer-message (if ambig
 522                                           " [Ambiguous dir name]"
 523                                         (if (eq mode 'help)
 524                                             " [No completions]"
 525                                           " [No match]")))
 526           nil))
 527
 528        ;; More than one valid completion found
 529        ((or (cdr (setq helpposs poss))
 530             (memq mode '(help word)))
 531
 532         ;; Handle completion-ignored-extensions
 533         (and filename
 534              (not (eq mode 'help))
 535              (let ((p2 poss))
 536
 537                ;; Build a regular expression representing the extensions list
 538                (or (equal completion-ignored-extensions PC-ignored-extensions)
 539                    (setq PC-ignored-regexp
 540                          (concat "\\("
 541                                  (mapconcat
 542                                   'regexp-quote
 543                                   (setq PC-ignored-extensions
 544                                         completion-ignored-extensions)
 545                                   "\\|")
 546                                  "\\)\\'")))
 547
 548                ;; Check if there are any without an ignored extension.
 549                ;; Also ignore `.' and `..'.
 550                (setq p nil)
 551                (while p2
 552                  (or (string-match PC-ignored-regexp (car p2))
 553                      (string-match "\\(\\`\\|/\\)[.][.]?/?\\'" (car p2))
 554                      (setq p (cons (car p2) p)))
 555                  (setq p2 (cdr p2)))
 556
 557                ;; If there are "good" names, use them
 558                (and p (setq poss p))))
 559
 560         ;; Is the actual string one of the possible completions?
 561         (setq p (and (not (eq mode 'help)) poss))
 562         (while (and p
 563                     (not (string-equal (car p) basestr)))
 564           (setq p (cdr p)))
 565         (and p (null mode)
 566              (PC-temp-minibuffer-message " [Complete, but not unique]"))
 567         (if (and p
 568                  (not (and (null mode)
 569                            (eq this-command last-command))))
 570             t
 571
 572           ;; If ambiguous, try for a partial completion
 573           (let ((improved nil)
 574                 prefix
 575                 (pt nil)
 576                 (skip "\\`"))
 577
 578             ;; Check if next few letters are the same in all cases
 579             (if (and (not (eq mode 'help))
 580                      (setq prefix (try-completion "" (mapcar 'list poss))))
 581                 (let ((first t) i)
 582                   (if (eq mode 'word)
 583                       (setq prefix (PC-chop-word prefix basestr)))
 584                   (goto-char (+ beg (length dirname)))
 585                   (while (and (progn
 586                                 (setq i 0)
 587                                 (while (< i (length prefix))
 588                                   (if (and (< (point) end)
 589                                            (eq (aref prefix i)
 590                                                (following-char)))
 591                                       (forward-char 1)
 592                                     (if (and (< (point) end)
 593                                              (or (and (looking-at " ")
 594                                                       (memq (aref prefix i)
 595                                                             PC-delims-list))
 596                                                  (eq (downcase (aref prefix i))
 597                                                      (downcase
 598                                                       (following-char)))))
 599                                         (progn
 600                                           (delete-char 1)
 601                                           (setq end (1- end)))
 602                                       (and filename (looking-at "\\*")
 603                                            (progn
 604                                              (delete-char 1)
 605                                              (setq end (1- end))))
 606                                       (setq improved t))
 607                                     (insert (substring prefix i (1+ i)))
 608                                     (setq end (1+ end)))
 609                                   (setq i (1+ i)))
 610                                 (or pt (equal (point) beg)
 611                                     (setq pt (point)))
 612                                 (looking-at PC-delim-regex))
 613                               (setq skip (concat skip
 614                                                  (regexp-quote prefix)
 615                                                  PC-ndelims-regex)
 616                                     prefix (try-completion
 617                                             ""
 618                                             (mapcar
 619                                              (function
 620                                               (lambda (x)
 621                                                 (list
 622                                                  (and (string-match skip x)
 623                                                       (substring
 624                                                        x
 625                                                        (match-end 0))))))
 626                                              poss)))
 627                               (or (> i 0) (> (length prefix) 0))
 628                               (or (not (eq mode 'word))
 629                                   (and first (> (length prefix) 0)
 630                                        (setq first nil
 631                                              prefix (substring prefix 0 1))))))
 632                   (goto-char (if (eq mode 'word) end
 633                                (or pt beg)))))
 634
 635             (if (and (eq mode 'word)
 636                      (not PC-word-failed-flag))
 637
 638                 (if improved
 639
 640                     ;; We changed it... would it be complete without the space?
 641                     (if (PC-is-complete-p (buffer-substring 1 (1- end))
 642                                           table pred)
 643                         (delete-region (1- end) end)))
 644
 645               (if improved
 646
 647                   ;; We changed it... enough to be complete?
 648                   (and (eq mode 'exit)
 649                        (PC-is-complete-p (buffer-string) table pred))
 650
 651                 ;; If totally ambiguous, display a list of completions
 652                 (if (or completion-auto-help
 653                         (eq mode 'help))
 654                     (with-output-to-temp-buffer "*Completions*"
 655                       (display-completion-list (sort helpposs 'string-lessp))
 656                       (save-excursion
 657                         (set-buffer standard-output)
 658                         ;; Record which part of the buffer we are completing
 659                         ;; so that choosing a completion from the list
 660                         ;; knows how much old text to replace.
 661                         (setq completion-base-size dirlength)))
 662                   (PC-temp-minibuffer-message " [Next char not unique]"))
 663                 nil)))))
 664
 665        ;; Only one possible completion
 666        (t
 667         (if (equal basestr (car poss))
 668             (if (null mode)
 669                 (PC-temp-minibuffer-message " [Sole completion]"))
 670           (delete-region beg end)
 671           (insert (format "%s"
 672                           (if filename
 673                               (substitute-in-file-name (concat dirname (car poss)))
 674                             (car poss)))))
 675         t)))))
 676
 677
 678 (defun PC-is-complete-p (str table pred)
 679   (let ((res (if (listp table)
 680                  (assoc str table)
 681                (if (vectorp table)
 682                    (or (equal str "nil")   ; heh, heh, heh
 683                        (intern-soft str table))
 684                  (funcall table str pred 'lambda)))))
 685     (and res
 686          (or (not pred)
 687              (and (not (listp table)) (not (vectorp table)))
 688              (funcall pred res))
 689          res)))
 690
 691 (defun PC-chop-word (new old)
 692   (let ((i -1)
 693         (j -1))
 694     (while (and (setq i (string-match PC-delim-regex old (1+ i)))
 695                 (setq j (string-match PC-delim-regex new (1+ j)))))
 696     (if (and j
 697              (or (not PC-word-failed-flag)
 698                  (setq j (string-match PC-delim-regex new (1+ j)))))
 699         (substring new 0 (1+ j))
 700       new)))
 701
 702 (defvar PC-not-minibuffer nil)
 703
 704 (defun PC-temp-minibuffer-message (message)
 705   "A Lisp version of `temp_minibuffer_message' from minibuf.c."
 706   (cond (PC-not-minibuffer
 707          (message message)
 708          (sit-for 2)
 709          (message ""))
 710         ((fboundp 'temp-minibuffer-message)
 711          (temp-minibuffer-message message))
 712         (t
 713          (let ((point-max (point-max)))
 714            (save-excursion
 715              (goto-char point-max)
 716              (insert message))
 717            (let ((inhibit-quit t))
 718              (sit-for 2)
 719              (delete-region point-max (point-max))
 720              (when quit-flag
 721                (setq quit-flag nil
 722                      unread-command-events '(7))))))))
 723
 724
 725 (defun PC-lisp-complete-symbol ()
 726   "Perform completion on Lisp symbol preceding point.
 727 That symbol is compared against the symbols that exist
 728 and any additional characters determined by what is there
 729 are inserted.
 730 If the symbol starts just after an open-parenthesis,
 731 only symbols with function definitions are considered.
 732 Otherwise, all symbols with function definitions, values
 733 or properties are considered."
 734   (interactive)
 735   (let* ((end (point))
 736          (buffer-syntax (syntax-table))
 737          (beg (unwind-protect
 738                   (save-excursion
 739                     (if lisp-mode-syntax-table
 740                         (set-syntax-table lisp-mode-syntax-table))
 741                     (backward-sexp 1)
 742                     (while (= (char-syntax (following-char)) ?\')
 743                       (forward-char 1))
 744                     (point))
 745                 (set-syntax-table buffer-syntax)))
 746          (minibuffer-completion-table obarray)
 747          (minibuffer-completion-predicate
 748           (if (eq (char-after (1- beg)) ?\()
 749               'fboundp
 750             (function (lambda (sym)
 751                         (or (boundp sym) (fboundp sym)
 752                             (symbol-plist sym))))))
 753          (PC-not-minibuffer t))
 754     (PC-do-completion nil beg end)))
 755
 756 ;;; Use the shell to do globbing.
 757 ;;; This could now use file-expand-wildcards instead.
 758
 759 (defun PC-expand-many-files (name)
 760   (save-excursion
 761     (set-buffer (generate-new-buffer " *Glob Output*"))
 762     (erase-buffer)
 763     (shell-command (concat "echo " name) t)
 764     (goto-char (point-min))
 765     (if (looking-at ".*No match")
 766         nil
 767       (insert "(\"")
 768       (while (search-forward " " nil t)
 769         (delete-backward-char 1)
 770         (insert "\" \""))
 771       (goto-char (point-max))
 772       (delete-backward-char 1)
 773       (insert "\")")
 774       (goto-char (point-min))
 775       (let ((files (read (current-buffer))) (p nil))
 776         (kill-buffer (current-buffer))
 777         (or (equal completion-ignored-extensions PC-ignored-extensions)
 778             (setq PC-ignored-regexp
 779                   (concat "\\("
 780                           (mapconcat
 781                            'regexp-quote
 782                            (setq PC-ignored-extensions
 783                                  completion-ignored-extensions)
 784                            "\\|")
 785                           "\\)\\'")))
 786         (setq p nil)
 787         (while files
 788           (or (string-match PC-ignored-regexp (car files))
 789               (setq p (cons (car files) p)))
 790           (setq files (cdr files)))
 791         p))))
 792
 793 ;;; Facilities for loading C header files.  This is independent from the
 794 ;;; main completion code.  See also the variable `PC-include-file-path'
 795 ;;; at top of this file.
 796
 797 (defun PC-look-for-include-file ()
 798   (if (string-match "[\"<]\\([^\"<>]*\\)[\">]?$" (buffer-file-name))
 799       (let ((name (substring (buffer-file-name)
 800                              (match-beginning 1) (match-end 1)))
 801             (punc (aref (buffer-file-name) (match-beginning 0)))
 802             (path nil)
 803             new-buf)
 804         (kill-buffer (current-buffer))
 805         (if (equal name "")
 806             (save-excursion
 807               (set-buffer (car (buffer-list)))
 808               (save-excursion
 809                 (beginning-of-line)
 810                 (if (looking-at
 811                      "[ \t]*#[ \t]*include[ \t]+[<\"]\\(.+\\)[>\"][ \t]*[\n/]")
 812                     (setq name (buffer-substring (match-beginning 1)
 813                                                  (match-end 1))
 814                           punc (char-after (1- (match-beginning 1))))
 815                   ;; Suggested by Frank Siebenlist:
 816                   (if (or (looking-at
 817                            "[ \t]*([ \t]*load[ \t]+\"\\([^\"]+\\)\"")
 818                           (looking-at
 819                            "[ \t]*([ \t]*load-library[ \t]+\"\\([^\"]+\\)\"")
 820                           (looking-at
 821                            "[ \t]*([ \t]*require[ \t]+'\\([^\t )]+\\)[\t )]"))
 822                       (progn
 823                         (setq name (buffer-substring (match-beginning 1)
 824                                                      (match-end 1))
 825                               punc ?\<
 826                               path load-path)
 827                         (if (string-match "\\.elc$" name)
 828                             (setq name (substring name 0 -1))
 829                           (or (string-match "\\.el$" name)
 830                               (setq name (concat name ".el")))))
 831                     (error "Not on an #include line"))))))
 832         (or (string-match "\\.[a-zA-Z0-9]+$" name)
 833             (setq name (concat name ".h")))
 834         (if (eq punc ?\<)
 835             (let ((path (or path (PC-include-file-path))))
 836               (while (and path
 837                           (not (file-exists-p
 838                                 (concat (file-name-as-directory (car path))
 839                                         name))))
 840                 (setq path (cdr path)))
 841               (if path
 842                   (setq name (concat (file-name-as-directory (car path)) name))
 843                 (error "No such include file: <%s>" name)))
 844           (let ((dir (save-excursion
 845                        (set-buffer (car (buffer-list)))
 846                        default-directory)))
 847             (if (file-exists-p (concat dir name))
 848                 (setq name (concat dir name))
 849               (error "No such include file: `%s'" name))))
 850         (setq new-buf (get-file-buffer name))
 851         (if new-buf
 852             ;; no need to verify last-modified time for this!
 853             (set-buffer new-buf)
 854           (setq new-buf (create-file-buffer name))
 855           (set-buffer new-buf)
 856           (erase-buffer)
 857           (insert-file-contents name t))
 858         ;; Returning non-nil with the new buffer current
 859         ;; is sufficient to tell find-file to use it.
 860         t)
 861     nil))
 862
 863 (defun PC-include-file-path ()
 864   (or PC-include-file-path
 865       (let ((env (getenv "INCPATH"))
 866             (path nil)
 867             pos)
 868         (or env (error "No include file path specified"))
 869         (while (setq pos (string-match ":[^:]+$" env))
 870           (setq path (cons (substring env (1+ pos)) path)
 871                 env (substring env 0 pos)))
 872         path)))
 873
 874 ;;; This is adapted from lib-complete.el, by Mike Williams.
 875 (defun PC-include-file-all-completions (file search-path &optional full)
 876   "Return all completions for FILE in any directory on SEARCH-PATH.
 877 If optional third argument FULL is non-nil, returned pathnames should be
 878 absolute rather than relative to some directory on the SEARCH-PATH."
 879   (setq search-path
 880         (mapcar '(lambda (dir)
 881                    (if dir (file-name-as-directory dir) default-directory))
 882                 search-path))
 883   (if (file-name-absolute-p file)
 884       ;; It's an absolute file name, so don't need search-path
 885       (progn
 886         (setq file (expand-file-name file))
 887         (file-name-all-completions
 888          (file-name-nondirectory file) (file-name-directory file)))
 889     (let ((subdir (file-name-directory file))
 890           (ndfile (file-name-nondirectory file))
 891           file-lists)
 892       ;; Append subdirectory part to each element of search-path
 893       (if subdir
 894           (setq search-path
 895                 (mapcar '(lambda (dir) (concat dir subdir))
 896                         search-path)
 897                 file ))
 898       ;; Make list of completions in each directory on search-path
 899       (while search-path
 900         (let* ((dir (car search-path))
 901                (subdir (if full dir subdir)))
 902           (if (file-directory-p dir)
 903               (progn
 904                 (setq file-lists
 905                       (cons
 906                        (mapcar '(lambda (file) (concat subdir file))
 907                                (file-name-all-completions ndfile
 908                                                           (car search-path)))
 909                        file-lists))))
 910           (setq search-path (cdr search-path))))
 911       ;; Compress out duplicates while building complete list (slloooow!)
 912       (let ((sorted (sort (apply 'nconc file-lists)
 913                           '(lambda (x y) (not (string-lessp x y)))))
 914             compressed)
 915         (while sorted
 916           (if (equal (car sorted) (car compressed)) nil
 917             (setq compressed (cons (car sorted) compressed)))
 918           (setq sorted (cdr sorted)))
 919         compressed))))
 920
 921 (defun PC-read-include-file-name-internal (string dir action)
 922   (if (string-match "<\\([^\"<>]*\\)>?$" string)
 923       (let* ((name (substring string (match-beginning 1) (match-end 1)))
 924              (str2 (substring string (match-beginning 0)))
 925              (completion-table
 926               (mapcar (function (lambda (x) (list (format "<%s>" x))))
 927                       (PC-include-file-all-completions
 928                        name (PC-include-file-path)))))
 929         (cond
 930          ((not completion-table) nil)
 931          ((eq action nil) (try-completion str2 completion-table nil))
 932          ((eq action t) (all-completions str2 completion-table nil))
 933          ((eq action 'lambda)
 934           (eq (try-completion str2 completion-table nil) t))))
 935     (funcall PC-old-read-file-name-internal string dir action)))
 936 \f
 937
 938 (provide 'complete)
 939
 940 ;;; End.