lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl)
  29   ;; Warning suppression -- can't require x-win in batch:
  30   (autoload 'xw-defined-colors "x-win"))
  31
  32 (require 'cus-face)
  33
  34 \f
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36 ;;; Font selection.
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38
  39 (defgroup font-selection nil
  40   "Influencing face font selection."
  41   :group 'faces)
  42
  43
  44 (defcustom face-font-selection-order
  45   '(:width :height :weight :slant)
  46   "*A list specifying how face font selection chooses fonts.
  47 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  48 must appear once in the list, and the list must not contain any other
  49 elements.  Font selection tries to find a best matching font for
  50 those face attributes first that appear first in the list.  For
  51 example, if `:slant' appears before `:height', font selection first
  52 tries to find a font with a suitable slant, even if this results in
  53 a font height that isn't optimal."
  54   :tag "Font selection order."
  55   :type '(list symbol symbol symbol symbol)
  56   :group 'font-selection
  57   :set #'(lambda (symbol value)
  58            (set-default symbol value)
  59            (internal-set-font-selection-order value)))
  60
  61
  62 ;; This is defined originally in xfaces.c.
  63 (defcustom face-font-family-alternatives
  64   '(("courier" "fixed")
  65     ("helv" "helvetica" "arial" "fixed"))
  66   "*Alist of alternative font family names.
  67 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  68 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  69 ALTERNATIVE2 etc."
  70   :tag "Alternative font families to try."
  71   :type '(repeat (repeat string))
  72   :group 'font-selection
  73   :set #'(lambda (symbol value)
  74            (set-default symbol value)
  75            (internal-set-alternative-font-family-alist value)))
  76
  77
  78 ;; This is defined originally in xfaces.c.
  79 (defcustom face-font-registry-alternatives
  80   '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  81     ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  82     ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  83     ("muletibetan-2" "muletibetan-0"))
  84   "*Alist of alternative font registry names.
  85 Each element has the the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  86 If fonts of registry REGISTRY can be loaded, font selection
  87 tries to find a best matching font among all fonts of registry
  88 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  89   :tag "Alternative font registries to try."
  90   :type '(repeat (repeat string))
  91   :version "21.1"
  92   :group 'font-selection
  93   :set #'(lambda (symbol value)
  94            (set-default symbol value)
  95            (internal-set-alternative-font-registry-alist value)))
  96
  97
  98 \f
  99 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 100 ;;; Creation, copying.
 101 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 102
 103
 104 (defun face-list ()
 105   "Return a list of all defined face names."
 106   (mapcar #'car face-new-frame-defaults))
 107
 108
 109 ;;; ### If not frame-local initialize by what X resources?
 110
 111 (defun make-face (face &optional no-init-from-resources)
 112   "Define a new face with name FACE, a symbol.
 113 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 114 variants of FACE from X resources.  (X resources recognized are found
 115 in the global variable `face-x-resources'.)  If FACE is already known
 116 as a face, leave it unmodified.  Value is FACE."
 117   (interactive "SMake face: ")
 118   (unless (facep face)
 119     ;; Make frame-local faces (this also makes the global one).
 120     (dolist (frame (frame-list))
 121       (internal-make-lisp-face face frame))
 122     ;; Add the face to the face menu.
 123     (when (fboundp 'facemenu-add-new-face)
 124       (facemenu-add-new-face face))
 125     ;; Define frame-local faces for all frames from X resources.
 126     (unless no-init-from-resources
 127       (make-face-x-resource-internal face)))
 128   face)
 129
 130
 131 (defun make-empty-face (face)
 132   "Define a new, empty face with name FACE.
 133 If the face already exists, it is left unmodified.  Value is FACE."
 134   (interactive "SMake empty face: ")
 135   (make-face face 'no-init-from-resources))
 136
 137
 138 (defun copy-face (old-face new-face &optional frame new-frame)
 139   "Define a face just like OLD-FACE, with name NEW-FACE.
 140
 141 If NEW-FACE already exists as a face, it is modified to be like
 142 OLD-FACE.  If it doesn't already exist, it is created.
 143
 144 If the optional argument FRAME is given as a frame,  NEW-FACE is
 145 changed on FRAME only.
 146 If FRAME is t, the frame-independent default specification for OLD-FACE
 147 is copied to NEW-FACE.
 148 If FRAME is nil, copying is done for the frame-independent defaults
 149 and for each existing frame.
 150
 151 If the optional fourth argument NEW-FRAME is given,
 152 copy the information from face OLD-FACE on frame FRAME
 153 to NEW-FACE on frame NEW-FRAME."
 154   (let ((inhibit-quit t))
 155     (if (null frame)
 156         (progn
 157           (dolist (frame (frame-list))
 158             (copy-face old-face new-face frame))
 159           (copy-face old-face new-face t))
 160       (internal-copy-lisp-face old-face new-face frame new-frame))
 161     new-face))
 162
 163
 164 \f
 165 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 166 ;;; Obsolete functions
 167 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 168
 169 ;; The functions in this section are defined because Lisp packages use
 170 ;; them, despite the prefix `internal-' suggesting that they are
 171 ;; private to the face implementation.
 172
 173 (defun internal-find-face (name &optional frame)
 174   "Retrieve the face named NAME.
 175 Return nil if there is no such face.
 176 If the optional argument FRAME is given, this gets the face NAME for
 177 that frame; otherwise, it uses the selected frame.
 178 If FRAME is the symbol t, then the global, non-frame face is returned.
 179 If NAME is already a face, it is simply returned.
 180
 181 This function is defined for compatibility with Emacs 20.2.  It
 182 should not be used anymore."
 183   (facep name))
 184 (make-obsolete 'internal-find-face 'facep "21.1")
 185
 186
 187 (defun internal-get-face (name &optional frame)
 188   "Retrieve the face named NAME; error if there is none.
 189 If the optional argument FRAME is given, this gets the face NAME for
 190 that frame; otherwise, it uses the selected frame.
 191 If FRAME is the symbol t, then the global, non-frame face is returned.
 192 If NAME is already a face, it is simply returned.
 193
 194 This function is defined for compatibility with Emacs 20.2.  It
 195 should not be used anymore."
 196   (or (internal-find-face name frame)
 197       (check-face name)))
 198 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 199
 200 \f
 201 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 202 ;;; Predicates, type checks.
 203 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 204
 205 (defun facep (face)
 206   "Return non-nil if FACE is a face name."
 207   (internal-lisp-face-p face))
 208
 209
 210 (defun check-face (face)
 211   "Signal an error if FACE doesn't name a face.
 212 Value is FACE."
 213   (unless (facep face)
 214     (error "Not a face: %s" face))
 215   face)
 216
 217
 218 ;; The ID returned is not to be confused with the internally used IDs
 219 ;; of realized faces.  The ID assigned to Lisp faces is used to
 220 ;; support faces in display table entries.
 221
 222 (defun face-id (face &optional frame)
 223   "Return the interNal ID of face with name FACE.
 224 If optional argument FRAME is nil or omitted, use the selected frame."
 225   (check-face face)
 226   (get face 'face))
 227
 228
 229 (defun face-equal (face1 face2 &optional frame)
 230   "Non-nil if faces FACE1 and FACE2 are equal.
 231 Faces are considered equal if all their attributes are equal.
 232 If the optional argument FRAME is given, report on face FACE in that frame.
 233 If FRAME is t, report on the defaults for face FACE (for new frames).
 234 If FRAME is omitted or nil, use the selected frame."
 235   (internal-lisp-face-equal-p face1 face2 frame))
 236
 237
 238 (defun face-differs-from-default-p (face &optional frame)
 239   "Non-nil if FACE displays differently from the default face.
 240 If the optional argument FRAME is given, report on face FACE in that frame.
 241 If FRAME is t, report on the defaults for face FACE (for new frames).
 242 If FRAME is omitted or nil, use the selected frame.
 243 A face is considered to be ``the same'' as the default face if it is
 244 actually specified in the same way (equal attributes) or if it is
 245 fully-unspecified, and thus inherits the attributes of any face it
 246 is displayed on top of."
 247   (cond ((eq frame t) (setq frame nil))
 248         ((null frame) (setq frame (selected-frame))))
 249   (let* ((v1 (internal-lisp-face-p face frame))
 250          (n (if v1 (length v1) 0))
 251          (v2 (internal-lisp-face-p 'default frame))
 252          (i 1))
 253     (unless v1
 254       (error "Not a face: %S" face))
 255     (while (and (< i n)
 256                 (or (eq 'unspecified (aref v1 i))
 257                     (equal (aref v1 i) (aref v2 i))))
 258       (setq i (1+ i)))
 259     (< i n)))
 260
 261
 262 (defun face-nontrivial-p (face &optional frame)
 263   "True if face FACE has some non-nil attribute.
 264 If the optional argument FRAME is given, report on face FACE in that frame.
 265 If FRAME is t, report on the defaults for face FACE (for new frames).
 266 If FRAME is omitted or nil, use the selected frame."
 267   (not (internal-lisp-face-empty-p face frame)))
 268
 269
 270 \f
 271 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 272 ;;; Setting face attributes from X resources.
 273 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 274
 275 (defcustom face-x-resources
 276   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 277     (:width (".attributeWidth" . "Face.AttributeWidth"))
 278     (:height (".attributeHeight" . "Face.AttributeHeight"))
 279     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 280     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 281     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 282     (:background (".attributeBackground" . "Face.AttributeBackground"))
 283     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 284     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 285     (:box (".attributeBox" . "Face.AttributeBox"))
 286     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 287     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 288     (:stipple
 289      (".attributeStipple" . "Face.AttributeStipple")
 290      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 291     (:bold (".attributeBold" . "Face.AttributeBold"))
 292     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 293     (:font (".attributeFont" . "Face.AttributeFont"))
 294     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 295   "*List of X resources and classes for face attributes.
 296 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 297 the name of a face attribute, and each ENTRY is a cons of the form
 298 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 299 X resource class for the attribute."
 300   :type '(repeat (cons symbol (repeat (cons string string))))
 301   :group 'faces)
 302
 303
 304 (defun set-face-attribute-from-resource (face attribute resource class frame)
 305   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 306 Value is the attribute value specified by the resource, or nil
 307 if not present.  This function displays a message if the resource
 308 specifies an invalid attribute."
 309   (let* ((face-name (face-name face))
 310          (value (internal-face-x-get-resource (concat face-name resource)
 311                                               class frame)))
 312     (when value
 313       (condition-case ()
 314           (internal-set-lisp-face-attribute-from-resource
 315            face attribute (downcase value) frame)
 316         (error
 317          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 318                   face-name frame attribute value))))
 319     value))
 320
 321
 322 (defun set-face-attributes-from-resources (face frame)
 323   "Set attributes of FACE from X resources for FRAME."
 324   (when (memq (framep frame) '(x w32 mac))
 325     (dolist (definition face-x-resources)
 326       (let ((attribute (car definition)))
 327         (dolist (entry (cdr definition))
 328           (set-face-attribute-from-resource face attribute (car entry)
 329                                             (cdr entry) frame))))))
 330
 331
 332 (defun make-face-x-resource-internal (face &optional frame)
 333   "Fill frame-local FACE on FRAME from X resources.
 334 FRAME nil or not specified means do it for all frames."
 335   (if (null frame)
 336       (dolist (frame (frame-list))
 337         (set-face-attributes-from-resources face frame))
 338     (set-face-attributes-from-resources face frame)))
 339
 340
 341 \f
 342 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 343 ;;; Retrieving face attributes.
 344 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 345
 346 (defun face-name (face)
 347   "Return the name of face FACE."
 348   (symbol-name (check-face face)))
 349
 350
 351 (defun face-attribute (face attribute &optional frame)
 352   "Return the value of FACE's ATTRIBUTE on FRAME.
 353 If the optional argument FRAME is given, report on face FACE in that frame.
 354 If FRAME is t, report on the defaults for face FACE (for new frames).
 355 If FRAME is omitted or nil, use the selected frame."
 356   (internal-get-lisp-face-attribute face attribute frame))
 357
 358
 359 (defun face-foreground (face &optional frame)
 360   "Return the foreground color name of FACE, or nil if unspecified.
 361 If the optional argument FRAME is given, report on face FACE in that frame.
 362 If FRAME is t, report on the defaults for face FACE (for new frames).
 363 If FRAME is omitted or nil, use the selected frame."
 364   (let ((value (internal-get-lisp-face-attribute face :foreground frame)))
 365     (if (eq value 'unspecified)
 366         nil
 367       value)))
 368
 369
 370 (defun face-background (face &optional frame)
 371   "Return the background color name of FACE, or nil if unspecified.
 372 If the optional argument FRAME is given, report on face FACE in that frame.
 373 If FRAME is t, report on the defaults for face FACE (for new frames).
 374 If FRAME is omitted or nil, use the selected frame."
 375   (let ((value (internal-get-lisp-face-attribute face :background frame)))
 376     (if (eq value 'unspecified)
 377         nil
 378       value)))
 379
 380
 381 (defun face-stipple (face &optional frame)
 382  "Return the stipple pixmap name of FACE, or nil if unspecified.
 383 If the optional argument FRAME is given, report on face FACE in that frame.
 384 If FRAME is t, report on the defaults for face FACE (for new frames).
 385 If FRAME is omitted or nil, use the selected frame."
 386   (let ((value (internal-get-lisp-face-attribute face :stipple frame)))
 387     (if (eq value 'unspecified)
 388         nil
 389       value)))
 390
 391
 392 (defalias 'face-background-pixmap 'face-stipple)
 393
 394
 395 (defun face-underline-p (face &optional frame)
 396  "Return non-nil if FACE is underlined.
 397 If the optional argument FRAME is given, report on face FACE in that frame.
 398 If FRAME is t, report on the defaults for face FACE (for new frames).
 399 If FRAME is omitted or nil, use the selected frame."
 400  (eq (face-attribute face :underline frame) t))
 401
 402
 403 (defun face-inverse-video-p (face &optional frame)
 404  "Return non-nil if FACE is in inverse video on FRAME.
 405 If the optional argument FRAME is given, report on face FACE in that frame.
 406 If FRAME is t, report on the defaults for face FACE (for new frames).
 407 If FRAME is omitted or nil, use the selected frame."
 408  (eq (face-attribute face :inverse-video frame) t))
 409
 410
 411 (defun face-bold-p (face &optional frame)
 412   "Return non-nil if the font of FACE is bold on FRAME.
 413 If the optional argument FRAME is given, report on face FACE in that frame.
 414 If FRAME is t, report on the defaults for face FACE (for new frames).
 415 If FRAME is omitted or nil, use the selected frame.
 416 Use `face-attribute' for finer control."
 417   (let ((bold (face-attribute face :weight frame)))
 418     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 419
 420
 421 (defun face-italic-p (face &optional frame)
 422   "Return non-nil if the font of FACE is italic on FRAME.
 423 If the optional argument FRAME is given, report on face FACE in that frame.
 424 If FRAME is t, report on the defaults for face FACE (for new frames).
 425 If FRAME is omitted or nil, use the selected frame.
 426 Use `face-attribute' for finer control."
 427   (let ((italic (face-attribute face :slant frame)))
 428     (memq italic '(italic oblique))))
 429
 430
 431 \f
 432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 433 ;;; Face documentation.
 434 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 435
 436 (defun face-documentation (face)
 437   "Get the documentation string for FACE."
 438   (get face 'face-documentation))
 439
 440
 441 (defun set-face-documentation (face string)
 442   "Set the documentation string for FACE to STRING."
 443   ;; Perhaps the text should go in DOC.
 444   (put face 'face-documentation (purecopy string)))
 445
 446
 447 (defalias 'face-doc-string 'face-documentation)
 448 (defalias 'set-face-doc-string 'set-face-documentation)
 449
 450
 451 \f
 452 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 453 ;; Setting face attributes.
 454 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 455
 456
 457 (defun set-face-attribute (face frame &rest args)
 458   "Set attributes of FACE on FRAME from ARGS.
 459
 460 FRAME nil means change attributes on all frames.  FRAME t means change
 461 the default for new frames (this is done automatically each time an
 462 attribute is changed on all frames).
 463
 464 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 465 face attribute name.  All attributes can be set to `unspecified';
 466 this fact is not further mentioned below.
 467
 468 The following attributes are recognized:
 469
 470 `:family'
 471
 472 VALUE must be a string specifying the font family, e.g. ``courier'',
 473 or a fontset alias name.  If a font family is specified, wild-cards `*'
 474 and `?' are allowed.
 475
 476 `:width'
 477
 478 VALUE specifies the relative proportionate width of the font to use.
 479 It must be one of the symbols `ultra-condensed', `extra-condensed',
 480 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 481 `extra-expanded', or `ultra-expanded'.
 482
 483 `:height'
 484
 485 VALUE must be either an integer specifying the height of the font to use
 486 in 1/10 pt, a floating point number specifying the amount by which to
 487 scale any underlying face, or a function, which is called with the old
 488 height (from the underlying face), and should return the new height.
 489
 490 `:weight'
 491
 492 VALUE specifies the weight of the font to use.  It must be one of the
 493 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 494 `semi-light', `light', `extra-light', `ultra-light'.
 495
 496 `:slant'
 497
 498 VALUE specifies the slant of the font to use.  It must be one of the
 499 symbols `italic', `oblique', `normal', `reverse-italic', or
 500 `reverse-oblique'.
 501
 502 `:foreground', `:background'
 503
 504 VALUE must be a color name, a string.
 505
 506 `:underline'
 507
 508 VALUE specifies whether characters in FACE should be underlined.  If
 509 VALUE is t, underline with foreground color of the face.  If VALUE is
 510 a string, underline with that color.  If VALUE is nil, explicitly
 511 don't underline.
 512
 513 `:overline'
 514
 515 VALUE specifies whether characters in FACE should be overlined.  If
 516 VALUE is t, overline with foreground color of the face.  If VALUE is a
 517 string, overline with that color.  If VALUE is nil, explicitly don't
 518 overline.
 519
 520 `:strike-through'
 521
 522 VALUE specifies whether characters in FACE should be drawn with a line
 523 striking through them.  If VALUE is t, use the foreground color of the
 524 face.  If VALUE is a string, strike-through with that color.  If VALUE
 525 is nil, explicitly don't strike through.
 526
 527 `:box'
 528
 529 VALUE specifies whether characters in FACE should have a box drawn
 530 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 531 VALUE is t, draw a box with lines of width 1 in the foreground color
 532 of the face.  If VALUE is a string, the string must be a color name,
 533 and the box is drawn in that color with a line width of 1.  Otherwise,
 534 VALUE must be a property list of the form `(:line-width WIDTH
 535 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 536 the property list, a default value will be used for the value, as
 537 specified below.  WIDTH specifies the width of the lines to draw; it
 538 defaults to 1.  If WIDTH is negative, the absolute value is the width
 539 of the lines, and draw top/bottom lines inside the characters area,
 540 not around it.  COLOR is the name of the color to draw in, default is
 541 the foreground color of the face for simple boxes, and the background
 542 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 543 should be draw.  If STYLE is `released-button', draw a box looking
 544 like a released 3D button.  If STYLE is `pressed-button' draw a box
 545 that appears like a pressed button.  If STYLE is nil, the default if
 546 the property list doesn't contain a style specification, draw a 2D
 547 box.
 548
 549 `:inverse-video'
 550
 551 VALUE specifies whether characters in FACE should be displayed in
 552 inverse video.  VALUE must be one of t or nil.
 553
 554 `:stipple'
 555
 556 If VALUE is a string, it must be the name of a file of pixmap data.
 557 The directories listed in the `x-bitmap-file-path' variable are
 558 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 559 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 560 is a string containing the raw bits of the bitmap.  VALUE nil means
 561 explicitly don't use a stipple pattern.
 562
 563 For convenience, attributes `:family', `:width', `:height', `:weight',
 564 and `:slant' may also be set in one step from an X font name:
 565
 566 `:font'
 567
 568 Set font-related face attributes from VALUE.  VALUE must be a valid
 569 XLFD font name.  If it is a font name pattern, the first matching font
 570 will be used.
 571
 572 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 573 be used to specify that a bold or italic font should be used.  VALUE
 574 must be t or nil in that case.  A value of `unspecified' is not allowed.
 575
 576 `:inherit'
 577
 578 VALUE is the name of a face from which to inherit attributes, or a list
 579 of face names.  Attributes from inherited faces are merged into the face
 580 like an underlying face would be, with higher priority than underlying faces."
 581   (let ((where (if (null frame) 0 frame)))
 582     (setq args (purecopy args))
 583     (while args
 584       (internal-set-lisp-face-attribute face (car args)
 585                                         (purecopy (cadr args))
 586                                         where)
 587       (setq args (cdr (cdr args))))))
 588
 589
 590 (defun make-face-bold (face &optional frame noerror)
 591   "Make the font of FACE be bold, if possible.
 592 FRAME nil or not specified means change face on all frames.
 593 Argument NOERROR is ignored and retained for compatibility.
 594 Use `set-face-attribute' for finer control of the font weight."
 595   (interactive (list (read-face-name "Make which face bold ")))
 596   (set-face-attribute face frame :weight 'bold))
 597
 598
 599 (defun make-face-unbold (face &optional frame noerror)
 600   "Make the font of FACE be non-bold, if possible.
 601 FRAME nil or not specified means change face on all frames.
 602 Argument NOERROR is ignored and retained for compatibility."
 603   (interactive (list (read-face-name "Make which face non-bold ")))
 604   (set-face-attribute face frame :weight 'normal))
 605
 606
 607 (defun make-face-italic (face &optional frame noerror)
 608   "Make the font of FACE be italic, if possible.
 609 FRAME nil or not specified means change face on all frames.
 610 Argument NOERROR is ignored and retained for compatibility.
 611 Use `set-face-attribute' for finer control of the font slant."
 612   (interactive (list (read-face-name "Make which face italic ")))
 613   (set-face-attribute face frame :slant 'italic))
 614
 615
 616 (defun make-face-unitalic (face &optional frame noerror)
 617   "Make the font of FACE be non-italic, if possible.
 618 FRAME nil or not specified means change face on all frames.
 619 Argument NOERROR is ignored and retained for compatibility."
 620   (interactive (list (read-face-name "Make which face non-italic ")))
 621   (set-face-attribute face frame :slant 'normal))
 622
 623
 624 (defun make-face-bold-italic (face &optional frame noerror)
 625   "Make the font of FACE be bold and italic, if possible.
 626 FRAME nil or not specified means change face on all frames.
 627 Argument NOERROR is ignored and retained for compatibility.
 628 Use `set-face-attribute' for finer control of font weight and slant."
 629   (interactive (list (read-face-name "Make which face bold-italic: ")))
 630   (set-face-attribute face frame :weight 'bold :slant 'italic))
 631
 632
 633 (defun set-face-font (face font &optional frame)
 634   "Change font-related attributes of FACE to those of FONT (a string).
 635 FRAME nil or not specified means change face on all frames.
 636 This sets the attributes `:family', `:width', `:height', `:weight',
 637 and `:slant'.  When called interactively, prompt for the face and font."
 638   (interactive (read-face-and-attribute :font))
 639   (set-face-attribute face frame :font font))
 640
 641
 642 ;; Implementation note: Emulating gray background colors with a
 643 ;; stipple pattern is now part of the face realization process, and is
 644 ;; done in C depending on the frame on which the face is realized.
 645
 646 (defun set-face-background (face color &optional frame)
 647   "Change the background color of face FACE to COLOR (a string).
 648 FRAME nil or not specified means change face on all frames.
 649 When called interactively, prompt for the face and color."
 650   (interactive (read-face-and-attribute :background))
 651   (set-face-attribute face frame :background (or color 'unspecified)))
 652
 653
 654 (defun set-face-foreground (face color &optional frame)
 655   "Change the foreground color of face FACE to COLOR (a string).
 656 FRAME nil or not specified means change face on all frames.
 657 When called interactively, prompt for the face and color."
 658   (interactive (read-face-and-attribute :foreground))
 659   (set-face-attribute face frame :foreground (or color 'unspecified)))
 660
 661
 662 (defun set-face-stipple (face stipple &optional frame)
 663   "Change the stipple pixmap of face FACE to STIPPLE.
 664 FRAME nil or not specified means change face on all frames.
 665 STIPPLE should be a string, the name of a file of pixmap data.
 666 The directories listed in the `x-bitmap-file-path' variable are searched.
 667
 668 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 669 where WIDTH and HEIGHT are the size in pixels,
 670 and DATA is a string, containing the raw bits of the bitmap."
 671   (interactive (read-face-and-attribute :stipple))
 672   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 673
 674
 675 (defun set-face-underline (face underline &optional frame)
 676   "Specify whether face FACE is underlined.
 677 UNDERLINE nil means FACE explicitly doesn't underline.
 678 UNDERLINE non-nil means FACE explicitly does underlining
 679 with the same of the foreground color.
 680 If UNDERLINE is a string, underline with the color named UNDERLINE.
 681 FRAME nil or not specified means change face on all frames.
 682 Use `set-face-attribute' to ``unspecify'' underlining."
 683   (interactive
 684    (let ((list (read-face-and-attribute :underline)))
 685      (list (car list) (eq (car (cdr list)) t))))
 686   (set-face-attribute face frame :underline underline))
 687
 688
 689 (defun set-face-underline-p (face underline-p &optional frame)
 690   "Specify whether face FACE is underlined.
 691 UNDERLINE-P nil means FACE explicitly doesn't underline.
 692 UNDERLINE-P non-nil means FACE explicitly does underlining.
 693 FRAME nil or not specified means change face on all frames.
 694 Use `set-face-attribute' to ``unspecify'' underlining."
 695   (interactive
 696    (let ((list (read-face-and-attribute :underline)))
 697      (list (car list) (eq (car (cdr list)) t))))
 698   (set-face-attribute face frame :underline underline-p))
 699
 700
 701 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 702   "Specify whether face FACE is in inverse video.
 703 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 704 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 705 FRAME nil or not specified means change face on all frames.
 706 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 707   (interactive
 708    (let ((list (read-face-and-attribute :inverse-video)))
 709      (list (car list) (eq (car (cdr list)) t))))
 710   (set-face-attribute face frame :inverse-video inverse-video-p))
 711
 712
 713 (defun set-face-bold-p (face bold-p &optional frame)
 714   "Specify whether face FACE is bold.
 715 BOLD-P non-nil means FACE should explicitly display bold.
 716 BOLD-P nil means FACE should explicitly display non-bold.
 717 FRAME nil or not specified means change face on all frames.
 718 Use `set-face-attribute' or `modify-face' for finer control."
 719   (if (null bold-p)
 720       (make-face-unbold face frame)
 721     (make-face-bold face frame)))
 722
 723
 724 (defun set-face-italic-p (face italic-p &optional frame)
 725   "Specify whether face FACE is italic.
 726 ITALIC-P non-nil means FACE should explicitly display italic.
 727 ITALIC-P nil means FACE should explicitly display non-italic.
 728 FRAME nil or not specified means change face on all frames.
 729 Use `set-face-attribute' or `modify-face' for finer control."
 730   (if (null italic-p)
 731       (make-face-unitalic face frame)
 732     (make-face-italic face frame)))
 733
 734
 735 (defalias 'set-face-background-pixmap 'set-face-stipple)
 736
 737
 738 (defun invert-face (face &optional frame)
 739   "Swap the foreground and background colors of FACE.
 740 FRAME nil or not specified means change face on all frames.
 741 If FACE specifies neither foreground nor background color,
 742 set its foreground and background to the background and foreground
 743 of the default face.  Value is FACE."
 744   (interactive (list (read-face-name "Invert face ")))
 745   (let ((fg (face-attribute face :foreground frame))
 746         (bg (face-attribute face :background frame)))
 747     (if (or fg bg)
 748         (set-face-attribute face frame :foreground bg :background fg)
 749       (set-face-attribute face frame
 750                           :foreground
 751                           (face-attribute 'default :background frame)
 752                           :background
 753                           (face-attribute 'default :foreground frame))))
 754   face)
 755
 756 \f
 757 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 758 ;;; Interactively modifying faces.
 759 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 760
 761 (defun read-face-name (prompt)
 762   "Read and return a face symbol, prompting with PROMPT.
 763 Value is a symbol naming a known face."
 764   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 765                            (face-list)))
 766         (def (thing-at-point 'symbol))
 767         face)
 768     (cond ((assoc def face-list)
 769            (setq prompt (concat prompt " (default " def "): ")))
 770           (t (setq def nil)
 771              (setq prompt (concat prompt ": "))))
 772     (while (equal "" (setq face (completing-read
 773                                  prompt face-list nil t nil nil def))))
 774     (intern face)))
 775
 776
 777 (defun face-valid-attribute-values (attribute &optional frame)
 778   "Return valid values for face attribute ATTRIBUTE.
 779 The optional argument FRAME is used to determine available fonts
 780 and colors.  If it is nil or not specified, the selected frame is
 781 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 782 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 783 an integer value."
 784   (let (valid)
 785     (setq valid
 786           (case attribute
 787             (:family
 788              (if window-system
 789                  (mapcar #'(lambda (x) (cons (car x) (car x)))
 790                          (x-font-family-list))
 791                ;; Only one font on TTYs.
 792                (list (cons "default" "default"))))
 793             ((:width :weight :slant :inverse-video)
 794              (mapcar #'(lambda (x) (cons (symbol-name x) x))
 795                      (internal-lisp-face-attribute-values attribute)))
 796             ((:underline :overline :strike-through :box)
 797              (if window-system
 798                  (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 799                                 (internal-lisp-face-attribute-values attribute))
 800                         (mapcar #'(lambda (c) (cons c c))
 801                                 (x-defined-colors frame)))
 802                (mapcar #'(lambda (x) (cons (symbol-name x) x))
 803                        (internal-lisp-face-attribute-values attribute))))
 804             ((:foreground :background)
 805              (mapcar #'(lambda (c) (cons c c))
 806                      (defined-colors frame)))
 807             ((:height)
 808              'integerp)
 809             (:stipple
 810              (and (memq window-system '(x w32 mac))
 811                   (mapcar #'list
 812                           (apply #'nconc
 813                                  (mapcar (lambda (dir)
 814                                            (and (file-readable-p dir)
 815                                                 (file-directory-p dir)
 816                                                 (directory-files dir)))
 817                                          x-bitmap-file-path)))))
 818             (:inherit
 819              (cons '("none" . nil)
 820                    (mapcar #'(lambda (c) (cons (symbol-name c) c))
 821                            (face-list))))
 822             (t
 823              (error "Internal error"))))
 824     (if (and (listp valid) (not (memq attribute '(:inherit))))
 825         (nconc (list (cons "unspecified" 'unspecified)) valid)
 826       valid)))
 827
 828
 829
 830 (defvar face-attribute-name-alist
 831   '((:family . "font family")
 832     (:width . "character set width")
 833     (:height . "height in 1/10 pt")
 834     (:weight . "weight")
 835     (:slant . "slant")
 836     (:underline . "underline")
 837     (:overline . "overline")
 838     (:strike-through . "strike-through")
 839     (:box . "box")
 840     (:inverse-video . "inverse-video display")
 841     (:foreground . "foreground color")
 842     (:background . "background color")
 843     (:stipple . "background stipple")
 844     (:inherit . "inheritance"))
 845   "An alist of descriptive names for face attributes.
 846 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 847 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 848 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 849
 850
 851 (defun face-descriptive-attribute-name (attribute)
 852   "Return a descriptive name for ATTRIBUTE."
 853   (cdr (assq attribute face-attribute-name-alist)))
 854
 855
 856 (defun face-read-string (face default name &optional completion-alist)
 857   "Interactively read a face attribute string value.
 858 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 859 default string to return if no new value is entered.  NAME is a
 860 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 861 alist of valid values, if non-nil.
 862
 863 Entering nothing accepts the default string DEFAULT.
 864 Value is the new attribute value."
 865   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 866   ;; each word in a string separately).
 867   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 868   (let* ((completion-ignore-case t)
 869          (value (completing-read
 870                  (if default
 871                      (format "%s for face `%s' (default %s): "
 872                              name face default)
 873                    (format "%s for face `%s': " name face))
 874                  completion-alist)))
 875     (if (equal value "") default value)))
 876
 877
 878 (defun face-read-integer (face default name)
 879   "Interactively read an integer face attribute value.
 880 FACE is the face whose attribute is read.  DEFAULT is the default
 881 value to return if no new value is entered.  NAME is a descriptive
 882 name of the attribute for prompting.  Value is the new attribute value."
 883   (let ((new-value
 884          (face-read-string face
 885                            (format "%s" default)
 886                            name
 887                            (list (cons "unspecified" 'unspecified)))))
 888     (cond ((equal new-value "unspecified")
 889            'unspecified)
 890           ((member new-value '("unspecified-fg" "unspecified-bg"))
 891            new-value)
 892           (t
 893            (string-to-int new-value)))))
 894
 895
 896 (defun read-face-attribute (face attribute &optional frame)
 897   "Interactively read a new value for FACE's ATTRIBUTE.
 898 Optional argument FRAME nil or unspecified means read an attribute value
 899 of a global face.  Value is the new attribute value."
 900   (let* ((old-value (face-attribute face attribute frame))
 901          (attribute-name (face-descriptive-attribute-name attribute))
 902          (valid (face-valid-attribute-values attribute frame))
 903          new-value)
 904     ;; Represent complex attribute values as strings by printing them
 905     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 906     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 907     ;; SHADOW)'.
 908     (when (and (or (eq attribute :stipple)
 909                    (eq attribute :box))
 910                (or (consp old-value)
 911                    (vectorp old-value)))
 912       (setq old-value (prin1-to-string old-value)))
 913     (cond ((listp valid)
 914            (let ((default
 915                    (or (car (rassoc old-value valid))
 916                        (format "%s" old-value))))
 917              (setq new-value
 918                    (face-read-string face default attribute-name valid))
 919              (if (equal new-value default)
 920                  ;; Nothing changed, so don't bother with all the stuff
 921                  ;; below.  In particular, this avoids a non-tty color
 922                  ;; from being canonicalized for a tty when the user
 923                  ;; just uses the default.
 924                  (setq new-value old-value)
 925                ;; Terminal frames can support colors that don't appear
 926                ;; explicitly in VALID, using color approximation code
 927                ;; in tty-colors.el.
 928                (when (and (memq attribute '(:foreground :background))
 929                           (not (memq window-system '(x w32 mac)))
 930                           (not (member new-value
 931                                        '("unspecified"
 932                                          "unspecified-fg" "unspecified-bg"))))
 933                  (setq new-value (car (tty-color-desc new-value frame))))
 934                (when (assoc new-value valid)
 935                  (setq new-value (cdr (assoc new-value valid)))))))
 936           ((eq valid 'integerp)
 937            (setq new-value (face-read-integer face old-value attribute-name)))
 938           (t (error "Internal error")))
 939     ;; Convert stipple and box value text we read back to a list or
 940     ;; vector if it looks like one.  This makes the assumption that a
 941     ;; pixmap file name won't start with an open-paren.
 942     (when (and (or (eq attribute :stipple)
 943                    (eq attribute :box))
 944                (stringp new-value)
 945                (string-match "^[[(]" new-value))
 946       (setq new-value (read new-value)))
 947     new-value))
 948
 949
 950 (defun read-face-font (face &optional frame)
 951   "Read the name of a font for FACE on FRAME.
 952 If optional argument FRAME Is nil or omitted, use the selected frame."
 953   (let ((completion-ignore-case t))
 954     (completing-read (format "Set font attributes of face `%s' from font: " face)
 955                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 956
 957
 958 (defun read-all-face-attributes (face &optional frame)
 959   "Interactively read all attributes for FACE.
 960 If optional argument FRAME Is nil or omitted, use the selected frame.
 961 Value is a property list of attribute names and new values."
 962   (let (result)
 963     (dolist (attribute face-attribute-name-alist result)
 964       (setq result (cons (car attribute)
 965                          (cons (read-face-attribute face (car attribute) frame)
 966                                result))))))
 967
 968
 969 (defun modify-face (&optional face foreground background stipple
 970                               bold-p italic-p underline-p inverse-p frame)
 971   "Modify attributes of faces interactively.
 972 If optional argument FRAME is nil or omitted, modify the face used
 973 for newly created frame, i.e. the global face.
 974 For non-interactive use, `set-face-attribute' is preferred.
 975 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
 976 and the face and its settings are obtained by querying the user."
 977   (interactive)
 978   (if face
 979       (set-face-attribute face frame
 980                           :foreground (or foreground 'unspecified)
 981                           :background (or background 'unspecified)
 982                           :stipple stipple
 983                           :bold bold-p
 984                           :italic italic-p
 985                           :underline underline-p
 986                           :inverse-video inverse-p)
 987     (setq face (read-face-name "Modify face"))
 988     (apply #'set-face-attribute face frame
 989            (read-all-face-attributes face frame))))
 990
 991 (defun read-face-and-attribute (attribute &optional frame)
 992   "Read face name and face attribute value.
 993 ATTRIBUTE is the attribute whose new value is read.
 994 FRAME nil or unspecified means read attribute value of global face.
 995 Value is a list (FACE NEW-VALUE) where FACE is the face read
 996 \(a symbol), and NEW-VALUE is value read."
 997   (cond ((eq attribute :font)
 998          (let* ((prompt "Set font-related attributes of face")
 999                 (face (read-face-name prompt))
1000                 (font (read-face-font face frame)))
1001            (list face font)))
1002         (t
1003          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1004                 (prompt (format "Set %s of face" attribute-name))
1005                 (face (read-face-name prompt))
1006                 (new-value (read-face-attribute face attribute frame)))
1007            (list face new-value)))))
1008
1009
1010 \f
1011 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1012 ;;; Listing faces.
1013 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1014
1015 (defvar list-faces-sample-text
1016   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1017   "*Text string to display as the sample text for `list-faces-display'.")
1018
1019
1020 ;; The name list-faces would be more consistent, but let's avoid a
1021 ;; conflict with Lucid, which uses that name differently.
1022
1023 (defun list-faces-display ()
1024   "List all faces, using the same sample text in each.
1025 The sample text is a string that comes from the variable
1026 `list-faces-sample-text'."
1027   (interactive)
1028   (let ((faces (sort (face-list) #'string-lessp))
1029         (face nil)
1030         (frame (selected-frame))
1031         disp-frame window face-name)
1032     (with-output-to-temp-buffer "*Faces*"
1033       (save-excursion
1034         (set-buffer standard-output)
1035         (setq truncate-lines t)
1036         (insert
1037          (substitute-command-keys
1038           (concat
1039            "Use "
1040            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1041            "\\[help-follow] on a face name to customize it\n"
1042            "or on its sample text for a decription of the face.\n\n")))
1043         (setq help-xref-stack nil)
1044         (while faces
1045           (setq face (car faces))
1046           (setq faces (cdr faces))
1047           (setq face-name (symbol-name face))
1048           (insert (format "%25s " face-name))
1049           ;; Hyperlink to a customization buffer for the face.  Using
1050           ;; the help xref mechanism may not be the best way.
1051           (save-excursion
1052             (save-match-data
1053               (search-backward face-name)
1054               (help-xref-button 0 (lambda (f)
1055                                     (if help-xref-stack
1056                                         (pop help-xref-stack))
1057                                     (customize-face f))
1058                                 face-name
1059                                 "mouse-2: customize this face")))
1060           (let ((beg (point)))
1061             (insert list-faces-sample-text)
1062             ;; Hyperlink to a help buffer for the face.
1063             (save-excursion
1064               (save-match-data
1065                 (search-backward list-faces-sample-text)
1066                 (help-xref-button 0 #'describe-face face
1067                                   "mouse-2: describe this face")))
1068             (insert "\n")
1069             (put-text-property beg (1- (point)) 'face face)
1070             ;; If the sample text has multiple lines, line up all of them.
1071             (goto-char beg)
1072             (forward-line 1)
1073             (while (not (eobp))
1074               (insert "                          ")
1075               (forward-line 1))))
1076         (goto-char (point-min)))
1077       (print-help-return-message))
1078     ;; If the *Faces* buffer appears in a different frame,
1079     ;; copy all the face definitions from FRAME,
1080     ;; so that the display will reflect the frame that was selected.
1081     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1082     (setq disp-frame (if window (window-frame window)
1083                        (car (frame-list))))
1084     (or (eq frame disp-frame)
1085         (let ((faces (face-list)))
1086           (while faces
1087             (copy-face (car faces) (car faces) frame disp-frame)
1088             (setq faces (cdr faces)))))))
1089
1090
1091 (defun describe-face (face &optional frame)
1092   "Display the properties of face FACE on FRAME.
1093 If the optional argument FRAME is given, report on face FACE in that frame.
1094 If FRAME is t, report on the defaults for face FACE (for new frames).
1095 If FRAME is omitted or nil, use the selected frame."
1096   (interactive (list (read-face-name "Describe face")))
1097   (let* ((attrs '((:family . "Family")
1098                   (:width . "Width")
1099                   (:height . "Height")
1100                   (:weight . "Weight")
1101                   (:slant . "Slant")
1102                   (:foreground . "Foreground")
1103                   (:background . "Background")
1104                   (:underline . "Underline")
1105                   (:overline . "Overline")
1106                   (:strike-through . "Strike-through")
1107                   (:box . "Box")
1108                   (:inverse-video . "Inverse")
1109                   (:stipple . "Stipple")
1110                   (:font . "Font or fontset")
1111                   (:inherit . "Inherit")))
1112         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1113                                         attrs))))
1114     (with-output-to-temp-buffer "*Help*"
1115       (save-excursion
1116         (set-buffer standard-output)
1117         (dolist (a attrs)
1118           (let ((attr (face-attribute face (car a) frame)))
1119             (insert (make-string (- max-width (length (cdr a))) ?\ )
1120                     (cdr a) ": " (format "%s" attr) "\n")))
1121         (insert "\nDocumentation:\n\n"
1122                 (or (face-documentation face)
1123                     "not documented as a face."))
1124         (let ((customize-label "customize"))
1125           (terpri)
1126           (terpri)
1127           (princ (concat "You can " customize-label " this face."))
1128           (with-current-buffer "*Help*"
1129             (save-excursion
1130               (re-search-backward
1131                (concat "\\(" customize-label "\\)") nil t)
1132               (help-xref-button 1 #'customize-face face
1133                                 "mouse-2, RET: customize face")))))
1134       (print-help-return-message)
1135       (with-current-buffer "*Help*"
1136         (help-setup-xref (list #'describe-face face) (interactive-p))
1137         (buffer-string)))))
1138 \f
1139 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1140 ;;; Face specifications (defface).
1141 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1142
1143 ;; Parameter FRAME Is kept for call compatibility to with previous
1144 ;; face implementation.
1145
1146 (defun face-attr-construct (face &optional frame)
1147   "Return a defface-style attribute list for FACE on FRAME.
1148 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1149 face attributes of FACE where ATTRIBUTE is the attribute name and
1150 VALUE is the specified value of that attribute."
1151   (let (result)
1152     (dolist (entry face-attribute-name-alist result)
1153       (let* ((attribute (car entry))
1154              (value (face-attribute face attribute)))
1155         (unless (eq value 'unspecified)
1156           (setq result (nconc (list attribute value) result)))))))
1157
1158
1159 (defun face-spec-set-match-display (display frame)
1160   "Non-nil if DISPLAY matches FRAME.
1161 DISPLAY is part of a spec such as can be used in `defface'.
1162 If FRAME is nil, the current FRAME is used."
1163   (let* ((conjuncts display)
1164          conjunct req options
1165          ;; t means we have succeeded against all the conjuncts in
1166          ;; DISPLAY that have been tested so far.
1167          (match t))
1168     (if (eq conjuncts t)
1169         (setq conjuncts nil))
1170     (while (and conjuncts match)
1171       (setq conjunct (car conjuncts)
1172             conjuncts (cdr conjuncts)
1173             req (car conjunct)
1174             options (cdr conjunct)
1175             match (cond ((eq req 'type)
1176                          (or (memq window-system options)
1177                              ;; FIXME: This should be revisited to use
1178                              ;; display-graphic-p, provided that the
1179                              ;; color selection depends on the number
1180                              ;; of supported colors, and all defface's
1181                              ;; are changed to look at number of colors
1182                              ;; instead of (type graphic) etc.
1183                              (and (null window-system)
1184                                   (memq 'tty options))
1185                              (and (memq 'motif options)
1186                                   (featurep 'motif))
1187                              (and (memq 'lucid options)
1188                                   (featurep 'x-toolkit)
1189                                   (not (featurep 'motif)))
1190                              (and (memq 'x-toolkit options)
1191                                   (featurep 'x-toolkit))))
1192                         ((eq req 'class)
1193                          (memq (frame-parameter frame 'display-type) options))
1194                         ((eq req 'background)
1195                          (memq (frame-parameter frame 'background-mode)
1196                                options))
1197                         (t (error "Unknown req `%S' with options `%S'"
1198                                   req options)))))
1199     match))
1200
1201
1202 (defun face-spec-choose (spec &optional frame)
1203   "Choose the proper attributes for FRAME, out of SPEC.
1204 If SPEC is nil, return nil."
1205   (unless frame
1206     (setq frame (selected-frame)))
1207   (let ((tail spec)
1208         result)
1209     (while tail
1210       (let* ((entry (pop tail))
1211              (display (car entry))
1212              (attrs (cdr entry)))
1213         (when (face-spec-set-match-display display frame)
1214           (setq result (if (listp (car attrs))
1215                            ;; Old-style entry, the attribute list is the
1216                            ;; first element.
1217                            (car attrs)
1218                          attrs)
1219                 tail nil))))
1220     result))
1221
1222
1223 (defun face-spec-reset-face (face &optional frame)
1224   "Reset all attributes of FACE on FRAME to unspecified."
1225   (let ((attrs face-attribute-name-alist))
1226     (while attrs
1227       (let ((attr-and-name (car attrs)))
1228         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1229       (setq attrs (cdr attrs)))))
1230
1231
1232 (defun face-spec-set (face spec &optional frame)
1233   "Set FACE's attributes according to the first matching entry in SPEC.
1234 FRAME is the frame whose frame-local face is set.  FRAME nil means
1235 do it on all frames.  See `defface' for information about SPEC.
1236 If SPEC is nil, do nothing."
1237   (let ((attrs (face-spec-choose spec frame)))
1238     (when attrs
1239       (face-spec-reset-face face frame))
1240     (while attrs
1241       (let ((attribute (car attrs))
1242             (value (car (cdr attrs))))
1243         ;; Support some old-style attribute names and values.
1244         (case attribute
1245           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1246           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1247           ((:foreground :background)
1248            ;; Compatibility with 20.x.  Some bogus face specs seem to
1249            ;; exist containing things like `:foreground nil'.
1250            (if (null value) (setq value 'unspecified)))
1251           (t (unless (assq attribute face-x-resources)
1252                (setq attribute nil))))
1253         (when attribute
1254           (set-face-attribute face frame attribute value)))
1255       (setq attrs (cdr (cdr attrs))))))
1256
1257
1258 (defun face-attr-match-p (face attrs &optional frame)
1259   "Return t if attributes of FACE match values in plist ATTRS.
1260 Optional parameter FRAME is the frame whose definition of FACE
1261 is used.  If nil or omitted, use the selected frame."
1262   (unless frame
1263     (setq frame (selected-frame)))
1264   (let ((list face-attribute-name-alist)
1265         (match t))
1266     (while (and match (not (null list)))
1267       (let* ((attr (car (car list)))
1268              (specified-value
1269               (if (plist-member attrs attr)
1270                   (plist-get attrs attr)
1271                 'unspecified))
1272              (value-now (face-attribute face attr frame)))
1273         (setq match (equal specified-value value-now))
1274         (setq list (cdr list))))
1275     match))
1276
1277 (defun face-spec-match-p (face spec &optional frame)
1278   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1279   (face-attr-match-p face (face-spec-choose spec frame) frame))
1280
1281 (defsubst face-default-spec (face)
1282   "Return the default face-spec for FACE, ignoring any user customization.
1283 If there is no default for FACE, return nil."
1284   (get face 'face-defface-spec))
1285
1286 (defsubst face-user-default-spec (face)
1287   "Return the user's customized face-spec for FACE, or the default if none.
1288 If there is neither a user setting nor a default for FACE, return nil."
1289   (or (get face 'saved-face)
1290       (face-default-spec face)))
1291
1292 \f
1293 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1294 ;;; Frame-type independent color support.
1295 ;;; We keep the old x-* names as aliases for back-compatibility.
1296 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1297
1298 (defun defined-colors (&optional frame)
1299   "Return a list of colors supported for a particular frame.
1300 The argument FRAME specifies which frame to try.
1301 The value may be different for frames on different display types.
1302 If FRAME doesn't support colors, the value is nil."
1303   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1304       (xw-defined-colors frame)
1305     (mapcar 'car (tty-color-alist frame))))
1306 (defalias 'x-defined-colors 'defined-colors)
1307
1308 (defun color-defined-p (color &optional frame)
1309   "Return non-nil if color COLOR is supported on frame FRAME.
1310 If FRAME is omitted or nil, use the selected frame.
1311 If COLOR is the symbol `unspecified' or one of the strings
1312 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1313   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1314       nil
1315     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1316         (xw-color-defined-p color frame)
1317       (numberp (tty-color-translate color frame)))))
1318 (defalias 'x-color-defined-p 'color-defined-p)
1319
1320 (defun color-values (color &optional frame)
1321   "Return a description of the color named COLOR on frame FRAME.
1322 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1323 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1324 If FRAME is omitted or nil, use the selected frame.
1325 If FRAME cannot display COLOR, the value is nil.
1326 If COLOR is the symbol `unspecified' or one of the strings
1327 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1328   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1329       nil
1330     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1331         (xw-color-values color frame)
1332       (tty-color-values color frame))))
1333 (defalias 'x-color-values 'color-values)
1334
1335 (defun display-color-p (&optional display)
1336   "Return t if DISPLAY supports color.
1337 The optional argument DISPLAY specifies which display to ask about.
1338 DISPLAY should be either a frame or a display name (a string).
1339 If omitted or nil, that stands for the selected frame's display."
1340   (if (memq (framep-on-display display) '(x w32 mac))
1341       (xw-display-color-p display)
1342     (tty-display-color-p display)))
1343 (defalias 'x-display-color-p 'display-color-p)
1344
1345 (defun display-grayscale-p (&optional display)
1346   "Return non-nil if frames on DISPLAY can display shades of gray."
1347   (let ((frame-type (framep-on-display display)))
1348     (cond
1349      ((memq frame-type '(x w32 mac))
1350       (x-display-grayscale-p display))
1351      (t
1352       (> (tty-color-gray-shades display) 2)))))
1353
1354 \f
1355 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1356 ;;; Background mode.
1357 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1358
1359 (defcustom frame-background-mode nil
1360   "*The brightness of the background.
1361 Set this to the symbol `dark' if your background color is dark, `light' if
1362 your background is light, or nil (default) if you want Emacs to
1363 examine the brightness for you.  Don't set this variable with `setq';
1364 this won't have the expected effect."
1365   :group 'faces
1366   :set #'(lambda (var value)
1367            (set-default var value)
1368            (mapc 'frame-set-background-mode (frame-list)))
1369   :initialize 'custom-initialize-changed
1370   :type '(choice (choice-item dark)
1371                  (choice-item light)
1372                  (choice-item :tag "default" nil)))
1373
1374
1375 (defun frame-set-background-mode (frame)
1376   "Set up display-dependent faces on FRAME.
1377 Display-dependent faces are those which have different definitions
1378 according to the `background-mode' and `display-type' frame parameters."
1379   (let* ((bg-resource
1380           (and window-system
1381                (x-get-resource ".backgroundMode" "BackgroundMode")))
1382          (bg-color (frame-parameter frame 'background-color))
1383          (bg-mode
1384           (cond (frame-background-mode)
1385                 (bg-resource
1386                  (intern (downcase bg-resource)))
1387                 ((and (null window-system) (null bg-color))
1388                  ;; No way to determine this automatically (?).
1389                  'dark)
1390                 ;; Unspecified frame background color can only happen
1391                 ;; on tty's.
1392                 ((member bg-color '(unspecified "unspecified-bg"))
1393                  'dark)
1394                 ((equal bg-color "unspecified-fg") ; inverted colors
1395                  'light)
1396                 ((>= (apply '+ (x-color-values bg-color frame))
1397                     ;; Just looking at the screen, colors whose
1398                     ;; values add up to .6 of the white total
1399                     ;; still look dark to me.
1400                     (* (apply '+ (x-color-values "white" frame)) .6))
1401                  'light)
1402                 (t 'dark)))
1403          (display-type
1404           (cond ((null window-system)
1405                  (if (tty-display-color-p frame) 'color 'mono))
1406                 ((x-display-color-p frame)
1407                  'color)
1408                 ((x-display-grayscale-p frame)
1409                  'grayscale)
1410                 (t 'mono)))
1411          (old-bg-mode
1412           (frame-parameter frame 'background-mode))
1413          (old-display-type
1414           (frame-parameter frame 'display-type)))
1415
1416     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1417       (let ((locally-modified-faces nil))
1418         ;; Before modifying the frame parameters, we collect a list of
1419         ;; faces that don't match what their face-spec says they should
1420         ;; look like; we then avoid changing these faces below.  A
1421         ;; negative list is used on the assumption that most faces will
1422         ;; be unmodified, so we can avoid consing in the common case.
1423         (dolist (face (face-list))
1424           (when (not (face-spec-match-p face
1425                                         (face-user-default-spec face)
1426                                         (selected-frame)))
1427             (push face locally-modified-faces)))
1428         ;; Now change to the new frame parameters
1429         (modify-frame-parameters frame
1430                                  (list (cons 'background-mode bg-mode)
1431                                        (cons 'display-type display-type)))
1432         ;; For all named faces, choose face specs matching the new frame
1433         ;; parameters, unless they have been locally modified.
1434         (dolist (face (face-list))
1435           (unless (memq face locally-modified-faces)
1436             (face-spec-set face (face-user-default-spec face) frame)))))))
1437
1438 \f
1439 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1440 ;;; Frame creation.
1441 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1442
1443 (defun x-handle-named-frame-geometry (parameters)
1444   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1445 Value is the new parameter list."
1446   (let* ((name (or (cdr (assq 'name parameters))
1447                    (cdr (assq 'name default-frame-alist))))
1448          (x-resource-name name)
1449          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1450     (when res-geometry
1451       (let ((parsed (x-parse-geometry res-geometry)))
1452         ;; If the resource specifies a position, call the position
1453         ;; and size "user-specified".
1454         (when (or (assq 'top parsed)
1455                   (assq 'left parsed))
1456           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1457         ;; Put the geometry parameters at the end.  Copy
1458         ;; default-frame-alist so that they go after it.
1459         (setq parameters (append parameters default-frame-alist parsed))))
1460     parameters))
1461
1462
1463 (defun x-handle-reverse-video (frame parameters)
1464   "Handle the reverse-video frame parameter and X resource.
1465 `x-create-frame' does not handle this one."
1466   (when (cdr (or (assq 'reverse parameters)
1467                  (assq 'reverse default-frame-alist)
1468                  (let ((resource (x-get-resource "reverseVideo"
1469                                                  "ReverseVideo")))
1470                    (if resource
1471                        (cons nil (member (downcase resource)
1472                                          '("on" "true")))))))
1473       (let* ((params (frame-parameters frame))
1474              (bg (cdr (assq 'foreground-color params)))
1475              (fg (cdr (assq 'background-color params))))
1476         (modify-frame-parameters frame
1477                                  (list (cons 'foreground-color fg)
1478                                        (cons 'background-color bg)))
1479         (if (equal bg (cdr (assq 'border-color params)))
1480             (modify-frame-parameters frame
1481                                      (list (cons 'border-color fg))))
1482         (if (equal bg (cdr (assq 'mouse-color params)))
1483             (modify-frame-parameters frame
1484                                      (list (cons 'mouse-color fg))))
1485         (if (equal bg (cdr (assq 'cursor-color params)))
1486             (modify-frame-parameters frame
1487                                      (list (cons 'cursor-color fg)))))))
1488
1489
1490 (defun x-create-frame-with-faces (&optional parameters)
1491   "Create a frame from optional frame parameters PARAMETERS.
1492 Parameters not specified by PARAMETERS are taken from
1493 `default-frame-alist'.  If PARAMETERS specify a frame name,
1494 handle X geometry resources for that name.  If either PARAMETERS
1495 or `default-frame-alist' contains a `reverse' parameter, or
1496 the X resource ``reverseVideo'' is present, handle that.
1497 Value is the new frame created."
1498   (setq parameters (x-handle-named-frame-geometry parameters))
1499   (let ((visibility-spec (assq 'visibility parameters))
1500         (frame-list (frame-list))
1501         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1502         success)
1503     (unwind-protect
1504         (progn
1505           (x-handle-reverse-video frame parameters)
1506           (frame-set-background-mode frame)
1507           (face-set-after-frame-default frame)
1508           (if (or (null frame-list) (null visibility-spec))
1509               (make-frame-visible frame)
1510             (modify-frame-parameters frame (list visibility-spec)))
1511           (setq success t))
1512       (unless success
1513         (delete-frame frame)))
1514     frame))
1515
1516
1517 (defun face-set-after-frame-default (frame)
1518   "Set frame-local faces of FRAME from face specs and resources.
1519 Initialize colors of certain faces from frame parameters."
1520   (dolist (face (face-list))
1521     (face-spec-set face (face-user-default-spec face) frame)
1522     (internal-merge-in-global-face face frame)
1523     (when (and (memq window-system '(x w32 mac))
1524                (or (not (boundp 'inhibit-default-face-x-resources))
1525                    (not (eq face 'default))))
1526       (make-face-x-resource-internal face frame)))
1527
1528   ;; Initialize attributes from frame parameters.
1529   (let ((params '((foreground-color default :foreground)
1530                   (background-color default :background)
1531                   (border-color border :background)
1532                   (cursor-color cursor :background)
1533                   (scroll-bar-foreground scroll-bar :foreground)
1534                   (scroll-bar-background scroll-bar :background)
1535                   (mouse-color mouse :background))))
1536     (dolist (param params)
1537       (let ((frame-param (frame-parameter frame (nth 0 param)))
1538             (face (nth 1 param))
1539             (attr (nth 2 param)))
1540         (when (and frame-param
1541                    ;; Don't override face attributes explicitly
1542                    ;; specified for new frames.
1543                    (eq (face-attribute face attr t) 'unspecified))
1544           (set-face-attribute face frame attr frame-param))))))
1545
1546
1547 (defun tty-handle-reverse-video (frame parameters)
1548   "Handle the reverse-video frame parameter for terminal frames."
1549   (when (cdr (or (assq 'reverse parameters)
1550                  (assq 'reverse default-frame-alist)))
1551     (let* ((params (frame-parameters frame))
1552            (bg (cdr (assq 'foreground-color params)))
1553            (fg (cdr (assq 'background-color params))))
1554       (modify-frame-parameters frame
1555                                (list (cons 'foreground-color fg)
1556                                      (cons 'background-color bg)))
1557       (if (equal bg (cdr (assq 'mouse-color params)))
1558           (modify-frame-parameters frame
1559                                    (list (cons 'mouse-color fg))))
1560       (if (equal bg (cdr (assq 'cursor-color params)))
1561           (modify-frame-parameters frame
1562                                    (list (cons 'cursor-color fg)))))))
1563
1564
1565 (defun tty-create-frame-with-faces (&optional parameters)
1566   "Create a frame from optional frame parameters PARAMETERS.
1567 Parameters not specified by PARAMETERS are taken from
1568 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1569 contains a `reverse' parameter, handle that.  Value is the new frame
1570 created."
1571   (let ((frame (make-terminal-frame parameters))
1572         success)
1573     (unwind-protect
1574         (progn
1575           (tty-handle-reverse-video frame (frame-parameters frame))
1576           (frame-set-background-mode frame)
1577           (face-set-after-frame-default frame)
1578           (setq success t))
1579       (unless success
1580         (delete-frame frame)))
1581     frame))
1582
1583
1584 ;; Called from C function init_display to initialize faces of the
1585 ;; dumped terminal frame on startup.
1586
1587 (defun tty-set-up-initial-frame-faces ()
1588   (let ((frame (selected-frame)))
1589     (frame-set-background-mode frame)
1590     (face-set-after-frame-default frame)))
1591
1592
1593
1594 \f
1595 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1596 ;;; Compatiblity with 20.2
1597 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1598
1599 ;; Update a frame's faces when we change its default font.
1600
1601 (defalias 'frame-update-faces 'ignore)
1602 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1603
1604 ;; Update the colors of FACE, after FRAME's own colors have been
1605 ;; changed.
1606
1607 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1608 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1609
1610 \f
1611 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1612 ;;; Standard faces.
1613 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1614
1615 (defgroup basic-faces nil
1616   "The standard faces of Emacs."
1617   :group 'faces)
1618
1619
1620 (defface default
1621   '((t nil))
1622   "Basic default face."
1623   :group 'basic-faces)
1624
1625
1626 (defface mode-line
1627   '((((type x w32 mac) (class color))
1628      (:box (:line-width -1 :style released-button)
1629            :background "grey75" :foreground "black"))
1630     (t
1631      (:inverse-video t)))
1632   "Basic mode line face."
1633   :version "21.1"
1634   :group 'modeline
1635   :group 'basic-faces)
1636
1637 ;; Make `modeline' an alias for `mode-line', for compatibility.
1638 (put 'modeline 'face-alias 'mode-line)
1639
1640 (defface header-line
1641   '((((type tty))
1642      ;; This used to be `:inverse-video t', but that doesn't look very
1643      ;; good when combined with inverse-video mode-lines and multiple
1644      ;; windows.  Underlining looks better, and is more consistent with
1645      ;; the window-system face variants, which deemphasize the
1646      ;; header-line in relation to the mode-line face.  If a terminal
1647      ;; can't underline, then the header-line will end up without any
1648      ;; highlighting; this may be too confusing in general, although it
1649      ;; happens to look good with the only current use of header-lines,
1650      ;; the info browser. XXX
1651      :underline t)
1652     (((class color grayscale) (background light))
1653      :inherit mode-line
1654      :background "grey90" :foreground "grey20"
1655      :box nil)
1656     (((class color grayscale) (background dark))
1657      :inherit mode-line
1658      :background "grey20" :foreground "grey90"
1659      :box nil)
1660     (((class mono) (background light))
1661      :inherit mode-line
1662      :background "white" :foreground "black"
1663      :inverse-video nil
1664      :box nil
1665      :underline t)
1666     (((class mono) (background dark))
1667      :inherit mode-line
1668      :background "black" :foreground "white"
1669      :inverse-video nil
1670      :box nil
1671      :underline t)
1672     (t
1673      :inverse-video t))
1674   "Basic header-line face."
1675   :version "21.1"
1676   :group 'basic-faces)
1677
1678
1679 (defface tool-bar
1680   '((((type x w32 mac) (class color))
1681      (:box (:line-width 1 :style released-button)
1682            :background "grey75" :foreground "black"))
1683     (((type x) (class mono))
1684      (:box (:line-width 1 :style released-button)
1685            :background "grey" :foreground "black"))
1686     (t
1687      ()))
1688   "Basic tool-bar face."
1689   :version "21.1"
1690   :group 'basic-faces)
1691
1692
1693 (defface region
1694   '((((type tty) (class color))
1695      (:background "blue" :foreground "white"))
1696     (((type tty) (class mono))
1697      (:inverse-video t))
1698     (((class color) (background dark))
1699      (:background "blue3"))
1700     (((class color) (background light))
1701      (:background "light goldenrod yellow"))
1702     (t (:background "gray")))
1703   "Basic face for highlighting the region."
1704   :version "21.1"
1705   :group 'basic-faces)
1706
1707
1708 (defface fringe
1709   '((((class color) (background light))
1710        (:background "grey95"))
1711       (((class color) (background dark))
1712        (:background "grey10"))
1713       (t
1714        (:background "gray")))
1715   "Basic face for the fringes to the left and right of windows under X."
1716   :version "21.1"
1717   :group 'frames
1718   :group 'basic-faces)
1719
1720
1721 (defface scroll-bar '()
1722   "Basic face for the scroll bar colors under X."
1723   :version "21.1"
1724   :group 'frames
1725   :group 'basic-faces)
1726
1727
1728 (defface menu
1729   '((((type tty))
1730      :inverse-video t)
1731     (((type x-toolkit))
1732      )
1733     (t
1734      :inverse-video t))
1735   "Basic face for the font and colors of the menu bar and popup menus."
1736   :version "21.1"
1737   :group 'menu
1738   :group 'basic-faces)
1739
1740
1741 (defface border '()
1742   "Basic face for the frame border under X."
1743   :version "21.1"
1744   :group 'frames
1745   :group 'basic-faces)
1746
1747
1748 (defface cursor '()
1749   "Basic face for the cursor color under X."
1750   :version "21.1"
1751   :group 'cursor
1752   :group 'basic-faces)
1753
1754
1755 (defface mouse '()
1756   "Basic face for the mouse color under X."
1757   :version "21.1"
1758   :group 'mouse
1759   :group 'basic-faces)
1760
1761
1762 (defface bold '((t (:weight bold)))
1763   "Basic bold face."
1764   :group 'basic-faces)
1765
1766
1767 (defface italic '((t (:slant italic)))
1768   "Basic italic font."
1769   :group 'basic-faces)
1770
1771
1772 (defface bold-italic '((t (:weight bold :slant italic)))
1773   "Basic bold-italic face."
1774   :group 'basic-faces)
1775
1776
1777 (defface underline '((t (:underline t)))
1778   "Basic underlined face."
1779   :group 'basic-faces)
1780
1781
1782 (defface highlight
1783   '((((type tty) (class color))
1784      (:background "green"))
1785     (((class color) (background light))
1786      (:background "darkseagreen2"))
1787     (((class color) (background dark))
1788      (:background "darkolivegreen"))
1789     (t (:inverse-video t)))
1790   "Basic face for highlighting."
1791   :group 'basic-faces)
1792
1793
1794 (defface secondary-selection
1795   '((((type tty) (class color))
1796      (:background "cyan" :foreground "black"))
1797     (((class color) (background light))
1798      (:background "yellow"))
1799     (((class color) (background dark))
1800      (:background "SkyBlue4"))
1801     (t (:inverse-video t)))
1802   "Basic face for displaying the secondary selection."
1803   :group 'basic-faces)
1804
1805
1806 (defface fixed-pitch '((t (:family "courier")))
1807   "The basic fixed-pitch face."
1808   :group 'basic-faces)
1809
1810
1811 (defface variable-pitch '((t (:family "helv")))
1812   "The basic variable-pitch face."
1813   :group 'basic-faces)
1814
1815
1816 (defface trailing-whitespace
1817   '((((class color) (background light))
1818      (:background "red"))
1819     (((class color) (background dark))
1820      (:background "red"))
1821     (t (:inverse-video t)))
1822   "Basic face for highlighting trailing whitespace."
1823   :version "21.1"
1824   :group 'font-lock                     ; like `show-trailing-whitespace'
1825   :group 'basic-faces)
1826
1827
1828 \f
1829 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1830 ;;; Manipulating font names.
1831 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1832
1833 ;; This is here for compatibilty with Emacs 20.2.  For example,
1834 ;; international/fontset.el uses x-resolve-font-name.  The following
1835 ;; functions are not used in the face implementation itself.
1836
1837 (defvar x-font-regexp nil)
1838 (defvar x-font-regexp-head nil)
1839 (defvar x-font-regexp-weight nil)
1840 (defvar x-font-regexp-slant nil)
1841
1842 (defconst x-font-regexp-weight-subnum 1)
1843 (defconst x-font-regexp-slant-subnum 2)
1844 (defconst x-font-regexp-swidth-subnum 3)
1845 (defconst x-font-regexp-adstyle-subnum 4)
1846
1847 ;;; Regexps matching font names in "Host Portable Character Representation."
1848 ;;;
1849 (let ((-                "[-?]")
1850       (foundry          "[^-]+")
1851       (family           "[^-]+")
1852       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1853 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1854       (weight\?         "\\([^-]*\\)")                                  ; 1
1855       (slant            "\\([ior]\\)")                                  ; 2
1856 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1857       (slant\?          "\\([^-]?\\)")                                  ; 2
1858 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1859       (swidth           "\\([^-]*\\)")                                  ; 3
1860 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1861       (adstyle          "\\([^-]*\\)")                                  ; 4
1862       (pixelsize        "[0-9]+")
1863       (pointsize        "[0-9][0-9]+")
1864       (resx             "[0-9][0-9]+")
1865       (resy             "[0-9][0-9]+")
1866       (spacing          "[cmp?*]")
1867       (avgwidth         "[0-9]+")
1868       (registry         "[^-]+")
1869       (encoding         "[^-]+")
1870       )
1871   (setq x-font-regexp
1872         (concat "\\`\\*?[-?*]"
1873                 foundry - family - weight\? - slant\? - swidth - adstyle -
1874                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1875                 registry - encoding "\\*?\\'"
1876                 ))
1877   (setq x-font-regexp-head
1878         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1879                 "\\([-*?]\\|\\'\\)"))
1880   (setq x-font-regexp-slant (concat - slant -))
1881   (setq x-font-regexp-weight (concat - weight -))
1882   nil)
1883
1884
1885 (defun x-resolve-font-name (pattern &optional face frame)
1886   "Return a font name matching PATTERN.
1887 All wildcards in PATTERN are instantiated.
1888 If PATTERN is nil, return the name of the frame's base font, which never
1889 contains wildcards.
1890 Given optional arguments FACE and FRAME, return a font which is
1891 also the same size as FACE on FRAME, or fail."
1892   (or (symbolp face)
1893       (setq face (face-name face)))
1894   (and (eq frame t)
1895        (setq frame nil))
1896   (if pattern
1897       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1898       (let ((fonts (x-list-fonts pattern face frame 1)))
1899         (or fonts
1900             (if face
1901                 (if (string-match "\\*" pattern)
1902                     (if (null (face-font face))
1903                         (error "No matching fonts are the same height as the frame default font")
1904                       (error "No matching fonts are the same height as face `%s'" face))
1905                   (if (null (face-font face))
1906                       (error "Height of font `%s' doesn't match the frame default font"
1907                              pattern)
1908                     (error "Height of font `%s' doesn't match face `%s'"
1909                            pattern face)))
1910               (error "No fonts match `%s'" pattern)))
1911         (car fonts))
1912     (cdr (assq 'font (frame-parameters (selected-frame))))))
1913
1914
1915 (defun x-frob-font-weight (font which)
1916   (let ((case-fold-search t))
1917     (cond ((string-match x-font-regexp font)
1918            (concat (substring font 0
1919                               (match-beginning x-font-regexp-weight-subnum))
1920                    which
1921                    (substring font (match-end x-font-regexp-weight-subnum)
1922                               (match-beginning x-font-regexp-adstyle-subnum))
1923                    ;; Replace the ADD_STYLE_NAME field with *
1924                    ;; because the info in it may not be the same
1925                    ;; for related fonts.
1926                    "*"
1927                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1928           ((string-match x-font-regexp-head font)
1929            (concat (substring font 0 (match-beginning 1)) which
1930                    (substring font (match-end 1))))
1931           ((string-match x-font-regexp-weight font)
1932            (concat (substring font 0 (match-beginning 1)) which
1933                    (substring font (match-end 1)))))))
1934 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
1935
1936 (defun x-frob-font-slant (font which)
1937   (let ((case-fold-search t))
1938     (cond ((string-match x-font-regexp font)
1939            (concat (substring font 0
1940                               (match-beginning x-font-regexp-slant-subnum))
1941                    which
1942                    (substring font (match-end x-font-regexp-slant-subnum)
1943                               (match-beginning x-font-regexp-adstyle-subnum))
1944                    ;; Replace the ADD_STYLE_NAME field with *
1945                    ;; because the info in it may not be the same
1946                    ;; for related fonts.
1947                    "*"
1948                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1949           ((string-match x-font-regexp-head font)
1950            (concat (substring font 0 (match-beginning 2)) which
1951                    (substring font (match-end 2))))
1952           ((string-match x-font-regexp-slant font)
1953            (concat (substring font 0 (match-beginning 1)) which
1954                    (substring font (match-end 1)))))))
1955 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
1956
1957 (defun x-make-font-bold (font)
1958   "Given an X font specification, make a bold version of it.
1959 If that can't be done, return nil."
1960   (x-frob-font-weight font "bold"))
1961 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
1962
1963 (defun x-make-font-demibold (font)
1964   "Given an X font specification, make a demibold version of it.
1965 If that can't be done, return nil."
1966   (x-frob-font-weight font "demibold"))
1967 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
1968
1969 (defun x-make-font-unbold (font)
1970   "Given an X font specification, make a non-bold version of it.
1971 If that can't be done, return nil."
1972   (x-frob-font-weight font "medium"))
1973 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
1974
1975 (defun x-make-font-italic (font)
1976   "Given an X font specification, make an italic version of it.
1977 If that can't be done, return nil."
1978   (x-frob-font-slant font "i"))
1979 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
1980
1981 (defun x-make-font-oblique (font) ; you say tomayto...
1982   "Given an X font specification, make an oblique version of it.
1983 If that can't be done, return nil."
1984   (x-frob-font-slant font "o"))
1985 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
1986
1987 (defun x-make-font-unitalic (font)
1988   "Given an X font specification, make a non-italic version of it.
1989 If that can't be done, return nil."
1990   (x-frob-font-slant font "r"))
1991 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
1992
1993 (defun x-make-font-bold-italic (font)
1994   "Given an X font specification, make a bold and italic version of it.
1995 If that can't be done, return nil."
1996   (and (setq font (x-make-font-bold font))
1997        (x-make-font-italic font)))
1998 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
1999
2000 (provide 'faces)
2001
2002 ;;; faces.el ends here