lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2000-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Maintainer: John Paul Wallington <jpw@gnu.org>
   7 ;; Created: 2 Dec 2001
   8 ;; Keywords: buffer, convenience
   9 ;; Package: ibuffer
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicitly (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'ibuf-macs)
  38   (require 'cl-lib))
  39
  40 ;;; Utility functions
  41 (defun ibuffer-delete-alist (key alist)
  42   "Delete all entries in ALIST that have a key equal to KEY."
  43   (let (entry)
  44     (while (setq entry (assoc key alist))
  45       (setq alist (delete entry alist)))
  46     alist))
  47
  48 ;; borrowed from Gnus
  49 (defun ibuffer-remove-duplicates (list)
  50   "Return a copy of LIST with duplicate elements removed."
  51   (let ((new nil)
  52         (tail list))
  53     (while tail
  54       (or (member (car tail) new)
  55           (setq new (cons (car tail) new)))
  56       (setq tail (cdr tail)))
  57     (nreverse new)))
  58
  59 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  60   (let ((hip-crowd nil)
  61         (lamers nil))
  62     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  63       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  64           (push ibuffer-split-list-elt hip-crowd)
  65         (push ibuffer-split-list-elt lamers)))
  66     ;; Too bad Emacs Lisp doesn't have multiple values.
  67     (list (nreverse hip-crowd) (nreverse lamers))))
  68
  69 (defcustom ibuffer-never-show-predicates nil
  70   "A list of predicates (a regexp or function) for buffers not to display.
  71 If a regexp, then it will be matched against the buffer's name.
  72 If a function, it will be called with the buffer as an argument, and
  73 should return non-nil if this buffer should not be shown."
  74   :type '(repeat (choice regexp function))
  75   :require 'ibuf-ext
  76   :group 'ibuffer)
  77
  78 (defcustom ibuffer-always-show-predicates nil
  79   "A list of predicates (a regexp or function) for buffers to always display.
  80 If a regexp, then it will be matched against the buffer's name.
  81 If a function, it will be called with the buffer as an argument, and
  82 should return non-nil if this buffer should be shown.
  83 Note that buffers matching one of these predicates will be shown
  84 regardless of any active filters in this buffer."
  85   :type '(repeat (choice regexp function))
  86   :group 'ibuffer)
  87
  88 (defvar ibuffer-tmp-hide-regexps nil
  89   "A list of regexps which should match buffer names to not show.")
  90
  91 (defvar ibuffer-tmp-show-regexps nil
  92   "A list of regexps which should match buffer names to always show.")
  93
  94 (defvar ibuffer-auto-buffers-changed nil)
  95
  96 (defcustom ibuffer-saved-filters '(("gnus"
  97                                     ((or (mode . message-mode)
  98                                          (mode . mail-mode)
  99                                          (mode . gnus-group-mode)
 100                                          (mode . gnus-summary-mode)
 101                                          (mode . gnus-article-mode))))
 102                                    ("programming"
 103                                     ((or (mode . emacs-lisp-mode)
 104                                          (mode . cperl-mode)
 105                                          (mode . c-mode)
 106                                          (mode . java-mode)
 107                                          (mode . idl-mode)
 108                                          (mode . lisp-mode)))))
 109
 110   "An alist of filter qualifiers to switch between.
 111
 112 This variable should look like ((\"STRING\" QUALIFIERS)
 113                                 (\"STRING\" QUALIFIERS) ...), where
 114 QUALIFIERS is a list of the same form as
 115 `ibuffer-filtering-qualifiers'.
 116 See also the variables `ibuffer-filtering-qualifiers',
 117 `ibuffer-filtering-alist', and the functions
 118 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 119   :type '(repeat sexp)
 120   :group 'ibuffer)
 121
 122 (defvar ibuffer-filtering-qualifiers nil
 123   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 124 See also `ibuffer-filtering-alist'.")
 125
 126 ;; This is now frobbed by `define-ibuffer-filter'.
 127 (defvar ibuffer-filtering-alist nil
 128   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 129
 130 You most likely do not want to modify this variable directly; see
 131 `define-ibuffer-filter'.
 132
 133 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 134 displaying information to the user.  FUNCTION is given a buffer and
 135 the value of the qualifier, and returns non-nil if and only if the
 136 buffer should be displayed.")
 137
 138 (defcustom ibuffer-filter-format-alist nil
 139   "An alist which has special formats used when a filter is active.
 140 The contents of this variable should look like:
 141  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 142
 143 For example, suppose that when you add a filter for buffers whose
 144 major mode is `emacs-lisp-mode', you only want to see the mark and the
 145 name of the buffer.  You could accomplish that by adding:
 146  (mode ((mark \" \" name)))
 147 to this variable."
 148   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 149                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 150   :group 'ibuffer)
 151
 152 (defvar ibuffer-cached-filter-formats nil)
 153 (defvar ibuffer-compiled-filter-formats nil)
 154
 155 (defvar ibuffer-filter-groups nil
 156   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 157 The SYMBOL should be one from `ibuffer-filtering-alist'.
 158 The QUALIFIER should be the same as QUALIFIER in
 159 `ibuffer-filtering-qualifiers'.")
 160
 161 (defcustom ibuffer-show-empty-filter-groups t
 162   "If non-nil, then show the names of filter groups which are empty."
 163   :type 'boolean
 164   :group 'ibuffer)
 165
 166 (defcustom ibuffer-saved-filter-groups nil
 167   "An alist of filtering groups to switch between.
 168
 169 This variable should look like ((\"STRING\" QUALIFIERS)
 170                                 (\"STRING\" QUALIFIERS) ...), where
 171 QUALIFIERS is a list of the same form as
 172 `ibuffer-filtering-qualifiers'.
 173
 174 See also the variables `ibuffer-filter-groups',
 175 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 176 functions `ibuffer-switch-to-saved-filter-groups',
 177 `ibuffer-save-filter-groups'."
 178   :type '(repeat sexp)
 179   :group 'ibuffer)
 180
 181 (defvar ibuffer-hidden-filter-groups nil
 182   "A list of filtering groups which are currently hidden.")
 183
 184 (defvar ibuffer-filter-group-kill-ring nil)
 185
 186 (defcustom ibuffer-old-time 72
 187   "The number of hours before a buffer is considered \"old\"."
 188   :type '(choice (const :tag "72 hours (3 days)" 72)
 189                  (const :tag "48 hours (2 days)" 48)
 190                  (const :tag "24 hours (1 day)" 24)
 191                  (integer :tag "hours"))
 192   :group 'ibuffer)
 193
 194 (defcustom ibuffer-save-with-custom t
 195   "If non-nil, then use Custom to save interactively changed variables.
 196 Currently, this only applies to `ibuffer-saved-filters' and
 197 `ibuffer-saved-filter-groups'."
 198   :type 'boolean
 199   :group 'ibuffer)
 200
 201 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 202   (or
 203    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 204    (and (not
 205          (or
 206           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 207           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 208         (or all
 209             (not
 210              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 211         (or ibuffer-view-ibuffer
 212             (and ibuffer-buf
 213                  (not (eq ibuffer-buf buf))))
 214         (or
 215          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 216          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 217
 218 ;;;###autoload
 219 (define-minor-mode ibuffer-auto-mode
 220   "Toggle use of Ibuffer's auto-update facility (Ibuffer Auto mode).
 221 With a prefix argument ARG, enable Ibuffer Auto mode if ARG is
 222 positive, and disable it otherwise.  If called from Lisp, enable
 223 the mode if ARG is omitted or nil."
 224   nil nil nil
 225   (unless (derived-mode-p 'ibuffer-mode)
 226     (error "This buffer is not in Ibuffer mode"))
 227   (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed) ; Initialize state vector
 228   (add-hook 'post-command-hook 'ibuffer-auto-update-changed))
 229
 230 (defun ibuffer-auto-update-changed ()
 231   (when (frame-or-buffer-changed-p 'ibuffer-auto-buffers-changed)
 232     (dolist (buf (buffer-list))
 233       (ignore-errors
 234         (with-current-buffer buf
 235           (when (and ibuffer-auto-mode
 236                      (derived-mode-p 'ibuffer-mode))
 237             (ibuffer-update nil t)))))))
 238
 239 ;;;###autoload
 240 (defun ibuffer-mouse-filter-by-mode (event)
 241   "Enable or disable filtering by the major mode chosen via mouse."
 242   (interactive "e")
 243   (ibuffer-interactive-filter-by-mode event))
 244
 245 ;;;###autoload
 246 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 247   "Enable or disable filtering by the major mode at point."
 248   (interactive "d")
 249   (if (eventp event-or-point)
 250       (posn-set-point (event-end event-or-point))
 251     (goto-char event-or-point))
 252   (let ((buf (ibuffer-current-buffer)))
 253     (if (assq 'mode ibuffer-filtering-qualifiers)
 254         (setq ibuffer-filtering-qualifiers
 255               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 256       (ibuffer-push-filter (cons 'mode (buffer-local-value 'major-mode buf)))))
 257   (ibuffer-update nil t))
 258
 259 ;;;###autoload
 260 (defun ibuffer-mouse-toggle-filter-group (event)
 261   "Toggle the display status of the filter group chosen with the mouse."
 262   (interactive "e")
 263   (ibuffer-toggle-filter-group-1 (save-excursion
 264                                    (mouse-set-point event)
 265                                    (point))))
 266
 267 ;;;###autoload
 268 (defun ibuffer-toggle-filter-group ()
 269   "Toggle the display status of the filter group on this line."
 270   (interactive)
 271   (ibuffer-toggle-filter-group-1 (point)))
 272
 273 (defun ibuffer-toggle-filter-group-1 (posn)
 274   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 275     (unless (stringp name)
 276       (error "No filtering group name present"))
 277     (if (member name ibuffer-hidden-filter-groups)
 278         (setq ibuffer-hidden-filter-groups
 279               (delete name ibuffer-hidden-filter-groups))
 280       (push name ibuffer-hidden-filter-groups))
 281     (ibuffer-update nil t)))
 282
 283 ;;;###autoload
 284 (defun ibuffer-forward-filter-group (&optional count)
 285   "Move point forwards by COUNT filtering groups."
 286   (interactive "P")
 287   (unless count
 288     (setq count 1))
 289   (when (> count 0)
 290     (when (get-text-property (point) 'ibuffer-filter-group-name)
 291       (goto-char (next-single-property-change
 292                   (point) 'ibuffer-filter-group-name
 293                   nil (point-max))))
 294     (goto-char (next-single-property-change
 295                 (point) 'ibuffer-filter-group-name
 296                 nil (point-max)))
 297     (ibuffer-forward-filter-group (1- count)))
 298   (ibuffer-forward-line 0))
 299
 300 ;;;###autoload
 301 (defun ibuffer-backward-filter-group (&optional count)
 302   "Move point backwards by COUNT filtering groups."
 303   (interactive "P")
 304   (unless count
 305     (setq count 1))
 306   (when (> count 0)
 307     (when (get-text-property (point) 'ibuffer-filter-group-name)
 308       (goto-char (previous-single-property-change
 309                   (point) 'ibuffer-filter-group-name
 310                   nil (point-min))))
 311     (goto-char (previous-single-property-change
 312                 (point) 'ibuffer-filter-group-name
 313                 nil (point-min)))
 314     (ibuffer-backward-filter-group (1- count)))
 315   (when (= (point) (point-min))
 316     (goto-char (point-max))
 317     (ibuffer-backward-filter-group 1))
 318   (ibuffer-forward-line 0))
 319
 320 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext")
 321 (define-ibuffer-op shell-command-pipe (command)
 322   "Pipe the contents of each marked buffer to shell command COMMAND."
 323   (:interactive "sPipe to shell command: "
 324    :opstring "Shell command executed on"
 325    :modifier-p nil)
 326   (shell-command-on-region
 327    (point-min) (point-max) command
 328    (get-buffer-create "* ibuffer-shell-output*")))
 329
 330 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext")
 331 (define-ibuffer-op shell-command-pipe-replace (command)
 332   "Replace the contents of marked buffers with output of pipe to COMMAND."
 333   (:interactive "sPipe to shell command (replace): "
 334    :opstring "Buffer contents replaced in"
 335    :active-opstring "replace buffer contents in"
 336    :dangerous t
 337    :modifier-p t)
 338   (with-current-buffer buf
 339     (shell-command-on-region (point-min) (point-max)
 340                              command nil t)))
 341
 342 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext")
 343 (define-ibuffer-op shell-command-file (command)
 344   "Run shell command COMMAND separately on files of marked buffers."
 345   (:interactive "sShell command on buffer's file: "
 346    :opstring "Shell command executed on"
 347    :modifier-p nil)
 348   (shell-command (concat command " "
 349                          (shell-quote-argument
 350                           (if buffer-file-name
 351                               buffer-file-name
 352                             (make-temp-file
 353                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 354
 355 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext")
 356 (define-ibuffer-op eval (form)
 357   "Evaluate FORM in each of the buffers.
 358 Does not display the buffer during evaluation. See
 359 `ibuffer-do-view-and-eval' for that."
 360   (:interactive
 361    (list
 362     (read-from-minibuffer
 363      "Eval in buffers (form): "
 364      nil read-expression-map t 'read-expression-history))
 365    :opstring "evaluated in"
 366    :modifier-p :maybe)
 367   (eval form))
 368
 369 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext")
 370 (define-ibuffer-op view-and-eval (form)
 371   "Evaluate FORM while displaying each of the marked buffers.
 372 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 373   (:interactive
 374    (list
 375     (read-from-minibuffer
 376      "Eval viewing in buffers (form): "
 377      nil read-expression-map t 'read-expression-history))
 378    :opstring "evaluated in"
 379    :complex t
 380    :modifier-p :maybe)
 381   (let ((ibuffer-buf (current-buffer)))
 382     (unwind-protect
 383         (progn
 384           (switch-to-buffer buf)
 385           (eval form))
 386       (switch-to-buffer ibuffer-buf))))
 387
 388 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext")
 389 (define-ibuffer-op rename-uniquely ()
 390   "Rename marked buffers as with `rename-uniquely'."
 391   (:opstring "renamed"
 392    :modifier-p t)
 393   (rename-uniquely))
 394
 395 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext")
 396 (define-ibuffer-op revert ()
 397   "Revert marked buffers as with `revert-buffer'."
 398   (:dangerous t
 399    :opstring "reverted"
 400    :active-opstring "revert"
 401    :modifier-p :maybe)
 402   (revert-buffer t t))
 403
 404 ;;;###autoload (autoload 'ibuffer-do-isearch "ibuf-ext")
 405 (define-ibuffer-op ibuffer-do-isearch ()
 406   "Perform a `isearch-forward' in marked buffers."
 407   (:interactive ()
 408    :opstring "searched in"
 409    :complex t
 410    :modifier-p :maybe)
 411   (multi-isearch-buffers (ibuffer-get-marked-buffers)))
 412
 413 ;;;###autoload (autoload 'ibuffer-do-isearch-regexp "ibuf-ext")
 414 (define-ibuffer-op ibuffer-do-isearch-regexp ()
 415   "Perform a `isearch-forward-regexp' in marked buffers."
 416   (:interactive ()
 417    :opstring "searched regexp in"
 418    :complex t
 419    :modifier-p :maybe)
 420   (multi-isearch-buffers-regexp (ibuffer-get-marked-buffers)))
 421
 422 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext")
 423 (define-ibuffer-op replace-regexp (from-str to-str)
 424   "Perform a `replace-regexp' in marked buffers."
 425   (:interactive
 426    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 427           (to-str (read-from-minibuffer (concat "Replace " from-str
 428                                                 " with: "))))
 429      (list from-str to-str))
 430    :opstring "replaced in"
 431    :complex t
 432    :modifier-p :maybe)
 433   (save-window-excursion
 434     (switch-to-buffer buf)
 435     (save-excursion
 436       (goto-char (point-min))
 437       (let ((case-fold-search ibuffer-case-fold-search))
 438         (while (re-search-forward from-str nil t)
 439           (replace-match to-str))))
 440     t))
 441
 442 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext")
 443 (define-ibuffer-op query-replace (&rest args)
 444   "Perform a `query-replace' in marked buffers."
 445   (:interactive
 446    (query-replace-read-args "Query replace" t t)
 447    :opstring "replaced in"
 448    :complex t
 449    :modifier-p :maybe)
 450   (save-window-excursion
 451     (switch-to-buffer buf)
 452     (save-excursion
 453       (let ((case-fold-search ibuffer-case-fold-search))
 454         (goto-char (point-min))
 455         (apply #'query-replace args)))
 456     t))
 457
 458 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext")
 459 (define-ibuffer-op query-replace-regexp (&rest args)
 460   "Perform a `query-replace-regexp' in marked buffers."
 461   (:interactive
 462    (query-replace-read-args "Query replace regexp" t t)
 463    :opstring "replaced in"
 464    :complex t
 465    :modifier-p :maybe)
 466   (save-window-excursion
 467     (switch-to-buffer buf)
 468     (save-excursion
 469       (let ((case-fold-search ibuffer-case-fold-search))
 470         (goto-char (point-min))
 471         (apply #'query-replace-regexp args)))
 472     t))
 473
 474 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext")
 475 (define-ibuffer-op print ()
 476   "Print marked buffers as with `print-buffer'."
 477   (:opstring "printed"
 478    :modifier-p nil)
 479   (print-buffer))
 480
 481 ;;;###autoload
 482 (defun ibuffer-included-in-filters-p (buf filters)
 483   (not
 484    (memq nil ;; a filter will return nil if it failed
 485          (mapcar
 486           ;; filter should be like (TYPE . QUALIFIER), or
 487           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 488           #'(lambda (qual)
 489               (ibuffer-included-in-filter-p buf qual))
 490           filters))))
 491
 492 (defun ibuffer-included-in-filter-p (buf filter)
 493   (if (eq (car filter) 'not)
 494       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 495     (ibuffer-included-in-filter-p-1 buf filter)))
 496
 497 (defun ibuffer-included-in-filter-p-1 (buf filter)
 498   (not
 499    (not
 500     (pcase (car filter)
 501       (`or
 502        (memq t (mapcar #'(lambda (x)
 503                            (ibuffer-included-in-filter-p buf x))
 504                        (cdr filter))))
 505       (`saved
 506        (let ((data
 507               (assoc (cdr filter)
 508                      ibuffer-saved-filters)))
 509          (unless data
 510            (ibuffer-filter-disable t)
 511            (error "Unknown saved filter %s" (cdr filter)))
 512          (ibuffer-included-in-filters-p buf (cadr data))))
 513       (_
 514        (pcase-let ((`(,_type ,_desc ,func)
 515                     (assq (car filter) ibuffer-filtering-alist)))
 516          (unless func
 517            (ibuffer-filter-disable t)
 518            (error "Undefined filter %s" (car filter)))
 519          (funcall func buf (cdr filter))))))))
 520
 521 (defun ibuffer-generate-filter-groups (bmarklist &optional noempty nodefault)
 522   (let ((filter-group-alist (if nodefault
 523                                 ibuffer-filter-groups
 524                               (append ibuffer-filter-groups
 525                                       (list (cons "Default" nil))))))
 526     ;; (dolist (hidden ibuffer-hidden-filter-groups)
 527     ;;   (setq filter-group-alist (ibuffer-delete-alist
 528     ;;                             hidden filter-group-alist)))
 529     (let ((vec (make-vector (length filter-group-alist) nil))
 530           (i 0))
 531       (dolist (filtergroup filter-group-alist)
 532         (let ((filterset (cdr filtergroup)))
 533           (cl-multiple-value-bind (hip-crowd lamers)
 534               (cl-values-list
 535                (ibuffer-split-list (lambda (bufmark)
 536                                      (ibuffer-included-in-filters-p (car bufmark)
 537                                                                     filterset))
 538                                    bmarklist))
 539             (aset vec i hip-crowd)
 540             (cl-incf i)
 541             (setq bmarklist lamers))))
 542       (let (ret)
 543         (dotimes (j i)
 544           (let ((bufs (aref vec j)))
 545             (unless (and noempty (null bufs))
 546               (push (cons (car (nth j filter-group-alist))
 547                           bufs)
 548                     ret))))
 549         ret))))
 550
 551 ;;;###autoload
 552 (defun ibuffer-filters-to-filter-group (name)
 553   "Make the current filters into a filtering group."
 554   (interactive "sName for filtering group: ")
 555   (when (null ibuffer-filtering-qualifiers)
 556     (error "No filters in effect"))
 557   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 558   (ibuffer-filter-disable))
 559
 560 ;;;###autoload
 561 (defun ibuffer-set-filter-groups-by-mode ()
 562   "Set the current filter groups to filter by mode."
 563   (interactive)
 564   (setq ibuffer-filter-groups
 565         (mapcar (lambda (mode)
 566                   (cons (format "%s" mode) `((mode . ,mode))))
 567                 (let ((modes
 568                        (ibuffer-remove-duplicates
 569                         (mapcar (lambda (buf)
 570                                   (buffer-local-value 'major-mode buf))
 571                                 (buffer-list)))))
 572                   (if ibuffer-view-ibuffer
 573                       modes
 574                     (delq 'ibuffer-mode modes)))))
 575   (ibuffer-update nil t))
 576
 577 ;;;###autoload
 578 (defun ibuffer-pop-filter-group ()
 579   "Remove the first filter group."
 580   (interactive)
 581   (when (null ibuffer-filter-groups)
 582     (error "No filter groups active"))
 583   (setq ibuffer-hidden-filter-groups
 584         (delete (pop ibuffer-filter-groups)
 585                 ibuffer-hidden-filter-groups))
 586   (ibuffer-update nil t))
 587
 588 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 589   (when (and (not noerror) (null ibuffer-filter-groups))
 590     (error "No filter groups active"))
 591   ;; `ibuffer-generate-filter-groups' returns all non-hidden filter
 592   ;; groups, possibly excluding empty groups or Default.
 593   ;; We add `ibuffer-hidden-filter-groups' to the list, excluding
 594   ;; Default if necessary.
 595   (completing-read msg (nconc
 596                         (ibuffer-generate-filter-groups
 597                          (ibuffer-current-state-list)
 598                          (not ibuffer-show-empty-filter-groups)
 599                          nodefault)
 600                         (if nodefault
 601                             (remove "Default" ibuffer-hidden-filter-groups)
 602                           ibuffer-hidden-filter-groups))
 603                    nil t))
 604
 605 ;;;###autoload
 606 (defun ibuffer-decompose-filter-group (group)
 607   "Decompose the filter group GROUP into active filters."
 608   (interactive
 609    (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 610   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 611     (setq ibuffer-filter-groups (ibuffer-delete-alist
 612                                  group ibuffer-filter-groups)
 613           ibuffer-filtering-qualifiers data))
 614   (ibuffer-update nil t))
 615
 616 ;;;###autoload
 617 (defun ibuffer-clear-filter-groups ()
 618   "Remove all filter groups."
 619   (interactive)
 620   (setq ibuffer-filter-groups nil
 621         ibuffer-hidden-filter-groups nil)
 622   (ibuffer-update nil t))
 623
 624 (defun ibuffer-current-filter-groups-with-position ()
 625   (save-excursion
 626     (goto-char (point-min))
 627     (let ((pos nil)
 628           (result nil))
 629       (while (and (not (eobp))
 630                   (setq pos (next-single-property-change
 631                              (point) 'ibuffer-filter-group-name)))
 632         (goto-char pos)
 633         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 634                     pos)
 635               result)
 636         (goto-char (next-single-property-change
 637                     pos 'ibuffer-filter-group-name)))
 638       (nreverse result))))
 639
 640 ;;;###autoload
 641 (defun ibuffer-jump-to-filter-group (name)
 642   "Move point to the filter group whose name is NAME."
 643   (interactive
 644    (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 645   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 646       (goto-char (cdr it))
 647     (error "No filter group with name %s" name)))
 648
 649 ;;;###autoload
 650 (defun ibuffer-kill-filter-group (name)
 651   "Kill the filter group named NAME.
 652 The group will be added to `ibuffer-filter-group-kill-ring'."
 653   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 654   (when (equal name "Default")
 655     (error "Can't kill default filter group"))
 656   (ibuffer-aif (assoc name ibuffer-filter-groups)
 657       (progn
 658         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 659         (setq ibuffer-filter-groups (ibuffer-delete-alist
 660                                      name ibuffer-filter-groups))
 661         (setq ibuffer-hidden-filter-groups
 662               (delete name ibuffer-hidden-filter-groups)))
 663     (error "No filter group with name \"%s\"" name))
 664   (ibuffer-update nil t))
 665
 666 ;;;###autoload
 667 (defun ibuffer-kill-line (&optional arg interactive-p)
 668   "Kill the filter group at point.
 669 See also `ibuffer-kill-filter-group'."
 670   (interactive "P\np")
 671   (ibuffer-aif (save-excursion
 672                  (ibuffer-forward-line 0)
 673                  (get-text-property (point) 'ibuffer-filter-group-name))
 674       (progn
 675         (ibuffer-kill-filter-group it))
 676       (funcall (if interactive-p #'call-interactively #'funcall)
 677                #'kill-line arg)))
 678
 679 (defun ibuffer-insert-filter-group-before (newgroup group)
 680   (let* ((found nil)
 681          (pos (let ((groups (mapcar #'car ibuffer-filter-groups))
 682                     (res 0))
 683                 (while groups
 684                   (if (equal (car groups) group)
 685                       (setq found t
 686                             groups nil)
 687                     (cl-incf res)
 688                     (setq groups (cdr groups))))
 689                 res)))
 690     (cond ((not found)
 691            (setq ibuffer-filter-groups
 692                  (nconc ibuffer-filter-groups (list newgroup))))
 693           ((zerop pos)
 694            (push newgroup ibuffer-filter-groups))
 695           (t
 696            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 697              (setf (cdr cell) (cons (car cell) (cdr cell)))
 698              (setf (car cell) newgroup))))))
 699
 700 ;;;###autoload
 701 (defun ibuffer-yank ()
 702   "Yank the last killed filter group before group at point."
 703   (interactive)
 704   (ibuffer-yank-filter-group
 705    (or (get-text-property (point) 'ibuffer-filter-group-name)
 706        (get-text-property (point) 'ibuffer-filter-group)
 707        (error "No filter group at point"))))
 708
 709 ;;;###autoload
 710 (defun ibuffer-yank-filter-group (name)
 711   "Yank the last killed filter group before group named NAME."
 712   (interactive (list (ibuffer-read-filter-group-name
 713                         "Yank filter group before group: ")))
 714   (unless ibuffer-filter-group-kill-ring
 715     (error "The Ibuffer filter group kill-ring is empty"))
 716   (save-excursion
 717     (ibuffer-forward-line 0)
 718     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 719                                         name))
 720   (ibuffer-update nil t))
 721
 722 ;;;###autoload
 723 (defun ibuffer-save-filter-groups (name groups)
 724   "Save all active filter groups GROUPS as NAME.
 725 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 726 prompt for NAME, and use the current filters."
 727   (interactive
 728    (if (null ibuffer-filter-groups)
 729        (error "No filter groups active")
 730      (list
 731       (read-from-minibuffer "Save current filter groups as: ")
 732       ibuffer-filter-groups)))
 733   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 734       (setcdr it groups)
 735     (push (cons name groups) ibuffer-saved-filter-groups))
 736   (ibuffer-maybe-save-stuff))
 737
 738 ;;;###autoload
 739 (defun ibuffer-delete-saved-filter-groups (name)
 740   "Delete saved filter groups with NAME.
 741 They are removed from `ibuffer-saved-filter-groups'."
 742   (interactive
 743    (list
 744     (if (null ibuffer-saved-filter-groups)
 745         (error "No saved filter groups")
 746       (completing-read "Delete saved filter group: "
 747                        ibuffer-saved-filter-groups nil t))))
 748   (setq ibuffer-saved-filter-groups
 749         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 750   (ibuffer-maybe-save-stuff)
 751   (ibuffer-update nil t))
 752
 753 ;;;###autoload
 754 (defun ibuffer-switch-to-saved-filter-groups (name)
 755   "Set this buffer's filter groups to saved version with NAME.
 756 The value from `ibuffer-saved-filter-groups' is used."
 757   (interactive
 758    (list
 759     (cond ((null ibuffer-saved-filter-groups)
 760            (error "No saved filters"))
 761           ;; `ibuffer-saved-filter-groups' is a user variable that defaults
 762           ;; to nil.  We assume that with one element in this list the user
 763           ;; knows what she wants.  See bug#12331.
 764           ((null (cdr ibuffer-saved-filter-groups))
 765            (caar ibuffer-saved-filter-groups))
 766           (t
 767            (completing-read "Switch to saved filter group: "
 768                             ibuffer-saved-filter-groups nil t)))))
 769   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 770         ibuffer-hidden-filter-groups nil)
 771   (ibuffer-update nil t))
 772
 773 ;;;###autoload
 774 (defun ibuffer-filter-disable (&optional delete-filter-groups)
 775   "Disable all filters currently in effect in this buffer.
 776 With optional arg DELETE-FILTER-GROUPS non-nil, delete all filter
 777 group definitions by setting `ibuffer-filter-groups' to nil."
 778   (interactive)
 779   (setq ibuffer-filtering-qualifiers nil)
 780   (if delete-filter-groups
 781       (setq ibuffer-filter-groups nil))
 782   (let ((buf (ibuffer-current-buffer)))
 783     (ibuffer-update nil t)
 784     (when buf
 785       (ibuffer-jump-to-buffer (buffer-name buf)))))
 786
 787 ;;;###autoload
 788 (defun ibuffer-pop-filter ()
 789   "Remove the top filter in this buffer."
 790   (interactive)
 791   (when (null ibuffer-filtering-qualifiers)
 792     (error "No filters in effect"))
 793   (pop ibuffer-filtering-qualifiers)
 794   (let ((buf (ibuffer-current-buffer)))
 795     (ibuffer-update nil t)
 796     (when buf
 797       (ibuffer-jump-to-buffer (buffer-name buf)))))
 798
 799 (defun ibuffer-push-filter (qualifier)
 800   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 801   (push qualifier ibuffer-filtering-qualifiers))
 802
 803 ;;;###autoload
 804 (defun ibuffer-decompose-filter ()
 805   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 806
 807 This means that the topmost filter on the filtering stack, which must
 808 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 809 turned into two separate filters [name: foo] and [mode: bar-mode]."
 810   (interactive)
 811   (when (null ibuffer-filtering-qualifiers)
 812     (error "No filters in effect"))
 813   (let ((lim (pop ibuffer-filtering-qualifiers)))
 814     (pcase (car lim)
 815       (`or
 816        (setq ibuffer-filtering-qualifiers (append
 817                                           (cdr lim)
 818                                           ibuffer-filtering-qualifiers)))
 819       (`saved
 820        (let ((data
 821               (assoc (cdr lim)
 822                      ibuffer-saved-filters)))
 823          (unless data
 824            (ibuffer-filter-disable)
 825            (error "Unknown saved filter %s" (cdr lim)))
 826          (setq ibuffer-filtering-qualifiers (append
 827                                             (cadr data)
 828                                             ibuffer-filtering-qualifiers))))
 829       (`not
 830        (push (cdr lim)
 831              ibuffer-filtering-qualifiers))
 832       (_
 833        (error "Filter type %s is not compound" (car lim)))))
 834   (ibuffer-update nil t))
 835
 836 ;;;###autoload
 837 (defun ibuffer-exchange-filters ()
 838   "Exchange the top two filters on the stack in this buffer."
 839   (interactive)
 840   (when (< (length ibuffer-filtering-qualifiers)
 841            2)
 842     (error "Need two filters to exchange"))
 843   (let ((first (pop ibuffer-filtering-qualifiers))
 844         (second (pop ibuffer-filtering-qualifiers)))
 845     (push first ibuffer-filtering-qualifiers)
 846     (push second ibuffer-filtering-qualifiers))
 847   (ibuffer-update nil t))
 848
 849 ;;;###autoload
 850 (defun ibuffer-negate-filter ()
 851   "Negate the sense of the top filter in the current buffer."
 852   (interactive)
 853   (when (null ibuffer-filtering-qualifiers)
 854     (error "No filters in effect"))
 855   (let ((lim (pop ibuffer-filtering-qualifiers)))
 856     (push (if (eq (car lim) 'not)
 857               (cdr lim)
 858             (cons 'not lim))
 859           ibuffer-filtering-qualifiers))
 860   (ibuffer-update nil t))
 861
 862 ;;;###autoload
 863 (defun ibuffer-or-filter (&optional reverse)
 864   "Replace the top two filters in this buffer with their logical OR.
 865 If optional argument REVERSE is non-nil, instead break the top OR
 866 filter into parts."
 867   (interactive "P")
 868   (if reverse
 869       (progn
 870         (when (or (null ibuffer-filtering-qualifiers)
 871                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 872           (error "Top filter is not an OR"))
 873         (let ((lim (pop ibuffer-filtering-qualifiers)))
 874           (setq ibuffer-filtering-qualifiers
 875                 (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 876     (when (< (length ibuffer-filtering-qualifiers) 2)
 877       (error "Need two filters to OR"))
 878     ;; If the second filter is an OR, just add to it.
 879     (let ((first (pop ibuffer-filtering-qualifiers))
 880           (second (pop ibuffer-filtering-qualifiers)))
 881       (if (eq 'or (car second))
 882           (push (nconc (list 'or first) (cdr second))
 883                 ibuffer-filtering-qualifiers)
 884         (push (list 'or first second)
 885               ibuffer-filtering-qualifiers))))
 886   (ibuffer-update nil t))
 887
 888 (defun ibuffer-maybe-save-stuff ()
 889   (when ibuffer-save-with-custom
 890     (if (fboundp 'customize-save-variable)
 891         (progn
 892           (customize-save-variable 'ibuffer-saved-filters
 893                                    ibuffer-saved-filters)
 894           (customize-save-variable 'ibuffer-saved-filter-groups
 895                                    ibuffer-saved-filter-groups))
 896       (message "Not saved permanently: Customize not available"))))
 897
 898 ;;;###autoload
 899 (defun ibuffer-save-filters (name filters)
 900   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 901 Interactively, prompt for NAME, and use the current filters."
 902   (interactive
 903    (if (null ibuffer-filtering-qualifiers)
 904        (error "No filters currently in effect")
 905      (list
 906       (read-from-minibuffer "Save current filters as: ")
 907       ibuffer-filtering-qualifiers)))
 908   (ibuffer-aif (assoc name ibuffer-saved-filters)
 909       (setcdr it filters)
 910     (push (list name filters) ibuffer-saved-filters))
 911   (ibuffer-maybe-save-stuff))
 912
 913 ;;;###autoload
 914 (defun ibuffer-delete-saved-filters (name)
 915   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 916   (interactive
 917    (list
 918     (if (null ibuffer-saved-filters)
 919         (error "No saved filters")
 920       (completing-read "Delete saved filters: "
 921                        ibuffer-saved-filters nil t))))
 922   (setq ibuffer-saved-filters
 923         (ibuffer-delete-alist name ibuffer-saved-filters))
 924   (ibuffer-maybe-save-stuff)
 925   (ibuffer-update nil t))
 926
 927 ;;;###autoload
 928 (defun ibuffer-add-saved-filters (name)
 929   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 930   (interactive
 931    (list
 932     (if (null ibuffer-saved-filters)
 933         (error "No saved filters")
 934       (completing-read "Add saved filters: "
 935                        ibuffer-saved-filters nil t))))
 936   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 937   (ibuffer-update nil t))
 938
 939 ;;;###autoload
 940 (defun ibuffer-switch-to-saved-filters (name)
 941   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'."
 942   (interactive
 943    (list
 944     (if (null ibuffer-saved-filters)
 945         (error "No saved filters")
 946       (completing-read "Switch to saved filters: "
 947                        ibuffer-saved-filters nil t))))
 948   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 949   (ibuffer-update nil t))
 950
 951 (defun ibuffer-format-filter-group-data (filter)
 952   (if (equal filter "Default")
 953       ""
 954     (concat "Filter:" (mapconcat #'ibuffer-format-qualifier
 955                                  (cdr (assq filter ibuffer-filter-groups))
 956                                  " "))))
 957
 958 (defun ibuffer-format-qualifier (qualifier)
 959   (if (eq (car-safe qualifier) 'not)
 960       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 961     (ibuffer-format-qualifier-1 qualifier)))
 962
 963 (defun ibuffer-format-qualifier-1 (qualifier)
 964   (pcase (car qualifier)
 965     (`saved
 966      (concat " [filter: " (cdr qualifier) "]"))
 967     (`or
 968      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 969                                (cdr qualifier) "") "]"))
 970     (_
 971      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 972        (unless qualifier
 973          (error "Ibuffer: bad qualifier %s" qualifier))
 974        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 975
 976
 977 (defun ibuffer-list-buffer-modes (&optional include-parents)
 978   "Create a completion table of buffer modes currently in use.
 979 If INCLUDE-PARENTS is non-nil then include parent modes."
 980   (let ((modes))
 981     (dolist (buf (buffer-list))
 982       (let ((this-mode (buffer-local-value 'major-mode buf)))
 983         (while (and this-mode (not (memq this-mode modes)))
 984           (push this-mode modes)
 985           (setq this-mode (and include-parents
 986                                (get this-mode 'derived-mode-parent))))))
 987     (mapcar #'symbol-name modes)))
 988
 989
 990 ;;; Extra operation definitions
 991
 992 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext")
 993 (define-ibuffer-filter mode
 994   "Toggle current view to buffers with major mode QUALIFIER."
 995   (:description "major mode"
 996    :reader
 997    (let* ((buf (ibuffer-current-buffer))
 998           (default (if (and buf (buffer-live-p buf))
 999                        (symbol-name (buffer-local-value
1000                                      'major-mode buf)))))
1001      (intern
1002       (completing-read
1003        (if default
1004            (format "Filter by major mode (default %s): " default)
1005          "Filter by major mode: ")
1006        obarray
1007        #'(lambda (e)
1008            (string-match "-mode\\'" (symbol-name e)))
1009        t nil nil default))))
1010   (eq qualifier (buffer-local-value 'major-mode buf)))
1011
1012 ;;;###autoload (autoload 'ibuffer-filter-by-used-mode "ibuf-ext")
1013 (define-ibuffer-filter used-mode
1014   "Toggle current view to buffers with major mode QUALIFIER.
1015 Called interactively, this function allows selection of modes
1016 currently used by buffers."
1017   (:description "major mode in use"
1018    :reader
1019    (let* ((buf (ibuffer-current-buffer))
1020           (default (if (and buf (buffer-live-p buf))
1021                        (symbol-name (buffer-local-value
1022                                      'major-mode buf)))))
1023      (intern
1024       (completing-read
1025        (if default
1026            (format "Filter by major mode (default %s): " default)
1027          "Filter by major mode: ")
1028        (ibuffer-list-buffer-modes) nil t nil nil default))))
1029   (eq qualifier (buffer-local-value 'major-mode buf)))
1030
1031 ;;;###autoload (autoload 'ibuffer-filter-by-derived-mode "ibuf-ext")
1032 (define-ibuffer-filter derived-mode
1033     "Toggle current view to buffers whose major mode inherits from QUALIFIER."
1034   (:description "derived mode"
1035                 :reader
1036                 (intern
1037                  (completing-read "Filter by derived mode: "
1038                                   (ibuffer-list-buffer-modes t)
1039                                   nil t)))
1040   (with-current-buffer buf (derived-mode-p qualifier)))
1041
1042 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext")
1043 (define-ibuffer-filter name
1044   "Toggle current view to buffers with name matching QUALIFIER."
1045   (:description "buffer name"
1046    :reader (read-from-minibuffer "Filter by name (regexp): "))
1047   (string-match qualifier (buffer-name buf)))
1048
1049 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext")
1050 (define-ibuffer-filter filename
1051   "Toggle current view to buffers with filename matching QUALIFIER."
1052   (:description "filename"
1053    :reader (read-from-minibuffer "Filter by filename (regexp): "))
1054   (ibuffer-awhen (with-current-buffer buf (ibuffer-buffer-file-name))
1055     (string-match qualifier it)))
1056
1057 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext")
1058 (define-ibuffer-filter size-gt
1059   "Toggle current view to buffers with size greater than QUALIFIER."
1060   (:description "size greater than"
1061    :reader
1062    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
1063   (> (with-current-buffer buf (buffer-size))
1064      qualifier))
1065
1066 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext")
1067 (define-ibuffer-filter size-lt
1068    "Toggle current view to buffers with size less than QUALIFIER."
1069   (:description "size less than"
1070    :reader
1071    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
1072   (< (with-current-buffer buf (buffer-size))
1073      qualifier))
1074
1075 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext")
1076 (define-ibuffer-filter content
1077    "Toggle current view to buffers whose contents match QUALIFIER."
1078   (:description "content"
1079    :reader (read-from-minibuffer "Filter by content (regexp): "))
1080   (with-current-buffer buf
1081     (save-excursion
1082       (goto-char (point-min))
1083       (re-search-forward qualifier nil t))))
1084
1085 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext")
1086 (define-ibuffer-filter predicate
1087    "Toggle current view to buffers for which QUALIFIER returns non-nil."
1088   (:description "predicate"
1089    :reader (read-minibuffer "Filter by predicate (form): "))
1090   (with-current-buffer buf
1091     (eval qualifier)))
1092
1093 ;;; Sorting
1094
1095 ;;;###autoload
1096 (defun ibuffer-toggle-sorting-mode ()
1097   "Toggle the current sorting mode.
1098 Default sorting modes are:
1099  Recency - the last time the buffer was viewed
1100  Name - the name of the buffer
1101  Major Mode - the name of the major mode of the buffer
1102  Size - the size of the buffer"
1103   (interactive)
1104   (let ((modes (mapcar #'car ibuffer-sorting-functions-alist)))
1105     (cl-pushnew 'recency modes)
1106     (setq modes (sort modes #'string-lessp))
1107     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1108                     (car modes))))
1109       (setq ibuffer-sorting-mode next)
1110       (message "Sorting by %s" next)))
1111   (ibuffer-redisplay t))
1112
1113 ;;;###autoload
1114 (defun ibuffer-invert-sorting ()
1115   "Toggle whether or not sorting is in reverse order."
1116   (interactive)
1117   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1118   (message "Sorting order %s"
1119            (if ibuffer-sorting-reversep
1120                "reversed"
1121              "normal"))
1122   (ibuffer-redisplay t))
1123
1124 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext")
1125 (define-ibuffer-sorter major-mode
1126   "Sort the buffers by major modes.
1127 Ordering is lexicographic."
1128   (:description "major mode")
1129   (string-lessp (downcase
1130                  (symbol-name (buffer-local-value 'major-mode (car a))))
1131                 (downcase
1132                  (symbol-name (buffer-local-value 'major-mode (car b))))))
1133
1134 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext")
1135 (define-ibuffer-sorter mode-name
1136   "Sort the buffers by their mode name.
1137 Ordering is lexicographic."
1138   (:description "major mode name")
1139   (string-lessp (downcase
1140                  (with-current-buffer
1141                      (car a)
1142                    (format-mode-line mode-name)))
1143                 (downcase
1144                  (with-current-buffer
1145                      (car b)
1146                    (format-mode-line mode-name)))))
1147
1148 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext")
1149 (define-ibuffer-sorter alphabetic
1150   "Sort the buffers by their names.
1151 Ordering is lexicographic."
1152   (:description "buffer name")
1153   (string-lessp
1154    (buffer-name (car a))
1155    (buffer-name (car b))))
1156
1157 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext")
1158 (define-ibuffer-sorter size
1159  "Sort the buffers by their size."
1160   (:description "size")
1161   (< (with-current-buffer (car a)
1162        (buffer-size))
1163      (with-current-buffer (car b)
1164        (buffer-size))))
1165
1166 ;;;###autoload (autoload 'ibuffer-do-sort-by-filename/process "ibuf-ext")
1167 (define-ibuffer-sorter filename/process
1168  "Sort the buffers by their file name/process name."
1169   (:description "file name")
1170   (string-lessp
1171    ;; FIXME: For now just compare the file name and the process name
1172    ;; (if it exists).  Is there a better way to do this?
1173    (or (buffer-file-name (car a))
1174        (let ((pr-a (get-buffer-process (car a))))
1175          (and (processp pr-a) (process-name pr-a))))
1176    (or (buffer-file-name (car b))
1177        (let ((pr-b (get-buffer-process (car b))))
1178          (and (processp pr-b) (process-name pr-b))))))
1179
1180 ;;; Functions to emulate bs.el
1181
1182 ;;;###autoload
1183 (defun ibuffer-bs-show ()
1184   "Emulate `bs-show' from the bs.el package."
1185   (interactive)
1186   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1187   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1188
1189 (defun ibuffer-bs-toggle-all ()
1190   "Emulate `bs-toggle-show-all' from the bs.el package."
1191   (interactive)
1192   (if ibuffer-filtering-qualifiers
1193       (ibuffer-pop-filter)
1194     (progn (ibuffer-push-filter '(filename . ".*"))
1195            (ibuffer-update nil t))))
1196
1197 ;;; Handy functions
1198
1199 ;;;###autoload
1200 (defun ibuffer-add-to-tmp-hide (regexp)
1201   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1202 This means that buffers whose name matches REGEXP will not be shown
1203 for this Ibuffer session."
1204   (interactive
1205    (list
1206     (read-from-minibuffer "Never show buffers matching: "
1207                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1208   (push regexp ibuffer-tmp-hide-regexps))
1209
1210 ;;;###autoload
1211 (defun ibuffer-add-to-tmp-show (regexp)
1212   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1213 This means that buffers whose name matches REGEXP will always be shown
1214 for this Ibuffer session."
1215   (interactive
1216    (list
1217     (read-from-minibuffer "Always show buffers matching: "
1218                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1219   (push regexp ibuffer-tmp-show-regexps))
1220
1221 ;;;###autoload
1222 (defun ibuffer-forward-next-marked (&optional count mark direction)
1223   "Move forward by COUNT marked buffers (default 1).
1224
1225 If MARK is non-nil, it should be a character denoting the type of mark
1226 to move by.  The default is `ibuffer-marked-char'.
1227
1228 If DIRECTION is non-nil, it should be an integer; negative integers
1229 mean move backwards, non-negative integers mean move forwards."
1230   (interactive "P")
1231   (unless count
1232     (setq count 1))
1233   (unless mark
1234     (setq mark ibuffer-marked-char))
1235   (unless direction
1236     (setq direction 1))
1237   ;; Skip the title
1238   (ibuffer-forward-line 0)
1239   (let ((opos (point)))
1240     (ibuffer-forward-line direction)
1241     (while (not (or (= (point) opos)
1242                     (eq (ibuffer-current-mark) mark)))
1243       (ibuffer-forward-line direction))
1244     (when (and (= (point) opos)
1245                (not (eq (ibuffer-current-mark) mark)))
1246       (error "No buffers with mark %c" mark))))
1247
1248 ;;;###autoload
1249 (defun ibuffer-backwards-next-marked (&optional count mark)
1250    "Move backwards by COUNT marked buffers (default 1).
1251
1252 If MARK is non-nil, it should be a character denoting the type of mark
1253 to move by.  The default is `ibuffer-marked-char'."
1254    (interactive "P")
1255    (ibuffer-forward-next-marked count mark -1))
1256
1257 ;;;###autoload
1258 (defun ibuffer-do-kill-lines ()
1259   "Hide all of the currently marked lines."
1260   (interactive)
1261   (if (= (ibuffer-count-marked-lines) 0)
1262       (message "No buffers marked; use 'm' to mark a buffer")
1263     (let ((count
1264            (ibuffer-map-marked-lines
1265             #'(lambda (_buf _mark)
1266                 'kill))))
1267       (message "Killed %s lines" count))))
1268
1269 ;;;###autoload
1270 (defun ibuffer-jump-to-buffer (name)
1271   "Move point to the buffer whose name is NAME.
1272
1273 If called interactively, prompt for a buffer name and go to the
1274 corresponding line in the Ibuffer buffer.  If said buffer is in a
1275 hidden group filter, open it.
1276
1277 If `ibuffer-jump-offer-only-visible-buffers' is non-nil, only offer
1278 visible buffers in the completion list.  Calling the command with
1279 a prefix argument reverses the meaning of that variable."
1280   (interactive (list
1281                 (let ((only-visible ibuffer-jump-offer-only-visible-buffers))
1282                   (when current-prefix-arg
1283                     (setq only-visible (not only-visible)))
1284                   (if only-visible
1285                       (let ((table (mapcar #'(lambda (x)
1286                                                (buffer-name (car x)))
1287                                            (ibuffer-current-state-list))))
1288                         (when (null table)
1289                           (error "No buffers!"))
1290                         (completing-read "Jump to buffer: "
1291                                          table nil t))
1292                     (read-buffer "Jump to buffer: " nil t)))))
1293   (when (not (string= "" name))
1294     (let (buf-point)
1295       ;; Blindly search for our buffer: it is very likely that it is
1296       ;; not in a hidden filter group.
1297       (ibuffer-map-lines #'(lambda (buf _marks)
1298                              (when (string= (buffer-name buf) name)
1299                                (setq buf-point (point))
1300                                nil))
1301                          t nil)
1302       (when (and
1303              (null buf-point)
1304              (not (null ibuffer-hidden-filter-groups)))
1305         ;; We did not find our buffer.  It must be in a hidden filter
1306         ;; group, so go through all hidden filter groups to find it.
1307         (catch 'found
1308           (dolist (group ibuffer-hidden-filter-groups)
1309             (ibuffer-jump-to-filter-group group)
1310             (ibuffer-toggle-filter-group)
1311             (ibuffer-map-lines #'(lambda (buf _marks)
1312                                    (when (string= (buffer-name buf) name)
1313                                      (setq buf-point (point))
1314                                      nil))
1315                                t group)
1316             (if buf-point
1317                 (throw 'found nil)
1318               (ibuffer-toggle-filter-group)))))
1319       (if (null buf-point)
1320           ;; Still not found even though we expanded all hidden filter
1321           ;; groups: that must be because it's hidden by predicate:
1322           ;; we won't bother trying to display it.
1323           (error "No buffer with name %s" name)
1324         (goto-char buf-point)))))
1325
1326 (declare-function diff-sentinel "diff"
1327                   (code &optional old-temp-file new-temp-file))
1328
1329 (defun ibuffer-diff-buffer-with-file-1 (buffer)
1330   (let ((bufferfile (buffer-local-value 'buffer-file-name buffer))
1331         (tempfile (make-temp-file "buffer-content-")))
1332     (when bufferfile
1333       (unwind-protect
1334           (progn
1335             (with-current-buffer buffer
1336               (write-region nil nil tempfile nil 'nomessage))
1337             (let* ((old (expand-file-name bufferfile))
1338                    (new (expand-file-name tempfile))
1339                    (oldtmp (file-local-copy old))
1340                    (newtmp (file-local-copy new))
1341                    (switches diff-switches)
1342                    (command
1343                     (mapconcat
1344                      'identity
1345                      `(,diff-command
1346                        ;; Use explicitly specified switches
1347                        ,@(if (listp switches) switches (list switches))
1348                        ,@(if (or old new)
1349                              (list "-L" (shell-quote-argument old)
1350                                    "-L" (shell-quote-argument
1351                                          (format "Buffer %s" (buffer-name buffer)))))
1352                        ,(shell-quote-argument (or oldtmp old))
1353                        ,(shell-quote-argument (or newtmp new)))
1354                      " ")))
1355               (let ((inhibit-read-only t))
1356                 (insert command "\n")
1357                 (diff-sentinel
1358                  (call-process shell-file-name nil
1359                                (current-buffer) nil
1360                                shell-command-switch command))
1361                 (insert "\n")))))
1362       (sit-for 0)
1363       (when (file-exists-p tempfile)
1364         (delete-file tempfile)))))
1365
1366 ;;;###autoload
1367 (defun ibuffer-diff-with-file ()
1368   "View the differences between marked buffers and their associated files.
1369 If no buffers are marked, use buffer at point.
1370 This requires the external program \"diff\" to be in your `exec-path'."
1371   (interactive)
1372   (require 'diff)
1373   (let ((marked-bufs (ibuffer-get-marked-buffers)))
1374     (when (null marked-bufs)
1375       (setq marked-bufs (list (ibuffer-current-buffer t))))
1376     (with-current-buffer (get-buffer-create "*Ibuffer Diff*")
1377       (setq buffer-read-only nil)
1378       (buffer-disable-undo (current-buffer))
1379       (erase-buffer)
1380       (buffer-enable-undo (current-buffer))
1381       (diff-mode)
1382       (dolist (buf marked-bufs)
1383         (unless (buffer-live-p buf)
1384           (error "Buffer %s has been killed" buf))
1385         (ibuffer-diff-buffer-with-file-1 buf))
1386       (setq buffer-read-only t)))
1387   (switch-to-buffer "*Ibuffer Diff*"))
1388
1389 ;;;###autoload
1390 (defun ibuffer-copy-filename-as-kill (&optional arg)
1391   "Copy filenames of marked buffers into the kill ring.
1392
1393 The names are separated by a space.
1394 If a buffer has no filename, it is ignored.
1395
1396 With no prefix arg, use the filename sans its directory of each marked file.
1397 With a zero prefix arg, use the complete filename of each marked file.
1398 With \\[universal-argument], use the filename of each marked file relative
1399 to `ibuffer-default-directory' if non-nil, otherwise `default-directory'.
1400
1401 You can then feed the file name(s) to other commands with \\[yank]."
1402   (interactive "p")
1403   (if (zerop (ibuffer-count-marked-lines))
1404       (message "No buffers marked; use 'm' to mark a buffer")
1405     (let ((ibuffer-copy-filename-as-kill-result "")
1406           (type (cond ((or (null arg) (zerop arg))
1407                        'full)
1408                       ((= arg 4)
1409                        'relative)
1410                       (t
1411                        'name))))
1412       (ibuffer-map-marked-lines
1413        #'(lambda (buf _mark)
1414            (setq ibuffer-copy-filename-as-kill-result
1415                  (concat ibuffer-copy-filename-as-kill-result
1416                          (let ((name (buffer-file-name buf)))
1417                            (cond (name
1418                                   (concat
1419                                    (pcase type
1420                                      (`full
1421                                       name)
1422                                      (`relative
1423                                       (file-relative-name
1424                                        name (or ibuffer-default-directory
1425                                                 default-directory)))
1426                                      (_
1427                                       (file-name-nondirectory name))) " "))
1428                                  (t "")))))))
1429       (when (not (zerop (length ibuffer-copy-filename-as-kill-result)))
1430         (setq ibuffer-copy-filename-as-kill-result
1431               (substring ibuffer-copy-filename-as-kill-result 0 -1)))
1432       (kill-new ibuffer-copy-filename-as-kill-result))))
1433
1434 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1435   (let ((count
1436          (ibuffer-map-lines
1437           #'(lambda (buf _mark)
1438               (when (funcall func buf)
1439                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1440                                         ibuffer-marked-char))
1441                 t))
1442           nil
1443           group)))
1444     (ibuffer-redisplay t)
1445     (unless (eq ibuffer-mark-on-buffer-mark ?\s)
1446       (message "Marked %s buffers" count))))
1447
1448 ;;;###autoload
1449 (defun ibuffer-mark-by-name-regexp (regexp)
1450   "Mark all buffers whose name matches REGEXP."
1451   (interactive "sMark by name (regexp): ")
1452   (ibuffer-mark-on-buffer
1453    #'(lambda (buf)
1454        (string-match regexp (buffer-name buf)))))
1455
1456 ;;;###autoload
1457 (defun ibuffer-mark-by-mode-regexp (regexp)
1458   "Mark all buffers whose major mode matches REGEXP."
1459   (interactive "sMark by major mode (regexp): ")
1460   (ibuffer-mark-on-buffer
1461    #'(lambda (buf)
1462        (with-current-buffer buf
1463          (string-match regexp (format-mode-line mode-name nil nil buf))))))
1464
1465 ;;;###autoload
1466 (defun ibuffer-mark-by-file-name-regexp (regexp)
1467   "Mark all buffers whose file name matches REGEXP."
1468   (interactive "sMark by file name (regexp): ")
1469   (ibuffer-mark-on-buffer
1470    #'(lambda (buf)
1471        (let ((name (or (buffer-file-name buf)
1472                        (with-current-buffer buf
1473                          (and
1474                           (boundp 'dired-directory)
1475                           (stringp dired-directory)
1476                           dired-directory)))))
1477          (when name
1478            (string-match regexp name))))))
1479
1480 ;;;###autoload
1481 (defun ibuffer-mark-by-mode (mode)
1482   "Mark all buffers whose major mode equals MODE."
1483   (interactive
1484    (let* ((buf (ibuffer-current-buffer))
1485           (default (if (and buf (buffer-live-p buf))
1486                        (symbol-name (buffer-local-value
1487                                      'major-mode buf)))))
1488      (list (intern
1489             (completing-read
1490              (if default
1491                  (format "Mark by major mode (default %s): " default)
1492                "Mark by major mode: ")
1493              (ibuffer-list-buffer-modes) nil t nil nil default)))))
1494   (ibuffer-mark-on-buffer
1495    #'(lambda (buf)
1496        (eq (buffer-local-value 'major-mode buf) mode))))
1497
1498 ;;;###autoload
1499 (defun ibuffer-mark-modified-buffers ()
1500   "Mark all modified buffers."
1501   (interactive)
1502   (ibuffer-mark-on-buffer
1503    #'(lambda (buf) (buffer-modified-p buf))))
1504
1505 ;;;###autoload
1506 (defun ibuffer-mark-unsaved-buffers ()
1507   "Mark all modified buffers that have an associated file."
1508   (interactive)
1509   (ibuffer-mark-on-buffer
1510    #'(lambda (buf) (and (buffer-local-value 'buffer-file-name buf)
1511                         (buffer-modified-p buf)))))
1512
1513 ;;;###autoload
1514 (defun ibuffer-mark-dissociated-buffers ()
1515   "Mark all buffers whose associated file does not exist."
1516   (interactive)
1517   (ibuffer-mark-on-buffer
1518    #'(lambda (buf)
1519        (with-current-buffer buf
1520          (or
1521           (and buffer-file-name
1522                (not (file-exists-p buffer-file-name)))
1523           (and (eq major-mode 'dired-mode)
1524                (boundp 'dired-directory)
1525                (stringp dired-directory)
1526                (not (file-exists-p (file-name-directory dired-directory)))))))))
1527
1528 ;;;###autoload
1529 (defun ibuffer-mark-help-buffers ()
1530   "Mark buffers whose major mode is in variable `ibuffer-help-buffer-modes'."
1531   (interactive)
1532   (ibuffer-mark-on-buffer
1533    #'(lambda (buf)
1534        (with-current-buffer buf
1535          (memq major-mode ibuffer-help-buffer-modes)))))
1536
1537 ;;;###autoload
1538 (defun ibuffer-mark-compressed-file-buffers ()
1539   "Mark buffers whose associated file is compressed."
1540   (interactive)
1541   (ibuffer-mark-on-buffer
1542    #'(lambda (buf)
1543        (with-current-buffer buf
1544          (and buffer-file-name
1545               (string-match ibuffer-compressed-file-name-regexp
1546                            buffer-file-name))))))
1547
1548 ;;;###autoload
1549 (defun ibuffer-mark-old-buffers ()
1550   "Mark buffers which have not been viewed in `ibuffer-old-time' hours."
1551   (interactive)
1552   (ibuffer-mark-on-buffer
1553    #'(lambda (buf)
1554        (with-current-buffer buf
1555          ;; hacked from midnight.el
1556          (when buffer-display-time
1557            (let* ((now (float-time))
1558                   (then (float-time buffer-display-time)))
1559              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1560
1561 ;;;###autoload
1562 (defun ibuffer-mark-special-buffers ()
1563   "Mark all buffers whose name begins and ends with `*'."
1564   (interactive)
1565   (ibuffer-mark-on-buffer
1566    #'(lambda (buf) (string-match "^\\*.+\\*$"
1567                                  (buffer-name buf)))))
1568
1569 ;;;###autoload
1570 (defun ibuffer-mark-read-only-buffers ()
1571   "Mark all read-only buffers."
1572   (interactive)
1573   (ibuffer-mark-on-buffer
1574    #'(lambda (buf) (buffer-local-value 'buffer-read-only buf))))
1575
1576 ;;;###autoload
1577 (defun ibuffer-mark-dired-buffers ()
1578   "Mark all `dired' buffers."
1579   (interactive)
1580   (ibuffer-mark-on-buffer
1581    #'(lambda (buf) (eq (buffer-local-value 'major-mode buf) 'dired-mode))))
1582
1583 ;;;###autoload
1584 (defun ibuffer-do-occur (regexp &optional nlines)
1585   "View lines which match REGEXP in all marked buffers.
1586 Optional argument NLINES says how many lines of context to display: it
1587 defaults to one."
1588   (interactive (occur-read-primary-args))
1589   (if (or (not (integerp nlines))
1590           (< nlines 0))
1591       (setq nlines 0))
1592   (when (zerop (ibuffer-count-marked-lines))
1593     (ibuffer-set-mark ibuffer-marked-char))
1594   (let ((ibuffer-do-occur-bufs nil))
1595     ;; Accumulate a list of marked buffers
1596     (ibuffer-map-marked-lines
1597      #'(lambda (buf _mark)
1598          (push buf ibuffer-do-occur-bufs)))
1599     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1600
1601 (provide 'ibuf-ext)
1602
1603 ;; Local Variables:
1604 ;; generated-autoload-file: "ibuffer-loaddefs.el"
1605 ;; End:
1606
1607 ;;; ibuf-ext.el ends here