lisp/wid-edit.el

   1 ;;; wid-edit.el --- Functions for creating and using widgets.
   2 ;;
   3 ;; Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: extensions
   7 ;; Version: 1.9951
   8 ;; X-URL: http://www.dina.kvl.dk/~abraham/custom/
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; See `widget.el'.
  30
  31 ;;; Code:
  32
  33 (require 'widget)
  34 (eval-when-compile (require 'cl))
  35
  36 ;;; Compatibility.
  37
  38 (eval-and-compile
  39   (autoload 'pp-to-string "pp")
  40   (autoload 'Info-goto-node "info")
  41   (autoload 'finder-commentary "finder" nil t)
  42
  43   (when (string-match "XEmacs" emacs-version)
  44     (condition-case nil
  45         (require 'overlay)
  46       (error (load-library "x-overlay"))))
  47
  48   (if (string-match "XEmacs" emacs-version)
  49       (defun widget-event-point (event)
  50         "Character position of the end of event if that exists, or nil."
  51         (if (mouse-event-p event)
  52             (event-point event)
  53           nil))
  54     (defun widget-event-point (event)
  55       "Character position of the end of event if that exists, or nil."
  56       (posn-point (event-end event))))
  57
  58   (defalias 'widget-read-event (if (string-match "XEmacs" emacs-version)
  59                                    'next-event
  60                                  'read-event))
  61
  62   (unless (and (featurep 'custom) (fboundp 'custom-declare-variable))
  63     ;; We have the old custom-library, hack around it!
  64     (defmacro defgroup (&rest args) nil)
  65     (defmacro defcustom (var value doc &rest args)
  66       (` (defvar (, var) (, value) (, doc))))
  67     (defmacro defface (&rest args) nil)
  68     (define-widget-keywords :prefix :tag :load :link :options :type :group)
  69     (when (fboundp 'copy-face)
  70       (copy-face 'default 'widget-documentation-face)
  71       (copy-face 'bold 'widget-button-face)
  72       (copy-face 'italic 'widget-field-face)))
  73
  74   (unless (fboundp 'button-release-event-p)
  75     ;; XEmacs function missing from Emacs.
  76     (defun button-release-event-p (event)
  77       "Non-nil if EVENT is a mouse-button-release event object."
  78       (and (eventp event)
  79            (memq (event-basic-type event) '(mouse-1 mouse-2 mouse-3))
  80            (or (memq 'click (event-modifiers event))
  81                (memq  'drag (event-modifiers event))))))
  82
  83   (unless (fboundp 'functionp)
  84     ;; Missing from Emacs 19.34 and earlier.
  85     (defun functionp (object)
  86       "Non-nil of OBJECT is a type of object that can be called as a function."
  87       (or (subrp object) (byte-code-function-p object)
  88           (eq (car-safe object) 'lambda)
  89           (and (symbolp object) (fboundp object)))))
  90
  91   (unless (fboundp 'error-message-string)
  92     ;; Emacs function missing in XEmacs.
  93     (defun error-message-string (obj)
  94       "Convert an error value to an error message."
  95       (let ((buf (get-buffer-create " *error-message*")))
  96         (erase-buffer buf)
  97         (display-error obj buf)
  98         (buffer-string buf)))))
  99
 100 ;;; Customization.
 101
 102 (defgroup widgets nil
 103   "Customization support for the Widget Library."
 104   :link '(custom-manual "(widget)Top")
 105   :link '(url-link :tag "Development Page"
 106                    "http://www.dina.kvl.dk/~abraham/custom/")
 107   :link '(emacs-library-link :tag "Lisp File" "widget.el")
 108   :prefix "widget-"
 109   :group 'extensions
 110   :group 'hypermedia)
 111
 112 (defgroup widget-documentation nil
 113   "Options controling the display of documentation strings."
 114   :group 'widgets)
 115
 116 (defgroup widget-faces nil
 117   "Faces used by the widget library."
 118   :group 'widgets
 119   :group 'faces)
 120
 121 (defvar widget-documentation-face 'widget-documentation-face
 122   "Face used for documentation strings in widges.
 123 This exists as a variable so it can be set locally in certain buffers.")
 124
 125 (defface widget-documentation-face '((((class color)
 126                                        (background dark))
 127                                       (:foreground "lime green"))
 128                                      (((class color)
 129                                        (background light))
 130                                       (:foreground "dark green"))
 131                                      (t nil))
 132   "Face used for documentation text."
 133   :group 'widget-documentation
 134   :group 'widget-faces)
 135
 136 (defvar widget-button-face 'widget-button-face
 137   "Face used for buttons in widges.
 138 This exists as a variable so it can be set locally in certain buffers.")
 139
 140 (defface widget-button-face '((t (:bold t)))
 141   "Face used for widget buttons."
 142   :group 'widget-faces)
 143
 144 (defcustom widget-mouse-face 'highlight
 145   "Face used for widget buttons when the mouse is above them."
 146   :type 'face
 147   :group 'widget-faces)
 148
 149 (defface widget-field-face '((((class grayscale color)
 150                                (background light))
 151                               (:background "gray85"))
 152                              (((class grayscale color)
 153                                (background dark))
 154                               (:background "dim gray"))
 155                              (t
 156                               (:italic t)))
 157   "Face used for editable fields."
 158   :group 'widget-faces)
 159
 160 (defface widget-single-line-field-face '((((class grayscale color)
 161                                            (background light))
 162                                           (:background "gray85"))
 163                                          (((class grayscale color)
 164                                            (background dark))
 165                                           (:background "dim gray"))
 166                                          (t
 167                                           (:italic t)))
 168   "Face used for editable fields spanning only a single line."
 169   :group 'widget-faces)
 170
 171 ;;; This causes display-table to be loaded, and not usefully.
 172 ;;;(defvar widget-single-line-display-table
 173 ;;;  (let ((table (make-display-table)))
 174 ;;;    (aset table 9  "^I")
 175 ;;;    (aset table 10 "^J")
 176 ;;;    table)
 177 ;;;  "Display table used for single-line editable fields.")
 178
 179 ;;;(when (fboundp 'set-face-display-table)
 180 ;;;  (set-face-display-table 'widget-single-line-field-face
 181 ;;;                       widget-single-line-display-table))
 182
 183 ;;; Utility functions.
 184 ;;
 185 ;; These are not really widget specific.
 186
 187 (defun widget-princ-to-string (object)
 188   ;; Return string representation of OBJECT, any Lisp object.
 189   ;; No quoting characters are used; no delimiters are printed around
 190   ;; the contents of strings.
 191   (save-excursion
 192     (set-buffer (get-buffer-create " *widget-tmp*"))
 193     (erase-buffer)
 194     (let ((standard-output (current-buffer)))
 195       (princ object))
 196     (buffer-string)))
 197
 198 (defun widget-clear-undo ()
 199   "Clear all undo information."
 200   (buffer-disable-undo (current-buffer))
 201   (buffer-enable-undo))
 202
 203 (defcustom widget-menu-max-size 40
 204   "Largest number of items allowed in a popup-menu.
 205 Larger menus are read through the minibuffer."
 206   :group 'widgets
 207   :type 'integer)
 208
 209 (defcustom widget-menu-minibuffer-flag (string-match "XEmacs" emacs-version)
 210   "*Control how to ask for a choice from the keyboard.
 211 Non-nil means use the minibuffer;
 212 nil means read a single character."
 213   :group 'widgets
 214   :type 'boolean)
 215
 216 (defun widget-choose (title items &optional event)
 217   "Choose an item from a list.
 218
 219 First argument TITLE is the name of the list.
 220 Second argument ITEMS is an list whose members are either
 221  (NAME . VALUE), to indicate selectable items, or just strings to
 222  indicate unselectable items.
 223 Optional third argument EVENT is an input event.
 224
 225 The user is asked to choose between each NAME from the items alist,
 226 and the VALUE of the chosen element will be returned.  If EVENT is a
 227 mouse event, and the number of elements in items is less than
 228 `widget-menu-max-size', a popup menu will be used, otherwise the
 229 minibuffer."
 230   (cond ((and (< (length items) widget-menu-max-size)
 231               event (fboundp 'x-popup-menu) window-system)
 232          ;; We are in Emacs-19, pressed by the mouse
 233          (x-popup-menu event
 234                        (list title (cons "" items))))
 235         ((and (< (length items) widget-menu-max-size)
 236               event (fboundp 'popup-menu) window-system)
 237          ;; We are in XEmacs, pressed by the mouse
 238          (let ((val (get-popup-menu-response
 239                      (cons title
 240                            (mapcar
 241                             (function
 242                              (lambda (x)
 243                                (if (stringp x)
 244                                    (vector x nil nil)
 245                                  (vector (car x) (list (car x)) t))))
 246                             items)))))
 247            (setq val (and val
 248                           (listp (event-object val))
 249                           (stringp (car-safe (event-object val)))
 250                           (car (event-object val))))
 251            (cdr (assoc val items))))
 252         (widget-menu-minibuffer-flag
 253          ;; Read the choice of name from the minibuffer.
 254          (setq items (widget-remove-if 'stringp items))
 255          (let ((val (completing-read (concat title ": ") items nil t)))
 256            (if (stringp val)
 257                (let ((try (try-completion val items)))
 258                  (when (stringp try)
 259                    (setq val try))
 260                  (cdr (assoc val items)))
 261              nil)))
 262         (t
 263          ;; Construct a menu of the choices
 264          ;; and then use it for prompting for a single character.
 265          (let* ((overriding-terminal-local-map
 266                  (make-sparse-keymap))
 267                 map choice (next-digit ?0)
 268                 some-choice-enabled
 269                 value)
 270            ;; Define SPC as a prefix char to get to this menu.
 271            (define-key overriding-terminal-local-map " "
 272              (setq map (make-sparse-keymap title)))
 273            (save-excursion
 274              (set-buffer (get-buffer-create " widget-choose"))
 275              (erase-buffer)
 276              (insert "Available choices:\n\n")
 277              (while items
 278                (setq choice (car items) items (cdr items))
 279                (if (consp choice)
 280                    (let* ((name (car choice))
 281                          (function (cdr choice)))
 282                      (insert (format "%c = %s\n" next-digit name))
 283                      (define-key map (vector next-digit) function)
 284                      (setq some-choice-enabled t)))
 285                ;; Allocate digits to disabled alternatives
 286                ;; so that the digit of a given alternative never varies.
 287                (setq next-digit (1+ next-digit)))
 288              (insert "\nC-g = Quit"))
 289            (or some-choice-enabled
 290                (error "None of the choices is currently meaningful"))
 291            (define-key map [?\C-g] 'keyboard-quit)
 292            (define-key map [t] 'keyboard-quit)
 293            (define-key map [?\M-\C-v] 'scroll-other-window)
 294            (define-key map [?\M--] 'negative-argument)
 295            (setcdr map (nreverse (cdr map)))
 296            ;; Read a char with the menu, and return the result
 297            ;; that corresponds to it.
 298            (save-window-excursion
 299              (let ((buf (get-buffer " widget-choose")))
 300                (display-buffer buf)
 301                (let ((cursor-in-echo-area t)
 302                      keys
 303                      (char 0)
 304                      (arg 1))
 305                  (while (not (or (and (>= char ?0) (< char next-digit))
 306                                  (eq value 'keyboard-quit)))
 307                    ;; Unread a SPC to lead to our new menu.
 308                    (setq unread-command-events (cons ?\ unread-command-events))
 309                    (setq keys (read-key-sequence title))
 310                    (setq value (lookup-key overriding-terminal-local-map keys t)
 311                          char (string-to-char (substring keys 1)))
 312                    (cond ((eq value 'scroll-other-window)
 313                           (let ((minibuffer-scroll-window (get-buffer-window buf)))
 314                             (if (> 0 arg)
 315                                 (scroll-other-window-down (window-height minibuffer-scroll-window))
 316                               (scroll-other-window))
 317                             (setq arg 1)))
 318                          ((eq value 'negative-argument)
 319                           (setq arg -1))
 320                          (t
 321                           (setq arg 1)))))))
 322            (when (eq value 'keyboard-quit)
 323              (error "Canceled"))
 324            value))))
 325
 326 (defun widget-remove-if (predictate list)
 327   (let (result (tail list))
 328     (while tail
 329       (or (funcall predictate (car tail))
 330           (setq result (cons (car tail) result)))
 331       (setq tail (cdr tail)))
 332     (nreverse result)))
 333
 334 ;;; Widget text specifications.
 335 ;;
 336 ;; These functions are for specifying text properties.
 337
 338 (defcustom widget-field-add-space
 339   (or (< emacs-major-version 20)
 340       (and (eq emacs-major-version 20)
 341            (< emacs-minor-version 3))
 342       (not (string-match "XEmacs" emacs-version)))
 343   "Non-nil means add extra space at the end of editable text fields.
 344
 345 This is needed on all versions of Emacs, and on XEmacs before 20.3.
 346 If you don't add the space, it will become impossible to edit a zero
 347 size field."
 348   :type 'boolean
 349   :group 'widgets)
 350
 351 (defcustom widget-field-use-before-change
 352   (and (or (> emacs-minor-version 34)
 353            (> emacs-major-version 19))
 354        (not (string-match "XEmacs" emacs-version)))
 355   "Non-nil means use `before-change-functions' to track editable fields.
 356 This enables the use of undo, but doesn't work on Emacs 19.34 and earlier.
 357 Using before hooks also means that the :notify function can't know the
 358 new value."
 359   :type 'boolean
 360   :group 'widgets)
 361
 362 (defun widget-specify-field (widget from to)
 363   "Specify editable button for WIDGET between FROM and TO."
 364   ;; Terminating space is not part of the field, but necessary in
 365   ;; order for local-map to work.  Remove next sexp if local-map works
 366   ;; at the end of the overlay.
 367   (save-excursion
 368     (goto-char to)
 369     (cond ((null (widget-get widget :size))
 370            (forward-char 1))
 371           (widget-field-add-space
 372            (insert-and-inherit " ")))
 373     (setq to (point)))
 374   (let ((map (widget-get widget :keymap))
 375         (face (or (widget-get widget :value-face) 'widget-field-face))
 376         (help-echo (widget-get widget :help-echo))
 377         (overlay (make-overlay from to nil
 378                                nil (or (not widget-field-add-space)
 379                                        (widget-get widget :size)))))
 380     (unless (or (stringp help-echo) (null help-echo))
 381       (setq help-echo 'widget-mouse-help))
 382     (widget-put widget :field-overlay overlay)
 383     (overlay-put overlay 'detachable nil)
 384     (overlay-put overlay 'field widget)
 385     (overlay-put overlay 'local-map map)
 386     (overlay-put overlay 'keymap map)
 387     (overlay-put overlay 'face face)
 388     (overlay-put overlay 'balloon-help help-echo)
 389     (overlay-put overlay 'help-echo help-echo)))
 390
 391 (defun widget-specify-button (widget from to)
 392   "Specify button for WIDGET between FROM and TO."
 393   (let ((face (widget-apply widget :button-face-get))
 394         (help-echo (widget-get widget :help-echo))
 395         (overlay (make-overlay from to nil t nil)))
 396     (widget-put widget :button-overlay overlay)
 397     (unless (or (null help-echo) (stringp help-echo))
 398       (setq help-echo 'widget-mouse-help))
 399     (overlay-put overlay 'button widget)
 400     (overlay-put overlay 'mouse-face widget-mouse-face)
 401     (overlay-put overlay 'balloon-help help-echo)
 402     (overlay-put overlay 'help-echo help-echo)
 403     (overlay-put overlay 'face face)))
 404
 405 (defun widget-mouse-help (extent)
 406   "Find mouse help string for button in extent."
 407   (let* ((widget (widget-at (extent-start-position extent)))
 408          (help-echo (and widget (widget-get widget :help-echo))))
 409     (cond ((stringp help-echo)
 410            help-echo)
 411           ((and (symbolp help-echo) (fboundp help-echo)
 412                 (stringp (setq help-echo (funcall help-echo widget))))
 413            help-echo)
 414           (t
 415            (format "(widget %S :help-echo %S)" widget help-echo)))))
 416
 417 (defun widget-specify-sample (widget from to)
 418   ;; Specify sample for WIDGET between FROM and TO.
 419   (let ((face (widget-apply widget :sample-face-get))
 420         (overlay (make-overlay from to nil t nil)))
 421     (overlay-put overlay 'face face)
 422     (widget-put widget :sample-overlay overlay)))
 423
 424 (defun widget-specify-doc (widget from to)
 425   ;; Specify documentation for WIDGET between FROM and TO.
 426   (let ((overlay (make-overlay from to nil t nil)))
 427     (overlay-put overlay 'widget-doc widget)
 428     (overlay-put overlay 'face widget-documentation-face)
 429     (widget-put widget :doc-overlay overlay)))
 430
 431 (defmacro widget-specify-insert (&rest form)
 432   ;; Execute FORM without inheriting any text properties.
 433   (`
 434    (save-restriction
 435      (let ((inhibit-read-only t)
 436            result
 437            before-change-functions
 438            after-change-functions)
 439        (insert "<>")
 440        (narrow-to-region (- (point) 2) (point))
 441        (goto-char (1+ (point-min)))
 442        (setq result (progn (,@ form)))
 443        (delete-region (point-min) (1+ (point-min)))
 444        (delete-region (1- (point-max)) (point-max))
 445        (goto-char (point-max))
 446        result))))
 447
 448 (defface widget-inactive-face '((((class grayscale color)
 449                                   (background dark))
 450                                  (:foreground "light gray"))
 451                                 (((class grayscale color)
 452                                   (background light))
 453                                  (:foreground "dim gray"))
 454                                 (t
 455                                  (:italic t)))
 456   "Face used for inactive widgets."
 457   :group 'widget-faces)
 458
 459 (defun widget-specify-inactive (widget from to)
 460   "Make WIDGET inactive for user modifications."
 461   (unless (widget-get widget :inactive)
 462     (let ((overlay (make-overlay from to nil t nil)))
 463       (overlay-put overlay 'face 'widget-inactive-face)
 464       ;; This is disabled, as it makes the mouse cursor change shape.
 465       ;; (overlay-put overlay 'mouse-face 'widget-inactive-face)
 466       (overlay-put overlay 'evaporate t)
 467       (overlay-put overlay 'priority 100)
 468       (overlay-put overlay (if (string-match "XEmacs" emacs-version)
 469                                'read-only
 470                              'modification-hooks) '(widget-overlay-inactive))
 471       (widget-put widget :inactive overlay))))
 472
 473 (defun widget-overlay-inactive (&rest junk)
 474   "Ignoring the arguments, signal an error."
 475   (unless inhibit-read-only
 476     (error "Attempt to modify inactive widget")))
 477
 478
 479 (defun widget-specify-active (widget)
 480   "Make WIDGET active for user modifications."
 481   (let ((inactive (widget-get widget :inactive)))
 482     (when inactive
 483       (delete-overlay inactive)
 484       (widget-put widget :inactive nil))))
 485
 486 ;;; Widget Properties.
 487
 488 (defsubst widget-type (widget)
 489   "Return the type of WIDGET, a symbol."
 490   (car widget))
 491
 492 (defun widget-get-indirect (widget property)
 493   "In WIDGET, get the value of PROPERTY.
 494 If the value is a symbol, return its binding.
 495 Otherwise, just return the value."
 496   (let ((value (widget-get widget property)))
 497     (if (symbolp value)
 498         (symbol-value value)
 499       value)))
 500
 501 (defun widget-member (widget property)
 502   "Non-nil iff there is a definition in WIDGET for PROPERTY."
 503   (cond ((widget-plist-member (cdr widget) property)
 504          t)
 505         ((car widget)
 506          (widget-member (get (car widget) 'widget-type) property))
 507         (t nil)))
 508
 509 (defun widget-value (widget)
 510   "Extract the current value of WIDGET."
 511   (widget-apply widget
 512                 :value-to-external (widget-apply widget :value-get)))
 513
 514 (defun widget-value-set (widget value)
 515   "Set the current value of WIDGET to VALUE."
 516   (widget-apply widget
 517                 :value-set (widget-apply widget
 518                                          :value-to-internal value)))
 519
 520 (defun widget-match-inline (widget vals)
 521   ;; In WIDGET, match the start of VALS.
 522   (cond ((widget-get widget :inline)
 523          (widget-apply widget :match-inline vals))
 524         ((and vals
 525               (widget-apply widget :match (car vals)))
 526          (cons (list (car vals)) (cdr vals)))
 527         (t nil)))
 528
 529 (defun widget-apply-action (widget &optional event)
 530   "Apply :action in WIDGET in response to EVENT."
 531   (if (widget-apply widget :active)
 532       (widget-apply widget :action event)
 533     (error "Attempt to perform action on inactive widget")))
 534
 535 ;;; Helper functions.
 536 ;;
 537 ;; These are widget specific.
 538
 539 ;;;###autoload
 540 (defun widget-prompt-value (widget prompt &optional value unbound)
 541   "Prompt for a value matching WIDGET, using PROMPT.
 542 The current value is assumed to be VALUE, unless UNBOUND is non-nil."
 543   (unless (listp widget)
 544     (setq widget (list widget)))
 545   (setq prompt (format "[%s] %s" (widget-type widget) prompt))
 546   (setq widget (widget-convert widget))
 547   (let ((answer (widget-apply widget :prompt-value prompt value unbound)))
 548     (unless (widget-apply widget :match answer)
 549       (error "Value does not match %S type." (car widget)))
 550     answer))
 551
 552 (defun widget-get-sibling (widget)
 553   "Get the item WIDGET is assumed to toggle.
 554 This is only meaningful for radio buttons or checkboxes in a list."
 555   (let* ((parent (widget-get widget :parent))
 556          (children (widget-get parent :children))
 557          child)
 558     (catch 'child
 559       (while children
 560         (setq child (car children)
 561               children (cdr children))
 562         (when (eq (widget-get child :button) widget)
 563           (throw 'child child)))
 564       nil)))
 565
 566 (defun widget-map-buttons (function &optional buffer maparg)
 567   "Map FUNCTION over the buttons in BUFFER.
 568 FUNCTION is called with the arguments WIDGET and MAPARG.
 569
 570 If FUNCTION returns non-nil, the walk is cancelled.
 571
 572 The arguments MAPARG, and BUFFER default to nil and (current-buffer),
 573 respectively."
 574   (let ((cur (point-min))
 575         (widget nil)
 576         (parent nil)
 577         (overlays (if buffer
 578                       (save-excursion (set-buffer buffer) (overlay-lists))
 579                     (overlay-lists))))
 580     (setq overlays (append (car overlays) (cdr overlays)))
 581     (while (setq cur (pop overlays))
 582       (setq widget (overlay-get cur 'button))
 583       (if (and widget (funcall function widget maparg))
 584           (setq overlays nil)))))
 585
 586 ;;; Glyphs.
 587
 588 (defcustom widget-glyph-directory (concat data-directory "custom/")
 589   "Where widget glyphs are located.
 590 If this variable is nil, widget will try to locate the directory
 591 automatically."
 592   :group 'widgets
 593   :type 'directory)
 594
 595 (defcustom widget-glyph-enable t
 596   "If non nil, use glyphs in images when available."
 597   :group 'widgets
 598   :type 'boolean)
 599
 600 (defcustom widget-image-conversion
 601   '((xpm ".xpm") (gif ".gif") (png ".png") (jpeg ".jpg" ".jpeg")
 602     (xbm ".xbm"))
 603   "Conversion alist from image formats to file name suffixes."
 604   :group 'widgets
 605   :type '(repeat (cons :format "%v"
 606                        (symbol :tag "Image Format" unknown)
 607                        (repeat :tag "Suffixes"
 608                                (string :format "%v")))))
 609
 610 (defun widget-glyph-find (image tag)
 611   "Create a glyph corresponding to IMAGE with string TAG as fallback.
 612 IMAGE should either already be a glyph, or be a file name sans
 613 extension (xpm, xbm, gif, jpg, or png) located in
 614 `widget-glyph-directory'."
 615   (cond ((not (and image
 616                    (string-match "XEmacs" emacs-version)
 617                    widget-glyph-enable
 618                    (fboundp 'make-glyph)
 619                    (fboundp 'locate-file)
 620                    image))
 621          ;; We don't want or can't use glyphs.
 622          nil)
 623         ((and (fboundp 'glyphp)
 624               (glyphp image))
 625          ;; Already a glyph.  Use it.
 626          image)
 627         ((stringp image)
 628          ;; A string.  Look it up in relevant directories.
 629          (let* ((dirlist (list (or widget-glyph-directory
 630                                    (concat data-directory
 631                                            "custom/"))
 632                                data-directory))
 633                 (formats widget-image-conversion)
 634                 file)
 635            (while (and formats (not file))
 636              (when (valid-image-instantiator-format-p (car (car formats)))
 637                (setq file (locate-file image dirlist
 638                                        (mapconcat 'identity
 639                                                   (cdr (car formats))
 640                                                   ":"))))
 641              (unless file
 642                (setq formats (cdr formats))))
 643            (and file
 644                 ;; We create a glyph with the file as the default image
 645                 ;; instantiator, and the TAG fallback
 646                 (make-glyph (list (vector (car (car formats)) ':file file)
 647                                   (vector 'string ':data tag))))))
 648         ((valid-instantiator-p image 'image)
 649          ;; A valid image instantiator (e.g. [gif :file "somefile"] etc.)
 650          (make-glyph (list image
 651                            (vector 'string ':data tag))))
 652         ((consp image)
 653          ;; This could be virtually anything.  Let `make-glyph' sort it out.
 654          (make-glyph image))
 655         (t
 656          ;; Oh well.
 657          nil)))
 658
 659 (defun widget-glyph-insert (widget tag image &optional down inactive)
 660   "In WIDGET, insert the text TAG or, if supported, IMAGE.
 661 IMAGE should either be a glyph, an image instantiator, or an image file
 662 name sans extension (xpm, xbm, gif, jpg, or png) located in
 663 `widget-glyph-directory'.
 664
 665 Optional arguments DOWN and INACTIVE is used instead of IMAGE when the
 666 glyph is pressed or inactive, respectively.
 667
 668 WARNING: If you call this with a glyph, and you want the user to be
 669 able to invoke the glyph, make sure it is unique.  If you use the
 670 same glyph for multiple widgets, invoking any of the glyphs will
 671 cause the last created widget to be invoked.
 672
 673 Instead of an instantiator, you can also use a list of instantiators,
 674 or whatever `make-glyph' will accept.  However, in that case you must
 675 provide the fallback TAG as a part of the instantiator yourself."
 676   (let ((glyph (widget-glyph-find image tag)))
 677     (if glyph
 678         (widget-glyph-insert-glyph widget
 679                                    glyph
 680                                    (widget-glyph-find down tag)
 681                                    (widget-glyph-find inactive tag))
 682       (insert tag))))
 683
 684 (defun widget-glyph-insert-glyph (widget glyph &optional down inactive)
 685   "In WIDGET, insert GLYPH.
 686 If optional arguments DOWN and INACTIVE are given, they should be
 687 glyphs used when the widget is pushed and inactive, respectively."
 688   (when widget
 689     (set-glyph-property glyph 'widget widget)
 690     (when down
 691       (set-glyph-property down 'widget widget))
 692     (when inactive
 693       (set-glyph-property inactive 'widget widget)))
 694   (insert "*")
 695   (let ((ext (make-extent (point) (1- (point))))
 696         (help-echo (and widget (widget-get widget :help-echo))))
 697     (set-extent-property ext 'invisible t)
 698     (set-extent-property ext 'start-open t)
 699     (set-extent-property ext 'end-open t)
 700     (set-extent-end-glyph ext glyph)
 701     (when help-echo
 702       (set-extent-property ext 'balloon-help help-echo)
 703       (set-extent-property ext 'help-echo help-echo)))
 704   (when widget
 705     (widget-put widget :glyph-up glyph)
 706     (when down (widget-put widget :glyph-down down))
 707     (when inactive (widget-put widget :glyph-inactive inactive))))
 708
 709 ;;; Buttons.
 710
 711 (defgroup widget-button nil
 712   "The look of various kinds of buttons."
 713   :group 'widgets)
 714
 715 (defcustom widget-button-prefix ""
 716   "String used as prefix for buttons."
 717   :type 'string
 718   :group 'widget-button)
 719
 720 (defcustom widget-button-suffix ""
 721   "String used as suffix for buttons."
 722   :type 'string
 723   :group 'widget-button)
 724
 725 ;;; Creating Widgets.
 726
 727 ;;;###autoload
 728 (defun widget-create (type &rest args)
 729   "Create widget of TYPE.
 730 The optional ARGS are additional keyword arguments."
 731   (let ((widget (apply 'widget-convert type args)))
 732     (widget-apply widget :create)
 733     widget))
 734
 735 (defun widget-create-child-and-convert (parent type &rest args)
 736   "As part of the widget PARENT, create a child widget TYPE.
 737 The child is converted, using the keyword arguments ARGS."
 738   (let ((widget (apply 'widget-convert type args)))
 739     (widget-put widget :parent parent)
 740     (unless (widget-get widget :indent)
 741       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 742                                     (or (widget-get widget :extra-offset) 0)
 743                                     (widget-get parent :offset))))
 744     (widget-apply widget :create)
 745     widget))
 746
 747 (defun widget-create-child (parent type)
 748   "Create widget of TYPE."
 749   (let ((widget (copy-sequence type)))
 750     (widget-put widget :parent parent)
 751     (unless (widget-get widget :indent)
 752       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 753                                     (or (widget-get widget :extra-offset) 0)
 754                                     (widget-get parent :offset))))
 755     (widget-apply widget :create)
 756     widget))
 757
 758 (defun widget-create-child-value (parent type value)
 759   "Create widget of TYPE with value VALUE."
 760   (let ((widget (copy-sequence type)))
 761     (widget-put widget :value (widget-apply widget :value-to-internal value))
 762     (widget-put widget :parent parent)
 763     (unless (widget-get widget :indent)
 764       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 765                                     (or (widget-get widget :extra-offset) 0)
 766                                     (widget-get parent :offset))))
 767     (widget-apply widget :create)
 768     widget))
 769
 770 ;;;###autoload
 771 (defun widget-delete (widget)
 772   "Delete WIDGET."
 773   (widget-apply widget :delete))
 774
 775 (defun widget-convert (type &rest args)
 776   "Convert TYPE to a widget without inserting it in the buffer.
 777 The optional ARGS are additional keyword arguments."
 778   ;; Don't touch the type.
 779   (let* ((widget (if (symbolp type)
 780                      (list type)
 781                    (copy-sequence type)))
 782          (current widget)
 783          (keys args))
 784     ;; First set the :args keyword.
 785     (while (cdr current)                ;Look in the type.
 786       (let ((next (car (cdr current))))
 787         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 788             (setq current (cdr (cdr current)))
 789           (setcdr current (list :args (cdr current)))
 790           (setq current nil))))
 791     (while args                         ;Look in the args.
 792       (let ((next (nth 0 args)))
 793         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 794             (setq args (nthcdr 2 args))
 795           (widget-put widget :args args)
 796           (setq args nil))))
 797     ;; Then Convert the widget.
 798     (setq type widget)
 799     (while type
 800       (let ((convert-widget (plist-get (cdr type) :convert-widget)))
 801         (if convert-widget
 802             (setq widget (funcall convert-widget widget))))
 803       (setq type (get (car type) 'widget-type)))
 804     ;; Finally set the keyword args.
 805     (while keys
 806       (let ((next (nth 0 keys)))
 807         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 808             (progn
 809               (widget-put widget next (nth 1 keys))
 810               (setq keys (nthcdr 2 keys)))
 811           (setq keys nil))))
 812     ;; Convert the :value to internal format.
 813     (if (widget-member widget :value)
 814         (let ((value (widget-get widget :value)))
 815           (widget-put widget
 816                       :value (widget-apply widget :value-to-internal value))))
 817     ;; Return the newly create widget.
 818     widget))
 819
 820 (defun widget-insert (&rest args)
 821   "Call `insert' with ARGS and make the text read only."
 822   (let ((inhibit-read-only t)
 823         before-change-functions
 824         after-change-functions
 825         (from (point)))
 826     (apply 'insert args)))
 827
 828 (defun widget-convert-text (type from to
 829                                  &optional button-from button-to
 830                                  &rest args)
 831   "Return a widget of type TYPE with endpoint FROM TO.
 832 Optional ARGS are extra keyword arguments for TYPE.
 833 and TO will be used as the widgets end points. If optional arguments
 834 BUTTON-FROM and BUTTON-TO are given, these will be used as the widgets
 835 button end points.
 836 Optional ARGS are extra keyword arguments for TYPE."
 837   (let ((widget (apply 'widget-convert type :delete 'widget-leave-text args))
 838         (from (copy-marker from))
 839         (to (copy-marker to)))
 840     (set-marker-insertion-type from t)
 841     (set-marker-insertion-type to nil)
 842     (widget-put widget :from from)
 843     (widget-put widget :to to)
 844     (when button-from
 845       (widget-specify-button widget button-from button-to))
 846     widget))
 847
 848 (defun widget-convert-button (type from to &rest args)
 849   "Return a widget of type TYPE with endpoint FROM TO.
 850 Optional ARGS are extra keyword arguments for TYPE.
 851 No text will be inserted to the buffer, instead the text between FROM
 852 and TO will be used as the widgets end points, as well as the widgets
 853 button end points."
 854   (apply 'widget-convert-text type from to from to args))
 855
 856 (defun widget-leave-text (widget)
 857   "Remove markers and overlays from WIDGET and its children."
 858   (let ((from (widget-get widget :from))
 859         (to (widget-get widget :to))
 860         (button (widget-get widget :button-overlay))
 861         (sample (widget-get widget :sample-overlay))
 862         (doc (widget-get widget :doc-overlay))
 863         (field (widget-get widget :field-overlay))
 864         (children (widget-get widget :children)))
 865     (set-marker from nil)
 866     (set-marker to nil)
 867     (when button
 868       (delete-overlay button))
 869     (when sample
 870       (delete-overlay sample))
 871     (when doc
 872       (delete-overlay doc))
 873     (when field
 874       (delete-overlay field))
 875     (mapcar 'widget-leave-text children)))
 876
 877 ;;; Keymap and Commands.
 878
 879 (defvar widget-keymap nil
 880   "Keymap containing useful binding for buffers containing widgets.
 881 Recommended as a parent keymap for modes using widgets.")
 882
 883 (unless widget-keymap
 884   (setq widget-keymap (make-sparse-keymap))
 885   (define-key widget-keymap "\t" 'widget-forward)
 886   (define-key widget-keymap [(shift tab)] 'widget-backward)
 887   (define-key widget-keymap [backtab] 'widget-backward)
 888   (if (string-match "XEmacs" emacs-version)
 889       (progn
 890         ;;Glyph support.
 891         (define-key widget-keymap [button1] 'widget-button1-click)
 892         (define-key widget-keymap [button2] 'widget-button-click))
 893     (define-key widget-keymap [down-mouse-2] 'widget-button-click))
 894   (define-key widget-keymap "\C-m" 'widget-button-press))
 895
 896 (defvar widget-global-map global-map
 897   "Keymap used for events the widget does not handle themselves.")
 898 (make-variable-buffer-local 'widget-global-map)
 899
 900 (defvar widget-field-keymap nil
 901   "Keymap used inside an editable field.")
 902
 903 (unless widget-field-keymap
 904   (setq widget-field-keymap (copy-keymap widget-keymap))
 905   (unless (string-match "XEmacs" (emacs-version))
 906     (define-key widget-field-keymap [menu-bar] 'nil))
 907   (define-key widget-field-keymap "\C-k" 'widget-kill-line)
 908   (define-key widget-field-keymap "\M-\t" 'widget-complete)
 909   (define-key widget-field-keymap "\C-m" 'widget-field-activate)
 910   (define-key widget-field-keymap "\C-a" 'widget-beginning-of-line)
 911   (define-key widget-field-keymap "\C-e" 'widget-end-of-line)
 912   (set-keymap-parent widget-field-keymap global-map))
 913
 914 (defvar widget-text-keymap nil
 915   "Keymap used inside a text field.")
 916
 917 (unless widget-text-keymap
 918   (setq widget-text-keymap (copy-keymap widget-keymap))
 919   (unless (string-match "XEmacs" (emacs-version))
 920     (define-key widget-text-keymap [menu-bar] 'nil))
 921   (define-key widget-text-keymap "\C-a" 'widget-beginning-of-line)
 922   (define-key widget-text-keymap "\C-e" 'widget-end-of-line)
 923   (set-keymap-parent widget-text-keymap global-map))
 924
 925 (defun widget-field-activate (pos &optional event)
 926   "Invoke the ediable field at point."
 927   (interactive "@d")
 928   (let ((field (get-char-property pos 'field)))
 929     (if field
 930         (widget-apply-action field event)
 931       (call-interactively
 932        (lookup-key widget-global-map (this-command-keys))))))
 933
 934 (defface widget-button-pressed-face
 935   '((((class color))
 936      (:foreground "red"))
 937     (t
 938      (:bold t :underline t)))
 939   "Face used for pressed buttons."
 940   :group 'widget-faces)
 941
 942 (defun widget-button-click (event)
 943   "Invoke the button that the mouse is pointing at, and move there."
 944   (interactive "@e")
 945   (mouse-set-point event)
 946   (cond ((and (fboundp 'event-glyph)
 947               (event-glyph event))
 948          (widget-glyph-click event))
 949         ((widget-event-point event)
 950          (let* ((pos (widget-event-point event))
 951                 (button (get-char-property pos 'button)))
 952            (if button
 953                (let* ((overlay (widget-get button :button-overlay))
 954                       (face (overlay-get overlay 'face))
 955                       (mouse-face (overlay-get overlay 'mouse-face)))
 956                  (unwind-protect
 957                      (let ((track-mouse t))
 958                        (overlay-put overlay
 959                                     'face 'widget-button-pressed-face)
 960                        (overlay-put overlay
 961                                     'mouse-face 'widget-button-pressed-face)
 962                        (unless (widget-apply button :mouse-down-action event)
 963                          (while (not (button-release-event-p event))
 964                            (setq event (widget-read-event)
 965                                  pos (widget-event-point event))
 966                            (if (and pos
 967                                     (eq (get-char-property pos 'button)
 968                                         button))
 969                                (progn
 970                                  (overlay-put overlay
 971                                               'face
 972                                               'widget-button-pressed-face)
 973                                  (overlay-put overlay
 974                                               'mouse-face
 975                                               'widget-button-pressed-face))
 976                              (overlay-put overlay 'face face)
 977                              (overlay-put overlay 'mouse-face mouse-face))))
 978                        (when (and pos
 979                                   (eq (get-char-property pos 'button) button))
 980                          (widget-apply-action button event)))
 981                    (overlay-put overlay 'face face)
 982                    (overlay-put overlay 'mouse-face mouse-face)))
 983              (let ((up t)
 984                    command)
 985                ;; Find the global command to run, and check whether it
 986                ;; is bound to an up event.
 987                (cond ((setq command     ;down event
 988                             (lookup-key widget-global-map [ button2 ]))
 989                       (setq up nil))
 990                      ((setq command     ;down event
 991                             (lookup-key widget-global-map [ down-mouse-2 ]))
 992                       (setq up nil))
 993                      ((setq command     ;up event
 994                             (lookup-key widget-global-map [ button2up ])))
 995                      ((setq command     ;up event
 996                             (lookup-key widget-global-map [ mouse-2]))))
 997                (when up
 998                  ;; Don't execute up events twice.
 999                  (while (not (button-release-event-p event))
1000                    (setq event (widget-read-event))))
1001                (when command
1002                  (call-interactively command))))))
1003         (t
1004          (message "You clicked somewhere weird."))))
1005
1006 (defun widget-button1-click (event)
1007   "Invoke glyph below mouse pointer."
1008   (interactive "@e")
1009   (if (and (fboundp 'event-glyph)
1010            (event-glyph event))
1011       (widget-glyph-click event)
1012     (call-interactively (lookup-key widget-global-map (this-command-keys)))))
1013
1014 (defun widget-glyph-click (event)
1015   "Handle click on a glyph."
1016   (let* ((glyph (event-glyph event))
1017          (widget (glyph-property glyph 'widget))
1018          (extent (event-glyph-extent event))
1019          (down-glyph (or (and widget (widget-get widget :glyph-down)) glyph))
1020          (up-glyph (or (and widget (widget-get widget :glyph-up)) glyph))
1021          (last event))
1022     ;; Wait for the release.
1023     (while (not (button-release-event-p last))
1024       (if (eq extent (event-glyph-extent last))
1025           (set-extent-property extent 'end-glyph down-glyph)
1026         (set-extent-property extent 'end-glyph up-glyph))
1027       (setq last (next-event event)))
1028     ;; Release glyph.
1029     (when down-glyph
1030       (set-extent-property extent 'end-glyph up-glyph))
1031     ;; Apply widget action.
1032     (when (eq extent (event-glyph-extent last))
1033       (let ((widget (glyph-property (event-glyph event) 'widget)))
1034         (cond ((null widget)
1035                (message "You clicked on a glyph."))
1036               ((not (widget-apply widget :active))
1037                (message "This glyph is inactive."))
1038               (t
1039                (widget-apply-action widget event)))))))
1040
1041 (defun widget-button-press (pos &optional event)
1042   "Invoke button at POS."
1043   (interactive "@d")
1044   (let ((button (get-char-property pos 'button)))
1045     (if button
1046         (widget-apply-action button event)
1047       (let ((command (lookup-key widget-global-map (this-command-keys))))
1048         (when (commandp command)
1049           (call-interactively command))))))
1050
1051 (defun widget-tabable-at (&optional pos)
1052   "Return the tabable widget at POS, or nil.
1053 POS defaults to the value of (point)."
1054   (unless pos
1055     (setq pos (point)))
1056   (let ((widget (or (get-char-property (point) 'button)
1057                     (get-char-property (point) 'field))))
1058     (if widget
1059         (let ((order (widget-get widget :tab-order)))
1060           (if order
1061               (if (>= order 0)
1062                   widget
1063                 nil)
1064             widget))
1065       nil)))
1066
1067 (defcustom widget-use-overlay-change (string-match "XEmacs" emacs-version)
1068   "If non-nil, use overlay change functions to tab around in the buffer.
1069 This is much faster, but doesn't work reliably on Emacs 19.34."
1070   :type 'boolean
1071   :group 'widgets)
1072
1073 (defun widget-move (arg)
1074   "Move point to the ARG next field or button.
1075 ARG may be negative to move backward."
1076   (or (bobp) (> arg 0) (backward-char))
1077   (let ((pos (point))
1078         (number arg)
1079         (old (widget-tabable-at))
1080         new)
1081     ;; Forward.
1082     (while (> arg 0)
1083       (cond ((eobp)
1084              (goto-char (point-min)))
1085             (widget-use-overlay-change
1086              (goto-char (next-overlay-change (point))))
1087             (t
1088              (forward-char 1)))
1089       (and (eq pos (point))
1090            (eq arg number)
1091            (error "No buttons or fields found"))
1092       (let ((new (widget-tabable-at)))
1093         (when new
1094           (unless (eq new old)
1095             (setq arg (1- arg))
1096             (setq old new)))))
1097     ;; Backward.
1098     (while (< arg 0)
1099       (cond ((bobp)
1100              (goto-char (point-max)))
1101             (widget-use-overlay-change
1102              (goto-char (previous-overlay-change (point))))
1103             (t
1104              (backward-char 1)))
1105       (and (eq pos (point))
1106            (eq arg number)
1107            (error "No buttons or fields found"))
1108       (let ((new (widget-tabable-at)))
1109         (when new
1110           (unless (eq new old)
1111             (setq arg (1+ arg))))))
1112     (let ((new (widget-tabable-at)))
1113       (while (eq (widget-tabable-at) new)
1114         (backward-char)))
1115     (forward-char))
1116   (widget-echo-help (point))
1117   (run-hooks 'widget-move-hook))
1118
1119 (defun widget-forward (arg)
1120   "Move point to the next field or button.
1121 With optional ARG, move across that many fields."
1122   (interactive "p")
1123   (run-hooks 'widget-forward-hook)
1124   (widget-move arg))
1125
1126 (defun widget-backward (arg)
1127   "Move point to the previous field or button.
1128 With optional ARG, move across that many fields."
1129   (interactive "p")
1130   (run-hooks 'widget-backward-hook)
1131   (widget-move (- arg)))
1132
1133 (defun widget-beginning-of-line ()
1134   "Go to beginning of field or beginning of line, whichever is first."
1135   (interactive)
1136   (let* ((field (widget-field-find (point)))
1137          (start (and field (widget-field-start field))))
1138     (if (and start (not (eq start (point))))
1139         (goto-char start)
1140       (call-interactively 'beginning-of-line)))
1141   ;; XEmacs: preserve the region
1142   (setq zmacs-region-stays t))
1143
1144 (defun widget-end-of-line ()
1145   "Go to end of field or end of line, whichever is first."
1146   (interactive)
1147   (let* ((field (widget-field-find (point)))
1148          (end (and field (widget-field-end field))))
1149     (if (and end (not (eq end (point))))
1150         (goto-char end)
1151       (call-interactively 'end-of-line)))
1152   ;; XEmacs: preserve the region
1153   (setq zmacs-region-stays t))
1154
1155 (defun widget-kill-line ()
1156   "Kill to end of field or end of line, whichever is first."
1157   (interactive)
1158   (let* ((field (widget-field-find (point)))
1159          (newline (save-excursion (forward-line 1) (point)))
1160          (end (and field (widget-field-end field))))
1161     (if (and field (> newline end))
1162         (kill-region (point) end)
1163       (call-interactively 'kill-line))))
1164
1165 (defcustom widget-complete-field (lookup-key global-map "\M-\t")
1166   "Default function to call for completion inside fields."
1167   :options '(ispell-complete-word complete-tag lisp-complete-symbol)
1168   :type 'function
1169   :group 'widgets)
1170
1171 (defun widget-complete ()
1172   "Complete content of editable field from point.
1173 When not inside a field, move to the previous button or field."
1174   (interactive)
1175   (let ((field (widget-field-find (point))))
1176     (if field
1177         (widget-apply field :complete)
1178       (error "Not in an editable field"))))
1179
1180 ;;; Setting up the buffer.
1181
1182 (defvar widget-field-new nil)
1183 ;; List of all newly created editable fields in the buffer.
1184 (make-variable-buffer-local 'widget-field-new)
1185
1186 (defvar widget-field-list nil)
1187 ;; List of all editable fields in the buffer.
1188 (make-variable-buffer-local 'widget-field-list)
1189
1190 (defun widget-setup ()
1191   "Setup current buffer so editing string widgets works."
1192   (let ((inhibit-read-only t)
1193         (after-change-functions nil)
1194         before-change-functions
1195         field)
1196     (while widget-field-new
1197       (setq field (car widget-field-new)
1198             widget-field-new (cdr widget-field-new)
1199             widget-field-list (cons field widget-field-list))
1200       (let ((from (car (widget-get field :field-overlay)))
1201             (to (cdr (widget-get field :field-overlay))))
1202         (widget-specify-field field
1203                               (marker-position from) (marker-position to))
1204         (set-marker from nil)
1205         (set-marker to nil))))
1206   (widget-clear-undo)
1207   (widget-add-change))
1208
1209 (defvar widget-field-last nil)
1210 ;; Last field containing point.
1211 (make-variable-buffer-local 'widget-field-last)
1212
1213 (defvar widget-field-was nil)
1214 ;; The widget data before the change.
1215 (make-variable-buffer-local 'widget-field-was)
1216
1217 (defun widget-field-buffer (widget)
1218   "Return the start of WIDGET's editing field."
1219   (let ((overlay (widget-get widget :field-overlay)))
1220     (and overlay (overlay-buffer overlay))))
1221
1222 (defun widget-field-start (widget)
1223   "Return the start of WIDGET's editing field."
1224   (let ((overlay (widget-get widget :field-overlay)))
1225     (and overlay (overlay-start overlay))))
1226
1227 (defun widget-field-end (widget)
1228   "Return the end of WIDGET's editing field."
1229   (let ((overlay (widget-get widget :field-overlay)))
1230     ;; Don't subtract one if local-map works at the end of the overlay.
1231     (and overlay (if (or widget-field-add-space
1232                          (null (widget-get widget :size)))
1233                      (1- (overlay-end overlay))
1234                    (overlay-end overlay)))))
1235
1236 (defun widget-field-find (pos)
1237   "Return the field at POS.
1238 Unlike (get-char-property POS 'field) this, works with empty fields too."
1239   (let ((fields widget-field-list)
1240         field found)
1241     (while fields
1242       (setq field (car fields)
1243             fields (cdr fields))
1244       (let ((start (widget-field-start field))
1245             (end (widget-field-end field)))
1246         (when (and (<= start pos) (<= pos end))
1247           (when found
1248             (debug "Overlapping fields"))
1249           (setq found field))))
1250     found))
1251
1252 (defun widget-before-change (from to)
1253   ;; This is how, for example, a variable changes its state to `modified'.
1254   ;; when it is being edited.
1255   (unless inhibit-read-only
1256     (let ((from-field (widget-field-find from))
1257           (to-field (widget-field-find to)))
1258       (cond ((not (eq from-field to-field))
1259              (add-hook 'post-command-hook 'widget-add-change nil t)
1260              (error "Change should be restricted to a single field"))
1261             ((null from-field)
1262              (add-hook 'post-command-hook 'widget-add-change nil t)
1263              (error "Attempt to change text outside editable field"))
1264             (widget-field-use-before-change
1265              (condition-case nil
1266                  (widget-apply from-field :notify from-field)
1267                (error (debug "Before Change"))))))))
1268
1269 (defun widget-add-change ()
1270   (make-local-hook 'post-command-hook)
1271   (remove-hook 'post-command-hook 'widget-add-change t)
1272   (make-local-hook 'before-change-functions)
1273   (add-hook 'before-change-functions 'widget-before-change nil t)
1274   (make-local-hook 'after-change-functions)
1275   (add-hook 'after-change-functions 'widget-after-change nil t))
1276
1277 (defun widget-after-change (from to old)
1278   ;; Adjust field size and text properties.
1279   (condition-case nil
1280       (let ((field (widget-field-find from))
1281             (other (widget-field-find to)))
1282         (when field
1283           (unless (eq field other)
1284             (debug "Change in different fields"))
1285           (let ((size (widget-get field :size))
1286                 (secret (widget-get field :secret)))
1287             (when size
1288               (let ((begin (widget-field-start field))
1289                     (end (widget-field-end field)))
1290                 (cond ((< (- end begin) size)
1291                        ;; Field too small.
1292                        (save-excursion
1293                          (goto-char end)
1294                          (insert-char ?\  (- (+ begin size) end))))
1295                       ((> (- end begin) size)
1296                        ;; Field too large and
1297                        (if (or (< (point) (+ begin size))
1298                                (> (point) end))
1299                            ;; Point is outside extra space.
1300                            (setq begin (+ begin size))
1301                          ;; Point is within the extra space.
1302                          (setq begin (point)))
1303                        (save-excursion
1304                          (goto-char end)
1305                          (while (and (eq (preceding-char) ?\ )
1306                                      (> (point) begin))
1307                            (delete-backward-char 1)))))))
1308             (when secret
1309               (let ((begin (widget-field-start field))
1310                     (end (widget-field-end field)))
1311                 (when size
1312                   (while (and (> end begin)
1313                               (eq (char-after (1- end)) ?\ ))
1314                     (setq end (1- end))))
1315                 (while (< begin end)
1316                   (let ((old (char-after begin)))
1317                     (unless (eq old secret)
1318                       (subst-char-in-region begin (1+ begin) old secret)
1319                       (put-text-property begin (1+ begin) 'secret old))
1320                     (setq begin (1+ begin)))))))
1321           (widget-apply field :notify field)))
1322     (error (debug "After Change"))))
1323
1324 ;;; Widget Functions
1325 ;;
1326 ;; These functions are used in the definition of multiple widgets.
1327
1328 (defun widget-parent-action (widget &optional event)
1329   "Tell :parent of WIDGET to handle the :action.
1330 Optional EVENT is the event that triggered the action."
1331   (widget-apply (widget-get widget :parent) :action event))
1332
1333 (defun widget-children-value-delete (widget)
1334   "Delete all :children and :buttons in WIDGET."
1335   (mapcar 'widget-delete (widget-get widget :children))
1336   (widget-put widget :children nil)
1337   (mapcar 'widget-delete (widget-get widget :buttons))
1338   (widget-put widget :buttons nil))
1339
1340 (defun widget-children-validate (widget)
1341   "All the :children must be valid."
1342   (let ((children (widget-get widget :children))
1343         child found)
1344     (while (and children (not found))
1345       (setq child (car children)
1346             children (cdr children)
1347             found (widget-apply child :validate)))
1348     found))
1349
1350 (defun widget-types-convert-widget (widget)
1351   "Convert :args as widget types in WIDGET."
1352   (widget-put widget :args (mapcar 'widget-convert (widget-get widget :args)))
1353   widget)
1354
1355 (defun widget-value-convert-widget (widget)
1356   "Initialize :value from :args in WIDGET."
1357   (let ((args (widget-get widget :args)))
1358     (when args
1359       (widget-put widget :value (car args))
1360       ;; Don't convert :value here, as this is done in `widget-convert'.
1361       ;; (widget-put widget :value (widget-apply widget
1362       ;;                                      :value-to-internal (car args)))
1363       (widget-put widget :args nil)))
1364   widget)
1365
1366 (defun widget-value-value-get (widget)
1367   "Return the :value property of WIDGET."
1368   (widget-get widget :value))
1369
1370 ;;; The `default' Widget.
1371
1372 (define-widget 'default nil
1373   "Basic widget other widgets are derived from."
1374   :value-to-internal (lambda (widget value) value)
1375   :value-to-external (lambda (widget value) value)
1376   :button-prefix 'widget-button-prefix
1377   :button-suffix 'widget-button-suffix
1378   :complete 'widget-default-complete
1379   :create 'widget-default-create
1380   :indent nil
1381   :offset 0
1382   :format-handler 'widget-default-format-handler
1383   :button-face-get 'widget-default-button-face-get
1384   :sample-face-get 'widget-default-sample-face-get
1385   :delete 'widget-default-delete
1386   :value-set 'widget-default-value-set
1387   :value-inline 'widget-default-value-inline
1388   :menu-tag-get 'widget-default-menu-tag-get
1389   :validate (lambda (widget) nil)
1390   :active 'widget-default-active
1391   :activate 'widget-specify-active
1392   :deactivate 'widget-default-deactivate
1393   :mouse-down-action (lambda (widget event) nil)
1394   :action 'widget-default-action
1395   :notify 'widget-default-notify
1396   :prompt-value 'widget-default-prompt-value)
1397
1398 (defun widget-default-complete (widget)
1399   "Call the value of the :complete-function property of WIDGET.
1400 If that does not exists, call the value of `widget-complete-field'."
1401   (let ((fun (widget-get widget :complete-function)))
1402     (call-interactively (or fun widget-complete-field))))
1403
1404 (defun widget-default-create (widget)
1405   "Create WIDGET at point in the current buffer."
1406   (widget-specify-insert
1407    (let ((from (point))
1408          button-begin button-end
1409          sample-begin sample-end
1410          doc-begin doc-end
1411          value-pos)
1412      (insert (widget-get widget :format))
1413      (goto-char from)
1414      ;; Parse escapes in format.
1415      (while (re-search-forward "%\\(.\\)" nil t)
1416        (let ((escape (aref (match-string 1) 0)))
1417          (replace-match "" t t)
1418          (cond ((eq escape ?%)
1419                 (insert "%"))
1420                ((eq escape ?\[)
1421                 (setq button-begin (point))
1422                 (insert (widget-get-indirect widget :button-prefix)))
1423                ((eq escape ?\])
1424                 (insert (widget-get-indirect widget :button-suffix))
1425                 (setq button-end (point)))
1426                ((eq escape ?\{)
1427                 (setq sample-begin (point)))
1428                ((eq escape ?\})
1429                 (setq sample-end (point)))
1430                ((eq escape ?n)
1431                 (when (widget-get widget :indent)
1432                   (insert "\n")
1433                   (insert-char ?  (widget-get widget :indent))))
1434                ((eq escape ?t)
1435                 (let ((glyph (widget-get widget :tag-glyph))
1436                       (tag (widget-get widget :tag)))
1437                   (cond (glyph
1438                          (widget-glyph-insert widget (or tag "image") glyph))
1439                         (tag
1440                          (insert tag))
1441                         (t
1442                          (let ((standard-output (current-buffer)))
1443                            (princ (widget-get widget :value)))))))
1444                ((eq escape ?d)
1445                 (let ((doc (widget-get widget :doc)))
1446                   (when doc
1447                     (setq doc-begin (point))
1448                     (insert doc)
1449                     (while (eq (preceding-char) ?\n)
1450                       (delete-backward-char 1))
1451                     (insert "\n")
1452                     (setq doc-end (point)))))
1453                ((eq escape ?v)
1454                 (if (and button-begin (not button-end))
1455                     (widget-apply widget :value-create)
1456                   (setq value-pos (point))))
1457                (t
1458                 (widget-apply widget :format-handler escape)))))
1459      ;; Specify button, sample, and doc, and insert value.
1460      (and button-begin button-end
1461           (widget-specify-button widget button-begin button-end))
1462      (and sample-begin sample-end
1463           (widget-specify-sample widget sample-begin sample-end))
1464      (and doc-begin doc-end
1465           (widget-specify-doc widget doc-begin doc-end))
1466      (when value-pos
1467        (goto-char value-pos)
1468        (widget-apply widget :value-create)))
1469    (let ((from (copy-marker (point-min)))
1470          (to (copy-marker (point-max))))
1471      (set-marker-insertion-type from t)
1472      (set-marker-insertion-type to nil)
1473      (widget-put widget :from from)
1474      (widget-put widget :to to)))
1475   (widget-clear-undo))
1476
1477 (defun widget-default-format-handler (widget escape)
1478   ;; We recognize the %h escape by default.
1479   (let* ((buttons (widget-get widget :buttons)))
1480     (cond ((eq escape ?h)
1481            (let* ((doc-property (widget-get widget :documentation-property))
1482                   (doc-try (cond ((widget-get widget :doc))
1483                                  ((symbolp doc-property)
1484                                   (documentation-property
1485                                    (widget-get widget :value)
1486                                    doc-property))
1487                                  (t
1488                                   (funcall doc-property
1489                                            (widget-get widget :value)))))
1490                   (doc-text (and (stringp doc-try)
1491                                  (> (length doc-try) 1)
1492                                  doc-try))
1493                   (doc-indent (widget-get widget :documentation-indent)))
1494              (when doc-text
1495                (and (eq (preceding-char) ?\n)
1496                     (widget-get widget :indent)
1497                     (insert-char ?  (widget-get widget :indent)))
1498                ;; The `*' in the beginning is redundant.
1499                (when (eq (aref doc-text  0) ?*)
1500                  (setq doc-text (substring doc-text 1)))
1501                ;; Get rid of trailing newlines.
1502                (when (string-match "\n+\\'" doc-text)
1503                  (setq doc-text (substring doc-text 0 (match-beginning 0))))
1504                (push (widget-create-child-and-convert
1505                       widget 'documentation-string
1506                       :indent (cond ((numberp doc-indent )
1507                                      doc-indent)
1508                                     ((null doc-indent)
1509                                      nil)
1510                                     (t 0))
1511                       doc-text)
1512                      buttons))))
1513           (t
1514            (error "Unknown escape `%c'" escape)))
1515     (widget-put widget :buttons buttons)))
1516
1517 (defun widget-default-button-face-get (widget)
1518   ;; Use :button-face or widget-button-face
1519   (or (widget-get widget :button-face)
1520       (let ((parent (widget-get widget :parent)))
1521         (if parent
1522             (widget-apply parent :button-face-get)
1523           widget-button-face))))
1524
1525 (defun widget-default-sample-face-get (widget)
1526   ;; Use :sample-face.
1527   (widget-get widget :sample-face))
1528
1529 (defun widget-default-delete (widget)
1530   ;; Remove widget from the buffer.
1531   (let ((from (widget-get widget :from))
1532         (to (widget-get widget :to))
1533         (inactive-overlay (widget-get widget :inactive))
1534         (button-overlay (widget-get widget :button-overlay))
1535         (sample-overlay (widget-get widget :sample-overlay))
1536         (doc-overlay (widget-get widget :doc-overlay))
1537         before-change-functions
1538         after-change-functions
1539         (inhibit-read-only t))
1540     (widget-apply widget :value-delete)
1541     (when inactive-overlay
1542       (delete-overlay inactive-overlay))
1543     (when button-overlay
1544       (delete-overlay button-overlay))
1545     (when sample-overlay
1546       (delete-overlay sample-overlay))
1547     (when doc-overlay
1548       (delete-overlay doc-overlay))
1549     (when (< from to)
1550       ;; Kludge: this doesn't need to be true for empty formats.
1551       (delete-region from to))
1552     (set-marker from nil)
1553     (set-marker to nil))
1554   (widget-clear-undo))
1555
1556 (defun widget-default-value-set (widget value)
1557   ;; Recreate widget with new value.
1558   (let* ((old-pos (point))
1559          (from (copy-marker (widget-get widget :from)))
1560          (to (copy-marker (widget-get widget :to)))
1561          (offset (if (and (<= from old-pos) (<= old-pos to))
1562                      (if (>= old-pos (1- to))
1563                          (- old-pos to 1)
1564                        (- old-pos from)))))
1565     ;;??? Bug: this ought to insert the new value before deleting the old one,
1566     ;; so that markers on either side of the value automatically
1567     ;; stay on the same side.  -- rms.
1568     (save-excursion
1569       (goto-char (widget-get widget :from))
1570       (widget-apply widget :delete)
1571       (widget-put widget :value value)
1572       (widget-apply widget :create))
1573     (if offset
1574         (if (< offset 0)
1575             (goto-char (+ (widget-get widget :to) offset 1))
1576           (goto-char (min (+ from offset) (1- (widget-get widget :to))))))))
1577
1578 (defun widget-default-value-inline (widget)
1579   ;; Wrap value in a list unless it is inline.
1580   (if (widget-get widget :inline)
1581       (widget-value widget)
1582     (list (widget-value widget))))
1583
1584 (defun widget-default-menu-tag-get (widget)
1585   ;; Use tag or value for menus.
1586   (or (widget-get widget :menu-tag)
1587       (widget-get widget :tag)
1588       (widget-princ-to-string (widget-get widget :value))))
1589
1590 (defun widget-default-active (widget)
1591   "Return t iff this widget active (user modifiable)."
1592   (and (not (widget-get widget :inactive))
1593        (let ((parent (widget-get widget :parent)))
1594          (or (null parent)
1595              (widget-apply parent :active)))))
1596
1597 (defun widget-default-deactivate (widget)
1598   "Make WIDGET inactive for user modifications."
1599   (widget-specify-inactive widget
1600                            (widget-get widget :from)
1601                            (widget-get widget :to)))
1602
1603 (defun widget-default-action (widget &optional event)
1604   ;; Notify the parent when a widget change
1605   (let ((parent (widget-get widget :parent)))
1606     (when parent
1607       (widget-apply parent :notify widget event))))
1608
1609 (defun widget-default-notify (widget child &optional event)
1610   ;; Pass notification to parent.
1611   (widget-default-action widget event))
1612
1613 (defun widget-default-prompt-value (widget prompt value unbound)
1614   ;; Read an arbitrary value.  Stolen from `set-variable'.
1615 ;;  (let ((initial (if unbound
1616 ;;                   nil
1617 ;;                 ;; It would be nice if we could do a `(cons val 1)' here.
1618 ;;                 (prin1-to-string (custom-quote value))))))
1619   (eval-minibuffer prompt ))
1620
1621 ;;; The `item' Widget.
1622
1623 (define-widget 'item 'default
1624   "Constant items for inclusion in other widgets."
1625   :convert-widget 'widget-value-convert-widget
1626   :value-create 'widget-item-value-create
1627   :value-delete 'ignore
1628   :value-get 'widget-value-value-get
1629   :match 'widget-item-match
1630   :match-inline 'widget-item-match-inline
1631   :action 'widget-item-action
1632   :format "%t\n")
1633
1634 (defun widget-item-value-create (widget)
1635   ;; Insert the printed representation of the value.
1636   (let ((standard-output (current-buffer)))
1637     (princ (widget-get widget :value))))
1638
1639 (defun widget-item-match (widget value)
1640   ;; Match if the value is the same.
1641   (equal (widget-get widget :value) value))
1642
1643 (defun widget-item-match-inline (widget values)
1644   ;; Match if the value is the same.
1645   (let ((value (widget-get widget :value)))
1646     (and (listp value)
1647          (<= (length value) (length values))
1648          (let ((head (widget-sublist values 0 (length value))))
1649            (and (equal head value)
1650                 (cons head (widget-sublist values (length value))))))))
1651
1652 (defun widget-sublist (list start &optional end)
1653   "Return the sublist of LIST from START to END.
1654 If END is omitted, it defaults to the length of LIST."
1655   (if (> start 0) (setq list (nthcdr start list)))
1656   (if end
1657       (if (<= end start)
1658           nil
1659         (setq list (copy-sequence list))
1660         (setcdr (nthcdr (- end start 1) list) nil)
1661         list)
1662     (copy-sequence list)))
1663
1664 (defun widget-item-action (widget &optional event)
1665   ;; Just notify itself.
1666   (widget-apply widget :notify widget event))
1667
1668 ;;; The `push-button' Widget.
1669
1670 (defcustom widget-push-button-gui t
1671   "If non nil, use GUI push buttons when available."
1672   :group 'widgets
1673   :type 'boolean)
1674
1675 ;; Cache already created GUI objects.
1676 (defvar widget-push-button-cache nil)
1677
1678 (defcustom widget-push-button-prefix "["
1679   "String used as prefix for buttons."
1680   :type 'string
1681   :group 'widget-button)
1682
1683 (defcustom widget-push-button-suffix "]"
1684   "String used as suffix for buttons."
1685   :type 'string
1686   :group 'widget-button)
1687
1688 (define-widget 'push-button 'item
1689   "A pushable button."
1690   :button-prefix ""
1691   :button-suffix ""
1692   :value-create 'widget-push-button-value-create
1693   :format "%[%v%]")
1694
1695 (defun widget-push-button-value-create (widget)
1696   ;; Insert text representing the `on' and `off' states.
1697   (let* ((tag (or (widget-get widget :tag)
1698                   (widget-get widget :value)))
1699          (tag-glyph (widget-get widget :tag-glyph))
1700          (text (concat widget-push-button-prefix
1701                        tag widget-push-button-suffix))
1702          (gui (cdr (assoc tag widget-push-button-cache))))
1703     (cond (tag-glyph
1704            (widget-glyph-insert widget text tag-glyph))
1705           ((and (fboundp 'make-gui-button)
1706              (fboundp 'make-glyph)
1707              widget-push-button-gui
1708              (fboundp 'device-on-window-system-p)
1709              (device-on-window-system-p)
1710              (string-match "XEmacs" emacs-version))
1711            (unless gui
1712              (setq gui (make-gui-button tag 'widget-gui-action widget))
1713              (push (cons tag gui) widget-push-button-cache))
1714            (widget-glyph-insert-glyph widget
1715                                       (make-glyph
1716                                        (list (nth 0 (aref gui 1))
1717                                              (vector 'string ':data text)))
1718                                       (make-glyph
1719                                        (list (nth 1 (aref gui 1))
1720                                              (vector 'string ':data text)))
1721                                       (make-glyph
1722                                        (list (nth 2 (aref gui 1))
1723                                              (vector 'string ':data text)))))
1724           (t
1725            (insert text)))))
1726
1727 (defun widget-gui-action (widget)
1728   "Apply :action for WIDGET."
1729   (widget-apply-action widget (this-command-keys)))
1730
1731 ;;; The `link' Widget.
1732
1733 (defcustom widget-link-prefix "["
1734   "String used as prefix for links."
1735   :type 'string
1736   :group 'widget-button)
1737
1738 (defcustom widget-link-suffix "]"
1739   "String used as suffix for links."
1740   :type 'string
1741   :group 'widget-button)
1742
1743 (define-widget 'link 'item
1744   "An embedded link."
1745   :button-prefix 'widget-link-prefix
1746   :button-suffix 'widget-link-suffix
1747   :help-echo "Follow the link."
1748   :format "%[%t%]")
1749
1750 ;;; The `info-link' Widget.
1751
1752 (define-widget 'info-link 'link
1753   "A link to an info file."
1754   :action 'widget-info-link-action)
1755
1756 (defun widget-info-link-action (widget &optional event)
1757   "Open the info node specified by WIDGET."
1758   (Info-goto-node (widget-value widget)))
1759
1760 ;;; The `url-link' Widget.
1761
1762 (define-widget 'url-link 'link
1763   "A link to an www page."
1764   :action 'widget-url-link-action)
1765
1766 (defun widget-url-link-action (widget &optional event)
1767   "Open the url specified by WIDGET."
1768   (require 'browse-url)
1769   (funcall browse-url-browser-function (widget-value widget)))
1770
1771 ;;; The `function-link' Widget.
1772
1773 (define-widget 'function-link 'link
1774   "A link to an Emacs function."
1775   :action 'widget-function-link-action)
1776
1777 (defun widget-function-link-action (widget &optional event)
1778   "Show the function specified by WIDGET."
1779   (describe-function (widget-value widget)))
1780
1781 ;;; The `variable-link' Widget.
1782
1783 (define-widget 'variable-link 'link
1784   "A link to an Emacs variable."
1785   :action 'widget-variable-link-action)
1786
1787 (defun widget-variable-link-action (widget &optional event)
1788   "Show the variable specified by WIDGET."
1789   (describe-variable (widget-value widget)))
1790
1791 ;;; The `file-link' Widget.
1792
1793 (define-widget 'file-link 'link
1794   "A link to a file."
1795   :action 'widget-file-link-action)
1796
1797 (defun widget-file-link-action (widget &optional event)
1798   "Find the file specified by WIDGET."
1799   (find-file (widget-value widget)))
1800
1801 ;;; The `emacs-library-link' Widget.
1802
1803 (define-widget 'emacs-library-link 'link
1804   "A link to an Emacs Lisp library file."
1805   :action 'widget-emacs-library-link-action)
1806
1807 (defun widget-emacs-library-link-action (widget &optional event)
1808   "Find the Emacs Library file specified by WIDGET."
1809   (find-file (locate-library (widget-value widget))))
1810
1811 ;;; The `emacs-commentary-link' Widget.
1812
1813 (define-widget 'emacs-commentary-link 'link
1814   "A link to Commentary in an Emacs Lisp library file."
1815   :action 'widget-emacs-commentary-link-action)
1816
1817 (defun widget-emacs-commentary-link-action (widget &optional event)
1818   "Find the Commentary section of the Emacs file specified by WIDGET."
1819   (finder-commentary (widget-value widget)))
1820
1821 ;;; The `editable-field' Widget.
1822
1823 (define-widget 'editable-field 'default
1824   "An editable text field."
1825   :convert-widget 'widget-value-convert-widget
1826   :keymap widget-field-keymap
1827   :format "%v"
1828   :value ""
1829   :prompt-internal 'widget-field-prompt-internal
1830   :prompt-history 'widget-field-history
1831   :prompt-value 'widget-field-prompt-value
1832   :action 'widget-field-action
1833   :validate 'widget-field-validate
1834   :valid-regexp ""
1835   :error "No match"
1836   :value-create 'widget-field-value-create
1837   :value-delete 'widget-field-value-delete
1838   :value-get 'widget-field-value-get
1839   :match 'widget-field-match)
1840
1841 (defvar widget-field-history nil
1842   "History of field minibuffer edits.")
1843
1844 (defun widget-field-prompt-internal (widget prompt initial history)
1845   ;; Read string for WIDGET promptinhg with PROMPT.
1846   ;; INITIAL is the initial input and HISTORY is a symbol containing
1847   ;; the earlier input.
1848   (read-string prompt initial history))
1849
1850 (defun widget-field-prompt-value (widget prompt value unbound)
1851   ;; Prompt for a string.
1852   (let ((initial (if unbound
1853                      nil
1854                    (cons (widget-apply widget :value-to-internal
1855                                        value) 0)))
1856         (history (widget-get widget :prompt-history)))
1857     (let ((answer (widget-apply widget
1858                                 :prompt-internal prompt initial history)))
1859       (widget-apply widget :value-to-external answer))))
1860
1861 (defvar widget-edit-functions nil)
1862
1863 (defun widget-field-action (widget &optional event)
1864   ;; Move to next field.
1865   (widget-forward 1)
1866   (run-hook-with-args 'widget-edit-functions widget))
1867
1868 (defun widget-field-validate (widget)
1869   ;; Valid if the content matches `:valid-regexp'.
1870   (save-excursion
1871     (let ((value (widget-apply widget :value-get))
1872           (regexp (widget-get widget :valid-regexp)))
1873       (if (string-match regexp value)
1874           nil
1875         widget))))
1876
1877 (defun widget-field-value-create (widget)
1878   ;; Create an editable text field.
1879   (let ((size (widget-get widget :size))
1880         (value (widget-get widget :value))
1881         (from (point))
1882         ;; This is changed to a real overlay in `widget-setup'.  We
1883         ;; need the end points to behave differently until
1884         ;; `widget-setup' is called.
1885         (overlay (cons (make-marker) (make-marker))))
1886     (widget-put widget :field-overlay overlay)
1887     (insert value)
1888     (and size
1889          (< (length value) size)
1890          (insert-char ?\  (- size (length value))))
1891     (unless (memq widget widget-field-list)
1892       (setq widget-field-new (cons widget widget-field-new)))
1893     (move-marker (cdr overlay) (point))
1894     (set-marker-insertion-type (cdr overlay) nil)
1895     (when (null size)
1896       (insert ?\n))
1897     (move-marker (car overlay) from)
1898     (set-marker-insertion-type (car overlay) t)))
1899
1900 (defun widget-field-value-delete (widget)
1901   ;; Remove the widget from the list of active editing fields.
1902   (setq widget-field-list (delq widget widget-field-list))
1903   ;; These are nil if the :format string doesn't contain `%v'.
1904   (let ((overlay (widget-get widget :field-overlay)))
1905     (when overlay
1906       (delete-overlay overlay))))
1907
1908 (defun widget-field-value-get (widget)
1909   ;; Return current text in editing field.
1910   (let ((from (widget-field-start widget))
1911         (to (widget-field-end widget))
1912         (buffer (widget-field-buffer widget))
1913         (size (widget-get widget :size))
1914         (secret (widget-get widget :secret))
1915         (old (current-buffer)))
1916     (if (and from to)
1917         (progn
1918           (set-buffer buffer)
1919           (while (and size
1920                       (not (zerop size))
1921                       (> to from)
1922                       (eq (char-after (1- to)) ?\ ))
1923             (setq to (1- to)))
1924           (let ((result (buffer-substring-no-properties from to)))
1925             (when secret
1926               (let ((index 0))
1927                 (while (< (+ from index) to)
1928                   (aset result index
1929                         (get-char-property (+ from index) 'secret))
1930                   (setq index (1+ index)))))
1931             (set-buffer old)
1932             result))
1933       (widget-get widget :value))))
1934
1935 (defun widget-field-match (widget value)
1936   ;; Match any string.
1937   (stringp value))
1938
1939 ;;; The `text' Widget.
1940
1941 (define-widget 'text 'editable-field
1942   :keymap widget-text-keymap
1943   "A multiline text area.")
1944
1945 ;;; The `menu-choice' Widget.
1946
1947 (define-widget 'menu-choice 'default
1948   "A menu of options."
1949   :convert-widget  'widget-types-convert-widget
1950   :format "%[%t%]: %v"
1951   :case-fold t
1952   :tag "choice"
1953   :void '(item :format "invalid (%t)\n")
1954   :value-create 'widget-choice-value-create
1955   :value-delete 'widget-children-value-delete
1956   :value-get 'widget-choice-value-get
1957   :value-inline 'widget-choice-value-inline
1958   :mouse-down-action 'widget-choice-mouse-down-action
1959   :action 'widget-choice-action
1960   :error "Make a choice"
1961   :validate 'widget-choice-validate
1962   :match 'widget-choice-match
1963   :match-inline 'widget-choice-match-inline)
1964
1965 (defun widget-choice-value-create (widget)
1966   ;; Insert the first choice that matches the value.
1967   (let ((value (widget-get widget :value))
1968         (args (widget-get widget :args))
1969         current)
1970     (while args
1971       (setq current (car args)
1972             args (cdr args))
1973       (when (widget-apply current :match value)
1974         (widget-put widget :children (list (widget-create-child-value
1975                                             widget current value)))
1976         (widget-put widget :choice current)
1977         (setq args nil
1978               current nil)))
1979     (when current
1980       (let ((void (widget-get widget :void)))
1981         (widget-put widget :children (list (widget-create-child-and-convert
1982                                             widget void :value value)))
1983         (widget-put widget :choice void)))))
1984
1985 (defun widget-choice-value-get (widget)
1986   ;; Get value of the child widget.
1987   (widget-value (car (widget-get widget :children))))
1988
1989 (defun widget-choice-value-inline (widget)
1990   ;; Get value of the child widget.
1991   (widget-apply (car (widget-get widget :children)) :value-inline))
1992
1993 (defcustom widget-choice-toggle nil
1994   "If non-nil, a binary choice will just toggle between the values.
1995 Otherwise, the user will explicitly have to choose between the values
1996 when he invoked the menu."
1997   :type 'boolean
1998   :group 'widgets)
1999
2000 (defun widget-choice-mouse-down-action (widget &optional event)
2001   ;; Return non-nil if we need a menu.
2002   (let ((args (widget-get widget :args))
2003         (old (widget-get widget :choice)))
2004     (cond ((not window-system)
2005            ;; No place to pop up a menu.
2006            nil)
2007           ((not (or (fboundp 'x-popup-menu) (fboundp 'popup-menu)))
2008            ;; No way to pop up a menu.
2009            nil)
2010           ((< (length args) 2)
2011            ;; Empty or singleton list, just return the value.
2012            nil)
2013           ((> (length args) widget-menu-max-size)
2014            ;; Too long, prompt.
2015            nil)
2016           ((> (length args) 2)
2017            ;; Reasonable sized list, use menu.
2018            t)
2019           ((and widget-choice-toggle (memq old args))
2020            ;; We toggle.
2021            nil)
2022           (t
2023            ;; Ask which of the two.
2024            t))))
2025
2026 (defun widget-choice-action (widget &optional event)
2027   ;; Make a choice.
2028   (let ((args (widget-get widget :args))
2029         (old (widget-get widget :choice))
2030         (tag (widget-apply widget :menu-tag-get))
2031         (completion-ignore-case (widget-get widget :case-fold))
2032         current choices)
2033     ;; Remember old value.
2034     (if (and old (not (widget-apply widget :validate)))
2035         (let* ((external (widget-value widget))
2036                (internal (widget-apply old :value-to-internal external)))
2037           (widget-put old :value internal)))
2038     ;; Find new choice.
2039     (setq current
2040           (cond ((= (length args) 0)
2041                  nil)
2042                 ((= (length args) 1)
2043                  (nth 0 args))
2044                 ((and widget-choice-toggle
2045                       (= (length args) 2)
2046                       (memq old args))
2047                  (if (eq old (nth 0 args))
2048                      (nth 1 args)
2049                    (nth 0 args)))
2050                 (t
2051                  (while args
2052                    (setq current (car args)
2053                          args (cdr args))
2054                    (setq choices
2055                          (cons (cons (widget-apply current :menu-tag-get)
2056                                      current)
2057                                choices)))
2058                  (widget-choose tag (reverse choices) event))))
2059     (when current
2060       (widget-value-set widget
2061                         (widget-apply current :value-to-external
2062                                       (widget-get current :value)))
2063       (widget-setup)
2064       (widget-apply widget :notify widget event)))
2065   (run-hook-with-args 'widget-edit-functions widget))
2066
2067 (defun widget-choice-validate (widget)
2068   ;; Valid if we have made a valid choice.
2069   (let ((void (widget-get widget :void))
2070         (choice (widget-get widget :choice))
2071         (child (car (widget-get widget :children))))
2072     (if (eq void choice)
2073         widget
2074       (widget-apply child :validate))))
2075
2076 (defun widget-choice-match (widget value)
2077   ;; Matches if one of the choices matches.
2078   (let ((args (widget-get widget :args))
2079         current found)
2080     (while (and args (not found))
2081       (setq current (car args)
2082             args (cdr args)
2083             found (widget-apply current :match value)))
2084     found))
2085
2086 (defun widget-choice-match-inline (widget values)
2087   ;; Matches if one of the choices matches.
2088   (let ((args (widget-get widget :args))
2089         current found)
2090     (while (and args (null found))
2091       (setq current (car args)
2092             args (cdr args)
2093             found (widget-match-inline current values)))
2094     found))
2095
2096 ;;; The `toggle' Widget.
2097
2098 (define-widget 'toggle 'item
2099   "Toggle between two states."
2100   :format "%[%v%]\n"
2101   :value-create 'widget-toggle-value-create
2102   :action 'widget-toggle-action
2103   :match (lambda (widget value) t)
2104   :on "on"
2105   :off "off")
2106
2107 (defun widget-toggle-value-create (widget)
2108   ;; Insert text representing the `on' and `off' states.
2109   (if (widget-value widget)
2110       (widget-glyph-insert widget
2111                            (widget-get widget :on)
2112                            (widget-get widget :on-glyph))
2113     (widget-glyph-insert widget
2114                          (widget-get widget :off)
2115                          (widget-get widget :off-glyph))))
2116
2117 (defun widget-toggle-action (widget &optional event)
2118   ;; Toggle value.
2119   (widget-value-set widget (not (widget-value widget)))
2120   (widget-apply widget :notify widget event)
2121   (run-hook-with-args 'widget-edit-functions widget))
2122
2123 ;;; The `checkbox' Widget.
2124
2125 (define-widget 'checkbox 'toggle
2126   "A checkbox toggle."
2127   :button-suffix ""
2128   :button-prefix ""
2129   :format "%[%v%]"
2130   :on "[X]"
2131   :on-glyph "check1"
2132   :off "[ ]"
2133   :off-glyph "check0"
2134   :action 'widget-checkbox-action)
2135
2136 (defun widget-checkbox-action (widget &optional event)
2137   "Toggle checkbox, notify parent, and set active state of sibling."
2138   (widget-toggle-action widget event)
2139   (let ((sibling (widget-get-sibling widget)))
2140     (when sibling
2141       (if (widget-value widget)
2142           (widget-apply sibling :activate)
2143         (widget-apply sibling :deactivate)))))
2144
2145 ;;; The `checklist' Widget.
2146
2147 (define-widget 'checklist 'default
2148   "A multiple choice widget."
2149   :convert-widget 'widget-types-convert-widget
2150   :format "%v"
2151   :offset 4
2152   :entry-format "%b %v"
2153   :menu-tag "checklist"
2154   :greedy nil
2155   :value-create 'widget-checklist-value-create
2156   :value-delete 'widget-children-value-delete
2157   :value-get 'widget-checklist-value-get
2158   :validate 'widget-checklist-validate
2159   :match 'widget-checklist-match
2160   :match-inline 'widget-checklist-match-inline)
2161
2162 (defun widget-checklist-value-create (widget)
2163   ;; Insert all values
2164   (let ((alist (widget-checklist-match-find widget (widget-get widget :value)))
2165         (args (widget-get widget :args)))
2166     (while args
2167       (widget-checklist-add-item widget (car args) (assq (car args) alist))
2168       (setq args (cdr args)))
2169     (widget-put widget :children (nreverse (widget-get widget :children)))))
2170
2171 (defun widget-checklist-add-item (widget type chosen)
2172   ;; Create checklist item in WIDGET of type TYPE.
2173   ;; If the item is checked, CHOSEN is a cons whose cdr is the value.
2174   (and (eq (preceding-char) ?\n)
2175        (widget-get widget :indent)
2176        (insert-char ?  (widget-get widget :indent)))
2177   (widget-specify-insert
2178    (let* ((children (widget-get widget :children))
2179           (buttons (widget-get widget :buttons))
2180           (button-args (or (widget-get type :sibling-args)
2181                            (widget-get widget :button-args)))
2182           (from (point))
2183           child button)
2184      (insert (widget-get widget :entry-format))
2185      (goto-char from)
2186      ;; Parse % escapes in format.
2187      (while (re-search-forward "%\\([bv%]\\)" nil t)
2188        (let ((escape (aref (match-string 1) 0)))
2189          (replace-match "" t t)
2190          (cond ((eq escape ?%)
2191                 (insert "%"))
2192                ((eq escape ?b)
2193                 (setq button (apply 'widget-create-child-and-convert
2194                                     widget 'checkbox
2195                                     :value (not (null chosen))
2196                                     button-args)))
2197                ((eq escape ?v)
2198                 (setq child
2199                       (cond ((not chosen)
2200                              (let ((child (widget-create-child widget type)))
2201                                (widget-apply child :deactivate)
2202                                child))
2203                             ((widget-get type :inline)
2204                              (widget-create-child-value
2205                               widget type (cdr chosen)))
2206                             (t
2207                              (widget-create-child-value
2208                               widget type (car (cdr chosen)))))))
2209                (t
2210                 (error "Unknown escape `%c'" escape)))))
2211      ;; Update properties.
2212      (and button child (widget-put child :button button))
2213      (and button (widget-put widget :buttons (cons button buttons)))
2214      (and child (widget-put widget :children (cons child children))))))
2215
2216 (defun widget-checklist-match (widget values)
2217   ;; All values must match a type in the checklist.
2218   (and (listp values)
2219        (null (cdr (widget-checklist-match-inline widget values)))))
2220
2221 (defun widget-checklist-match-inline (widget values)
2222   ;; Find the values which match a type in the checklist.
2223   (let ((greedy (widget-get widget :greedy))
2224         (args (copy-sequence (widget-get widget :args)))
2225         found rest)
2226     (while values
2227       (let ((answer (widget-checklist-match-up args values)))
2228         (cond (answer
2229                (let ((vals (widget-match-inline answer values)))
2230                  (setq found (append found (car vals))
2231                        values (cdr vals)
2232                        args (delq answer args))))
2233               (greedy
2234                (setq rest (append rest (list (car values)))
2235                      values (cdr values)))
2236               (t
2237                (setq rest (append rest values)
2238                      values nil)))))
2239     (cons found rest)))
2240
2241 (defun widget-checklist-match-find (widget vals)
2242   ;; Find the vals which match a type in the checklist.
2243   ;; Return an alist of (TYPE MATCH).
2244   (let ((greedy (widget-get widget :greedy))
2245         (args (copy-sequence (widget-get widget :args)))
2246         found)
2247     (while vals
2248       (let ((answer (widget-checklist-match-up args vals)))
2249         (cond (answer
2250                (let ((match (widget-match-inline answer vals)))
2251                  (setq found (cons (cons answer (car match)) found)
2252                        vals (cdr match)
2253                        args (delq answer args))))
2254               (greedy
2255                (setq vals (cdr vals)))
2256               (t
2257                (setq vals nil)))))
2258     found))
2259
2260 (defun widget-checklist-match-up (args vals)
2261   ;; Rerturn the first type from ARGS that matches VALS.
2262   (let (current found)
2263     (while (and args (null found))
2264       (setq current (car args)
2265             args (cdr args)
2266             found (widget-match-inline current vals)))
2267     (if found
2268         current
2269       nil)))
2270
2271 (defun widget-checklist-value-get (widget)
2272   ;; The values of all selected items.
2273   (let ((children (widget-get widget :children))
2274         child result)
2275     (while children
2276       (setq child (car children)
2277             children (cdr children))
2278       (if (widget-value (widget-get child :button))
2279           (setq result (append result (widget-apply child :value-inline)))))
2280     result))
2281
2282 (defun widget-checklist-validate (widget)
2283   ;; Ticked chilren must be valid.
2284   (let ((children (widget-get widget :children))
2285         child button found)
2286     (while (and children (not found))
2287       (setq child (car children)
2288             children (cdr children)
2289             button (widget-get child :button)
2290             found (and (widget-value button)
2291                        (widget-apply child :validate))))
2292     found))
2293
2294 ;;; The `option' Widget
2295
2296 (define-widget 'option 'checklist
2297   "An widget with an optional item."
2298   :inline t)
2299
2300 ;;; The `choice-item' Widget.
2301
2302 (define-widget 'choice-item 'item
2303   "Button items that delegate action events to their parents."
2304   :action 'widget-parent-action
2305   :format "%[%t%] \n")
2306
2307 ;;; The `radio-button' Widget.
2308
2309 (define-widget 'radio-button 'toggle
2310   "A radio button for use in the `radio' widget."
2311   :notify 'widget-radio-button-notify
2312   :format "%[%v%]"
2313   :button-suffix ""
2314   :button-prefix ""
2315   :on "(*)"
2316   :on-glyph "radio1"
2317   :off "( )"
2318   :off-glyph "radio0")
2319
2320 (defun widget-radio-button-notify (widget child &optional event)
2321   ;; Tell daddy.
2322   (widget-apply (widget-get widget :parent) :action widget event))
2323
2324 ;;; The `radio-button-choice' Widget.
2325
2326 (define-widget 'radio-button-choice 'default
2327   "Select one of multiple options."
2328   :convert-widget 'widget-types-convert-widget
2329   :offset 4
2330   :format "%v"
2331   :entry-format "%b %v"
2332   :menu-tag "radio"
2333   :value-create 'widget-radio-value-create
2334   :value-delete 'widget-children-value-delete
2335   :value-get 'widget-radio-value-get
2336   :value-inline 'widget-radio-value-inline
2337   :value-set 'widget-radio-value-set
2338   :error "You must push one of the buttons"
2339   :validate 'widget-radio-validate
2340   :match 'widget-choice-match
2341   :match-inline 'widget-choice-match-inline
2342   :action 'widget-radio-action)
2343
2344 (defun widget-radio-value-create (widget)
2345   ;; Insert all values
2346   (let ((args (widget-get widget :args))
2347         arg)
2348     (while args
2349       (setq arg (car args)
2350             args (cdr args))
2351       (widget-radio-add-item widget arg))))
2352
2353 (defun widget-radio-add-item (widget type)
2354   "Add to radio widget WIDGET a new radio button item of type TYPE."
2355   ;; (setq type (widget-convert type))
2356   (and (eq (preceding-char) ?\n)
2357        (widget-get widget :indent)
2358        (insert-char ?  (widget-get widget :indent)))
2359   (widget-specify-insert
2360    (let* ((value (widget-get widget :value))
2361           (children (widget-get widget :children))
2362           (buttons (widget-get widget :buttons))
2363           (button-args (or (widget-get type :sibling-args)
2364                            (widget-get widget :button-args)))
2365           (from (point))
2366           (chosen (and (null (widget-get widget :choice))
2367                        (widget-apply type :match value)))
2368           child button)
2369      (insert (widget-get widget :entry-format))
2370      (goto-char from)
2371      ;; Parse % escapes in format.
2372      (while (re-search-forward "%\\([bv%]\\)" nil t)
2373        (let ((escape (aref (match-string 1) 0)))
2374          (replace-match "" t t)
2375          (cond ((eq escape ?%)
2376                 (insert "%"))
2377                ((eq escape ?b)
2378                 (setq button (apply 'widget-create-child-and-convert
2379                                     widget 'radio-button
2380                                     :value (not (null chosen))
2381                                     button-args)))
2382                ((eq escape ?v)
2383                 (setq child (if chosen
2384                                 (widget-create-child-value
2385                                  widget type value)
2386                               (widget-create-child widget type)))
2387                 (unless chosen
2388                   (widget-apply child :deactivate)))
2389                (t
2390                 (error "Unknown escape `%c'" escape)))))
2391      ;; Update properties.
2392      (when chosen
2393        (widget-put widget :choice type))
2394      (when button
2395        (widget-put child :button button)
2396        (widget-put widget :buttons (nconc buttons (list button))))
2397      (when child
2398        (widget-put widget :children (nconc children (list child))))
2399      child)))
2400
2401 (defun widget-radio-value-get (widget)
2402   ;; Get value of the child widget.
2403   (let ((chosen (widget-radio-chosen widget)))
2404     (and chosen (widget-value chosen))))
2405
2406 (defun widget-radio-chosen (widget)
2407   "Return the widget representing the chosen radio button."
2408   (let ((children (widget-get widget :children))
2409         current found)
2410     (while children
2411       (setq current (car children)
2412             children (cdr children))
2413       (let* ((button (widget-get current :button))
2414              (value (widget-apply button :value-get)))
2415         (when value
2416           (setq found current
2417                 children nil))))
2418     found))
2419
2420 (defun widget-radio-value-inline (widget)
2421   ;; Get value of the child widget.
2422   (let ((children (widget-get widget :children))
2423         current found)
2424     (while children
2425       (setq current (car children)
2426             children (cdr children))
2427       (let* ((button (widget-get current :button))
2428              (value (widget-apply button :value-get)))
2429         (when value
2430           (setq found (widget-apply current :value-inline)
2431                 children nil))))
2432     found))
2433
2434 (defun widget-radio-value-set (widget value)
2435   ;; We can't just delete and recreate a radio widget, since children
2436   ;; can be added after the original creation and won't be recreated
2437   ;; by `:create'.
2438   (let ((children (widget-get widget :children))
2439         current found)
2440     (while children
2441       (setq current (car children)
2442             children (cdr children))
2443       (let* ((button (widget-get current :button))
2444              (match (and (not found)
2445                          (widget-apply current :match value))))
2446         (widget-value-set button match)
2447         (if match
2448             (progn
2449               (widget-value-set current value)
2450               (widget-apply current :activate))
2451           (widget-apply current :deactivate))
2452         (setq found (or found match))))))
2453
2454 (defun widget-radio-validate (widget)
2455   ;; Valid if we have made a valid choice.
2456   (let ((children (widget-get widget :children))
2457         current found button)
2458     (while (and children (not found))
2459       (setq current (car children)
2460             children (cdr children)
2461             button (widget-get current :button)
2462             found (widget-apply button :value-get)))
2463     (if found
2464         (widget-apply current :validate)
2465       widget)))
2466
2467 (defun widget-radio-action (widget child event)
2468   ;; Check if a radio button was pressed.
2469   (let ((children (widget-get widget :children))
2470         (buttons (widget-get widget :buttons))
2471         current)
2472     (when (memq child buttons)
2473       (while children
2474         (setq current (car children)
2475               children (cdr children))
2476         (let* ((button (widget-get current :button)))
2477           (cond ((eq child button)
2478                  (widget-value-set button t)
2479                  (widget-apply current :activate))
2480                 ((widget-value button)
2481                  (widget-value-set button nil)
2482                  (widget-apply current :deactivate)))))))
2483   ;; Pass notification to parent.
2484   (widget-apply widget :notify child event))
2485
2486 ;;; The `insert-button' Widget.
2487
2488 (define-widget 'insert-button 'push-button
2489   "An insert button for the `editable-list' widget."
2490   :tag "INS"
2491   :help-echo "Insert a new item into the list at this position."
2492   :action 'widget-insert-button-action)
2493
2494 (defun widget-insert-button-action (widget &optional event)
2495   ;; Ask the parent to insert a new item.
2496   (widget-apply (widget-get widget :parent)
2497                 :insert-before (widget-get widget :widget)))
2498
2499 ;;; The `delete-button' Widget.
2500
2501 (define-widget 'delete-button 'push-button
2502   "A delete button for the `editable-list' widget."
2503   :tag "DEL"
2504   :help-echo "Delete this item from the list."
2505   :action 'widget-delete-button-action)
2506
2507 (defun widget-delete-button-action (widget &optional event)
2508   ;; Ask the parent to insert a new item.
2509   (widget-apply (widget-get widget :parent)
2510                 :delete-at (widget-get widget :widget)))
2511
2512 ;;; The `editable-list' Widget.
2513
2514 (defcustom widget-editable-list-gui nil
2515   "If non nil, use GUI push-buttons in editable list when available."
2516   :type 'boolean
2517   :group 'widgets)
2518
2519 (define-widget 'editable-list 'default
2520   "A variable list of widgets of the same type."
2521   :convert-widget 'widget-types-convert-widget
2522   :offset 12
2523   :format "%v%i\n"
2524   :format-handler 'widget-editable-list-format-handler
2525   :entry-format "%i %d %v"
2526   :menu-tag "editable-list"
2527   :value-create 'widget-editable-list-value-create
2528   :value-delete 'widget-children-value-delete
2529   :value-get 'widget-editable-list-value-get
2530   :validate 'widget-children-validate
2531   :match 'widget-editable-list-match
2532   :match-inline 'widget-editable-list-match-inline
2533   :insert-before 'widget-editable-list-insert-before
2534   :delete-at 'widget-editable-list-delete-at)
2535
2536 (defun widget-editable-list-format-handler (widget escape)
2537   ;; We recognize the insert button.
2538   (let ((widget-push-button-gui widget-editable-list-gui))
2539     (cond ((eq escape ?i)
2540            (and (widget-get widget :indent)
2541                 (insert-char ?  (widget-get widget :indent)))
2542            (apply 'widget-create-child-and-convert
2543                   widget 'insert-button
2544                   (widget-get widget :append-button-args)))
2545           (t
2546            (widget-default-format-handler widget escape)))))
2547
2548 (defun widget-editable-list-value-create (widget)
2549   ;; Insert all values
2550   (let* ((value (widget-get widget :value))
2551          (type (nth 0 (widget-get widget :args)))
2552          (inlinep (widget-get type :inline))
2553          children)
2554     (widget-put widget :value-pos (copy-marker (point)))
2555     (set-marker-insertion-type (widget-get widget :value-pos) t)
2556     (while value
2557       (let ((answer (widget-match-inline type value)))
2558         (if answer
2559             (setq children (cons (widget-editable-list-entry-create
2560                                   widget
2561                                   (if inlinep
2562                                       (car answer)
2563                                     (car (car answer)))
2564                                   t)
2565                                  children)
2566                   value (cdr answer))
2567           (setq value nil))))
2568     (widget-put widget :children (nreverse children))))
2569
2570 (defun widget-editable-list-value-get (widget)
2571   ;; Get value of the child widget.
2572   (apply 'append (mapcar (lambda (child) (widget-apply child :value-inline))
2573                          (widget-get widget :children))))
2574
2575 (defun widget-editable-list-match (widget value)
2576   ;; Value must be a list and all the members must match the type.
2577   (and (listp value)
2578        (null (cdr (widget-editable-list-match-inline widget value)))))
2579
2580 (defun widget-editable-list-match-inline (widget value)
2581   (let ((type (nth 0 (widget-get widget :args)))
2582         (ok t)
2583         found)
2584     (while (and value ok)
2585       (let ((answer (widget-match-inline type value)))
2586         (if answer
2587             (setq found (append found (car answer))
2588                   value (cdr answer))
2589           (setq ok nil))))
2590     (cons found value)))
2591
2592 (defun widget-editable-list-insert-before (widget before)
2593   ;; Insert a new child in the list of children.
2594   (save-excursion
2595     (let ((children (widget-get widget :children))
2596           (inhibit-read-only t)
2597           before-change-functions
2598           after-change-functions)
2599       (cond (before
2600              (goto-char (widget-get before :entry-from)))
2601             (t
2602              (goto-char (widget-get widget :value-pos))))
2603       (let ((child (widget-editable-list-entry-create
2604                     widget nil nil)))
2605         (when (< (widget-get child :entry-from) (widget-get widget :from))
2606           (set-marker (widget-get widget :from)
2607                       (widget-get child :entry-from)))
2608         (if (eq (car children) before)
2609             (widget-put widget :children (cons child children))
2610           (while (not (eq (car (cdr children)) before))
2611             (setq children (cdr children)))
2612           (setcdr children (cons child (cdr children)))))))
2613   (widget-setup)
2614   (widget-apply widget :notify widget))
2615
2616 (defun widget-editable-list-delete-at (widget child)
2617   ;; Delete child from list of children.
2618   (save-excursion
2619     (let ((buttons (copy-sequence (widget-get widget :buttons)))
2620           button
2621           (inhibit-read-only t)
2622           before-change-functions
2623           after-change-functions)
2624       (while buttons
2625         (setq button (car buttons)
2626               buttons (cdr buttons))
2627         (when (eq (widget-get button :widget) child)
2628           (widget-put widget
2629                       :buttons (delq button (widget-get widget :buttons)))
2630           (widget-delete button))))
2631     (let ((entry-from (widget-get child :entry-from))
2632           (entry-to (widget-get child :entry-to))
2633           (inhibit-read-only t)
2634           before-change-functions
2635           after-change-functions)
2636       (widget-delete child)
2637       (delete-region entry-from entry-to)
2638       (set-marker entry-from nil)
2639       (set-marker entry-to nil))
2640     (widget-put widget :children (delq child (widget-get widget :children))))
2641   (widget-setup)
2642   (widget-apply widget :notify widget))
2643
2644 (defun widget-editable-list-entry-create (widget value conv)
2645   ;; Create a new entry to the list.
2646   (let ((type (nth 0 (widget-get widget :args)))
2647         (widget-push-button-gui widget-editable-list-gui)
2648         child delete insert)
2649     (widget-specify-insert
2650      (save-excursion
2651        (and (widget-get widget :indent)
2652             (insert-char ?  (widget-get widget :indent)))
2653        (insert (widget-get widget :entry-format)))
2654      ;; Parse % escapes in format.
2655      (while (re-search-forward "%\\(.\\)" nil t)
2656        (let ((escape (aref (match-string 1) 0)))
2657          (replace-match "" t t)
2658          (cond ((eq escape ?%)
2659                 (insert "%"))
2660                ((eq escape ?i)
2661                 (setq insert (apply 'widget-create-child-and-convert
2662                                     widget 'insert-button
2663                                     (widget-get widget :insert-button-args))))
2664                ((eq escape ?d)
2665                 (setq delete (apply 'widget-create-child-and-convert
2666                                     widget 'delete-button
2667                                     (widget-get widget :delete-button-args))))
2668                ((eq escape ?v)
2669                 (if conv
2670                     (setq child (widget-create-child-value
2671                                  widget type value))
2672                   (setq child (widget-create-child widget type))))
2673                (t
2674                 (error "Unknown escape `%c'" escape)))))
2675      (widget-put widget
2676                  :buttons (cons delete
2677                                 (cons insert
2678                                       (widget-get widget :buttons))))
2679      (let ((entry-from (copy-marker (point-min)))
2680            (entry-to (copy-marker (point-max))))
2681        (set-marker-insertion-type entry-from t)
2682        (set-marker-insertion-type entry-to nil)
2683        (widget-put child :entry-from entry-from)
2684        (widget-put child :entry-to entry-to)))
2685     (widget-put insert :widget child)
2686     (widget-put delete :widget child)
2687     child))
2688
2689 ;;; The `group' Widget.
2690
2691 (define-widget 'group 'default
2692   "A widget which group other widgets inside."
2693   :convert-widget 'widget-types-convert-widget
2694   :format "%v"
2695   :value-create 'widget-group-value-create
2696   :value-delete 'widget-children-value-delete
2697   :value-get 'widget-editable-list-value-get
2698   :validate 'widget-children-validate
2699   :match 'widget-group-match
2700   :match-inline 'widget-group-match-inline)
2701
2702 (defun widget-group-value-create (widget)
2703   ;; Create each component.
2704   (let ((args (widget-get widget :args))
2705         (value (widget-get widget :value))
2706         arg answer children)
2707     (while args
2708       (setq arg (car args)
2709             args (cdr args)
2710             answer (widget-match-inline arg value)
2711             value (cdr answer))
2712       (and (eq (preceding-char) ?\n)
2713            (widget-get widget :indent)
2714            (insert-char ?  (widget-get widget :indent)))
2715       (push (cond ((null answer)
2716                    (widget-create-child widget arg))
2717                   ((widget-get arg :inline)
2718                    (widget-create-child-value widget arg  (car answer)))
2719                   (t
2720                    (widget-create-child-value widget arg  (car (car answer)))))
2721             children))
2722     (widget-put widget :children (nreverse children))))
2723
2724 (defun widget-group-match (widget values)
2725   ;; Match if the components match.
2726   (and (listp values)
2727        (let ((match (widget-group-match-inline widget values)))
2728          (and match (null (cdr match))))))
2729
2730 (defun widget-group-match-inline (widget vals)
2731   ;; Match if the components match.
2732   (let ((args (widget-get widget :args))
2733         argument answer found)
2734     (while args
2735       (setq argument (car args)
2736             args (cdr args)
2737             answer (widget-match-inline argument vals))
2738       (if answer
2739           (setq vals (cdr answer)
2740                 found (append found (car answer)))
2741         (setq vals nil
2742               args nil)))
2743     (if answer
2744         (cons found vals)
2745       nil)))
2746
2747 ;;; The `visibility' Widget.
2748
2749 (define-widget 'visibility 'item
2750   "An indicator and manipulator for hidden items."
2751   :format "%[%v%]"
2752   :button-prefix ""
2753   :button-suffix ""
2754   :on "Hide"
2755   :off "Show"
2756   :value-create 'widget-visibility-value-create
2757   :action 'widget-toggle-action
2758   :match (lambda (widget value) t))
2759
2760 (defun widget-visibility-value-create (widget)
2761   ;; Insert text representing the `on' and `off' states.
2762   (let ((on (widget-get widget :on))
2763         (off (widget-get widget :off)))
2764     (if on
2765         (setq on (concat widget-push-button-prefix
2766                          on
2767                          widget-push-button-suffix))
2768       (setq on ""))
2769     (if off
2770         (setq off (concat widget-push-button-prefix
2771                           off
2772                           widget-push-button-suffix))
2773       (setq off ""))
2774     (if (widget-value widget)
2775         (widget-glyph-insert widget on "down" "down-pushed")
2776       (widget-glyph-insert widget off "right" "right-pushed"))))
2777
2778 ;;; The `documentation-link' Widget.
2779 ;;
2780 ;; This is a helper widget for `documentation-string'.
2781
2782 (define-widget 'documentation-link 'link
2783   "Link type used in documentation strings."
2784   :tab-order -1
2785   :help-echo 'widget-documentation-link-echo-help
2786   :action 'widget-documentation-link-action)
2787
2788 (defun widget-documentation-link-echo-help (widget)
2789   "Tell what this link will describe."
2790   (concat "Describe the `" (widget-get widget :value) "' symbol."))
2791
2792 (defun widget-documentation-link-action (widget &optional event)
2793   "Display documentation for WIDGET's value.  Ignore optional argument EVENT."
2794   (let* ((string (widget-get widget :value))
2795          (symbol (intern string)))
2796     (if (and (fboundp symbol) (boundp symbol))
2797         ;; If there are two doc strings, give the user a way to pick one.
2798         (apropos (concat "\\`" (regexp-quote string) "\\'"))
2799       (if (fboundp symbol)
2800           (describe-function symbol)
2801         (describe-variable symbol)))))
2802
2803 (defcustom widget-documentation-links t
2804   "Add hyperlinks to documentation strings when non-nil."
2805   :type 'boolean
2806   :group 'widget-documentation)
2807
2808 (defcustom widget-documentation-link-regexp "`\\([^\n`' ]+\\)'"
2809   "Regexp for matching potential links in documentation strings.
2810 The first group should be the link itself."
2811   :type 'regexp
2812   :group 'widget-documentation)
2813
2814 (defcustom widget-documentation-link-p 'intern-soft
2815   "Predicate used to test if a string is useful as a link.
2816 The value should be a function.  The function will be called one
2817 argument, a string, and should return non-nil if there should be a
2818 link for that string."
2819   :type 'function
2820   :options '(widget-documentation-link-p)
2821   :group 'widget-documentation)
2822
2823 (defcustom widget-documentation-link-type 'documentation-link
2824   "Widget type used for links in documentation strings."
2825   :type 'symbol
2826   :group 'widget-documentation)
2827
2828 (defun widget-documentation-link-add (widget from to)
2829   (widget-specify-doc widget from to)
2830   (when widget-documentation-links
2831     (let ((regexp widget-documentation-link-regexp)
2832           (predicate widget-documentation-link-p)
2833           (type widget-documentation-link-type)
2834           (buttons (widget-get widget :buttons)))
2835       (save-excursion
2836         (goto-char from)
2837         (while (re-search-forward regexp to t)
2838           (let ((name (match-string 1))
2839                 (begin (match-beginning 1))
2840                 (end (match-end 1)))
2841             (when (funcall predicate name)
2842               (push (widget-convert-button type begin end :value name)
2843                     buttons)))))
2844       (widget-put widget :buttons buttons)))
2845   (let ((indent (widget-get widget :indent)))
2846     (when (and indent (not (zerop indent)))
2847       (save-excursion
2848         (save-restriction
2849           (narrow-to-region from to)
2850           (goto-char (point-min))
2851           (while (search-forward "\n" nil t)
2852             (insert-char ?\  indent)))))))
2853
2854 ;;; The `documentation-string' Widget.
2855
2856 (define-widget 'documentation-string 'item
2857   "A documentation string."
2858   :format "%v"
2859   :action 'widget-documentation-string-action
2860   :value-delete 'widget-children-value-delete
2861   :value-create 'widget-documentation-string-value-create)
2862
2863 (defun widget-documentation-string-value-create (widget)
2864   ;; Insert documentation string.
2865   (let ((doc (widget-value widget))
2866         (indent (widget-get widget :indent))
2867         (shown (widget-get (widget-get widget :parent) :documentation-shown))
2868         (start (point)))
2869     (if (string-match "\n" doc)
2870         (let ((before (substring doc 0 (match-beginning 0)))
2871               (after (substring doc (match-beginning 0)))
2872               buttons)
2873           (insert before " ")
2874           (widget-documentation-link-add widget start (point))
2875           (push (widget-create-child-and-convert
2876                  widget 'visibility
2877                  :help-echo "Show or hide rest of the documentation."
2878                  :off "More"
2879                  :action 'widget-parent-action
2880                  shown)
2881                 buttons)
2882           (when shown
2883             (setq start (point))
2884             (when (and indent (not (zerop indent)))
2885               (insert-char ?\  indent))
2886             (insert after)
2887             (widget-documentation-link-add widget start (point)))
2888           (widget-put widget :buttons buttons))
2889       (insert doc)
2890       (widget-documentation-link-add widget start (point))))
2891   (insert "\n"))
2892
2893 (defun widget-documentation-string-action (widget &rest ignore)
2894   ;; Toggle documentation.
2895   (let ((parent (widget-get widget :parent)))
2896     (widget-put parent :documentation-shown
2897                 (not (widget-get parent :documentation-shown))))
2898   ;; Redraw.
2899   (widget-value-set widget (widget-value widget)))
2900
2901 ;;; The Sexp Widgets.
2902
2903 (define-widget 'const 'item
2904   "An immutable sexp."
2905   :prompt-value 'widget-const-prompt-value
2906   :format "%t\n%d")
2907
2908 (defun widget-const-prompt-value (widget prompt value unbound)
2909   ;; Return the value of the const.
2910   (widget-value widget))
2911
2912 (define-widget 'function-item 'const
2913   "An immutable function name."
2914   :format "%v\n%h"
2915   :documentation-property (lambda (symbol)
2916                             (condition-case nil
2917                                 (documentation symbol t)
2918                               (error nil))))
2919
2920 (define-widget 'variable-item 'const
2921   "An immutable variable name."
2922   :format "%v\n%h"
2923   :documentation-property 'variable-documentation)
2924
2925 (defvar widget-string-prompt-value-history nil
2926   "History of input to `widget-string-prompt-value'.")
2927
2928 (define-widget 'string 'editable-field
2929   "A string"
2930   :tag "String"
2931   :format "%{%t%}: %v"
2932   :complete-function 'ispell-complete-word
2933   :prompt-history 'widget-string-prompt-value-history)
2934
2935 (define-widget 'regexp 'string
2936   "A regular expression."
2937   :match 'widget-regexp-match
2938   :validate 'widget-regexp-validate
2939   ;; Doesn't work well with terminating newline.
2940   ;; :value-face 'widget-single-line-field-face
2941   :tag "Regexp")
2942
2943 (defun widget-regexp-match (widget value)
2944   ;; Match valid regexps.
2945   (and (stringp value)
2946        (condition-case nil
2947            (prog1 t
2948              (string-match value ""))
2949          (error nil))))
2950
2951 (defun widget-regexp-validate (widget)
2952   "Check that the value of WIDGET is a valid regexp."
2953   (let ((val (widget-value widget)))
2954     (condition-case data
2955         (prog1 nil
2956           (string-match val ""))
2957       (error (widget-put widget :error (error-message-string data))
2958              widget))))
2959
2960 (define-widget 'file 'string
2961   "A file widget.
2962 It will read a file name from the minibuffer when invoked."
2963   :complete-function 'widget-file-complete
2964   :prompt-value 'widget-file-prompt-value
2965   :format "%{%t%}: %v"
2966   ;; Doesn't work well with terminating newline.
2967   ;; :value-face 'widget-single-line-field-face
2968   :tag "File")
2969
2970 (defun widget-file-complete ()
2971   "Perform completion on file name preceding point."
2972   (interactive)
2973   (let* ((end (point))
2974          (beg (save-excursion
2975                 (skip-chars-backward "^ ")
2976                 (point)))
2977          (pattern (buffer-substring beg end))
2978          (name-part (file-name-nondirectory pattern))
2979          (directory (file-name-directory pattern))
2980          (completion (file-name-completion name-part directory)))
2981     (cond ((eq completion t))
2982           ((null completion)
2983            (message "Can't find completion for \"%s\"" pattern)
2984            (ding))
2985           ((not (string= name-part completion))
2986            (delete-region beg end)
2987            (insert (expand-file-name completion directory)))
2988           (t
2989            (message "Making completion list...")
2990            (let ((list (file-name-all-completions name-part directory)))
2991              (setq list (sort list 'string<))
2992              (with-output-to-temp-buffer "*Completions*"
2993                (display-completion-list list)))
2994            (message "Making completion list...%s" "done")))))
2995
2996 (defun widget-file-prompt-value (widget prompt value unbound)
2997   ;; Read file from minibuffer.
2998   (abbreviate-file-name
2999    (if unbound
3000        (read-file-name prompt)
3001      (let ((prompt2 (format "%s (default %s) " prompt value))
3002            (dir (file-name-directory value))
3003            (file (file-name-nondirectory value))
3004            (must-match (widget-get widget :must-match)))
3005        (read-file-name prompt2 dir nil must-match file)))))
3006
3007 ;;;(defun widget-file-action (widget &optional event)
3008 ;;;  ;; Read a file name from the minibuffer.
3009 ;;;  (let* ((value (widget-value widget))
3010 ;;;      (dir (file-name-directory value))
3011 ;;;      (file (file-name-nondirectory value))
3012 ;;;      (menu-tag (widget-apply widget :menu-tag-get))
3013 ;;;      (must-match (widget-get widget :must-match))
3014 ;;;      (answer (read-file-name (concat menu-tag ": (default `" value "') ")
3015 ;;;                              dir nil must-match file)))
3016 ;;;    (widget-value-set widget (abbreviate-file-name answer))
3017 ;;;    (widget-setup)
3018 ;;;    (widget-apply widget :notify widget event)))
3019
3020 (define-widget 'directory 'file
3021   "A directory widget.
3022 It will read a directory name from the minibuffer when invoked."
3023   :tag "Directory")
3024
3025 (defvar widget-symbol-prompt-value-history nil
3026   "History of input to `widget-symbol-prompt-value'.")
3027
3028 (define-widget 'symbol 'editable-field
3029   "A lisp symbol."
3030   :value nil
3031   :tag "Symbol"
3032   :format "%{%t%}: %v"
3033   :match (lambda (widget value) (symbolp value))
3034   :complete-function 'lisp-complete-symbol
3035   :prompt-internal 'widget-symbol-prompt-internal
3036   :prompt-match 'symbolp
3037   :prompt-history 'widget-symbol-prompt-value-history
3038   :value-to-internal (lambda (widget value)
3039                        (if (symbolp value)
3040                            (symbol-name value)
3041                          value))
3042   :value-to-external (lambda (widget value)
3043                        (if (stringp value)
3044                            (intern value)
3045                          value)))
3046
3047 (defun widget-symbol-prompt-internal (widget prompt initial history)
3048   ;; Read file from minibuffer.
3049   (let ((answer (completing-read prompt obarray
3050                                  (widget-get widget :prompt-match)
3051                                  nil initial history)))
3052     (if (and (stringp answer)
3053              (not (zerop (length answer))))
3054         answer
3055       (error "No value"))))
3056
3057 (defvar widget-function-prompt-value-history nil
3058   "History of input to `widget-function-prompt-value'.")
3059
3060 (define-widget 'function 'sexp
3061   "A lisp function."
3062   :complete-function 'lisp-complete-symbol
3063   :prompt-value 'widget-field-prompt-value
3064   :prompt-internal 'widget-symbol-prompt-internal
3065   :prompt-match 'fboundp
3066   :prompt-history 'widget-function-prompt-value-history
3067   :action 'widget-field-action
3068   :tag "Function")
3069
3070 (defvar widget-variable-prompt-value-history nil
3071   "History of input to `widget-variable-prompt-value'.")
3072
3073 (define-widget 'variable 'symbol
3074   ;; Should complete on variables.
3075   "A lisp variable."
3076   :prompt-match 'boundp
3077   :prompt-history 'widget-variable-prompt-value-history
3078   :tag "Variable")
3079
3080 (when (featurep 'mule)
3081   (defvar widget-coding-system-prompt-value-history nil
3082     "History of input to `widget-coding-system-prompt-value'.")
3083
3084   (define-widget 'coding-system 'symbol
3085     "A MULE coding-system."
3086     :format "%{%t%}: %v"
3087     :tag "Coding system"
3088     :prompt-history 'widget-coding-system-prompt-value-history
3089     :prompt-value 'widget-coding-system-prompt-value
3090     :action 'widget-coding-system-action)
3091
3092   (defun widget-coding-system-prompt-value (widget prompt value unbound)
3093     ;; Read coding-system from minibuffer.
3094     (intern
3095      (completing-read (format "%s (default %s) " prompt value)
3096                       (mapcar (function
3097                                (lambda (sym)
3098                                  (list (symbol-name sym))
3099                                  ))
3100                               (coding-system-list)))))
3101
3102   (defun widget-coding-system-action (widget &optional event)
3103     ;; Read a file name from the minibuffer.
3104     (let ((answer
3105            (widget-coding-system-prompt-value
3106             widget
3107             (widget-apply widget :menu-tag-get)
3108             (widget-value widget)
3109             t)))
3110       (widget-value-set widget answer)
3111       (widget-apply widget :notify widget event)
3112       (widget-setup)))
3113   )
3114
3115 (define-widget 'sexp 'editable-field
3116   "An arbitrary lisp expression."
3117   :tag "Lisp expression"
3118   :format "%{%t%}: %v"
3119   :value nil
3120   :validate 'widget-sexp-validate
3121   :match (lambda (widget value) t)
3122   :value-to-internal 'widget-sexp-value-to-internal
3123   :value-to-external (lambda (widget value) (read value))
3124   :prompt-history 'widget-sexp-prompt-value-history
3125   :prompt-value 'widget-sexp-prompt-value)
3126
3127 (defun widget-sexp-value-to-internal (widget value)
3128   ;; Use pp for printer representation.
3129   (let ((pp (if (symbolp value)
3130                 (prin1-to-string value)
3131               (pp-to-string value))))
3132     (while (string-match "\n\\'" pp)
3133       (setq pp (substring pp 0 -1)))
3134     (if (or (string-match "\n\\'" pp)
3135             (> (length pp) 40))
3136         (concat "\n" pp)
3137       pp)))
3138
3139 (defun widget-sexp-validate (widget)
3140   ;; Valid if we can read the string and there is no junk left after it.
3141   (save-excursion
3142     (let ((buffer (set-buffer (get-buffer-create " *Widget Scratch*"))))
3143       (erase-buffer)
3144       (insert (widget-apply widget :value-get))
3145       (goto-char (point-min))
3146       (condition-case data
3147           (let ((value (read buffer)))
3148             (if (eobp)
3149                 (if (widget-apply widget :match value)
3150                     nil
3151                   (widget-put widget :error (widget-get widget :type-error))
3152                   widget)
3153               (widget-put widget
3154                           :error (format "Junk at end of expression: %s"
3155                                          (buffer-substring (point)
3156                                                            (point-max))))
3157               widget))
3158         (error (widget-put widget :error (error-message-string data))
3159                widget)))))
3160
3161 (defvar widget-sexp-prompt-value-history nil
3162   "History of input to `widget-sexp-prompt-value'.")
3163
3164 (defun widget-sexp-prompt-value (widget prompt value unbound)
3165   ;; Read an arbitrary sexp.
3166   (let ((found (read-string prompt
3167                             (if unbound nil (cons (prin1-to-string value) 0))
3168                             (widget-get widget :prompt-history))))
3169     (save-excursion
3170       (let ((buffer (set-buffer (get-buffer-create " *Widget Scratch*"))))
3171         (erase-buffer)
3172         (insert found)
3173         (goto-char (point-min))
3174         (let ((answer (read buffer)))
3175           (unless (eobp)
3176             (error "Junk at end of expression: %s"
3177                    (buffer-substring (point) (point-max))))
3178           answer)))))
3179
3180 (define-widget 'restricted-sexp 'sexp
3181   "A Lisp expression restricted to values that match.
3182 To use this type, you must define :match or :match-alternatives."
3183   :type-error "The specified value is not valid"
3184   :match 'widget-restricted-sexp-match
3185   :value-to-internal (lambda (widget value)
3186                        (if (widget-apply widget :match value)
3187                            (prin1-to-string value)
3188                          value)))
3189
3190 (defun widget-restricted-sexp-match (widget value)
3191   (let ((alternatives (widget-get widget :match-alternatives))
3192         matched)
3193     (while (and alternatives (not matched))
3194       (if (cond ((functionp (car alternatives))
3195                  (funcall (car alternatives) value))
3196                 ((and (consp (car alternatives))
3197                       (eq (car (car alternatives)) 'quote))
3198                  (eq value (nth 1 (car alternatives)))))
3199           (setq matched t))
3200       (setq alternatives (cdr alternatives)))
3201     matched))
3202
3203 (define-widget 'integer 'restricted-sexp
3204   "An integer."
3205   :tag "Integer"
3206   :value 0
3207   :type-error "This field should contain an integer"
3208   :match-alternatives '(integerp))
3209
3210 (define-widget 'number 'restricted-sexp
3211   "A floating point number."
3212   :tag "Number"
3213   :value 0.0
3214   :type-error "This field should contain a number"
3215   :match-alternatives '(numberp))
3216
3217 (define-widget 'character 'editable-field
3218   "A character."
3219   :tag "Character"
3220   :value 0
3221   :size 1
3222   :format "%{%t%}: %v\n"
3223   :valid-regexp "\\`.\\'"
3224   :error "This field should contain a single character"
3225   :value-to-internal (lambda (widget value)
3226                        (if (stringp value)
3227                            value
3228                          (char-to-string value)))
3229   :value-to-external (lambda (widget value)
3230                        (if (stringp value)
3231                            (aref value 0)
3232                          value))
3233   :match (lambda (widget value)
3234            (if (fboundp 'characterp)
3235                (characterp value)
3236              (integerp value))))
3237
3238 (define-widget 'list 'group
3239   "A lisp list."
3240   :tag "List"
3241   :format "%{%t%}:\n%v")
3242
3243 (define-widget 'vector 'group
3244   "A lisp vector."
3245   :tag "Vector"
3246   :format "%{%t%}:\n%v"
3247   :match 'widget-vector-match
3248   :value-to-internal (lambda (widget value) (append value nil))
3249   :value-to-external (lambda (widget value) (apply 'vector value)))
3250
3251 (defun widget-vector-match (widget value)
3252   (and (vectorp value)
3253        (widget-group-match widget
3254                            (widget-apply widget :value-to-internal value))))
3255
3256 (define-widget 'cons 'group
3257   "A cons-cell."
3258   :tag "Cons-cell"
3259   :format "%{%t%}:\n%v"
3260   :match 'widget-cons-match
3261   :value-to-internal (lambda (widget value)
3262                        (list (car value) (cdr value)))
3263   :value-to-external (lambda (widget value)
3264                        (cons (nth 0 value) (nth 1 value))))
3265
3266 (defun widget-cons-match (widget value)
3267   (and (consp value)
3268        (widget-group-match widget
3269                            (widget-apply widget :value-to-internal value))))
3270
3271 (define-widget 'choice 'menu-choice
3272   "A union of several sexp types."
3273   :tag "Choice"
3274   :format "%{%t%}: %[Value Menu%] %v"
3275   :button-prefix 'widget-push-button-prefix
3276   :button-suffix 'widget-push-button-suffix
3277   :prompt-value 'widget-choice-prompt-value)
3278
3279 (defun widget-choice-prompt-value (widget prompt value unbound)
3280   "Make a choice."
3281   (let ((args (widget-get widget :args))
3282         (completion-ignore-case (widget-get widget :case-fold))
3283         current choices old)
3284     ;; Find the first arg that match VALUE.
3285     (let ((look args))
3286       (while look
3287         (if (widget-apply (car look) :match value)
3288             (setq old (car look)
3289                   look nil)
3290           (setq look (cdr look)))))
3291     ;; Find new choice.
3292     (setq current
3293           (cond ((= (length args) 0)
3294                  nil)
3295                 ((= (length args) 1)
3296                  (nth 0 args))
3297                 ((and (= (length args) 2)
3298                       (memq old args))
3299                  (if (eq old (nth 0 args))
3300                      (nth 1 args)
3301                    (nth 0 args)))
3302                 (t
3303                  (while args
3304                    (setq current (car args)
3305                          args (cdr args))
3306                    (setq choices
3307                          (cons (cons (widget-apply current :menu-tag-get)
3308                                      current)
3309                                choices)))
3310                  (let ((val (completing-read prompt choices nil t)))
3311                    (if (stringp val)
3312                        (let ((try (try-completion val choices)))
3313                          (when (stringp try)
3314                            (setq val try))
3315                          (cdr (assoc val choices)))
3316                      nil)))))
3317     (if current
3318         (widget-prompt-value current prompt nil t)
3319       value)))
3320
3321 (define-widget 'radio 'radio-button-choice
3322   "A union of several sexp types."
3323   :tag "Choice"
3324   :format "%{%t%}:\n%v"
3325   :prompt-value 'widget-choice-prompt-value)
3326
3327 (define-widget 'repeat 'editable-list
3328   "A variable length homogeneous list."
3329   :tag "Repeat"
3330   :format "%{%t%}:\n%v%i\n")
3331
3332 (define-widget 'set 'checklist
3333   "A list of members from a fixed set."
3334   :tag "Set"
3335   :format "%{%t%}:\n%v")
3336
3337 (define-widget 'boolean 'toggle
3338   "To be nil or non-nil, that is the question."
3339   :tag "Boolean"
3340   :prompt-value 'widget-boolean-prompt-value
3341   :button-prefix 'widget-push-button-prefix
3342   :button-suffix 'widget-push-button-suffix
3343   :format "%{%t%}: %[Toggle%]  %v\n"
3344   :on "on (non-nil)"
3345   :off "off (nil)")
3346
3347 (defun widget-boolean-prompt-value (widget prompt value unbound)
3348   ;; Toggle a boolean.
3349   (y-or-n-p prompt))
3350
3351 ;;; The `color' Widget.
3352
3353 (define-widget 'color 'editable-field
3354   "Choose a color name (with sample)."
3355   :format "%t: %v (%{sample%})\n"
3356   :size 10
3357   :tag "Color"
3358   :value "black"
3359   :complete 'widget-color-complete
3360   :sample-face-get 'widget-color-sample-face-get
3361   :notify 'widget-color-notify
3362   :action 'widget-color-action)
3363
3364 (defun widget-color-complete (widget)
3365   "Complete the color in WIDGET."
3366   (let* ((prefix (buffer-substring-no-properties (widget-field-start widget)
3367                                                  (point)))
3368          (list (widget-color-choice-list))
3369          (completion (try-completion prefix list)))
3370     (cond ((eq completion t)
3371            (message "Exact match."))
3372           ((null completion)
3373            (error "Can't find completion for \"%s\"" prefix))
3374           ((not (string-equal prefix completion))
3375            (insert-and-inherit (substring completion (length prefix))))
3376           (t
3377            (message "Making completion list...")
3378            (let ((list (all-completions prefix list nil)))
3379              (with-output-to-temp-buffer "*Completions*"
3380                (display-completion-list list)))
3381            (message "Making completion list...done")))))
3382
3383 (defun widget-color-sample-face-get (widget)
3384   (let* ((value (condition-case nil
3385                     (widget-value widget)
3386                   (error (widget-get widget :value))))
3387          (symbol (intern (concat "fg:" value))))
3388     (if (string-match "XEmacs" emacs-version)
3389         (prog1 symbol
3390           (or (find-face symbol)
3391               (set-face-foreground (make-face symbol) value)))
3392       (condition-case nil
3393           (facemenu-get-face symbol)
3394         (error 'default)))))
3395
3396 (defvar widget-color-choice-list nil)
3397 ;; Variable holding the possible colors.
3398
3399 (defun widget-color-choice-list ()
3400   (unless widget-color-choice-list
3401     (setq widget-color-choice-list
3402           (if (fboundp 'read-color-completion-table)
3403               (read-color-completion-table)
3404             (mapcar '(lambda (color) (list color))
3405                     (x-defined-colors)))))
3406   widget-color-choice-list)
3407
3408 (defvar widget-color-history nil
3409   "History of entered colors")
3410
3411 (defun widget-color-action (widget &optional event)
3412   ;; Prompt for a color.
3413   (let* ((tag (widget-apply widget :menu-tag-get))
3414          (prompt (concat tag ": "))
3415          (value (widget-value widget))
3416          (start (widget-field-start widget))
3417          (pos (cond ((< (point) start)
3418                      0)
3419                     ((> (point) (+ start (length value)))
3420                      (length value))
3421                     (t
3422                      (- (point) start))))
3423          (answer (if (commandp 'read-color)
3424                      (read-color prompt)
3425                    (completing-read (concat tag ": ")
3426                                     (widget-color-choice-list)
3427                                     nil nil
3428                                     (cons value pos)
3429                                     'widget-color-history))))
3430     (unless (zerop (length answer))
3431       (widget-value-set widget answer)
3432       (widget-setup)
3433       (widget-apply widget :notify widget event))))
3434
3435 (defun widget-color-notify (widget child &optional event)
3436   "Update the sample, and notofy the parent."
3437   (overlay-put (widget-get widget :sample-overlay)
3438                'face (widget-apply widget :sample-face-get))
3439   (widget-default-notify widget child event))
3440
3441 ;;; The Help Echo
3442
3443 (defun widget-echo-help-mouse ()
3444   "Display the help message for the widget under the mouse.
3445 Enable with (run-with-idle-timer 1 t 'widget-echo-help-mouse)"
3446   (let* ((pos (mouse-position))
3447          (frame (car pos))
3448          (x (car (cdr pos)))
3449          (y (cdr (cdr pos)))
3450          (win (window-at x y frame))
3451          (where (coordinates-in-window-p (cons x y) win)))
3452     (when (consp where)
3453       (save-window-excursion
3454         (progn ; save-excursion
3455           (select-window win)
3456           (let* ((result (compute-motion (window-start win)
3457                                          '(0 . 0)
3458                                          (window-end win)
3459                                          where
3460                                          (window-width win)
3461                                          (cons (window-hscroll) 0)
3462                                          win)))
3463             (when (and (eq (nth 1 result) x)
3464                        (eq (nth 2 result) y))
3465               (widget-echo-help (nth 0 result))))))))
3466   (unless track-mouse
3467     (setq track-mouse t)
3468     (add-hook 'post-command-hook 'widget-stop-mouse-tracking)))
3469
3470 (defun widget-stop-mouse-tracking (&rest args)
3471   "Stop the mouse tracking done while idle."
3472   (remove-hook 'post-command-hook 'widget-stop-mouse-tracking)
3473   (setq track-mouse nil))
3474
3475 (defun widget-at (pos)
3476   "The button or field at POS."
3477   (or (get-char-property pos 'button)
3478       (get-char-property pos 'field)))
3479
3480 (defun widget-echo-help (pos)
3481   "Display the help echo for widget at POS."
3482   (let* ((widget (widget-at pos))
3483          (help-echo (and widget (widget-get widget :help-echo))))
3484     (cond ((stringp help-echo)
3485            (message "%s" help-echo))
3486           ((and (symbolp help-echo) (fboundp help-echo)
3487                 (stringp (setq help-echo (funcall help-echo widget))))
3488            (message "%s" help-echo)))))
3489
3490 ;;; The End:
3491
3492 (provide 'wid-edit)
3493
3494 ;; wid-edit.el ends here