lisp/help-mode.el

   1 ;;; help-mode.el --- `help-mode' used by *Help* buffers
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001, 2002,
   4 ;;   2003, 2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Defines `help-mode', which is the mode used by *Help* buffers, and
  29 ;; associated support machinery, such as adding hyperlinks, etc.,
  30
  31 ;;; Code:
  32
  33 (require 'button)
  34 (require 'view)
  35
  36 (defvar help-mode-map (make-sparse-keymap)
  37   "Keymap for help mode.")
  38
  39 (set-keymap-parent help-mode-map button-buffer-map)
  40
  41 (define-key help-mode-map [mouse-2] 'help-follow-mouse)
  42 (define-key help-mode-map "\C-c\C-b" 'help-go-back)
  43 (define-key help-mode-map "\C-c\C-c" 'help-follow)
  44 ;; Documentation only, since we use minor-mode-overriding-map-alist.
  45 (define-key help-mode-map "\r" 'help-follow)
  46
  47 (defvar help-xref-stack nil
  48   "A stack of ways by which to return to help buffers after following xrefs.
  49 Used by `help-follow' and `help-xref-go-back'.
  50 An element looks like (POSITION FUNCTION ARGS...).
  51 To use the element, do (apply FUNCTION ARGS) then goto the point.")
  52 (put 'help-xref-stack 'permanent-local t)
  53 (make-variable-buffer-local 'help-xref-stack)
  54
  55 (defvar help-xref-stack-item nil
  56   "An item for `help-follow' in this buffer to push onto `help-xref-stack'.
  57 The format is (FUNCTION ARGS...).")
  58 (put 'help-xref-stack-item 'permanent-local t)
  59 (make-variable-buffer-local 'help-xref-stack-item)
  60
  61 (setq-default help-xref-stack nil help-xref-stack-item nil)
  62
  63 (defcustom help-mode-hook nil
  64   "Hook run by `help-mode'."
  65   :type 'hook
  66   :group 'help)
  67 \f
  68 ;; Button types used by help
  69
  70 (define-button-type 'help-xref
  71   'follow-link t
  72   'action #'help-button-action)
  73
  74 (defun help-button-action (button)
  75   "Call BUTTON's help function."
  76   (help-do-xref (button-start button)
  77                 (button-get button 'help-function)
  78                 (button-get button 'help-args)))
  79
  80 ;; These 6 calls to define-button-type were generated in a dolist
  81 ;; loop, but that is bad because it means these button types don't
  82 ;; have an easily found definition.
  83
  84 (define-button-type 'help-function
  85   :supertype 'help-xref
  86   'help-function 'describe-function
  87   'help-echo (purecopy "mouse-2, RET: describe this function"))
  88
  89 (define-button-type 'help-variable
  90   :supertype 'help-xref
  91   'help-function 'describe-variable
  92   'help-echo (purecopy "mouse-2, RET: describe this variable"))
  93
  94 (define-button-type 'help-face
  95   :supertype 'help-xref
  96   'help-function 'describe-face
  97   'help-echo (purecopy "mouse-2, RET: describe this face"))
  98
  99 (define-button-type 'help-coding-system
 100   :supertype 'help-xref
 101   'help-function 'describe-coding-system
 102   'help-echo (purecopy "mouse-2, RET: describe this coding system"))
 103
 104 (define-button-type 'help-input-method
 105   :supertype 'help-xref
 106   'help-function 'describe-input-method
 107   'help-echo (purecopy "mouse-2, RET: describe this input method"))
 108
 109 (define-button-type 'help-character-set
 110   :supertype 'help-xref
 111   'help-function 'describe-character-set
 112   'help-echo (purecopy "mouse-2, RET: describe this character set"))
 113
 114 ;; make some more ideosyncratic button types
 115
 116 (define-button-type 'help-symbol
 117   :supertype 'help-xref
 118   'help-function #'help-xref-interned
 119   'help-echo (purecopy "mouse-2, RET: describe this symbol"))
 120
 121 (define-button-type 'help-back
 122   :supertype 'help-xref
 123   'help-function #'help-xref-go-back
 124   'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
 125
 126 (define-button-type 'help-info
 127   :supertype 'help-xref
 128   'help-function #'info
 129   'help-echo (purecopy "mouse-2, RET: read this Info node"))
 130
 131 (define-button-type 'help-url
 132   :supertype 'help-xref
 133   'help-function #'browse-url
 134   'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
 135
 136 (define-button-type 'help-customize-variable
 137   :supertype 'help-xref
 138   'help-function (lambda (v)
 139                    (if help-xref-stack
 140                        (pop help-xref-stack))
 141                    (customize-variable v))
 142   'help-echo (purecopy "mouse-2, RET: customize variable"))
 143
 144 (define-button-type 'help-customize-face
 145   :supertype 'help-xref
 146   'help-function (lambda (v)
 147                    (if help-xref-stack
 148                        (pop help-xref-stack))
 149                    (customize-face v))
 150   'help-echo (purecopy "mouse-2, RET: customize face"))
 151
 152 (define-button-type 'help-function-def
 153   :supertype 'help-xref
 154   'help-function (lambda (fun file)
 155                    (require 'find-func)
 156                    (when (eq file 'C-source)
 157                      (setq file
 158                            (help-C-file-name (indirect-function fun) 'fun)))
 159                    ;; Don't use find-function-noselect because it follows
 160                    ;; aliases (which fails for built-in functions).
 161                    (let ((location
 162                           (find-function-search-for-symbol fun nil file)))
 163                      (pop-to-buffer (car location))
 164                      (goto-char (cdr location))))
 165   'help-echo (purecopy "mouse-2, RET: find function's definition"))
 166
 167 (define-button-type 'help-variable-def
 168   :supertype 'help-xref
 169   'help-function (lambda (var &optional file)
 170                    (when (eq file 'C-source)
 171                      (setq file (help-C-file-name var 'var)))
 172                    (let ((location (find-variable-noselect var file)))
 173                      (pop-to-buffer (car location))
 174                      (goto-char (cdr location))))
 175   'help-echo (purecopy"mouse-2, RET: find variable's definition"))
 176
 177 (define-button-type 'help-face-def
 178   :supertype 'help-xref
 179   'help-function (lambda (fun file)
 180                    (require 'find-func)
 181                    ;; Don't use find-function-noselect because it follows
 182                    ;; aliases (which fails for built-in functions).
 183                    (let ((location
 184                           (find-function-search-for-symbol fun 'defface file)))
 185                      (pop-to-buffer (car location))
 186                      (goto-char (cdr location))))
 187   'help-echo (purecopy "mouse-2, RET: find face's definition"))
 188
 189 \f
 190 ;;;###autoload
 191 (defun help-mode ()
 192   "Major mode for viewing help text and navigating references in it.
 193 Entry to this mode runs the normal hook `help-mode-hook'.
 194 Commands:
 195 \\{help-mode-map}"
 196   (interactive)
 197   (kill-all-local-variables)
 198   (use-local-map help-mode-map)
 199   (setq mode-name "Help")
 200   (setq major-mode 'help-mode)
 201   (view-mode)
 202   (make-local-variable 'view-no-disable-on-exit)
 203   (setq view-no-disable-on-exit t)
 204   (run-mode-hooks 'help-mode-hook))
 205
 206 ;;;###autoload
 207 (defun help-mode-setup ()
 208   (help-mode)
 209   (setq buffer-read-only nil))
 210
 211 ;;;###autoload
 212 (defun help-mode-finish ()
 213   (let ((entry (assq (selected-window) view-return-to-alist)))
 214         (if entry
 215             ;; When entering Help mode from the Help window,
 216             ;; such as by following a link, preserve the same
 217             ;; meaning for the q command.
 218             ;; (setcdr entry (cons (selected-window) help-return-method))
 219             nil
 220           (setq view-return-to-alist
 221                 (cons (cons (selected-window) help-return-method)
 222                       view-return-to-alist))))
 223   (when (eq major-mode 'help-mode)
 224     ;; View mode's read-only status of existing *Help* buffer is lost
 225     ;; by with-output-to-temp-buffer.
 226     (toggle-read-only 1)
 227     (help-make-xrefs (current-buffer))))
 228 \f
 229 ;; Grokking cross-reference information in doc strings and
 230 ;; hyperlinking it.
 231
 232 ;; This may have some scope for extension and the same or something
 233 ;; similar should be done for widget doc strings, which currently use
 234 ;; another mechanism.
 235
 236 (defvar help-back-label (purecopy "[back]")
 237   "Label to use by `help-make-xrefs' for the go-back reference.")
 238
 239 (defconst help-xref-symbol-regexp
 240   (purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|"
 241                     "\\(function\\|command\\)\\|"
 242                     "\\(face\\)\\|"
 243                     "\\(symbol\\)\\|"
 244                     "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
 245                     "[ \t\n]+\\)?"
 246                     ;; Note starting with word-syntax character:
 247                     "`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
 248   "Regexp matching doc string references to symbols.
 249
 250 The words preceding the quoted symbol can be used in doc strings to
 251 distinguish references to variables, functions and symbols.")
 252
 253 (defvar help-xref-mule-regexp nil
 254   "Regexp matching doc string references to MULE-related keywords.
 255
 256 It is usually nil, and is temporarily bound to an appropriate regexp
 257 when help commands related to multilingual environment (e.g.,
 258 `describe-coding-system') are invoked.")
 259
 260
 261 (defconst help-xref-info-regexp
 262   (purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
 263   "Regexp matching doc string references to an Info node.")
 264
 265 (defconst help-xref-url-regexp
 266   (purecopy "\\<[Uu][Rr][Ll][ \t\n]+`\\([^']+\\)'")
 267   "Regexp matching doc string references to a URL.")
 268
 269 ;;;###autoload
 270 (defun help-setup-xref (item interactive-p)
 271   "Invoked from commands using the \"*Help*\" buffer to install some xref info.
 272
 273 ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
 274 buffer after following a reference.  INTERACTIVE-P is non-nil if the
 275 calling command was invoked interactively.  In this case the stack of
 276 items for help buffer \"back\" buttons is cleared.
 277
 278 This should be called very early, before the output buffer is cleared,
 279 because we want to record the \"previous\" position of point so we can
 280 restore it properly when going back."
 281   (with-current-buffer (help-buffer)
 282     (when help-xref-stack-item
 283       (push (cons (point) help-xref-stack-item) help-xref-stack))
 284     (when interactive-p
 285       (let ((tail (nthcdr 10 help-xref-stack)))
 286         ;; Truncate the stack.
 287         (if tail (setcdr tail nil))))
 288     (setq help-xref-stack-item item)))
 289
 290 (defvar help-xref-following nil
 291   "Non-nil when following a help cross-reference.")
 292
 293 (defun help-buffer ()
 294   (buffer-name                          ;for with-output-to-temp-buffer
 295    (if help-xref-following
 296        (current-buffer)
 297      (get-buffer-create "*Help*"))))
 298
 299 (defvar help-xref-override-view-map
 300   (let ((map (make-sparse-keymap)))
 301     (set-keymap-parent map view-mode-map)
 302     (define-key map "\r" nil)
 303     map)
 304   "Replacement keymap for `view-mode' in help buffers.")
 305
 306 ;;;###autoload
 307 (defun help-make-xrefs (&optional buffer)
 308   "Parse and hyperlink documentation cross-references in the given BUFFER.
 309
 310 Find cross-reference information in a buffer and activate such cross
 311 references for selection with `help-follow'.  Cross-references have
 312 the canonical form `...'  and the type of reference may be
 313 disambiguated by the preceding word(s) used in
 314 `help-xref-symbol-regexp'.  Faces only get cross-referenced if
 315 preceded or followed by the word `face'.  Variables without
 316 variable documentation do not get cross-referenced, unless
 317 preceded by the word `variable' or `option'.
 318
 319 If the variable `help-xref-mule-regexp' is non-nil, find also
 320 cross-reference information related to multilingual environment
 321 \(e.g., coding-systems).  This variable is also used to disambiguate
 322 the type of reference as the same way as `help-xref-symbol-regexp'.
 323
 324 A special reference `back' is made to return back through a stack of
 325 help buffers.  Variable `help-back-label' specifies the text for
 326 that."
 327   (interactive "b")
 328   (save-excursion
 329     (set-buffer (or buffer (current-buffer)))
 330     (goto-char (point-min))
 331     ;; Skip the header-type info, though it might be useful to parse
 332     ;; it at some stage (e.g. "function in `library'").
 333     (forward-paragraph)
 334     (let ((old-modified (buffer-modified-p)))
 335       (let ((stab (syntax-table))
 336             (case-fold-search t)
 337             (inhibit-read-only t))
 338         (set-syntax-table emacs-lisp-mode-syntax-table)
 339         ;; The following should probably be abstracted out.
 340         (unwind-protect
 341             (progn
 342               ;; Info references
 343               (save-excursion
 344                 (while (re-search-forward help-xref-info-regexp nil t)
 345                   (let ((data (match-string 2)))
 346                     (save-match-data
 347                       (unless (string-match "^([^)]+)" data)
 348                         (setq data (concat "(emacs)" data))))
 349                     (help-xref-button 2 'help-info data))))
 350               ;; URLs
 351               (save-excursion
 352                 (while (re-search-forward help-xref-url-regexp nil t)
 353                   (let ((data (match-string 1)))
 354                     (help-xref-button 1 'help-url data))))
 355               ;; Mule related keywords.  Do this before trying
 356               ;; `help-xref-symbol-regexp' because some of Mule
 357               ;; keywords have variable or function definitions.
 358               (if help-xref-mule-regexp
 359                   (save-excursion
 360                     (while (re-search-forward help-xref-mule-regexp nil t)
 361                       (let* ((data (match-string 7))
 362                              (sym (intern-soft data)))
 363                         (cond
 364                          ((match-string 3) ; coding system
 365                           (and sym (coding-system-p sym)
 366                                (help-xref-button 6 'help-coding-system sym)))
 367                          ((match-string 4) ; input method
 368                           (and (assoc data input-method-alist)
 369                                (help-xref-button 7 'help-input-method data)))
 370                          ((or (match-string 5) (match-string 6)) ; charset
 371                           (and sym (charsetp sym)
 372                                (help-xref-button 7 'help-character-set sym)))
 373                          ((assoc data input-method-alist)
 374                           (help-xref-button 7 'help-character-set data))
 375                          ((and sym (coding-system-p sym))
 376                           (help-xref-button 7 'help-coding-system sym))
 377                          ((and sym (charsetp sym))
 378                           (help-xref-button 7 'help-character-set sym)))))))
 379               ;; Quoted symbols
 380               (save-excursion
 381                 (while (re-search-forward help-xref-symbol-regexp nil t)
 382                   (let* ((data (match-string 8))
 383                          (sym (intern-soft data)))
 384                     (if sym
 385                         (cond
 386                          ((match-string 3)  ; `variable' &c
 387                           (and (boundp sym) ; `variable' doesn't ensure
 388                                         ; it's actually bound
 389                                (help-xref-button 8 'help-variable sym)))
 390                          ((match-string 4)   ; `function' &c
 391                           (and (fboundp sym) ; similarly
 392                                (help-xref-button 8 'help-function sym)))
 393                          ((match-string 5) ; `face'
 394                           (and (facep sym)
 395                                (help-xref-button 8 'help-face sym)))
 396                          ((match-string 6)) ; nothing for `symbol'
 397                          ((match-string 7)
 398 ;;;  this used:
 399 ;;;                       #'(lambda (arg)
 400 ;;;                           (let ((location
 401 ;;;                                  (find-function-noselect arg)))
 402 ;;;                             (pop-to-buffer (car location))
 403 ;;;                             (goto-char (cdr location))))
 404                           (help-xref-button 8 'help-function-def sym))
 405                          ((and
 406                            (facep sym)
 407                            (save-match-data (looking-at "[ \t\n]+face\\W")))
 408                           (help-xref-button 8 'help-face sym))
 409                          ((and (boundp sym) (fboundp sym))
 410                           ;; We can't intuit whether to use the
 411                           ;; variable or function doc -- supply both.
 412                           (help-xref-button 8 'help-symbol sym))
 413                          ((and
 414                            (boundp sym)
 415                            (or
 416                             (documentation-property
 417                              sym 'variable-documentation)
 418                             (condition-case nil
 419                                 (documentation-property
 420                                  (indirect-variable sym)
 421                                  'variable-documentation)
 422                               (cyclic-variable-indirection nil))))
 423                           (help-xref-button 8 'help-variable sym))
 424                          ((fboundp sym)
 425                           (help-xref-button 8 'help-function sym)))))))
 426               ;; An obvious case of a key substitution:
 427               (save-excursion
 428                 (while (re-search-forward
 429                         ;; Assume command name is only word characters
 430                         ;; and dashes to get things like `use M-x foo.'.
 431                         "\\<M-x\\s-+\\(\\sw\\(\\sw\\|-\\)+\\)" nil t)
 432                   (let ((sym (intern-soft (match-string 1))))
 433                     (if (fboundp sym)
 434                         (help-xref-button 1 'help-function sym)))))
 435               ;; Look for commands in whole keymap substitutions:
 436               (save-excursion
 437                 ;; Make sure to find the first keymap.
 438                 (goto-char (point-min))
 439                 ;; Find a header and the column at which the command
 440                 ;; name will be found.
 441
 442                 ;; If the keymap substitution isn't the last thing in
 443                 ;; the doc string, and if there is anything on the
 444                 ;; same line after it, this code won't recognize the end of it.
 445                 (while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
 446                                           nil t)
 447                   (let ((col (- (match-end 1) (match-beginning 1))))
 448                     (while
 449                         (and (not (eobp))
 450                              ;; Stop at a pair of blank lines.
 451                              (not (looking-at "\n\\s-*\n")))
 452                       ;; Skip a single blank line.
 453                       (and (eolp) (forward-line))
 454                       (end-of-line)
 455                       (skip-chars-backward "^\t\n")
 456                       (if (and (>= (current-column) col)
 457                                (looking-at "\\(\\sw\\|-\\)+$"))
 458                           (let ((sym (intern-soft (match-string 0))))
 459                             (if (fboundp sym)
 460                                 (help-xref-button 0 'help-function sym))))
 461                       (forward-line))))))
 462           (set-syntax-table stab))
 463         ;; Delete extraneous newlines at the end of the docstring
 464         (goto-char (point-max))
 465         (while (and (not (bobp)) (bolp))
 466           (delete-char -1))
 467         (insert "\n")
 468         ;; Make a back-reference in this buffer if appropriate.
 469         (when help-xref-stack
 470           (insert "\n")
 471           (help-insert-xref-button help-back-label 'help-back
 472                                    (current-buffer))
 473           (insert "\n")))
 474       ;; View mode steals RET from us.
 475       (set (make-local-variable 'minor-mode-overriding-map-alist)
 476            (list (cons 'view-mode help-xref-override-view-map)))
 477       (set-buffer-modified-p old-modified))))
 478
 479 ;;;###autoload
 480 (defun help-xref-button (match-number type &rest args)
 481   "Make a hyperlink for cross-reference text previously matched.
 482 MATCH-NUMBER is the subexpression of interest in the last matched
 483 regexp.  TYPE is the type of button to use.  Any remaining arguments are
 484 passed to the button's help-function when it is invoked.
 485 See `help-make-xrefs'."
 486   ;; Don't mung properties we've added specially in some instances.
 487   (unless (button-at (match-beginning match-number))
 488     (make-text-button (match-beginning match-number)
 489                       (match-end match-number)
 490                       'type type 'help-args args)))
 491
 492 ;;;###autoload
 493 (defun help-insert-xref-button (string type &rest args)
 494   "Insert STRING and make a hyperlink from cross-reference text on it.
 495 TYPE is the type of button to use.  Any remaining arguments are passed
 496 to the button's help-function when it is invoked.
 497 See `help-make-xrefs'."
 498   (unless (button-at (point))
 499     (insert-text-button string 'type type 'help-args args)))
 500
 501 ;;;###autoload
 502 (defun help-xref-on-pp (from to)
 503   "Add xrefs for symbols in `pp's output between FROM and TO."
 504   (if (> (- to from) 5000) nil
 505     (with-syntax-table emacs-lisp-mode-syntax-table
 506       (save-excursion
 507         (save-restriction
 508           (narrow-to-region from to)
 509           (goto-char (point-min))
 510           (condition-case nil
 511               (while (not (eobp))
 512                 (cond
 513                  ((looking-at "\"") (forward-sexp 1))
 514                  ((looking-at "#<") (search-forward ">" nil 'move))
 515                  ((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
 516                   (let* ((sym (intern-soft (match-string 1)))
 517                          (type (cond ((fboundp sym) 'help-function)
 518                                      ((or (memq sym '(t nil))
 519                                           (keywordp sym))
 520                                       nil)
 521                                      ((and sym (boundp sym))
 522                                       'help-variable))))
 523                     (when type (help-xref-button 1 type sym)))
 524                   (goto-char (match-end 1)))
 525                  (t (forward-char 1))))
 526             (error nil)))))))
 527
 528 \f
 529 ;; Additional functions for (re-)creating types of help buffers.
 530 (defun help-xref-interned (symbol)
 531   "Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
 532 Both variable, function and face documentation are extracted into a single
 533 help buffer."
 534   (with-current-buffer (help-buffer)
 535     ;; Push the previous item on the stack before clobbering the output buffer.
 536     (help-setup-xref nil nil)
 537     (let ((facedoc (when (facep symbol)
 538                      ;; Don't record the current entry in the stack.
 539                      (setq help-xref-stack-item nil)
 540                      (describe-face symbol)))
 541           (fdoc (when (fboundp symbol)
 542                   ;; Don't record the current entry in the stack.
 543                   (setq help-xref-stack-item nil)
 544                   (describe-function symbol)))
 545           (sdoc (when (boundp symbol)
 546                   ;; Don't record the current entry in the stack.
 547                   (setq help-xref-stack-item nil)
 548                   (describe-variable symbol))))
 549       (cond
 550        (sdoc
 551         ;; We now have a help buffer on the variable.
 552         ;; Insert the function and face text before it.
 553         (when (or fdoc facedoc)
 554           (goto-char (point-min))
 555           (let ((inhibit-read-only t))
 556             (when fdoc
 557               (insert fdoc "\n\n")
 558               (when facedoc
 559                 (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 560                         " is also a " "face." "\n\n")))
 561             (when facedoc
 562               (insert facedoc "\n\n"))
 563             (insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
 564                     " is also a " "variable." "\n\n"))
 565           ;; Don't record the `describe-variable' item in the stack.
 566           (setq help-xref-stack-item nil)
 567           (help-setup-xref (list #'help-xref-interned symbol) nil)))
 568        (fdoc
 569         ;; We now have a help buffer on the function.
 570         ;; Insert face text before it.
 571         (when facedoc
 572           (goto-char (point-max))
 573           (let ((inhibit-read-only t))
 574             (insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
 575                     " is also a " "face." "\n\n" facedoc))
 576           ;; Don't record the `describe-function' item in the stack.
 577           (setq help-xref-stack-item nil)
 578           (help-setup-xref (list #'help-xref-interned symbol) nil)))))))
 579
 580 \f
 581 ;; Navigation/hyperlinking with xrefs
 582
 583 (defun help-follow-mouse (click)
 584   "Follow the cross-reference that you CLICK on."
 585   (interactive "e")
 586   (let* ((start (event-start click))
 587          (window (car start))
 588          (pos (car (cdr start))))
 589     (with-current-buffer (window-buffer window)
 590       (help-follow pos))))
 591
 592 (defun help-xref-go-back (buffer)
 593   "From BUFFER, go back to previous help buffer text using `help-xref-stack'."
 594   (let (item position method args)
 595     (with-current-buffer buffer
 596       (when help-xref-stack
 597         (setq item (pop help-xref-stack)
 598               ;; Clear the current item so that it won't get pushed
 599               ;; by the function we're about to call.  TODO: We could also
 600               ;; push it onto a "forward" stack and add a `forw' button.
 601               help-xref-stack-item nil
 602               position (car item)
 603               method (cadr item)
 604               args (cddr item))))
 605     (apply method args)
 606     (with-current-buffer buffer
 607       (if (get-buffer-window buffer)
 608           (set-window-point (get-buffer-window buffer) position)
 609         (goto-char position)))))
 610
 611 (defun help-go-back ()
 612   "Go back to previous topic in this help buffer."
 613   (interactive)
 614   (if help-xref-stack
 615       (help-xref-go-back (current-buffer))
 616     (error "No previous help buffer")))
 617
 618 (defun help-do-xref (pos function args)
 619   "Call the help cross-reference function FUNCTION with args ARGS.
 620 Things are set up properly so that the resulting help-buffer has
 621 a proper [back] button."
 622   ;; There is a reference at point.  Follow it.
 623   (let ((help-xref-following t))
 624     (apply function args)))
 625
 626 (defun help-follow (&optional pos)
 627   "Follow cross-reference at POS, defaulting to point.
 628
 629 For the cross-reference format, see `help-make-xrefs'."
 630   (interactive "d")
 631   (unless pos
 632     (setq pos (point)))
 633   (unless (push-button pos)
 634     ;; check if the symbol under point is a function or variable
 635     (let ((sym
 636            (intern
 637             (save-excursion
 638               (goto-char pos) (skip-syntax-backward "w_")
 639               (buffer-substring (point)
 640                                 (progn (skip-syntax-forward "w_")
 641                                        (point)))))))
 642       (when (or (boundp sym) (fboundp sym) (facep sym))
 643         (help-do-xref pos #'help-xref-interned (list sym))))))
 644
 645
 646 (provide 'help-mode)
 647
 648 ;; arch-tag: 850954ae-3725-4cb4-8e91-0bf6d52d6b0b
 649 ;;; help-mode.el ends here