lisp/frameset.el

   1 ;;; frameset.el --- save and restore frame and window setup -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2013-2017 Free Software Foundation, Inc.
   4
   5 ;; Author: Juanma Barranquero <lekktu@gmail.com>
   6 ;; Keywords: convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <https://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file provides a set of operations to save a frameset (the state
  26 ;; of all or a subset of the existing frames and windows), both
  27 ;; in-session and persistently, and restore it at some point in the
  28 ;; future.
  29 ;;
  30 ;; It should be noted that restoring the frames' windows depends on
  31 ;; the buffers they are displaying, but this package does not provide
  32 ;; any way to save and restore sets of buffers (see desktop.el for
  33 ;; that).  So, it's up to the user of frameset.el to make sure that
  34 ;; any relevant buffer is loaded before trying to restore a frameset.
  35 ;; When a window is restored and a buffer is missing, the window will
  36 ;; be deleted unless it is the last one in the frame, in which case
  37 ;; some previous buffer will be shown instead.
  38
  39 ;;; Code:
  40
  41 (require 'cl-lib)
  42
  43 \f
  44 (cl-defstruct (frameset (:type vector) :named
  45                         (:constructor frameset--make)
  46                         ;; Copier is defined below.
  47                         (:copier nil))
  48
  49   "A frameset encapsulates a serializable view of a set of frames and windows.
  50
  51 It contains the following slots, which can be accessed with
  52 \(frameset-SLOT fs) and set with (setf (frameset-SLOT fs) VALUE):
  53
  54   version      A read-only version number, identifying the format
  55                  of the frameset struct.  Currently its value is 1.
  56   timestamp    A read-only timestamp, the output of `current-time'.
  57   app          A symbol, or a list whose first element is a symbol, which
  58                  identifies the creator of the frameset and related info;
  59                  for example, desktop.el sets this slot to a list
  60                  `(desktop . ,desktop-file-version).
  61   name         A string, the name of the frameset instance.
  62   description  A string, a description for user consumption (to show in
  63                  menus, messages, etc).
  64   properties   A property list, to store both frameset-specific and
  65                  user-defined serializable data.
  66   states       A list of items (FRAME-PARAMETERS . WINDOW-STATE), in no
  67                  particular order.  Each item represents a frame to be
  68                  restored.  FRAME-PARAMETERS is a frame's parameter alist,
  69                  extracted with (frame-parameters FRAME) and filtered
  70                  through `frameset-filter-params'.
  71                  WINDOW-STATE is the output of `window-state-get' applied
  72                  to the root window of the frame.
  73
  74 To avoid collisions, it is recommended that applications wanting to add
  75 private serializable data to `properties' either store all info under a
  76 single, distinctive name, or use property names with a well-chosen prefix.
  77
  78 A frameset is intended to be used through the following simple API:
  79
  80  - `frameset-save', the type's constructor, captures all or a subset of the
  81    live frames, and returns a serializable snapshot of them (a frameset).
  82  - `frameset-restore' takes a frameset, and restores the frames and windows
  83    it describes, as faithfully as possible.
  84  - `frameset-p' is the predicate for the frameset type.
  85  - `frameset-valid-p' checks a frameset's validity.
  86  - `frameset-copy' returns a deep copy of a frameset.
  87  - `frameset-prop' is a `setf'able accessor for the contents of the
  88    `properties' slot.
  89  - The `frameset-SLOT' accessors described above."
  90
  91   (version     1              :read-only t)
  92   (timestamp   (current-time) :read-only t)
  93   (app         nil)
  94   (name        nil)
  95   (description nil)
  96   (properties  nil)
  97   (states      nil))
  98
  99 ;; Add nicer docstrings for built-in predicate and accessors.
 100 (put 'frameset-p 'function-documentation
 101      "Return non-nil if OBJECT is a frameset, nil otherwise.\n\n(fn OBJECT)")
 102 (put 'frameset-version 'function-documentation
 103      "Return the version number of FRAMESET.\n
 104 It is an integer that identifies the format of the frameset struct.
 105 This slot cannot be modified.\n\n(fn FRAMESET)")
 106 (put 'frameset-timestamp 'function-documentation
 107      "Return the creation timestamp of FRAMESET.\n
 108 The value is in the format returned by `current-time'.
 109 This slot cannot be modified.\n\n(fn FRAMESET)")
 110 (put 'frameset-app 'function-documentation
 111      "Return the application identifier for FRAMESET.\n
 112 The value is either a symbol, like `my-app', or a list
 113 \(my-app ADDITIONAL-DATA...).\n\n(fn FRAMESET)")
 114 (put 'frameset-name 'function-documentation
 115      "Return the name of FRAMESET (a string).\n\n(fn FRAMESET)")
 116 (put 'frameset-description 'function-documentation
 117      "Return the description of FRAMESET (a string).\n\n(fn FRAMESET)")
 118 (put 'frameset-properties 'function-documentation
 119      "Return the property list of FRAMESET.\n
 120 This list is useful to store both frameset-specific and user-defined
 121 serializable data.  The simplest way to access and modify it is
 122 through `frameset-prop' (which see).\n\n(fn FRAMESET)")
 123 (put 'frameset-states 'function-documentation
 124      "Return the list of frame states of FRAMESET.\n
 125 A frame state is a pair (FRAME-PARAMETERS . WINDOW-STATE), where
 126 FRAME-PARAMETERS is a frame's parameter alist, extracted with
 127 \(frame-parameters FRAME) and filtered through `frameset-filter-params',
 128 and WINDOW-STATE is the output of `window-state-get' applied to the
 129 root window of the frame.\n
 130 IMPORTANT: Modifying this slot may cause frameset functions to fail,
 131 unless the type constraints defined above are respected.\n\n(fn FRAMESET)")
 132
 133 ;; We autoloaded this for use in register.el, but now that we use registerv
 134 ;; objects, this autoload is not useful any more.
 135 ;; ;;;###autoload (autoload 'frameset-p "frameset"
 136 ;; ;;;###autoload   "Return non-nil if OBJECT is a frameset, nil otherwise." nil)
 137
 138 (defun frameset-copy (frameset)
 139   "Return a deep copy of FRAMESET.
 140 FRAMESET is copied with `copy-tree'."
 141   (copy-tree frameset t))
 142
 143 (defun frameset-valid-p (object)
 144   "Return non-nil if OBJECT is a valid frameset, nil otherwise."
 145   (and (frameset-p object)
 146        (integerp (frameset-version object))
 147        (consp (frameset-timestamp object))
 148        (let ((app (frameset-app object)))
 149          (or (null app)                   ; APP is nil
 150              (symbolp app)                ; or a symbol
 151              (and (consp app)             ; or a list
 152                   (symbolp (car app)))))  ; starting with a symbol
 153        (stringp (or (frameset-name object) ""))
 154        (stringp (or (frameset-description object) ""))
 155        (listp (frameset-properties object))
 156        (let ((states (frameset-states object)))
 157          (and (listp states)
 158               (cl-every #'consp (frameset-states object))))
 159        (frameset-version object)))        ; And VERSION is non-nil.
 160
 161 (defun frameset--prop-setter (frameset property value)
 162   "Setter function for `frameset-prop'.  Internal use only."
 163   (setf (frameset-properties frameset)
 164         (plist-put (frameset-properties frameset) property value))
 165   value)
 166
 167 ;; A setf'able accessor to the frameset's properties
 168 (defun frameset-prop (frameset property)
 169   "Return the value for FRAMESET of PROPERTY.
 170
 171 Properties can be set with
 172
 173   (setf (frameset-prop FRAMESET PROPERTY) NEW-VALUE)"
 174   (declare (gv-setter frameset--prop-setter))
 175   (plist-get (frameset-properties frameset) property))
 176
 177 \f
 178 ;; Filtering
 179
 180 ;; What's the deal with these "filter alists"?
 181 ;;
 182 ;; Let's say that Emacs' frame parameters were never designed as a tool to
 183 ;; precisely record (or restore) a frame's state.  They grew organically,
 184 ;; and their uses and behaviors reflect their history.  In using them to
 185 ;; implement framesets, the unwary implementer, or the prospective package
 186 ;; writer willing to use framesets in their code, might fall victim of some
 187 ;; unexpected... oddities.
 188 ;;
 189 ;; You can find frame parameters that:
 190 ;;
 191 ;; - can be used to get and set some data from the frame's current state
 192 ;;   (`height', `width')
 193 ;; - can be set at creation time, and setting them afterwards has no effect
 194 ;;   (`window-state', `minibuffer')
 195 ;; - can be set at creation time, and setting them afterwards will fail with
 196 ;;   an error, *unless* you set it to the same value, a noop (`border-width')
 197 ;; - act differently when passed at frame creation time, and when set
 198 ;;   afterwards (`height')
 199 ;; - affect the value of other parameters (`name', `visibility')
 200 ;; - can be ignored by window managers (most positional args, like `height',
 201 ;;   `width', `left' and `top', and others, like `auto-raise', `auto-lower')
 202 ;; - can be set externally in X resources or Window registry (again, most
 203 ;;   positional parameters, and also `toolbar-lines', `menu-bar-lines' etc.)
 204 ;, - can contain references to live objects (`buffer-list', `minibuffer') or
 205 ;;   code (`buffer-predicate')
 206 ;; - are set automatically, and cannot be changed (`window-id', `parent-id'),
 207 ;;   but setting them produces no error
 208 ;; - have a noticeable effect in some window managers, and are ignored in
 209 ;;   others (`menu-bar-lines')
 210 ;; - can not be safely set in a tty session and then copied back to a GUI
 211 ;;   session (`font', `background-color', `foreground-color')
 212 ;;
 213 ;; etc etc.
 214 ;;
 215 ;; Which means that, in order to save a parameter alist to disk and read it
 216 ;; back later to reconstruct a frame, some processing must be done.  That's
 217 ;; what `frameset-filter-params' and the `frameset-*-filter-alist' variables
 218 ;; are for.
 219 ;;
 220 ;; First, a clarification.  The word "filter" in these names refers to both
 221 ;; common meanings of filter: to filter out (i.e., to remove), and to pass
 222 ;; through a transformation function (think `filter-buffer-substring').
 223 ;;
 224 ;; `frameset-filter-params' takes a parameter alist PARAMETERS, a filtering
 225 ;; alist FILTER-ALIST, and a flag SAVING to indicate whether we are filtering
 226 ;; parameters with the intent of saving a frame or restoring it.  It then
 227 ;; accumulates an output alist, FILTERED, by checking each parameter in
 228 ;; PARAMETERS against FILTER-ALIST and obeying any rule found there.  The
 229 ;; absence of a rule just means the parameter/value pair (called CURRENT in
 230 ;; filtering functions) is copied to FILTERED as is.  Keyword values :save,
 231 ;; :restore and :never tell the function to copy CURRENT to FILTERED in the
 232 ;; respective situations, that is, when saving, restoring, or never at all.
 233 ;; Values :save and :restore are not used in this package, because usually if
 234 ;; you don't want to save a parameter, you don't want to restore it either.
 235 ;; But they can be useful, for example, if you already have a saved frameset
 236 ;; created with some intent, and want to reuse it for a different objective
 237 ;; where the expected parameter list has different requirements.
 238 ;;
 239 ;; Finally, the value can also be a filtering function, or a filtering
 240 ;; function plus some arguments.  The function is called for each matching
 241 ;; parameter, and receives CURRENT (the parameter/value pair being processed),
 242 ;; FILTERED (the output alist so far), PARAMETERS (the full parameter alist),
 243 ;; SAVING (the save/restore flag), plus any additional ARGS set along the
 244 ;; function in the `frameset-*-filter-alist' entry.  The filtering function
 245 ;; then has the possibility to pass along CURRENT, or reject it altogether,
 246 ;; or pass back a (NEW-PARAM . NEW-VALUE) pair, which does not even need to
 247 ;; refer to the same parameter (so you can filter `width' and return `height'
 248 ;; and vice versa, if you're feeling silly and want to mess with the user's
 249 ;; mind).  As a help in deciding what to do, the filtering function has
 250 ;; access to PARAMETERS, but must not change it in any way.  It also has
 251 ;; access to FILTERED, which can be modified at will.  This allows two or
 252 ;; more filters to coordinate themselves, because in general there's no way
 253 ;; to predict the order in which they will be run.
 254 ;;
 255 ;; So, which parameters are filtered by default, and why? Let's see.
 256 ;;
 257 ;; - `buffer-list', `buried-buffer-list', `buffer-predicate': They contain
 258 ;;   references to live objects, or in the case of `buffer-predicate', it
 259 ;;   could also contain an fbound symbol (a predicate function) that could
 260 ;;   not be defined in a later session.
 261 ;;
 262 ;; - `window-id', `outer-window-id', `parent-id': They are assigned
 263 ;;   automatically and cannot be set, so keeping them is harmless, but they
 264 ;;   add clutter.  `window-system' is similar: it's assigned at frame
 265 ;;   creation, and does not serve any useful purpose later.
 266 ;;
 267 ;; - `left', `top': Only problematic when saving an iconified frame, because
 268 ;;   when the frame is iconified they are set to (- 32000), which doesn't
 269 ;;   really help in restoring the frame.  Better to remove them and let the
 270 ;;   window manager choose a default position for the frame.
 271 ;;
 272 ;; - `background-color', `foreground-color': In tty frames they can be set
 273 ;;   to "unspecified-bg" and "unspecified-fg", which aren't understood on
 274 ;;   GUI sessions.  They have to be filtered out when switching from tty to
 275 ;;   a graphical display.
 276 ;;
 277 ;; - `tty', `tty-type': These are tty-specific.  When switching to a GUI
 278 ;;   display they do no harm, but they clutter the parameter alist.
 279 ;;
 280 ;; - `minibuffer': It can contain a reference to a live window, which cannot
 281 ;;   be serialized.  Because of Emacs' idiosyncratic treatment of this
 282 ;;   parameter, frames created with (minibuffer . t) have a parameter
 283 ;;   (minibuffer . #<window...>), while frames created with
 284 ;;   (minibuffer . #<window...>) have (minibuffer . nil), which is madness
 285 ;;   but helps to differentiate between minibufferless and "normal" frames.
 286 ;;   So, changing (minibuffer . #<window...>) to (minibuffer . t) allows
 287 ;;   Emacs to set up the new frame correctly.  Nice, uh?
 288 ;;
 289 ;; - `name': If this parameter is directly set, `explicit-name' is
 290 ;;   automatically set to t, and then `name' no longer changes dynamically.
 291 ;;   So, in general, not saving `name' is the right thing to do, though
 292 ;;   surely there are applications that will want to override this filter.
 293 ;;
 294 ;; - `font', `fullscreen', `height' and `width': These parameters suffer
 295 ;;   from the fact that they are badly mangled when going through a
 296 ;;   tty session, though not all in the same way.  When saving a GUI frame
 297 ;;   and restoring it in a tty, the height and width of the new frame are
 298 ;;   those of the tty screen (let's say 80x25, for example); going back
 299 ;;   to a GUI session means getting frames of the tty screen size (so all
 300 ;;   your frames are 80 cols x 25 rows).  For `fullscreen' there's a
 301 ;;   similar problem, because a tty frame cannot really be fullscreen or
 302 ;;   maximized, so the state is lost.  The problem with `font' is a bit
 303 ;;   different, because a valid GUI font spec in `font' turns into
 304 ;;   (font . "tty") in a tty frame, and when read back into a GUI session
 305 ;;   it fails because `font's value is no longer a valid font spec.
 306 ;;
 307 ;; In most cases, the filtering functions just do the obvious thing: remove
 308 ;; CURRENT when it is meaningless to keep it, or pass a modified copy if
 309 ;; that helps (as in the case of `minibuffer').
 310 ;;
 311 ;; The exception are the parameters in the last set, which should survive
 312 ;; the roundtrip though tty-land.  The answer is to add "stashing
 313 ;; parameters", working in pairs, to shelve the GUI-specific contents and
 314 ;; restore it once we're back in pixel country.  That's what functions
 315 ;; `frameset-filter-shelve-param' and `frameset-filter-unshelve-param' do.
 316 ;;
 317 ;; Basically, if you set `frameset-filter-shelve-param' as the filter for
 318 ;; a parameter P, it will detect when it is restoring a GUI frame into a
 319 ;; tty session, and save P's value in the custom parameter X:P, but only
 320 ;; if X:P does not exist already (so it is not overwritten if you enter
 321 ;; the tty session more than once).  If you're not switching to a tty
 322 ;; frame, the filter just passes CURRENT along.
 323 ;;
 324 ;; The parameter X:P, on the other hand, must have been setup to be
 325 ;; filtered by `frameset-filter-unshelve-param', which unshelves the
 326 ;; value: if we're entering a GUI session, returns P instead of CURRENT,
 327 ;; while in other cases it just passes it along.
 328 ;;
 329 ;; The only additional trick is that `frameset-filter-shelve-param' does
 330 ;; not set P if switching back to GUI and P already has a value, because
 331 ;; it assumes that `frameset-filter-unshelve-param' did set it up.  And
 332 ;; `frameset-filter-unshelve-param', when unshelving P, must look into
 333 ;; FILTERED to determine if P has already been set and if so, modify it;
 334 ;; else just returns P.
 335 ;;
 336 ;; Currently, the value of X in X:P is `GUI', but you can use any prefix,
 337 ;; by passing its symbol as argument in the filter:
 338 ;;
 339 ;;   (my-parameter frameset-filter-shelve-param MYPREFIX)
 340 ;;
 341 ;; instead of
 342 ;;
 343 ;;   (my-parameter . frameset-filter-shelve-param)
 344 ;;
 345 ;; Note that `frameset-filter-unshelve-param' does not need MYPREFIX
 346 ;; because it is available from the parameter name in CURRENT.  Also note
 347 ;; that the colon between the prefix and the parameter name is hardcoded.
 348 ;; The reason is that X:P is quite readable, and that the colon is a
 349 ;; very unusual character in symbol names, other than in initial position
 350 ;; in keywords (emacs -Q has only two such symbols, and one of them is a
 351 ;; URL).  So the probability of a collision with existing or future
 352 ;; symbols is quite insignificant.
 353 ;;
 354 ;; Now, what about the filter alist variables? There are three of them,
 355 ;; though only two sets of parameters:
 356 ;;
 357 ;; - `frameset-session-filter-alist' contains these filters that allow
 358 ;;   saving and restoring framesets in-session, without the need to
 359 ;;   serialize the frameset or save it to disk (for example, to save a
 360 ;;   frameset in a register and restore it later).  Filters in this
 361 ;;   list do not remove live objects, except in `minibuffer', which is
 362 ;;   dealt especially by `frameset-save' / `frameset-restore'.
 363 ;;
 364 ;; - `frameset-persistent-filter-alist' is the whole deal.  It does all
 365 ;;   the filtering described above, and the result is ready to be saved on
 366 ;;   disk without loss of information.  That's the format used by the
 367 ;;   desktop.el package, for example.
 368 ;;
 369 ;; IMPORTANT: These variables share structure and should NEVER be modified.
 370 ;;
 371 ;; - `frameset-filter-alist': The value of this variable is the default
 372 ;;   value for the FILTERS arguments of `frameset-save' and
 373 ;;   `frameset-restore'.  It is set to `frameset-persistent-filter-alist',
 374 ;;   though it can be changed by specific applications.
 375 ;;
 376 ;; How to use them?
 377 ;;
 378 ;; The simplest way is just do nothing.  The default should work
 379 ;; reasonably and sensibly enough.  But, what if you really need a
 380 ;; customized filter alist?  Then you can create your own variable
 381 ;;
 382 ;;   (defvar my-filter-alist
 383 ;;     '((my-param1 . :never)
 384 ;;       (my-param2 . :save)
 385 ;;       (my-param3 . :restore)
 386 ;;       (my-param4 . my-filtering-function-without-args)
 387 ;;       (my-param5   my-filtering-function-with arg1 arg2)
 388 ;;       ;;; many other parameters
 389 ;;       )
 390 ;;     "My customized parameter filter alist.")
 391 ;;
 392 ;; or, if you're only changing a few items,
 393 ;;
 394 ;;   (defvar my-filter-alist
 395 ;;     (nconc '((my-param1 . :never)
 396 ;;              (my-param2 . my-filtering-function))
 397 ;;            frameset-filter-alist)
 398 ;;     "My brief customized parameter filter alist.")
 399 ;;
 400 ;; and pass it to the FILTER arg of the save/restore functions,
 401 ;; ALWAYS taking care of not modifying the original lists; if you're
 402 ;; going to do any modifying of my-filter-alist, please use
 403 ;;
 404 ;;   (nconc '((my-param1 . :never) ...)
 405 ;;          (copy-sequence frameset-filter-alist))
 406 ;;
 407 ;; One thing you shouldn't forget is that they are alists, so searching
 408 ;; in them is sequential.  If you just want to change the default of
 409 ;; `name' to allow it to be saved, you can set (name . nil) in your
 410 ;; customized filter alist; it will take precedence over the latter
 411 ;; setting.  In case you decide that you *always* want to save `name',
 412 ;; you can add it to `frameset-filter-alist':
 413 ;;
 414 ;;   (push '(name . nil) frameset-filter-alist)
 415 ;;
 416 ;; In certain applications, having a parameter filtering function like
 417 ;; `frameset-filter-params' can be useful, even if you're not using
 418 ;; framesets.  The interface of `frameset-filter-params' is generic
 419 ;; and does not depend of global state, with one exception: it uses
 420 ;; the dynamically bound variable `frameset--target-display' to decide
 421 ;; if, and how, to modify the `display' parameter of FILTERED.  That
 422 ;; should not represent a problem, because it's only meaningful when
 423 ;; restoring, and customized uses of `frameset-filter-params' are
 424 ;; likely to use their own filter alist and just call
 425 ;;
 426 ;;   (setq my-filtered (frameset-filter-params my-params my-filters t))
 427 ;;
 428 ;; In case you want to use it with the standard filters, you can
 429 ;; wrap the call to `frameset-filter-params' in a let form to bind
 430 ;; `frameset--target-display' to nil or the desired value.
 431 ;;
 432
 433 ;;;###autoload
 434 (defvar frameset-session-filter-alist
 435   '((name            . :never)
 436     (left            . frameset-filter-iconified)
 437     (minibuffer      . frameset-filter-minibuffer)
 438     (top             . frameset-filter-iconified))
 439   "Minimum set of parameters to filter for live (on-session) framesets.
 440 DO NOT MODIFY.  See `frameset-filter-alist' for a full description.")
 441
 442 ;;;###autoload
 443 (defvar frameset-persistent-filter-alist
 444   (nconc
 445    '((background-color   . frameset-filter-sanitize-color)
 446      (buffer-list        . :never)
 447      (buffer-predicate   . :never)
 448      (buried-buffer-list . :never)
 449      ;; Don't save the 'client' parameter to avoid that a subsequent
 450      ;; `save-buffers-kill-terminal' in a non-client session barks at
 451      ;; the user (Bug#29067).
 452      (client             . :never)
 453      (delete-before      . :never)
 454      (font               . frameset-filter-font-param)
 455      (foreground-color   . frameset-filter-sanitize-color)
 456      (fullscreen         . frameset-filter-shelve-param)
 457      (GUI:font           . frameset-filter-unshelve-param)
 458      (GUI:fullscreen     . frameset-filter-unshelve-param)
 459      (GUI:height         . frameset-filter-unshelve-param)
 460      (GUI:width          . frameset-filter-unshelve-param)
 461      (height             . frameset-filter-shelve-param)
 462      (outer-window-id    . :never)
 463      (parent-frame       . :never)
 464      (parent-id          . :never)
 465      (mouse-wheel-frame  . :never)
 466      (tty                . frameset-filter-tty-to-GUI)
 467      (tty-type           . frameset-filter-tty-to-GUI)
 468      (width              . frameset-filter-shelve-param)
 469      (window-id          . :never)
 470      (window-system      . :never))
 471    frameset-session-filter-alist)
 472   "Parameters to filter for persistent framesets.
 473 DO NOT MODIFY.  See `frameset-filter-alist' for a full description.")
 474
 475 ;;;###autoload
 476 (defvar frameset-filter-alist frameset-persistent-filter-alist
 477   "Alist of frame parameters and filtering functions.
 478
 479 This alist is the default value of the FILTERS argument of
 480 `frameset-save' and `frameset-restore' (which see).
 481
 482 Initially, `frameset-filter-alist' is set to, and shares the value of,
 483 `frameset-persistent-filter-alist'.  You can override any item in
 484 this alist by `push'ing a new item onto it.  If, for some reason, you
 485 intend to modify existing values, do
 486
 487   (setq frameset-filter-alist (copy-tree frameset-filter-alist))
 488
 489 before changing anything.
 490
 491 On saving, PARAMETERS is the parameter alist of each frame processed,
 492 and FILTERED is the parameter alist that gets saved to the frameset.
 493
 494 On restoring, PARAMETERS is the parameter alist extracted from the
 495 frameset, and FILTERED is the resulting frame parameter alist used
 496 to restore the frame.
 497
 498 Elements of `frameset-filter-alist' are conses (PARAM . ACTION),
 499 where PARAM is a parameter name (a symbol identifying a frame
 500 parameter), and ACTION can be:
 501
 502  nil       The parameter is copied to FILTERED.
 503  :never    The parameter is never copied to FILTERED.
 504  :save     The parameter is copied only when saving the frame.
 505  :restore  The parameter is copied only when restoring the frame.
 506  FILTER    A filter function.
 507
 508 FILTER can be a symbol FILTER-FUN, or a list (FILTER-FUN ARGS...).
 509 FILTER-FUN is invoked with
 510
 511   (apply FILTER-FUN CURRENT FILTERED PARAMETERS SAVING ARGS)
 512
 513 where
 514
 515  CURRENT     A cons (PARAM . VALUE), where PARAM is the one being
 516              filtered and VALUE is its current value.
 517  FILTERED    The resulting alist (so far).
 518  PARAMETERS  The complete alist of parameters being filtered,
 519  SAVING      Non-nil if filtering before saving state, nil if filtering
 520                before restoring it.
 521  ARGS        Any additional arguments specified in the ACTION.
 522
 523 FILTER-FUN is allowed to modify items in FILTERED, but no other arguments.
 524 It must return:
 525  nil                      Skip CURRENT (do not add it to FILTERED).
 526  t                        Add CURRENT to FILTERED as is.
 527  (NEW-PARAM . NEW-VALUE)  Add this to FILTERED instead of CURRENT.
 528
 529 Frame parameters not on this alist are passed intact, as if they were
 530 defined with ACTION = nil.")
 531
 532 ;; Dynamically bound in `frameset-save', `frameset-restore'.
 533 (defvar frameset--target-display)
 534 ;; Either (display . VALUE) or nil.
 535 ;; This refers to the current frame config being processed with
 536 ;; `frameset-filter-params' and its auxiliary filtering functions.
 537 ;; If nil, there is no need to change the display.
 538 ;; If non-nil, display parameter to use when creating the frame.
 539
 540 (defun frameset-switch-to-gui-p (parameters)
 541   "True when switching to a graphic display.
 542 Return non-nil if the parameter alist PARAMETERS describes a frame on a
 543 text-only terminal, and the frame is being restored on a graphic display;
 544 otherwise return nil.  Only meaningful when called from a filtering
 545 function in `frameset-filter-alist'."
 546   (and frameset--target-display                   ; we're switching
 547        (null (cdr (assq 'display parameters)))    ; from a tty
 548        (cdr frameset--target-display)))           ; to a GUI display
 549
 550 (defun frameset-switch-to-tty-p (parameters)
 551   "True when switching to a text-only terminal.
 552 Return non-nil if the parameter alist PARAMETERS describes a frame on a
 553 graphic display, and the frame is being restored on a text-only terminal;
 554 otherwise return nil.  Only meaningful when called from a filtering
 555 function in `frameset-filter-alist'."
 556   (and frameset--target-display                   ; we're switching
 557        (cdr (assq 'display parameters))           ; from a GUI display
 558        (null (cdr frameset--target-display))))    ; to a tty
 559
 560 (defun frameset-filter-tty-to-GUI (_current _filtered parameters saving)
 561   "Remove CURRENT when switching from tty to a graphic display.
 562
 563 For the meaning of CURRENT, FILTERED, PARAMETERS and SAVING,
 564 see `frameset-filter-alist'."
 565   (or saving
 566       (not (frameset-switch-to-gui-p parameters))))
 567
 568 (defun frameset-filter-sanitize-color (current _filtered parameters saving)
 569   "When switching to a GUI frame, remove \"unspecified\" colors.
 570 Useful as a filter function for tty-specific parameters.
 571
 572 For the meaning of CURRENT, FILTERED, PARAMETERS and SAVING,
 573 see `frameset-filter-alist'."
 574   (or saving
 575       (not (frameset-switch-to-gui-p parameters))
 576       (not (stringp (cdr current)))
 577       (not (string-match-p "^unspecified-[fb]g$" (cdr current)))))
 578
 579 (defun frameset-filter-minibuffer (current filtered _parameters saving)
 580   "Force the minibuffer parameter to have a sensible value.
 581
 582 When saving, convert (minibuffer . #<window>) to (minibuffer . nil).
 583 When restoring, if there are two copies, keep the one pointing to
 584 a live window.
 585
 586 For the meaning of CURRENT, FILTERED, PARAMETERS and SAVING,
 587 see `frameset-filter-alist'."
 588   (let ((value (cdr current)) mini)
 589     (cond (saving
 590            ;; "Fix semantics of 'minibuffer' frame parameter" change:
 591            ;; When the cdr of the parameter is a minibuffer window, save
 592            ;; (minibuffer . nil) instead of (minibuffer . t).
 593            (if (windowp value)
 594                '(minibuffer . nil)
 595              t))
 596           ((setq mini (assq 'minibuffer filtered))
 597            (when (windowp value) (setcdr mini value))
 598            nil)
 599           (t t))))
 600
 601 (defun frameset-filter-shelve-param (current _filtered parameters saving
 602                                              &optional prefix)
 603   "When switching to a tty frame, save parameter P as PREFIX:P.
 604 The parameter can be later restored with `frameset-filter-unshelve-param'.
 605 PREFIX defaults to `GUI'.
 606
 607 For the meaning of CURRENT, FILTERED, PARAMETERS and SAVING,
 608 see `frameset-filter-alist'."
 609   (unless prefix (setq prefix 'GUI))
 610   (cond (saving t)
 611         ((frameset-switch-to-tty-p parameters)
 612          (let ((prefix:p (intern (format "%s:%s" prefix (car current)))))
 613            (if (assq prefix:p parameters)
 614                nil
 615              (cons prefix:p (cdr current)))))
 616         ((frameset-switch-to-gui-p parameters)
 617          (not (assq (intern (format "%s:%s" prefix (car current))) parameters)))
 618         (t t)))
 619
 620 (defun frameset-filter-unshelve-param (current filtered parameters saving)
 621   "When switching to a GUI frame, restore PREFIX:P parameter as P.
 622 CURRENT must be of the form (PREFIX:P . value).
 623
 624 For the meaning of CURRENT, FILTERED, PARAMETERS and SAVING,
 625 see `frameset-filter-alist'."
 626   (or saving
 627       (not (frameset-switch-to-gui-p parameters))
 628       (let* ((prefix:p (symbol-name (car current)))
 629              (p (intern (substring prefix:p
 630                                    (1+ (string-match-p ":" prefix:p)))))
 631              (val (cdr current))
 632              (found (assq p filtered)))
 633         (if (not found)
 634             (cons p val)
 635           (setcdr found val)
 636           nil))))
 637
 638 (defun frameset-filter-font-param (current filtered parameters saving
 639                                            &optional prefix)
 640   "When switching from a tty frame to a GUI frame, remove the FONT param.
 641
 642 When switching from a GUI frame to a tty frame, behave
 643 as `frameset-filter-shelve-param' does."
 644   (or saving
 645       (if (frameset-switch-to-tty-p parameters)
 646           (frameset-filter-shelve-param current filtered parameters saving
 647                                         prefix))))
 648
 649 (defun frameset-filter-iconified (_current _filtered parameters saving)
 650   "Remove CURRENT when saving an iconified frame.
 651 This is used for positional parameters `left' and `top', which are
 652 meaningless in an iconified frame, so the frame is restored in a
 653 default position.
 654
 655 For the meaning of CURRENT, FILTERED, PARAMETERS and SAVING,
 656 see `frameset-filter-alist'."
 657   (not (and saving (eq (cdr (assq 'visibility parameters)) 'icon))))
 658
 659 (defun frameset-filter-params (parameters filter-alist saving)
 660   "Filter parameter alist PARAMETERS and return a filtered alist.
 661 FILTER-ALIST is an alist of parameter filters, in the format of
 662 `frameset-filter-alist' (which see).
 663 SAVING is non-nil while filtering parameters to save a frameset,
 664 nil while the filtering is done to restore it."
 665   (let ((filtered nil))
 666     (dolist (current parameters)
 667       ;; When saving, the parameter alist is temporary, so modifying it
 668       ;; is not a problem.  When restoring, the parameter alist is part
 669       ;; of a frameset, so we must copy parameters to avoid inadvertent
 670       ;; modifications.
 671       (pcase (cdr (assq (car current) filter-alist))
 672         (`nil
 673          (push (if saving current (copy-tree current)) filtered))
 674         (:never
 675          nil)
 676         (:restore
 677          (unless saving (push (copy-tree current) filtered)))
 678         (:save
 679          (when saving (push current filtered)))
 680         ((or `(,fun . ,args) (and fun (pred fboundp)))
 681          (let* ((this (apply fun current filtered parameters saving args))
 682                 (val (if (eq this t) current this)))
 683            (when val
 684              (push (if saving val (copy-tree val)) filtered))))
 685         (other
 686          (delay-warning 'frameset (format "Unknown filter %S" other) :error))))
 687     ;; Set the display parameter after filtering, so that filter functions
 688     ;; have access to its original value.
 689     (when frameset--target-display
 690       (setf (alist-get 'display filtered) (cdr frameset--target-display)))
 691     filtered))
 692
 693 \f
 694 ;; Frame ids
 695
 696 (defun frameset--set-id (frame)
 697   "Set FRAME's id if not yet set.
 698 Internal use only."
 699   (unless (frame-parameter frame 'frameset--id)
 700     (set-frame-parameter frame
 701                          'frameset--id
 702                          (mapconcat (lambda (n) (format "%04X" n))
 703                                     (cl-loop repeat 4 collect (random 65536))
 704                                     "-"))))
 705
 706 (defun frameset-cfg-id (frame-cfg)
 707   "Return the frame id for frame configuration FRAME-CFG."
 708   (cdr (assq 'frameset--id frame-cfg)))
 709
 710 ;;;###autoload
 711 (defun frameset-frame-id (frame)
 712   "Return the frame id of FRAME, if it has one; else, return nil.
 713 A frame id is a string that uniquely identifies a frame.
 714 It is persistent across `frameset-save' / `frameset-restore'
 715 invocations, and once assigned is never changed unless the same
 716 frame is duplicated (via `frameset-restore'), in which case the
 717 newest frame keeps the id and the old frame's is set to nil."
 718   (frame-parameter frame 'frameset--id))
 719
 720 ;;;###autoload
 721 (defun frameset-frame-id-equal-p (frame id)
 722   "Return non-nil if FRAME's id matches ID."
 723   (string= (frameset-frame-id frame) id))
 724
 725 ;;;###autoload
 726 (defun frameset-frame-with-id (id &optional frame-list)
 727   "Return the live frame with id ID, if exists; else nil.
 728 If FRAME-LIST is a list of frames, check these frames only.
 729 If nil, check all live frames."
 730   (cl-find-if (lambda (f)
 731                 (and (frame-live-p f)
 732                      (frameset-frame-id-equal-p f id)))
 733               (or frame-list (frame-list))))
 734
 735 \f
 736 ;; Saving framesets
 737
 738 (defun frameset--record-relationships (frame-list)
 739   "Process FRAME-LIST and record relationships.
 740 FRAME-LIST is a list of frames.
 741
 742 The relationships recorded for each frame are
 743
 744 - `minibuffer' via `frameset--mini'
 745 - `delete-before' via `frameset--delete-before'
 746 - `parent-frame' via `frameset--parent-frame'
 747 - `mouse-wheel-frame' via `frameset--mouse-wheel-frame'
 748
 749 Internal use only."
 750   ;; Record frames with their own minibuffer
 751   (dolist (frame (minibuffer-frame-list))
 752     (when (memq frame frame-list)
 753       (frameset--set-id frame)
 754       ;; For minibuffer-owning frames, frameset--mini is a cons
 755       ;; (t . DEFAULT?), where DEFAULT? is a boolean indicating whether
 756       ;; the frame is the one pointed out by `default-minibuffer-frame'.
 757       (set-frame-parameter frame
 758                            'frameset--mini
 759                            (cons t (eq frame default-minibuffer-frame)))))
 760   ;; Now link minibufferless frames with their minibuffer frames and
 761   ;; store `parent-frame', `delete-before' and `mouse-wheel-frame'
 762   ;; relationships in a similar way.
 763   (dolist (frame frame-list)
 764     (let ((parent-frame (frame-parent frame))
 765           (delete-before (frame-parameter frame 'delete-before))
 766           (mouse-wheel-frame (frame-parameter frame 'mouse-wheel-frame))
 767           (nomini (not (frame-parameter frame 'frameset--mini))))
 768       (when (or nomini parent-frame delete-before mouse-wheel-frame)
 769         (when nomini
 770           (frameset--set-id frame))
 771         (when parent-frame
 772           (set-frame-parameter
 773            frame 'frameset--parent-frame (frameset-frame-id parent-frame)))
 774         (when delete-before
 775           (set-frame-parameter
 776            frame 'frameset--delete-before (frameset-frame-id delete-before)))
 777         (when mouse-wheel-frame
 778           (set-frame-parameter
 779            frame 'frameset--mouse-wheel-frame
 780            (frameset-frame-id mouse-wheel-frame)))
 781         (when nomini
 782           (let ((mb-frame (window-frame (minibuffer-window frame))))
 783             ;; For minibufferless frames, frameset--mini is a cons
 784             ;; (nil . FRAME-ID), where FRAME-ID is the frameset--id of
 785             ;; the frame containing its minibuffer window.
 786             ;; FRAME-ID can be set to nil, if FRAME-LIST doesn't contain
 787             ;; the minibuffer frame of a minibufferless frame; we allow
 788             ;; it without trying to second-guess the user.
 789             (set-frame-parameter
 790              frame
 791              'frameset--mini
 792              (cons nil
 793                    (and mb-frame
 794                         (frameset-frame-id mb-frame))))))))))
 795
 796 ;;;###autoload
 797 (cl-defun frameset-save (frame-list
 798                          &key app name description
 799                               filters predicate properties)
 800   "Return a frameset for FRAME-LIST, a list of frames.
 801 Dead frames and non-frame objects are silently removed from the list.
 802 If nil, FRAME-LIST defaults to the output of `frame-list' (all live frames).
 803 APP, NAME and DESCRIPTION are optional data; see the docstring of the
 804 `frameset' defstruct for details.
 805 FILTERS is an alist of parameter filters; if nil, the value of the variable
 806 `frameset-filter-alist' is used instead.
 807 PREDICATE is a predicate function, which must return non-nil for frames that
 808 should be saved; if PREDICATE is nil, all frames from FRAME-LIST are saved.
 809 PROPERTIES is a user-defined property list to add to the frameset."
 810   (let* ((list (or (copy-sequence frame-list) (frame-list)))
 811          (frameset--target-display nil)
 812          (frames (cl-delete-if-not #'frame-live-p
 813                                    (if predicate
 814                                        (cl-delete-if-not predicate list)
 815                                      list)))
 816          fs)
 817     (frameset--record-relationships frames)
 818     (setq fs (frameset--make
 819               :app app
 820               :name name
 821               :description description
 822               :properties properties
 823               :states (mapcar
 824                        (lambda (frame)
 825                          (cons
 826                           (frameset-filter-params (frame-parameters frame)
 827                                                   (or filters
 828                                                       frameset-filter-alist)
 829                                                   t)
 830                           (window-state-get (frame-root-window frame) t)))
 831                        frames)))
 832     (cl-assert (frameset-valid-p fs))
 833     fs))
 834
 835 \f
 836 ;; Restoring framesets
 837
 838 ;; Dynamically bound in `frameset-restore'.
 839 (defvar frameset--reuse-list)
 840 (defvar frameset--action-map)
 841
 842 (defun frameset-compute-pos (value left/top right/bottom)
 843   "Return an absolute positioning value for a frame.
 844 VALUE is the value of a positional frame parameter (`left' or `top').
 845 If VALUE is relative to the screen edges (like (+ -35) or (-200), it is
 846 converted to absolute by adding it to the corresponding edge; if it is
 847 an absolute position, it is returned unmodified.
 848 LEFT/TOP and RIGHT/BOTTOM indicate the dimensions of the screen in
 849 pixels along the relevant direction: either the position of the left
 850 and right edges for a `left' positional parameter, or the position of
 851 the top and bottom edges for a `top' parameter."
 852   (pcase value
 853     (`(+ ,val) (+ left/top val))
 854     (`(- ,val) (+ right/bottom val))
 855     (val val)))
 856
 857 (defun frameset-move-onscreen (frame force-onscreen)
 858   "If FRAME is offscreen, move it back onscreen and, if necessary, resize it.
 859 For the description of FORCE-ONSCREEN, see `frameset-restore'.
 860 When forced onscreen, frames wider than the monitor's workarea are converted
 861 to fullwidth, and frames taller than the workarea are converted to fullheight.
 862 NOTE: This only works for non-iconified frames."
 863   (pcase-let* ((`(,left ,top ,width ,height) (cl-cdadr (frame-monitor-attributes frame)))
 864                (right (+ left width -1))
 865                (bottom (+ top height -1))
 866                (fr-left (frameset-compute-pos (frame-parameter frame 'left) left right))
 867                (fr-top (frameset-compute-pos (frame-parameter frame 'top) top bottom))
 868                (ch-width (frame-char-width frame))
 869                (ch-height (frame-char-height frame))
 870                (fr-width (max (frame-pixel-width frame) (* ch-width (frame-width frame))))
 871                (fr-height (max (frame-pixel-height frame) (* ch-height (frame-height frame))))
 872                (fr-right (+ fr-left fr-width -1))
 873                (fr-bottom (+ fr-top fr-height -1)))
 874     (when (pcase force-onscreen
 875             ;; A predicate.
 876             ((pred functionp)
 877              (funcall force-onscreen
 878                       frame
 879                       (list fr-left fr-top fr-width fr-height)
 880                       (list left top width height)))
 881             ;; Any corner is outside the screen.
 882             (:all (or (< fr-bottom top)  (> fr-bottom bottom)
 883                       (< fr-left   left) (> fr-left   right)
 884                       (< fr-right  left) (> fr-right  right)
 885                       (< fr-top    top)  (> fr-top    bottom)))
 886             ;; Displaced to the left, right, above or below the screen.
 887             (`t   (or (> fr-left   right)
 888                       (< fr-right  left)
 889                       (> fr-top    bottom)
 890                       (< fr-bottom top)))
 891             ;; Fully inside, no need to do anything.
 892             (_ nil))
 893       (let ((fullwidth (> fr-width width))
 894             (fullheight (> fr-height height))
 895             (params nil))
 896         ;; Position frame horizontally.
 897         (cond (fullwidth
 898                (push `(left . ,left) params))
 899               ((> fr-right right)
 900                (push `(left . ,(+ left (- width fr-width))) params))
 901               ((< fr-left left)
 902                (push `(left . ,left) params)))
 903         ;; Position frame vertically.
 904         (cond (fullheight
 905                (push `(top . ,top) params))
 906               ((> fr-bottom bottom)
 907                (push `(top . ,(+ top (- height fr-height))) params))
 908               ((< fr-top top)
 909                (push `(top . ,top) params)))
 910         ;; Compute fullscreen state, if required.
 911         (when (or fullwidth fullheight)
 912           (push (cons 'fullscreen
 913                       (cond ((not fullwidth) 'fullheight)
 914                             ((not fullheight) 'fullwidth)
 915                             (t 'maximized)))
 916                 params))
 917         ;; Finally, move the frame back onscreen.
 918         (when params
 919           (modify-frame-parameters frame params))))))
 920
 921 (defun frameset--find-frame-if (predicate display &rest args)
 922   "Find a reusable frame satisfying PREDICATE.
 923 Look through available frames whose display property matches DISPLAY
 924 and return the first one for which (PREDICATE frame ARGS) returns t.
 925 If PREDICATE is nil, it is always satisfied.  Internal use only."
 926   (cl-find-if (lambda (frame)
 927                 (and (equal (frame-parameter frame 'display) display)
 928                      (or (null predicate)
 929                          (apply predicate frame args))))
 930               frameset--reuse-list))
 931
 932 (defun frameset--reuse-frame (display parameters)
 933   "Return an existing frame to reuse, or nil if none found.
 934 DISPLAY is the display where the frame will be shown, and PARAMETERS
 935 is the parameter alist of the frame being restored.  Internal use only."
 936   (let ((frame nil)
 937         mini)
 938     ;; There are no fancy heuristics there.  We could implement some
 939     ;; based on frame size and/or position, etc., but it is not clear
 940     ;; that any "gain" (in the sense of reduced flickering, etc.) is
 941     ;; worth the added complexity.  In fact, the code below mainly
 942     ;; tries to work nicely when M-x desktop-read is used after a
 943     ;; desktop session has already been loaded.  The other main use
 944     ;; case, which is the initial desktop-read upon starting Emacs,
 945     ;; will usually have only one frame, and should already work.
 946     (cond ((null display)
 947            ;; When the target is tty, every existing frame is reusable.
 948            (setq frame (frameset--find-frame-if nil display)))
 949           ((car (setq mini (cdr (assq 'frameset--mini parameters))))
 950            ;; If the frame has its own minibuffer, let's see whether
 951            ;; that frame has already been loaded (which can happen after
 952            ;; M-x desktop-read).
 953            (setq frame (frameset--find-frame-if
 954                         (lambda (f id)
 955                           (frameset-frame-id-equal-p f id))
 956                         display (frameset-cfg-id parameters)))
 957            ;; If it has not been loaded, and it is not a minibuffer-only frame,
 958            ;; let's look for an existing non-minibuffer-only frame to reuse.
 959            (unless (or frame (eq (cdr (assq 'minibuffer parameters)) 'only))
 960            ;; "Fix semantics of 'minibuffer' frame parameter" change:
 961            ;; The 'minibuffer' frame parameter of a non-minibuffer-only
 962            ;; frame is t instead of that frame's minibuffer window.
 963              (setq frame (frameset--find-frame-if
 964                           (lambda (f)
 965                             (eq (frame-parameter f 'minibuffer) t))
 966                           display))))
 967           (mini
 968            ;; For minibufferless frames, check whether they already exist,
 969            ;; and that they are linked to the right minibuffer frame.
 970            (setq frame (frameset--find-frame-if
 971                         (lambda (f id mini-id)
 972                           (and (frameset-frame-id-equal-p f id)
 973                                (or (null mini-id) ; minibuffer frame not saved
 974                                    (frameset-frame-id-equal-p
 975                                     (window-frame (minibuffer-window f))
 976                                     mini-id))))
 977                         display (frameset-cfg-id parameters) (cdr mini))))
 978           (t
 979            ;; Default to just finding a frame in the same display.
 980            (setq frame (frameset--find-frame-if nil display))))
 981     ;; If found, remove from the list.
 982     (when frame
 983       (setq frameset--reuse-list (delq frame frameset--reuse-list)))
 984     frame))
 985
 986 (defun frameset--initial-params (parameters)
 987   "Return a list of PARAMETERS that must be set when creating the frame.
 988 Setting position and size parameters as soon as possible helps reducing
 989 flickering; other parameters, like `minibuffer' and `border-width', can
 990 not be changed once the frame has been created.  Internal use only."
 991   (cl-loop for param in '(left top width height border-width minibuffer)
 992            when (assq param parameters) collect it))
 993
 994 (defun frameset--restore-frame (parameters window-state filters force-onscreen)
 995   "Set up and return a frame according to its saved state.
 996 That means either reusing an existing frame or creating one anew.
 997 PARAMETERS is the frame's parameter alist; WINDOW-STATE is its window state.
 998 For the meaning of FILTERS and FORCE-ONSCREEN, see `frameset-restore'.
 999 Internal use only."
1000   (let* ((fullscreen (cdr (assq 'fullscreen parameters)))
1001          (filtered-cfg (frameset-filter-params parameters filters nil))
1002          (display (cdr (assq 'display filtered-cfg))) ;; post-filtering
1003          alt-cfg frame)
1004
1005     (when fullscreen
1006       ;; Currently Emacs has the limitation that it does not record the size
1007       ;; and position of a frame before maximizing it, so we cannot save &
1008       ;; restore that info.  Instead, when restoring, we resort to creating
1009       ;; invisible "fullscreen" frames of default size and then maximizing them
1010       ;; (and making them visible) which at least is somewhat user-friendly
1011       ;; when these frames are later de-maximized.
1012       (let ((width (and (eq fullscreen 'fullheight) (cdr (assq 'width filtered-cfg))))
1013             (height (and (eq fullscreen 'fullwidth) (cdr (assq 'height filtered-cfg))))
1014             (visible (assq 'visibility filtered-cfg)))
1015         (setq filtered-cfg (cl-delete-if (lambda (p)
1016                                            (memq p '(visibility fullscreen width height)))
1017                                          filtered-cfg :key #'car))
1018         (when width
1019           (setq filtered-cfg (append `((user-size . t) (width . ,width))
1020                                      filtered-cfg)))
1021         (when height
1022           (setq filtered-cfg (append `((user-size . t) (height . ,height))
1023                                      filtered-cfg)))
1024         ;; These are parameters to apply after creating/setting the frame.
1025         (push visible alt-cfg)
1026         (push (cons 'fullscreen fullscreen) alt-cfg)))
1027
1028     ;; Time to find or create a frame and apply the big bunch of parameters.
1029     (setq frame (and frameset--reuse-list
1030                      (frameset--reuse-frame display filtered-cfg)))
1031     (if frame
1032         (puthash frame :reused frameset--action-map)
1033       ;; If a frame needs to be created and it falls partially or fully offscreen,
1034       ;; sometimes it gets "pushed back" onscreen; however, moving it afterwards is
1035       ;; allowed.  So we create the frame as invisible and then reapply the full
1036       ;; parameter alist (including position and size parameters).
1037       (setq frame (make-frame-on-display display
1038                                          (cons '(visibility)
1039                                                (frameset--initial-params filtered-cfg))))
1040       (puthash frame :created frameset--action-map))
1041
1042     ;; Remove `border-width' from the list of parameters.  If it has not
1043     ;; been assigned via `make-frame-on-display', any attempt to assign
1044     ;; it now via `modify-frame-parameters' may result in an error on X
1045     ;; (Bug#28873).
1046     (setq filtered-cfg (assq-delete-all 'border-width filtered-cfg))
1047
1048     ;; Try to assign parent-frame right here - it will improve things
1049     ;; for minibuffer-less child frames.
1050     (let* ((frame-id (frame-parameter frame 'frameset--parent-frame))
1051            (parent-frame
1052             (and frame-id (frameset-frame-with-id frame-id))))
1053       (when (frame-live-p parent-frame)
1054         (set-frame-parameter frame 'parent-frame parent-frame)))
1055
1056     (modify-frame-parameters frame
1057                              (if (eq (frame-parameter frame 'fullscreen) fullscreen)
1058                                  ;; Workaround for bug#14949
1059                                  (assq-delete-all 'fullscreen filtered-cfg)
1060                                filtered-cfg))
1061
1062     ;; If requested, force frames to be onscreen.
1063     (when (and force-onscreen
1064                ;; FIXME: iconified frames should be checked too,
1065                ;; but it is impossible without deiconifying them.
1066                (not (eq (frame-parameter frame 'visibility) 'icon)))
1067       (frameset-move-onscreen frame force-onscreen))
1068
1069     ;; Let's give the finishing touches (visibility, maximization).
1070     (when alt-cfg (modify-frame-parameters frame alt-cfg))
1071     ;; Now restore window state.
1072     (window-state-put window-state (frame-root-window frame) 'safe)
1073     frame))
1074
1075 (defun frameset--minibufferless-last-p (state1 state2)
1076   "Predicate to sort frame states in an order suitable for creating frames.
1077 It sorts minibuffer-owning frames before minibufferless ones.
1078 Internal use only."
1079   (pcase-let ((`(,hasmini1 ,id-def1) (assq 'frameset--mini (car state1)))
1080               (`(,hasmini2 ,id-def2) (assq 'frameset--mini (car state2))))
1081     (cond ((eq id-def1 t) t)
1082           ((eq id-def2 t) nil)
1083           ((not (eq hasmini1 hasmini2)) (eq hasmini1 t))
1084           ((eq hasmini1 nil) (or id-def1 id-def2))
1085           (t t))))
1086
1087 (defun frameset-keep-original-display-p (force-display)
1088   "True if saved frames' displays should be honored.
1089 For the meaning of FORCE-DISPLAY, see `frameset-restore'."
1090   (cond ((eq system-type 'windows-nt) nil) ;; Does ns support more than one display?
1091         ((daemonp) t)
1092         (t (not force-display))))
1093
1094 (defun frameset-minibufferless-first-p (frame1 _frame2)
1095   "Predicate to sort minibuffer-less frames before other frames."
1096   ;; "Fix semantics of 'minibuffer' frame parameter" change: The
1097   ;; 'minibuffer' frame parameter of a minibuffer-less frame is that
1098   ;; frame's minibuffer window instead of nil.
1099   (windowp (frame-parameter frame1 'minibuffer)))
1100
1101 ;;;###autoload
1102 (cl-defun frameset-restore (frameset
1103                             &key predicate filters reuse-frames
1104                                  force-display force-onscreen
1105                                  cleanup-frames)
1106   "Restore a FRAMESET into the current display(s).
1107
1108 PREDICATE is a function called with two arguments, the parameter alist
1109 and the window-state of the frame being restored, in that order (see
1110 the docstring of the `frameset' defstruct for additional details).
1111 If PREDICATE returns nil, the frame described by that parameter alist
1112 and window-state is not restored.
1113
1114 FILTERS is an alist of parameter filters; if nil, the value of
1115 `frameset-filter-alist' is used instead.
1116
1117 REUSE-FRAMES selects the policy to reuse frames when restoring:
1118   t        All existing frames can be reused.
1119   nil      No existing frame can be reused.
1120   match    Only frames with matching frame ids can be reused.
1121   PRED     A predicate function; it receives as argument a live frame,
1122              and must return non-nil to allow reusing it, nil otherwise.
1123
1124 FORCE-DISPLAY can be:
1125   t        Frames are restored in the current display.
1126   nil      Frames are restored, if possible, in their original displays.
1127   delete   Frames in other displays are deleted instead of restored.
1128   PRED     A function called with two arguments, the parameter alist and
1129              the window state (in that order).  It must return t, nil or
1130              `delete', as above but affecting only the frame that will
1131              be created from that parameter alist.
1132
1133 FORCE-ONSCREEN can be:
1134   t        Force onscreen only those frames that are fully offscreen.
1135   nil      Do not force any frame back onscreen.
1136   all      Force onscreen any frame fully or partially offscreen.
1137   PRED     A function called with three arguments,
1138            - the live frame just restored,
1139            - a list (LEFT TOP WIDTH HEIGHT), describing the frame,
1140            - a list (LEFT TOP WIDTH HEIGHT), describing the workarea.
1141            It must return non-nil to force the frame onscreen, nil otherwise.
1142
1143 CLEANUP-FRAMES allows \"cleaning up\" the frame list after restoring a frameset:
1144   t        Delete all frames that were not created or restored upon.
1145   nil      Keep all frames.
1146   FUNC     A function called with two arguments:
1147            - FRAME, a live frame.
1148            - ACTION, which can be one of
1149              :rejected  Frame existed, but was not a candidate for reuse.
1150              :ignored   Frame existed, was a candidate, but wasn't reused.
1151              :reused    Frame existed, was a candidate, and restored upon.
1152              :created   Frame didn't exist, was created and restored upon.
1153            Return value is ignored.
1154
1155 Note the timing and scope of the operations described above: REUSE-FRAMES
1156 affects existing frames; PREDICATE, FILTERS and FORCE-DISPLAY affect the frame
1157 being restored before that happens; FORCE-ONSCREEN affects the frame once
1158 it has been restored; and CLEANUP-FRAMES affects all frames alive after the
1159 restoration, including those that have been reused or created anew.
1160
1161 All keyword parameters default to nil."
1162
1163   (cl-assert (frameset-valid-p frameset))
1164
1165   (let* ((frames (frame-list))
1166          (frameset--action-map (make-hash-table :test #'eq))
1167          ;; frameset--reuse-list is a list of frames potentially reusable.  Later we
1168          ;; will decide which ones can be reused, and how to deal with any leftover.
1169          (frameset--reuse-list
1170           (pcase reuse-frames
1171             (`t
1172              frames)
1173             (`nil
1174              nil)
1175             (`match
1176              (cl-loop for (state) in (frameset-states frameset)
1177                       when (frameset-frame-with-id (frameset-cfg-id state) frames)
1178                       collect it))
1179             ((pred functionp)
1180              (cl-remove-if-not reuse-frames frames))
1181             (_
1182              (error "Invalid arg :reuse-frames %s" reuse-frames)))))
1183
1184     ;; Mark existing frames in the map; candidates to reuse are marked as :ignored;
1185     ;; they will be reassigned later, if chosen.
1186     (dolist (frame frames)
1187       (puthash frame
1188                (if (memq frame frameset--reuse-list) :ignored :rejected)
1189                frameset--action-map))
1190
1191     ;; Sort saved states to guarantee that minibufferless frames will be created
1192     ;; after the frames that contain their minibuffer windows.
1193     (dolist (state (sort (copy-sequence (frameset-states frameset))
1194                          #'frameset--minibufferless-last-p))
1195       (pcase-let ((`(,frame-cfg . ,window-cfg) state))
1196         (when (or (null predicate) (funcall predicate frame-cfg window-cfg))
1197           (condition-case-unless-debug err
1198               (let* ((d-mini (cdr (assq 'frameset--mini frame-cfg)))
1199                      (mb-id (cdr d-mini))
1200                      (default (and (car d-mini) mb-id))
1201                      (force-display (if (functionp force-display)
1202                                         (funcall force-display frame-cfg window-cfg)
1203                                       force-display))
1204                      (frameset--target-display nil)
1205                      frame to-tty duplicate)
1206                 ;; Only set target if forcing displays and the target display is different.
1207                 (unless (or (frameset-keep-original-display-p force-display)
1208                             (equal (frame-parameter nil 'display)
1209                                    (cdr (assq 'display frame-cfg))))
1210                   (setq frameset--target-display (cons 'display
1211                                                        (frame-parameter nil 'display))
1212                         to-tty (null (cdr frameset--target-display))))
1213                 ;; Time to restore frames and set up their minibuffers as they were.
1214                 ;; We only skip a frame (thus deleting it) if either:
1215                 ;; - we're switching displays, and the user chose the option to delete, or
1216                 ;; - we're switching to tty, and the frame to restore is minibuffer-only.
1217                 (unless (and frameset--target-display
1218                              (or (eq force-display 'delete)
1219                                  (and to-tty
1220                                       (eq (cdr (assq 'minibuffer frame-cfg)) 'only))))
1221                   ;; To avoid duplicating frame ids after restoration, we note any
1222                   ;; existing frame whose id matches a frame configuration in the
1223                   ;; frameset.  Once the frame config is properly restored, we can
1224                   ;; reset the old frame's id to nil.
1225                   (setq duplicate (frameset-frame-with-id (frameset-cfg-id frame-cfg)
1226                                                           frames))
1227                   ;; Restore minibuffers.  Some of this stuff could be done in a filter
1228                   ;; function, but it would be messy because restoring minibuffers affects
1229                   ;; global state; it's best to do it here than add a bunch of global
1230                   ;; variables to pass info back-and-forth to/from the filter function.
1231                   (cond
1232                    ((null d-mini)) ;; No frameset--mini.  Process as normal frame.
1233                    (to-tty) ;; Ignore minibuffer stuff and process as normal frame.
1234                    ((car d-mini) ;; Frame has minibuffer (or it is minibuffer-only).
1235                     (when (eq (cdr (assq 'minibuffer frame-cfg)) 'only)
1236                       (setq frame-cfg (append '((tool-bar-lines . 0) (menu-bar-lines . 0))
1237                                               frame-cfg))))
1238                    (t ;; Frame depends on other frame's minibuffer window.
1239                     (when mb-id
1240                       (let ((mb-frame (frameset-frame-with-id mb-id))
1241                             (mb-window nil))
1242                         (if (not mb-frame)
1243                             (delay-warning 'frameset
1244                                            (format "Minibuffer frame %S not found" mb-id)
1245                                            :warning)
1246                           (setq mb-window (minibuffer-window mb-frame))
1247                           (unless (and (window-live-p mb-window)
1248                                        (window-minibuffer-p mb-window))
1249                             (delay-warning 'frameset
1250                                            (format "Not a minibuffer window %s" mb-window)
1251                                            :warning)
1252                             (setq mb-window nil)))
1253                         (when mb-window
1254                           (push (cons 'minibuffer mb-window) frame-cfg))))))
1255                   ;; OK, we're ready at last to create (or reuse) a frame and
1256                   ;; restore the window config.
1257                   (setq frame (frameset--restore-frame frame-cfg window-cfg
1258                                                        (or filters frameset-filter-alist)
1259                                                        force-onscreen))
1260                   ;; Now reset any duplicate frameset--id
1261                   (when (and duplicate (not (eq frame duplicate)))
1262                     (set-frame-parameter duplicate 'frameset--id nil))
1263                   ;; Set default-minibuffer if required.
1264                   (when default (setq default-minibuffer-frame frame))))
1265             (error
1266              (delay-warning 'frameset (error-message-string err) :error))))))
1267
1268     ;; Setting the parent frame after the frame has been created is a
1269     ;; pain because one can see the frame move on the screen.  Ideally,
1270     ;; we would restore minibuffer equipped child frames after their
1271     ;; respective parents have been made but this might interfere with
1272     ;; the reordering of minibuffer frames.  Left to the experts ...
1273     (dolist (frame (frame-list))
1274       (let* ((frame-id (frame-parameter frame 'frameset--parent-frame))
1275              (parent-frame
1276               (and frame-id (frameset-frame-with-id frame-id))))
1277         (when (and (not (eq (frame-parameter frame 'parent-frame) parent-frame))
1278                    (frame-live-p parent-frame))
1279           (set-frame-parameter frame 'parent-frame parent-frame)))
1280       (let* ((frame-id (frame-parameter frame 'frameset--delete-before))
1281              (delete-before
1282               (and frame-id (frameset-frame-with-id frame-id))))
1283         (when (frame-live-p delete-before)
1284           (set-frame-parameter frame 'delete-before delete-before)))
1285       (let* ((frame-id (frame-parameter frame 'frameset--mouse-wheel-frame))
1286              (mouse-wheel-frame
1287               (and frame-id (frameset-frame-with-id frame-id))))
1288         (when (frame-live-p mouse-wheel-frame)
1289           (set-frame-parameter frame 'mouse-wheel-frame mouse-wheel-frame))))
1290
1291     ;; In case we try to delete the initial frame, we want to make sure that
1292     ;; other frames are already visible (discussed in thread for bug#14841).
1293     (sit-for 0 t)
1294
1295     ;; Clean up the frame list
1296     (when cleanup-frames
1297       (let ((map nil)
1298             (cleanup (if (eq cleanup-frames t)
1299                          (lambda (frame action)
1300                            (when (memq action '(:rejected :ignored))
1301                              (delete-frame frame)))
1302                        cleanup-frames)))
1303         (maphash (lambda (frame _action) (push frame map)) frameset--action-map)
1304         (dolist (frame (sort map
1305                              ;; Minibufferless frames must go first to avoid
1306                              ;; errors when attempting to delete a frame whose
1307                              ;; minibuffer window is used by another frame.
1308                              #'frameset-minibufferless-first-p))
1309           (condition-case-unless-debug err
1310               (funcall cleanup frame (gethash frame frameset--action-map))
1311             (error
1312              (delay-warning 'frameset (error-message-string err) :warning))))))
1313
1314     ;; Make sure there's at least one visible frame.
1315     (unless (or (daemonp)
1316                 (catch 'visible
1317                   (maphash (lambda (frame _)
1318                              (and (frame-live-p frame) (frame-visible-p frame)
1319                                   (throw 'visible t)))
1320                            frameset--action-map)))
1321       (make-frame-visible (selected-frame)))))
1322
1323 \f
1324 ;; Register support
1325
1326 ;;;###autoload
1327 (defun frameset--jump-to-register (data)
1328   "Restore frameset from DATA stored in register.
1329 Called from `jump-to-register'.  Internal use only."
1330   (frameset-restore
1331    (aref data 0)
1332    :filters frameset-session-filter-alist
1333    :reuse-frames (if current-prefix-arg t 'match)
1334    :cleanup-frames (if current-prefix-arg
1335                        ;; delete frames
1336                        nil
1337                      ;; iconify frames
1338                      (lambda (frame action)
1339                        (pcase action
1340                          (`rejected (iconify-frame frame))
1341                          ;; In the unexpected case that a frame was a candidate
1342                          ;; (matching frame id) and yet not restored, remove it
1343                          ;; because it is in fact a duplicate.
1344                          (`ignored (delete-frame frame))))))
1345
1346   ;; Restore selected frame, buffer and point.
1347   (let ((frame (frameset-frame-with-id (aref data 1)))
1348         buffer window)
1349     (when frame
1350       (select-frame-set-input-focus frame)
1351       (when (and (buffer-live-p (setq buffer (marker-buffer (aref data 2))))
1352                  (window-live-p (setq window (get-buffer-window buffer frame))))
1353         (set-frame-selected-window frame window)
1354         (with-current-buffer buffer (goto-char (aref data 2)))))))
1355
1356 ;;;###autoload
1357 (defun frameset--print-register (data)
1358   "Print basic info about frameset stored in DATA.
1359 Called from `list-registers' and `view-register'.  Internal use only."
1360   (let* ((fs (aref data 0))
1361          (ns (length (frameset-states fs))))
1362     (princ (format "a frameset (%d frame%s, saved on %s)."
1363                    ns
1364                    (if (= 1 ns) "" "s")
1365                    (format-time-string "%c" (frameset-timestamp fs))))))
1366
1367 ;;;###autoload
1368 (defun frameset-to-register (register)
1369   "Store the current frameset in register REGISTER.
1370 Use \\[jump-to-register] to restore the frameset.
1371 Argument is a character, naming the register.
1372
1373 Interactively, reads the register using `register-read-with-preview'."
1374   (interactive (list (register-read-with-preview "Frameset to register: ")))
1375   (set-register register
1376                 (registerv-make
1377                  (vector (frameset-save nil
1378                                         :app 'register
1379                                         :filters frameset-session-filter-alist)
1380                          ;; frameset-save does not include the value of point
1381                          ;; in the current buffer, so record that separately.
1382                          (frameset-frame-id nil)
1383                          (point-marker))
1384                  :print-func #'frameset--print-register
1385                  :jump-func #'frameset--jump-to-register)))
1386
1387 (provide 'frameset)
1388
1389 ;;; frameset.el ends here