lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001, 2002
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   ;; Warning suppression -- can't require x-win in batch:
  33   (autoload 'xw-defined-colors "x-win"))
  34
  35 \f
  36 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  37 ;;; Font selection.
  38 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  39
  40 (defgroup font-selection nil
  41   "Influencing face font selection."
  42   :group 'faces)
  43
  44
  45 (defcustom face-font-selection-order
  46   '(:width :height :weight :slant)
  47   "*A list specifying how face font selection chooses fonts.
  48 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  49 must appear once in the list, and the list must not contain any other
  50 elements.  Font selection tries to find a best matching font for
  51 those face attributes first that appear first in the list.  For
  52 example, if `:slant' appears before `:height', font selection first
  53 tries to find a font with a suitable slant, even if this results in
  54 a font height that isn't optimal."
  55   :tag "Font selection order"
  56   :type '(list symbol symbol symbol symbol)
  57   :group 'font-selection
  58   :set #'(lambda (symbol value)
  59            (set-default symbol value)
  60            (internal-set-font-selection-order value)))
  61
  62
  63 ;; This is defined originally in xfaces.c.
  64 (defcustom face-font-family-alternatives
  65   '(("courier" "fixed")
  66     ("helv" "helvetica" "arial" "fixed"))
  67   "*Alist of alternative font family names.
  68 Each element has the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  69 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  70 ALTERNATIVE2 etc."
  71   :tag "Alternative font families to try"
  72   :type '(repeat (repeat string))
  73   :group 'font-selection
  74   :set #'(lambda (symbol value)
  75            (set-default symbol value)
  76            (internal-set-alternative-font-family-alist value)))
  77
  78
  79 ;; This is defined originally in xfaces.c.
  80 (defcustom face-font-registry-alternatives
  81   (if (eq system-type 'windows-nt)
  82       '(("iso8859-1" "ms-oemlatin")
  83         ("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try"
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame, NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned.
 187
 188 This function is defined for compatibility with Emacs 20.2.  It
 189 should not be used anymore."
 190   (facep name))
 191 (make-obsolete 'internal-find-face 'facep "21.1")
 192
 193
 194 (defun internal-get-face (name &optional frame)
 195   "Retrieve the face named NAME; error if there is none.
 196 If the optional argument FRAME is given, this gets the face NAME for
 197 that frame; otherwise, it uses the selected frame.
 198 If FRAME is the symbol t, then the global, non-frame face is returned.
 199 If NAME is already a face, it is simply returned."
 200   (or (facep name)
 201       (check-face name)))
 202 (make-obsolete 'internal-get-face "see `facep' and `check-face'." "21.1")
 203
 204 \f
 205 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 206 ;;; Predicates, type checks.
 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 208
 209 (defun facep (face)
 210   "Return non-nil if FACE is a face name."
 211   (internal-lisp-face-p face))
 212
 213
 214 (defun check-face (face)
 215   "Signal an error if FACE doesn't name a face.
 216 Value is FACE."
 217   (unless (facep face)
 218     (error "Not a face: %s" face))
 219   face)
 220
 221
 222 ;; The ID returned is not to be confused with the internally used IDs
 223 ;; of realized faces.  The ID assigned to Lisp faces is used to
 224 ;; support faces in display table entries.
 225
 226 (defun face-id (face &optional frame)
 227   "Return the internal ID of face with name FACE.
 228 If optional argument FRAME is nil or omitted, use the selected frame."
 229   (check-face face)
 230   (get face 'face))
 231
 232
 233 (defun face-equal (face1 face2 &optional frame)
 234   "Non-nil if faces FACE1 and FACE2 are equal.
 235 Faces are considered equal if all their attributes are equal.
 236 If the optional argument FRAME is given, report on face FACE in that frame.
 237 If FRAME is t, report on the defaults for face FACE (for new frames).
 238 If FRAME is omitted or nil, use the selected frame."
 239   (internal-lisp-face-equal-p face1 face2 frame))
 240
 241
 242 (defun face-differs-from-default-p (face &optional frame)
 243   "Non-nil if FACE displays differently from the default face.
 244 If the optional argument FRAME is given, report on face FACE in that frame.
 245 If FRAME is t, report on the defaults for face FACE (for new frames).
 246 If FRAME is omitted or nil, use the selected frame.
 247 A face is considered to be ``the same'' as the default face if it is
 248 actually specified in the same way (equal attributes) or if it is
 249 fully-unspecified, and thus inherits the attributes of any face it
 250 is displayed on top of."
 251   (cond ((eq frame t) (setq frame nil))
 252         ((null frame) (setq frame (selected-frame))))
 253   (let* ((v1 (internal-lisp-face-p face frame))
 254          (n (if v1 (length v1) 0))
 255          (v2 (internal-lisp-face-p 'default frame))
 256          (i 1))
 257     (unless v1
 258       (error "Not a face: %S" face))
 259     (while (and (< i n)
 260                 (or (eq 'unspecified (aref v1 i))
 261                     (equal (aref v1 i) (aref v2 i))))
 262       (setq i (1+ i)))
 263     (< i n)))
 264
 265
 266 (defun face-nontrivial-p (face &optional frame)
 267   "True if face FACE has some non-nil attribute.
 268 If the optional argument FRAME is given, report on face FACE in that frame.
 269 If FRAME is t, report on the defaults for face FACE (for new frames).
 270 If FRAME is omitted or nil, use the selected frame."
 271   (not (internal-lisp-face-empty-p face frame)))
 272
 273
 274 \f
 275 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 276 ;;; Setting face attributes from X resources.
 277 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 278
 279 (defcustom face-x-resources
 280   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 281     (:width (".attributeWidth" . "Face.AttributeWidth"))
 282     (:height (".attributeHeight" . "Face.AttributeHeight"))
 283     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 284     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 285     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 286     (:background (".attributeBackground" . "Face.AttributeBackground"))
 287     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 288     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 289     (:box (".attributeBox" . "Face.AttributeBox"))
 290     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 291     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 292     (:stipple
 293      (".attributeStipple" . "Face.AttributeStipple")
 294      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 295     (:bold (".attributeBold" . "Face.AttributeBold"))
 296     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 297     (:font (".attributeFont" . "Face.AttributeFont"))
 298     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 299   "*List of X resources and classes for face attributes.
 300 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 301 the name of a face attribute, and each ENTRY is a cons of the form
 302 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 303 X resource class for the attribute."
 304   :type '(repeat (cons symbol (repeat (cons string string))))
 305   :group 'faces)
 306
 307
 308 (defun set-face-attribute-from-resource (face attribute resource class frame)
 309   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 310 Value is the attribute value specified by the resource, or nil
 311 if not present.  This function displays a message if the resource
 312 specifies an invalid attribute."
 313   (let* ((face-name (face-name face))
 314          (value (internal-face-x-get-resource (concat face-name resource)
 315                                               class frame)))
 316     (when value
 317       (condition-case ()
 318           (internal-set-lisp-face-attribute-from-resource
 319            face attribute (downcase value) frame)
 320         (error
 321          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 322                   face-name frame attribute value))))
 323     value))
 324
 325
 326 (defun set-face-attributes-from-resources (face frame)
 327   "Set attributes of FACE from X resources for FRAME."
 328   (when (memq (framep frame) '(x w32 mac))
 329     (dolist (definition face-x-resources)
 330       (let ((attribute (car definition)))
 331         (dolist (entry (cdr definition))
 332           (set-face-attribute-from-resource face attribute (car entry)
 333                                             (cdr entry) frame))))))
 334
 335
 336 (defun make-face-x-resource-internal (face &optional frame)
 337   "Fill frame-local FACE on FRAME from X resources.
 338 FRAME nil or not specified means do it for all frames."
 339   (if (null frame)
 340       (dolist (frame (frame-list))
 341         (set-face-attributes-from-resources face frame))
 342     (set-face-attributes-from-resources face frame)))
 343
 344
 345 \f
 346 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 347 ;;; Retrieving face attributes.
 348 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 349
 350 (defun face-name (face)
 351   "Return the name of face FACE."
 352   (symbol-name (check-face face)))
 353
 354
 355 (defun face-attribute (face attribute &optional frame inherit)
 356   "Return the value of FACE's ATTRIBUTE on FRAME.
 357 If the optional argument FRAME is given, report on face FACE in that frame.
 358 If FRAME is t, report on the defaults for face FACE (for new frames).
 359 If FRAME is omitted or nil, use the selected frame.
 360
 361 If INHERIT is nil, only attributes directly defined by FACE are considered,
 362   so the return value may be `unspecified', or a relative value.
 363 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 364   faces specified by its `:inherit' attribute; however the return value
 365   may still be `unspecified' or relative.
 366 If INHERIT is a face or a list of faces, then the result is further merged
 367   with that face (or faces), until it becomes specified and absolute.
 368
 369 To ensure that the return value is always specified and absolute, use a
 370 value of `default' for INHERIT; this will resolve any unspecified or
 371 relative values by merging with the `default' face (which is always
 372 completely specified)."
 373   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 374     (when (and inherit (face-attribute-relative-p attribute value))
 375       ;; VALUE is relative, so merge with inherited faces
 376       (let ((inh-from (face-attribute face :inherit frame)))
 377         (unless (or (null inh-from) (eq inh-from 'unspecified))
 378           (setq value
 379                 (face-attribute-merged-with attribute value inh-from frame)))))
 380     (when (and inherit
 381                (not (eq inherit t))
 382                (face-attribute-relative-p attribute value))
 383       ;; We should merge with INHERIT as well
 384       (setq value (face-attribute-merged-with attribute value inherit frame)))
 385     value))
 386
 387 (defun face-attribute-merged-with (attribute value faces &optional frame)
 388   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 389 FACES may be either a single face or a list of faces.
 390 \[This is an internal function]"
 391   (cond ((not (face-attribute-relative-p attribute value))
 392          value)
 393         ((null faces)
 394          value)
 395         ((consp faces)
 396          (face-attribute-merged-with
 397           attribute
 398           (face-attribute-merged-with attribute value (car faces) frame)
 399           (cdr faces)
 400           frame))
 401         (t
 402          (merge-face-attribute attribute
 403                                value
 404                                (face-attribute faces attribute frame t)))))
 405
 406
 407 (defmacro face-attribute-specified-or (value &rest body)
 408   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 409   (let ((temp (make-symbol "value")))
 410     `(let ((,temp ,value))
 411        (if (not (eq ,temp 'unspecified))
 412            ,temp
 413          ,@body))))
 414
 415 (defun face-foreground (face &optional frame inherit)
 416   "Return the foreground color name of FACE, or nil if unspecified.
 417 If the optional argument FRAME is given, report on face FACE in that frame.
 418 If FRAME is t, report on the defaults for face FACE (for new frames).
 419 If FRAME is omitted or nil, use the selected frame.
 420
 421 If INHERIT is nil, only a foreground color directly defined by FACE is
 422   considered, so the return value may be nil.
 423 If INHERIT is t, and FACE doesn't define a foreground color, then any
 424   foreground color that FACE inherits through its `:inherit' attribute
 425   is considered as well; however the return value may still be nil.
 426 If INHERIT is a face or a list of faces, then it is used to try to
 427   resolve an unspecified foreground color.
 428
 429 To ensure that a valid color is always returned, use a value of
 430 `default' for INHERIT; this will resolve any unspecified values by
 431 merging with the `default' face (which is always completely specified)."
 432   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 433                                nil))
 434
 435 (defun face-background (face &optional frame inherit)
 436   "Return the background color name of FACE, or nil if unspecified.
 437 If the optional argument FRAME is given, report on face FACE in that frame.
 438 If FRAME is t, report on the defaults for face FACE (for new frames).
 439 If FRAME is omitted or nil, use the selected frame.
 440
 441 If INHERIT is nil, only a background color directly defined by FACE is
 442   considered, so the return value may be nil.
 443 If INHERIT is t, and FACE doesn't define a background color, then any
 444   background color that FACE inherits through its `:inherit' attribute
 445   is considered as well; however the return value may still be nil.
 446 If INHERIT is a face or a list of faces, then it is used to try to
 447   resolve an unspecified background color.
 448
 449 To ensure that a valid color is always returned, use a value of
 450 `default' for INHERIT; this will resolve any unspecified values by
 451 merging with the `default' face (which is always completely specified)."
 452   (face-attribute-specified-or (face-attribute face :background frame inherit)
 453                                nil))
 454
 455 (defun face-stipple (face &optional frame inherit)
 456  "Return the stipple pixmap name of FACE, or nil if unspecified.
 457 If the optional argument FRAME is given, report on face FACE in that frame.
 458 If FRAME is t, report on the defaults for face FACE (for new frames).
 459 If FRAME is omitted or nil, use the selected frame.
 460
 461 If INHERIT is nil, only a stipple directly defined by FACE is
 462   considered, so the return value may be nil.
 463 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 464   that FACE inherits through its `:inherit' attribute is considered as
 465   well; however the return value may still be nil.
 466 If INHERIT is a face or a list of faces, then it is used to try to
 467   resolve an unspecified stipple.
 468
 469 To ensure that a valid stipple or nil is always returned, use a value of
 470 `default' for INHERIT; this will resolve any unspecified values by merging
 471 with the `default' face (which is always completely specified)."
 472   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 473                                nil))
 474
 475
 476 (defalias 'face-background-pixmap 'face-stipple)
 477
 478
 479 (defun face-underline-p (face &optional frame)
 480  "Return non-nil if FACE is underlined.
 481 If the optional argument FRAME is given, report on face FACE in that frame.
 482 If FRAME is t, report on the defaults for face FACE (for new frames).
 483 If FRAME is omitted or nil, use the selected frame."
 484  (eq (face-attribute face :underline frame) t))
 485
 486
 487 (defun face-inverse-video-p (face &optional frame)
 488  "Return non-nil if FACE is in inverse video on FRAME.
 489 If the optional argument FRAME is given, report on face FACE in that frame.
 490 If FRAME is t, report on the defaults for face FACE (for new frames).
 491 If FRAME is omitted or nil, use the selected frame."
 492  (eq (face-attribute face :inverse-video frame) t))
 493
 494
 495 (defun face-bold-p (face &optional frame)
 496   "Return non-nil if the font of FACE is bold on FRAME.
 497 If the optional argument FRAME is given, report on face FACE in that frame.
 498 If FRAME is t, report on the defaults for face FACE (for new frames).
 499 If FRAME is omitted or nil, use the selected frame.
 500 Use `face-attribute' for finer control."
 501   (let ((bold (face-attribute face :weight frame)))
 502     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 503
 504
 505 (defun face-italic-p (face &optional frame)
 506   "Return non-nil if the font of FACE is italic on FRAME.
 507 If the optional argument FRAME is given, report on face FACE in that frame.
 508 If FRAME is t, report on the defaults for face FACE (for new frames).
 509 If FRAME is omitted or nil, use the selected frame.
 510 Use `face-attribute' for finer control."
 511   (let ((italic (face-attribute face :slant frame)))
 512     (memq italic '(italic oblique))))
 513
 514
 515 \f
 516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 517 ;;; Face documentation.
 518 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 519
 520 (defun face-documentation (face)
 521   "Get the documentation string for FACE."
 522   (get face 'face-documentation))
 523
 524
 525 (defun set-face-documentation (face string)
 526   "Set the documentation string for FACE to STRING."
 527   ;; Perhaps the text should go in DOC.
 528   (put face 'face-documentation (purecopy string)))
 529
 530
 531 (defalias 'face-doc-string 'face-documentation)
 532 (defalias 'set-face-doc-string 'set-face-documentation)
 533
 534
 535 \f
 536 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 537 ;; Setting face attributes.
 538 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 539
 540
 541 (defun set-face-attribute (face frame &rest args)
 542   "Set attributes of FACE on FRAME from ARGS.
 543
 544 FRAME nil means change attributes on all frames.  FRAME t means change
 545 the default for new frames (this is done automatically each time an
 546 attribute is changed on all frames).
 547
 548 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 549 face attribute name.  All attributes can be set to `unspecified';
 550 this fact is not further mentioned below.
 551
 552 The following attributes are recognized:
 553
 554 `:family'
 555
 556 VALUE must be a string specifying the font family, e.g. ``courier'',
 557 or a fontset alias name.  If a font family is specified, wild-cards `*'
 558 and `?' are allowed.
 559
 560 `:width'
 561
 562 VALUE specifies the relative proportionate width of the font to use.
 563 It must be one of the symbols `ultra-condensed', `extra-condensed',
 564 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 565 `extra-expanded', or `ultra-expanded'.
 566
 567 `:height'
 568
 569 VALUE must be either an integer specifying the height of the font to use
 570 in 1/10 pt, a floating point number specifying the amount by which to
 571 scale any underlying face, or a function, which is called with the old
 572 height (from the underlying face), and should return the new height.
 573
 574 `:weight'
 575
 576 VALUE specifies the weight of the font to use.  It must be one of the
 577 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 578 `semi-light', `light', `extra-light', `ultra-light'.
 579
 580 `:slant'
 581
 582 VALUE specifies the slant of the font to use.  It must be one of the
 583 symbols `italic', `oblique', `normal', `reverse-italic', or
 584 `reverse-oblique'.
 585
 586 `:foreground', `:background'
 587
 588 VALUE must be a color name, a string.
 589
 590 `:underline'
 591
 592 VALUE specifies whether characters in FACE should be underlined.  If
 593 VALUE is t, underline with foreground color of the face.  If VALUE is
 594 a string, underline with that color.  If VALUE is nil, explicitly
 595 don't underline.
 596
 597 `:overline'
 598
 599 VALUE specifies whether characters in FACE should be overlined.  If
 600 VALUE is t, overline with foreground color of the face.  If VALUE is a
 601 string, overline with that color.  If VALUE is nil, explicitly don't
 602 overline.
 603
 604 `:strike-through'
 605
 606 VALUE specifies whether characters in FACE should be drawn with a line
 607 striking through them.  If VALUE is t, use the foreground color of the
 608 face.  If VALUE is a string, strike-through with that color.  If VALUE
 609 is nil, explicitly don't strike through.
 610
 611 `:box'
 612
 613 VALUE specifies whether characters in FACE should have a box drawn
 614 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 615 VALUE is t, draw a box with lines of width 1 in the foreground color
 616 of the face.  If VALUE is a string, the string must be a color name,
 617 and the box is drawn in that color with a line width of 1.  Otherwise,
 618 VALUE must be a property list of the form `(:line-width WIDTH
 619 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 620 the property list, a default value will be used for the value, as
 621 specified below.  WIDTH specifies the width of the lines to draw; it
 622 defaults to 1.  If WIDTH is negative, the absolute value is the width
 623 of the lines, and draw top/bottom lines inside the characters area,
 624 not around it.  COLOR is the name of the color to draw in, default is
 625 the foreground color of the face for simple boxes, and the background
 626 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 627 should be draw.  If STYLE is `released-button', draw a box looking
 628 like a released 3D button.  If STYLE is `pressed-button' draw a box
 629 that appears like a pressed button.  If STYLE is nil, the default if
 630 the property list doesn't contain a style specification, draw a 2D
 631 box.
 632
 633 `:inverse-video'
 634
 635 VALUE specifies whether characters in FACE should be displayed in
 636 inverse video.  VALUE must be one of t or nil.
 637
 638 `:stipple'
 639
 640 If VALUE is a string, it must be the name of a file of pixmap data.
 641 The directories listed in the `x-bitmap-file-path' variable are
 642 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 643 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 644 is a string containing the raw bits of the bitmap.  VALUE nil means
 645 explicitly don't use a stipple pattern.
 646
 647 For convenience, attributes `:family', `:width', `:height', `:weight',
 648 and `:slant' may also be set in one step from an X font name:
 649
 650 `:font'
 651
 652 Set font-related face attributes from VALUE.  VALUE must be a valid
 653 XLFD font name.  If it is a font name pattern, the first matching font
 654 will be used.
 655
 656 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 657 be used to specify that a bold or italic font should be used.  VALUE
 658 must be t or nil in that case.  A value of `unspecified' is not allowed.
 659
 660 `:inherit'
 661
 662 VALUE is the name of a face from which to inherit attributes, or a list
 663 of face names.  Attributes from inherited faces are merged into the face
 664 like an underlying face would be, with higher priority than underlying faces."
 665   (let ((where (if (null frame) 0 frame)))
 666     (setq args (purecopy args))
 667     (while args
 668       (internal-set-lisp-face-attribute face (car args)
 669                                         (purecopy (cadr args))
 670                                         where)
 671       (setq args (cdr (cdr args))))))
 672
 673
 674 (defun make-face-bold (face &optional frame noerror)
 675   "Make the font of FACE be bold, if possible.
 676 FRAME nil or not specified means change face on all frames.
 677 Argument NOERROR is ignored and retained for compatibility.
 678 Use `set-face-attribute' for finer control of the font weight."
 679   (interactive (list (read-face-name "Make which face bold")))
 680   (set-face-attribute face frame :weight 'bold))
 681
 682
 683 (defun make-face-unbold (face &optional frame noerror)
 684   "Make the font of FACE be non-bold, if possible.
 685 FRAME nil or not specified means change face on all frames.
 686 Argument NOERROR is ignored and retained for compatibility."
 687   (interactive (list (read-face-name "Make which face non-bold")))
 688   (set-face-attribute face frame :weight 'normal))
 689
 690
 691 (defun make-face-italic (face &optional frame noerror)
 692   "Make the font of FACE be italic, if possible.
 693 FRAME nil or not specified means change face on all frames.
 694 Argument NOERROR is ignored and retained for compatibility.
 695 Use `set-face-attribute' for finer control of the font slant."
 696   (interactive (list (read-face-name "Make which face italic")))
 697   (set-face-attribute face frame :slant 'italic))
 698
 699
 700 (defun make-face-unitalic (face &optional frame noerror)
 701   "Make the font of FACE be non-italic, if possible.
 702 FRAME nil or not specified means change face on all frames.
 703 Argument NOERROR is ignored and retained for compatibility."
 704   (interactive (list (read-face-name "Make which face non-italic")))
 705   (set-face-attribute face frame :slant 'normal))
 706
 707
 708 (defun make-face-bold-italic (face &optional frame noerror)
 709   "Make the font of FACE be bold and italic, if possible.
 710 FRAME nil or not specified means change face on all frames.
 711 Argument NOERROR is ignored and retained for compatibility.
 712 Use `set-face-attribute' for finer control of font weight and slant."
 713   (interactive (list (read-face-name "Make which face bold-italic")))
 714   (set-face-attribute face frame :weight 'bold :slant 'italic))
 715
 716
 717 (defun set-face-font (face font &optional frame)
 718   "Change font-related attributes of FACE to those of FONT (a string).
 719 FRAME nil or not specified means change face on all frames.
 720 This sets the attributes `:family', `:width', `:height', `:weight',
 721 and `:slant'.  When called interactively, prompt for the face and font."
 722   (interactive (read-face-and-attribute :font))
 723   (set-face-attribute face frame :font font))
 724
 725
 726 ;; Implementation note: Emulating gray background colors with a
 727 ;; stipple pattern is now part of the face realization process, and is
 728 ;; done in C depending on the frame on which the face is realized.
 729
 730 (defun set-face-background (face color &optional frame)
 731   "Change the background color of face FACE to COLOR (a string).
 732 FRAME nil or not specified means change face on all frames.
 733 When called interactively, prompt for the face and color."
 734   (interactive (read-face-and-attribute :background))
 735   (set-face-attribute face frame :background (or color 'unspecified)))
 736
 737
 738 (defun set-face-foreground (face color &optional frame)
 739   "Change the foreground color of face FACE to COLOR (a string).
 740 FRAME nil or not specified means change face on all frames.
 741 When called interactively, prompt for the face and color."
 742   (interactive (read-face-and-attribute :foreground))
 743   (set-face-attribute face frame :foreground (or color 'unspecified)))
 744
 745
 746 (defun set-face-stipple (face stipple &optional frame)
 747   "Change the stipple pixmap of face FACE to STIPPLE.
 748 FRAME nil or not specified means change face on all frames.
 749 STIPPLE should be a string, the name of a file of pixmap data.
 750 The directories listed in the `x-bitmap-file-path' variable are searched.
 751
 752 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 753 where WIDTH and HEIGHT are the size in pixels,
 754 and DATA is a string, containing the raw bits of the bitmap."
 755   (interactive (read-face-and-attribute :stipple))
 756   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 757
 758
 759 (defun set-face-underline (face underline &optional frame)
 760   "Specify whether face FACE is underlined.
 761 UNDERLINE nil means FACE explicitly doesn't underline.
 762 UNDERLINE non-nil means FACE explicitly does underlining
 763 with the same of the foreground color.
 764 If UNDERLINE is a string, underline with the color named UNDERLINE.
 765 FRAME nil or not specified means change face on all frames.
 766 Use `set-face-attribute' to ``unspecify'' underlining."
 767   (interactive
 768    (let ((list (read-face-and-attribute :underline)))
 769      (list (car list) (eq (car (cdr list)) t))))
 770   (set-face-attribute face frame :underline underline))
 771
 772
 773 (defun set-face-underline-p (face underline-p &optional frame)
 774   "Specify whether face FACE is underlined.
 775 UNDERLINE-P nil means FACE explicitly doesn't underline.
 776 UNDERLINE-P non-nil means FACE explicitly does underlining.
 777 FRAME nil or not specified means change face on all frames.
 778 Use `set-face-attribute' to ``unspecify'' underlining."
 779   (interactive
 780    (let ((list (read-face-and-attribute :underline)))
 781      (list (car list) (eq (car (cdr list)) t))))
 782   (set-face-attribute face frame :underline underline-p))
 783
 784
 785 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 786   "Specify whether face FACE is in inverse video.
 787 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 788 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 789 FRAME nil or not specified means change face on all frames.
 790 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 791   (interactive
 792    (let ((list (read-face-and-attribute :inverse-video)))
 793      (list (car list) (eq (car (cdr list)) t))))
 794   (set-face-attribute face frame :inverse-video inverse-video-p))
 795
 796
 797 (defun set-face-bold-p (face bold-p &optional frame)
 798   "Specify whether face FACE is bold.
 799 BOLD-P non-nil means FACE should explicitly display bold.
 800 BOLD-P nil means FACE should explicitly display non-bold.
 801 FRAME nil or not specified means change face on all frames.
 802 Use `set-face-attribute' or `modify-face' for finer control."
 803   (if (null bold-p)
 804       (make-face-unbold face frame)
 805     (make-face-bold face frame)))
 806
 807
 808 (defun set-face-italic-p (face italic-p &optional frame)
 809   "Specify whether face FACE is italic.
 810 ITALIC-P non-nil means FACE should explicitly display italic.
 811 ITALIC-P nil means FACE should explicitly display non-italic.
 812 FRAME nil or not specified means change face on all frames.
 813 Use `set-face-attribute' or `modify-face' for finer control."
 814   (if (null italic-p)
 815       (make-face-unitalic face frame)
 816     (make-face-italic face frame)))
 817
 818
 819 (defalias 'set-face-background-pixmap 'set-face-stipple)
 820
 821
 822 (defun invert-face (face &optional frame)
 823   "Swap the foreground and background colors of FACE.
 824 If FRAME is omitted or nil, it means change face on all frames.
 825 If FACE specifies neither foreground nor background color,
 826 set its foreground and background to the background and foreground
 827 of the default face.  Value is FACE."
 828   (interactive (list (read-face-name "Invert face")))
 829   (let ((fg (face-attribute face :foreground frame))
 830         (bg (face-attribute face :background frame)))
 831     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 832         (set-face-attribute face frame :foreground bg :background fg)
 833       (set-face-attribute face frame
 834                           :foreground
 835                           (face-attribute 'default :background frame)
 836                           :background
 837                           (face-attribute 'default :foreground frame))))
 838   face)
 839
 840 \f
 841 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 842 ;;; Interactively modifying faces.
 843 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 844
 845 (defun read-face-name (prompt &optional string-describing-default multiple)
 846   "Read a face, defaulting to the face or faces on the char after point.
 847 If it has a `read-face-name' property, that overrides the `face' property.
 848 PROMPT describes what you will do with the face (don't end in a space).
 849 STRING-DESCRIBING-DEFAULT describes what default you will use
 850 if this function returns nil.
 851 If MULTIPLE is non-nil, return a list of faces (possibly only one).
 852 Otherwise, return a single face."
 853   (let ((faceprop (or (get-char-property (point) 'read-face-name)
 854                       (get-char-property (point) 'face)))
 855         faces)
 856     ;; Make a list of the named faces that the `face' property uses.
 857     (if (listp faceprop)
 858         (dolist (f faceprop)
 859           (if (symbolp f)
 860               (push f faces)))
 861       (if (symbolp faceprop)
 862           (setq faces (list faceprop))))
 863     ;; If there are none, try to get a face name from the buffer.
 864     (if (and (null faces)
 865              (memq (intern-soft (thing-at-point 'symbol)) (face-list)))
 866         (setq faces (list (intern-soft (thing-at-point 'symbol)))))
 867
 868     ;; If we only want one, and the default is more than one,
 869     ;; discard the unwanted ones now.
 870     (unless multiple
 871       (if faces
 872           (setq faces (list (car faces)))))
 873     (let* ((input
 874             ;; Read the input.
 875             (completing-read
 876              (if (or faces string-describing-default)
 877                  (format "%s (default %s): " prompt
 878                          (if faces (mapconcat 'symbol-name faces ", ")
 879                            string-describing-default))
 880                (format "%s: " prompt))
 881              obarray 'custom-facep t))
 882            ;; Canonicalize the output.
 883            (output
 884             (if (equal input "")
 885                 faces
 886               (if (stringp input)
 887                   (list (intern input))
 888                 input))))
 889       ;; Return either a list of faces or just one face.
 890       (if multiple
 891           output
 892         (car output)))))
 893
 894
 895 (defun face-valid-attribute-values (attribute &optional frame)
 896   "Return valid values for face attribute ATTRIBUTE.
 897 The optional argument FRAME is used to determine available fonts
 898 and colors.  If it is nil or not specified, the selected frame is
 899 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 900 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 901 an integer value."
 902   (let ((valid
 903          (case attribute
 904            (:family
 905             (if window-system
 906                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 907                         (x-font-family-list))
 908               ;; Only one font on TTYs.
 909               (list (cons "default" "default"))))
 910            ((:width :weight :slant :inverse-video)
 911             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 912                     (internal-lisp-face-attribute-values attribute)))
 913            ((:underline :overline :strike-through :box)
 914             (if window-system
 915                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 916                                (internal-lisp-face-attribute-values attribute))
 917                        (mapcar #'(lambda (c) (cons c c))
 918                                (x-defined-colors frame)))
 919               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 920                       (internal-lisp-face-attribute-values attribute))))
 921            ((:foreground :background)
 922             (mapcar #'(lambda (c) (cons c c))
 923                     (defined-colors frame)))
 924            ((:height)
 925             'integerp)
 926            (:stipple
 927             (and (memq window-system '(x w32 mac))
 928                  (mapcar #'list
 929                          (apply #'nconc
 930                                 (mapcar (lambda (dir)
 931                                           (and (file-readable-p dir)
 932                                                (file-directory-p dir)
 933                                                (directory-files dir)))
 934                                         x-bitmap-file-path)))))
 935            (:inherit
 936             (cons '("none" . nil)
 937                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 938                           (face-list))))
 939            (t
 940             (error "Internal error")))))
 941     (if (and (listp valid) (not (memq attribute '(:inherit))))
 942         (nconc (list (cons "unspecified" 'unspecified)) valid)
 943       valid)))
 944
 945
 946 (defvar face-attribute-name-alist
 947   '((:family . "font family")
 948     (:width . "character set width")
 949     (:height . "height in 1/10 pt")
 950     (:weight . "weight")
 951     (:slant . "slant")
 952     (:underline . "underline")
 953     (:overline . "overline")
 954     (:strike-through . "strike-through")
 955     (:box . "box")
 956     (:inverse-video . "inverse-video display")
 957     (:foreground . "foreground color")
 958     (:background . "background color")
 959     (:stipple . "background stipple")
 960     (:inherit . "inheritance"))
 961   "An alist of descriptive names for face attributes.
 962 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 963 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 964 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 965
 966
 967 (defun face-descriptive-attribute-name (attribute)
 968   "Return a descriptive name for ATTRIBUTE."
 969   (cdr (assq attribute face-attribute-name-alist)))
 970
 971
 972 (defun face-read-string (face default name &optional completion-alist)
 973   "Interactively read a face attribute string value.
 974 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 975 default string to return if no new value is entered.  NAME is a
 976 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 977 alist of valid values, if non-nil.
 978
 979 Entering nothing accepts the default string DEFAULT.
 980 Value is the new attribute value."
 981   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 982   ;; each word in a string separately).
 983   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 984   (let* ((completion-ignore-case t)
 985          (value (completing-read
 986                  (if default
 987                      (format "%s for face `%s' (default %s): "
 988                              name face default)
 989                    (format "%s for face `%s': " name face))
 990                  completion-alist)))
 991     (if (equal value "") default value)))
 992
 993
 994 (defun face-read-integer (face default name)
 995   "Interactively read an integer face attribute value.
 996 FACE is the face whose attribute is read.  DEFAULT is the default
 997 value to return if no new value is entered.  NAME is a descriptive
 998 name of the attribute for prompting.  Value is the new attribute value."
 999   (let ((new-value
1000          (face-read-string face
1001                            (format "%s" default)
1002                            name
1003                            (list (cons "unspecified" 'unspecified)))))
1004     (cond ((equal new-value "unspecified")
1005            'unspecified)
1006           ((member new-value '("unspecified-fg" "unspecified-bg"))
1007            new-value)
1008           (t
1009            (string-to-int new-value)))))
1010
1011
1012 (defun read-face-attribute (face attribute &optional frame)
1013   "Interactively read a new value for FACE's ATTRIBUTE.
1014 Optional argument FRAME nil or unspecified means read an attribute value
1015 of a global face.  Value is the new attribute value."
1016   (let* ((old-value (face-attribute face attribute frame))
1017          (attribute-name (face-descriptive-attribute-name attribute))
1018          (valid (face-valid-attribute-values attribute frame))
1019          new-value)
1020     ;; Represent complex attribute values as strings by printing them
1021     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
1022     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
1023     ;; SHADOW)'.
1024     (when (and (or (eq attribute :stipple)
1025                    (eq attribute :box))
1026                (or (consp old-value)
1027                    (vectorp old-value)))
1028       (setq old-value (prin1-to-string old-value)))
1029     (cond ((listp valid)
1030            (let ((default
1031                    (or (car (rassoc old-value valid))
1032                        (format "%s" old-value))))
1033              (setq new-value
1034                    (face-read-string face default attribute-name valid))
1035              (if (equal new-value default)
1036                  ;; Nothing changed, so don't bother with all the stuff
1037                  ;; below.  In particular, this avoids a non-tty color
1038                  ;; from being canonicalized for a tty when the user
1039                  ;; just uses the default.
1040                  (setq new-value old-value)
1041                ;; Terminal frames can support colors that don't appear
1042                ;; explicitly in VALID, using color approximation code
1043                ;; in tty-colors.el.
1044                (when (and (memq attribute '(:foreground :background))
1045                           (not (memq window-system '(x w32 mac)))
1046                           (not (member new-value
1047                                        '("unspecified"
1048                                          "unspecified-fg" "unspecified-bg"))))
1049                  (setq new-value (car (tty-color-desc new-value frame))))
1050                (when (assoc new-value valid)
1051                  (setq new-value (cdr (assoc new-value valid)))))))
1052           ((eq valid 'integerp)
1053            (setq new-value (face-read-integer face old-value attribute-name)))
1054           (t (error "Internal error")))
1055     ;; Convert stipple and box value text we read back to a list or
1056     ;; vector if it looks like one.  This makes the assumption that a
1057     ;; pixmap file name won't start with an open-paren.
1058     (when (and (or (eq attribute :stipple)
1059                    (eq attribute :box))
1060                (stringp new-value)
1061                (string-match "^[[(]" new-value))
1062       (setq new-value (read new-value)))
1063     new-value))
1064
1065
1066 (defun read-face-font (face &optional frame)
1067   "Read the name of a font for FACE on FRAME.
1068 If optional argument FRAME Is nil or omitted, use the selected frame."
1069   (let ((completion-ignore-case t))
1070     (completing-read (format "Set font attributes of face `%s' from font: " face)
1071                      (mapcar 'list (x-list-fonts "*" nil frame)))))
1072
1073
1074 (defun read-all-face-attributes (face &optional frame)
1075   "Interactively read all attributes for FACE.
1076 If optional argument FRAME Is nil or omitted, use the selected frame.
1077 Value is a property list of attribute names and new values."
1078   (let (result)
1079     (dolist (attribute face-attribute-name-alist result)
1080       (setq result (cons (car attribute)
1081                          (cons (read-face-attribute face (car attribute) frame)
1082                                result))))))
1083
1084 (defun modify-face (&optional face foreground background stipple
1085                               bold-p italic-p underline-p inverse-p frame)
1086   "Modify attributes of faces interactively.
1087 If optional argument FRAME is nil or omitted, modify the face used
1088 for newly created frame, i.e. the global face.
1089 For non-interactive use, `set-face-attribute' is preferred.
1090 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
1091 and the face and its settings are obtained by querying the user."
1092   (interactive)
1093   (if face
1094       (set-face-attribute face frame
1095                           :foreground (or foreground 'unspecified)
1096                           :background (or background 'unspecified)
1097                           :stipple stipple
1098                           :bold bold-p
1099                           :italic italic-p
1100                           :underline underline-p
1101                           :inverse-video inverse-p)
1102     (setq face (read-face-name "Modify face"))
1103     (apply #'set-face-attribute face frame
1104            (read-all-face-attributes face frame))))
1105
1106 (defun read-face-and-attribute (attribute &optional frame)
1107   "Read face name and face attribute value.
1108 ATTRIBUTE is the attribute whose new value is read.
1109 FRAME nil or unspecified means read attribute value of global face.
1110 Value is a list (FACE NEW-VALUE) where FACE is the face read
1111 \(a symbol), and NEW-VALUE is value read."
1112   (cond ((eq attribute :font)
1113          (let* ((prompt "Set font-related attributes of face")
1114                 (face (read-face-name prompt))
1115                 (font (read-face-font face frame)))
1116            (list face font)))
1117         (t
1118          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1119                 (prompt (format "Set %s of face" attribute-name))
1120                 (face (read-face-name prompt))
1121                 (new-value (read-face-attribute face attribute frame)))
1122            (list face new-value)))))
1123
1124
1125 \f
1126 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1127 ;;; Listing faces.
1128 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1129
1130 (defvar list-faces-sample-text
1131   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1132   "*Text string to display as the sample text for `list-faces-display'.")
1133
1134
1135 ;; The name list-faces would be more consistent, but let's avoid a
1136 ;; conflict with Lucid, which uses that name differently.
1137
1138 (defvar help-xref-stack)
1139 (defun list-faces-display ()
1140   "List all faces, using the same sample text in each.
1141 The sample text is a string that comes from the variable
1142 `list-faces-sample-text'."
1143   (interactive)
1144   (let ((faces (sort (face-list) #'string-lessp))
1145         (face nil)
1146         (frame (selected-frame))
1147         disp-frame window face-name)
1148     (with-output-to-temp-buffer "*Faces*"
1149       (save-excursion
1150         (set-buffer standard-output)
1151         (setq truncate-lines t)
1152         (insert
1153          (substitute-command-keys
1154           (concat
1155            "Use "
1156            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1157            "\\[help-follow] on a face name to customize it\n"
1158            "or on its sample text for a description of the face.\n\n")))
1159         (setq help-xref-stack nil)
1160         (while faces
1161           (setq face (car faces))
1162           (setq faces (cdr faces))
1163           (setq face-name (symbol-name face))
1164           (insert (format "%25s " face-name))
1165           ;; Hyperlink to a customization buffer for the face.  Using
1166           ;; the help xref mechanism may not be the best way.
1167           (save-excursion
1168             (save-match-data
1169               (search-backward face-name)
1170               (help-xref-button 0 'help-customize-face face)))
1171           (let ((beg (point))
1172                 (line-beg (line-beginning-position)))
1173             (insert list-faces-sample-text)
1174             ;; Hyperlink to a help buffer for the face.
1175             (save-excursion
1176               (save-match-data
1177                 (search-backward list-faces-sample-text)
1178                 (help-xref-button 0 'help-face face)))
1179             (insert "\n")
1180             (put-text-property beg (1- (point)) 'face face)
1181             ;; Make all face commands default to the proper face
1182             ;; anywhere in the line.
1183             (put-text-property line-beg (1- (point)) 'read-face-name face)
1184             ;; If the sample text has multiple lines, line up all of them.
1185             (goto-char beg)
1186             (forward-line 1)
1187             (while (not (eobp))
1188               (insert "                          ")
1189               (forward-line 1))))
1190         (goto-char (point-min)))
1191       (print-help-return-message))
1192     ;; If the *Faces* buffer appears in a different frame,
1193     ;; copy all the face definitions from FRAME,
1194     ;; so that the display will reflect the frame that was selected.
1195     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1196     (setq disp-frame (if window (window-frame window)
1197                        (car (frame-list))))
1198     (or (eq frame disp-frame)
1199         (let ((faces (face-list)))
1200           (while faces
1201             (copy-face (car faces) (car faces) frame disp-frame)
1202             (setq faces (cdr faces)))))))
1203
1204 (defun describe-face (face &optional frame)
1205   "Display the properties of face FACE on FRAME.
1206 Interactively, FACE defaults to the faces of the character after point
1207 and FRAME defaults to the selected frame.
1208
1209 If the optional argument FRAME is given, report on face FACE in that frame.
1210 If FRAME is t, report on the defaults for face FACE (for new frames).
1211 If FRAME is omitted or nil, use the selected frame."
1212   (interactive (list (read-face-name "Describe face" "= `default' face" t)))
1213   (let* ((attrs '((:family . "Family")
1214                   (:width . "Width")
1215                   (:height . "Height")
1216                   (:weight . "Weight")
1217                   (:slant . "Slant")
1218                   (:foreground . "Foreground")
1219                   (:background . "Background")
1220                   (:underline . "Underline")
1221                   (:overline . "Overline")
1222                   (:strike-through . "Strike-through")
1223                   (:box . "Box")
1224                   (:inverse-video . "Inverse")
1225                   (:stipple . "Stipple")
1226                   (:font . "Font or fontset")
1227                   (:inherit . "Inherit")))
1228         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1229                                         attrs))))
1230     (help-setup-xref (list #'describe-face face) (interactive-p))
1231     (unless face
1232       (setq face 'default))
1233     (if (not (listp face))
1234         (setq face (list face)))
1235     (with-output-to-temp-buffer (help-buffer)
1236       (save-excursion
1237         (set-buffer standard-output)
1238         (dolist (f face)
1239           (insert "Face: " (symbol-name f))
1240           (if (not (facep f))
1241               (insert "   undefined face.\n")
1242             (let ((customize-label "customize this face"))
1243               (princ (concat " (" customize-label ")\n"))
1244               (insert "Documentation: "
1245                       (or (face-documentation f)
1246                           "Not documented as a face.")
1247                       "\n\n")
1248               (with-current-buffer standard-output
1249                 (save-excursion
1250                   (re-search-backward
1251                    (concat "\\(" customize-label "\\)") nil t)
1252                   (help-xref-button 1 'help-customize-face f)))
1253               (dolist (a attrs)
1254                 (let ((attr (face-attribute f (car a) frame)))
1255                   (insert (make-string (- max-width (length (cdr a))) ?\ )
1256                           (cdr a) ": " (format "%s" attr) "\n")))))
1257           (terpri)))
1258       (print-help-return-message))))
1259
1260 \f
1261 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1262 ;;; Face specifications (defface).
1263 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1264
1265 ;; Parameter FRAME Is kept for call compatibility to with previous
1266 ;; face implementation.
1267
1268 (defun face-attr-construct (face &optional frame)
1269   "Return a defface-style attribute list for FACE on FRAME.
1270 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1271 face attributes of FACE where ATTRIBUTE is the attribute name and
1272 VALUE is the specified value of that attribute."
1273   (let (result)
1274     (dolist (entry face-attribute-name-alist result)
1275       (let* ((attribute (car entry))
1276              (value (face-attribute face attribute)))
1277         (unless (eq value 'unspecified)
1278           (setq result (nconc (list attribute value) result)))))))
1279
1280
1281 (defun face-spec-set-match-display (display frame)
1282   "Non-nil if DISPLAY matches FRAME.
1283 DISPLAY is part of a spec such as can be used in `defface'.
1284 If FRAME is nil, the current FRAME is used."
1285   (let* ((conjuncts display)
1286          conjunct req options
1287          ;; t means we have succeeded against all the conjuncts in
1288          ;; DISPLAY that have been tested so far.
1289          (match t))
1290     (if (eq conjuncts t)
1291         (setq conjuncts nil))
1292     (while (and conjuncts match)
1293       (setq conjunct (car conjuncts)
1294             conjuncts (cdr conjuncts)
1295             req (car conjunct)
1296             options (cdr conjunct)
1297             match (cond ((eq req 'type)
1298                          (or (memq window-system options)
1299                              ;; FIXME: This should be revisited to use
1300                              ;; display-graphic-p, provided that the
1301                              ;; color selection depends on the number
1302                              ;; of supported colors, and all defface's
1303                              ;; are changed to look at number of colors
1304                              ;; instead of (type graphic) etc.
1305                              (and (null window-system)
1306                                   (memq 'tty options))
1307                              (and (memq 'motif options)
1308                                   (featurep 'motif))
1309                              (and (memq 'lucid options)
1310                                   (featurep 'x-toolkit)
1311                                   (not (featurep 'motif)))
1312                              (and (memq 'x-toolkit options)
1313                                   (featurep 'x-toolkit))))
1314                         ((eq req 'class)
1315                          (memq (frame-parameter frame 'display-type) options))
1316                         ((eq req 'background)
1317                          (memq (frame-parameter frame 'background-mode)
1318                                options))
1319                         ((eq req 'supports)
1320                          (display-supports-face-attributes-p options frame))
1321                         (t (error "Unknown req `%S' with options `%S'"
1322                                   req options)))))
1323     match))
1324
1325
1326 (defun face-spec-choose (spec &optional frame)
1327   "Choose the proper attributes for FRAME, out of SPEC.
1328 If SPEC is nil, return nil."
1329   (unless frame
1330     (setq frame (selected-frame)))
1331   (let ((tail spec)
1332         result all)
1333     (while tail
1334       (let* ((entry (pop tail))
1335              (display (car entry))
1336              (attrs (cdr entry)))
1337         (when (face-spec-set-match-display display frame)
1338           (setq result (if (null (cdr attrs)) ;; was (listp (car attrs))
1339                            ;; Old-style entry, the attribute list is the
1340                            ;; first element.
1341                            (car attrs)
1342                          attrs))
1343           (if (eq display t)
1344               (setq all result result nil)
1345             (setq tail nil)))))
1346     (if all (append result all) result)))
1347
1348
1349 (defun face-spec-reset-face (face &optional frame)
1350   "Reset all attributes of FACE on FRAME to unspecified."
1351   (let ((attrs face-attribute-name-alist))
1352     (while attrs
1353       (let ((attr-and-name (car attrs)))
1354         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1355       (setq attrs (cdr attrs)))))
1356
1357
1358 (defun face-spec-set (face spec &optional frame)
1359   "Set FACE's attributes according to the first matching entry in SPEC.
1360 FRAME is the frame whose frame-local face is set.  FRAME nil means
1361 do it on all frames.  See `defface' for information about SPEC.
1362 If SPEC is nil, do nothing."
1363   (let ((attrs (face-spec-choose spec frame)))
1364     (when attrs
1365       (face-spec-reset-face face frame))
1366     (while attrs
1367       (let ((attribute (car attrs))
1368             (value (car (cdr attrs))))
1369         ;; Support some old-style attribute names and values.
1370         (case attribute
1371           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1372           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1373           ((:foreground :background)
1374            ;; Compatibility with 20.x.  Some bogus face specs seem to
1375            ;; exist containing things like `:foreground nil'.
1376            (if (null value) (setq value 'unspecified)))
1377           (t (unless (assq attribute face-x-resources)
1378                (setq attribute nil))))
1379         (when attribute
1380           (set-face-attribute face frame attribute value)))
1381       (setq attrs (cdr (cdr attrs))))))
1382
1383
1384 (defun face-attr-match-p (face attrs &optional frame)
1385   "Return t if attributes of FACE match values in plist ATTRS.
1386 Optional parameter FRAME is the frame whose definition of FACE
1387 is used.  If nil or omitted, use the selected frame."
1388   (unless frame
1389     (setq frame (selected-frame)))
1390   (let ((list face-attribute-name-alist)
1391         (match t))
1392     (while (and match (not (null list)))
1393       (let* ((attr (car (car list)))
1394              (specified-value
1395               (if (plist-member attrs attr)
1396                   (plist-get attrs attr)
1397                 'unspecified))
1398              (value-now (face-attribute face attr frame)))
1399         (setq match (equal specified-value value-now))
1400         (setq list (cdr list))))
1401     match))
1402
1403 (defun face-spec-match-p (face spec &optional frame)
1404   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1405   (face-attr-match-p face (face-spec-choose spec frame) frame))
1406
1407 (defsubst face-default-spec (face)
1408   "Return the default face-spec for FACE, ignoring any user customization.
1409 If there is no default for FACE, return nil."
1410   (get face 'face-defface-spec))
1411
1412 (defsubst face-user-default-spec (face)
1413   "Return the user's customized face-spec for FACE, or the default if none.
1414 If there is neither a user setting nor a default for FACE, return nil."
1415   (or (get face 'saved-face)
1416       (face-default-spec face)))
1417
1418 \f
1419 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1420 ;;; Frame-type independent color support.
1421 ;;; We keep the old x-* names as aliases for back-compatibility.
1422 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1423
1424 (defun defined-colors (&optional frame)
1425   "Return a list of colors supported for a particular frame.
1426 The argument FRAME specifies which frame to try.
1427 The value may be different for frames on different display types.
1428 If FRAME doesn't support colors, the value is nil."
1429   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1430       (xw-defined-colors frame)
1431     (mapcar 'car (tty-color-alist frame))))
1432 (defalias 'x-defined-colors 'defined-colors)
1433
1434 (defun color-defined-p (color &optional frame)
1435   "Return non-nil if color COLOR is supported on frame FRAME.
1436 If FRAME is omitted or nil, use the selected frame.
1437 If COLOR is the symbol `unspecified' or one of the strings
1438 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1439   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1440       nil
1441     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1442         (xw-color-defined-p color frame)
1443       (numberp (tty-color-translate color frame)))))
1444 (defalias 'x-color-defined-p 'color-defined-p)
1445
1446 (defun color-values (color &optional frame)
1447   "Return a description of the color named COLOR on frame FRAME.
1448 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1449 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1450 If FRAME is omitted or nil, use the selected frame.
1451 If FRAME cannot display COLOR, the value is nil.
1452 If COLOR is the symbol `unspecified' or one of the strings
1453 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1454   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1455       nil
1456     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1457         (xw-color-values color frame)
1458       (tty-color-values color frame))))
1459 (defalias 'x-color-values 'color-values)
1460
1461 (defun display-color-p (&optional display)
1462   "Return t if DISPLAY supports color.
1463 The optional argument DISPLAY specifies which display to ask about.
1464 DISPLAY should be either a frame or a display name (a string).
1465 If omitted or nil, that stands for the selected frame's display."
1466   (if (memq (framep-on-display display) '(x w32 mac))
1467       (xw-display-color-p display)
1468     (tty-display-color-p display)))
1469 (defalias 'x-display-color-p 'display-color-p)
1470
1471 (defun display-grayscale-p (&optional display)
1472   "Return non-nil if frames on DISPLAY can display shades of gray."
1473   (let ((frame-type (framep-on-display display)))
1474     (cond
1475      ((memq frame-type '(x w32 mac))
1476       (x-display-grayscale-p display))
1477      (t
1478       (> (tty-color-gray-shades display) 2)))))
1479
1480 (defun display-supports-face-attributes-p (attributes &optional display)
1481   "Return non-nil if all the face attributes in ATTRIBUTES are supported.
1482 The optional argument DISPLAY can be a display name, a frame, or
1483 nil (meaning the selected frame's display)
1484
1485 The definition of `supported' is somewhat heuristic, but basically means
1486 that a face containing all the attributes in ATTRIBUTES, when merged
1487 with the default face for display, can be represented in a way that's
1488
1489  (1) different in appearance than the default face, and
1490  (2) `close in spirit' to what the attributes specify, if not exact.
1491
1492 Point (2) implies that a `:weight black' attribute will be satisified by
1493 any display that can display bold, and a `:foreground \"yellow\"' as long
1494 as it can display a yellowish color, but `:slant italic' will _not_ be
1495 satisified by the tty display code's automatic substitution of a `dim'
1496 face for italic."
1497   (let ((frame
1498          (if (framep display)
1499              display
1500            (car (frames-on-display-list display)))))
1501     ;; For now, we assume that non-tty displays can support everything.
1502     ;; Later, we should add the ability to query about specific fonts,
1503     ;; colors, etc.
1504     (or (memq (framep frame) '(x w32 mac))
1505         (tty-supports-face-attributes-p attributes frame))))
1506
1507 \f
1508 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1509 ;;; Background mode.
1510 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1511
1512 (defcustom frame-background-mode nil
1513   "*The brightness of the background.
1514 Set this to the symbol `dark' if your background color is dark, `light' if
1515 your background is light, or nil (default) if you want Emacs to
1516 examine the brightness for you.  Don't set this variable with `setq';
1517 this won't have the expected effect."
1518   :group 'faces
1519   :set #'(lambda (var value)
1520            (set-default var value)
1521            (mapc 'frame-set-background-mode (frame-list)))
1522   :initialize 'custom-initialize-changed
1523   :type '(choice (choice-item dark)
1524                  (choice-item light)
1525                  (choice-item :tag "default" nil)))
1526
1527
1528 (defun frame-set-background-mode (frame)
1529   "Set up display-dependent faces on FRAME.
1530 Display-dependent faces are those which have different definitions
1531 according to the `background-mode' and `display-type' frame parameters."
1532   (let* ((bg-resource
1533           (and window-system
1534                (x-get-resource "backgroundMode" "BackgroundMode")))
1535          (bg-color (frame-parameter frame 'background-color))
1536          (bg-mode
1537           (cond (frame-background-mode)
1538                 (bg-resource
1539                  (intern (downcase bg-resource)))
1540                 ((and (null window-system) (null bg-color))
1541                  ;; No way to determine this automatically (?).
1542                  'dark)
1543                 ;; Unspecified frame background color can only happen
1544                 ;; on tty's.
1545                 ((member bg-color '(unspecified "unspecified-bg"))
1546                  'dark)
1547                 ((equal bg-color "unspecified-fg") ; inverted colors
1548                  'light)
1549                 ((>= (apply '+ (x-color-values bg-color frame))
1550                     ;; Just looking at the screen, colors whose
1551                     ;; values add up to .6 of the white total
1552                     ;; still look dark to me.
1553                     (* (apply '+ (x-color-values "white" frame)) .6))
1554                  'light)
1555                 (t 'dark)))
1556          (display-type
1557           (cond ((null window-system)
1558                  (if (tty-display-color-p frame) 'color 'mono))
1559                 ((x-display-color-p frame)
1560                  'color)
1561                 ((x-display-grayscale-p frame)
1562                  'grayscale)
1563                 (t 'mono)))
1564          (old-bg-mode
1565           (frame-parameter frame 'background-mode))
1566          (old-display-type
1567           (frame-parameter frame 'display-type)))
1568
1569     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1570       (let ((locally-modified-faces nil))
1571         ;; Before modifying the frame parameters, we collect a list of
1572         ;; faces that don't match what their face-spec says they should
1573         ;; look like; we then avoid changing these faces below.  A
1574         ;; negative list is used on the assumption that most faces will
1575         ;; be unmodified, so we can avoid consing in the common case.
1576         (dolist (face (face-list))
1577           (when (not (face-spec-match-p face
1578                                         (face-user-default-spec face)
1579                                         (selected-frame)))
1580             (push face locally-modified-faces)))
1581         ;; Now change to the new frame parameters
1582         (modify-frame-parameters frame
1583                                  (list (cons 'background-mode bg-mode)
1584                                        (cons 'display-type display-type)))
1585         ;; For all named faces, choose face specs matching the new frame
1586         ;; parameters, unless they have been locally modified.
1587         (dolist (face (face-list))
1588           (unless (memq face locally-modified-faces)
1589             (face-spec-set face (face-user-default-spec face) frame)))))))
1590
1591 \f
1592 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1593 ;;; Frame creation.
1594 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1595
1596 (defun x-handle-named-frame-geometry (parameters)
1597   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1598 Value is the new parameter list."
1599   (let* ((name (or (cdr (assq 'name parameters))
1600                    (cdr (assq 'name default-frame-alist))))
1601          (x-resource-name name)
1602          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1603     (when res-geometry
1604       (let ((parsed (x-parse-geometry res-geometry)))
1605         ;; If the resource specifies a position, call the position
1606         ;; and size "user-specified".
1607         (when (or (assq 'top parsed)
1608                   (assq 'left parsed))
1609           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1610         ;; Put the geometry parameters at the end.  Copy
1611         ;; default-frame-alist so that they go after it.
1612         (setq parameters (append parameters default-frame-alist parsed))))
1613     parameters))
1614
1615
1616 (defun x-handle-reverse-video (frame parameters)
1617   "Handle the reverse-video frame parameter and X resource.
1618 `x-create-frame' does not handle this one."
1619   (when (cdr (or (assq 'reverse parameters)
1620                  (assq 'reverse default-frame-alist)
1621                  (let ((resource (x-get-resource "reverseVideo"
1622                                                  "ReverseVideo")))
1623                    (if resource
1624                        (cons nil (member (downcase resource)
1625                                          '("on" "true")))))))
1626       (let* ((params (frame-parameters frame))
1627              (bg (cdr (assq 'foreground-color params)))
1628              (fg (cdr (assq 'background-color params))))
1629         (modify-frame-parameters frame
1630                                  (list (cons 'foreground-color fg)
1631                                        (cons 'background-color bg)))
1632         (if (equal bg (cdr (assq 'border-color params)))
1633             (modify-frame-parameters frame
1634                                      (list (cons 'border-color fg))))
1635         (if (equal bg (cdr (assq 'mouse-color params)))
1636             (modify-frame-parameters frame
1637                                      (list (cons 'mouse-color fg))))
1638         (if (equal bg (cdr (assq 'cursor-color params)))
1639             (modify-frame-parameters frame
1640                                      (list (cons 'cursor-color fg)))))))
1641
1642
1643 (defun x-create-frame-with-faces (&optional parameters)
1644   "Create a frame from optional frame parameters PARAMETERS.
1645 Parameters not specified by PARAMETERS are taken from
1646 `default-frame-alist'.  If PARAMETERS specify a frame name,
1647 handle X geometry resources for that name.  If either PARAMETERS
1648 or `default-frame-alist' contains a `reverse' parameter, or
1649 the X resource ``reverseVideo'' is present, handle that.
1650 Value is the new frame created."
1651   (setq parameters (x-handle-named-frame-geometry parameters))
1652   (let ((visibility-spec (assq 'visibility parameters))
1653         (frame-list (frame-list))
1654         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1655         success)
1656     (unwind-protect
1657         (progn
1658           (x-handle-reverse-video frame parameters)
1659           (frame-set-background-mode frame)
1660           ;; No need to call `face-set-after-frame-default'
1661           ;; since x-create-frame does that.
1662           (if (or (null frame-list) (null visibility-spec))
1663               (make-frame-visible frame)
1664             (modify-frame-parameters frame (list visibility-spec)))
1665           (setq success t))
1666       (unless success
1667         (delete-frame frame)))
1668     frame))
1669
1670
1671 (defun face-set-after-frame-default (frame)
1672   "Set frame-local faces of FRAME from face specs and resources.
1673 Initialize colors of certain faces from frame parameters."
1674   (if (face-attribute 'default :font t)
1675       (set-face-attribute 'default frame :font
1676                           (face-attribute 'default :font t))
1677     (set-face-attribute 'default frame :family
1678                         (face-attribute 'default :family t))
1679     (set-face-attribute 'default frame :height
1680                         (face-attribute 'default :height t))
1681     (set-face-attribute 'default frame :slant
1682                         (face-attribute 'default :slant t))
1683     (set-face-attribute 'default frame :weight
1684                         (face-attribute 'default :weight t))
1685     (set-face-attribute 'default frame :width
1686                         (face-attribute 'default :width t)))
1687   (dolist (face (face-list))
1688     ;; Don't let frame creation fail because of an invalid face spec.
1689     (condition-case ()
1690         (when (not (equal face 'default))
1691           (face-spec-set face (face-user-default-spec face) frame)
1692           (internal-merge-in-global-face face frame)
1693           (when (and (memq window-system '(x w32 mac))
1694                      (or (not (boundp 'inhibit-default-face-x-resources))
1695                          (not (eq face 'default))))
1696             (make-face-x-resource-internal face frame)))
1697       (error nil)))
1698   ;; Initialize attributes from frame parameters.
1699   (let ((params '((foreground-color default :foreground)
1700                   (background-color default :background)
1701                   (border-color border :background)
1702                   (cursor-color cursor :background)
1703                   (scroll-bar-foreground scroll-bar :foreground)
1704                   (scroll-bar-background scroll-bar :background)
1705                   (mouse-color mouse :background))))
1706     (dolist (param params)
1707       (let ((frame-param (frame-parameter frame (nth 0 param)))
1708             (face (nth 1 param))
1709             (attr (nth 2 param)))
1710         (when (and frame-param
1711                    ;; Don't override face attributes explicitly
1712                    ;; specified for new frames.
1713                    (eq (face-attribute face attr t) 'unspecified))
1714           (set-face-attribute face frame attr frame-param))))))
1715
1716
1717 (defun tty-handle-reverse-video (frame parameters)
1718   "Handle the reverse-video frame parameter for terminal frames."
1719   (when (cdr (or (assq 'reverse parameters)
1720                  (assq 'reverse default-frame-alist)))
1721     (let* ((params (frame-parameters frame))
1722            (bg (cdr (assq 'foreground-color params)))
1723            (fg (cdr (assq 'background-color params))))
1724       (modify-frame-parameters frame
1725                                (list (cons 'foreground-color fg)
1726                                      (cons 'background-color bg)))
1727       (if (equal bg (cdr (assq 'mouse-color params)))
1728           (modify-frame-parameters frame
1729                                    (list (cons 'mouse-color fg))))
1730       (if (equal bg (cdr (assq 'cursor-color params)))
1731           (modify-frame-parameters frame
1732                                    (list (cons 'cursor-color fg)))))))
1733
1734
1735 (defun tty-create-frame-with-faces (&optional parameters)
1736   "Create a frame from optional frame parameters PARAMETERS.
1737 Parameters not specified by PARAMETERS are taken from
1738 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1739 contains a `reverse' parameter, handle that.  Value is the new frame
1740 created."
1741   (let ((frame (make-terminal-frame parameters))
1742         success)
1743     (unwind-protect
1744         (progn
1745           (tty-handle-reverse-video frame (frame-parameters frame))
1746           (frame-set-background-mode frame)
1747           (face-set-after-frame-default frame)
1748           (setq success t))
1749       (unless success
1750         (delete-frame frame)))
1751     frame))
1752
1753
1754 ;; Called from C function init_display to initialize faces of the
1755 ;; dumped terminal frame on startup.
1756
1757 (defun tty-set-up-initial-frame-faces ()
1758   (let ((frame (selected-frame)))
1759     (frame-set-background-mode frame)
1760     (face-set-after-frame-default frame)))
1761
1762
1763
1764 \f
1765 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1766 ;;; Compatiblity with 20.2
1767 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1768
1769 ;; Update a frame's faces when we change its default font.
1770
1771 (defalias 'frame-update-faces 'ignore)
1772 (make-obsolete 'frame-update-faces "no longer necessary." "21.1")
1773
1774 ;; Update the colors of FACE, after FRAME's own colors have been
1775 ;; changed.
1776
1777 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1778 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1779
1780 \f
1781 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1782 ;;; Standard faces.
1783 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1784
1785 (defgroup basic-faces nil
1786   "The standard faces of Emacs."
1787   :group 'faces)
1788
1789
1790 (defface default
1791   '((t nil))
1792   "Basic default face."
1793   :group 'basic-faces)
1794
1795
1796 (defface mode-line
1797   '((((type x w32 mac) (class color))
1798      :box (:line-width -1 :style released-button)
1799      :background "grey75" :foreground "black")
1800     (t
1801      :inverse-video t))
1802   "Basic mode line face for selected window."
1803   :version "21.1"
1804   :group 'modeline
1805   :group 'basic-faces)
1806
1807 (defface mode-line-inactive
1808   '((t
1809      :inherit mode-line)
1810     (((type x w32 mac) (background light) (class color))
1811      :weight light
1812      :box (:line-width -1 :color "grey75" :style nil)
1813      :foreground "grey20" :background "grey90")
1814     (((type x w32 mac) (background dark) (class color))
1815      :weight light
1816      :box (:line-width -1 :color "grey40" :style nil)
1817      :foreground "grey80" :background "grey30"))
1818   "Basic mode line face for non-selected windows."
1819   :version "21.4"
1820   :group 'modeline
1821   :group 'basic-faces)
1822
1823 ;; Make `modeline' an alias for `mode-line', for compatibility.
1824 (put 'modeline 'face-alias 'mode-line)
1825 (put 'modeline-inactive 'face-alias 'mode-line-inactive)
1826
1827 (defface header-line
1828   '((((type tty))
1829      ;; This used to be `:inverse-video t', but that doesn't look very
1830      ;; good when combined with inverse-video mode-lines and multiple
1831      ;; windows.  Underlining looks better, and is more consistent with
1832      ;; the window-system face variants, which deemphasize the
1833      ;; header-line in relation to the mode-line face.  If a terminal
1834      ;; can't underline, then the header-line will end up without any
1835      ;; highlighting; this may be too confusing in general, although it
1836      ;; happens to look good with the only current use of header-lines,
1837      ;; the info browser. XXX
1838      :underline t)
1839     (((class color grayscale) (background light))
1840      :background "grey90" :foreground "grey20"
1841      :box nil
1842      :inherit mode-line)
1843     (((class color grayscale) (background dark))
1844      :background "grey20" :foreground "grey90"
1845      :box nil
1846      :inherit mode-line)
1847     (((class mono) (background light))
1848      :background "white" :foreground "black"
1849      :inverse-video nil
1850      :box nil
1851      :underline t
1852      :inherit mode-line)
1853     (((class mono) (background dark))
1854      :background "black" :foreground "white"
1855      :inverse-video nil
1856      :box nil
1857      :underline t
1858      :inherit mode-line))
1859   "Basic header-line face."
1860   :version "21.1"
1861   :group 'basic-faces)
1862
1863
1864 (defface tool-bar
1865   '((((type x w32 mac) (class color))
1866      :box (:line-width 1 :style released-button)
1867      :background "grey75" :foreground "black")
1868     (((type x) (class mono))
1869      :box (:line-width 1 :style released-button)
1870      :background "grey" :foreground "black")
1871     (t
1872      ()))
1873   "Basic tool-bar face."
1874   :version "21.1"
1875   :group 'basic-faces)
1876
1877
1878 (defface minibuffer-prompt '((((background dark)) :foreground "cyan")
1879                              (((type pc)) :foreground "magenta")
1880                              (t :foreground "dark blue"))
1881   "Face for minibuffer prompts."
1882   :version "21.4"
1883   :group 'basic-faces)
1884
1885 (setq minibuffer-prompt-properties
1886       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
1887
1888 (defface region
1889   '((((type tty) (class color))
1890      :background "blue" :foreground "white")
1891     (((type tty) (class mono))
1892      :inverse-video t)
1893     (((class color) (background dark))
1894      :background "blue3")
1895     (((class color) (background light))
1896      :background "lightgoldenrod2")
1897     (t :background "gray"))
1898   "Basic face for highlighting the region."
1899   :version "21.1"
1900   :group 'basic-faces)
1901
1902
1903 (defface fringe
1904   '((((class color) (background light))
1905      :background "grey95")
1906     (((class color) (background dark))
1907      :background "grey10")
1908     (t
1909      :background "gray"))
1910   "Basic face for the fringes to the left and right of windows under X."
1911   :version "21.1"
1912   :group 'frames
1913   :group 'basic-faces)
1914
1915
1916 (defface scroll-bar '()
1917   "Basic face for the scroll bar colors under X."
1918   :version "21.1"
1919   :group 'frames
1920   :group 'basic-faces)
1921
1922
1923 (defface menu
1924   '((((type tty))
1925      :inverse-video t)
1926     (((type x-toolkit))
1927      )
1928     (t
1929      :inverse-video t))
1930   "Basic face for the font and colors of the menu bar and popup menus."
1931   :version "21.1"
1932   :group 'menu
1933   :group 'basic-faces)
1934
1935
1936 (defface border '()
1937   "Basic face for the frame border under X."
1938   :version "21.1"
1939   :group 'frames
1940   :group 'basic-faces)
1941
1942
1943 (defface cursor '()
1944   "Basic face for the cursor color under X."
1945   :version "21.1"
1946   :group 'cursor
1947   :group 'basic-faces)
1948
1949
1950 (defface mouse '()
1951   "Basic face for the mouse color under X."
1952   :version "21.1"
1953   :group 'mouse
1954   :group 'basic-faces)
1955
1956
1957 (defface bold '((t :weight bold))
1958   "Basic bold face."
1959   :group 'basic-faces)
1960
1961
1962 (defface italic
1963   '((((supports :slant italic))
1964      :slant italic)
1965     (((supports :underline t))
1966      :underline t)
1967     (t
1968      ;; default to italic, even it doesn't appear to be supported,
1969      ;; because in some cases the display engine will do it's own
1970      ;; workaround (to `dim' on ttys)
1971      :slant italic))
1972   "Basic italic font."
1973   :group 'basic-faces)
1974
1975
1976 (defface bold-italic '((t :weight bold :slant italic))
1977   "Basic bold-italic face."
1978   :group 'basic-faces)
1979
1980
1981 (defface underline '((t :underline t))
1982   "Basic underlined face."
1983   :group 'basic-faces)
1984
1985
1986 (defface highlight
1987   '((((type tty) (class color))
1988      :background "green" :foreground "black")
1989     (((class color) (background light))
1990      :background "darkseagreen2")
1991     (((class color) (background dark))
1992      :background "darkolivegreen")
1993     (t :inverse-video t))
1994   "Basic face for highlighting."
1995   :group 'basic-faces)
1996
1997
1998 (defface secondary-selection
1999   '((((type tty) (class color))
2000      :background "cyan" :foreground "black")
2001     (((class color) (background light))
2002      :background "yellow")
2003     (((class color) (background dark))
2004      :background "SkyBlue4")
2005     (t :inverse-video t))
2006   "Basic face for displaying the secondary selection."
2007   :group 'basic-faces)
2008
2009
2010 (defface fixed-pitch '((t :family "courier"))
2011   "The basic fixed-pitch face."
2012   :group 'basic-faces)
2013
2014
2015 (defface variable-pitch '((t :family "helv"))
2016   "The basic variable-pitch face."
2017   :group 'basic-faces)
2018
2019
2020 (defface trailing-whitespace
2021   '((((class color) (background light))
2022      :background "red")
2023     (((class color) (background dark))
2024      :background "red")
2025     (t :inverse-video t))
2026   "Basic face for highlighting trailing whitespace."
2027   :version "21.1"
2028   :group 'font-lock                     ; like `show-trailing-whitespace'
2029   :group 'basic-faces)
2030
2031
2032 \f
2033 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2034 ;;; Manipulating font names.
2035 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
2036
2037 ;; This is here for compatibilty with Emacs 20.2.  For example,
2038 ;; international/fontset.el uses x-resolve-font-name.  The following
2039 ;; functions are not used in the face implementation itself.
2040
2041 (defvar x-font-regexp nil)
2042 (defvar x-font-regexp-head nil)
2043 (defvar x-font-regexp-weight nil)
2044 (defvar x-font-regexp-slant nil)
2045
2046 (defconst x-font-regexp-weight-subnum 1)
2047 (defconst x-font-regexp-slant-subnum 2)
2048 (defconst x-font-regexp-swidth-subnum 3)
2049 (defconst x-font-regexp-adstyle-subnum 4)
2050
2051 ;;; Regexps matching font names in "Host Portable Character Representation."
2052 ;;;
2053 (let ((-                "[-?]")
2054       (foundry          "[^-]+")
2055       (family           "[^-]+")
2056       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
2057 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
2058       (weight\?         "\\([^-]*\\)")                                  ; 1
2059       (slant            "\\([ior]\\)")                                  ; 2
2060 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
2061       (slant\?          "\\([^-]?\\)")                                  ; 2
2062 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
2063       (swidth           "\\([^-]*\\)")                                  ; 3
2064 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
2065       (adstyle          "\\([^-]*\\)")                                  ; 4
2066       (pixelsize        "[0-9]+")
2067       (pointsize        "[0-9][0-9]+")
2068       (resx             "[0-9][0-9]+")
2069       (resy             "[0-9][0-9]+")
2070       (spacing          "[cmp?*]")
2071       (avgwidth         "[0-9]+")
2072       (registry         "[^-]+")
2073       (encoding         "[^-]+")
2074       )
2075   (setq x-font-regexp
2076         (concat "\\`\\*?[-?*]"
2077                 foundry - family - weight\? - slant\? - swidth - adstyle -
2078                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
2079                 registry - encoding "\\*?\\'"
2080                 ))
2081   (setq x-font-regexp-head
2082         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
2083                 "\\([-*?]\\|\\'\\)"))
2084   (setq x-font-regexp-slant (concat - slant -))
2085   (setq x-font-regexp-weight (concat - weight -))
2086   nil)
2087
2088
2089 (defun x-resolve-font-name (pattern &optional face frame)
2090   "Return a font name matching PATTERN.
2091 All wildcards in PATTERN are instantiated.
2092 If PATTERN is nil, return the name of the frame's base font, which never
2093 contains wildcards.
2094 Given optional arguments FACE and FRAME, return a font which is
2095 also the same size as FACE on FRAME, or fail."
2096   (or (symbolp face)
2097       (setq face (face-name face)))
2098   (and (eq frame t)
2099        (setq frame nil))
2100   (if pattern
2101       ;; Note that x-list-fonts has code to handle a face with nil as its font.
2102       (let ((fonts (x-list-fonts pattern face frame 1)))
2103         (or fonts
2104             (if face
2105                 (if (string-match "\\*" pattern)
2106                     (if (null (face-font face))
2107                         (error "No matching fonts are the same height as the frame default font")
2108                       (error "No matching fonts are the same height as face `%s'" face))
2109                   (if (null (face-font face))
2110                       (error "Height of font `%s' doesn't match the frame default font"
2111                              pattern)
2112                     (error "Height of font `%s' doesn't match face `%s'"
2113                            pattern face)))
2114               (error "No fonts match `%s'" pattern)))
2115         (car fonts))
2116     (cdr (assq 'font (frame-parameters (selected-frame))))))
2117
2118
2119 (defun x-frob-font-weight (font which)
2120   (let ((case-fold-search t))
2121     (cond ((string-match x-font-regexp font)
2122            (concat (substring font 0
2123                               (match-beginning x-font-regexp-weight-subnum))
2124                    which
2125                    (substring font (match-end x-font-regexp-weight-subnum)
2126                               (match-beginning x-font-regexp-adstyle-subnum))
2127                    ;; Replace the ADD_STYLE_NAME field with *
2128                    ;; because the info in it may not be the same
2129                    ;; for related fonts.
2130                    "*"
2131                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2132           ((string-match x-font-regexp-head font)
2133            (concat (substring font 0 (match-beginning 1)) which
2134                    (substring font (match-end 1))))
2135           ((string-match x-font-regexp-weight font)
2136            (concat (substring font 0 (match-beginning 1)) which
2137                    (substring font (match-end 1)))))))
2138 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2139
2140 (defun x-frob-font-slant (font which)
2141   (let ((case-fold-search t))
2142     (cond ((string-match x-font-regexp font)
2143            (concat (substring font 0
2144                               (match-beginning x-font-regexp-slant-subnum))
2145                    which
2146                    (substring font (match-end x-font-regexp-slant-subnum)
2147                               (match-beginning x-font-regexp-adstyle-subnum))
2148                    ;; Replace the ADD_STYLE_NAME field with *
2149                    ;; because the info in it may not be the same
2150                    ;; for related fonts.
2151                    "*"
2152                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2153           ((string-match x-font-regexp-head font)
2154            (concat (substring font 0 (match-beginning 2)) which
2155                    (substring font (match-end 2))))
2156           ((string-match x-font-regexp-slant font)
2157            (concat (substring font 0 (match-beginning 1)) which
2158                    (substring font (match-end 1)))))))
2159 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2160
2161 ;; These aliases are here so that we don't get warnings about obsolete
2162 ;; functions from the byte compiler.
2163 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2164 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2165
2166 (defun x-make-font-bold (font)
2167   "Given an X font specification, make a bold version of it.
2168 If that can't be done, return nil."
2169   (internal-frob-font-weight font "bold"))
2170 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2171
2172 (defun x-make-font-demibold (font)
2173   "Given an X font specification, make a demibold version of it.
2174 If that can't be done, return nil."
2175   (internal-frob-font-weight font "demibold"))
2176 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2177
2178 (defun x-make-font-unbold (font)
2179   "Given an X font specification, make a non-bold version of it.
2180 If that can't be done, return nil."
2181   (internal-frob-font-weight font "medium"))
2182 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2183
2184 (defun x-make-font-italic (font)
2185   "Given an X font specification, make an italic version of it.
2186 If that can't be done, return nil."
2187   (internal-frob-font-slant font "i"))
2188 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2189
2190 (defun x-make-font-oblique (font) ; you say tomayto...
2191   "Given an X font specification, make an oblique version of it.
2192 If that can't be done, return nil."
2193   (internal-frob-font-slant font "o"))
2194 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2195
2196 (defun x-make-font-unitalic (font)
2197   "Given an X font specification, make a non-italic version of it.
2198 If that can't be done, return nil."
2199   (internal-frob-font-slant font "r"))
2200 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2201
2202 (defun x-make-font-bold-italic (font)
2203   "Given an X font specification, make a bold and italic version of it.
2204 If that can't be done, return nil."
2205   (and (setq font (internal-frob-font-weight font "bold"))
2206        (internal-frob-font-slant font "i")))
2207 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2208
2209 (provide 'faces)
2210
2211 ;;; faces.el ends here