m4/limits-h.m4

   1 dnl Check whether limits.h has needed features.
   2
   3 dnl Copyright 2016 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl From Paul Eggert.
   9
  10 AC_DEFUN_ONCE([gl_LIMITS_H],
  11 [
  12   gl_CHECK_NEXT_HEADERS([limits.h])
  13
  14   AC_CACHE_CHECK([whether limits.h has ULLONG_WIDTH etc.],
  15     [gl_cv_header_limits_width],
  16     [AC_COMPILE_IFELSE(
  17        [AC_LANG_PROGRAM([[#define __STDC_WANT_IEC_60559_BFP_EXT__ 1
  18                           #include <limits.h>
  19                           int ullw = ULLONG_WIDTH;]])],
  20        [gl_cv_header_limits_width=yes],
  21        [gl_cv_header_limits_width=no])])
  22   if test "$gl_cv_header_limits_width" = yes; then
  23     LIMITS_H=
  24   else
  25     LIMITS_H=limits.h
  26   fi
  27   AC_SUBST([LIMITS_H])
  28   AM_CONDITIONAL([GL_GENERATE_LIMITS_H], [test -n "$LIMITS_H"])
  29 ])