lisp/hi-lock.el

   1 ;;; hi-lock.el --- minor mode for interactive automatic highlighting  -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2000-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: David M. Koppelman <koppel@ece.lsu.edu>
   6 ;; Keywords: faces, minor-mode, matching, display
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24 ;;
  25 ;;  With the hi-lock commands text matching interactively entered
  26 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  27 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  28 ;;  using a yellow background face.  New occurrences of `clearly' will
  29 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  30 ;;  will remove the highlighting.  Any existing face can be used for
  31 ;;  highlighting and a set of appropriate faces is provided.  The
  32 ;;  regexps can be written into the current buffer in a form that will
  33 ;;  be recognized the next time the corresponding file is read (when
  34 ;;  file patterns is turned on).
  35 ;;
  36 ;;  Applications:
  37 ;;
  38 ;;    In program source code highlight a variable to quickly see all
  39 ;;    places it is modified or referenced:
  40 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  41 ;;
  42 ;;    In a shell or other buffer that is showing lots of program
  43 ;;    output, highlight the parts of the output you're interested in:
  44 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  45 ;;
  46 ;;    In buffers displaying tables, highlight the lines you're interested in:
  47 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  48 ;;
  49 ;;    When writing text, highlight personal cliches.  This can be
  50 ;;    amusing.
  51 ;;    M-x highlight-phrase as can be seen RET RET
  52 ;;
  53 ;;  Setup:
  54 ;;
  55 ;;    Put the following code in your init file.  This turns on
  56 ;;    hi-lock mode and adds a "Regexp Highlighting" entry
  57 ;;    to the edit menu.
  58 ;;
  59 ;;    (global-hi-lock-mode 1)
  60 ;;
  61 ;;    To enable the use of patterns found in files (presumably placed
  62 ;;    there by hi-lock) include the following in your init file:
  63 ;;
  64 ;;    (setq hi-lock-file-patterns-policy 'ask)
  65 ;;
  66 ;;    If you get tired of being asked each time a file is loaded replace
  67 ;;    `ask' with a function that returns t if patterns should be read.
  68 ;;
  69 ;;    You might also want to bind the hi-lock commands to more
  70 ;;    finger-friendly sequences:
  71
  72 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  73 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  74 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  75 ;;    (define-key hi-lock-map "\C-zp" 'highlight-phrase)
  76 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  77 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  78
  79 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  80 ;;    additional instructions.
  81
  82 ;; Sample file patterns:
  83
  84 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  85 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  86 ; Hi-lock: end
  87
  88 ;;; Code:
  89
  90 (require 'font-lock)
  91
  92 (defgroup hi-lock nil
  93   "Interactively add and remove font-lock patterns for highlighting text."
  94   :link '(custom-manual "(emacs)Highlight Interactively")
  95   :group 'font-lock)
  96
  97 (defcustom hi-lock-file-patterns-range 10000
  98   "Limit of search in a buffer for hi-lock patterns.
  99 When a file is visited and hi-lock mode is on, patterns starting
 100 up to this limit are added to font-lock's patterns.  See documentation
 101 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 102   :type 'integer
 103   :group 'hi-lock)
 104
 105 (defcustom hi-lock-highlight-range 200000
 106   "Size of area highlighted by hi-lock when font-lock not active.
 107 Font-lock is not active in buffers that do their own highlighting,
 108 such as the buffer created by `list-colors-display'.  In those buffers
 109 hi-lock patterns will only be applied over a range of
 110 `hi-lock-highlight-range' characters.  If font-lock is active then
 111 highlighting will be applied throughout the buffer."
 112   :type 'integer
 113   :group 'hi-lock)
 114
 115 (defcustom hi-lock-exclude-modes
 116   '(rmail-mode mime/viewer-mode gnus-article-mode)
 117   "List of major modes in which hi-lock will not run.
 118 For security reasons since font lock patterns can specify function
 119 calls."
 120   :type '(repeat symbol)
 121   :group 'hi-lock)
 122
 123 (defcustom hi-lock-file-patterns-policy 'ask
 124   "Specify when hi-lock should use patterns found in file.
 125 If `ask', prompt when patterns found in buffer; if bound to a function,
 126 use patterns when function returns t (function is called with patterns
 127 as first argument); if nil or `never' or anything else, don't use file
 128 patterns."
 129   :type '(choice (const :tag "Do not use file patterns" never)
 130                  (const :tag "Ask about file patterns" ask)
 131                  (function :tag "Function to check file patterns"))
 132   :group 'hi-lock
 133   :version "22.1")
 134
 135 ;; It can have a function value.
 136 (put 'hi-lock-file-patterns-policy 'risky-local-variable t)
 137
 138 (defcustom hi-lock-auto-select-face nil
 139   "Non-nil if highlighting commands should not prompt for face names.
 140 When non-nil, each hi-lock command will cycle through faces in
 141 `hi-lock-face-defaults' without prompting."
 142   :type 'boolean
 143   :version "24.4")
 144
 145 (defgroup hi-lock-faces nil
 146   "Faces for hi-lock."
 147   :group 'hi-lock
 148   :group 'faces)
 149
 150 (defface hi-yellow
 151   '((((min-colors 88) (background dark))
 152      (:background "yellow1" :foreground "black"))
 153     (((background dark)) (:background "yellow" :foreground "black"))
 154     (((min-colors 88)) (:background "yellow1"))
 155     (t (:background "yellow")))
 156   "Default face for hi-lock mode."
 157   :group 'hi-lock-faces)
 158
 159 (defface hi-pink
 160   '((((background dark)) (:background "pink" :foreground "black"))
 161     (t (:background "pink")))
 162   "Face for hi-lock mode."
 163   :group 'hi-lock-faces)
 164
 165 (defface hi-green
 166   '((((min-colors 88) (background dark))
 167      (:background "green1" :foreground "black"))
 168     (((background dark)) (:background "green" :foreground "black"))
 169     (((min-colors 88)) (:background "green1"))
 170     (t (:background "green")))
 171   "Face for hi-lock mode."
 172   :group 'hi-lock-faces)
 173
 174 (defface hi-blue
 175   '((((background dark)) (:background "light blue" :foreground "black"))
 176     (t (:background "light blue")))
 177   "Face for hi-lock mode."
 178   :group 'hi-lock-faces)
 179
 180 (defface hi-black-b
 181   '((t (:weight bold)))
 182   "Face for hi-lock mode."
 183   :group 'hi-lock-faces)
 184
 185 (defface hi-blue-b
 186   '((((min-colors 88)) (:weight bold :foreground "blue1"))
 187     (t (:weight bold :foreground "blue")))
 188   "Face for hi-lock mode."
 189   :group 'hi-lock-faces)
 190
 191 (defface hi-green-b
 192   '((((min-colors 88)) (:weight bold :foreground "green1"))
 193     (t (:weight bold :foreground "green")))
 194   "Face for hi-lock mode."
 195   :group 'hi-lock-faces)
 196
 197 (defface hi-red-b
 198   '((((min-colors 88)) (:weight bold :foreground "red1"))
 199     (t (:weight bold :foreground "red")))
 200   "Face for hi-lock mode."
 201   :group 'hi-lock-faces)
 202
 203 (defface hi-black-hb
 204   '((t (:weight bold :height 1.67 :inherit variable-pitch)))
 205   "Face for hi-lock mode."
 206   :group 'hi-lock-faces)
 207
 208 (defvar-local hi-lock-file-patterns nil
 209   "Patterns found in file for hi-lock.  Should not be changed.")
 210 (put 'hi-lock-file-patterns 'permanent-local t)
 211
 212 (defvar-local hi-lock-interactive-patterns nil
 213   "Patterns provided to hi-lock by user.  Should not be changed.")
 214 (put 'hi-lock-interactive-patterns 'permanent-local t)
 215
 216 (define-obsolete-variable-alias 'hi-lock-face-history
 217                                 'hi-lock-face-defaults "23.1")
 218 (defvar hi-lock-face-defaults
 219   '("hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 220     "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 221   "Default faces for hi-lock interactive functions.")
 222
 223 (define-obsolete-variable-alias 'hi-lock-regexp-history
 224                                 'regexp-history
 225                                 "23.1")
 226
 227 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 228   "Search target for finding hi-lock patterns at top of file.")
 229
 230 (defvar hi-lock-archaic-interface-message-used nil
 231   "True if user alerted that `global-hi-lock-mode' is now the global switch.
 232 Earlier versions of hi-lock used `hi-lock-mode' as the global switch;
 233 the message is issued if it appears that `hi-lock-mode' is used assuming
 234 that older functionality.  This variable avoids multiple reminders.")
 235
 236 (defvar hi-lock-archaic-interface-deduce nil
 237   "If non-nil, sometimes assume that `hi-lock-mode' means `global-hi-lock-mode'.
 238 Assumption is made if `hi-lock-mode' used in the *scratch* buffer while
 239 a library is being loaded.")
 240
 241 (defvar hi-lock-menu
 242   (let ((map (make-sparse-keymap "Hi Lock")))
 243     (define-key-after map [highlight-regexp]
 244       '(menu-item "Highlight Regexp..." highlight-regexp
 245         :help "Highlight text matching PATTERN (a regexp)."))
 246
 247     (define-key-after map [highlight-phrase]
 248       '(menu-item "Highlight Phrase..." highlight-phrase
 249         :help "Highlight text matching PATTERN (a regexp processed to match phrases)."))
 250
 251     (define-key-after map [highlight-lines-matching-regexp]
 252       '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 253         :help "Highlight lines containing match of PATTERN (a regexp)."))
 254
 255     (define-key-after map [unhighlight-regexp]
 256       '(menu-item "Remove Highlighting..." unhighlight-regexp
 257         :help "Remove previously entered highlighting pattern."
 258         :enable hi-lock-interactive-patterns))
 259
 260     (define-key-after map [hi-lock-write-interactive-patterns]
 261       '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 262         :help "Insert interactively added REGEXPs into buffer at point."
 263         :enable hi-lock-interactive-patterns))
 264
 265     (define-key-after map [hi-lock-find-patterns]
 266       '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 267         :help "Use patterns (if any) near top of buffer."))
 268     map)
 269   "Menu for hi-lock mode.")
 270
 271 (defvar hi-lock-map
 272   (let ((map (make-sparse-keymap "Hi Lock")))
 273     (define-key map "\C-xwi" 'hi-lock-find-patterns)
 274     (define-key map "\C-xwl" 'highlight-lines-matching-regexp)
 275     (define-key map "\C-xwp" 'highlight-phrase)
 276     (define-key map "\C-xwh" 'highlight-regexp)
 277     (define-key map "\C-xwr" 'unhighlight-regexp)
 278     (define-key map "\C-xwb" 'hi-lock-write-interactive-patterns)
 279     map)
 280   "Key map for hi-lock.")
 281
 282 (defvar hi-lock-read-regexp-defaults-function
 283   'hi-lock-read-regexp-defaults
 284   "Function that provides default regexp(s) for highlighting commands.
 285 This function should take no arguments and return one of nil, a
 286 regexp or a list of regexps for use with highlighting commands -
 287 `hi-lock-face-phrase-buffer', `hi-lock-line-face-buffer' and
 288 `hi-lock-face-buffer'.  The return value of this function is used
 289 as DEFAULTS param of `read-regexp' while executing the
 290 highlighting command.  This function is called only during
 291 interactive use.
 292
 293 For example, to highlight at symbol at point use
 294
 295     \(setq hi-lock-read-regexp-defaults-function
 296           'find-tag-default-as-regexp\)
 297
 298 If you need different defaults for different highlighting
 299 operations, use `this-command' to identify the command under
 300 execution.")
 301
 302 ;; Visible Functions
 303
 304 ;;;###autoload
 305 (define-minor-mode hi-lock-mode
 306   "Toggle selective highlighting of patterns (Hi Lock mode).
 307 With a prefix argument ARG, enable Hi Lock mode if ARG is
 308 positive, and disable it otherwise.  If called from Lisp, enable
 309 the mode if ARG is omitted or nil.
 310
 311 Hi Lock mode is automatically enabled when you invoke any of the
 312 highlighting commands listed below, such as \\[highlight-regexp].
 313 To enable Hi Lock mode in all buffers, use `global-hi-lock-mode'
 314 or add (global-hi-lock-mode 1) to your init file.
 315
 316 In buffers where Font Lock mode is enabled, patterns are
 317 highlighted using font lock.  In buffers where Font Lock mode is
 318 disabled, patterns are applied using overlays; in this case, the
 319 highlighting will not be updated as you type.
 320
 321 When Hi Lock mode is enabled, a \"Regexp Highlighting\" submenu
 322 is added to the \"Edit\" menu.  The commands in the submenu,
 323 which can be called interactively, are:
 324
 325 \\[highlight-regexp] REGEXP FACE
 326   Highlight matches of pattern REGEXP in current buffer with FACE.
 327
 328 \\[highlight-phrase] PHRASE FACE
 329   Highlight matches of phrase PHRASE in current buffer with FACE.
 330   (PHRASE can be any REGEXP, but spaces will be replaced by matches
 331   to whitespace and initial lower-case letters will become case insensitive.)
 332
 333 \\[highlight-lines-matching-regexp] REGEXP FACE
 334   Highlight lines containing matches of REGEXP in current buffer with FACE.
 335
 336 \\[unhighlight-regexp] REGEXP
 337   Remove highlighting on matches of REGEXP in current buffer.
 338
 339 \\[hi-lock-write-interactive-patterns]
 340   Write active REGEXPs into buffer as comments (if possible).  They may
 341   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 342   is issued.  The inserted regexps are in the form of font lock keywords.
 343   (See `font-lock-keywords'.)  They may be edited and re-loaded with \\[hi-lock-find-patterns],
 344   any valid `font-lock-keywords' form is acceptable.  When a file is
 345   loaded the patterns are read if `hi-lock-file-patterns-policy' is
 346   'ask and the user responds y to the prompt, or if
 347   `hi-lock-file-patterns-policy' is bound to a function and that
 348   function returns t.
 349
 350 \\[hi-lock-find-patterns]
 351   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 352
 353 When hi-lock is started and if the mode is not excluded or patterns
 354 rejected, the beginning of the buffer is searched for lines of the
 355 form:
 356   Hi-lock: FOO
 357
 358 where FOO is a list of patterns.  The patterns must start before
 359 position \(number of characters into buffer)
 360 `hi-lock-file-patterns-range'.  Patterns will be read until
 361 Hi-lock: end is found.  A mode is excluded if it's in the list
 362 `hi-lock-exclude-modes'."
 363   :group 'hi-lock
 364   :lighter (:eval (if (or hi-lock-interactive-patterns
 365                           hi-lock-file-patterns)
 366                       " Hi" ""))
 367   :global nil
 368   :keymap hi-lock-map
 369   (when (and (equal (buffer-name) "*scratch*")
 370              load-in-progress
 371              (not (called-interactively-p 'interactive))
 372              (not hi-lock-archaic-interface-message-used))
 373     (setq hi-lock-archaic-interface-message-used t)
 374     (if hi-lock-archaic-interface-deduce
 375         (global-hi-lock-mode hi-lock-mode)
 376       (warn
 377        "Possible archaic use of (hi-lock-mode).
 378 Use (global-hi-lock-mode 1) in .emacs to enable hi-lock for all buffers,
 379 use (hi-lock-mode 1) for individual buffers.  For compatibility with Emacs
 380 versions before 22 use the following in your init file:
 381
 382         (if (functionp 'global-hi-lock-mode)
 383             (global-hi-lock-mode 1)
 384           (hi-lock-mode 1))
 385 ")))
 386   (if hi-lock-mode
 387       ;; Turned on.
 388       (progn
 389         (define-key-after menu-bar-edit-menu [hi-lock]
 390           (cons "Regexp Highlighting" hi-lock-menu))
 391         (hi-lock-find-patterns)
 392         (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook nil t)
 393         ;; Remove regexps from font-lock-keywords (bug#13891).
 394         (add-hook 'change-major-mode-hook (lambda () (hi-lock-mode -1)) nil t))
 395     ;; Turned off.
 396     (when (or hi-lock-interactive-patterns
 397               hi-lock-file-patterns)
 398       (when hi-lock-interactive-patterns
 399         (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 400         (setq hi-lock-interactive-patterns nil))
 401       (when hi-lock-file-patterns
 402         (font-lock-remove-keywords nil hi-lock-file-patterns)
 403         (setq hi-lock-file-patterns nil))
 404       (remove-overlays nil nil 'hi-lock-overlay t)
 405       (when font-lock-fontified (font-lock-fontify-buffer)))
 406     (define-key-after menu-bar-edit-menu [hi-lock] nil)
 407     (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook t)))
 408
 409 ;;;###autoload
 410 (define-globalized-minor-mode global-hi-lock-mode
 411   hi-lock-mode turn-on-hi-lock-if-enabled
 412   :group 'hi-lock)
 413
 414 (defun turn-on-hi-lock-if-enabled ()
 415   (setq hi-lock-archaic-interface-message-used t)
 416   (unless (memq major-mode hi-lock-exclude-modes)
 417     (hi-lock-mode 1)))
 418
 419 ;;;###autoload
 420 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 421 ;;;###autoload
 422 (defun hi-lock-line-face-buffer (regexp &optional face)
 423   "Set face of all lines containing a match of REGEXP to FACE.
 424 Interactively, prompt for REGEXP then FACE.  Use
 425 `hi-lock-read-regexp-defaults-function' to retrieve default
 426 value(s) of REGEXP.  Use the global history list for FACE.
 427
 428 Use Font lock mode, if enabled, to highlight REGEXP.  Otherwise,
 429 use overlays for highlighting.  If overlays are used, the
 430 highlighting will not update as you type."
 431   (interactive
 432    (list
 433     (hi-lock-regexp-okay
 434      (read-regexp "Regexp to highlight line"
 435                   (funcall hi-lock-read-regexp-defaults-function)))
 436     (hi-lock-read-face-name)))
 437   (or (facep face) (setq face 'hi-yellow))
 438   (unless hi-lock-mode (hi-lock-mode 1))
 439   (hi-lock-set-pattern
 440    ;; The \\(?:...\\) grouping construct ensures that a leading ^, +, * or ?
 441    ;; or a trailing $ in REGEXP will be interpreted correctly.
 442    (concat "^.*\\(?:" regexp "\\).*$") face))
 443
 444
 445 ;;;###autoload
 446 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 447 ;;;###autoload
 448 (defun hi-lock-face-buffer (regexp &optional face)
 449   "Set face of each match of REGEXP to FACE.
 450 Interactively, prompt for REGEXP then FACE.  Use
 451 `hi-lock-read-regexp-defaults-function' to retrieve default
 452 value(s) REGEXP.  Use the global history list for FACE.
 453
 454 Use Font lock mode, if enabled, to highlight REGEXP.  Otherwise,
 455 use overlays for highlighting.  If overlays are used, the
 456 highlighting will not update as you type."
 457   (interactive
 458    (list
 459     (hi-lock-regexp-okay
 460      (read-regexp "Regexp to highlight"
 461                   (funcall hi-lock-read-regexp-defaults-function)))
 462     (hi-lock-read-face-name)))
 463   (or (facep face) (setq face 'hi-yellow))
 464   (unless hi-lock-mode (hi-lock-mode 1))
 465   (hi-lock-set-pattern regexp face))
 466
 467 ;;;###autoload
 468 (defalias 'highlight-phrase 'hi-lock-face-phrase-buffer)
 469 ;;;###autoload
 470 (defun hi-lock-face-phrase-buffer (regexp &optional face)
 471   "Set face of each match of phrase REGEXP to FACE.
 472 Interactively, prompt for REGEXP then FACE.  Use
 473 `hi-lock-read-regexp-defaults-function' to retrieve default
 474 value(s) of REGEXP.  Use the global history list for FACE.  When
 475 called interactively, replace whitespace in user provided regexp
 476 with arbitrary whitespace and make initial lower-case letters
 477 case-insensitive before highlighting with `hi-lock-set-pattern'.
 478
 479 Use Font lock mode, if enabled, to highlight REGEXP.  Otherwise,
 480 use overlays for highlighting.  If overlays are used, the
 481 highlighting will not update as you type."
 482   (interactive
 483    (list
 484     (hi-lock-regexp-okay
 485      (hi-lock-process-phrase
 486       (read-regexp "Phrase to highlight"
 487                    (funcall hi-lock-read-regexp-defaults-function))))
 488     (hi-lock-read-face-name)))
 489   (or (facep face) (setq face 'hi-yellow))
 490   (unless hi-lock-mode (hi-lock-mode 1))
 491   (hi-lock-set-pattern regexp face))
 492
 493 (defun hi-lock-keyword->face (keyword)
 494   (cadr (cadr (cadr keyword))))    ; Keyword looks like (REGEXP (0 'FACE) ...).
 495
 496 (declare-function x-popup-menu "menu.c" (position menu))
 497
 498 (defun hi-lock--regexps-at-point ()
 499   (let ((regexps '()))
 500     ;; When using overlays, there is no ambiguity on the best
 501     ;; choice of regexp.
 502     (let ((regexp (get-char-property (point) 'hi-lock-overlay-regexp)))
 503       (when regexp (push regexp regexps)))
 504     ;; With font-locking on, check if the cursor is on a highlighted text.
 505     (let ((face-after (get-text-property (point) 'face))
 506           (face-before
 507            (unless (bobp) (get-text-property (1- (point)) 'face)))
 508           (faces (mapcar #'hi-lock-keyword->face
 509                          hi-lock-interactive-patterns)))
 510       (unless (memq face-before faces) (setq face-before nil))
 511       (unless (memq face-after faces) (setq face-after nil))
 512       (when (and face-before face-after (not (eq face-before face-after)))
 513         (setq face-before nil))
 514       (when (or face-after face-before)
 515         (let* ((hi-text
 516                 (buffer-substring-no-properties
 517                  (if face-before
 518                      (or (previous-single-property-change (point) 'face)
 519                          (point-min))
 520                    (point))
 521                  (if face-after
 522                      (or (next-single-property-change (point) 'face)
 523                          (point-max))
 524                    (point)))))
 525           ;; Compute hi-lock patterns that match the
 526           ;; highlighted text at point.  Use this later in
 527           ;; during completing-read.
 528           (dolist (hi-lock-pattern hi-lock-interactive-patterns)
 529             (let ((regexp (car hi-lock-pattern)))
 530               (if (string-match regexp hi-text)
 531                   (push regexp regexps)))))))
 532     regexps))
 533
 534 (defvar-local hi-lock--unused-faces nil
 535   "List of faces that is not used and is available for highlighting new text.
 536 Face names from this list come from `hi-lock-face-defaults'.")
 537
 538 ;;;###autoload
 539 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 540 ;;;###autoload
 541 (defun hi-lock-unface-buffer (regexp)
 542   "Remove highlighting of each match to REGEXP set by hi-lock.
 543 Interactively, prompt for REGEXP, accepting only regexps
 544 previously inserted by hi-lock interactive functions.
 545 If REGEXP is t (or if \\[universal-argument] was specified interactively),
 546 then remove all hi-lock highlighting."
 547   (interactive
 548    (cond
 549     (current-prefix-arg (list t))
 550     ((and (display-popup-menus-p)
 551           (listp last-nonmenu-event)
 552           use-dialog-box)
 553      (catch 'snafu
 554        (or
 555         (x-popup-menu
 556          t
 557          (cons
 558           `keymap
 559           (cons "Select Pattern to Unhighlight"
 560                 (mapcar (lambda (pattern)
 561                           (list (car pattern)
 562                                 (format
 563                                  "%s (%s)" (car pattern)
 564                                  (hi-lock-keyword->face pattern))
 565                                 (cons nil nil)
 566                                 (car pattern)))
 567                         hi-lock-interactive-patterns))))
 568         ;; If the user clicks outside the menu, meaning that they
 569         ;; change their mind, x-popup-menu returns nil, and
 570         ;; interactive signals a wrong number of arguments error.
 571         ;; To prevent that, we return an empty string, which will
 572         ;; effectively disable the rest of the function.
 573         (throw 'snafu '("")))))
 574     (t
 575      ;; Un-highlighting triggered via keyboard action.
 576      (unless hi-lock-interactive-patterns
 577        (error "No highlighting to remove"))
 578      ;; Infer the regexp to un-highlight based on cursor position.
 579      (let* ((defaults (or (hi-lock--regexps-at-point)
 580                           (mapcar #'car hi-lock-interactive-patterns))))
 581        (list
 582         (completing-read (if (null defaults)
 583                              "Regexp to unhighlight: "
 584                            (format "Regexp to unhighlight (default %s): "
 585                                    (car defaults)))
 586                          hi-lock-interactive-patterns
 587                          nil t nil nil defaults))))))
 588   (dolist (keyword (if (eq regexp t) hi-lock-interactive-patterns
 589                      (list (assoc regexp hi-lock-interactive-patterns))))
 590     (when keyword
 591       (let ((face (hi-lock-keyword->face keyword)))
 592         ;; Make `face' the next one to use by default.
 593         (when (symbolp face)          ;Don't add it if it's a list (bug#13297).
 594           (add-to-list 'hi-lock--unused-faces (face-name face))))
 595       (font-lock-remove-keywords nil (list keyword))
 596       (setq hi-lock-interactive-patterns
 597             (delq keyword hi-lock-interactive-patterns))
 598       (remove-overlays
 599        nil nil 'hi-lock-overlay-regexp (hi-lock--hashcons (car keyword)))
 600       (when font-lock-fontified (font-lock-fontify-buffer)))))
 601
 602 ;;;###autoload
 603 (defun hi-lock-write-interactive-patterns ()
 604   "Write interactively added patterns, if any, into buffer at point.
 605
 606 Interactively added patterns are those normally specified using
 607 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 608 be found in variable `hi-lock-interactive-patterns'."
 609   (interactive)
 610   (if (null hi-lock-interactive-patterns)
 611       (error "There are no interactive patterns"))
 612   (let ((beg (point)))
 613     (mapc
 614      (lambda (pattern)
 615        (insert (format "%s: (%s)\n"
 616                        hi-lock-file-patterns-prefix
 617                        (prin1-to-string pattern))))
 618      hi-lock-interactive-patterns)
 619     (comment-region beg (point)))
 620   (when (> (point) hi-lock-file-patterns-range)
 621     (warn "Inserted keywords not close enough to top of file")))
 622
 623 ;; Implementation Functions
 624
 625 (defun hi-lock-process-phrase (phrase)
 626   "Convert regexp PHRASE to a regexp that matches phrases.
 627
 628 Blanks in PHRASE replaced by regexp that matches arbitrary whitespace
 629 and initial lower-case letters made case insensitive."
 630   (let ((mod-phrase nil))
 631     ;; FIXME fragile; better to just bind case-fold-search?  (Bug#7161)
 632     (setq mod-phrase
 633           (replace-regexp-in-string
 634            "\\(^\\|\\s-\\)\\([a-z]\\)"
 635            (lambda (m) (format "%s[%s%s]"
 636                                (match-string 1 m)
 637                                (upcase (match-string 2 m))
 638                                (match-string 2 m))) phrase))
 639     ;; FIXME fragile; better to use search-spaces-regexp?
 640     (setq mod-phrase
 641           (replace-regexp-in-string
 642            "\\s-+" "[ \t\n]+" mod-phrase nil t))))
 643
 644 (defun hi-lock-regexp-okay (regexp)
 645   "Return REGEXP if it appears suitable for a font-lock pattern.
 646
 647 Otherwise signal an error.  A pattern that matches the null string is
 648 not suitable."
 649   (if (string-match regexp "")
 650       (error "Regexp cannot match an empty string")
 651     regexp))
 652
 653 (defun hi-lock-read-regexp-defaults ()
 654   "Return the latest regexp from `regexp-history'.
 655 See `hi-lock-read-regexp-defaults-function' for details."
 656   (car regexp-history))
 657
 658 (defun hi-lock-read-face-name ()
 659   "Return face for interactive highlighting.
 660 When `hi-lock-auto-select-face' is non-nil, just return the next face.
 661 Otherwise, read face name from minibuffer with completion and history."
 662   (unless hi-lock-interactive-patterns
 663     (setq hi-lock--unused-faces hi-lock-face-defaults))
 664   (let* ((last-used-face
 665           (when hi-lock-interactive-patterns
 666             (face-name (hi-lock-keyword->face
 667                         (car hi-lock-interactive-patterns)))))
 668          (defaults (append hi-lock--unused-faces
 669                            (cdr (member last-used-face hi-lock-face-defaults))
 670                            hi-lock-face-defaults))
 671          face)
 672           (if (and hi-lock-auto-select-face (not current-prefix-arg))
 673         (setq face (or (pop hi-lock--unused-faces) (car defaults)))
 674       (setq face (completing-read
 675                   (format "Highlight using face (default %s): "
 676                           (car defaults))
 677                   obarray 'facep t nil 'face-name-history defaults))
 678       ;; Update list of un-used faces.
 679       (setq hi-lock--unused-faces (remove face hi-lock--unused-faces))
 680       ;; Grow the list of defaults.
 681       (add-to-list 'hi-lock-face-defaults face t))
 682     (intern face)))
 683
 684 (defun hi-lock-set-pattern (regexp face)
 685   "Highlight REGEXP with face FACE."
 686   ;; Hashcons the regexp, so it can be passed to remove-overlays later.
 687   (setq regexp (hi-lock--hashcons regexp))
 688   (let ((pattern (list regexp (list 0 (list 'quote face) t))))
 689     ;; Refuse to highlight a text that is already highlighted.
 690     (unless (assoc regexp hi-lock-interactive-patterns)
 691       (push pattern hi-lock-interactive-patterns)
 692       (if font-lock-mode
 693           (progn
 694             (font-lock-add-keywords nil (list pattern) t)
 695             (font-lock-fontify-buffer))
 696         (let* ((range-min (- (point) (/ hi-lock-highlight-range 2)))
 697                (range-max (+ (point) (/ hi-lock-highlight-range 2)))
 698                (search-start
 699                 (max (point-min)
 700                      (- range-min (max 0 (- range-max (point-max))))))
 701                (search-end
 702                 (min (point-max)
 703                      (+ range-max (max 0 (- (point-min) range-min))))))
 704           (save-excursion
 705             (goto-char search-start)
 706             (while (re-search-forward regexp search-end t)
 707               (let ((overlay (make-overlay (match-beginning 0) (match-end 0))))
 708                 (overlay-put overlay 'hi-lock-overlay t)
 709                 (overlay-put overlay 'hi-lock-overlay-regexp regexp)
 710                 (overlay-put overlay 'face face))
 711               (goto-char (match-end 0)))))))))
 712
 713 (defun hi-lock-set-file-patterns (patterns)
 714   "Replace file patterns list with PATTERNS and refontify."
 715   (when (or hi-lock-file-patterns patterns)
 716     (font-lock-remove-keywords nil hi-lock-file-patterns)
 717     (setq hi-lock-file-patterns patterns)
 718     (font-lock-add-keywords nil hi-lock-file-patterns t)
 719     (font-lock-fontify-buffer)))
 720
 721 (defun hi-lock-find-patterns ()
 722   "Find patterns in current buffer for hi-lock."
 723   (interactive)
 724   (unless (memq major-mode hi-lock-exclude-modes)
 725     (let ((all-patterns nil)
 726           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 727       (save-excursion
 728         (save-restriction
 729           (widen)
 730           (goto-char (point-min))
 731           (re-search-forward target-regexp
 732                              (+ (point) hi-lock-file-patterns-range) t)
 733           (beginning-of-line)
 734           (while (and (re-search-forward target-regexp (+ (point) 100) t)
 735                       (not (looking-at "\\s-*end")))
 736             (condition-case nil
 737                 (setq all-patterns (append (read (current-buffer)) all-patterns))
 738               (error (message "Invalid pattern list expression at %d"
 739                               (line-number-at-pos)))))))
 740       (when (and all-patterns
 741                  hi-lock-mode
 742                  (cond
 743                   ((eq this-command 'hi-lock-find-patterns) t)
 744                   ((functionp hi-lock-file-patterns-policy)
 745                    (funcall hi-lock-file-patterns-policy all-patterns))
 746                   ((eq hi-lock-file-patterns-policy 'ask)
 747                    (y-or-n-p "Add patterns from this buffer to hi-lock? "))
 748                   (t nil)))
 749         (hi-lock-set-file-patterns all-patterns)
 750         (if (called-interactively-p 'interactive)
 751             (message "Hi-lock added %d patterns." (length all-patterns)))))))
 752
 753 (defun hi-lock-font-lock-hook ()
 754   "Add hi-lock patterns to font-lock's."
 755   (when font-lock-fontified
 756     (font-lock-add-keywords nil hi-lock-file-patterns t)
 757     (font-lock-add-keywords nil hi-lock-interactive-patterns t)))
 758
 759 (defvar hi-lock--hashcons-hash
 760   (make-hash-table :test 'equal :weakness t)
 761   "Hash table used to hash cons regexps.")
 762
 763 (defun hi-lock--hashcons (string)
 764   "Return unique object equal to STRING."
 765   (or (gethash string hi-lock--hashcons-hash)
 766       (puthash string string hi-lock--hashcons-hash)))
 767
 768 (defun hi-lock-unload-function ()
 769   "Unload the Hi-Lock library."
 770   (global-hi-lock-mode -1)
 771   ;; continue standard unloading
 772   nil)
 773
 774 (provide 'hi-lock)
 775
 776 ;;; hi-lock.el ends here