lisp/progmodes/ruby-mode.el

   1 ;;; ruby-mode.el --- Major mode for editing Ruby files
   2
   3 ;; Copyright (C) 1994-2012  Free Software Foundation, Inc.
   4
   5 ;; Authors: Yukihiro Matsumoto
   6 ;;      Nobuyoshi Nakada
   7 ;; URL: http://www.emacswiki.org/cgi-bin/wiki/RubyMode
   8 ;; Created: Fri Feb  4 14:49:13 JST 1994
   9 ;; Keywords: languages ruby
  10 ;; Version: 1.0
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; Provides font-locking, indentation support, and navigation for Ruby code.
  30 ;;
  31 ;; If you're installing manually, you should add this to your .emacs
  32 ;; file after putting it on your load path:
  33 ;;
  34 ;;    (autoload 'ruby-mode "ruby-mode" "Major mode for ruby files" t)
  35 ;;    (add-to-list 'auto-mode-alist '("\\.rb$" . ruby-mode))
  36 ;;    (add-to-list 'interpreter-mode-alist '("ruby" . ruby-mode))
  37 ;;
  38 ;; Still needs more docstrings; search below for TODO.
  39
  40 ;;; Code:
  41
  42 (eval-when-compile (require 'cl))
  43
  44 (defgroup ruby nil
  45   "Major mode for editing Ruby code."
  46   :prefix "ruby-"
  47   :group 'languages)
  48
  49 (defconst ruby-keyword-end-re
  50   (if (string-match "\\_>" "ruby")
  51       "\\_>"
  52     "\\>"))
  53
  54 (defconst ruby-block-beg-keywords
  55   '("class" "module" "def" "if" "unless" "case" "while" "until" "for" "begin" "do")
  56   "Keywords at the beginning of blocks.")
  57
  58 (defconst ruby-block-beg-re
  59   (regexp-opt ruby-block-beg-keywords)
  60   "Regexp to match the beginning of blocks.")
  61
  62 (defconst ruby-non-block-do-re
  63   (concat (regexp-opt '("while" "until" "for" "rescue") t) ruby-keyword-end-re)
  64   "Regexp to match keywords that nest without blocks.")
  65
  66 (defconst ruby-indent-beg-re
  67   (concat "\\(\\s *" (regexp-opt '("class" "module" "def") t) "\\)\\|"
  68           (regexp-opt '("if" "unless" "case" "while" "until" "for" "begin")))
  69   "Regexp to match where the indentation gets deeper.")
  70
  71 (defconst ruby-modifier-beg-keywords
  72   '("if" "unless" "while" "until")
  73   "Modifiers that are the same as the beginning of blocks.")
  74
  75 (defconst ruby-modifier-beg-re
  76   (regexp-opt ruby-modifier-beg-keywords)
  77   "Regexp to match modifiers same as the beginning of blocks.")
  78
  79 (defconst ruby-modifier-re
  80   (regexp-opt (cons "rescue" ruby-modifier-beg-keywords))
  81   "Regexp to match modifiers.")
  82
  83 (defconst ruby-block-mid-keywords
  84   '("then" "else" "elsif" "when" "rescue" "ensure")
  85   "Keywords where the indentation gets shallower in middle of block statements.")
  86
  87 (defconst ruby-block-mid-re
  88   (regexp-opt ruby-block-mid-keywords)
  89   "Regexp to match where the indentation gets shallower in middle of block statements.")
  90
  91 (defconst ruby-block-op-keywords
  92   '("and" "or" "not")
  93   "Regexp to match boolean keywords.")
  94
  95 (defconst ruby-block-hanging-re
  96   (regexp-opt (append ruby-modifier-beg-keywords ruby-block-op-keywords))
  97   "Regexp to match hanging block modifiers.")
  98
  99 (defconst ruby-block-end-re "\\_<end\\_>")
 100
 101 (eval-and-compile
 102   (defconst ruby-here-doc-beg-re
 103   "\\(<\\)<\\(-\\)?\\(\\([a-zA-Z0-9_]+\\)\\|[\"]\\([^\"]+\\)[\"]\\|[']\\([^']+\\)[']\\)"
 104     "Regexp to match the beginning of a heredoc."))
 105
 106 (defun ruby-here-doc-end-match ()
 107   "Return a regexp to find the end of a heredoc.
 108
 109 This should only be called after matching against `ruby-here-doc-beg-re'."
 110   (concat "^"
 111           (if (match-string 2) "[ \t]*" nil)
 112           (regexp-quote
 113            (or (match-string 4)
 114                (match-string 5)
 115                (match-string 6)))))
 116
 117 (defconst ruby-delimiter
 118   (concat "[?$/%(){}#\"'`.:]\\|<<\\|\\[\\|\\]\\|\\_<\\("
 119           ruby-block-beg-re
 120           "\\)\\_>\\|" ruby-block-end-re
 121           "\\|^=begin\\|" ruby-here-doc-beg-re))
 122
 123 (defconst ruby-negative
 124   (concat "^[ \t]*\\(\\(" ruby-block-mid-re "\\)\\>\\|"
 125           ruby-block-end-re "\\|}\\|\\]\\)")
 126   "Regexp to match where the indentation gets shallower.")
 127
 128 (defconst ruby-operator-re "[-,.+*/%&|^~=<>:]"
 129   "Regexp to match operators.")
 130
 131 (defconst ruby-symbol-chars "a-zA-Z0-9_"
 132   "List of characters that symbol names may contain.")
 133 (defconst ruby-symbol-re (concat "[" ruby-symbol-chars "]")
 134   "Regexp to match symbols.")
 135
 136 (define-abbrev-table 'ruby-mode-abbrev-table ()
 137   "Abbrev table in use in Ruby mode buffers.")
 138
 139 (defvar ruby-mode-map
 140   (let ((map (make-sparse-keymap)))
 141     (define-key map "{" 'ruby-electric-brace)
 142     (define-key map "}" 'ruby-electric-brace)
 143     (define-key map (kbd "M-C-a") 'ruby-beginning-of-defun)
 144     (define-key map (kbd "M-C-e") 'ruby-end-of-defun)
 145     (define-key map (kbd "M-C-b") 'ruby-backward-sexp)
 146     (define-key map (kbd "M-C-f") 'ruby-forward-sexp)
 147     (define-key map (kbd "M-C-p") 'ruby-beginning-of-block)
 148     (define-key map (kbd "M-C-n") 'ruby-end-of-block)
 149     (define-key map (kbd "M-C-h") 'ruby-mark-defun)
 150     (define-key map (kbd "M-C-q") 'ruby-indent-exp)
 151     (define-key map (kbd "C-M-h") 'backward-kill-word)
 152     (define-key map (kbd "C-j")   'reindent-then-newline-and-indent)
 153     (define-key map (kbd "C-m")   'newline)
 154     (define-key map (kbd "C-c C-c") 'comment-region)
 155     map)
 156   "Keymap used in Ruby mode.")
 157
 158 (defvar ruby-mode-syntax-table
 159   (let ((table (make-syntax-table)))
 160     (modify-syntax-entry ?\' "\"" table)
 161     (modify-syntax-entry ?\" "\"" table)
 162     (modify-syntax-entry ?\` "\"" table)
 163     (modify-syntax-entry ?# "<" table)
 164     (modify-syntax-entry ?\n ">" table)
 165     (modify-syntax-entry ?\\ "\\" table)
 166     (modify-syntax-entry ?$ "." table)
 167     (modify-syntax-entry ?? "_" table)
 168     (modify-syntax-entry ?_ "_" table)
 169     (modify-syntax-entry ?: "_" table)
 170     (modify-syntax-entry ?< "." table)
 171     (modify-syntax-entry ?> "." table)
 172     (modify-syntax-entry ?& "." table)
 173     (modify-syntax-entry ?| "." table)
 174     (modify-syntax-entry ?% "." table)
 175     (modify-syntax-entry ?= "." table)
 176     (modify-syntax-entry ?/ "." table)
 177     (modify-syntax-entry ?+ "." table)
 178     (modify-syntax-entry ?* "." table)
 179     (modify-syntax-entry ?- "." table)
 180     (modify-syntax-entry ?\; "." table)
 181     (modify-syntax-entry ?\( "()" table)
 182     (modify-syntax-entry ?\) ")(" table)
 183     (modify-syntax-entry ?\{ "(}" table)
 184     (modify-syntax-entry ?\} "){" table)
 185     (modify-syntax-entry ?\[ "(]" table)
 186     (modify-syntax-entry ?\] ")[" table)
 187     table)
 188   "Syntax table to use in Ruby mode.")
 189
 190 (defcustom ruby-indent-tabs-mode nil
 191   "Indentation can insert tabs in Ruby mode if this is non-nil."
 192   :type 'boolean :group 'ruby)
 193
 194 (defcustom ruby-indent-level 2
 195   "Indentation of Ruby statements."
 196   :type 'integer :group 'ruby)
 197
 198 (defcustom ruby-comment-column 32
 199   "Indentation column of comments."
 200   :type 'integer :group 'ruby)
 201
 202 (defcustom ruby-deep-arglist t
 203   "Deep indent lists in parenthesis when non-nil.
 204 Also ignores spaces after parenthesis when 'space."
 205   :group 'ruby)
 206
 207 (defcustom ruby-deep-indent-paren '(?\( ?\[ ?\] t)
 208   "Deep indent lists in parenthesis when non-nil.
 209 The value t means continuous line.
 210 Also ignores spaces after parenthesis when 'space."
 211   :group 'ruby)
 212
 213 (defcustom ruby-deep-indent-paren-style 'space
 214   "Default deep indent style."
 215   :options '(t nil space) :group 'ruby)
 216
 217 (defcustom ruby-encoding-map '((shift_jis . cp932) (shift-jis . cp932))
 218   "Alist to map encoding name from Emacs to Ruby."
 219   :group 'ruby)
 220
 221 (defcustom ruby-insert-encoding-magic-comment t
 222   "Insert a magic Emacs 'coding' comment upon save if this is non-nil."
 223   :type 'boolean :group 'ruby)
 224
 225 (defcustom ruby-use-encoding-map t
 226   "Use `ruby-encoding-map' to set encoding magic comment if this is non-nil."
 227   :type 'boolean :group 'ruby)
 228
 229 ;; Safe file variables
 230 (put 'ruby-indent-tabs-mode 'safe-local-variable 'booleanp)
 231 (put 'ruby-indent-level 'safe-local-variable 'integerp)
 232 (put 'ruby-comment-column 'safe-local-variable 'integerp)
 233 (put 'ruby-deep-arglist 'safe-local-variable 'booleanp)
 234
 235 (defun ruby-imenu-create-index-in-block (prefix beg end)
 236   "Create an imenu index of methods inside a block."
 237   (let ((index-alist '()) (case-fold-search nil)
 238         name next pos decl sing)
 239     (goto-char beg)
 240     (while (re-search-forward "^\\s *\\(\\(class\\s +\\|\\(class\\s *<<\\s *\\)\\|module\\s +\\)\\([^\(<\n ]+\\)\\|\\(def\\|alias\\)\\s +\\([^\(\n ]+\\)\\)" end t)
 241       (setq sing (match-beginning 3))
 242       (setq decl (match-string 5))
 243       (setq next (match-end 0))
 244       (setq name (or (match-string 4) (match-string 6)))
 245       (setq pos (match-beginning 0))
 246       (cond
 247        ((string= "alias" decl)
 248         (if prefix (setq name (concat prefix name)))
 249         (push (cons name pos) index-alist))
 250        ((string= "def" decl)
 251         (if prefix
 252             (setq name
 253                   (cond
 254                    ((string-match "^self\." name)
 255                     (concat (substring prefix 0 -1) (substring name 4)))
 256                   (t (concat prefix name)))))
 257         (push (cons name pos) index-alist)
 258         (ruby-accurate-end-of-block end))
 259        (t
 260         (if (string= "self" name)
 261             (if prefix (setq name (substring prefix 0 -1)))
 262           (if prefix (setq name (concat (substring prefix 0 -1) "::" name)))
 263           (push (cons name pos) index-alist))
 264         (ruby-accurate-end-of-block end)
 265         (setq beg (point))
 266         (setq index-alist
 267               (nconc (ruby-imenu-create-index-in-block
 268                       (concat name (if sing "." "#"))
 269                       next beg) index-alist))
 270         (goto-char beg))))
 271     index-alist))
 272
 273 (defun ruby-imenu-create-index ()
 274   "Create an imenu index of all methods in the buffer."
 275   (nreverse (ruby-imenu-create-index-in-block nil (point-min) nil)))
 276
 277 (defun ruby-accurate-end-of-block (&optional end)
 278   "TODO: document."
 279   (let (state
 280         (end (or end (point-max))))
 281     (while (and (setq state (apply 'ruby-parse-partial end state))
 282                 (>= (nth 2 state) 0) (< (point) end)))))
 283
 284 (defun ruby-mode-variables ()
 285   "Set up initial buffer-local variables for Ruby mode."
 286   (set-syntax-table ruby-mode-syntax-table)
 287   (setq local-abbrev-table ruby-mode-abbrev-table)
 288   (setq indent-tabs-mode ruby-indent-tabs-mode)
 289   (set (make-local-variable 'indent-line-function) 'ruby-indent-line)
 290   (set (make-local-variable 'require-final-newline) t)
 291   (set (make-local-variable 'comment-start) "# ")
 292   (set (make-local-variable 'comment-end) "")
 293   (set (make-local-variable 'comment-column) ruby-comment-column)
 294   (set (make-local-variable 'comment-start-skip) "#+ *")
 295   (set (make-local-variable 'parse-sexp-ignore-comments) t)
 296   (set (make-local-variable 'parse-sexp-lookup-properties) t)
 297   (set (make-local-variable 'paragraph-start) (concat "$\\|" page-delimiter))
 298   (set (make-local-variable 'paragraph-separate) paragraph-start)
 299   (set (make-local-variable 'paragraph-ignore-fill-prefix) t))
 300
 301 (defun ruby-mode-set-encoding ()
 302   "Insert a magic comment header with the proper encoding if necessary."
 303   (save-excursion
 304     (widen)
 305     (goto-char (point-min))
 306     (when (re-search-forward "[^\0-\177]" nil t)
 307       (goto-char (point-min))
 308       (let ((coding-system
 309              (or coding-system-for-write
 310                  buffer-file-coding-system)))
 311         (if coding-system
 312             (setq coding-system
 313                   (or (coding-system-get coding-system 'mime-charset)
 314                       (coding-system-change-eol-conversion coding-system nil))))
 315         (setq coding-system
 316               (if coding-system
 317                   (symbol-name
 318                    (or (and ruby-use-encoding-map
 319                             (cdr (assq coding-system ruby-encoding-map)))
 320                        coding-system))
 321                 "ascii-8bit"))
 322         (if (looking-at "^#!") (beginning-of-line 2))
 323         (cond ((looking-at "\\s *#.*-\*-\\s *\\(en\\)?coding\\s *:\\s *\\([-a-z0-9_]*\\)\\s *\\(;\\|-\*-\\)")
 324                (unless (string= (match-string 2) coding-system)
 325                  (goto-char (match-beginning 2))
 326                  (delete-region (point) (match-end 2))
 327                  (and (looking-at "-\*-")
 328                       (let ((n (skip-chars-backward " ")))
 329                         (cond ((= n 0) (insert "  ") (backward-char))
 330                               ((= n -1) (insert " "))
 331                               ((forward-char)))))
 332                  (insert coding-system)))
 333               ((looking-at "\\s *#.*coding\\s *[:=]"))
 334               (t (when ruby-insert-encoding-magic-comment
 335                    (insert "# -*- coding: " coding-system " -*-\n"))))))))
 336
 337 (defun ruby-current-indentation ()
 338   "Return the indentation level of current line."
 339   (save-excursion
 340     (beginning-of-line)
 341     (back-to-indentation)
 342     (current-column)))
 343
 344 (defun ruby-indent-line (&optional ignored)
 345   "Correct the indentation of the current Ruby line."
 346   (interactive)
 347   (ruby-indent-to (ruby-calculate-indent)))
 348
 349 (defun ruby-indent-to (column)
 350   "Indent the current line to COLUMN."
 351   (when column
 352     (let (shift top beg)
 353       (and (< column 0) (error "invalid nest"))
 354       (setq shift (current-column))
 355       (beginning-of-line)
 356       (setq beg (point))
 357       (back-to-indentation)
 358       (setq top (current-column))
 359       (skip-chars-backward " \t")
 360       (if (>= shift top) (setq shift (- shift top))
 361         (setq shift 0))
 362       (if (and (bolp)
 363                (= column top))
 364           (move-to-column (+ column shift))
 365         (move-to-column top)
 366         (delete-region beg (point))
 367         (beginning-of-line)
 368         (indent-to column)
 369         (move-to-column (+ column shift))))))
 370
 371 (defun ruby-special-char-p (&optional pos)
 372   "Return t if the character before POS is a special character.
 373 If omitted, POS defaults to the current point.
 374 Special characters are `?', `$', `:' when preceded by whitespace,
 375 and `\\' when preceded by `?'."
 376   (setq pos (or pos (point)))
 377   (let ((c (char-before pos)) (b (and (< (point-min) pos)
 378                                       (char-before (1- pos)))))
 379     (cond ((or (eq c ??) (eq c ?$)))
 380           ((and (eq c ?:) (or (not b) (eq (char-syntax b) ? ))))
 381           ((eq c ?\\) (eq b ??)))))
 382
 383 (defun ruby-expr-beg (&optional option)
 384   "TODO: document."
 385   (save-excursion
 386     (store-match-data nil)
 387     (let ((space (skip-chars-backward " \t")))
 388       (cond
 389        ((bolp) t)
 390        ((progn
 391           (forward-char -1)
 392           (and (looking-at "\\?")
 393                (or (eq (char-syntax (char-before (point))) ?w)
 394                    (ruby-special-char-p))))
 395         nil)
 396        ((and (eq option 'heredoc) (< space 0)) t)
 397        ((or (looking-at ruby-operator-re)
 398             (looking-at "[\\[({,;]")
 399             (and (looking-at "[!?]")
 400                  (or (not (eq option 'modifier))
 401                      (bolp)
 402                      (save-excursion (forward-char -1) (looking-at "\\Sw$"))))
 403             (and (looking-at ruby-symbol-re)
 404                  (skip-chars-backward ruby-symbol-chars)
 405                  (cond
 406                   ((looking-at (regexp-opt
 407                                 (append ruby-block-beg-keywords
 408                                         ruby-block-op-keywords
 409                                         ruby-block-mid-keywords)
 410                                 'words))
 411                    (goto-char (match-end 0))
 412                    (not (looking-at "\\s_")))
 413                   ((eq option 'expr-qstr)
 414                    (looking-at "[a-zA-Z][a-zA-z0-9_]* +%[^ \t]"))
 415                   ((eq option 'expr-re)
 416                    (looking-at "[a-zA-Z][a-zA-z0-9_]* +/[^ \t]"))
 417                   (t nil)))))))))
 418
 419 (defun ruby-forward-string (term &optional end no-error expand)
 420   "TODO: document."
 421   (let ((n 1) (c (string-to-char term))
 422         (re (if expand
 423                 (concat "[^\\]\\(\\\\\\\\\\)*\\([" term "]\\|\\(#{\\)\\)")
 424               (concat "[^\\]\\(\\\\\\\\\\)*[" term "]"))))
 425     (while (and (re-search-forward re end no-error)
 426                 (if (match-beginning 3)
 427                     (ruby-forward-string "}{" end no-error nil)
 428                   (> (setq n (if (eq (char-before (point)) c)
 429                                      (1- n) (1+ n))) 0)))
 430       (forward-char -1))
 431     (cond ((zerop n))
 432           (no-error nil)
 433           ((error "unterminated string")))))
 434
 435 (defun ruby-deep-indent-paren-p (c)
 436   "TODO: document."
 437   (cond ((listp ruby-deep-indent-paren)
 438          (let ((deep (assoc c ruby-deep-indent-paren)))
 439            (cond (deep
 440                   (or (cdr deep) ruby-deep-indent-paren-style))
 441                  ((memq c ruby-deep-indent-paren)
 442                   ruby-deep-indent-paren-style))))
 443         ((eq c ruby-deep-indent-paren) ruby-deep-indent-paren-style)
 444         ((eq c ?\( ) ruby-deep-arglist)))
 445
 446 (defun ruby-parse-partial (&optional end in-string nest depth pcol indent)
 447   "TODO: document throughout function body."
 448   (or depth (setq depth 0))
 449   (or indent (setq indent 0))
 450   (when (re-search-forward ruby-delimiter end 'move)
 451     (let ((pnt (point)) w re expand)
 452       (goto-char (match-beginning 0))
 453       (cond
 454        ((and (memq (char-before) '(?@ ?$)) (looking-at "\\sw"))
 455         (goto-char pnt))
 456        ((looking-at "[\"`]")            ;skip string
 457         (cond
 458          ((and (not (eobp))
 459                (ruby-forward-string (buffer-substring (point) (1+ (point))) end t t))
 460           nil)
 461          (t
 462           (setq in-string (point))
 463           (goto-char end))))
 464        ((looking-at "'")
 465         (cond
 466          ((and (not (eobp))
 467                (re-search-forward "[^\\]\\(\\\\\\\\\\)*'" end t))
 468           nil)
 469          (t
 470           (setq in-string (point))
 471           (goto-char end))))
 472        ((looking-at "/=")
 473         (goto-char pnt))
 474        ((looking-at "/")
 475         (cond
 476          ((and (not (eobp)) (ruby-expr-beg 'expr-re))
 477           (if (ruby-forward-string "/" end t t)
 478               nil
 479             (setq in-string (point))
 480             (goto-char end)))
 481          (t
 482           (goto-char pnt))))
 483        ((looking-at "%")
 484         (cond
 485          ((and (not (eobp))
 486                (ruby-expr-beg 'expr-qstr)
 487                (not (looking-at "%="))
 488                (looking-at "%[QqrxWw]?\\([^a-zA-Z0-9 \t\n]\\)"))
 489           (goto-char (match-beginning 1))
 490           (setq expand (not (memq (char-before) '(?q ?w))))
 491           (setq w (match-string 1))
 492           (cond
 493            ((string= w "[") (setq re "]["))
 494            ((string= w "{") (setq re "}{"))
 495            ((string= w "(") (setq re ")("))
 496            ((string= w "<") (setq re "><"))
 497            ((and expand (string= w "\\"))
 498             (setq w (concat "\\" w))))
 499           (unless (cond (re (ruby-forward-string re end t expand))
 500                         (expand (ruby-forward-string w end t t))
 501                         (t (re-search-forward
 502                             (if (string= w "\\")
 503                                 "\\\\[^\\]*\\\\"
 504                               (concat "[^\\]\\(\\\\\\\\\\)*" w))
 505                             end t)))
 506             (setq in-string (point))
 507             (goto-char end)))
 508          (t
 509           (goto-char pnt))))
 510        ((looking-at "\\?")              ;skip ?char
 511         (cond
 512          ((and (ruby-expr-beg)
 513                (looking-at "?\\(\\\\C-\\|\\\\M-\\)*\\\\?."))
 514           (goto-char (match-end 0)))
 515          (t
 516           (goto-char pnt))))
 517        ((looking-at "\\$")              ;skip $char
 518         (goto-char pnt)
 519         (forward-char 1))
 520        ((looking-at "#")                ;skip comment
 521         (forward-line 1)
 522         (goto-char (point))
 523         )
 524        ((looking-at "[\\[{(]")
 525         (let ((deep (ruby-deep-indent-paren-p (char-after))))
 526           (if (and deep (or (not (eq (char-after) ?\{)) (ruby-expr-beg)))
 527               (progn
 528                 (and (eq deep 'space) (looking-at ".\\s +[^# \t\n]")
 529                      (setq pnt (1- (match-end 0))))
 530                 (setq nest (cons (cons (char-after (point)) pnt) nest))
 531                 (setq pcol (cons (cons pnt depth) pcol))
 532                 (setq depth 0))
 533             (setq nest (cons (cons (char-after (point)) pnt) nest))
 534             (setq depth (1+ depth))))
 535         (goto-char pnt)
 536         )
 537        ((looking-at "[])}]")
 538         (if (ruby-deep-indent-paren-p (matching-paren (char-after)))
 539             (setq depth (cdr (car pcol)) pcol (cdr pcol))
 540           (setq depth (1- depth)))
 541         (setq nest (cdr nest))
 542         (goto-char pnt))
 543        ((looking-at ruby-block-end-re)
 544         (if (or (and (not (bolp))
 545                      (progn
 546                        (forward-char -1)
 547                        (setq w (char-after (point)))
 548                        (or (eq ?_ w)
 549                            (eq ?. w))))
 550                 (progn
 551                   (goto-char pnt)
 552                   (setq w (char-after (point)))
 553                   (or (eq ?_ w)
 554                       (eq ?! w)
 555                       (eq ?? w))))
 556             nil
 557           (setq nest (cdr nest))
 558           (setq depth (1- depth)))
 559         (goto-char pnt))
 560        ((looking-at "def\\s +[^(\n;]*")
 561         (if (or (bolp)
 562                 (progn
 563                   (forward-char -1)
 564                   (not (eq ?_ (char-after (point))))))
 565             (progn
 566               (setq nest (cons (cons nil pnt) nest))
 567               (setq depth (1+ depth))))
 568         (goto-char (match-end 0)))
 569        ((looking-at (concat "\\_<\\(" ruby-block-beg-re "\\)\\_>"))
 570         (and
 571          (save-match-data
 572            (or (not (looking-at (concat "do" ruby-keyword-end-re)))
 573                (save-excursion
 574                  (back-to-indentation)
 575                  (not (looking-at ruby-non-block-do-re)))))
 576          (or (bolp)
 577              (progn
 578                (forward-char -1)
 579                (setq w (char-after (point)))
 580                (not (or (eq ?_ w)
 581                         (eq ?. w)))))
 582          (goto-char pnt)
 583          (setq w (char-after (point)))
 584          (not (eq ?_ w))
 585          (not (eq ?! w))
 586          (not (eq ?? w))
 587          (skip-chars-forward " \t")
 588          (goto-char (match-beginning 0))
 589          (or (not (looking-at ruby-modifier-re))
 590              (ruby-expr-beg 'modifier))
 591          (goto-char pnt)
 592          (setq nest (cons (cons nil pnt) nest))
 593          (setq depth (1+ depth)))
 594         (goto-char pnt))
 595        ((looking-at ":\\(['\"]\\)")
 596         (goto-char (match-beginning 1))
 597         (ruby-forward-string (buffer-substring (match-beginning 1) (match-end 1)) end))
 598        ((looking-at ":\\([-,.+*/%&|^~<>]=?\\|===?\\|<=>\\|![~=]?\\)")
 599         (goto-char (match-end 0)))
 600        ((looking-at ":\\([a-zA-Z_][a-zA-Z_0-9]*[!?=]?\\)?")
 601         (goto-char (match-end 0)))
 602        ((or (looking-at "\\.\\.\\.?")
 603             (looking-at "\\.[0-9]+")
 604             (looking-at "\\.[a-zA-Z_0-9]+")
 605             (looking-at "\\."))
 606         (goto-char (match-end 0)))
 607        ((looking-at "^=begin")
 608         (if (re-search-forward "^=end" end t)
 609             (forward-line 1)
 610           (setq in-string (match-end 0))
 611           (goto-char end)))
 612        ((looking-at "<<")
 613         (cond
 614          ((and (ruby-expr-beg 'heredoc)
 615                (looking-at "<<\\(-\\)?\\(\\([\"'`]\\)\\([^\n]+?\\)\\3\\|\\(?:\\sw\\|\\s_\\)+\\)"))
 616           (setq re (regexp-quote (or (match-string 4) (match-string 2))))
 617           (if (match-beginning 1) (setq re (concat "\\s *" re)))
 618           (let* ((id-end (goto-char (match-end 0)))
 619                  (line-end-position (point-at-eol))
 620                  (state (list in-string nest depth pcol indent)))
 621             ;; parse the rest of the line
 622             (while (and (> line-end-position (point))
 623                         (setq state (apply 'ruby-parse-partial
 624                                            line-end-position state))))
 625             (setq in-string (car state)
 626                   nest (nth 1 state)
 627                   depth (nth 2 state)
 628                   pcol (nth 3 state)
 629                   indent (nth 4 state))
 630             ;; skip heredoc section
 631             (if (re-search-forward (concat "^" re "$") end 'move)
 632                 (forward-line 1)
 633               (setq in-string id-end)
 634               (goto-char end))))
 635          (t
 636           (goto-char pnt))))
 637        ((looking-at "^__END__$")
 638         (goto-char pnt))
 639        ((and (looking-at ruby-here-doc-beg-re)
 640              (boundp 'ruby-indent-point))
 641         (if (re-search-forward (ruby-here-doc-end-match)
 642                                ruby-indent-point t)
 643             (forward-line 1)
 644           (setq in-string (match-end 0))
 645           (goto-char ruby-indent-point)))
 646        (t
 647         (error (format "bad string %s"
 648                        (buffer-substring (point) pnt)
 649                        ))))))
 650   (list in-string nest depth pcol))
 651
 652 (defun ruby-parse-region (start end)
 653   "TODO: document."
 654   (let (state)
 655     (save-excursion
 656       (if start
 657           (goto-char start)
 658         (ruby-beginning-of-indent))
 659       (save-restriction
 660         (narrow-to-region (point) end)
 661         (while (and (> end (point))
 662                     (setq state (apply 'ruby-parse-partial end state))))))
 663     (list (nth 0 state)                 ; in-string
 664           (car (nth 1 state))           ; nest
 665           (nth 2 state)                 ; depth
 666           (car (car (nth 3 state)))     ; pcol
 667           ;(car (nth 5 state))          ; indent
 668           )))
 669
 670 (defun ruby-indent-size (pos nest)
 671   "Return the indentation level in spaces NEST levels deeper than POS."
 672   (+ pos (* (or nest 1) ruby-indent-level)))
 673
 674 (defun ruby-calculate-indent (&optional parse-start)
 675   "Return the proper indentation level of the current line."
 676   ;; TODO: Document body
 677   (save-excursion
 678     (beginning-of-line)
 679     (let ((ruby-indent-point (point))
 680           (case-fold-search nil)
 681           state eol begin op-end
 682           (paren (progn (skip-syntax-forward " ")
 683                         (and (char-after) (matching-paren (char-after)))))
 684           (indent 0))
 685       (if parse-start
 686           (goto-char parse-start)
 687         (ruby-beginning-of-indent)
 688         (setq parse-start (point)))
 689       (back-to-indentation)
 690       (setq indent (current-column))
 691       (setq state (ruby-parse-region parse-start ruby-indent-point))
 692       (cond
 693        ((nth 0 state)                   ; within string
 694         (setq indent nil))              ;  do nothing
 695        ((car (nth 1 state))             ; in paren
 696         (goto-char (setq begin (cdr (nth 1 state))))
 697         (let ((deep (ruby-deep-indent-paren-p (car (nth 1 state)))))
 698           (if deep
 699               (cond ((and (eq deep t) (eq (car (nth 1 state)) paren))
 700                      (skip-syntax-backward " ")
 701                      (setq indent (1- (current-column))))
 702                     ((let ((s (ruby-parse-region (point) ruby-indent-point)))
 703                        (and (nth 2 s) (> (nth 2 s) 0)
 704                             (or (goto-char (cdr (nth 1 s))) t)))
 705                      (forward-word -1)
 706                      (setq indent (ruby-indent-size (current-column)
 707                                                     (nth 2 state))))
 708                     (t
 709                      (setq indent (current-column))
 710                      (cond ((eq deep 'space))
 711                            (paren (setq indent (1- indent)))
 712                            (t (setq indent (ruby-indent-size (1- indent) 1))))))
 713             (if (nth 3 state) (goto-char (nth 3 state))
 714               (goto-char parse-start) (back-to-indentation))
 715             (setq indent (ruby-indent-size (current-column) (nth 2 state))))
 716           (and (eq (car (nth 1 state)) paren)
 717                (ruby-deep-indent-paren-p (matching-paren paren))
 718                (search-backward (char-to-string paren))
 719                (setq indent (current-column)))))
 720        ((and (nth 2 state) (> (nth 2 state) 0)) ; in nest
 721         (if (null (cdr (nth 1 state)))
 722             (error "invalid nest"))
 723         (goto-char (cdr (nth 1 state)))
 724         (forward-word -1)               ; skip back a keyword
 725         (setq begin (point))
 726         (cond
 727          ((looking-at "do\\>[^_]")      ; iter block is a special case
 728           (if (nth 3 state) (goto-char (nth 3 state))
 729             (goto-char parse-start) (back-to-indentation))
 730           (setq indent (ruby-indent-size (current-column) (nth 2 state))))
 731          (t
 732           (setq indent (+ (current-column) ruby-indent-level)))))
 733
 734        ((and (nth 2 state) (< (nth 2 state) 0)) ; in negative nest
 735         (setq indent (ruby-indent-size (current-column) (nth 2 state)))))
 736       (when indent
 737         (goto-char ruby-indent-point)
 738         (end-of-line)
 739         (setq eol (point))
 740         (beginning-of-line)
 741         (cond
 742          ((and (not (ruby-deep-indent-paren-p paren))
 743                (re-search-forward ruby-negative eol t))
 744           (and (not (eq ?_ (char-after (match-end 0))))
 745                (setq indent (- indent ruby-indent-level))))
 746          ((and
 747            (save-excursion
 748              (beginning-of-line)
 749              (not (bobp)))
 750            (or (ruby-deep-indent-paren-p t)
 751                (null (car (nth 1 state)))))
 752           ;; goto beginning of non-empty no-comment line
 753           (let (end done)
 754             (while (not done)
 755               (skip-chars-backward " \t\n")
 756               (setq end (point))
 757               (beginning-of-line)
 758               (if (re-search-forward "^\\s *#" end t)
 759                   (beginning-of-line)
 760                 (setq done t))))
 761           (end-of-line)
 762           ;; skip the comment at the end
 763           (skip-chars-backward " \t")
 764           (let (end (pos (point)))
 765             (beginning-of-line)
 766             (while (and (re-search-forward "#" pos t)
 767                         (setq end (1- (point)))
 768                         (or (ruby-special-char-p end)
 769                             (and (setq state (ruby-parse-region parse-start end))
 770                                  (nth 0 state))))
 771               (setq end nil))
 772             (goto-char (or end pos))
 773             (skip-chars-backward " \t")
 774             (setq begin (if (and end (nth 0 state)) pos (cdr (nth 1 state))))
 775             (setq state (ruby-parse-region parse-start (point))))
 776           (or (bobp) (forward-char -1))
 777           (and
 778            (or (and (looking-at ruby-symbol-re)
 779                     (skip-chars-backward ruby-symbol-chars)
 780                     (looking-at (concat "\\<\\(" ruby-block-hanging-re "\\)\\>"))
 781                     (not (eq (point) (nth 3 state)))
 782                     (save-excursion
 783                       (goto-char (match-end 0))
 784                       (not (looking-at "[a-z_]"))))
 785                (and (looking-at ruby-operator-re)
 786                     (not (ruby-special-char-p))
 787                     ;; operator at the end of line
 788                     (let ((c (char-after (point))))
 789                       (and
 790 ;;                     (or (null begin)
 791 ;;                         (save-excursion
 792 ;;                           (goto-char begin)
 793 ;;                           (skip-chars-forward " \t")
 794 ;;                           (not (or (eolp) (looking-at "#")
 795 ;;                                    (and (eq (car (nth 1 state)) ?{)
 796 ;;                                         (looking-at "|"))))))
 797                        ;; not a regexp or general delimited literal
 798                        (null (nth 0 (ruby-parse-region (or begin parse-start) (point))))
 799                        (or (not (eq ?| (char-after (point))))
 800                            (save-excursion
 801                              (or (eolp) (forward-char -1))
 802                              (cond
 803                               ((search-backward "|" nil t)
 804                                (skip-chars-backward " \t\n")
 805                                (and (not (eolp))
 806                                     (progn
 807                                       (forward-char -1)
 808                                       (not (looking-at "{")))
 809                                     (progn
 810                                       (forward-word -1)
 811                                       (not (looking-at "do\\>[^_]")))))
 812                               (t t))))
 813                        (not (eq ?, c))
 814                        (setq op-end t)))))
 815            (setq indent
 816                  (cond
 817                   ((and
 818                     (null op-end)
 819                     (not (looking-at (concat "\\<\\(" ruby-block-hanging-re "\\)\\>")))
 820                     (eq (ruby-deep-indent-paren-p t) 'space)
 821                     (not (bobp)))
 822                    (widen)
 823                    (goto-char (or begin parse-start))
 824                    (skip-syntax-forward " ")
 825                    (current-column))
 826                   ((car (nth 1 state)) indent)
 827                   (t
 828                    (+ indent ruby-indent-level))))))))
 829       (goto-char ruby-indent-point)
 830       (beginning-of-line)
 831       (skip-syntax-forward " ")
 832       (if (looking-at "\\.[^.]")
 833           (+ indent ruby-indent-level)
 834         indent))))
 835
 836 (defun ruby-electric-brace (arg)
 837   "Insert a brace and re-indent the current line."
 838   (interactive "P")
 839   (self-insert-command (prefix-numeric-value arg))
 840   (ruby-indent-line t))
 841
 842 ;; TODO: Why isn't one ruby-*-of-defun written in terms of the other?
 843 (defun ruby-beginning-of-defun (&optional arg)
 844   "Move backward to the beginning of the current top-level defun.
 845 With ARG, move backward multiple defuns.  Negative ARG means
 846 move forward."
 847   (interactive "p")
 848   (and (re-search-backward (concat "^\\(" ruby-block-beg-re "\\)\\b")
 849                            nil 'move (or arg 1))
 850        (beginning-of-line)))
 851
 852 (defun ruby-end-of-defun (&optional arg)
 853   "Move forward to the end of the current top-level defun.
 854 With ARG, move forward multiple defuns.  Negative ARG means
 855 move backward."
 856   (interactive "p")
 857   (and (re-search-forward (concat "^\\(" ruby-block-end-re "\\)\\($\\|\\b[^_]\\)")
 858                           nil 'move (or arg 1))
 859        (beginning-of-line))
 860   (forward-line 1))
 861
 862 (defun ruby-beginning-of-indent ()
 863   "TODO: document"
 864   ;; I don't understand this function.
 865   ;; It seems like it should move to the line where indentation should deepen,
 866   ;; but ruby-indent-beg-re only accounts for whitespace before class, module and def,
 867   ;; so this will only match other block beginners at the beginning of the line.
 868   (and (re-search-backward (concat "^\\(" ruby-indent-beg-re "\\)\\_>") nil 'move)
 869        (beginning-of-line)))
 870
 871 (defun ruby-move-to-block (n)
 872   "Move to the beginning (N < 0) or the end (N > 0) of the current block
 873 or blocks containing the current block."
 874   ;; TODO: Make this work for n > 1,
 875   ;; make it not loop for n = 0,
 876   ;; document body
 877   (let (start pos done down)
 878     (setq start (ruby-calculate-indent))
 879     (setq down (looking-at (if (< n 0) ruby-block-end-re
 880                              (concat "\\<\\(" ruby-block-beg-re "\\)\\>"))))
 881     (while (and (not done) (not (if (< n 0) (bobp) (eobp))))
 882       (forward-line n)
 883       (cond
 884        ((looking-at "^\\s *$"))
 885        ((looking-at "^\\s *#"))
 886        ((and (> n 0) (looking-at "^=begin\\>"))
 887         (re-search-forward "^=end\\>"))
 888        ((and (< n 0) (looking-at "^=end\\>"))
 889         (re-search-backward "^=begin\\>"))
 890        (t
 891         (setq pos (current-indentation))
 892         (cond
 893          ((< start pos)
 894           (setq down t))
 895          ((and down (= pos start))
 896           (setq done t))
 897          ((> start pos)
 898           (setq done t)))))
 899       (if done
 900           (save-excursion
 901             (back-to-indentation)
 902             (if (looking-at (concat "\\<\\(" ruby-block-mid-re "\\)\\>"))
 903                 (setq done nil))))))
 904   (back-to-indentation))
 905
 906 (defun ruby-beginning-of-block (&optional arg)
 907   "Move backward to the beginning of the current block.
 908 With ARG, move up multiple blocks."
 909   (interactive "p")
 910   (ruby-move-to-block (- (or arg 1))))
 911
 912 (defun ruby-end-of-block (&optional arg)
 913   "Move forward to the end of the current block.
 914 With ARG, move out of multiple blocks."
 915   ;; Passing a value > 1 to ruby-move-to-block currently doesn't work.
 916   (interactive)
 917   (ruby-move-to-block (or arg 1)))
 918
 919 (defun ruby-forward-sexp (&optional arg)
 920   "Move forward across one balanced expression (sexp).
 921 With ARG, do it many times.  Negative ARG means move backward."
 922   ;; TODO: Document body
 923   (interactive "p")
 924   (if (and (numberp arg) (< arg 0))
 925       (ruby-backward-sexp (- arg))
 926     (let ((i (or arg 1)))
 927       (condition-case nil
 928           (while (> i 0)
 929             (skip-syntax-forward " ")
 930             (if (looking-at ",\\s *") (goto-char (match-end 0)))
 931             (cond ((looking-at "\\?\\(\\\\[CM]-\\)*\\\\?\\S ")
 932                    (goto-char (match-end 0)))
 933                   ((progn
 934                      (skip-chars-forward ",.:;|&^~=!?\\+\\-\\*")
 935                      (looking-at "\\s("))
 936                    (goto-char (scan-sexps (point) 1)))
 937                   ((and (looking-at (concat "\\<\\(" ruby-block-beg-re "\\)\\>"))
 938                         (not (eq (char-before (point)) ?.))
 939                         (not (eq (char-before (point)) ?:)))
 940                    (ruby-end-of-block)
 941                    (forward-word 1))
 942                   ((looking-at "\\(\\$\\|@@?\\)?\\sw")
 943                    (while (progn
 944                             (while (progn (forward-word 1) (looking-at "_")))
 945                             (cond ((looking-at "::") (forward-char 2) t)
 946                                   ((> (skip-chars-forward ".") 0))
 947                                   ((looking-at "\\?\\|!\\(=[~=>]\\|[^~=]\\)")
 948                                    (forward-char 1) nil)))))
 949                   ((let (state expr)
 950                      (while
 951                          (progn
 952                            (setq expr (or expr (ruby-expr-beg)
 953                                           (looking-at "%\\sw?\\Sw\\|[\"'`/]")))
 954                            (nth 1 (setq state (apply 'ruby-parse-partial nil state))))
 955                        (setq expr t)
 956                        (skip-chars-forward "<"))
 957                      (not expr))))
 958             (setq i (1- i)))
 959         ((error) (forward-word 1)))
 960       i)))
 961
 962 (defun ruby-backward-sexp (&optional arg)
 963   "Move backward across one balanced expression (sexp).
 964 With ARG, do it many times.  Negative ARG means move forward."
 965   ;; TODO: Document body
 966   (interactive "p")
 967   (if (and (numberp arg) (< arg 0))
 968       (ruby-forward-sexp (- arg))
 969     (let ((i (or arg 1)))
 970       (condition-case nil
 971           (while (> i 0)
 972             (skip-chars-backward " \t\n,.:;|&^~=!?\\+\\-\\*")
 973             (forward-char -1)
 974             (cond ((looking-at "\\s)")
 975                    (goto-char (scan-sexps (1+ (point)) -1))
 976                    (case (char-before)
 977                      (?% (forward-char -1))
 978                      ((?q ?Q ?w ?W ?r ?x)
 979                       (if (eq (char-before (1- (point))) ?%) (forward-char -2))))
 980                    nil)
 981                   ((looking-at "\\s\"\\|\\\\\\S_")
 982                    (let ((c (char-to-string (char-before (match-end 0)))))
 983                      (while (and (search-backward c)
 984                                  (eq (logand (skip-chars-backward "\\") 1)
 985                                      1))))
 986                    nil)
 987                   ((looking-at "\\s.\\|\\s\\")
 988                    (if (ruby-special-char-p) (forward-char -1)))
 989                   ((looking-at "\\s(") nil)
 990                   (t
 991                    (forward-char 1)
 992                    (while (progn (forward-word -1)
 993                                  (case (char-before)
 994                                    (?_ t)
 995                                    (?. (forward-char -1) t)
 996                                    ((?$ ?@)
 997                                     (forward-char -1)
 998                                     (and (eq (char-before) (char-after)) (forward-char -1)))
 999                                    (?:
1000                                     (forward-char -1)
1001                                     (eq (char-before) :)))))
1002                    (if (looking-at ruby-block-end-re)
1003                        (ruby-beginning-of-block))
1004                    nil))
1005             (setq i (1- i)))
1006         ((error)))
1007       i)))
1008
1009 (defun ruby-mark-defun ()
1010   "Put mark at end of this Ruby function, point at beginning."
1011   (interactive)
1012   (push-mark (point))
1013   (ruby-end-of-defun)
1014   (push-mark (point) nil t)
1015   (ruby-beginning-of-defun)
1016   (re-search-backward "^\n" (- (point) 1) t))
1017
1018 (defun ruby-indent-exp (&optional ignored)
1019   "Indent each line in the balanced expression following the point."
1020   (interactive "*P")
1021   (let ((here (point-marker)) start top column (nest t))
1022     (set-marker-insertion-type here t)
1023     (unwind-protect
1024         (progn
1025           (beginning-of-line)
1026           (setq start (point) top (current-indentation))
1027           (while (and (not (eobp))
1028                       (progn
1029                         (setq column (ruby-calculate-indent start))
1030                         (cond ((> column top)
1031                                (setq nest t))
1032                               ((and (= column top) nest)
1033                                (setq nest nil) t))))
1034             (ruby-indent-to column)
1035             (beginning-of-line 2)))
1036       (goto-char here)
1037       (set-marker here nil))))
1038
1039 (defun ruby-add-log-current-method ()
1040   "Return the current method name as a string.
1041 This string includes all namespaces.
1042
1043 For example:
1044
1045   #exit
1046   String#gsub
1047   Net::HTTP#active?
1048   File::open.
1049
1050 See `add-log-current-defun-function'."
1051   ;; TODO: Document body
1052   ;; Why does this append a period to class methods?
1053   (condition-case nil
1054       (save-excursion
1055         (let (mname mlist (indent 0))
1056           ;; get current method (or class/module)
1057           (if (re-search-backward
1058                (concat "^[ \t]*\\(def\\|class\\|module\\)[ \t]+"
1059                        "\\("
1060                        ;; \\. and :: for class method
1061                         "\\([A-Za-z_]" ruby-symbol-re "*\\|\\.\\|::" "\\)"
1062                         "+\\)")
1063                nil t)
1064               (progn
1065                 (setq mname (match-string 2))
1066                 (unless (string-equal "def" (match-string 1))
1067                   (setq mlist (list mname) mname nil))
1068                 (goto-char (match-beginning 1))
1069                 (setq indent (current-column))
1070                 (beginning-of-line)))
1071           ;; nest class/module
1072           (while (and (> indent 0)
1073                       (re-search-backward
1074                        (concat
1075                         "^[ \t]*\\(class\\|module\\)[ \t]+"
1076                         "\\([A-Z]" ruby-symbol-re "*\\)")
1077                        nil t))
1078             (goto-char (match-beginning 1))
1079             (if (< (current-column) indent)
1080                 (progn
1081                   (setq mlist (cons (match-string 2) mlist))
1082                   (setq indent (current-column))
1083                   (beginning-of-line))))
1084           (when mname
1085             (let ((mn (split-string mname "\\.\\|::")))
1086               (if (cdr mn)
1087                   (progn
1088                     (cond
1089                      ((string-equal "" (car mn))
1090                       (setq mn (cdr mn) mlist nil))
1091                      ((string-equal "self" (car mn))
1092                       (setq mn (cdr mn)))
1093                      ((let ((ml (nreverse mlist)))
1094                         (while ml
1095                           (if (string-equal (car ml) (car mn))
1096                               (setq mlist (nreverse (cdr ml)) ml nil))
1097                           (or (setq ml (cdr ml)) (nreverse mlist))))))
1098                     (if mlist
1099                         (setcdr (last mlist) mn)
1100                       (setq mlist mn))
1101                     (setq mn (last mn 2))
1102                     (setq mname (concat "." (cadr mn)))
1103                     (setcdr mn nil))
1104                 (setq mname (concat "#" mname)))))
1105           ;; generate string
1106           (if (consp mlist)
1107               (setq mlist (mapconcat (function identity) mlist "::")))
1108           (if mname
1109               (if mlist (concat mlist mname) mname)
1110             mlist)))))
1111
1112 (declare-function ruby-syntax-propertize-heredoc "ruby-mode" (limit))
1113
1114 (if (eval-when-compile (fboundp #'syntax-propertize-rules))
1115     ;; New code that works independently from font-lock.
1116     (progn
1117       (defun ruby-syntax-propertize-function (start end)
1118         "Syntactic keywords for Ruby mode.  See `syntax-propertize-function'."
1119         (goto-char start)
1120         (ruby-syntax-propertize-heredoc end)
1121         (ruby-syntax-general-delimiters-goto-beg)
1122         (funcall
1123          (syntax-propertize-rules
1124           ;; #{ }, #$hoge, #@foo are not comments
1125           ("\\(#\\)[{$@]" (1 "."))
1126           ;; $' $" $` .... are variables
1127           ;; ?' ?" ?` are ascii codes
1128           ("\\([?$]\\)[#\"'`]"
1129            (1 (unless (save-excursion
1130                         ;; Not within a string.
1131                         (nth 3 (syntax-ppss (match-beginning 0))))
1132                 (string-to-syntax "\\"))))
1133           ;; regexps
1134           ("\\(^\\|[[=(,~?:;<>]\\|\\(?:^\\|\\s \\)\\(?:if\\|elsif\\|unless\\|while\\|until\\|when\\|and\\|or\\|&&\\|||\\)\\|g?sub!?\\|scan\\|split!?\\)?\\s *\\(/\\)[^/\n\\\\]*\\(?:\\\\.[^/\n\\\\]*\\)*\\(/\\)"
1135            (2 (ruby-syntax-propertize-regexp)))
1136           ("^=en\\(d\\)\\_>" (1 "!"))
1137           ("^\\(=\\)begin\\_>" (1 "!"))
1138           ;; Handle here documents.
1139           ((concat ruby-here-doc-beg-re ".*\\(\n\\)")
1140            (7 (prog1 "\"" (ruby-syntax-propertize-heredoc end))))
1141           ;; Handle percent literals: %w(), %q{}, etc.
1142           ("\\(?:^\\|[[ \t\n<+(,=]\\)\\(%\\)[qQrswWx]?\\([[:punct:]]\\)"
1143            (1 (prog1 "|" (ruby-syntax-propertize-general-delimiters end)))))
1144          (point) end))
1145
1146       (defun ruby-syntax-propertize-regexp ()
1147         (let ((syn (string-to-syntax "\"/")))
1148           (goto-char (match-end 3))
1149           (if (or
1150                ;; after paren, comma, operator, control flow keyword,
1151                ;; or a method from hardcoded list
1152                (match-beginning 1)
1153                ;; followed by comma or block
1154                (looking-at "[imxo]*\\s *\\(?:,\\|\\<do\\>\\)"))
1155               (progn
1156                 (put-text-property (1- (point)) (point)
1157                                    'syntax-table syn)
1158                 syn)
1159             (goto-char (match-end 2)))))
1160
1161       (defun ruby-syntax-propertize-heredoc (limit)
1162         (let ((ppss (syntax-ppss))
1163               (res '()))
1164           (when (eq ?\n (nth 3 ppss))
1165             (save-excursion
1166               (goto-char (nth 8 ppss))
1167               (beginning-of-line)
1168               (while (re-search-forward ruby-here-doc-beg-re
1169                                         (line-end-position) t)
1170                 (push (concat (ruby-here-doc-end-match) "\n") res)))
1171             (let ((start (point)))
1172               ;; With multiple openers on the same line, we don't know in which
1173               ;; part `start' is, so we have to go back to the beginning.
1174               (when (cdr res)
1175                 (goto-char (nth 8 ppss))
1176                 (setq res (nreverse res)))
1177               (while (and res (re-search-forward (pop res) limit 'move))
1178                 (if (null res)
1179                     (put-text-property (1- (point)) (point)
1180                                        'syntax-table (string-to-syntax "\""))))
1181               ;; Make extra sure we don't move back, lest we could fall into an
1182               ;; inf-loop.
1183               (if (< (point) start) (goto-char start))))))
1184
1185       (defun ruby-syntax-general-delimiters-goto-beg ()
1186         (let ((state (syntax-ppss)))
1187           ;; Move to the start of the literal, in case it's multiline.
1188           ;; TODO: determine the literal type more reliably here?
1189           (when (eq t (nth 3 state))
1190             (goto-char (nth 8 state))
1191             (beginning-of-line))))
1192
1193       (defun ruby-syntax-propertize-general-delimiters (limit)
1194         (goto-char (match-beginning 2))
1195         (let* ((op (char-after))
1196                (ops (char-to-string op))
1197                (cl (or (cdr (aref (syntax-table) op))
1198                        (cdr (assoc op '((?< . ?>))))))
1199                parse-sexp-lookup-properties)
1200           (ignore-errors
1201             (if cl
1202                 (progn  ; paired delimiters
1203                   ;; Delimiter pairs of the same kind can be nested
1204                   ;; inside the literal, as long as they are balanced.
1205                   ;; Create syntax table that ignores other characters.
1206                   (with-syntax-table (make-char-table 'syntax-table nil)
1207                     (modify-syntax-entry op (concat "(" (char-to-string cl)))
1208                     (modify-syntax-entry cl (concat ")" ops))
1209                     (modify-syntax-entry ?\\ "\\")
1210                     (save-restriction
1211                       (narrow-to-region (point) limit)
1212                       (forward-list))))  ; skip to the paired character
1213               ;; single character delimiter
1214               (re-search-forward (concat "[^\\]\\(?:\\\\\\\\\\)*"
1215                                          (regexp-quote ops)) limit nil))
1216             ;; if we reached here, the closing delimiter was found
1217             (put-text-property (1- (point)) (point)
1218                                'syntax-table (string-to-syntax "|")))))
1219       )
1220
1221   ;; For Emacsen where syntax-propertize-rules is not (yet) available,
1222   ;; fallback on the old font-lock-syntactic-keywords stuff.
1223
1224   (defconst ruby-here-doc-end-re
1225     "^\\([ \t]+\\)?\\(.*\\)\\(\n\\)"
1226     "Regexp to match the end of heredocs.
1227
1228 This will actually match any line with one or more characters.
1229 It's useful in that it divides up the match string so that
1230 `ruby-here-doc-beg-match' can search for the beginning of the heredoc.")
1231
1232   (defun ruby-here-doc-beg-match ()
1233     "Return a regexp to find the beginning of a heredoc.
1234
1235 This should only be called after matching against `ruby-here-doc-end-re'."
1236     (let ((contents (concat
1237                      (regexp-quote (concat (match-string 2) (match-string 3)))
1238                      (if (string= (match-string 3) "_") "\\B" "\\b"))))
1239       (concat "<<"
1240               (let ((match (match-string 1)))
1241                 (if (and match (> (length match) 0))
1242                     (concat "\\(?:-\\([\"']?\\)\\|\\([\"']\\)"
1243                             (match-string 1) "\\)"
1244                             contents "\\(\\1\\|\\2\\)")
1245                   (concat "-?\\([\"']\\|\\)" contents "\\1"))))))
1246
1247   (defconst ruby-font-lock-syntactic-keywords
1248     `( ;; #{ }, #$hoge, #@foo are not comments
1249     ("\\(#\\)[{$@]" 1 (1 . nil))
1250     ;; the last $', $", $` in the respective string is not variable
1251     ;; the last ?', ?", ?` in the respective string is not ascii code
1252     ("\\(^\\|[\[ \t\n<+\(,=]\\)\\(['\"`]\\)\\(\\\\.\\|\\2\\|[^'\"`\n\\\\]\\)*?\\\\?[?$]\\(\\2\\)"
1253      (2 (7 . nil))
1254      (4 (7 . nil)))
1255     ;; $' $" $` .... are variables
1256     ;; ?' ?" ?` are ascii codes
1257     ("\\(^\\|[^\\\\]\\)\\(\\\\\\\\\\)*[?$]\\([#\"'`]\\)" 3 (1 . nil))
1258     ;; regexps
1259     ("\\(^\\|[[=(,~?:;<>]\\|\\(^\\|\\s \\)\\(if\\|elsif\\|unless\\|while\\|until\\|when\\|and\\|or\\|&&\\|||\\)\\|g?sub!?\\|scan\\|split!?\\)\\s *\\(/\\)[^/\n\\\\]*\\(\\\\.[^/\n\\\\]*\\)*\\(/\\)"
1260      (4 (7 . ?/))
1261      (6 (7 . ?/)))
1262     ("^=en\\(d\\)\\_>" 1 "!")
1263     ;; general delimited string
1264     ("\\(^\\|[[ \t\n<+(,=]\\)\\(%[xrqQwW]?\\([^<[{(a-zA-Z0-9 \n]\\)[^\n\\\\]*\\(\\\\.[^\n\\\\]*\\)*\\(\\3\\)\\)"
1265      (3 "\"")
1266      (5 "\""))
1267     ("^\\(=\\)begin\\_>" 1 (ruby-comment-beg-syntax))
1268     ;; Currently, the following case is highlighted incorrectly:
1269     ;;
1270     ;;   <<FOO
1271     ;;   FOO
1272     ;;   <<BAR
1273     ;;   <<BAZ
1274     ;;   BAZ
1275     ;;   BAR
1276     ;;
1277     ;; This is because all here-doc beginnings are highlighted before any endings,
1278     ;; so although <<BAR is properly marked as a beginning, when we get to <<BAZ
1279     ;; it thinks <<BAR is part of a string so it's marked as well.
1280     ;;
1281     ;; This may be fixable by modifying ruby-in-here-doc-p to use
1282     ;; ruby-in-non-here-doc-string-p rather than syntax-ppss-context,
1283     ;; but I don't want to try that until we've got unit tests set up
1284     ;; to make sure I don't break anything else.
1285     (,(concat ruby-here-doc-beg-re ".*\\(\n\\)")
1286      ,(+ 1 (regexp-opt-depth ruby-here-doc-beg-re))
1287      (ruby-here-doc-beg-syntax))
1288     (,ruby-here-doc-end-re 3 (ruby-here-doc-end-syntax)))
1289   "Syntactic keywords for Ruby mode.  See `font-lock-syntactic-keywords'.")
1290
1291   (defun ruby-comment-beg-syntax ()
1292   "Return the syntax cell for a the first character of a =begin.
1293 See the definition of `ruby-font-lock-syntactic-keywords'.
1294
1295 This returns a comment-delimiter cell as long as the =begin
1296 isn't in a string or another comment."
1297     (when (not (nth 3 (syntax-ppss)))
1298       (string-to-syntax "!")))
1299
1300   (defun ruby-in-here-doc-p ()
1301     "Return whether or not the point is in a heredoc."
1302     (save-excursion
1303       (let ((old-point (point)) (case-fold-search nil))
1304         (beginning-of-line)
1305         (catch 'found-beg
1306           (while (re-search-backward ruby-here-doc-beg-re nil t)
1307             (if (not (or (ruby-in-ppss-context-p 'anything)
1308                          (ruby-here-doc-find-end old-point)))
1309                 (throw 'found-beg t)))))))
1310
1311   (defun ruby-here-doc-find-end (&optional limit)
1312     "Expects the point to be on a line with one or more heredoc openers.
1313 Returns the buffer position at which all heredocs on the line
1314 are terminated, or nil if they aren't terminated before the
1315 buffer position `limit' or the end of the buffer."
1316     (save-excursion
1317       (beginning-of-line)
1318       (catch 'done
1319         (let ((eol (point-at-eol))
1320               (case-fold-search nil)
1321               ;; Fake match data such that (match-end 0) is at eol
1322               (end-match-data (progn (looking-at ".*$") (match-data)))
1323               beg-match-data end-re)
1324           (while (re-search-forward ruby-here-doc-beg-re eol t)
1325             (setq beg-match-data (match-data))
1326             (setq end-re (ruby-here-doc-end-match))
1327
1328             (set-match-data end-match-data)
1329             (goto-char (match-end 0))
1330             (unless (re-search-forward end-re limit t) (throw 'done nil))
1331             (setq end-match-data (match-data))
1332
1333             (set-match-data beg-match-data)
1334             (goto-char (match-end 0)))
1335           (set-match-data end-match-data)
1336           (goto-char (match-end 0))
1337           (point)))))
1338
1339   (defun ruby-here-doc-beg-syntax ()
1340     "Return the syntax cell for a line that may begin a heredoc.
1341 See the definition of `ruby-font-lock-syntactic-keywords'.
1342
1343 This sets the syntax cell for the newline ending the line
1344 containing the heredoc beginning so that cases where multiple
1345 heredocs are started on one line are handled correctly."
1346     (save-excursion
1347       (goto-char (match-beginning 0))
1348       (unless (or (ruby-in-ppss-context-p 'non-heredoc)
1349                   (ruby-in-here-doc-p))
1350         (string-to-syntax "\""))))
1351
1352   (defun ruby-here-doc-end-syntax ()
1353     "Return the syntax cell for a line that may end a heredoc.
1354 See the definition of `ruby-font-lock-syntactic-keywords'."
1355     (let ((pss (syntax-ppss)) (case-fold-search nil))
1356       ;; If we aren't in a string, we definitely aren't ending a heredoc,
1357       ;; so we can just give up.
1358       ;; This means we aren't doing a full-document search
1359       ;; every time we enter a character.
1360       (when (ruby-in-ppss-context-p 'heredoc pss)
1361         (save-excursion
1362           (goto-char (nth 8 pss))    ; Go to the beginning of heredoc.
1363           (let ((eol (point)))
1364             (beginning-of-line)
1365             (if (and (re-search-forward (ruby-here-doc-beg-match) eol t) ; If there is a heredoc that matches this line...
1366                      (not (ruby-in-ppss-context-p 'anything)) ; And that's not inside a heredoc/string/comment...
1367                      (progn (goto-char (match-end 0)) ; And it's the last heredoc on its line...
1368                             (not (re-search-forward ruby-here-doc-beg-re eol t))))
1369                 (string-to-syntax "\"")))))))
1370
1371   (unless (functionp 'syntax-ppss)
1372     (defun syntax-ppss (&optional pos)
1373       (parse-partial-sexp (point-min) (or pos (point)))))
1374   )
1375
1376 (defun ruby-in-ppss-context-p (context &optional ppss)
1377   (let ((ppss (or ppss (syntax-ppss (point)))))
1378     (if (cond
1379          ((eq context 'anything)
1380           (or (nth 3 ppss)
1381               (nth 4 ppss)))
1382          ((eq context 'string)
1383           (nth 3 ppss))
1384          ((eq context 'heredoc)
1385           (eq ?\n (nth 3 ppss)))
1386          ((eq context 'non-heredoc)
1387           (and (ruby-in-ppss-context-p 'anything)
1388                (not (ruby-in-ppss-context-p 'heredoc))))
1389          ((eq context 'comment)
1390           (nth 4 ppss))
1391          (t
1392           (error (concat
1393                   "Internal error on `ruby-in-ppss-context-p': "
1394                   "context name `" (symbol-name context) "' is unknown"))))
1395         t)))
1396
1397 (if (featurep 'xemacs)
1398     (put 'ruby-mode 'font-lock-defaults
1399          '((ruby-font-lock-keywords)
1400            nil nil nil
1401            beginning-of-line
1402            (font-lock-syntactic-keywords
1403             . ruby-font-lock-syntactic-keywords))))
1404
1405 (defvar ruby-font-lock-syntax-table
1406   (let ((tbl (copy-syntax-table ruby-mode-syntax-table)))
1407     (modify-syntax-entry ?_ "w" tbl)
1408     tbl)
1409   "The syntax table to use for fontifying Ruby mode buffers.
1410 See `font-lock-syntax-table'.")
1411
1412 (defconst ruby-font-lock-keywords
1413   (list
1414    ;; functions
1415    '("^\\s *def\\s +\\([^( \t\n]+\\)"
1416      1 font-lock-function-name-face)
1417    ;; keywords
1418    (cons (concat
1419           "\\(^\\|[^_:.@$]\\|\\.\\.\\)\\b\\(defined\\?\\|"
1420           (regexp-opt
1421            '("alias_method"
1422              "alias"
1423              "and"
1424              "begin"
1425              "break"
1426              "case"
1427              "catch"
1428              "class"
1429              "def"
1430              "do"
1431              "elsif"
1432              "else"
1433              "fail"
1434              "ensure"
1435              "for"
1436              "end"
1437              "if"
1438              "in"
1439              "module_function"
1440              "module"
1441              "next"
1442              "not"
1443              "or"
1444              "public"
1445              "private"
1446              "protected"
1447              "raise"
1448              "redo"
1449              "rescue"
1450              "retry"
1451              "return"
1452              "then"
1453              "throw"
1454              "super"
1455              "unless"
1456              "undef"
1457              "until"
1458              "when"
1459              "while"
1460              "yield")
1461            t)
1462           "\\)"
1463           ruby-keyword-end-re)
1464          2)
1465    ;; here-doc beginnings
1466    (list ruby-here-doc-beg-re 0 'font-lock-string-face)
1467    ;; variables
1468    '("\\(^\\|[^_:.@$]\\|\\.\\.\\)\\b\\(nil\\|self\\|true\\|false\\)\\>"
1469      2 font-lock-variable-name-face)
1470    ;; variables
1471    '("\\(\\$\\([^a-zA-Z0-9 \n]\\|[0-9]\\)\\)\\W"
1472      1 font-lock-variable-name-face)
1473    '("\\(\\$\\|@\\|@@\\)\\(\\w\\|_\\)+"
1474      0 font-lock-variable-name-face)
1475    ;; constants
1476    '("\\(^\\|[^_]\\)\\b\\([A-Z]+\\(\\w\\|_\\)*\\)"
1477      2 font-lock-type-face)
1478    ;; symbols
1479    '("\\(^\\|[^:]\\)\\(:\\([-+~]@?\\|[/%&|^`]\\|\\*\\*?\\|<\\(<\\|=>?\\)?\\|>[>=]?\\|===?\\|=~\\|![~=]?\\|\\[\\]=?\\|\\(\\w\\|_\\)+\\([!?=]\\|\\b_*\\)\\|#{[^}\n\\\\]*\\(\\\\.[^}\n\\\\]*\\)*}\\)\\)"
1480      2 font-lock-reference-face)
1481    '("\\(^\\s *\\|[\[\{\(,]\\s *\\|\\sw\\s +\\)\\(\\(\\sw\\|_\\)+\\):[^:]" 2 font-lock-reference-face)
1482    ;; expression expansion
1483    '("#\\({[^}\n\\\\]*\\(\\\\.[^}\n\\\\]*\\)*}\\|\\(\\$\\|@\\|@@\\)\\(\\w\\|_\\)+\\)"
1484      0 font-lock-variable-name-face t)
1485    ;; warn lower camel case
1486                                         ;'("\\<[a-z]+[a-z0-9]*[A-Z][A-Za-z0-9]*\\([!?]?\\|\\>\\)"
1487                                         ;  0 font-lock-warning-face)
1488    )
1489   "Additional expressions to highlight in Ruby mode.")
1490
1491 ;;;###autoload
1492 (define-derived-mode ruby-mode prog-mode "Ruby"
1493   "Major mode for editing Ruby scripts.
1494 \\[ruby-indent-line] properly indents subexpressions of multi-line
1495 class, module, def, if, while, for, do, and case statements, taking
1496 nesting into account.
1497
1498 The variable `ruby-indent-level' controls the amount of indentation.
1499
1500 \\{ruby-mode-map}"
1501   (ruby-mode-variables)
1502
1503   (set (make-local-variable 'imenu-create-index-function)
1504        'ruby-imenu-create-index)
1505   (set (make-local-variable 'add-log-current-defun-function)
1506        'ruby-add-log-current-method)
1507
1508   (add-hook
1509    (cond ((boundp 'before-save-hook) 'before-save-hook)
1510          ((boundp 'write-contents-functions) 'write-contents-functions)
1511          ((boundp 'write-contents-hooks) 'write-contents-hooks))
1512    'ruby-mode-set-encoding nil 'local)
1513
1514   (set (make-local-variable 'electric-indent-chars)
1515        (append '(?\{ ?\}) electric-indent-chars))
1516
1517   (set (make-local-variable 'font-lock-defaults)
1518        '((ruby-font-lock-keywords) nil nil))
1519   (set (make-local-variable 'font-lock-keywords)
1520        ruby-font-lock-keywords)
1521   (set (make-local-variable 'font-lock-syntax-table)
1522        ruby-font-lock-syntax-table)
1523
1524   (if (eval-when-compile (fboundp 'syntax-propertize-rules))
1525       (set (make-local-variable 'syntax-propertize-function)
1526            #'ruby-syntax-propertize-function)
1527     (set (make-local-variable 'font-lock-syntactic-keywords)
1528          ruby-font-lock-syntactic-keywords)))
1529
1530 ;;; Invoke ruby-mode when appropriate
1531
1532 ;;;###autoload
1533 (add-to-list 'auto-mode-alist (cons (purecopy "\\.rb\\'") 'ruby-mode))
1534
1535 ;;;###autoload
1536 (dolist (name (list "ruby" "rbx" "jruby" "ruby1.9" "ruby1.8"))
1537   (add-to-list 'interpreter-mode-alist (cons (purecopy name) 'ruby-mode)))
1538
1539 (provide 'ruby-mode)
1540
1541 ;;; ruby-mode.el ends here