lisp/vms-patch.el

   1 ;;; vms-patch.el --- override parts of files.el for VMS
   2
   3 ;; Copyright (C) 1986, 1992, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: vms
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar print-region-function)
  31
  32 (setq auto-mode-alist (cons '(("\\.com\\'" . dcl-mode)) auto-mode-alist))
  33
  34 ;;; Functions that need redefinition
  35
  36 ;;; VMS file names are upper case, but buffer names are more
  37 ;;; convenient in lower case.
  38
  39 (defun create-file-buffer (filename)
  40   "Create a suitably named buffer for visiting FILENAME, and return it.
  41 FILENAME (sans directory) is used unchanged if that name is free;
  42 otherwise a string <2> or <3> or ... is appended to get an unused name."
  43   (generate-new-buffer (downcase (file-name-nondirectory filename))))
  44
  45 ;;; Given a string FN, return a similar name which is a legal VMS filename.
  46 ;;; This is used to avoid invalid auto save file names.
  47 (defun make-legal-file-name (fn)
  48   (setq fn (copy-sequence fn))
  49   (let ((dot nil) (indx 0) (len (length fn)) chr)
  50     (while (< indx len)
  51       (setq chr (aref fn indx))
  52       (cond
  53        ((eq chr ?.) (if dot (aset fn indx ?_) (setq dot t)))
  54        ((not (or (and (>= chr ?a) (<= chr ?z)) (and (>= chr ?A) (<= chr ?Z))
  55                  (and (>= chr ?0) (<= chr ?9))
  56                  (eq chr ?$) (eq chr ?_) (and (eq chr ?-) (> indx 0))))
  57         (aset fn indx ?_)))
  58       (setq indx (1+ indx))))
  59   fn)
  60
  61 ;;; Auto save filesnames start with _$ and end with $.
  62
  63 (defun make-auto-save-file-name ()
  64   "Return file name to use for auto-saves of current buffer.
  65 This function does not consider `auto-save-visited-file-name';
  66 the caller should check that before calling this function.
  67 This is a separate function so that your `.emacs' file or the site's
  68 `site-init.el' can redefine it.
  69 See also `auto-save-file-name-p'."
  70   (if buffer-file-name
  71       (concat (file-name-directory buffer-file-name)
  72               "_$"
  73               (file-name-nondirectory buffer-file-name)
  74               "$")
  75     (expand-file-name (concat "_$_" (make-legal-file-name (buffer-name)) "$"))))
  76
  77 (defun auto-save-file-name-p (filename)
  78   "Return t if FILENAME can be yielded by `make-auto-save-file-name'.
  79 FILENAME should lack slashes.
  80 This is a separate function so that your `.emacs' file or the site's
  81 `site-init.el' can redefine it."
  82   (string-match "^_\\$.*\\$" filename))
  83
  84 ;;;
  85 ;;; This goes along with kepteditor.com which defines these logicals
  86 ;;; If EMACS_COMMAND_ARGS is defined, it supersedes EMACS_FILE_NAME,
  87 ;;;   which is probably set up incorrectly anyway.
  88 ;;; The function command-line-again is a kludge, but it does the job.
  89 ;;;
  90 (defun vms-suspend-resume-hook ()
  91   "When resuming suspended Emacs, check for file to be found.
  92 If the logical name `EMACS_FILE_NAME' is defined, `find-file' that file."
  93   (let ((file (vms-system-info "LOGICAL" "EMACS_FILE_NAME"))
  94         (args (vms-system-info "LOGICAL" "EMACS_COMMAND_ARGS"))
  95         (line (vms-system-info "LOGICAL" "EMACS_FILE_LINE")))
  96     (if (not args)
  97         (if file
  98             (progn (find-file file)
  99                    (if line (goto-line (string-to-number line)))))
 100       (cd (file-name-directory file))
 101       (vms-command-line-again))))
 102
 103 (setq suspend-resume-hook 'vms-suspend-resume-hook)
 104
 105 (defun vms-suspend-hook ()
 106   "Don't allow suspending if logical name `DONT_SUSPEND_EMACS' is defined."
 107   (if (vms-system-info "LOGICAL" "DONT_SUSPEND_EMACS")
 108       (error "Can't suspend this emacs"))
 109   nil)
 110
 111 (setq suspend-hook 'vms-suspend-hook)
 112
 113 ;;;
 114 ;;; A kludge that allows reprocessing of the command line.  This is mostly
 115 ;;;   to allow a spawned VMS mail process to do something reasonable when
 116 ;;;   used in conjunction with the modifications to sysdep.c that allow
 117 ;;;   Emacs to attach to a "foster" parent.
 118 ;;;
 119 (defun vms-command-line-again ()
 120   "Reprocess command line arguments.  VMS specific.
 121 Command line arguments are initialized from the logical EMACS_COMMAND_ARGS
 122 which is defined by kepteditor.com.  On VMS this allows attaching to a
 123 spawned Emacs and doing things like \"emacs -l myfile.el -f doit\""
 124   (let* ((args (downcase (vms-system-info "LOGICAL" "EMACS_COMMAND_ARGS")))
 125          (command-line-args (list "emacs"))
 126          (beg 0)
 127          (end 0)
 128          (len (length args))
 129          this-char)
 130     (if args
 131         (progn
 132 ;;; replace non-printable stuff with spaces
 133           (while (< beg (length args))
 134             (if (or (> 33 (setq this-char (aref args beg)))
 135                     (< 127 this-char))
 136                 (aset args beg 32))
 137             (setq beg (1+ beg)))
 138           (setq beg (1- (length args)))
 139           (while (= 32 (aref args beg)) (setq beg (1- beg)))
 140           (setq args (substring args 0 (1+ beg)))
 141           (setq beg 0)
 142 ;;; now start parsing args
 143           (while (< beg (length args))
 144             (while (and (< beg (length args))
 145                         (or (> 33 (setq this-char (aref args beg)))
 146                             (< 127 this-char))
 147                         (setq beg (1+ beg))))
 148             (setq end (1+ beg))
 149             (while (and (< end (length args))
 150                         (< 32 (setq this-char (aref args end)))
 151                         (> 127 this-char))
 152               (setq end (1+ end)))
 153             (setq command-line-args (append
 154                                      command-line-args
 155                                      (list (substring args beg end))))
 156             (setq beg (1+ end)))
 157           (command-line)))))
 158
 159 (defun vms-read-directory (dirname switches buffer)
 160   (save-excursion
 161     (set-buffer buffer)
 162     (subprocess-command-to-buffer
 163      (concat "DIRECTORY " switches " " dirname)
 164      buffer)
 165     (goto-char (point-min))
 166     ;; Remove all the trailing blanks.
 167     (while (search-forward " \n")
 168       (forward-char -1)
 169       (delete-horizontal-space))
 170     (goto-char (point-min))))
 171
 172 (setq dired-listing-switches
 173       "/SIZE/DATE/OWNER/WIDTH=(FILENAME=32,SIZE=5)")
 174
 175 (setq print-region-function
 176       (lambda (start end command ign1 ign2 ign3 &rest switches)
 177          (write-region start end "sys$login:delete-me.txt")
 178          (send-command-to-subprocess
 179           1
 180           (concat command
 181                   " sys$login:delete-me.txt/name=\"GNUprintbuffer\" "
 182                   (mapconcat 'identity switches " "))
 183           nil nil nil)))
 184
 185 ;;;
 186 ;;; Fuctions for using Emacs as a VMS Mail editor
 187 ;;;
 188 (autoload 'vms-pmail-setup "vms-pmail"
 189   "Set up file assuming use by VMS Mail utility.
 190 The buffer is put into text-mode, auto-save is turned off and the
 191 following bindings are established.
 192
 193 \\[vms-pmail-save-and-exit]     vms-pmail-save-and-exit
 194 \\[vms-pmail-abort]     vms-pmail-abort
 195
 196 All other Emacs commands are still available."
 197   t)
 198
 199 ;;;
 200 ;;; Filename handling in the minibuffer
 201 ;;;
 202 (defun vms-magic-right-square-brace ()
 203   "\
 204 Insert a right square brace, but do other things first depending on context.
 205 During filename completion, when point is at the end of the line and the
 206 character before is not a right square brace, do one of three things before
 207 inserting the brace:
 208  - If there are already two left square braces preceding, do nothing special.
 209  - If there is a previous right-square-brace, convert it to dot.
 210  - If the character before is dot, delete it.
 211 Additionally, if the preceding chars are right-square-brace followed by
 212 either \"-\" or \"..\", strip one level of directory hierarchy."
 213   (interactive)
 214   (when (and minibuffer-completing-file-name
 215              (= (point) (point-max))
 216              (not (= 93 (char-before))))
 217     (cond
 218      ;; Avoid clobbering: user:[one.path][another.path
 219      ((search-backward "[" (field-beginning) t 2))
 220      ((search-backward "]" (field-beginning) t)
 221       (delete-char 1)
 222       (insert ".")
 223       (goto-char (point-max)))
 224      ((= ?. (char-before))
 225       (delete-char -1)))
 226     (goto-char (point-max))
 227     (let ((specs '(".." "-"))
 228           (pmax (point-max)))
 229       (while specs
 230         (let* ((up (car specs))
 231                (len (length up))
 232                (cut (- (point) len)))
 233           (when (and (< (1+ len) pmax)
 234                      (= ?. (char-before cut))
 235                      (string= up (buffer-substring cut (point))))
 236             (delete-char (- (1+ len)))
 237             (while (not (let ((c (char-before)))
 238                           (or (= ?. c) (= 91 c))))
 239               (delete-char -1))
 240             (when (= ?. (char-before)) (delete-char -1))
 241             (setq specs nil)))
 242         (setq specs (cdr specs)))))
 243   (insert "]"))
 244
 245 (defun vms-magic-colon ()
 246   "\
 247 Insert a colon, but do other things first depending on context.
 248 During filename completion, when point is at the end of the line
 249 and the line contains a right square brace, remove all characters
 250 from the beginning of the line up to and including such brace.
 251 This enables one to type a new filespec without having to delete
 252 the old one."
 253   (interactive)
 254   (when (and minibuffer-completing-file-name
 255              (= (point) (point-max))
 256              (search-backward "]" (field-beginning) t))
 257     (delete-region (field-beginning) (1+ (point)))
 258     (goto-char (point-max)))
 259   (insert ":"))
 260
 261 (let ((m minibuffer-local-completion-map))
 262   (define-key m "]" 'vms-magic-right-square-brace)
 263   (define-key m "/" 'vms-magic-right-square-brace)
 264   (define-key m ":" 'vms-magic-colon))
 265
 266 ;;; arch-tag: c178494e-2c37-4d02-99b7-e47e615656cf
 267 ;;; vms-patch.el ends here