lisp/url/url-file.el

   1 ;;; url-file.el --- File retrieval code
   2
   3 ;; Copyright (C) 1996, 1997, 1998, 1999, 2004, 2005, 2006, 2007, 2008,
   4 ;;   2009, 2010  Free Software Foundation, Inc.
   5
   6 ;; Keywords: comm, data, processes
   7
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28 (require 'mailcap)
  29 (require 'url-vars)
  30 (require 'url-parse)
  31 (require 'url-dired)
  32
  33 (defconst url-file-default-port 21 "Default FTP port.")
  34 (defconst url-file-asynchronous-p t "FTP transfers are asynchronous.")
  35 (defalias 'url-file-expand-file-name 'url-default-expander)
  36
  37 (defun url-file-find-possibly-compressed-file (fname &rest args)
  38   "Find the exact file referenced by `fname'.
  39 This tries the common compression extensions, because things like
  40 ange-ftp and efs are not quite smart enough to realize when a server
  41 can do automatic decompression for them, and won't find 'foo' if
  42 'foo.gz' exists, even though the FTP server would happily serve it up
  43 to them."
  44   (let ((scratch nil)
  45         (compressed-extensions '("" ".gz" ".z" ".Z" ".bz2"))
  46         (found nil))
  47     (while (and compressed-extensions (not found))
  48       (if (file-exists-p (setq scratch (concat fname (pop compressed-extensions))))
  49           (setq found scratch)))
  50     found))
  51
  52 (defun url-file-host-is-local-p (host)
  53   "Return t if HOST references our local machine."
  54   (let ((case-fold-search t))
  55     (or
  56      (null host)
  57      (string= "" host)
  58      (equal (downcase host) (downcase (system-name)))
  59      (and (string-match "^localhost$" host) t)
  60      (and (not (string-match (regexp-quote ".") host))
  61           (equal (downcase host) (if (string-match (regexp-quote ".")
  62                                                    (system-name))
  63                                      (substring (system-name) 0
  64                                                 (match-beginning 0))
  65                                    (system-name)))))))
  66
  67 (defun url-file-asynch-callback (x y name buff func args &optional efs)
  68   (if (not (featurep 'ange-ftp))
  69       ;; EFS passes us an extra argument
  70       (setq name buff
  71             buff func
  72             func args
  73             args efs))
  74   (let ((size (nth 7 (file-attributes name))))
  75     (with-current-buffer buff
  76       (goto-char (point-max))
  77       (if (/= -1 size)
  78           (insert (format "Content-length: %d\n" size)))
  79       (insert "\n")
  80       (insert-file-contents-literally name)
  81       (if (not (url-file-host-is-local-p (url-host url-current-object)))
  82           (condition-case ()
  83               (delete-file name)
  84             (error nil)))
  85       (apply func args))))
  86
  87 (declare-function ange-ftp-set-passwd "ange-ftp" (host user passwd))
  88 (declare-function ange-ftp-copy-file-internal "ange-ftp"
  89                   (filename newname ok-if-already-exists
  90                             keep-date &optional msg cont nowait))
  91
  92 (defun url-file-build-filename (url)
  93   (if (not (vectorp url))
  94       (setq url (url-generic-parse-url url)))
  95   (let* ((user (url-user url))
  96          (pass (url-password url))
  97          (port (url-port url))
  98          (host (url-host url))
  99          (site (if (and port (/= port 21))
 100                    (if (featurep 'ange-ftp)
 101                        (format "%s %d" host port)
 102                      ;; This works in Emacs 21's ange-ftp too.
 103                      (format "%s#%d" host port))
 104                  host))
 105          (file (url-unhex-string (url-filename url)))
 106          (filename (if (or user (not (url-file-host-is-local-p host)))
 107                        (concat "/" (or user "anonymous") "@" site ":" file)
 108                      (if (and (memq system-type '(ms-dos windows-nt))
 109                               (string-match "^/[a-zA-Z]:/" file))
 110                          (substring file 1)
 111                        file)))
 112          pos-index)
 113
 114     (and user pass
 115          (cond
 116           ((featurep 'ange-ftp)
 117            (ange-ftp-set-passwd host user pass))
 118           ((when (featurep 'xemacs)
 119              (or (featurep 'efs) (featurep 'efs-auto)
 120                  (efs-set-passwd host user pass))))
 121           (t
 122            nil)))
 123
 124     ;; This makes sure that directories have a trailing directory
 125     ;; separator on them so URL expansion works right.
 126     ;;
 127     ;; FIXME?  What happens if the remote system doesn't use our local
 128     ;; directory-sep-char as its separator?  Would it be safer to just
 129     ;; use '/' unconditionally and rely on the FTP server to
 130     ;; straighten it out for us?
 131     ;; (if (and (file-directory-p filename)
 132     ;;          (not (string-match (format "%c$" directory-sep-char) filename)))
 133     ;;     (setf (url-filename url)
 134     ;;           (format "%s%c" filename directory-sep-char)))
 135     (if (and (file-directory-p filename)
 136              (not (string-match "/\\'" filename)))
 137         (setf (url-filename url) (format "%s/" filename)))
 138
 139
 140     ;; If it is a directory, look for an index file first.
 141     (if (and (file-directory-p filename)
 142              url-directory-index-file
 143              (setq pos-index (expand-file-name url-directory-index-file filename))
 144              (file-exists-p pos-index)
 145              (file-readable-p pos-index))
 146         (setq filename pos-index))
 147
 148     ;; Find the (possibly compressed) file
 149     (setq filename (url-file-find-possibly-compressed-file filename))
 150     filename))
 151
 152 ;;;###autoload
 153 (defun url-file (url callback cbargs)
 154   "Handle file: and ftp: URLs."
 155   (let* ((buffer nil)
 156          (uncompressed-filename nil)
 157          (content-type nil)
 158          (content-encoding nil)
 159          (coding-system-for-read 'binary)
 160          (filename (url-file-build-filename url)))
 161     (or filename (error "File does not exist: %s" (url-recreate-url url)))
 162     ;; Need to figure out the content-type from the real extension,
 163     ;; not the compressed one.
 164     (setq uncompressed-filename (if (string-match "\\.\\(gz\\|Z\\|z\\)$" filename)
 165                                     (substring filename 0 (match-beginning 0))
 166                                   filename))
 167     (setq content-type (mailcap-extension-to-mime
 168                         (url-file-extension uncompressed-filename))
 169           content-encoding (case (intern (url-file-extension filename))
 170                              ((\.z \.gz) "gzip")
 171                              (\.Z "compress")
 172                              (\.uue "x-uuencoded")
 173                              (\.hqx "x-hqx")
 174                              (\.bz2 "x-bzip2")
 175                              (otherwise nil)))
 176
 177     (if (file-directory-p filename)
 178         ;; A directory is done the same whether we are local or remote
 179         (url-find-file-dired filename)
 180       (with-current-buffer
 181           (setq buffer (generate-new-buffer " *url-file*"))
 182         (mm-disable-multibyte)
 183         (setq url-current-object url)
 184         (insert "Content-type: " (or content-type "application/octet-stream") "\n")
 185         (if content-encoding
 186             (insert "Content-transfer-encoding: " content-encoding "\n"))
 187         (if (url-file-host-is-local-p (url-host url))
 188               ;; Local files are handled slightly oddly
 189             (if (featurep 'ange-ftp)
 190                 (url-file-asynch-callback nil nil
 191                                           filename
 192                                           (current-buffer)
 193                                           callback cbargs)
 194               (url-file-asynch-callback nil nil nil
 195                                         filename
 196                                         (current-buffer)
 197                                         callback cbargs))
 198           ;; FTP handling
 199           (let ((new (make-temp-file
 200                       (format "url-tmp.%d" (user-real-uid)))))
 201             (if (featurep 'ange-ftp)
 202                 (ange-ftp-copy-file-internal filename (expand-file-name new) t
 203                                              nil t
 204                                              (list 'url-file-asynch-callback
 205                                                    new (current-buffer)
 206                                                    callback cbargs)
 207                                              t)
 208               (when (featurep 'xemacs)
 209                 (autoload 'efs-copy-file-internal "efs")
 210                 (efs-copy-file-internal filename (efs-ftp-path filename)
 211                                         new (efs-ftp-path new)
 212                                         t nil 0
 213                                         (list 'url-file-asynch-callback
 214                                               new (current-buffer)
 215                                               callback cbargs)
 216                                         0 nil)))))))
 217     buffer))
 218
 219 (defmacro url-file-create-wrapper (method args)
 220   `(defalias ',(intern (format "url-ftp-%s" method))
 221      (defun ,(intern (format "url-file-%s" method)) ,args
 222        ,(format "FTP/FILE URL wrapper around `%s' call." method)
 223        (setq url (url-file-build-filename url))
 224        (and url (,method ,@(remove '&rest (remove '&optional args)))))))
 225
 226 (url-file-create-wrapper file-exists-p (url))
 227 (url-file-create-wrapper file-attributes (url &optional id-format))
 228 (url-file-create-wrapper file-symlink-p (url))
 229 (url-file-create-wrapper file-readable-p (url))
 230 (url-file-create-wrapper file-writable-p (url))
 231 (url-file-create-wrapper file-executable-p (url))
 232 (url-file-create-wrapper directory-files (url &optional full match nosort))
 233 (url-file-create-wrapper file-truename (url &optional counter prev-dirs))
 234
 235 (provide 'url-file)
 236
 237 ;; arch-tag: 010e914a-7313-494b-8a8c-6495a862157d
 238 ;;; url-file.el ends here