lisp/paren.el

   1 ;;; paren.el --- highlight matching paren
   2
   3 ;; Copyright (C) 1993, 1996, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: rms@gnu.org
   7 ;; Maintainer: FSF
   8 ;; Keywords: languages, faces
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Put this into your ~/.emacs:
  28
  29 ;;  (show-paren-mode t)
  30
  31 ;; It will display highlighting on whatever paren matches the one
  32 ;; before or after point.
  33
  34 ;;; Code:
  35
  36 (defgroup paren-showing nil
  37   "Showing (un)matching of parens and expressions."
  38   :prefix "show-paren-"
  39   :group 'paren-matching)
  40
  41 ;; This is the overlay used to highlight the matching paren.
  42 (defvar show-paren-overlay nil)
  43 ;; This is the overlay used to highlight the closeparen right before point.
  44 (defvar show-paren-overlay-1 nil)
  45
  46 (defcustom show-paren-style 'parenthesis
  47   "*Style used when showing a matching paren.
  48 Valid styles are `parenthesis' (meaning show the matching paren),
  49 `expression' (meaning show the entire expression enclosed by the paren) and
  50 `mixed' (meaning show the matching paren if it is visible, and the expression
  51 otherwise)."
  52   :type '(choice (const parenthesis) (const expression) (const mixed))
  53   :group 'paren-showing)
  54
  55 (defcustom show-paren-delay
  56   (if (featurep 'lisp-float-type) (/ (float 1) (float 8)) 1)
  57   "*Time in seconds to delay before showing a matching paren."
  58   :type '(number :tag "seconds")
  59   :group 'paren-showing)
  60
  61 (defcustom show-paren-priority 1000
  62   "*Priority of paren highlighting overlays."
  63   :type 'integer
  64   :group 'paren-showing
  65   :version "21.1")
  66
  67 (defcustom show-paren-ring-bell-on-mismatch nil
  68   "*If non-nil, beep if mismatched paren is detected."
  69   :type 'boolean
  70   :group 'paren-showing
  71   :version "20.3")
  72
  73 (defgroup paren-showing-faces nil
  74   "Group for faces of Show Paren mode."
  75   :group 'paren-showing
  76   :group 'faces
  77   :version "22.1")
  78
  79 (defface show-paren-match
  80   '((((class color) (background light))
  81      :background "turquoise")           ; looks OK on tty (becomes cyan)
  82     (((class color) (background dark))
  83      :background "steelblue3")          ; looks OK on tty (becomes blue)
  84     (((background dark))
  85      :background "grey50")
  86     (t
  87      :background "gray"))
  88   "Show Paren mode face used for a matching paren."
  89   :group 'paren-showing-faces)
  90 ;; backward-compatibility alias
  91 (put 'show-paren-match-face 'face-alias 'show-paren-match)
  92
  93 (defface show-paren-mismatch
  94   '((((class color)) (:foreground "white" :background "purple"))
  95     (t (:inverse-video t)))
  96   "Show Paren mode face used for a mismatching paren."
  97   :group 'paren-showing-faces)
  98 ;; backward-compatibility alias
  99 (put 'show-paren-mismatch-face 'face-alias 'show-paren-mismatch)
 100
 101 (defvar show-paren-highlight-openparen t
 102   "*Non-nil turns on openparen highlighting when matching forward.")
 103
 104 (defvar show-paren-idle-timer nil)
 105
 106 ;;;###autoload
 107 (define-minor-mode show-paren-mode
 108   "Toggle Show Paren mode.
 109 With prefix ARG, turn Show Paren mode on if and only if ARG is positive.
 110 Returns the new status of Show Paren mode (non-nil means on).
 111
 112 When Show Paren mode is enabled, any matching parenthesis is highlighted
 113 in `show-paren-style' after `show-paren-delay' seconds of Emacs idle time."
 114   :global t :group 'paren-showing
 115     ;; Enable or disable the mechanism.
 116     ;; First get rid of the old idle timer.
 117     (if show-paren-idle-timer
 118         (cancel-timer show-paren-idle-timer))
 119     (setq show-paren-idle-timer nil)
 120     ;; If show-paren-mode is enabled in some buffer now,
 121     ;; set up a new timer.
 122     (when (memq t (mapcar (lambda (buffer)
 123                             (with-current-buffer buffer
 124                               show-paren-mode))
 125                           (buffer-list)))
 126       (setq show-paren-idle-timer (run-with-idle-timer
 127                                    show-paren-delay t
 128                                    'show-paren-function)))
 129     (unless show-paren-mode
 130       (and show-paren-overlay
 131            (eq (overlay-buffer show-paren-overlay) (current-buffer))
 132            (delete-overlay show-paren-overlay))
 133       (and show-paren-overlay-1
 134            (eq (overlay-buffer show-paren-overlay-1) (current-buffer))
 135            (delete-overlay show-paren-overlay-1))))
 136
 137 ;; Find the place to show, if there is one,
 138 ;; and show it until input arrives.
 139 (defun show-paren-function ()
 140   (if show-paren-mode
 141       (let ((oldpos (point))
 142             (dir (cond ((eq (syntax-class (syntax-after (1- (point)))) 5) -1)
 143                        ((eq (syntax-class (syntax-after (point)))      4) 1)))
 144             pos mismatch face)
 145         ;;
 146         ;; Find the other end of the sexp.
 147         (when dir
 148           (save-excursion
 149             (save-restriction
 150               ;; Determine the range within which to look for a match.
 151               (when blink-matching-paren-distance
 152                 (narrow-to-region
 153                  (max (point-min) (- (point) blink-matching-paren-distance))
 154                  (min (point-max) (+ (point) blink-matching-paren-distance))))
 155               ;; Scan across one sexp within that range.
 156               ;; Errors or nil mean there is a mismatch.
 157               (condition-case ()
 158                   (setq pos (scan-sexps (point) dir))
 159                 (error (setq pos t mismatch t)))
 160               ;; Move back the other way and verify we get back to the
 161               ;; starting point.  If not, these two parens don't really match.
 162               ;; Maybe the one at point is escaped and doesn't really count.
 163               (when (integerp pos)
 164                 (unless (condition-case ()
 165                             (eq (point) (scan-sexps pos (- dir)))
 166                           (error nil))
 167                   (setq pos nil)))
 168               ;; If found a "matching" paren, see if it is the right
 169               ;; kind of paren to match the one we started at.
 170               (when (integerp pos)
 171                 (let ((beg (min pos oldpos)) (end (max pos oldpos)))
 172                   (unless (eq (syntax-class (syntax-after beg)) 8)
 173                     (setq mismatch
 174                           (not (or (eq (char-before end)
 175                                        ;; This can give nil.
 176                                        (cdr (syntax-after beg)))
 177                                    (eq (char-after beg)
 178                                        ;; This can give nil.
 179                                        (cdr (syntax-after (1- end))))
 180                                    ;; The cdr might hold a new paren-class
 181                                    ;; info rather than a matching-char info,
 182                                    ;; in which case the two CDRs should match.
 183                                    (eq (cdr (syntax-after (1- end)))
 184                                        (cdr (syntax-after beg))))))))))))
 185         ;;
 186         ;; Highlight the other end of the sexp, or unhighlight if none.
 187         (if (not pos)
 188             (progn
 189               ;; If not at a paren that has a match,
 190               ;; turn off any previous paren highlighting.
 191               (and show-paren-overlay (overlay-buffer show-paren-overlay)
 192                    (delete-overlay show-paren-overlay))
 193               (and show-paren-overlay-1 (overlay-buffer show-paren-overlay-1)
 194                    (delete-overlay show-paren-overlay-1)))
 195           ;;
 196           ;; Use the correct face.
 197           (if mismatch
 198               (progn
 199                 (if show-paren-ring-bell-on-mismatch
 200                     (beep))
 201                 (setq face 'show-paren-mismatch))
 202             (setq face 'show-paren-match))
 203           ;;
 204           ;; If matching backwards, highlight the closeparen
 205           ;; before point as well as its matching open.
 206           ;; If matching forward, and the openparen is unbalanced,
 207           ;; highlight the paren at point to indicate misbalance.
 208           ;; Otherwise, turn off any such highlighting.
 209           (if (and (not show-paren-highlight-openparen) (= dir 1) (integerp pos))
 210               (when (and show-paren-overlay-1
 211                          (overlay-buffer show-paren-overlay-1))
 212                 (delete-overlay show-paren-overlay-1))
 213             (let ((from (if (= dir 1)
 214                             (point)
 215                           (forward-point -1)))
 216                   (to (if (= dir 1)
 217                           (forward-point 1)
 218                         (point))))
 219               (if show-paren-overlay-1
 220                   (move-overlay show-paren-overlay-1 from to (current-buffer))
 221                 (setq show-paren-overlay-1 (make-overlay from to nil t)))
 222               ;; Always set the overlay face, since it varies.
 223               (overlay-put show-paren-overlay-1 'priority show-paren-priority)
 224               (overlay-put show-paren-overlay-1 'face face)))
 225           ;;
 226           ;; Turn on highlighting for the matching paren, if found.
 227           ;; If it's an unmatched paren, turn off any such highlighting.
 228           (unless (integerp pos)
 229             (delete-overlay show-paren-overlay))
 230           (let ((to (if (or (eq show-paren-style 'expression)
 231                             (and (eq show-paren-style 'mixed)
 232                                  (not (pos-visible-in-window-p pos))))
 233                         (point)
 234                       pos))
 235                 (from (if (or (eq show-paren-style 'expression)
 236                               (and (eq show-paren-style 'mixed)
 237                                    (not (pos-visible-in-window-p pos))))
 238                           pos
 239                         (save-excursion
 240                           (goto-char pos)
 241                           (forward-point (- dir))))))
 242             (if show-paren-overlay
 243                 (move-overlay show-paren-overlay from to (current-buffer))
 244               (setq show-paren-overlay (make-overlay from to nil t))))
 245           ;;
 246           ;; Always set the overlay face, since it varies.
 247           (overlay-put show-paren-overlay 'priority show-paren-priority)
 248           (overlay-put show-paren-overlay 'face face)))
 249     ;; show-paren-mode is nil in this buffer.
 250     (and show-paren-overlay
 251          (delete-overlay show-paren-overlay))
 252     (and show-paren-overlay-1
 253          (delete-overlay show-paren-overlay-1))))
 254
 255 (provide 'paren)
 256
 257 ;; arch-tag: d0969b88-7ac0-4bd0-bd53-e73b892b86a9
 258 ;;; paren.el ends here