lisp/epa-mail.el

   1 ;;; epa-mail.el --- the EasyPG Assistant, minor-mode for mail composer
   2 ;; Copyright (C) 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
   3
   4 ;; Author: Daiki Ueno <ueno@unixuser.org>
   5 ;; Keywords: PGP, GnuPG, mail, message
   6 ;; Package: epa
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Code:
  24
  25 (require 'epa)
  26 (require 'mail-utils)
  27
  28 (defvar epa-mail-mode-map
  29   (let ((keymap (make-sparse-keymap)))
  30     (define-key keymap "\C-c\C-ed" 'epa-mail-decrypt)
  31     (define-key keymap "\C-c\C-ev" 'epa-mail-verify)
  32     (define-key keymap "\C-c\C-es" 'epa-mail-sign)
  33     (define-key keymap "\C-c\C-ee" 'epa-mail-encrypt)
  34     (define-key keymap "\C-c\C-ei" 'epa-mail-import-keys)
  35     (define-key keymap "\C-c\C-eo" 'epa-insert-keys)
  36     (define-key keymap "\C-c\C-e\C-d" 'epa-mail-decrypt)
  37     (define-key keymap "\C-c\C-e\C-v" 'epa-mail-verify)
  38     (define-key keymap "\C-c\C-e\C-s" 'epa-mail-sign)
  39     (define-key keymap "\C-c\C-e\C-e" 'epa-mail-encrypt)
  40     (define-key keymap "\C-c\C-e\C-i" 'epa-mail-import-keys)
  41     (define-key keymap "\C-c\C-e\C-o" 'epa-insert-keys)
  42     keymap))
  43
  44 (defvar epa-mail-mode-hook nil)
  45 (defvar epa-mail-mode-on-hook nil)
  46 (defvar epa-mail-mode-off-hook nil)
  47
  48 ;;;###autoload
  49 (define-minor-mode epa-mail-mode
  50   "A minor-mode for composing encrypted/clearsigned mails."
  51   nil " epa-mail" epa-mail-mode-map)
  52
  53 (defun epa-mail--find-usable-key (keys usage)
  54   "Find a usable key from KEYS for USAGE."
  55   (catch 'found
  56     (while keys
  57       (let ((pointer (epg-key-sub-key-list (car keys))))
  58         (while pointer
  59           (if (and (memq usage (epg-sub-key-capability (car pointer)))
  60                    (not (memq (epg-sub-key-validity (car pointer))
  61                               '(revoked expired))))
  62               (throw 'found (car keys)))
  63           (setq pointer (cdr pointer))))
  64       (setq keys (cdr keys)))))
  65
  66 ;;;###autoload
  67 (defun epa-mail-decrypt ()
  68   "Decrypt OpenPGP armors in the current buffer.
  69 The buffer is expected to contain a mail message.
  70
  71 Don't use this command in Lisp programs!"
  72   (interactive)
  73   (epa-decrypt-armor-in-region (point-min) (point-max)))
  74
  75 ;;;###autoload
  76 (defun epa-mail-verify ()
  77   "Verify OpenPGP cleartext signed messages in the current buffer.
  78 The buffer is expected to contain a mail message.
  79
  80 Don't use this command in Lisp programs!"
  81   (interactive)
  82   (epa-verify-cleartext-in-region (point-min) (point-max)))
  83
  84 ;;;###autoload
  85 (defun epa-mail-sign (start end signers mode)
  86   "Sign the current buffer.
  87 The buffer is expected to contain a mail message.
  88
  89 Don't use this command in Lisp programs!"
  90   (interactive
  91    (save-excursion
  92      (goto-char (point-min))
  93      (if (search-forward mail-header-separator nil t)
  94          (forward-line))
  95      (setq epa-last-coding-system-specified
  96            (or coding-system-for-write
  97                (epa--select-safe-coding-system (point) (point-max))))
  98      (let ((verbose current-prefix-arg))
  99        (list (point) (point-max)
 100              (if verbose
 101                  (epa-select-keys (epg-make-context epa-protocol)
 102                                   "Select keys for signing.
 103 If no one is selected, default secret key is used.  "
 104                                   nil t))
 105              (if verbose
 106                  (epa--read-signature-type)
 107                'clear)))))
 108   (epa-sign-region start end signers mode))
 109
 110 ;;;###autoload
 111 (defun epa-mail-encrypt (start end recipients sign signers)
 112   "Encrypt the current buffer.
 113 The buffer is expected to contain a mail message.
 114
 115 Don't use this command in Lisp programs!"
 116   (interactive
 117    (save-excursion
 118      (let ((verbose current-prefix-arg)
 119            (context (epg-make-context epa-protocol))
 120            recipients-string recipients recipient-key)
 121        (goto-char (point-min))
 122        (save-restriction
 123          (narrow-to-region (point)
 124                            (if (search-forward mail-header-separator nil 0)
 125                                (match-beginning 0)
 126                              (point)))
 127          (setq recipients-string
 128                (mapconcat #'identity
 129                           (nconc (mail-fetch-field "to" nil nil t)
 130                                  (mail-fetch-field "cc" nil nil t)
 131                                  (mail-fetch-field "bcc" nil nil t))
 132                           ","))
 133          (setq recipients
 134                (mail-strip-quoted-names
 135                 (with-temp-buffer
 136                   (insert "to: " recipients-string "\n")
 137                   (expand-mail-aliases (point-min) (point-max))
 138                   (car (mail-fetch-field "to" nil nil t))))))
 139        (if recipients
 140            (setq recipients (delete ""
 141                                     (split-string recipients
 142                                                   "[ \t\n]*,[ \t\n]*"))))
 143        (goto-char (point-min))
 144        (if (search-forward mail-header-separator nil t)
 145            (forward-line))
 146        (setq epa-last-coding-system-specified
 147              (or coding-system-for-write
 148                  (epa--select-safe-coding-system (point) (point-max))))
 149        (list (point) (point-max)
 150              (if verbose
 151                  (epa-select-keys
 152                   context
 153                   "Select recipients for encryption.
 154 If no one is selected, symmetric encryption will be performed.  "
 155                   recipients)
 156                (if recipients
 157                    (mapcar
 158                     (lambda (recipient)
 159                       (setq recipient-key
 160                             (epa-mail--find-usable-key
 161                              (epg-list-keys
 162                               (epg-make-context epa-protocol)
 163                               (if (string-match "@" recipient)
 164                                   (concat "<" recipient ">")
 165                                 recipient))
 166                              'encrypt))
 167                       (unless (or recipient-key
 168                                   (y-or-n-p
 169                                    (format
 170                                     "No public key for %s; skip it? "
 171                                     recipient)))
 172                         (error "No public key for %s" recipient))
 173                       recipient-key)
 174                     recipients)))
 175              (setq sign (if verbose (y-or-n-p "Sign? ")))
 176              (if sign
 177                  (epa-select-keys context
 178                                   "Select keys for signing.  "))))))
 179   (epa-encrypt-region start end recipients sign signers))
 180
 181 ;;;###autoload
 182 (defun epa-mail-import-keys ()
 183   "Import keys in the OpenPGP armor format in the current buffer.
 184 The buffer is expected to contain a mail message.
 185
 186 Don't use this command in Lisp programs!"
 187   (interactive)
 188   (epa-import-armor-in-region (point-min) (point-max)))
 189
 190 ;;;###autoload
 191 (define-minor-mode epa-global-mail-mode
 192   "Minor mode to hook EasyPG into Mail mode."
 193   :global t :init-value nil :group 'epa-mail :version "23.1"
 194   (remove-hook 'mail-mode-hook 'epa-mail-mode)
 195   (if epa-global-mail-mode
 196       (add-hook 'mail-mode-hook 'epa-mail-mode)))
 197
 198 (provide 'epa-mail)
 199
 200 ;; arch-tag: a6f82b3f-d177-4a11-af95-040da55927d2
 201 ;;; epa-mail.el ends here