lisp/ruler-mode.el

   1 ;;; ruler-mode.el --- display a ruler in the header line
   2
   3 ;; Copyright (C) 2001-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: David Ponce <david@dponce.com>
   6 ;; Maintainer: David Ponce <david@dponce.com>
   7 ;; Created: 24 Mar 2001
   8 ;; Version: 1.6
   9 ;; Keywords: convenience
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; This library provides a minor mode to display a ruler in the header
  29 ;; line.  It works from Emacs 21 onwards.
  30 ;;
  31 ;; You can use the mouse to change the `fill-column' `comment-column',
  32 ;; `goal-column', `window-margins' and `tab-stop-list' settings:
  33 ;;
  34 ;; [header-line (shift down-mouse-1)] set left margin end to the ruler
  35 ;; graduation where the mouse pointer is on.
  36 ;;
  37 ;; [header-line (shift down-mouse-3)] set right margin beginning to
  38 ;; the ruler graduation where the mouse pointer is on.
  39 ;;
  40 ;; [header-line down-mouse-2] Drag the `fill-column', `comment-column'
  41 ;; or `goal-column' to a ruler graduation.
  42 ;;
  43 ;; [header-line (control down-mouse-1)] add a tab stop to the ruler
  44 ;; graduation where the mouse pointer is on.
  45 ;;
  46 ;; [header-line (control down-mouse-3)] remove the tab stop at the
  47 ;; ruler graduation where the mouse pointer is on.
  48 ;;
  49 ;; [header-line (control down-mouse-2)] or M-x
  50 ;; `ruler-mode-toggle-show-tab-stops' toggle showing and visually
  51 ;; editing `tab-stop-list' setting.  The `ruler-mode-show-tab-stops'
  52 ;; option controls if the ruler shows tab stops by default.
  53 ;;
  54 ;; In the ruler the character `ruler-mode-current-column-char' shows
  55 ;; the `current-column' location, `ruler-mode-fill-column-char' shows
  56 ;; the `fill-column' location, `ruler-mode-comment-column-char' shows
  57 ;; the `comment-column' location, `ruler-mode-goal-column-char' shows
  58 ;; the `goal-column' and `ruler-mode-tab-stop-char' shows tab stop
  59 ;; locations.  Graduations in `window-margins' and `window-fringes'
  60 ;; areas are shown with a different foreground color.
  61 ;;
  62 ;; It is also possible to customize the following characters:
  63 ;;
  64 ;; - `ruler-mode-basic-graduation-char' character used for basic
  65 ;;   graduations ('.' by default).
  66 ;; - `ruler-mode-inter-graduation-char' character used for
  67 ;;   intermediate graduations ('!' by default).
  68 ;;
  69 ;; The following faces are customizable:
  70 ;;
  71 ;; - `ruler-mode-default' the ruler default face.
  72 ;; - `ruler-mode-fill-column' the face used to highlight the
  73 ;;   `fill-column' character.
  74 ;; - `ruler-mode-comment-column' the face used to highlight the
  75 ;;   `comment-column' character.
  76 ;; - `ruler-mode-goal-column' the face used to highlight the
  77 ;;   `goal-column' character.
  78 ;; - `ruler-mode-current-column' the face used to highlight the
  79 ;;   `current-column' character.
  80 ;; - `ruler-mode-tab-stop' the face used to highlight tab stop
  81 ;;   characters.
  82 ;; - `ruler-mode-margins' the face used to highlight graduations
  83 ;;   in the `window-margins' areas.
  84 ;; - `ruler-mode-fringes' the face used to highlight graduations
  85 ;;   in the `window-fringes' areas.
  86 ;; - `ruler-mode-column-number' the face used to highlight the
  87 ;;   numbered graduations.
  88 ;;
  89 ;; `ruler-mode-default' inherits from the built-in `default' face.
  90 ;; All `ruler-mode' faces inherit from `ruler-mode-default'.
  91 ;;
  92 ;; WARNING: To keep ruler graduations aligned on text columns it is
  93 ;; important to use the same font family and size for ruler and text
  94 ;; areas.
  95 ;;
  96 ;; You can override the ruler format by defining an appropriate
  97 ;; function as the buffer-local value of `ruler-mode-ruler-function'.
  98
  99 ;; Installation
 100 ;;
 101 ;; To automatically display the ruler in specific major modes use:
 102 ;;
 103 ;;    (add-hook '<major-mode>-hook 'ruler-mode)
 104 ;;
 105
 106 ;;; History:
 107 ;;
 108 \f
 109 ;;; Code:
 110 (eval-when-compile
 111   (require 'wid-edit))
 112 (require 'scroll-bar)
 113 (require 'fringe)
 114
 115 (defgroup ruler-mode nil
 116   "Display a ruler in the header line."
 117   :version "22.1"
 118   :group 'convenience)
 119
 120 (defcustom ruler-mode-show-tab-stops nil
 121   "If non-nil the ruler shows tab stop positions.
 122 Also allowing to visually change `tab-stop-list' setting using
 123 <C-down-mouse-1> and <C-down-mouse-3> on the ruler to respectively add
 124 or remove a tab stop.  \\[ruler-mode-toggle-show-tab-stops] or
 125 <C-down-mouse-2> on the ruler toggles showing/editing of tab stops."
 126   :group 'ruler-mode
 127   :type 'boolean)
 128
 129 ;; IMPORTANT: This function must be defined before the following
 130 ;; defcustoms because it is used in their :validate clause.
 131 (defun ruler-mode-character-validate (widget)
 132   "Ensure WIDGET value is a valid character value."
 133   (save-excursion
 134     (let ((value (widget-value widget)))
 135       (unless (characterp value)
 136         (widget-put widget :error
 137                     (format "Invalid character value: %S" value))
 138         widget))))
 139
 140 (defcustom ruler-mode-fill-column-char (if (char-displayable-p ?¶)
 141                                            ?\¶
 142                                          ?\|)
 143   "Character used at the `fill-column' location."
 144   :group 'ruler-mode
 145   :type '(choice
 146           (character :tag "Character")
 147           (integer :tag "Integer char value"
 148                    :validate ruler-mode-character-validate)))
 149
 150 (defcustom ruler-mode-comment-column-char ?\#
 151   "Character used at the `comment-column' location."
 152   :group 'ruler-mode
 153   :type '(choice
 154           (character :tag "Character")
 155           (integer :tag "Integer char value"
 156                    :validate ruler-mode-character-validate)))
 157
 158 (defcustom ruler-mode-goal-column-char ?G
 159   "Character used at the `goal-column' location."
 160   :group 'ruler-mode
 161   :type '(choice
 162           (character :tag "Character")
 163           (integer :tag "Integer char value"
 164                    :validate ruler-mode-character-validate)))
 165
 166 (defcustom ruler-mode-current-column-char (if (char-displayable-p ?¦)
 167                                               ?\¦
 168                                             ?\@)
 169   "Character used at the `current-column' location."
 170   :group 'ruler-mode
 171   :type '(choice
 172           (character :tag "Character")
 173           (integer :tag "Integer char value"
 174                    :validate ruler-mode-character-validate)))
 175
 176 (defcustom ruler-mode-tab-stop-char ?\T
 177   "Character used at `tab-stop-list' locations."
 178   :group 'ruler-mode
 179   :type '(choice
 180           (character :tag "Character")
 181           (integer :tag "Integer char value"
 182                    :validate ruler-mode-character-validate)))
 183
 184 (defcustom ruler-mode-basic-graduation-char ?\.
 185   "Character used for basic graduations."
 186   :group 'ruler-mode
 187   :type '(choice
 188           (character :tag "Character")
 189           (integer :tag "Integer char value"
 190                    :validate ruler-mode-character-validate)))
 191
 192 (defcustom ruler-mode-inter-graduation-char ?\!
 193   "Character used for intermediate graduations."
 194   :group 'ruler-mode
 195   :type '(choice
 196           (character :tag "Character")
 197           (integer :tag "Integer char value"
 198                    :validate ruler-mode-character-validate)))
 199
 200 (defcustom ruler-mode-set-goal-column-ding-flag t
 201   "Non-nil means do `ding' when `goal-column' is set."
 202   :group 'ruler-mode
 203   :type 'boolean)
 204 \f
 205 (defface ruler-mode-default
 206   '((((type tty))
 207      (:inherit default
 208                :background "grey64"
 209                :foreground "grey50"
 210                ))
 211     (t
 212      (:inherit default
 213                :background "grey76"
 214                :foreground "grey64"
 215                :box (:color "grey76"
 216                             :line-width 1
 217                             :style released-button)
 218                )))
 219   "Default face used by the ruler."
 220   :group 'ruler-mode)
 221
 222 (defface ruler-mode-pad
 223   '((((type tty))
 224      (:inherit ruler-mode-default
 225                :background "grey50"
 226                ))
 227     (t
 228      (:inherit ruler-mode-default
 229                :background "grey64"
 230                )))
 231   "Face used to pad inactive ruler areas."
 232   :group 'ruler-mode)
 233
 234 (defface ruler-mode-margins
 235   '((t
 236      (:inherit ruler-mode-default
 237                :foreground "white"
 238                )))
 239   "Face used to highlight margin areas."
 240   :group 'ruler-mode)
 241
 242 (defface ruler-mode-fringes
 243   '((t
 244      (:inherit ruler-mode-default
 245                :foreground "green"
 246                )))
 247   "Face used to highlight fringes areas."
 248   :group 'ruler-mode)
 249
 250 (defface ruler-mode-column-number
 251   '((t
 252      (:inherit ruler-mode-default
 253                :foreground "black"
 254                )))
 255   "Face used to highlight number graduations."
 256   :group 'ruler-mode)
 257
 258 (defface ruler-mode-fill-column
 259   '((t
 260      (:inherit ruler-mode-default
 261                :foreground "red"
 262                )))
 263   "Face used to highlight the fill column character."
 264   :group 'ruler-mode)
 265
 266 (defface ruler-mode-comment-column
 267   '((t
 268      (:inherit ruler-mode-default
 269                :foreground "red"
 270                )))
 271   "Face used to highlight the comment column character."
 272   :group 'ruler-mode)
 273
 274 (defface ruler-mode-goal-column
 275   '((t
 276      (:inherit ruler-mode-default
 277                :foreground "red"
 278                )))
 279   "Face used to highlight the goal column character."
 280   :group 'ruler-mode)
 281
 282 (defface ruler-mode-tab-stop
 283   '((t
 284      (:inherit ruler-mode-default
 285                :foreground "steelblue"
 286                )))
 287   "Face used to highlight tab stop characters."
 288   :group 'ruler-mode)
 289
 290 (defface ruler-mode-current-column
 291   '((t
 292      (:inherit ruler-mode-default
 293                :weight bold
 294                :foreground "yellow"
 295                )))
 296   "Face used to highlight the `current-column' character."
 297   :group 'ruler-mode)
 298 \f
 299
 300 (defsubst ruler-mode-full-window-width ()
 301   "Return the full width of the selected window."
 302   (let ((edges (window-edges)))
 303     (- (nth 2 edges) (nth 0 edges))))
 304
 305 (defsubst ruler-mode-window-col (n)
 306   "Return a column number relative to the selected window.
 307 N is a column number relative to selected frame."
 308   (- n
 309      (car (window-edges))
 310      (or (car (window-margins)) 0)
 311      (fringe-columns 'left)
 312      (scroll-bar-columns 'left)))
 313 \f
 314 (defun ruler-mode-mouse-set-left-margin (start-event)
 315   "Set left margin end to the graduation where the mouse pointer is on.
 316 START-EVENT is the mouse click event."
 317   (interactive "e")
 318   (let* ((start (event-start start-event))
 319          (end   (event-end   start-event))
 320          col w lm rm)
 321     (when (eq start end) ;; mouse click
 322       (save-selected-window
 323         (select-window (posn-window start))
 324         (setq col (- (car (posn-col-row start)) (car (window-edges))
 325                      (scroll-bar-columns 'left))
 326               w   (- (ruler-mode-full-window-width)
 327                      (scroll-bar-columns 'left)
 328                      (scroll-bar-columns 'right)))
 329         (when (and (>= col 0) (< col w))
 330           (setq lm (window-margins)
 331                 rm (or (cdr lm) 0)
 332                 lm (or (car lm) 0))
 333           (message "Left margin set to %d (was %d)" col lm)
 334           (set-window-margins nil col rm))))))
 335
 336 (defun ruler-mode-mouse-set-right-margin (start-event)
 337   "Set right margin beginning to the graduation where the mouse pointer is on.
 338 START-EVENT is the mouse click event."
 339   (interactive "e")
 340   (let* ((start (event-start start-event))
 341          (end   (event-end   start-event))
 342          col w lm rm)
 343     (when (eq start end) ;; mouse click
 344       (save-selected-window
 345         (select-window (posn-window start))
 346         (setq col (- (car (posn-col-row start)) (car (window-edges))
 347                      (scroll-bar-columns 'left))
 348               w   (- (ruler-mode-full-window-width)
 349                      (scroll-bar-columns 'left)
 350                      (scroll-bar-columns 'right)))
 351         (when (and (>= col 0) (< col w))
 352           (setq lm  (window-margins)
 353                 rm  (or (cdr lm) 0)
 354                 lm  (or (car lm) 0)
 355                 col (- w col 1))
 356           (message "Right margin set to %d (was %d)" col rm)
 357           (set-window-margins nil lm col))))))
 358
 359 (defvar ruler-mode-dragged-symbol nil
 360   "Column symbol dragged in the ruler.
 361 That is `fill-column', `comment-column', `goal-column', or nil when
 362 nothing is dragged.")
 363
 364 (defun ruler-mode-mouse-grab-any-column (start-event)
 365   "Drag a column symbol on the ruler.
 366 Start dragging on mouse down event START-EVENT, and update the column
 367 symbol value with the current value of the ruler graduation while
 368 dragging.  See also the variable `ruler-mode-dragged-symbol'."
 369   (interactive "e")
 370   (setq ruler-mode-dragged-symbol nil)
 371   (let* ((start (event-start start-event))
 372          col newc oldc)
 373     (save-selected-window
 374       (select-window (posn-window start))
 375       (setq col  (ruler-mode-window-col (car (posn-col-row start)))
 376             newc (+ col (window-hscroll)))
 377       (and
 378        (>= col 0) (< col (window-width))
 379        (cond
 380
 381         ;; Handle the fill column.
 382         ((eq newc fill-column)
 383          (setq oldc fill-column
 384                ruler-mode-dragged-symbol 'fill-column)
 385          t) ;; Start dragging
 386
 387         ;; Handle the comment column.
 388         ((eq newc comment-column)
 389          (setq oldc comment-column
 390                ruler-mode-dragged-symbol 'comment-column)
 391          t) ;; Start dragging
 392
 393         ;; Handle the goal column.
 394         ;; A. On mouse down on the goal column character on the ruler,
 395         ;;    update the `goal-column' value while dragging.
 396         ;; B. If `goal-column' is nil, set the goal column where the
 397         ;;    mouse is clicked.
 398         ;; C. On mouse click on the goal column character on the
 399         ;;    ruler, unset the goal column.
 400         ((eq newc goal-column)          ; A. Drag the goal column.
 401          (setq oldc goal-column
 402                ruler-mode-dragged-symbol 'goal-column)
 403          t) ;; Start dragging
 404
 405         ((null goal-column)             ; B. Set the goal column.
 406          (setq oldc goal-column
 407                goal-column newc)
 408          ;; mouse-2 coming AFTER drag-mouse-2 invokes `ding'.  This
 409          ;; `ding' flushes the next messages about setting goal
 410          ;; column.  So here I force fetch the event(mouse-2) and
 411          ;; throw away.
 412          (read-event)
 413          ;; Ding BEFORE `message' is OK.
 414          (when ruler-mode-set-goal-column-ding-flag
 415            (ding))
 416          (message "Goal column set to %d (click on %s again to unset it)"
 417                   newc
 418                   (propertize (char-to-string ruler-mode-goal-column-char)
 419                               'face 'ruler-mode-goal-column))
 420          nil) ;; Don't start dragging.
 421         )
 422        (if (eq 'click (ruler-mode-mouse-drag-any-column-iteration
 423                        (posn-window start)))
 424            (when (eq 'goal-column ruler-mode-dragged-symbol)
 425              ;; C. Unset the goal column.
 426              (set-goal-column t))
 427          ;; At end of dragging, report the updated column symbol.
 428          (message "%s is set to %d (was %d)"
 429                   ruler-mode-dragged-symbol
 430                   (symbol-value ruler-mode-dragged-symbol)
 431                   oldc))))))
 432
 433 (defun ruler-mode-mouse-drag-any-column-iteration (window)
 434   "Update the ruler while dragging the mouse.
 435 WINDOW is the window where occurred the last down-mouse event.
 436 Return the symbol `drag' if the mouse has been dragged, or `click' if
 437 the mouse has been clicked."
 438   (let ((drags 0)
 439         event)
 440     (track-mouse
 441       (while (mouse-movement-p (setq event (read-event)))
 442         (setq drags (1+ drags))
 443         (when (eq window (posn-window (event-end event)))
 444           (ruler-mode-mouse-drag-any-column event)
 445           (force-mode-line-update))))
 446     (if (and (zerop drags) (eq 'click (car (event-modifiers event))))
 447         'click
 448       'drag)))
 449
 450 (defun ruler-mode-mouse-drag-any-column (start-event)
 451   "Update the value of the symbol dragged on the ruler.
 452 Called on each mouse motion event START-EVENT."
 453   (let* ((start (event-start start-event))
 454          (end   (event-end   start-event))
 455          col newc)
 456     (save-selected-window
 457       (select-window (posn-window start))
 458       (setq col  (ruler-mode-window-col (car (posn-col-row end)))
 459             newc (+ col (window-hscroll)))
 460       (when (and (>= col 0) (< col (window-width)))
 461         (set ruler-mode-dragged-symbol newc)))))
 462 \f
 463 (defun ruler-mode-mouse-add-tab-stop (start-event)
 464   "Add a tab stop to the graduation where the mouse pointer is on.
 465 START-EVENT is the mouse click event."
 466   (interactive "e")
 467   (when ruler-mode-show-tab-stops
 468     (let* ((start (event-start start-event))
 469            (end   (event-end   start-event))
 470            col ts)
 471       (when (eq start end) ;; mouse click
 472         (save-selected-window
 473           (select-window (posn-window start))
 474           (setq col (ruler-mode-window-col (car (posn-col-row start)))
 475                 ts  (+ col (window-hscroll)))
 476           (and (>= col 0) (< col (window-width))
 477                (not (member ts tab-stop-list))
 478                (progn
 479                  (message "Tab stop set to %d" ts)
 480                  (when (null tab-stop-list)
 481                    (setq tab-stop-list (indent-accumulate-tab-stops (1- ts))))
 482                  (setq tab-stop-list (sort (cons ts tab-stop-list) #'<)))))))))
 483
 484 (defun ruler-mode-mouse-del-tab-stop (start-event)
 485   "Delete tab stop at the graduation where the mouse pointer is on.
 486 START-EVENT is the mouse click event."
 487   (interactive "e")
 488   (when ruler-mode-show-tab-stops
 489     (let* ((start (event-start start-event))
 490            (end   (event-end   start-event))
 491            col ts)
 492       (when (eq start end) ;; mouse click
 493         (save-selected-window
 494           (select-window (posn-window start))
 495           (setq col (ruler-mode-window-col (car (posn-col-row start)))
 496                 ts  (+ col (window-hscroll)))
 497           (and (>= col 0) (< col (window-width))
 498                (member ts tab-stop-list)
 499                (progn
 500                  (message "Tab stop at %d deleted" ts)
 501                  (setq tab-stop-list (delete ts tab-stop-list)))))))))
 502
 503 (defun ruler-mode-toggle-show-tab-stops ()
 504   "Toggle showing of tab stops on the ruler."
 505   (interactive)
 506   (setq ruler-mode-show-tab-stops (not ruler-mode-show-tab-stops))
 507   (force-mode-line-update))
 508 \f
 509 (defvar ruler-mode-map
 510   (let ((km (make-sparse-keymap)))
 511     (define-key km [header-line down-mouse-1]
 512       #'ignore)
 513     (define-key km [header-line down-mouse-3]
 514       #'ignore)
 515     (define-key km [header-line down-mouse-2]
 516       #'ruler-mode-mouse-grab-any-column)
 517     (define-key km [header-line (shift down-mouse-1)]
 518       #'ruler-mode-mouse-set-left-margin)
 519     (define-key km [header-line (shift down-mouse-3)]
 520       #'ruler-mode-mouse-set-right-margin)
 521     (define-key km [header-line (control down-mouse-1)]
 522       #'ruler-mode-mouse-add-tab-stop)
 523     (define-key km [header-line (control down-mouse-3)]
 524       #'ruler-mode-mouse-del-tab-stop)
 525     (define-key km [header-line (control down-mouse-2)]
 526       #'ruler-mode-toggle-show-tab-stops)
 527     (define-key km [header-line (shift mouse-1)]
 528       'ignore)
 529     (define-key km [header-line (shift mouse-3)]
 530       'ignore)
 531     (define-key km [header-line (control mouse-1)]
 532       'ignore)
 533     (define-key km [header-line (control mouse-3)]
 534       'ignore)
 535     (define-key km [header-line (control mouse-2)]
 536       'ignore)
 537     km)
 538   "Keymap for ruler minor mode.")
 539
 540 (defvar ruler-mode-header-line-format-old nil
 541   "Hold previous value of `header-line-format'.")
 542
 543 (defvar ruler-mode-ruler-function 'ruler-mode-ruler
 544   "Function to call to return ruler header line format.
 545 This variable is expected to be made buffer-local by modes.")
 546
 547 (defconst ruler-mode-header-line-format
 548   '(:eval (funcall ruler-mode-ruler-function))
 549   "`header-line-format' used in ruler mode.
 550 Call `ruler-mode-ruler-function' to compute the ruler value.")
 551
 552 ;;;###autoload
 553 (defvar ruler-mode nil
 554   "Non-nil if Ruler mode is enabled.
 555 Use the command `ruler-mode' to change this variable.")
 556 (make-variable-buffer-local 'ruler-mode)
 557
 558 (defun ruler--save-header-line-format ()
 559   "Install the header line format for Ruler mode.
 560 Unless Ruler mode is already enabled, save the old header line
 561 format first."
 562   (when (and (not ruler-mode)
 563              (local-variable-p 'header-line-format)
 564              (not (local-variable-p 'ruler-mode-header-line-format-old)))
 565     (set (make-local-variable 'ruler-mode-header-line-format-old)
 566          header-line-format))
 567   (setq header-line-format ruler-mode-header-line-format))
 568
 569 ;;;###autoload
 570 (define-minor-mode ruler-mode
 571   "Toggle display of ruler in header line (Ruler mode).
 572 With a prefix argument ARG, enable Ruler mode if ARG is positive,
 573 and disable it otherwise.  If called from Lisp, enable the mode
 574 if ARG is omitted or nil."
 575   nil nil
 576   ruler-mode-map
 577   :group 'ruler-mode
 578   :variable (ruler-mode
 579              . (lambda (enable)
 580                  (when enable
 581                    (ruler--save-header-line-format))
 582                  (setq ruler-mode enable)))
 583   (if ruler-mode
 584       (add-hook 'post-command-hook 'force-mode-line-update nil t)
 585     ;; When `ruler-mode' is off restore previous header line format if
 586     ;; the current one is the ruler header line format.
 587     (when (eq header-line-format ruler-mode-header-line-format)
 588       (kill-local-variable 'header-line-format)
 589       (when (local-variable-p 'ruler-mode-header-line-format-old)
 590         (setq header-line-format ruler-mode-header-line-format-old)
 591         (kill-local-variable 'ruler-mode-header-line-format-old)))
 592     (remove-hook 'post-command-hook 'force-mode-line-update t)))
 593 \f
 594 ;; Add ruler-mode to the minor mode menu in the mode line
 595 (define-key mode-line-mode-menu [ruler-mode]
 596   `(menu-item "Ruler" ruler-mode
 597               :button (:toggle . ruler-mode)))
 598
 599 (defconst ruler-mode-ruler-help-echo
 600   "\
 601 S-mouse-1/3: set L/R margin, \
 602 mouse-2: set goal column, \
 603 C-mouse-2: show tabs"
 604   "Help string shown when mouse is over the ruler.
 605 `ruler-mode-show-tab-stops' is nil.")
 606
 607 (defconst ruler-mode-ruler-help-echo-when-goal-column
 608   "\
 609 S-mouse-1/3: set L/R margin, \
 610 C-mouse-2: show tabs"
 611   "Help string shown when mouse is over the ruler.
 612 `goal-column' is set and `ruler-mode-show-tab-stops' is nil.")
 613
 614 (defconst ruler-mode-ruler-help-echo-when-tab-stops
 615   "\
 616 C-mouse1/3: set/unset tab, \
 617 C-mouse-2: hide tabs"
 618   "Help string shown when mouse is over the ruler.
 619 `ruler-mode-show-tab-stops' is non-nil.")
 620
 621 (defconst ruler-mode-fill-column-help-echo
 622   "drag-mouse-2: set fill column"
 623   "Help string shown when mouse is on the fill column character.")
 624
 625 (defconst ruler-mode-comment-column-help-echo
 626   "drag-mouse-2: set comment column"
 627   "Help string shown when mouse is on the comment column character.")
 628
 629 (defconst ruler-mode-goal-column-help-echo
 630   "\
 631 drag-mouse-2: set goal column, \
 632 mouse-2: unset goal column"
 633   "Help string shown when mouse is on the goal column character.")
 634
 635 (defconst ruler-mode-margin-help-echo
 636   "%s margin %S"
 637   "Help string shown when mouse is over a margin area.")
 638
 639 (defconst ruler-mode-fringe-help-echo
 640   "%s fringe %S"
 641   "Help string shown when mouse is over a fringe area.")
 642
 643 (defsubst ruler-mode-space (width &rest props)
 644   "Return a single space string of WIDTH times the normal character width.
 645 Optional argument PROPS specifies other text properties to apply."
 646   (apply 'propertize " " 'display (list 'space :width width) props))
 647 \f
 648 (defun ruler-mode-ruler ()
 649   "Compute and return a header line ruler."
 650   (let* ((w (window-width))
 651          (m (window-margins))
 652          (f (window-fringes))
 653          (i 0)
 654          (j (window-hscroll))
 655          ;; Setup the scrollbar, fringes, and margins areas.
 656          (lf (ruler-mode-space
 657               'left-fringe
 658               'face 'ruler-mode-fringes
 659               'help-echo (format ruler-mode-fringe-help-echo
 660                                  "Left" (or (car f) 0))))
 661          (rf (ruler-mode-space
 662               'right-fringe
 663               'face 'ruler-mode-fringes
 664               'help-echo (format ruler-mode-fringe-help-echo
 665                                  "Right" (or (cadr f) 0))))
 666          (lm (ruler-mode-space
 667               'left-margin
 668               'face 'ruler-mode-margins
 669               'help-echo (format ruler-mode-margin-help-echo
 670                                  "Left" (or (car m) 0))))
 671          (rm (ruler-mode-space
 672               'right-margin
 673               'face 'ruler-mode-margins
 674               'help-echo (format ruler-mode-margin-help-echo
 675                                  "Right" (or (cdr m) 0))))
 676          (sb (ruler-mode-space
 677               'scroll-bar
 678               'face 'ruler-mode-pad))
 679          ;; Remember the scrollbar vertical type.
 680          (sbvt (car (window-current-scroll-bars)))
 681          ;; Create an "clean" ruler.
 682          (ruler
 683           (propertize
 684            (string-to-multibyte
 685             (make-string w ruler-mode-basic-graduation-char))
 686            'face 'ruler-mode-default
 687            'local-map ruler-mode-map
 688            'help-echo (cond
 689                        (ruler-mode-show-tab-stops
 690                         ruler-mode-ruler-help-echo-when-tab-stops)
 691                        (goal-column
 692                         ruler-mode-ruler-help-echo-when-goal-column)
 693                        (ruler-mode-ruler-help-echo))))
 694          k c)
 695     ;; Setup the active area.
 696     (while (< i w)
 697       ;; Graduations.
 698       (cond
 699        ;; Show a number graduation.
 700        ((= (mod j 10) 0)
 701         (setq c (number-to-string (/ j 10))
 702               m (length c)
 703               k i)
 704         (put-text-property
 705          i (1+ i) 'face 'ruler-mode-column-number
 706          ruler)
 707         (while (and (> m 0) (>= k 0))
 708           (aset ruler k (aref c (setq m (1- m))))
 709           (setq k (1- k))))
 710        ;; Show an intermediate graduation.
 711        ((= (mod j 5) 0)
 712         (aset ruler i ruler-mode-inter-graduation-char)))
 713       ;; Special columns.
 714       (cond
 715        ;; Show the `current-column' marker.
 716        ((= j (current-column))
 717         (aset ruler i ruler-mode-current-column-char)
 718         (put-text-property
 719          i (1+ i) 'face 'ruler-mode-current-column
 720          ruler))
 721        ;; Show the `goal-column' marker.
 722        ((and goal-column (= j goal-column))
 723         (aset ruler i ruler-mode-goal-column-char)
 724         (put-text-property
 725          i (1+ i) 'face 'ruler-mode-goal-column
 726          ruler)
 727         (put-text-property
 728          i (1+ i) 'mouse-face 'mode-line-highlight
 729          ruler)
 730         (put-text-property
 731          i (1+ i) 'help-echo ruler-mode-goal-column-help-echo
 732          ruler))
 733        ;; Show the `comment-column' marker.
 734        ((= j comment-column)
 735         (aset ruler i ruler-mode-comment-column-char)
 736         (put-text-property
 737          i (1+ i) 'face 'ruler-mode-comment-column
 738          ruler)
 739         (put-text-property
 740          i (1+ i) 'mouse-face 'mode-line-highlight
 741          ruler)
 742         (put-text-property
 743          i (1+ i) 'help-echo ruler-mode-comment-column-help-echo
 744          ruler))
 745        ;; Show the `fill-column' marker.
 746        ((= j fill-column)
 747         (aset ruler i ruler-mode-fill-column-char)
 748         (put-text-property
 749          i (1+ i) 'face 'ruler-mode-fill-column
 750          ruler)
 751         (put-text-property
 752          i (1+ i) 'mouse-face 'mode-line-highlight
 753          ruler)
 754         (put-text-property
 755          i (1+ i) 'help-echo ruler-mode-fill-column-help-echo
 756          ruler))
 757        ;; Show the `tab-stop-list' markers.
 758        ((and ruler-mode-show-tab-stops (= j (indent-next-tab-stop (1- j))))
 759         (aset ruler i ruler-mode-tab-stop-char)
 760         (put-text-property
 761          i (1+ i) 'face 'ruler-mode-tab-stop
 762          ruler)))
 763       (setq i (1+ i)
 764             j (1+ j)))
 765     ;; Return the ruler propertized string.  Using list here,
 766     ;; instead of concat visually separate the different areas.
 767     (if (nth 2 (window-fringes))
 768         ;; fringes outside margins.
 769         (list "" (and (eq 'left sbvt) sb) lf lm
 770               ruler rm rf (and (eq 'right sbvt) sb))
 771       ;; fringes inside margins.
 772       (list "" (and (eq 'left sbvt) sb) lm lf
 773             ruler rf rm (and (eq 'right sbvt) sb)))))
 774
 775 (provide 'ruler-mode)
 776
 777 ;; Local Variables:
 778 ;; coding: utf-8
 779 ;; End:
 780
 781 ;;; ruler-mode.el ends here