lisp/nxml/rng-valid.el

   1 ;;; rng-valid.el --- real-time validation of XML using RELAX NG  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 2003, 2007-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: James Clark
   6 ;; Keywords: wp, hypermedia, languages, XML, RelaxNG
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; For usage information, see the documentation for rng-validate-mode.
  26 ;;
  27 ;; This file provides a minor mode that continually validates a buffer
  28 ;; against a RELAX NG schema. The validation state is used to support
  29 ;; schema-sensitive editing as well as validation. Validation is
  30 ;; performed while Emacs is idle.  XML parsing is done using
  31 ;; xmltok.el. This file is responsible for checking that end-tags
  32 ;; match their start-tags.  Namespace processing is handled by
  33 ;; nxml-ns.el. The RELAX NG Compact Syntax schema is parsed into
  34 ;; internal form by rng-cmpct.el.  This internal form is described by
  35 ;; rng-pttrn.el.  Validation of the document by matching against this
  36 ;; internal form is done by rng-match.el. Handling of W3C XML Schema
  37 ;; datatypes is delegated by rng-match.el to rng-xsd.el.  The minor
  38 ;; mode is intended to be used in conjunction with the nxml major
  39 ;; mode, but does not have to be.
  40 ;;
  41 ;; The major responsibility of this file is to allow validation to
  42 ;; happen incrementally.  If a buffer has been validated and is then
  43 ;; changed, we can often revalidate it without having to completely
  44 ;; parse and validate it from start to end.  As we parse and validate
  45 ;; the buffer, we periodically cache the state.  The state has three
  46 ;; components: the stack of open elements, the namespace processing
  47 ;; state and the RELAX NG validation state. The state is cached as the
  48 ;; value of the rng-state text property on the closing greater-than of
  49 ;; tags (but at intervals, not on every tag).  We keep track of the
  50 ;; position up to which cached state is known to be correct by adding
  51 ;; a function to the buffer's after-change-functions. This is stored
  52 ;; in the rng-validate-up-to-date-end variable.  The first way in
  53 ;; which we make validation incremental is obvious: we start
  54 ;; validation from the first cached state before
  55 ;; rng-validate-up-to-date-end.
  56 ;;
  57 ;; To make this work efficiently, we have to be able to copy the
  58 ;; current parsing and validation state efficiently.  We do this by
  59 ;; minimizing destructive changes to the objects storing the state.
  60 ;; When state is changed, we use the old state to create new objects
  61 ;; representing the new state rather than destructively modifying the
  62 ;; objects representing the old state. Copying the state is just a
  63 ;; matter of making a list of three objects, one for each component of
  64 ;; the state; the three objects themselves can be shared and do not
  65 ;; need to be copied.
  66 ;;
  67 ;; There's one other idea that is used to make validation incremental.
  68 ;; Suppose we have a buffer that's 4000 bytes long and suppose we
  69 ;; validated it, caching state at positions 1000, 2000 and 3000.  Now
  70 ;; suppose we make a change at position 1500 inserting 100 characters.
  71 ;; rng-validate-up-to-date-end will be changed to 1500.  When Emacs
  72 ;; becomes idle and we revalidate, validation will restart using the
  73 ;; cached state at position 1000.  However, we take advantage of the
  74 ;; cached state beyond rng-validate-up-to-date-end as follows.  When
  75 ;; our validation reaches position 2100 (the current position of the
  76 ;; character that was at 2000), we compare our current state with the
  77 ;; cached state.  If they are the same, then we can stop parsing
  78 ;; immediately and set rng-validate-up-to-date-end to the end of the
  79 ;; buffer: we already know that the state cached at position 3100 is
  80 ;; correct.  If they are not the same, then we have to continue
  81 ;; parsing.  After the change, but before revalidation, we call the
  82 ;; region from 1600 to the end of the buffer "conditionally
  83 ;; up-to-date".
  84 ;;
  85 ;; As well as the cached parsing and validation state, we also keep
  86 ;; track of the errors in the file.  Errors are stored as overlays
  87 ;; with a category of rng-error.  The number of such overlays in the
  88 ;; buffer must always be equal to rng-error-count.
  89
  90 ;;; Code:
  91
  92 (require 'xmltok)
  93 (require 'nxml-enc)
  94 (require 'nxml-util)
  95 (require 'nxml-ns)
  96 (require 'rng-match)
  97 (require 'rng-util)
  98 (require 'rng-loc)
  99
 100 ;;; Customizable variables
 101
 102 (defgroup relax-ng nil
 103   "Validation of XML using RELAX NG."
 104   :group 'wp
 105   :group 'nxml
 106   :group 'languages)
 107
 108 (defface rng-error '((t (:inherit font-lock-warning-face)))
 109   "Face for highlighting XML errors."
 110   :group 'relax-ng)
 111
 112 (defcustom rng-state-cache-distance 2000
 113   "Distance in characters between each parsing and validation state cache."
 114   :type 'integer
 115   :group 'relax-ng)
 116
 117 (defcustom rng-validate-chunk-size 8000
 118   "Number of characters in a RELAX NG validation chunk.
 119 A validation chunk will be the smallest chunk that is at least this
 120 size and ends with a tag.  After validating a chunk, validation will
 121 continue only if Emacs is still idle."
 122   :type 'integer
 123   :group 'relax-ng)
 124
 125 (defcustom rng-validate-delay 1.5
 126   "Time in seconds that Emacs must be idle before starting a full validation.
 127 A full validation continues until either validation is up to date
 128 or Emacs is no longer idle."
 129   :type 'number
 130   :group 'relax-ng)
 131
 132 (defcustom rng-validate-quick-delay 0.3
 133   "Time in seconds that Emacs must be idle before starting a quick validation.
 134 A quick validation validates at most one chunk."
 135   :type 'number
 136   :group 'relax-ng)
 137
 138 ;; Global variables
 139
 140 (defvar rng-validate-timer nil)
 141 (make-variable-buffer-local 'rng-validate-timer)
 142 ;; ensure that we can cancel the timer even after a kill-all-local-variables
 143 (put 'rng-validate-timer 'permanent-local t)
 144
 145 (defvar rng-validate-quick-timer nil)
 146 (make-variable-buffer-local 'rng-validate-quick-timer)
 147 ;; ensure that we can cancel the timer even after a kill-all-local-variables
 148 (put 'rng-validate-quick-timer 'permanent-local t)
 149
 150 (defvar rng-error-count nil
 151   "Number of errors in the current buffer.
 152 Always equal to number of overlays with category `rng-error'.")
 153 (make-variable-buffer-local 'rng-error-count)
 154
 155 (defvar rng-message-overlay nil
 156   "Overlay in this buffer whose `help-echo' property was last printed.
 157 It is nil if none.")
 158 (make-variable-buffer-local 'rng-message-overlay)
 159
 160 (defvar rng-message-overlay-inhibit-point nil
 161   "Position at which message from overlay should be inhibited.
 162 If point is equal to this and the error overlay around
 163 point is `rng-message-overlay', then the `help-echo' property
 164 of the error overlay should not be printed with `message'.")
 165 (make-variable-buffer-local 'rng-message-overlay-inhibit-point)
 166
 167 (defvar rng-message-overlay-current nil
 168   "Non-nil if `rng-message-overlay' is still the current message.")
 169 (make-variable-buffer-local 'rng-message-overlay-current)
 170
 171 (defvar rng-open-elements nil
 172   "Stack of names of open elements represented as a list.
 173 Each member of the list is either t or a (PREFIX . LOCAL-NAME) pair.
 174 \(PREFIX . LOCAL-NAME) is pushed for a start-tag; t is pushed
 175 for a mismatched end-tag.")
 176
 177 (defvar rng-pending-contents nil
 178   "Text content of current element that has yet to be processed.
 179 Value is a list of segments (VALUE START END) positions in reverse
 180 order.  VALUE is a string or nil.  If VALUE is nil, then the value is
 181 the string between START and END.  A segment can also be nil
 182 indicating an unresolvable entity or character reference.")
 183
 184 (defvar rng-collecting-text nil)
 185
 186 (defvar rng-validate-up-to-date-end nil
 187   "Last position where validation is known to be up to date.")
 188 (make-variable-buffer-local 'rng-validate-up-to-date-end)
 189
 190 (defvar rng-conditional-up-to-date-start nil
 191   "Marker for the start of the conditionally up-to-date region.
 192 It is nil if there is no conditionally up-to-date region.  The
 193 conditionally up-to-date region must be such that for any cached
 194 state S with position P in the conditionally up-to-date region,
 195 if at some point it is determined that S becomes correct for P,
 196 then all states with position >= P in the conditionally up to
 197 date region must also then be correct and all errors between P
 198 and the end of the region must then be correctly marked.")
 199 (make-variable-buffer-local 'rng-conditional-up-to-date-start)
 200
 201 (defvar rng-conditional-up-to-date-end nil
 202   "Marker for the end of the conditionally up-to-date region.
 203 It is nil if there is no conditionally up-to-date region.
 204 See the variable `rng-conditional-up-to-date-start'.")
 205 (make-variable-buffer-local 'rng-conditional-up-to-date-end)
 206
 207 (defvar rng-parsing-for-state nil
 208   "Non-nil means we are currently parsing just to compute the state.
 209 Should be dynamically bound.")
 210
 211 (defvar rng-validate-mode nil)
 212 (make-variable-buffer-local 'rng-validate-mode)
 213
 214 (defvar rng-dtd nil)
 215 (make-variable-buffer-local 'rng-dtd)
 216
 217 ;;;###autoload
 218 (defun rng-validate-mode (&optional arg no-change-schema)
 219   "Minor mode performing continual validation against a RELAX NG schema.
 220
 221 Checks whether the buffer is a well-formed XML 1.0 document,
 222 conforming to the XML Namespaces Recommendation and valid against a
 223 RELAX NG schema.  The mode-line indicates whether it is or not.  Any
 224 parts of the buffer that cause it not to be are considered errors and
 225 are highlighted with face `rng-error'.  A description of each error is
 226 available as a tooltip.  \\[rng-next-error] goes to the next error
 227 after point.  Clicking mouse-1 on the word `Invalid' in the mode-line
 228 goes to the first error in the buffer.  If the buffer changes, then it
 229 will be automatically rechecked when Emacs becomes idle; the
 230 rechecking will be paused whenever there is input pending.
 231
 232 By default, uses a vacuous schema that allows any well-formed XML
 233 document.  A schema can be specified explicitly using
 234 \\[rng-set-schema-file-and-validate], or implicitly based on the buffer's
 235 file name or on the root element name.  In each case the schema must
 236 be a RELAX NG schema using the compact schema \(such schemas
 237 conventionally have a suffix of `.rnc').  The variable
 238 `rng-schema-locating-files' specifies files containing rules
 239 to use for finding the schema."
 240   (interactive "P")
 241   (setq rng-validate-mode
 242         (if (null arg)
 243             (not rng-validate-mode)
 244           (> (prefix-numeric-value arg) 0)))
 245   (save-restriction
 246     (widen)
 247     (with-silent-modifications
 248       (rng-clear-cached-state (point-min) (point-max)))
 249     ;; 1+ to clear empty overlays at (point-max)
 250     (rng-clear-overlays (point-min) (1+ (point-max)))
 251     (setq rng-validate-up-to-date-end (point-min)))
 252   (rng-clear-conditional-region)
 253   (setq rng-error-count 0)
 254   ;; do this here to avoid infinite loop if we set the schema
 255   (remove-hook 'rng-schema-change-hook 'rng-validate-clear t)
 256   (cond (rng-validate-mode
 257          (unwind-protect
 258              (save-excursion
 259                ;; An error can change the current buffer
 260                (when (or (not rng-current-schema)
 261                          (and (eq rng-current-schema rng-any-element)
 262                               (not no-change-schema)))
 263                  (rng-auto-set-schema t)))
 264            (unless rng-current-schema (rng-set-schema-file-1 nil))
 265            (add-hook 'rng-schema-change-hook 'rng-validate-clear nil t)
 266            (add-hook 'after-change-functions 'rng-after-change-function nil t)
 267            (add-hook 'kill-buffer-hook 'rng-kill-timers nil t)
 268            (add-hook 'echo-area-clear-hook 'rng-echo-area-clear-function nil t)
 269            (add-hook 'post-command-hook 'rng-maybe-echo-error-at-point nil t)
 270            (rng-match-init-buffer)
 271            (rng-activate-timers)
 272            ;; Start validating right away if the buffer is visible.
 273            ;; If it's not visible, don't do this, because the user
 274            ;; won't get any progress indication. When the user finds
 275            ;; a new file, then the buffer won't be visible
 276            ;; when this is invoked.
 277            (when (get-buffer-window (current-buffer) 'visible)
 278              (rng-validate-while-idle (current-buffer)))))
 279         (t
 280          (rng-cancel-timers)
 281          (force-mode-line-update)
 282          (remove-hook 'kill-buffer-hook 'rng-cancel-timers t)
 283          (remove-hook 'post-command-hook 'rng-maybe-echo-error-at-point t)
 284          (remove-hook 'echo-area-clear-hook 'rng-echo-area-clear-function t)
 285          (remove-hook 'after-change-functions 'rng-after-change-function t))))
 286
 287 (defun rng-set-schema-file-and-validate (filename)
 288   "Sets the schema and turns on `rng-validate-mode' if not already on.
 289 The schema is set like `rng-set-schema'."
 290   (interactive "fSchema file: ")
 291   (rng-set-schema-file filename)
 292   (or rng-validate-mode (rng-validate-mode)))
 293
 294 (defun rng-set-document-type-and-validate (type-id)
 295   (interactive (list (rng-read-type-id)))
 296   (and (rng-set-document-type type-id)
 297        (or rng-validate-mode (rng-validate-mode))))
 298
 299 (defun rng-auto-set-schema-and-validate ()
 300   "Set the schema for this buffer automatically and turn on `rng-validate-mode'.
 301 The schema is set like `rng-auto-set-schema'."
 302   (interactive)
 303   (rng-auto-set-schema)
 304   (or rng-validate-mode (rng-validate-mode)))
 305
 306 (defun rng-after-change-function (start end pre-change-len)
 307   (setq rng-message-overlay-inhibit-point nil)
 308   (with-silent-modifications
 309     (rng-clear-cached-state start end))
 310   ;; rng-validate-up-to-date-end holds the position before the change
 311   ;; Adjust it to reflect the change.
 312   (if (< start rng-validate-up-to-date-end)
 313       (setq rng-validate-up-to-date-end
 314             (if (<= (+ start pre-change-len) rng-validate-up-to-date-end)
 315                 (+ rng-validate-up-to-date-end
 316                    (- end start pre-change-len))
 317               start)))
 318   ;; Adjust the conditional zone
 319   (cond (rng-conditional-up-to-date-start
 320          (when (< rng-conditional-up-to-date-start end)
 321            (if (< end rng-conditional-up-to-date-end)
 322                (set-marker rng-conditional-up-to-date-start end)
 323              (rng-clear-conditional-region))))
 324         ((< end rng-validate-up-to-date-end)
 325          (setq rng-conditional-up-to-date-end
 326                (copy-marker rng-validate-up-to-date-end nil))
 327          (setq rng-conditional-up-to-date-start
 328                (copy-marker end t))))
 329   ;; Adjust rng-validate-up-to-date-end
 330   (if (< start rng-validate-up-to-date-end)
 331       (setq rng-validate-up-to-date-end start))
 332   ;; Must make rng-validate-up-to-date-end < point-max
 333   ;; (unless the buffer is empty).
 334   ;; otherwise rng-validate-prepare will say there's nothing to do.
 335   (when (>= rng-validate-up-to-date-end (point-max))
 336     (setq rng-validate-up-to-date-end
 337           (if (< (point-min) (point-max))
 338               (1- (point-max))
 339             ;; Only widen if really necessary.
 340             (save-restriction (widen) (max (point-min) (1- (point-max)))))))
 341   ;; Arrange to revalidate
 342   (rng-activate-timers)
 343   ;; Need to do this after activating the timer
 344   (force-mode-line-update))
 345
 346 (defun rng-compute-mode-line-string ()
 347   (cond (rng-validate-timer
 348          (format " Validated:%d%%"
 349                  (if (= 0 (buffer-size))
 350                      0
 351                    (floor (- rng-validate-up-to-date-end (point-min))
 352                           (- (point-max) (point-min))))))
 353         ((> rng-error-count 0)
 354          (concat " "
 355                  (propertize "Invalid"
 356                              'help-echo "mouse-1: go to first error"
 357                              'local-map (make-mode-line-mouse-map
 358                                          'mouse-1
 359                                          'rng-mouse-first-error))))
 360         (t " Valid")))
 361
 362 (defun rng-cancel-timers ()
 363   (let ((inhibit-quit t))
 364     (when rng-validate-timer
 365       (cancel-timer rng-validate-timer)
 366       (setq rng-validate-timer nil))
 367     (when rng-validate-quick-timer
 368       (cancel-timer rng-validate-quick-timer)
 369       (setq rng-validate-quick-timer nil))))
 370
 371 (defun rng-kill-timers ()
 372   ;; rng-validate-timer and rng-validate-quick-timer have the
 373   ;; permanent-local property, so that the timers can be
 374   ;; canceled even after changing mode.
 375   ;; This function takes care of canceling the timers and
 376   ;; then killing the local variables.
 377   (when (local-variable-p 'rng-validate-timer)
 378     (when rng-validate-timer
 379       (cancel-timer rng-validate-timer))
 380     (kill-local-variable 'rng-validate-timer))
 381   (when (local-variable-p 'rng-validate-quick-timer)
 382     (when rng-validate-quick-timer
 383       (cancel-timer rng-validate-quick-timer))
 384     (kill-local-variable 'rng-validate-quick-timer)))
 385
 386 (defun rng-activate-timers ()
 387   (unless rng-validate-timer
 388     (let ((inhibit-quit t))
 389       (setq rng-validate-timer
 390             (run-with-idle-timer rng-validate-delay
 391                                  t
 392                                  'rng-validate-while-idle
 393                                  (current-buffer)))
 394       (setq rng-validate-quick-timer
 395             (run-with-idle-timer rng-validate-quick-delay
 396                                  t
 397                                  'rng-validate-quick-while-idle
 398                                  (current-buffer))))))
 399
 400 (defun rng-validate-clear ()
 401   (rng-validate-mode 1 t))
 402
 403 ;; These two variables are dynamically bound and used
 404 ;; to pass information between rng-validate-while-idle
 405 ;; and rng-validate-while-idle-continue-p.
 406
 407 (defvar rng-validate-display-point nil)
 408 (defvar rng-validate-display-modified-p nil)
 409
 410 (defun rng-validate-while-idle-continue-p ()
 411   (and (not (input-pending-p))
 412        ;; Fake rng-validate-up-to-date-end so that the mode line
 413        ;; shows progress.  Also use this to save point.
 414        (let ((rng-validate-up-to-date-end (point)))
 415          (goto-char rng-validate-display-point)
 416          (when (not rng-validate-display-modified-p)
 417            (restore-buffer-modified-p nil))
 418          (force-mode-line-update)
 419          (let ((continue (sit-for 0)))
 420            (goto-char rng-validate-up-to-date-end)
 421            continue))))
 422
 423 ;; Calling rng-do-some-validation once with a continue-p function, as
 424 ;; opposed to calling it repeatedly, helps on initial validation of a
 425 ;; large buffer with lots of errors.  The overlays for errors will all
 426 ;; get added when rng-do-some-validation returns and won't slow the
 427 ;; validation process down.
 428
 429 (defun rng-validate-while-idle (buffer)
 430   (when (buffer-live-p buffer)          ; bug#13999
 431     (with-current-buffer buffer
 432       (if rng-validate-mode
 433           (if (let ((rng-validate-display-point (point))
 434                     (rng-validate-display-modified-p (buffer-modified-p)))
 435                 (rng-do-some-validation 'rng-validate-while-idle-continue-p))
 436               (force-mode-line-update)
 437             (rng-validate-done))
 438         ;; Must have done kill-all-local-variables.
 439         (rng-kill-timers)))))
 440
 441 (defun rng-validate-quick-while-idle (buffer)
 442   (when (buffer-live-p buffer)          ; bug#13999
 443     (with-current-buffer buffer
 444       (if rng-validate-mode
 445           (if (rng-do-some-validation)
 446               (force-mode-line-update)
 447             (rng-validate-done))
 448         ;; must have done kill-all-local-variables
 449         (rng-kill-timers)))))
 450
 451 (defun rng-validate-done ()
 452   (when (or (not (current-message))
 453             (rng-current-message-from-error-overlay-p))
 454     (rng-error-overlay-message (or (rng-error-overlay-after (point))
 455                                    (rng-error-overlay-after (1- (point))))))
 456   (rng-cancel-timers)
 457   (force-mode-line-update))
 458
 459 (defun rng-do-some-validation (&optional continue-p-function)
 460   "Do some validation work.  Return t if more to do, nil otherwise."
 461   (save-excursion
 462     (save-restriction
 463       (widen)
 464       (nxml-with-invisible-motion
 465         (condition-case-unless-debug err
 466             (and (rng-validate-prepare)
 467                  (let ((rng-dt-namespace-context-getter '(nxml-ns-get-context)))
 468                    (with-silent-modifications
 469                      (rng-do-some-validation-1 continue-p-function))))
 470           ;; errors signaled from a function run by an idle timer
 471           ;; are ignored; if we don't catch them, validation
 472           ;; will get mysteriously stuck at a single place
 473           (rng-compile-error
 474            (message "Incorrect schema. %s" (nth 1 err))
 475            (rng-validate-mode 0)
 476            nil)
 477           (error
 478            (message "Internal error in rng-validate-mode triggered at buffer position %d. %s"
 479                     (point)
 480                     (error-message-string err))
 481            (rng-validate-mode 0)
 482            nil))))))
 483
 484 (defun rng-validate-prepare ()
 485   "Prepare to do some validation, initializing point and the state.
 486 Return t if there is work to do, nil otherwise."
 487   (cond ((= rng-validate-up-to-date-end (point-min))
 488          (rng-set-initial-state)
 489          t)
 490         ((= rng-validate-up-to-date-end (point-max))
 491          nil)
 492         (t (let ((state (get-text-property (1- rng-validate-up-to-date-end)
 493                                            'rng-state)))
 494              (cond (state
 495                     (rng-restore-state state)
 496                     (goto-char rng-validate-up-to-date-end))
 497                    (t
 498                     (let ((pos (previous-single-property-change
 499                                 rng-validate-up-to-date-end
 500                                 'rng-state)))
 501                       (cond (pos
 502                              (rng-restore-state
 503                               (or (get-text-property (1- pos) 'rng-state)
 504                                   (error "Internal error: state null")))
 505                              (goto-char pos))
 506                             (t (rng-set-initial-state))))))))))
 507
 508 (defun rng-dtd-trivial-p (dtd)
 509   "Check whether the current dtd is different from the trivial default."
 510   (or (null dtd) (eq dtd xmltok-predefined-entity-alist)))
 511
 512 (defun rng-do-some-validation-1 (&optional continue-p-function)
 513   (let ((limit (+ rng-validate-up-to-date-end
 514                   rng-validate-chunk-size))
 515         (remove-start rng-validate-up-to-date-end)
 516         (next-cache-point (+ (point) rng-state-cache-distance))
 517         (continue t)
 518         (xmltok-dtd rng-dtd)
 519         have-remaining-chars
 520         xmltok-type
 521         xmltok-start
 522         xmltok-name-colon
 523         xmltok-name-end
 524         xmltok-replacement
 525         xmltok-attributes
 526         xmltok-namespace-attributes
 527         xmltok-errors)
 528     (when (= (point) 1)
 529       (let ((regions (xmltok-forward-prolog)))
 530         (rng-clear-overlays 1 (point))
 531         (while regions
 532           (when (eq (aref (car regions) 0) 'encoding-name)
 533             (rng-process-encoding-name (aref (car regions) 1)
 534                                        (aref (car regions) 2)))
 535           (setq regions (cdr regions))))
 536       (unless (equal rng-dtd xmltok-dtd)
 537         (rng-clear-conditional-region))
 538       (setq rng-dtd xmltok-dtd))
 539     (while continue
 540       (setq have-remaining-chars (rng-forward))
 541       (let ((pos (point)))
 542         (setq continue
 543               (and have-remaining-chars
 544                    (or (< pos limit)
 545                        (and continue-p-function
 546                             (funcall continue-p-function)
 547                             (setq limit (+ limit rng-validate-chunk-size))
 548                             t))))
 549         (cond ((and rng-conditional-up-to-date-start
 550                     ;; > because we are getting the state from (1- pos)
 551                     (> pos rng-conditional-up-to-date-start)
 552                     (< pos rng-conditional-up-to-date-end)
 553                     (rng-state-matches-current (get-text-property (1- pos)
 554                                                                   'rng-state)))
 555                (when (< remove-start (1- pos))
 556                  (rng-clear-cached-state remove-start (1- pos)))
 557                ;; sync up with cached validation state
 558                (setq continue nil)
 559                ;; do this before setting rng-validate-up-to-date-end
 560                ;; in case we get a quit
 561                (rng-mark-xmltok-errors)
 562                (setq rng-validate-up-to-date-end
 563                      (marker-position rng-conditional-up-to-date-end))
 564                (rng-clear-conditional-region)
 565                (setq have-remaining-chars
 566                      (< rng-validate-up-to-date-end (point-max))))
 567               ((or (>= pos next-cache-point)
 568                    (not continue))
 569                (setq next-cache-point (+ pos rng-state-cache-distance))
 570                (rng-clear-cached-state remove-start pos)
 571                (when have-remaining-chars
 572                  (rng-cache-state (1- pos)))
 573                (setq remove-start pos)
 574                (unless continue
 575                  ;; if we have just blank chars skip to the end
 576                  (when have-remaining-chars
 577                    (skip-chars-forward " \t\r\n")
 578                    (when (= (point) (point-max))
 579                      (rng-clear-overlays pos (point))
 580                      (rng-clear-cached-state pos (point))
 581                      (setq have-remaining-chars nil)
 582                      (setq pos (point))))
 583                  (when (not have-remaining-chars)
 584                    (rng-process-end-document))
 585                  (rng-mark-xmltok-errors)
 586                  (setq rng-validate-up-to-date-end pos)
 587                  (when rng-conditional-up-to-date-end
 588                    (cond ((<= rng-conditional-up-to-date-end pos)
 589                           (rng-clear-conditional-region))
 590                          ((< rng-conditional-up-to-date-start pos)
 591                           (set-marker rng-conditional-up-to-date-start
 592                                       pos)))))))))
 593     have-remaining-chars))
 594
 595 (defun rng-clear-conditional-region ()
 596   (when rng-conditional-up-to-date-start
 597     (set-marker rng-conditional-up-to-date-start nil)
 598     (setq rng-conditional-up-to-date-start nil))
 599   (when rng-conditional-up-to-date-end
 600     (set-marker rng-conditional-up-to-date-end nil)
 601     (setq rng-conditional-up-to-date-end nil)))
 602
 603 (defun rng-clear-cached-state (start end)
 604   "Clear cached state between START and END."
 605   (remove-text-properties start end '(rng-state nil)))
 606
 607 (defun rng-cache-state (pos)
 608   "Save the current state in a text property on the character at pos."
 609   (put-text-property pos
 610                      (1+ pos)
 611                      'rng-state
 612                      (rng-get-state)))
 613
 614 (defun rng-state-matches-current (state)
 615   (and state
 616        (rng-match-state-equal (car state))
 617        (nxml-ns-state-equal (nth 1 state))
 618        (equal (nth 2 state) rng-open-elements)))
 619
 620 (defun rng-get-state ()
 621   (list (rng-match-state)
 622         (nxml-ns-state)
 623         rng-open-elements))
 624
 625 (defun rng-restore-state (state)
 626   (rng-set-match-state (car state))
 627   (setq state (cdr state))
 628   (nxml-ns-set-state (car state))
 629   (setq rng-open-elements (cadr state))
 630   (setq rng-pending-contents nil)
 631   (setq rng-collecting-text (rng-match-text-typed-p)))
 632
 633 (defun rng-set-initial-state ()
 634   (nxml-ns-init)
 635   (rng-match-start-document)
 636   (setq rng-open-elements nil)
 637   (setq rng-pending-contents nil)
 638   (goto-char (point-min)))
 639
 640 (defun rng-clear-overlays (beg end)
 641   (unless rng-parsing-for-state
 642     (let ((overlays (overlays-in beg end)))
 643       (while overlays
 644         (let* ((overlay (car overlays))
 645                (category (overlay-get overlay 'category)))
 646           (cond ((eq category 'rng-error)
 647                  (let ((inhibit-quit t))
 648                    (when (eq overlay rng-message-overlay)
 649                      (rng-error-overlay-message nil))
 650                    (delete-overlay overlay)
 651                    ;; rng-error-count could be nil
 652                    ;; if overlays left over from a previous use
 653                    ;; of rng-validate-mode that ended with a change of mode
 654                    (when rng-error-count
 655                      (setq rng-error-count (1- rng-error-count)))))))
 656         (setq overlays (cdr overlays))))))
 657
 658 ;;; Error state
 659
 660 (defun rng-mark-xmltok-errors ()
 661   (while xmltok-errors
 662     (let ((err (car xmltok-errors)))
 663       (rng-mark-not-well-formed (xmltok-error-message err)
 664                                 (xmltok-error-start err)
 665                                 (xmltok-error-end err)))
 666     (setq xmltok-errors (cdr xmltok-errors))))
 667
 668 (defun rng-mark-invalid (message beg end)
 669   (rng-mark-error message beg end))
 670
 671 (defun rng-mark-not-well-formed (message beg end)
 672   ;; Don't try to validate further
 673   ;;(rng-set-match-state rng-not-allowed-ipattern)
 674   (rng-mark-error message beg end))
 675
 676 (defun rng-mark-error (message beg end)
 677   (unless rng-parsing-for-state
 678     (let ((overlays (overlays-in beg end)))
 679       (while (and overlays message)
 680         (let ((o (car overlays)))
 681           (when (and (eq (overlay-get o 'category) 'rng-error)
 682                      (= (overlay-start o) beg)
 683                      (= (overlay-end o) end))
 684             (overlay-put o
 685                          'help-echo
 686                          (concat (overlay-get o 'help-echo)
 687                                  "\n"
 688                                  message))
 689             (setq message nil)))
 690         (setq overlays (cdr overlays))))
 691     (when message
 692       (let ((inhibit-quit t))
 693         (setq rng-error-count (1+ rng-error-count))
 694         (let ((overlay
 695                (make-overlay beg end nil t
 696                              ;; Need to make the rear delimiter advance
 697                              ;; with the front delimiter when the overlay
 698                              ;; is empty, otherwise the front delimiter
 699                              ;; will move past the rear delimiter.
 700                              (= beg end))))
 701           ;; Ensure when we have two overlapping messages, the help-echo
 702           ;; of the one that starts first is shown
 703           (overlay-put overlay 'priority beg)
 704           (overlay-put overlay 'category 'rng-error)
 705           (overlay-put overlay 'help-echo message))))))
 706
 707 (put 'rng-error 'face 'rng-error)
 708 (put 'rng-error 'modification-hooks '(rng-error-modified))
 709
 710 ;; If we don't do this, then the front delimiter can move
 711 ;; past the end delimiter.
 712 (defun rng-error-modified (overlay after-p _beg _end &optional _pre-change-len)
 713   (when (and after-p
 714              (overlay-start overlay)    ; check not deleted
 715              (>= (overlay-start overlay)
 716                  (overlay-end overlay)))
 717     (let ((inhibit-quit t))
 718       (delete-overlay overlay)
 719       (setq rng-error-count (1- rng-error-count)))))
 720
 721 (defun rng-echo-area-clear-function ()
 722   (setq rng-message-overlay-current nil))
 723
 724 ;;; Error navigation
 725
 726 (defun rng-maybe-echo-error-at-point ()
 727   (when (or (not (current-message))
 728             (rng-current-message-from-error-overlay-p))
 729     (rng-error-overlay-message (rng-error-overlay-after (point)))))
 730
 731 (defun rng-error-overlay-after (pos)
 732   (let ((overlays (overlays-in pos (1+ pos)))
 733         (best nil))
 734     (while overlays
 735       (let ((overlay (car overlays)))
 736         (when (and (eq (overlay-get overlay 'category)
 737                        'rng-error)
 738                    (or (not best)
 739                        (< (overlay-start best)
 740                           (overlay-start overlay))))
 741           (setq best overlay)))
 742       (setq overlays (cdr overlays)))
 743     best))
 744
 745 (defun rng-first-error ()
 746   "Go to the first validation error.
 747 Turn on `rng-validate-mode' if it is not already on."
 748   (interactive)
 749   (or rng-validate-mode (rng-validate-mode))
 750   (rng-do-some-validation)
 751   (let ((err (rng-find-next-error-overlay (1- (point-min)))))
 752     (if err
 753         (rng-goto-error-overlay err)
 754       (let ((pos (save-excursion
 755                    (goto-char (point-min))
 756                    (rng-next-error 1))))
 757         (when pos
 758           (goto-char pos))))))
 759
 760 (defun rng-mouse-first-error (event)
 761   "Go to the first validation error from a mouse click."
 762   (interactive "e")
 763   (select-window (posn-window (event-start event)))
 764   (rng-first-error))
 765
 766 (defun rng-next-error (arg)
 767   "Go to the next validation error after point.
 768 Turn on `rng-validate-mode' if it is not already on.
 769 A prefix ARG specifies how many errors to move.
 770 A negative ARG moves backwards.  Just \\[universal-argument] as a prefix
 771 means goto the first error."
 772   (interactive "P")
 773   (if (consp arg)
 774       (rng-first-error)
 775     (or rng-validate-mode (rng-validate-mode))
 776     (setq arg (prefix-numeric-value arg))
 777     (if (< arg 0)
 778         (rng-previous-error-1 (- arg))
 779       (rng-next-error-1 arg))))
 780
 781 (defun rng-previous-error (arg)
 782   "Go to the previous validation error before point.
 783 Turn on `rng-validate-mode' if it is not already on.
 784 A prefix ARG specifies how many errors to move.
 785 A negative ARG moves forwards.  Just \\[universal-argument] as a prefix
 786 means goto the first error."
 787   (interactive "P")
 788   (if (consp arg)
 789       (rng-first-error)
 790     (or rng-validate-mode (rng-validate-mode))
 791     (setq arg (prefix-numeric-value arg))
 792     (if (< arg 0)
 793         (rng-next-error-1 (- arg))
 794       (rng-previous-error-1 arg))))
 795
 796 (defun rng-next-error-1 (arg)
 797   (let* ((pos (point))
 798          err last-err)
 799     (while (and (> arg 0)
 800                 (setq err (rng-find-next-error-overlay pos)))
 801       (setq arg (1- arg))
 802       (setq last-err err)
 803       (setq pos (overlay-start err)))
 804     (when (> arg 0)
 805       (setq pos (max pos (1- rng-validate-up-to-date-end)))
 806       (when (< rng-validate-up-to-date-end (point-max))
 807         (message "Parsing...")
 808         (while (let ((more-to-do (rng-do-some-validation)))
 809                  (while (and (> arg 0)
 810                              (setq err (rng-find-next-error-overlay pos)))
 811                    (setq arg (1- arg))
 812                    (setq last-err err)
 813                    (setq pos (overlay-start err)))
 814                  (when (and (> arg 0)
 815                             more-to-do
 816                             (< rng-validate-up-to-date-end (point-max)))
 817                    ;; Display percentage validated.
 818                    (force-mode-line-update)
 819                    (sit-for 0)
 820                    (setq pos
 821                          (max pos (1- rng-validate-up-to-date-end)))
 822                    t)))))
 823     (if last-err
 824         (rng-goto-error-overlay last-err)
 825       (message "No more errors")
 826       nil)))
 827
 828 (defun rng-previous-error-1 (arg)
 829   (let* ((pos (point))
 830          err last-err)
 831     (while (and (> arg 0)
 832                 (setq err (rng-find-previous-error-overlay pos)))
 833       (setq pos (overlay-start err))
 834       (setq last-err err)
 835       (setq arg (1- arg)))
 836     (when (and (> arg 0)
 837                (< rng-validate-up-to-date-end (min pos (point-max))))
 838       (message "Parsing...")
 839       (while (and (rng-do-some-validation)
 840                   (< rng-validate-up-to-date-end (min pos (point-max))))
 841         (force-mode-line-update)
 842         (sit-for 0))
 843       (while (and (> arg 0)
 844                   (setq err (rng-find-previous-error-overlay pos)))
 845         (setq pos (overlay-start err))
 846         (setq last-err err)
 847         (setq arg (1- arg))))
 848     (if last-err
 849         (rng-goto-error-overlay last-err)
 850       (message "No previous errors")
 851       nil)))
 852
 853 (defun rng-goto-error-overlay (err)
 854   "Goto the start of error overlay ERR and print its message."
 855   (goto-char (overlay-start err))
 856   (setq rng-message-overlay-inhibit-point nil)
 857   (rng-error-overlay-message err))
 858
 859 (defun rng-error-overlay-message (err)
 860   (if err
 861       (unless (or (and (eq rng-message-overlay-inhibit-point (point))
 862                        (eq rng-message-overlay err))
 863                   (= (point-max) 1))
 864         (message "%s" (overlay-get err 'help-echo))
 865         (setq rng-message-overlay-current t)
 866         (setq rng-message-overlay-inhibit-point (point)))
 867     (when (rng-current-message-from-error-overlay-p)
 868       (message nil))
 869     (setq rng-message-overlay-inhibit-point nil))
 870   (setq rng-message-overlay err))
 871
 872 (defun rng-current-message-from-error-overlay-p ()
 873   (and rng-message-overlay-current
 874        rng-message-overlay
 875        (equal (overlay-get rng-message-overlay 'help-echo)
 876               (current-message))))
 877
 878 (defun rng-find-next-error-overlay (pos)
 879   "Return the overlay for the next error starting after POS.
 880 Return nil if there is no such overlay or it is out of date.
 881 Do not do any additional validation."
 882   (when rng-error-count
 883     (let (done found overlays)
 884       (while (not done)
 885         (cond (overlays
 886                (let ((overlay (car overlays)))
 887                  (setq overlays (cdr overlays))
 888                  (when (and (eq (overlay-get overlay 'category) 'rng-error)
 889                             ;; Is it the first?
 890                             (= (overlay-start overlay) pos)
 891                             ;; Is it up to date?
 892                             (<= (overlay-end overlay)
 893                                 rng-validate-up-to-date-end))
 894                    (setq done t)
 895                    (setq found overlay))))
 896               ((or (= pos (point-max))
 897                    (> (setq pos (next-overlay-change pos))
 898                       rng-validate-up-to-date-end))
 899                (setq done t))
 900               (t (setq overlays (overlays-in pos (1+ pos))))))
 901       found)))
 902
 903 (defun rng-find-previous-error-overlay (pos)
 904   "Return the overlay for the last error starting before POS.
 905 Return nil if there is no such overlay or it is out of date.
 906 Do not do any additional validation."
 907   (when (and rng-error-count
 908              (<= pos rng-validate-up-to-date-end))
 909     (let (done found overlays)
 910       (while (not done)
 911         (cond (overlays
 912                (let ((overlay (car overlays)))
 913                  (setq overlays (cdr overlays))
 914                  (when (and (eq (overlay-get overlay 'category) 'rng-error)
 915                             ;; Is it the first?
 916                             (= (overlay-start overlay) pos))
 917                    (setq done t)
 918                    (setq found overlay))))
 919               ((= pos (point-min))
 920                (setq done t))
 921               (t
 922                (setq pos (previous-overlay-change pos))
 923                (setq overlays (overlays-in pos (1+ pos))))))
 924       found)))
 925
 926 ;;; Parsing
 927
 928 (defun rng-forward (&optional limit)
 929   "Move forward over one or more tokens updating the state.
 930 If LIMIT is nil, stop after tags.
 931 If LIMIT is non-nil, stop when end of last token parsed is >= LIMIT.
 932 Return nil at end of buffer, t otherwise."
 933   (let (type)
 934     (while (progn
 935              (setq type (xmltok-forward))
 936              (rng-clear-overlays xmltok-start (point))
 937              (let ((continue
 938                     (cond ((eq type 'start-tag)
 939                            (rng-process-start-tag 'start-tag)
 940                            nil)
 941                           ((eq type 'end-tag)
 942                            (rng-process-end-tag)
 943                            nil)
 944                           ((eq type 'empty-element)
 945                            (rng-process-start-tag 'empty-element)
 946                            nil)
 947                           ((eq type 'space)
 948                            (rng-process-text xmltok-start nil t)
 949                            t)
 950                           ((eq type 'data)
 951                            (rng-process-text xmltok-start nil nil)
 952                            t)
 953                           ((memq type '(entity-ref char-ref))
 954                            (cond (xmltok-replacement
 955                                   (rng-process-text xmltok-start
 956                                                     nil
 957                                                     'maybe
 958                                                     xmltok-replacement))
 959                                  ((eq type 'char-ref)
 960                                   (rng-process-unknown-char))
 961                                  (t
 962                                   (rng-process-unknown-entity)))
 963                            t)
 964                           ((eq type 'cdata-section)
 965                            (rng-process-text (+ xmltok-start 9) ; "<![CDATA["
 966                                              (- (point) 3) ; "]]>"
 967                                              'maybe)
 968                            t)
 969                           ((eq type 'partial-start-tag)
 970                            (rng-process-start-tag 'partial-start-tag)
 971                            t)
 972                           ((eq type 'partial-empty-element)
 973                            (rng-process-start-tag 'empty-element)
 974                            t)
 975                           ((eq type 'partial-end-tag)
 976                            (rng-process-end-tag 'partial)
 977                            t)
 978                           (t type))))
 979                (if limit
 980                    (< (point) limit)
 981                  continue))))
 982     (and type t)))
 983
 984 (defun rng-process-start-tag (tag-type)
 985   "TAG-TYPE is `start-tag' for a start-tag, `empty-element' for
 986 an empty element.  `partial-empty-element' should be passed
 987 as empty-element."
 988   (and rng-collecting-text (rng-flush-text))
 989   (setq rng-collecting-text nil)
 990   (setq rng-pending-contents nil)
 991   (rng-process-namespaces)
 992   (let ((tag (rng-process-tag-name)))
 993     (rng-process-attributes)
 994     ;; set the state appropriately
 995     (cond ((eq tag-type 'empty-element)
 996            (rng-process-start-tag-close)
 997            ;; deal with missing content with empty element
 998            (when (not (rng-match-empty-content))
 999              (rng-match-after)
1000              (rng-mark-start-tag-close "Empty content not allowed"))
1001            (nxml-ns-pop-state))
1002           ((eq tag-type 'start-tag)
1003            (rng-process-start-tag-close)
1004            (setq rng-collecting-text (rng-match-text-typed-p))
1005            (rng-push-tag tag))
1006           ((eq tag-type 'partial-start-tag)
1007            (rng-process-start-tag-close)
1008            (rng-match-after)
1009            (nxml-ns-pop-state)))))
1010
1011 (defun rng-process-namespaces ()
1012   (let ((nsatts xmltok-namespace-attributes)
1013         prefixes)
1014     (nxml-ns-push-state)
1015     (while nsatts
1016       (let* ((att (car nsatts))
1017              (value (xmltok-attribute-value att)))
1018         (when value
1019           (let ((ns (nxml-make-namespace value))
1020                 (prefix (and (xmltok-attribute-prefix att)
1021                              (xmltok-attribute-local-name att))))
1022             (cond ((member prefix prefixes)
1023                    (rng-mark-invalid "Duplicate namespace declaration"
1024                                      (xmltok-attribute-name-start att)
1025                                      (xmltok-attribute-name-end att)))
1026                   ((not prefix)
1027                    (nxml-ns-set-default ns))
1028                   (ns
1029                    (nxml-ns-set-prefix prefix ns))
1030                   (t
1031                    ;; cannot have xmlns:foo=""
1032                    (rng-mark-invalid "Namespace prefix cannot be undeclared"
1033                                      (1- (xmltok-attribute-value-start att))
1034                                      (1+ (xmltok-attribute-value-end att)))))
1035             (setq prefixes (cons prefix prefixes)))))
1036       (setq nsatts (cdr nsatts)))))
1037
1038 (defun rng-process-tag-name ()
1039   (let* ((prefix (xmltok-start-tag-prefix))
1040          (local-name (xmltok-start-tag-local-name))
1041          (name
1042           (if prefix
1043               (let ((ns (nxml-ns-get-prefix prefix)))
1044                 (cond (ns (cons ns local-name))
1045                       ((and (setq ns
1046                                   (rng-match-infer-start-tag-namespace
1047                                    local-name))
1048                             (rng-match-start-tag-open (cons ns local-name)))
1049                        (nxml-ns-set-prefix prefix ns)
1050                        (rng-mark-start-tag-close "Missing xmlns:%s=\"%s\""
1051                                                  prefix
1052                                                  (nxml-namespace-name ns))
1053                        nil)
1054                       (t
1055                        (rng-recover-bad-element-prefix)
1056                        nil)))
1057             (cons (nxml-ns-get-default) local-name))))
1058     (when (and name
1059                (not (rng-match-start-tag-open name)))
1060       (unless (and (not (car name))
1061                    (let ((ns (rng-match-infer-start-tag-namespace (cdr name))))
1062                      (and ns
1063                           (rng-match-start-tag-open (cons ns local-name))
1064                           (progn
1065                             (nxml-ns-set-default ns)
1066                             ;; XXX need to check we don't have xmlns=""
1067                             (rng-mark-start-tag-close "Missing xmlns=\"%s\""
1068                                                       (nxml-namespace-name ns))
1069                             t))))
1070         (rng-recover-start-tag-open name)))
1071     (cons prefix local-name)))
1072
1073 (defun rng-process-attributes ()
1074   (let ((atts xmltok-attributes)
1075         names)
1076     (while atts
1077       (let* ((att (car atts))
1078              (prefix (xmltok-attribute-prefix att))
1079              (local-name (xmltok-attribute-local-name att))
1080              (name
1081               (if prefix
1082                   (let ((ns (nxml-ns-get-prefix prefix)))
1083                     (and ns
1084                          (cons ns local-name)))
1085                 (cons nil local-name))))
1086         (cond ((not name)
1087                (rng-recover-bad-attribute-prefix att))
1088               ((member name names)
1089                (rng-recover-duplicate-attribute-name att))
1090               ((not (rng-match-attribute-name name))
1091                (rng-recover-attribute-name att))
1092               ((rng-match-text-typed-p)
1093                (let ((value (xmltok-attribute-value att)))
1094                  (if value
1095                      (or (rng-match-attribute-value value)
1096                          (rng-recover-attribute-value att))
1097                    (rng-match-after))))
1098               (t (or (rng-match-end-tag)
1099                      (error "Internal error:\
1100  invalid on untyped attribute value"))))
1101         (setq names (cons name names)))
1102       (setq atts (cdr atts)))))
1103
1104 (defun rng-process-start-tag-close ()
1105   ;; deal with missing attributes
1106   (unless (rng-match-start-tag-close)
1107     (rng-mark-start-tag-close (rng-missing-attributes-message))
1108     (rng-match-ignore-attributes)))
1109
1110 (defun rng-mark-start-tag-close (&rest args)
1111   (when (not (eq xmltok-type 'partial-start-tag))
1112     (rng-mark-invalid (apply 'format args)
1113                       (- (point)
1114                          (if (eq xmltok-type 'empty-element)
1115                              2
1116                            1))
1117                       (point))))
1118
1119 (defun rng-recover-bad-element-prefix ()
1120   (rng-mark-invalid "Prefix not declared"
1121                     (1+ xmltok-start)
1122                     xmltok-name-colon)
1123   (rng-match-unknown-start-tag-open))
1124
1125 (defun rng-recover-bad-attribute-prefix (att)
1126   (rng-mark-invalid "Prefix not declared"
1127                     (xmltok-attribute-name-start att)
1128                     (xmltok-attribute-name-colon att)))
1129
1130 (defun rng-recover-duplicate-attribute-name (att)
1131   (rng-mark-invalid "Duplicate attribute"
1132                     (xmltok-attribute-name-start att)
1133                     (xmltok-attribute-name-end att)))
1134
1135 (defun rng-recover-start-tag-open (name)
1136   (let ((required (rng-match-required-element-name)))
1137     (cond ((and required
1138                 (rng-match-start-tag-open required)
1139                 (rng-match-after)
1140                 (rng-match-start-tag-open name))
1141            (rng-mark-invalid (format "Missing element \"%s\""
1142                                      (rng-name-to-string required))
1143                              xmltok-start
1144                              (1+ xmltok-start)))
1145           ((and (rng-match-optionalize-elements)
1146                 (rng-match-start-tag-open name))
1147            (rng-mark-invalid "Required elements missing"
1148                              xmltok-start
1149                              (1+ xmltok-start)))
1150           ((rng-match-out-of-context-start-tag-open name)
1151            (rng-mark-invalid "Element not allowed in this context"
1152                              (1+ xmltok-start)
1153                              xmltok-name-end))
1154           (t
1155            (rng-match-unknown-start-tag-open)
1156            (rng-mark-invalid "Unknown element"
1157                              (1+ xmltok-start)
1158                              xmltok-name-end)))))
1159
1160 (defun rng-recover-attribute-value (att)
1161   (let ((start (xmltok-attribute-value-start att))
1162         (end (xmltok-attribute-value-end att)))
1163     (if (= start end)
1164         (rng-mark-invalid "Empty attribute value invalid" start (1+ end))
1165       (rng-mark-invalid "Attribute value invalid" start end)))
1166   (rng-match-after))
1167
1168 (defun rng-recover-attribute-name (att)
1169   (rng-mark-invalid "Attribute not allowed"
1170                     (xmltok-attribute-name-start att)
1171                     (xmltok-attribute-name-end att)))
1172
1173 (defun rng-missing-attributes-message ()
1174   (let ((required-attributes
1175          (rng-match-required-attribute-names)))
1176     (cond ((not required-attributes)
1177            "Required attributes missing")
1178           ((not (cdr required-attributes))
1179            (format "Missing attribute \"%s\""
1180                    (rng-name-to-string (car required-attributes) t)))
1181           (t
1182            (format "Missing attributes \"%s\""
1183                    (mapconcat (lambda (nm)
1184                                  (rng-name-to-string nm t))
1185                               required-attributes
1186                               "\", \""))))))
1187
1188 (defun rng-process-end-tag (&optional partial)
1189   (cond ((not rng-open-elements)
1190          (rng-mark-not-well-formed "Extra end-tag"
1191                                    xmltok-start
1192                                    (point)))
1193         ((or partial
1194              (equal (cons (xmltok-end-tag-prefix)
1195                           (xmltok-end-tag-local-name))
1196                     (car rng-open-elements)))
1197          (rng-end-element))
1198         (t (rng-recover-mismatched-end-tag))))
1199
1200 (defun rng-end-element ()
1201   (if rng-collecting-text
1202       (let ((contents (rng-contents-string)))
1203         (cond ((not contents) (rng-match-after))
1204               ((not (rng-match-element-value contents))
1205                (let* ((region (rng-contents-region)))
1206                  (if (not region)
1207                      (rng-mark-invalid "Empty content not allowed"
1208                                        xmltok-start
1209                                        (+ xmltok-start 2))
1210                    (rng-mark-invalid "Invalid data"
1211                                      (car region)
1212                                      (cdr region))))
1213                (rng-match-after)))
1214         (setq rng-collecting-text nil)
1215         (setq rng-pending-contents nil))
1216     (unless (rng-match-end-tag)
1217        (rng-mark-invalid (rng-missing-element-message)
1218                          xmltok-start
1219                          (+ xmltok-start 2))
1220        (rng-match-after)))
1221   (nxml-ns-pop-state)
1222   (when (eq (car rng-open-elements) t)
1223     (rng-pop-tag))
1224   (rng-pop-tag))
1225
1226 (defun rng-missing-element-message ()
1227   (let ((element (rng-match-required-element-name)))
1228     (if element
1229         (format "Missing element \"%s\"" (rng-name-to-string element))
1230       "Required child elements missing")))
1231
1232 (defun rng-recover-mismatched-end-tag ()
1233   (let* ((name (cons (xmltok-end-tag-prefix)
1234                      (xmltok-end-tag-local-name))))
1235     (cond ((member name (cdr rng-open-elements))
1236            (let* ((suppress-error (eq (car rng-open-elements) t))
1237                   missing top)
1238              (while (progn
1239                       (setq top (car rng-open-elements))
1240                       (rng-pop-tag)
1241                       (unless (eq top t)
1242                         (setq missing (cons top missing))
1243                         (nxml-ns-pop-state)
1244                         (rng-match-after))
1245                       (not (equal top name))))
1246              (unless suppress-error
1247                (rng-mark-missing-end-tags (cdr missing)))))
1248           ((rng-match-empty-before-p)
1249            (rng-mark-mismatched-end-tag)
1250            (rng-end-element))
1251           (t (rng-mark-mismatched-end-tag)
1252              (setq rng-open-elements
1253                    (cons t rng-open-elements))))))
1254
1255 (defun rng-mark-missing-end-tags (missing)
1256   (rng-mark-not-well-formed
1257    (format "Missing end-tag%s \"%s\""
1258            (if (null (cdr missing)) "" "s")
1259            (mapconcat (lambda (name)
1260                         (if (car name)
1261                             (concat (car name)
1262                                     ":"
1263                                     (cdr name))
1264                           (cdr name)))
1265                       missing
1266                       "\", \""))
1267    xmltok-start
1268    (+ xmltok-start 2)))
1269
1270 (defun rng-mark-mismatched-end-tag ()
1271   (rng-mark-not-well-formed "Mismatched end-tag"
1272                             (+ xmltok-start 2)
1273                             xmltok-name-end))
1274
1275 (defun rng-push-tag (prefix-local-name)
1276   (setq rng-open-elements
1277         (cons prefix-local-name rng-open-elements)))
1278
1279 (defun rng-pop-tag ()
1280   (setq rng-open-elements (cdr rng-open-elements)))
1281
1282 (defun rng-contents-string ()
1283   (let ((contents rng-pending-contents))
1284     (cond ((not contents) "")
1285           ((memq nil contents) nil)
1286           ((not (cdr contents))
1287            (rng-segment-string (car contents)))
1288           (t (apply 'concat
1289                     (nreverse (mapcar 'rng-segment-string
1290                                       contents)))))))
1291
1292 (defun rng-segment-string (segment)
1293   (or (car segment)
1294       (apply 'buffer-substring-no-properties
1295              (cdr segment))))
1296
1297 (defun rng-segment-blank-p (segment)
1298   (if (car segment)
1299       (rng-blank-p (car segment))
1300     (apply 'rng-region-blank-p
1301            (cdr segment))))
1302
1303 (defun rng-contents-region ()
1304   (if (null rng-pending-contents)
1305       nil
1306     (let* ((contents rng-pending-contents)
1307            (head (cdar contents))
1308            (start (car head))
1309            (end (cadr head)))
1310       (while (setq contents (cdr contents))
1311         (setq start (car (cdar contents))))
1312       (cons start end))))
1313
1314 (defun rng-process-text (start end whitespace &optional value)
1315   "Process characters between position START and END as text.
1316 END nil means point.  WHITESPACE t means known to be whitespace, nil
1317 means known not to be, anything else means unknown whether whitespace
1318 or not.  END must not be nil if WHITESPACE is neither t nor nil.
1319 VALUE is a string or nil; nil means the value is equal to the
1320 string between START and END."
1321   (cond (rng-collecting-text
1322          (setq rng-pending-contents (cons (list value start (or end (point)))
1323                                           rng-pending-contents)))
1324         ((not (or (and whitespace
1325                        (or (eq whitespace t)
1326                            (if value
1327                                (rng-blank-p value)
1328                              (rng-region-blank-p start end))))
1329                   (rng-match-mixed-text)))
1330          (rng-mark-invalid "Text not allowed" start (or end (point))))))
1331
1332 (defun rng-process-unknown-char ()
1333   (when rng-collecting-text
1334     (setq rng-pending-contents
1335           (cons nil rng-pending-contents))))
1336
1337 (defun rng-process-unknown-entity ()
1338   (rng-process-unknown-char)
1339   (rng-match-optionalize-elements))
1340
1341 (defun rng-region-blank-p (beg end)
1342   (save-excursion
1343     (goto-char beg)
1344     (= (skip-chars-forward " \n\r\t" end)
1345        (- end beg))))
1346
1347 (defun rng-flush-text ()
1348   (while rng-pending-contents
1349     (let ((segment (car rng-pending-contents)))
1350       (unless (or (rng-segment-blank-p segment)
1351                   (rng-match-mixed-text))
1352         (let ((region (cdr segment)))
1353           (rng-mark-invalid "In this context text cannot be mixed with elements"
1354                             (car region)
1355                             (cadr region)))))
1356     (setq rng-pending-contents (cdr rng-pending-contents))))
1357
1358 (defun rng-process-end-document ()
1359   ;; this is necessary to clear empty overlays at (point-max)
1360   (rng-clear-overlays (point) (point))
1361   (let ((start (save-excursion
1362                  (skip-chars-backward " \t\r\n")
1363                  (point))))
1364     (cond (rng-open-elements
1365            (unless (eq (car rng-open-elements) t)
1366              (rng-mark-not-well-formed "Missing end-tag"
1367                                        start
1368                                        (point))))
1369           ((not (rng-match-nullable-p))
1370            (rng-mark-not-well-formed "No document element"
1371                                      start
1372                                      (point))))))
1373
1374 (defun rng-process-encoding-name (beg end)
1375   (unless (let ((charset (buffer-substring-no-properties beg end)))
1376             (or (nxml-mime-charset-coding-system charset)
1377                 (string= (downcase charset) "utf-16")))
1378     (rng-mark-not-well-formed "Unsupported encoding" beg end)))
1379
1380 (defun rng-name-to-string (name &optional attributep)
1381   (let ((ns (car name))
1382         (local-name (cdr name)))
1383     (if (or (not ns)
1384             (and (not attributep)
1385                  (eq (nxml-ns-get-default) ns)))
1386         local-name
1387       (let ((prefix (nxml-ns-prefix-for ns)))
1388         (if prefix
1389             (concat prefix ":" local-name)
1390           (concat "{" (symbol-name ns) "}" local-name))))))
1391
1392 (provide 'rng-valid)
1393
1394 ;;; rng-valid.el ends here