lisp/custom.el

   1 ;;; custom.el -- Tools for declaring and initializing options.
   2 ;;
   3 ;; Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: help, faces
   7 ;; Version: 1.97
   8 ;; X-URL: http://www.dina.kvl.dk/~abraham/custom/
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; If you want to use this code, please visit the URL above.
  30 ;;
  31 ;; This file only contain the code needed to declare and initialize
  32 ;; user options.  The code to customize options is autoloaded from
  33 ;; `cus-edit.el'.
  34
  35 ;; The code implementing face declarations is in `cus-face.el'
  36
  37 ;;; Code:
  38
  39 (require 'widget)
  40
  41 (define-widget-keywords :initialize :set :get :require :prefix :tag
  42   :load :link :options :type :group)
  43
  44
  45 (defvar custom-define-hook nil
  46   ;; Customize information for this option is in `cus-edit.el'.
  47   "Hook called after defining each customize option.")
  48
  49 ;;; The `defcustom' Macro.
  50
  51 (defun custom-initialize-default (symbol value)
  52   "Initialize SYMBOL with VALUE.
  53 This will do nothing if symbol already has a default binding.
  54 Otherwise, if symbol has a `saved-value' property, it will evaluate
  55 the car of that and used as the default binding for symbol.
  56 Otherwise, VALUE will be evaluated and used as the default binding for
  57 symbol."
  58   (unless (default-boundp symbol)
  59     ;; Use the saved value if it exists, otherwise the factory setting.
  60     (set-default symbol (if (get symbol 'saved-value)
  61                             (eval (car (get symbol 'saved-value)))
  62                           (eval value)))))
  63
  64 (defun custom-initialize-set (symbol value)
  65   "Initialize SYMBOL with VALUE.
  66 Like `custom-initialize-default', but use the function specified by
  67 `:set' to initialize SYMBOL."
  68   (unless (default-boundp symbol)
  69     (funcall (or (get symbol 'custom-set) 'set-default)
  70              symbol
  71              (if (get symbol 'saved-value)
  72                  (eval (car (get symbol 'saved-value)))
  73                (eval value)))))
  74
  75 (defun custom-initialize-reset (symbol value)
  76   "Initialize SYMBOL with VALUE.
  77 Like `custom-initialize-set', but use the function specified by
  78 `:get' to reinitialize SYMBOL if it is already bound."
  79     (funcall (or (get symbol 'custom-set) 'set-default)
  80              symbol
  81              (cond ((default-boundp symbol)
  82                     (funcall (or (get symbol 'custom-get) 'default-value)
  83                              symbol))
  84                    ((get symbol 'saved-value)
  85                     (eval (car (get symbol 'saved-value))))
  86                    (t
  87                     (eval value)))))
  88
  89 (defun custom-initialize-changed (symbol value)
  90   "Initialize SYMBOL with VALUE.
  91 Like `custom-initialize-reset', but only use the `:set' function if the
  92 not using the factory setting.  Otherwise, use the `set-default'."
  93   (cond ((default-boundp symbol)
  94          (funcall (or (get symbol 'custom-set) 'set-default)
  95                   symbol
  96                   (funcall (or (get symbol 'custom-get) 'default-value)
  97                            symbol)))
  98         ((get symbol 'saved-value)
  99          (funcall (or (get symbol 'custom-set) 'set-default)
 100                   symbol
 101                   (eval (car (get symbol 'saved-value)))))
 102         (t
 103          (set-default symbol (eval value)))))
 104
 105 (defun custom-declare-variable (symbol value doc &rest args)
 106   "Like `defcustom', but SYMBOL and VALUE are evaluated as normal arguments."
 107   ;; Remember the factory setting.
 108   (put symbol 'factory-value (list value))
 109   ;; Maybe this option was rogue in an earlier version.  It no longer is.
 110   (when (get symbol 'force-value)
 111     ;; It no longer is.
 112     (put symbol 'force-value nil))
 113   (when doc
 114     (put symbol 'variable-documentation doc))
 115   (let ((initialize 'custom-initialize-set)
 116         (requests nil))
 117     (while args
 118       (let ((arg (car args)))
 119         (setq args (cdr args))
 120         (unless (symbolp arg)
 121           (error "Junk in args %S" args))
 122         (let ((keyword arg)
 123               (value (car args)))
 124           (unless args
 125             (error "Keyword %s is missing an argument" keyword))
 126           (setq args (cdr args))
 127           (cond ((eq keyword :initialize)
 128                  (setq initialize value))
 129                 ((eq keyword :set)
 130                  (put symbol 'custom-set value))
 131                 ((eq keyword :get)
 132                  (put symbol 'custom-get value))
 133                 ((eq keyword :require)
 134                  (setq requests (cons value requests)))
 135                 ((eq keyword :type)
 136                  (put symbol 'custom-type value))
 137                 ((eq keyword :options)
 138                  (if (get symbol 'custom-options)
 139                      ;; Slow safe code to avoid duplicates.
 140                      (mapcar (lambda (option)
 141                                (custom-add-option symbol option))
 142                              value)
 143                    ;; Fast code for the common case.
 144                    (put symbol 'custom-options (copy-sequence value))))
 145                 (t
 146                  (custom-handle-keyword symbol keyword value
 147                                         'custom-variable))))))
 148     (put symbol 'custom-requests requests)
 149     ;; Do the actual initialization.
 150     (funcall initialize symbol value))
 151   (run-hooks 'custom-define-hook)
 152   symbol)
 153
 154 (defmacro defcustom (symbol value doc &rest args)
 155   "Declare SYMBOL as a customizable variable that defaults to VALUE.
 156 DOC is the variable documentation.
 157
 158 Neither SYMBOL nor VALUE needs to be quoted.
 159 If SYMBOL is not already bound, initialize it to VALUE.
 160 The remaining arguments should have the form
 161
 162    [KEYWORD VALUE]...
 163
 164 The following KEYWORD's are defined:
 165
 166 :type   VALUE should be a widget type for editing the symbols value.
 167         The default is `sexp'.
 168 :options VALUE should be a list of valid members of the widget type.
 169 :group  VALUE should be a customization group.
 170         Add SYMBOL to that group.
 171 :initialize VALUE should be a function used to initialize the
 172         variable.  It takes two arguments, the symbol and value
 173         given in the `defcustom' call.  The default is
 174         `custom-initialize-default'
 175 :set    VALUE should be a function to set the value of the symbol.
 176         It takes two arguments, the symbol to set and the value to
 177         give it.  The default is `set-default'.
 178 :get    VALUE should be a function to extract the value of symbol.
 179         The function takes one argument, a symbol, and should return
 180         the current value for that symbol.  The default is
 181         `default-value'.
 182 :require VALUE should be a feature symbol.  Each feature will be
 183         required after initialization, of the the user have saved this
 184         option.
 185
 186 Read the section about customization in the Emacs Lisp manual for more
 187 information."
 188   `(custom-declare-variable (quote ,symbol) (quote ,value) ,doc ,@args))
 189
 190 ;;; The `defface' Macro.
 191
 192 (defmacro defface (face spec doc &rest args)
 193   "Declare FACE as a customizable face that defaults to SPEC.
 194 FACE does not need to be quoted.
 195
 196 Third argument DOC is the face documentation.
 197
 198 If FACE has been set with `custom-set-face', set the face attributes
 199 as specified by that function, otherwise set the face attributes
 200 according to SPEC.
 201
 202 The remaining arguments should have the form
 203
 204    [KEYWORD VALUE]...
 205
 206 The following KEYWORD's are defined:
 207
 208 :group  VALUE should be a customization group.
 209         Add FACE to that group.
 210
 211 SPEC should be an alist of the form ((DISPLAY ATTS)...).
 212
 213 ATTS is a list of face attributes and their values.  The possible
 214 attributes are defined in the variable `custom-face-attributes'.
 215 Alternatively, ATTS can be a face in which case the attributes of that
 216 face is used.
 217
 218 The ATTS of the first entry in SPEC where the DISPLAY matches the
 219 frame should take effect in that frame.  DISPLAY can either be the
 220 symbol t, which will match all frames, or an alist of the form
 221 \((REQ ITEM...)...)
 222
 223 For the DISPLAY to match a FRAME, the REQ property of the frame must
 224 match one of the ITEM.  The following REQ are defined:
 225
 226 `type' (the value of `window-system')
 227   Should be one of `x' or `tty'.
 228
 229 `class' (the frame's color support)
 230   Should be one of `color', `grayscale', or `mono'.
 231
 232 `background' (what color is used for the background text)
 233   Should be one of `light' or `dark'.
 234
 235 Read the section about customization in the Emacs Lisp manual for more
 236 information."
 237   `(custom-declare-face (quote ,face) ,spec ,doc ,@args))
 238
 239 ;;; The `defgroup' Macro.
 240
 241 (defun custom-declare-group (symbol members doc &rest args)
 242   "Like `defgroup', but SYMBOL is evaluated as a normal argument."
 243   (while members
 244     (apply 'custom-add-to-group symbol (car members))
 245     (setq members (cdr members)))
 246   (put symbol 'custom-group (nconc members (get symbol 'custom-group)))
 247   (when doc
 248     (put symbol 'group-documentation doc))
 249   (while args
 250     (let ((arg (car args)))
 251       (setq args (cdr args))
 252       (unless (symbolp arg)
 253         (error "Junk in args %S" args))
 254       (let ((keyword arg)
 255             (value (car args)))
 256         (unless args
 257           (error "Keyword %s is missing an argument" keyword))
 258         (setq args (cdr args))
 259         (cond ((eq keyword :prefix)
 260                (put symbol 'custom-prefix value))
 261               (t
 262                (custom-handle-keyword symbol keyword value
 263                                       'custom-group))))))
 264   (run-hooks 'custom-define-hook)
 265   symbol)
 266
 267 (defmacro defgroup (symbol members doc &rest args)
 268   "Declare SYMBOL as a customization group containing MEMBERS.
 269 SYMBOL does not need to be quoted.
 270
 271 Third arg DOC is the group documentation.
 272
 273 MEMBERS should be an alist of the form ((NAME WIDGET)...) where
 274 NAME is a symbol and WIDGET is a widget is a widget for editing that
 275 symbol.  Useful widgets are `custom-variable' for editing variables,
 276 `custom-face' for edit faces, and `custom-group' for editing groups.
 277
 278 The remaining arguments should have the form
 279
 280    [KEYWORD VALUE]...
 281
 282 The following KEYWORD's are defined:
 283
 284 :group  VALUE should be a customization group.
 285         Add SYMBOL to that group.
 286
 287 Read the section about customization in the Emacs Lisp manual for more
 288 information."
 289   `(custom-declare-group (quote ,symbol) ,members ,doc ,@args))
 290
 291 (defun custom-add-to-group (group option widget)
 292   "To existing GROUP add a new OPTION of type WIDGET.
 293 If there already is an entry for that option, overwrite it."
 294   (let* ((members (get group 'custom-group))
 295          (old (assq option members)))
 296     (if old
 297         (setcar (cdr old) widget)
 298       (put group 'custom-group (nconc members (list (list option widget)))))))
 299
 300 ;;; Properties.
 301
 302 (defun custom-handle-all-keywords (symbol args type)
 303   "For customization option SYMBOL, handle keyword arguments ARGS.
 304 Third argument TYPE is the custom option type."
 305   (while args
 306     (let ((arg (car args)))
 307       (setq args (cdr args))
 308       (unless (symbolp arg)
 309         (error "Junk in args %S" args))
 310       (let ((keyword arg)
 311             (value (car args)))
 312         (unless args
 313           (error "Keyword %s is missing an argument" keyword))
 314         (setq args (cdr args))
 315         (custom-handle-keyword symbol keyword value type)))))
 316
 317 (defun custom-handle-keyword (symbol keyword value type)
 318   "For customization option SYMBOL, handle KEYWORD with VALUE.
 319 Fourth argument TYPE is the custom option type."
 320   (cond ((eq keyword :group)
 321          (custom-add-to-group value symbol type))
 322         ((eq keyword :link)
 323          (custom-add-link symbol value))
 324         ((eq keyword :load)
 325          (custom-add-load symbol value))
 326         ((eq keyword :tag)
 327          (put symbol 'custom-tag value))
 328         (t
 329          (error "Unknown keyword %s" symbol))))
 330
 331 (defun custom-add-option (symbol option)
 332   "To the variable SYMBOL add OPTION.
 333
 334 If SYMBOL is a hook variable, OPTION should be a hook member.
 335 For other types variables, the effect is undefined."
 336   (let ((options (get symbol 'custom-options)))
 337     (unless (member option options)
 338       (put symbol 'custom-options (cons option options)))))
 339
 340 (defun custom-add-link (symbol widget)
 341   "To the custom option SYMBOL add the link WIDGET."
 342   (let ((links (get symbol 'custom-links)))
 343     (unless (member widget links)
 344       (put symbol 'custom-links (cons widget links)))))
 345
 346 (defun custom-add-load (symbol load)
 347   "To the custom option SYMBOL add the dependency LOAD.
 348 LOAD should be either a library file name, or a feature name."
 349   (let ((loads (get symbol 'custom-loads)))
 350     (unless (member load loads)
 351       (put symbol 'custom-loads (cons load loads)))))
 352
 353 ;;; Initializing.
 354
 355 (defun custom-set-variables (&rest args)
 356   "Initialize variables according to user preferences.
 357
 358 The arguments should be a list where each entry has the form:
 359
 360   (SYMBOL VALUE [NOW])
 361
 362 The unevaluated VALUE is stored as the saved value for SYMBOL.
 363 If NOW is present and non-nil, VALUE is also evaluated and bound as
 364 the default value for the SYMBOL."
 365   (while args
 366     (let ((entry (car args)))
 367       (if (listp entry)
 368           (let* ((symbol (nth 0 entry))
 369                  (value (nth 1 entry))
 370                  (now (nth 2 entry))
 371                  (requests (nth 3 entry))
 372                  (set (or (get symbol 'custom-set) 'set-default)))
 373             (put symbol 'saved-value (list value))
 374             (cond (now
 375                    ;; Rogue variable, set it now.
 376                    (put symbol 'force-value t)
 377                    (funcall set symbol (eval value)))
 378                   ((default-boundp symbol)
 379                    ;; Something already set this, overwrite it.
 380                    (funcall set symbol (eval value))))
 381             (when requests
 382               (put symbol 'custom-requests requests)
 383               (mapcar 'require requests))
 384             (setq args (cdr args)))
 385         ;; Old format, a plist of SYMBOL VALUE pairs.
 386         (message "Warning: old format `custom-set-variables'")
 387         (ding)
 388         (sit-for 2)
 389         (let ((symbol (nth 0 args))
 390               (value (nth 1 args)))
 391           (put symbol 'saved-value (list value)))
 392         (setq args (cdr (cdr args)))))))
 393
 394 ;;; The End.
 395
 396 (provide 'custom)
 397
 398 ;; custom.el ends here