lisp/eshell/em-hist.el

   1 ;;; em-hist.el --- history list management  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1999-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: John Wiegley <johnw@gnu.org>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23
  24 ;; Eshell's history facility imitates the syntax used by bash
  25 ;; ([(bash)History Interaction]).  Thus:
  26 ;;
  27 ;;   !ls           ; repeat the last command beginning with 'ls'
  28 ;;   !?ls          ; repeat the last command containing ls
  29 ;;   echo !ls:2    ; echo the second arg of the last 'ls' command
  30 ;;   !ls<tab>      ; complete against all possible words in this
  31 ;;                 ; position, by looking at the history list
  32 ;;   !ls<C-c SPC>  ; expand any matching history input at point
  33 ;;
  34 ;; Also, most of `comint-mode's keybindings are accepted:
  35 ;;
  36 ;;   M-r     ; search backward for a previous command by regexp
  37 ;;   M-s     ; search forward for a previous command by regexp
  38 ;;   M-p     ; access the last command entered, repeatable
  39 ;;   M-n     ; access the first command entered, repeatable
  40 ;;
  41 ;;   C-c M-r ; using current input, find a matching command thus, with
  42 ;;           ; 'ls' as the current input, it will go back to the same
  43 ;;           ; command that '!ls' would have selected
  44 ;;   C-c M-s ; same, but in reverse order
  45 ;;
  46 ;; Note that some of these keybindings are only available if the
  47 ;; `eshell-rebind' is not in use, in which case M-p does what C-c M-r
  48 ;; normally would do, and C-p is used instead of M-p.  It may seem
  49 ;; confusing, but the intention is to make the most useful
  50 ;; functionality the most easily accessible.  If `eshell-rebind' is
  51 ;; not being used, history navigation will use comint's keybindings;
  52 ;; if it is, history navigation tries to use similar keybindings to
  53 ;; bash.  This is all configurable, of course.
  54
  55 ;;; Code:
  56
  57 (eval-when-compile (require 'cl-lib))
  58
  59 (require 'ring)
  60 (require 'esh-opt)
  61 (require 'em-pred)
  62 (require 'eshell)
  63
  64 ;;;###autoload
  65 (progn
  66 (defgroup eshell-hist nil
  67   "This module provides command history management."
  68   :tag "History list management"
  69   :group 'eshell-module))
  70
  71 ;;; User Variables:
  72
  73 (defcustom eshell-hist-load-hook nil
  74   "A list of functions to call when loading `eshell-hist'."
  75   :version "24.1"                       ; removed eshell-hist-initialize
  76   :type 'hook
  77   :group 'eshell-hist)
  78
  79 (defcustom eshell-hist-unload-hook
  80   (list
  81    (function
  82     (lambda ()
  83       (remove-hook 'kill-emacs-hook 'eshell-save-some-history))))
  84   "A hook that gets run when `eshell-hist' is unloaded."
  85   :type 'hook
  86   :group 'eshell-hist)
  87
  88 (defcustom eshell-history-file-name
  89   (expand-file-name "history" eshell-directory-name)
  90   "If non-nil, name of the file to read/write input history.
  91 See also `eshell-read-history' and `eshell-write-history'.
  92 If it is nil, Eshell will use the value of HISTFILE."
  93   :type '(choice (const :tag "Use HISTFILE" nil)
  94                  file)
  95   :group 'eshell-hist)
  96
  97 (defcustom eshell-history-size 128
  98   "Size of the input history ring.  If nil, use envvar HISTSIZE."
  99   :type '(choice (const :tag "Use HISTSIZE" nil)
 100                  integer)
 101   :group 'eshell-hist)
 102
 103 (defcustom eshell-hist-ignoredups nil
 104   "If non-nil, don't add input matching the last on the input ring.
 105 This mirrors the optional behavior of bash."
 106   :type 'boolean
 107   :group 'eshell-hist)
 108
 109 (defcustom eshell-save-history-on-exit t
 110   "Determine if history should be automatically saved.
 111 History is always preserved after sanely exiting an Eshell buffer.
 112 However, when Emacs is being shut down, this variable determines
 113 whether to prompt the user.
 114 If set to nil, it means never save history on termination of Emacs.
 115 If set to `ask', ask if any Eshell buffers are open at exit time.
 116 If set to t, history will always be saved, silently."
 117   :type '(choice (const :tag "Never" nil)
 118                  (const :tag "Ask" ask)
 119                  (const :tag "Always save" t))
 120   :group 'eshell-hist)
 121
 122 (defcustom eshell-input-filter
 123   (function
 124    (lambda (str)
 125      (not (string-match "\\`\\s-*\\'" str))))
 126   "Predicate for filtering additions to input history.
 127 Takes one argument, the input.  If non-nil, the input may be saved on
 128 the input history list.  Default is to save anything that isn't all
 129 whitespace."
 130   :type 'function
 131   :group 'eshell-hist)
 132
 133 (put 'eshell-input-filter 'risky-local-variable t)
 134
 135 (defcustom eshell-hist-match-partial t
 136   "If non-nil, movement through history is constrained by current input.
 137 Otherwise, typing <M-p> and <M-n> will always go to the next history
 138 element, regardless of any text on the command line.  In that case,
 139 <C-c M-r> and <C-c M-s> still offer that functionality."
 140   :type 'boolean
 141   :group 'eshell-hist)
 142
 143 (defcustom eshell-hist-move-to-end t
 144   "If non-nil, move to the end of the buffer before cycling history."
 145   :type 'boolean
 146   :group 'eshell-hist)
 147
 148 (defcustom eshell-hist-event-designator
 149   "^!\\(!\\|-?[0-9]+\\|\\??[^:^$%*?]+\\??\\|#\\)"
 150   "The regexp used to identifier history event designators."
 151   :type 'regexp
 152   :group 'eshell-hist)
 153
 154 (defcustom eshell-hist-word-designator
 155   "^:?\\([0-9]+\\|[$^%*]\\)?\\(\\*\\|-[0-9]*\\|[$^%*]\\)?"
 156   "The regexp used to identify history word designators."
 157   :type 'regexp
 158   :group 'eshell-hist)
 159
 160 (defcustom eshell-hist-modifier
 161   "^\\(:\\([hretpqx&g]\\|s/\\([^/]*\\)/\\([^/]*\\)/\\)\\)*"
 162   "The regexp used to identity history modifiers."
 163   :type 'regexp
 164   :group 'eshell-hist)
 165
 166 (defcustom eshell-hist-rebind-keys-alist
 167   '(([(control ?p)]   . eshell-previous-input)
 168     ([(control ?n)]   . eshell-next-input)
 169     ([(control up)]   . eshell-previous-input)
 170     ([(control down)] . eshell-next-input)
 171     ([(control ?r)]   . eshell-isearch-backward)
 172     ([(control ?s)]   . eshell-isearch-forward)
 173     ([(meta ?r)]      . eshell-previous-matching-input)
 174     ([(meta ?s)]      . eshell-next-matching-input)
 175     ([(meta ?p)]      . eshell-previous-matching-input-from-input)
 176     ([(meta ?n)]      . eshell-next-matching-input-from-input)
 177     ([up]             . eshell-previous-matching-input-from-input)
 178     ([down]           . eshell-next-matching-input-from-input))
 179   "History keys to bind differently if point is in input text."
 180   :type '(repeat (cons (vector :tag "Keys to bind"
 181                                (repeat :inline t sexp))
 182                        (function :tag "Command")))
 183   :group 'eshell-hist)
 184
 185 ;;; Internal Variables:
 186
 187 (defvar eshell-history-ring nil)
 188 (defvar eshell-history-index nil)
 189 (defvar eshell-matching-input-from-input-string "")
 190 (defvar eshell-save-history-index nil)
 191
 192 (defvar eshell-isearch-map
 193   (let ((map (copy-keymap isearch-mode-map)))
 194     (define-key map [(control ?m)] 'eshell-isearch-return)
 195     (define-key map [return] 'eshell-isearch-return)
 196     (define-key map [(control ?r)] 'eshell-isearch-repeat-backward)
 197     (define-key map [(control ?s)] 'eshell-isearch-repeat-forward)
 198     (define-key map [(control ?g)] 'eshell-isearch-abort)
 199     (define-key map [backspace] 'eshell-isearch-delete-char)
 200     (define-key map [delete] 'eshell-isearch-delete-char)
 201     (define-key map "\C-c\C-c" 'eshell-isearch-cancel)
 202     map)
 203   "Keymap used in isearch in Eshell.")
 204
 205 (defvar eshell-rebind-keys-alist)
 206
 207 ;;; Functions:
 208
 209 (defun eshell-hist-initialize ()
 210   "Initialize the history management code for one Eshell buffer."
 211   (add-hook 'eshell-expand-input-functions
 212             'eshell-expand-history-references nil t)
 213
 214   (when (eshell-using-module 'eshell-cmpl)
 215     (add-hook 'pcomplete-try-first-hook
 216               'eshell-complete-history-reference nil t))
 217
 218   (if (and (eshell-using-module 'eshell-rebind)
 219            (not eshell-non-interactive-p))
 220       (let ((rebind-alist eshell-rebind-keys-alist))
 221         (make-local-variable 'eshell-rebind-keys-alist)
 222         (setq eshell-rebind-keys-alist
 223               (append rebind-alist eshell-hist-rebind-keys-alist))
 224         (set (make-local-variable 'search-invisible) t)
 225         (set (make-local-variable 'search-exit-option) t)
 226         (add-hook 'isearch-mode-hook
 227                   (function
 228                    (lambda ()
 229                      (if (>= (point) eshell-last-output-end)
 230                          (setq overriding-terminal-local-map
 231                                eshell-isearch-map)))) nil t)
 232         (add-hook 'isearch-mode-end-hook
 233                   (function
 234                    (lambda ()
 235                      (setq overriding-terminal-local-map nil))) nil t))
 236     (define-key eshell-mode-map [up] 'eshell-previous-matching-input-from-input)
 237     (define-key eshell-mode-map [down] 'eshell-next-matching-input-from-input)
 238     (define-key eshell-mode-map [(control up)] 'eshell-previous-input)
 239     (define-key eshell-mode-map [(control down)] 'eshell-next-input)
 240     (define-key eshell-mode-map [(meta ?r)] 'eshell-previous-matching-input)
 241     (define-key eshell-mode-map [(meta ?s)] 'eshell-next-matching-input)
 242     (define-key eshell-command-map [(meta ?r)]
 243       'eshell-previous-matching-input-from-input)
 244     (define-key eshell-command-map [(meta ?s)]
 245       'eshell-next-matching-input-from-input)
 246     (if eshell-hist-match-partial
 247         (progn
 248           (define-key eshell-mode-map [(meta ?p)]
 249             'eshell-previous-matching-input-from-input)
 250           (define-key eshell-mode-map [(meta ?n)]
 251             'eshell-next-matching-input-from-input)
 252           (define-key eshell-command-map [(meta ?p)] 'eshell-previous-input)
 253           (define-key eshell-command-map [(meta ?n)] 'eshell-next-input))
 254       (define-key eshell-mode-map [(meta ?p)] 'eshell-previous-input)
 255       (define-key eshell-mode-map [(meta ?n)] 'eshell-next-input)
 256       (define-key eshell-command-map [(meta ?p)]
 257         'eshell-previous-matching-input-from-input)
 258       (define-key eshell-command-map [(meta ?n)]
 259         'eshell-next-matching-input-from-input)))
 260
 261   (make-local-variable 'eshell-history-size)
 262   (or eshell-history-size
 263       (let ((hsize (getenv "HISTSIZE")))
 264         (setq eshell-history-size
 265               (if (and (stringp hsize)
 266                        (integerp (setq hsize (string-to-number hsize)))
 267                        (> hsize 0))
 268                   hsize
 269                 128))))
 270
 271   (make-local-variable 'eshell-history-file-name)
 272   (or eshell-history-file-name
 273       (setq eshell-history-file-name (getenv "HISTFILE")))
 274
 275   (make-local-variable 'eshell-history-index)
 276   (make-local-variable 'eshell-save-history-index)
 277
 278   (if (minibuffer-window-active-p (selected-window))
 279       (set (make-local-variable 'eshell-save-history-on-exit) nil)
 280     (set (make-local-variable 'eshell-history-ring) nil)
 281     (if eshell-history-file-name
 282         (eshell-read-history nil t))
 283
 284     (add-hook 'eshell-exit-hook 'eshell-write-history nil t))
 285
 286   (unless eshell-history-ring
 287     (setq eshell-history-ring (make-ring eshell-history-size)))
 288
 289   (add-hook 'eshell-exit-hook 'eshell-write-history nil t)
 290
 291   (add-hook 'kill-emacs-hook 'eshell-save-some-history)
 292
 293   (make-local-variable 'eshell-input-filter-functions)
 294   (add-hook 'eshell-input-filter-functions 'eshell-add-to-history nil t)
 295
 296   (define-key eshell-command-map [(control ?l)] 'eshell-list-history)
 297   (define-key eshell-command-map [(control ?x)] 'eshell-get-next-from-history))
 298
 299 (defun eshell-save-some-history ()
 300   "Save the history for any open Eshell buffers."
 301   (dolist (buf (buffer-list))
 302     (if (buffer-live-p buf)
 303         (with-current-buffer buf
 304           (if (and eshell-mode
 305                    eshell-history-file-name
 306                    eshell-save-history-on-exit
 307                    (or (eq eshell-save-history-on-exit t)
 308                        (y-or-n-p
 309                         (format "Save input history for Eshell buffer `%s'? "
 310                                 (buffer-name buf)))))
 311               (eshell-write-history))))))
 312
 313 (defun eshell/history (&rest args)
 314   "List in help buffer the buffer's input history."
 315   (eshell-init-print-buffer)
 316   (eshell-eval-using-options
 317    "history" args
 318    '((?r "read" nil read-history
 319          "read from history file to current history list")
 320      (?w "write" nil write-history
 321          "write current history list to history file")
 322      (?a "append" nil append-history
 323          "append current history list to history file")
 324      (?h "help" nil nil "display this usage message")
 325      :usage "[n] [-rwa [filename]]"
 326      :post-usage
 327 "When Eshell is started, history is read from `eshell-history-file-name'.
 328 This is also the location where history info will be saved by this command,
 329 unless a different file is specified on the command line.")
 330    (and (or (not (ring-p eshell-history-ring))
 331            (ring-empty-p eshell-history-ring))
 332         (error "No history"))
 333    (let (length file)
 334      (when (and args (string-match "^[0-9]+$" (car args)))
 335        (setq length (min (eshell-convert (car args))
 336                          (ring-length eshell-history-ring))
 337              args (cdr args)))
 338      (and length
 339           (or read-history write-history append-history)
 340           (error "history: extra arguments"))
 341      (when (and args (stringp (car args)))
 342        (setq file (car args)
 343              args (cdr args)))
 344      (cond
 345       (read-history (eshell-read-history file))
 346       (write-history (eshell-write-history file))
 347       (append-history (eshell-write-history file t))
 348       (t
 349        (let* ((index (1- (or length (ring-length eshell-history-ring))))
 350               (ref (- (ring-length eshell-history-ring) index)))
 351          ;; We have to build up a list ourselves from the ring vector.
 352          (while (>= index 0)
 353            (eshell-buffered-print
 354             (format "%5d  %s\n" ref (eshell-get-history index)))
 355            (setq index (1- index)
 356                  ref (1+ ref)))))))
 357    (eshell-flush)
 358    nil))
 359
 360 (defun eshell-put-history (input &optional ring at-beginning)
 361   "Put a new input line into the history ring."
 362   (unless ring (setq ring eshell-history-ring))
 363   (if at-beginning
 364       (ring-insert-at-beginning ring input)
 365     (ring-insert ring input)))
 366
 367 (defun eshell-get-history (index &optional ring)
 368   "Get an input line from the history ring."
 369   (ring-ref (or ring eshell-history-ring) index))
 370
 371 (defun eshell-add-input-to-history (input)
 372   "Add the string INPUT to the history ring.
 373 Input is entered into the input history ring, if the value of
 374 variable `eshell-input-filter' returns non-nil when called on the
 375 input."
 376   (if (and (funcall eshell-input-filter input)
 377            (or (null eshell-hist-ignoredups)
 378                (not (ring-p eshell-history-ring))
 379                (ring-empty-p eshell-history-ring)
 380                (not (string-equal (eshell-get-history 0) input))))
 381       (eshell-put-history input))
 382   (setq eshell-save-history-index eshell-history-index)
 383   (setq eshell-history-index nil))
 384
 385 (defun eshell-add-command-to-history ()
 386   "Add the command entered at `eshell-command's prompt to the history ring.
 387 The command is added to the input history ring, if the value of
 388 variable `eshell-input-filter' returns non-nil when called on the
 389 command.
 390
 391 This function is supposed to be called from the minibuffer, presumably
 392 as a minibuffer-exit-hook."
 393   (eshell-add-input-to-history
 394    (buffer-substring (minibuffer-prompt-end) (point-max))))
 395
 396 (defun eshell-add-to-history ()
 397   "Add last Eshell command to the history ring.
 398 The command is entered into the input history ring, if the value of
 399 variable `eshell-input-filter' returns non-nil when called on the
 400 command."
 401   (when (> (1- eshell-last-input-end) eshell-last-input-start)
 402     (let ((input (buffer-substring eshell-last-input-start
 403                                    (1- eshell-last-input-end))))
 404       (eshell-add-input-to-history input))))
 405
 406 (defun eshell-read-history (&optional filename silent)
 407   "Sets the buffer's `eshell-history-ring' from a history file.
 408 The name of the file is given by the variable
 409 `eshell-history-file-name'.  The history ring is of size
 410 `eshell-history-size', regardless of file size.  If
 411 `eshell-history-file-name' is nil this function does nothing.
 412
 413 If the optional argument SILENT is non-nil, we say nothing about a
 414 failure to read the history file.
 415
 416 This function is useful for major mode commands and mode hooks.
 417
 418 The structure of the history file should be one input command per
 419 line, with the most recent command last.  See also
 420 `eshell-hist-ignoredups' and `eshell-write-history'."
 421   (let ((file (or filename eshell-history-file-name)))
 422     (cond
 423      ((or (null file)
 424           (equal file ""))
 425       nil)
 426      ((not (file-readable-p file))
 427       (or silent
 428           (message "Cannot read history file %s" file)))
 429      (t
 430       (let* ((count 0)
 431              (size eshell-history-size)
 432              (ring (make-ring size))
 433              (ignore-dups eshell-hist-ignoredups))
 434         (with-temp-buffer
 435           (insert-file-contents file)
 436           ;; Save restriction in case file is already visited...
 437           ;; Watch for those date stamps in history files!
 438           (goto-char (point-max))
 439           (while (and (< count size)
 440                       (re-search-backward "^[ \t]*\\([^#\n].*\\)[ \t]*$"
 441                                           nil t))
 442             (let ((history (match-string 1)))
 443               (if (or (null ignore-dups)
 444                       (ring-empty-p ring)
 445                       (not (string-equal (ring-ref ring 0) history)))
 446                   (ring-insert-at-beginning
 447                    ring (subst-char-in-string ?\177 ?\n history))))
 448             (setq count (1+ count))))
 449         (setq eshell-history-ring ring
 450               eshell-history-index nil))))))
 451
 452 (defun eshell-write-history (&optional filename append)
 453   "Writes the buffer's `eshell-history-ring' to a history file.
 454 The name of the file is given by the variable
 455 `eshell-history-file-name'.  The original contents of the file are
 456 lost if `eshell-history-ring' is not empty.  If
 457 `eshell-history-file-name' is nil this function does nothing.
 458
 459 Useful within process sentinels.
 460
 461 See also `eshell-read-history'."
 462   (let ((file (or filename eshell-history-file-name)))
 463     (cond
 464      ((or (null file)
 465           (equal file "")
 466           (null eshell-history-ring)
 467           (ring-empty-p eshell-history-ring))
 468       nil)
 469      ((not (file-writable-p file))
 470       (message "Cannot write history file %s" file))
 471      (t
 472       (let* ((ring eshell-history-ring)
 473              (index (ring-length ring)))
 474         ;; Write it all out into a buffer first.  Much faster, but
 475         ;; messier, than writing it one line at a time.
 476         (with-temp-buffer
 477           (while (> index 0)
 478             (setq index (1- index))
 479             (let ((start (point)))
 480               (insert (ring-ref ring index) ?\n)
 481               (subst-char-in-region start (1- (point)) ?\n ?\177)))
 482           (eshell-with-private-file-modes
 483            (write-region (point-min) (point-max) file append
 484                          'no-message))))))))
 485
 486 (defun eshell-list-history ()
 487   "List in help buffer the buffer's input history."
 488   (interactive)
 489   (let (prefix prelen)
 490     (save-excursion
 491       (if (re-search-backward "!\\(.+\\)" (line-beginning-position) t)
 492           (setq prefix (match-string 1)
 493                 prelen (length prefix))))
 494     (if (or (not (ring-p eshell-history-ring))
 495             (ring-empty-p eshell-history-ring))
 496         (message "No history")
 497       (let ((history nil)
 498             (history-buffer " *Input History*")
 499             (index (1- (ring-length eshell-history-ring)))
 500             (conf (current-window-configuration)))
 501         ;; We have to build up a list ourselves from the ring vector.
 502         (while (>= index 0)
 503           (let ((hist (eshell-get-history index)))
 504             (if (or (not prefix)
 505                     (and (>= (length hist) prelen)
 506                          (string= (substring hist 0 prelen) prefix)))
 507                 (setq history (cons hist history))))
 508           (setq index (1- index)))
 509         ;; Change "completion" to "history reference"
 510         ;; to make the display accurate.
 511         (with-output-to-temp-buffer history-buffer
 512           (display-completion-list history prefix)
 513           (set-buffer history-buffer)
 514           (forward-line 3)
 515           (while (search-backward "completion" nil 'move)
 516             (replace-match "history reference")))
 517         (eshell-redisplay)
 518         (message "Hit space to flush")
 519         (let ((ch (read-event)))
 520           (if (eq ch ?\ )
 521               (set-window-configuration conf)
 522             (setq unread-command-events (list ch))))))))
 523
 524 (defun eshell-hist-word-reference (ref)
 525   "Return the word designator index referred to by REF."
 526   (cond
 527    ((string-match "^[0-9]+$" ref)
 528     (string-to-number ref))
 529    ((string= "^" ref) 1)
 530    ((string= "$" ref) nil)
 531    ((string= "%" ref)
 532     (error "`%%' history word designator not yet implemented"))))
 533
 534 (defun eshell-hist-parse-arguments (&optional b e)
 535   "Parse current command arguments in a history-code-friendly way."
 536   (let ((end (or e (point)))
 537         (begin (or b (save-excursion (eshell-bol) (point))))
 538         (posb (list t))
 539         (pose (list t))
 540         (textargs (list t))
 541         hist args)
 542     (unless (catch 'eshell-incomplete
 543               (ignore
 544                (setq args (eshell-parse-arguments begin end))))
 545       (save-excursion
 546         (goto-char begin)
 547         (while (< (point) end)
 548           (if (get-text-property (point) 'arg-begin)
 549               (nconc posb (list (point))))
 550           (if (get-text-property (point) 'arg-end)
 551               (nconc pose
 552                      (list (if (= (1+ (point)) end)
 553                                (1+ (point))
 554                              (point)))))
 555           (forward-char))
 556         (setq posb (cdr posb)
 557               pose (cdr pose))
 558         (cl-assert (= (length posb) (length args)))
 559         (cl-assert (<= (length posb) (length pose))))
 560       (setq hist (buffer-substring-no-properties begin end))
 561       (let ((b posb) (e pose))
 562         (while b
 563           (nconc textargs
 564                  (list (substring hist (- (car b) begin)
 565                                   (- (car e) begin))))
 566           (setq b (cdr b)
 567                 e (cdr e))))
 568       (setq textargs (cdr textargs))
 569       (cl-assert (= (length textargs) (length args)))
 570       (list textargs posb pose))))
 571
 572 (defun eshell-expand-history-references (beg end)
 573   "Parse and expand any history references in current input."
 574   (let ((result (eshell-hist-parse-arguments beg end)))
 575     (when result
 576       (let ((textargs (nreverse (nth 0 result)))
 577             (posb (nreverse (nth 1 result)))
 578             (pose (nreverse (nth 2 result))))
 579         (save-excursion
 580           (while textargs
 581             (let ((str (eshell-history-reference (car textargs))))
 582               (unless (eq str (car textargs))
 583                 (goto-char (car posb))
 584                 (insert-and-inherit str)
 585                 (delete-char (- (car pose) (car posb)))))
 586             (setq textargs (cdr textargs)
 587                   posb (cdr posb)
 588                   pose (cdr pose))))))))
 589
 590 (defvar pcomplete-stub)
 591 (defvar pcomplete-last-completion-raw)
 592 (declare-function pcomplete-actual-arg "pcomplete")
 593
 594 (defun eshell-complete-history-reference ()
 595   "Complete a history reference, by completing the event designator."
 596   (let ((arg (pcomplete-actual-arg)))
 597     (when (string-match "\\`![^:^$*%]*\\'" arg)
 598       (setq pcomplete-stub (substring arg 1)
 599             pcomplete-last-completion-raw t)
 600       (throw 'pcomplete-completions
 601              (let ((history nil)
 602                    (index (1- (ring-length eshell-history-ring)))
 603                    (stublen (length pcomplete-stub)))
 604                ;; We have to build up a list ourselves from the ring
 605                ;; vector.
 606                (while (>= index 0)
 607                  (let ((hist (eshell-get-history index)))
 608                    (if (and (>= (length hist) stublen)
 609                             (string= (substring hist 0 stublen)
 610                                      pcomplete-stub)
 611                             (string-match "^\\([^:^$*% \t\n]+\\)" hist))
 612                        (setq history (cons (match-string 1 hist)
 613                                            history))))
 614                  (setq index (1- index)))
 615                (let ((fhist (list t)))
 616                  ;; uniquify the list, but preserve the order
 617                  (while history
 618                    (unless (member (car history) fhist)
 619                      (nconc fhist (list (car history))))
 620                    (setq history (cdr history)))
 621                  (cdr fhist)))))))
 622
 623 (defun eshell-history-reference (reference)
 624   "Expand directory stack REFERENCE.
 625 The syntax used here was taken from the Bash info manual.
 626 Returns the resultant reference, or the same string REFERENCE if none
 627 matched."
 628   ;; `^string1^string2^'
 629   ;;      Quick Substitution.  Repeat the last command, replacing
 630   ;;      STRING1 with STRING2.  Equivalent to `!!:s/string1/string2/'
 631   (if (and (eshell-using-module 'eshell-pred)
 632            (string-match "\\^\\([^^]+\\)\\^\\([^^]+\\)\\^?\\s-*$"
 633                          reference))
 634       (setq reference (format "!!:s/%s/%s/"
 635                               (match-string 1 reference)
 636                               (match-string 2 reference))))
 637   ;; `!'
 638   ;;      Start a history substitution, except when followed by a
 639   ;;      space, tab, the end of the line, = or (.
 640   (if (not (string-match "^![^ \t\n=\(]" reference))
 641       reference
 642     (setq eshell-history-index nil)
 643     (let ((event (eshell-hist-parse-event-designator reference)))
 644       (unless event
 645         (error "Could not find history event `%s'" reference))
 646       (setq eshell-history-index (car event)
 647             reference (substring reference (cdr event))
 648             event (eshell-get-history eshell-history-index))
 649       (if (not (string-match "^[:^$*%]" reference))
 650           event
 651         (let ((word (eshell-hist-parse-word-designator
 652                      event reference)))
 653           (unless word
 654             (error "Unable to honor word designator `%s'" reference))
 655           (unless (string-match "^[:^$*%][[$^*%0-9-]" reference)
 656             (setcdr word 0))
 657           (setq event (car word)
 658                 reference (substring reference (cdr word)))
 659           (if (not (and (eshell-using-module 'eshell-pred)
 660                         (string-match "^:" reference)))
 661               event
 662             (eshell-hist-parse-modifier event reference)))))))
 663
 664 (defun eshell-hist-parse-event-designator (reference)
 665   "Parse a history event designator beginning in REFERENCE."
 666   (let* ((index (string-match eshell-hist-event-designator reference))
 667          (end (and index (match-end 0))))
 668     (unless index
 669       (error "Invalid history event designator `%s'" reference))
 670     (let* ((event (match-string 1 reference))
 671            (pos
 672             (cond
 673              ((string= event "!") (ring-length eshell-history-ring))
 674              ((string= event "#") (error "!# not yet implemented"))
 675              ((string-match "^-?[0-9]+$" event)
 676               (let ((num (string-to-number event)))
 677                 (if (>= num 0)
 678                     (- (ring-length eshell-history-ring) num)
 679                   (1- (abs num)))))
 680              ((string-match "^\\(\\??\\)\\([^?]+\\)\\??$" event)
 681               (let ((pref (if (> (length (match-string 1 event)) 0)
 682                               "" "^"))
 683                     (str (match-string 2 event)))
 684                 (save-match-data
 685                   (eshell-previous-matching-input-string-position
 686                    (concat pref (regexp-quote str)) 1))))
 687              (t
 688               (error "Failed to parse event designator `%s'" event)))))
 689       (and pos (cons pos end)))))
 690
 691 (defun eshell-hist-parse-word-designator (hist reference)
 692   "Parse a history word designator beginning for HIST in REFERENCE."
 693   (let* ((index (string-match eshell-hist-word-designator reference))
 694          (end (and index (match-end 0))))
 695     (unless (memq (aref reference 0) '(?: ?^ ?$ ?* ?%))
 696       (error "Invalid history word designator `%s'" reference))
 697     (let ((nth (match-string 1 reference))
 698           (mth (match-string 2 reference))
 699           (here (point))
 700           textargs)
 701       (insert hist)
 702       (setq textargs (car (eshell-hist-parse-arguments here (point))))
 703       (delete-region here (point))
 704       (if (string= nth "*")
 705           (if mth
 706               (error "Invalid history word designator `%s'"
 707                      reference)
 708             (setq nth 1 mth "-$")))
 709       (if (not mth)
 710           (if nth
 711               (setq mth nth)
 712             (setq nth 0 mth "$"))
 713         (if (string= mth "-")
 714             (setq mth (- (length textargs) 2))
 715           (if (string= mth "*")
 716               (setq mth "$")
 717             (if (not (and (> (length mth) 1)
 718                           (eq (aref mth 0) ?-)))
 719                 (error "Invalid history word designator `%s'"
 720                        reference)
 721               (setq mth (substring mth 1))))))
 722       (unless (numberp nth)
 723         (setq nth (eshell-hist-word-reference nth)))
 724       (unless (numberp mth)
 725         (setq mth (eshell-hist-word-reference mth)))
 726       (cons (mapconcat 'identity (eshell-sublist textargs nth mth) "")
 727             end))))
 728
 729 (defun eshell-hist-parse-modifier (hist reference)
 730   "Parse a history modifier beginning for HIST in REFERENCE."
 731   (let ((here (point)))
 732     (insert reference)
 733     (prog1
 734         (save-restriction
 735           (narrow-to-region here (point))
 736           (goto-char (point-min))
 737           (let ((modifiers (cdr (eshell-parse-modifiers))))
 738             (dolist (mod modifiers)
 739               (setq hist (funcall mod hist)))
 740             hist))
 741       (delete-region here (point)))))
 742
 743 (defun eshell-get-next-from-history ()
 744   "After fetching a line from input history, this fetches the next.
 745 In other words, this recalls the input line after the line you
 746 recalled last.  You can use this to repeat a sequence of input lines."
 747   (interactive)
 748   (if eshell-save-history-index
 749       (progn
 750         (setq eshell-history-index (1+ eshell-save-history-index))
 751         (eshell-next-input 1))
 752     (message "No previous history command")))
 753
 754 (defun eshell-search-arg (arg)
 755   ;; First make sure there is a ring and that we are after the process
 756   ;; mark
 757   (if (and eshell-hist-move-to-end
 758            (< (point) eshell-last-output-end))
 759       (goto-char eshell-last-output-end))
 760   (cond ((or (null eshell-history-ring)
 761              (ring-empty-p eshell-history-ring))
 762          (error "Empty input ring"))
 763         ((zerop arg)
 764          ;; arg of zero resets search from beginning, and uses arg of
 765          ;; 1
 766          (setq eshell-history-index nil)
 767          1)
 768         (t
 769          arg)))
 770
 771 (defun eshell-search-start (arg)
 772   "Index to start a directional search, starting at `eshell-history-index'."
 773   (if eshell-history-index
 774       ;; If a search is running, offset by 1 in direction of arg
 775       (mod (+ eshell-history-index (if (> arg 0) 1 -1))
 776            (ring-length eshell-history-ring))
 777     ;; For a new search, start from beginning or end, as appropriate
 778     (if (>= arg 0)
 779         0                               ; First elt for forward search
 780       ;; Last elt for backward search
 781       (1- (ring-length eshell-history-ring)))))
 782
 783 (defun eshell-previous-input-string (arg)
 784   "Return the string ARG places along the input ring.
 785 Moves relative to `eshell-history-index'."
 786   (eshell-get-history (if eshell-history-index
 787                           (mod (+ arg eshell-history-index)
 788                                (ring-length eshell-history-ring))
 789                         arg)))
 790
 791 (defun eshell-previous-input (arg)
 792   "Cycle backwards through input history."
 793   (interactive "*p")
 794   (eshell-previous-matching-input "." arg))
 795
 796 (defun eshell-next-input (arg)
 797   "Cycle forwards through input history."
 798   (interactive "*p")
 799   (eshell-previous-input (- arg)))
 800
 801 (defun eshell-previous-matching-input-string (regexp arg)
 802   "Return the string matching REGEXP ARG places along the input ring.
 803 Moves relative to `eshell-history-index'."
 804   (let* ((pos (eshell-previous-matching-input-string-position regexp arg)))
 805     (if pos (eshell-get-history pos))))
 806
 807 (defun eshell-previous-matching-input-string-position
 808   (regexp arg &optional start)
 809   "Return the index matching REGEXP ARG places along the input ring.
 810 Moves relative to START, or `eshell-history-index'."
 811   (if (or (not (ring-p eshell-history-ring))
 812           (ring-empty-p eshell-history-ring))
 813       (error "No history"))
 814   (let* ((len (ring-length eshell-history-ring))
 815          (motion (if (> arg 0) 1 -1))
 816          (n (mod (- (or start (eshell-search-start arg)) motion) len))
 817          (tried-each-ring-item nil)
 818          (case-fold-search (eshell-under-windows-p))
 819          (prev nil))
 820     ;; Do the whole search as many times as the argument says.
 821     (while (and (/= arg 0) (not tried-each-ring-item))
 822       ;; Step once.
 823       (setq prev n
 824             n (mod (+ n motion) len))
 825       ;; If we haven't reached a match, step some more.
 826       (while (and (< n len) (not tried-each-ring-item)
 827                   (not (string-match regexp (eshell-get-history n))))
 828         (setq n (mod (+ n motion) len)
 829               ;; If we have gone all the way around in this search.
 830               tried-each-ring-item (= n prev)))
 831       (setq arg (if (> arg 0) (1- arg) (1+ arg))))
 832     ;; Now that we know which ring element to use, if we found it,
 833     ;; return that.
 834     (if (string-match regexp (eshell-get-history n))
 835         n)))
 836
 837 (defun eshell-previous-matching-input (regexp arg)
 838   "Search backwards through input history for match for REGEXP.
 839 \(Previous history elements are earlier commands.)
 840 With prefix argument N, search for Nth previous match.
 841 If N is negative, find the next or Nth next match."
 842   (interactive (eshell-regexp-arg "Previous input matching (regexp): "))
 843   (setq arg (eshell-search-arg arg))
 844   (if (> eshell-last-output-end (point))
 845       (error "Point not located after prompt"))
 846   (let ((pos (eshell-previous-matching-input-string-position regexp arg)))
 847     ;; Has a match been found?
 848     (if (null pos)
 849         (error "Not found")
 850       (setq eshell-history-index pos)
 851       (unless (minibuffer-window-active-p (selected-window))
 852         (message "History item: %d" (- (ring-length eshell-history-ring) pos)))
 853       ;; Can't use kill-region as it sets this-command
 854       (delete-region eshell-last-output-end (point))
 855       (insert-and-inherit (eshell-get-history pos)))))
 856
 857 (defun eshell-next-matching-input (regexp arg)
 858   "Search forwards through input history for match for REGEXP.
 859 \(Later history elements are more recent commands.)
 860 With prefix argument N, search for Nth following match.
 861 If N is negative, find the previous or Nth previous match."
 862   (interactive (eshell-regexp-arg "Next input matching (regexp): "))
 863   (eshell-previous-matching-input regexp (- arg)))
 864
 865 (defun eshell-previous-matching-input-from-input (arg)
 866   "Search backwards through input history for match for current input.
 867 \(Previous history elements are earlier commands.)
 868 With prefix argument N, search for Nth previous match.
 869 If N is negative, search forwards for the -Nth following match."
 870   (interactive "p")
 871   (if (not (memq last-command '(eshell-previous-matching-input-from-input
 872                                 eshell-next-matching-input-from-input)))
 873       ;; Starting a new search
 874       (setq eshell-matching-input-from-input-string
 875             (buffer-substring (save-excursion (eshell-bol) (point))
 876                               (point))
 877             eshell-history-index nil))
 878   (eshell-previous-matching-input
 879    (concat "^" (regexp-quote eshell-matching-input-from-input-string))
 880    arg))
 881
 882 (defun eshell-next-matching-input-from-input (arg)
 883   "Search forwards through input history for match for current input.
 884 \(Following history elements are more recent commands.)
 885 With prefix argument N, search for Nth following match.
 886 If N is negative, search backwards for the -Nth previous match."
 887   (interactive "p")
 888   (eshell-previous-matching-input-from-input (- arg)))
 889
 890 (defun eshell-test-imatch ()
 891   "If isearch match good, put point at the beginning and return non-nil."
 892   (if (get-text-property (point) 'history)
 893       (progn (beginning-of-line) t)
 894     (let ((before (point)))
 895       (eshell-bol)
 896       (if (and (not (bolp))
 897                (<= (point) before))
 898           t
 899         (if isearch-forward
 900             (progn
 901               (end-of-line)
 902               (forward-char))
 903           (beginning-of-line)
 904           (backward-char))))))
 905
 906 (defun eshell-return-to-prompt ()
 907   "Once a search string matches, insert it at the end and go there."
 908   (setq isearch-other-end nil)
 909   (let ((found (eshell-test-imatch)) before)
 910     (while (and (not found)
 911                 (setq before
 912                       (funcall (if isearch-forward
 913                                    're-search-forward
 914                                  're-search-backward)
 915                                isearch-string nil t)))
 916       (setq found (eshell-test-imatch)))
 917     (if (not found)
 918         (progn
 919           (goto-char eshell-last-output-end)
 920           (delete-region (point) (point-max)))
 921       (setq before (point))
 922       (let ((text (buffer-substring-no-properties
 923                    (point) (line-end-position)))
 924             (orig (marker-position eshell-last-output-end)))
 925         (goto-char eshell-last-output-end)
 926         (delete-region (point) (point-max))
 927         (when (and text (> (length text) 0))
 928           (insert text)
 929           (put-text-property (1- (point)) (point)
 930                              'last-search-pos before)
 931           (set-marker eshell-last-output-end orig)
 932           (goto-char eshell-last-output-end))))))
 933
 934 (defun eshell-prepare-for-search ()
 935   "Make sure the old history file is at the beginning of the buffer."
 936   (unless (get-text-property (point-min) 'history)
 937     (save-excursion
 938       (goto-char (point-min))
 939       (let ((end (copy-marker (point) t)))
 940         (insert-file-contents eshell-history-file-name)
 941         (set-text-properties (point-min) end
 942                              '(history t invisible t))))))
 943
 944 (defun eshell-isearch-backward (&optional invert)
 945   "Do incremental regexp search backward through past commands."
 946   (interactive)
 947   (let ((inhibit-read-only t))
 948     (eshell-prepare-for-search)
 949     (goto-char (point-max))
 950     (set-marker eshell-last-output-end (point))
 951     (delete-region (point) (point-max)))
 952   (isearch-mode invert t 'eshell-return-to-prompt))
 953
 954 (defun eshell-isearch-repeat-backward (&optional invert)
 955   "Do incremental regexp search backward through past commands."
 956   (interactive)
 957   (let ((old-pos (get-text-property (1- (point-max))
 958                                     'last-search-pos)))
 959     (when old-pos
 960       (goto-char old-pos)
 961       (if invert
 962           (end-of-line)
 963         (backward-char)))
 964     (setq isearch-forward invert)
 965     (isearch-search-and-update)))
 966
 967 (defun eshell-isearch-forward ()
 968   "Do incremental regexp search backward through past commands."
 969   (interactive)
 970   (eshell-isearch-backward t))
 971
 972 (defun eshell-isearch-repeat-forward ()
 973   "Do incremental regexp search backward through past commands."
 974   (interactive)
 975   (eshell-isearch-repeat-backward t))
 976
 977 (defun eshell-isearch-cancel ()
 978   (interactive)
 979   (goto-char eshell-last-output-end)
 980   (delete-region (point) (point-max))
 981   (call-interactively 'isearch-cancel))
 982
 983 (defun eshell-isearch-abort ()
 984   (interactive)
 985   (goto-char eshell-last-output-end)
 986   (delete-region (point) (point-max))
 987   (call-interactively 'isearch-abort))
 988
 989 (defun eshell-isearch-delete-char ()
 990   (interactive)
 991   (save-excursion
 992   (isearch-delete-char)))
 993
 994 (defun eshell-isearch-return ()
 995   (interactive)
 996   (isearch-done)
 997   (eshell-send-input))
 998
 999 (provide 'em-hist)
1000
1001 ;; Local Variables:
1002 ;; generated-autoload-file: "esh-groups.el"
1003 ;; End:
1004
1005 ;;; em-hist.el ends here