lisp/textmodes/spell.el

   1 ;;; spell.el --- spelling correction interface for Emacs
   2
   3 ;; Copyright (C) 1985, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006, 2007, 2008, 2009, 2010, 2011, 2012 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: wp, unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This mode provides an Emacs interface to the UNIX spell(1) program.
  27 ;; Entry points are `spell-buffer', `spell-word', `spell-region' and
  28 ;; `spell-string'.
  29
  30 ;; See also ispell.el for an interface to the ispell program.
  31
  32 ;;; Code:
  33
  34 (defgroup spell nil
  35   "Interface to the UNIX spell(1) program."
  36   :prefix "spell-"
  37   :group 'applications)
  38
  39 (defcustom spell-command "spell"
  40   "*Command to run the spell program."
  41   :type 'string
  42   :group 'spell)
  43
  44 (defcustom spell-filter nil
  45   "*Filter function to process text before passing it to spell program.
  46 This function might remove text-processor commands.
  47 nil means don't alter the text before checking it."
  48   :type '(choice (const nil) function)
  49   :group 'spell)
  50
  51 ;;;###autoload
  52 (put 'spell-filter 'risky-local-variable t)
  53
  54 ;;;###autoload
  55 (defun spell-buffer ()
  56   "Check spelling of every word in the buffer.
  57 For each incorrect word, you are asked for the correct spelling
  58 and then put into a query-replace to fix some or all occurrences.
  59 If you do not want to change a word, just give the same word
  60 as its \"correct\" spelling; then the query replace is skipped."
  61   (interactive)
  62   ;; Don't warn about spell-region being obsolete.
  63   (with-no-warnings
  64     (spell-region (point-min) (point-max) "buffer")))
  65 ;;;###autoload
  66 (make-obsolete 'spell-buffer 'ispell-buffer "23.1")
  67
  68 ;;;###autoload
  69 (defun spell-word ()
  70   "Check spelling of word at or before point.
  71 If it is not correct, ask user for the correct spelling
  72 and `query-replace' the entire buffer to substitute it."
  73   (interactive)
  74   (let (beg end spell-filter)
  75     (save-excursion
  76      (if (not (looking-at "\\<"))
  77          (forward-word -1))
  78      (setq beg (point))
  79      (forward-word 1)
  80      (setq end (point)))
  81     ;; Don't warn about spell-region being obsolete.
  82     (with-no-warnings
  83       (spell-region beg end (buffer-substring beg end)))))
  84 ;;;###autoload
  85 (make-obsolete 'spell-word 'ispell-word "23.1")
  86
  87 ;;;###autoload
  88 (defun spell-region (start end &optional description)
  89   "Like `spell-buffer' but applies only to region.
  90 Used in a program, applies from START to END.
  91 DESCRIPTION is an optional string naming the unit being checked:
  92 for example, \"word\"."
  93   (interactive "r")
  94   (let ((filter spell-filter)
  95         (buf (get-buffer-create " *temp*")))
  96     (with-current-buffer buf
  97      (widen)
  98      (erase-buffer))
  99     (message "Checking spelling of %s..." (or description "region"))
 100     (if (and (null filter) (= ?\n (char-after (1- end))))
 101         (if (string= "spell" spell-command)
 102             (call-process-region start end "spell" nil buf)
 103           (call-process-region start end shell-file-name
 104                                nil buf nil "-c" spell-command))
 105       (let ((oldbuf (current-buffer)))
 106         (with-current-buffer buf
 107           (insert-buffer-substring oldbuf start end)
 108           (or (bolp) (insert ?\n))
 109           (if filter (funcall filter))
 110           (if (string= "spell" spell-command)
 111               (call-process-region (point-min) (point-max) "spell" t buf)
 112             (call-process-region (point-min) (point-max) shell-file-name
 113                                  t buf nil "-c" spell-command)))))
 114     (message "Checking spelling of %s...%s"
 115              (or description "region")
 116              (if (with-current-buffer buf
 117                    (> (buffer-size) 0))
 118                  "not correct"
 119                "correct"))
 120     (let (word newword
 121           (case-fold-search t)
 122           (case-replace t))
 123       (while (with-current-buffer buf
 124                (> (buffer-size) 0))
 125         (with-current-buffer buf
 126           (goto-char (point-min))
 127           (setq word (downcase
 128                       (buffer-substring (point)
 129                                         (progn (end-of-line) (point)))))
 130           (forward-char 1)
 131           (delete-region (point-min) (point))
 132           (setq newword
 133                 (read-string (concat "`" word
 134                                      "' not recognized; edit a replacement: ")
 135                              word))
 136           (flush-lines (concat "^" (regexp-quote word) "$")))
 137         (if (not (equal word newword))
 138             (progn
 139              (goto-char (point-min))
 140              (query-replace-regexp (concat "\\b" (regexp-quote word) "\\b")
 141                                    newword)))))))
 142 ;;;###autoload
 143 (make-obsolete 'spell-region 'ispell-region "23.1")
 144
 145 ;;;###autoload
 146 (defun spell-string (string)
 147   "Check spelling of string supplied as argument."
 148   (interactive "sSpell string: ")
 149   (let ((buf (get-buffer-create " *temp*")))
 150     (with-current-buffer buf
 151       (widen)
 152       (erase-buffer)
 153       (insert string "\n")
 154       (if (string= "spell" spell-command)
 155           (call-process-region (point-min) (point-max) "spell"
 156                                t t)
 157         (call-process-region (point-min) (point-max) shell-file-name
 158                              t t nil "-c" spell-command))
 159       (if (= 0 (buffer-size))
 160           (message "%s is correct" string)
 161         (goto-char (point-min))
 162         (while (search-forward "\n" nil t)
 163           (replace-match " "))
 164         (message "%sincorrect" (buffer-substring 1 (point-max)))))))
 165 ;;;###autoload
 166 (make-obsolete 'spell-string "The `spell' package is obsolete - use `ispell'."
 167                "23.1")
 168
 169 (provide 'spell)
 170
 171 ;; arch-tag: 7eabb848-9c76-431a-bcdb-0e0592d2db04
 172 ;;; spell.el ends here