lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Emmanuel Briot  <briot@gnat.com>
   7 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
   8 ;; Keywords: xml, data
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 3, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This file contains a somewhat incomplete non-validating XML parser.  It
  30 ;; parses a file, and returns a list that can be used internally by
  31 ;; any other Lisp libraries.
  32
  33 ;;; FILE FORMAT
  34
  35 ;; The document type declaration may either be ignored or (optionally)
  36 ;; parsed, but currently the parsing will only accept element
  37 ;; declarations.  The XML file is assumed to be well-formed.  In case
  38 ;; of error, the parsing stops and the XML file is shown where the
  39 ;; parsing stopped.
  40 ;;
  41 ;; It also knows how to ignore comments and processing instructions.
  42 ;;
  43 ;; The XML file should have the following format:
  44 ;;    <node1 attr1="name1" attr2="name2" ...>value
  45 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  46 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  47 ;;    </node1>
  48 ;; Of course, the name of the nodes and attributes can be anything.  There can
  49 ;; be any number of attributes (or none), as well as any number of children
  50 ;; below the nodes.
  51 ;;
  52 ;; There can be only top level node, but with any number of children below.
  53
  54 ;;; LIST FORMAT
  55
  56 ;; The functions `xml-parse-file', `xml-parse-region' and
  57 ;; `xml-parse-tag' return a list with the following format:
  58 ;;
  59 ;;    xml-list   ::= (node node ...)
  60 ;;    node       ::= (qname attribute-list . child_node_list)
  61 ;;    child_node_list ::= child_node child_node ...
  62 ;;    child_node ::= node | string
  63 ;;    qname      ::= (:namespace-uri . "name") | "name"
  64 ;;    attribute_list ::= ((qname . "value") (qname . "value") ...)
  65 ;;                       | nil
  66 ;;    string     ::= "..."
  67 ;;
  68 ;; Some macros are provided to ease the parsing of this list.
  69 ;; Whitespace is preserved.  Fixme: There should be a tree-walker that
  70 ;; can remove it.
  71
  72 ;; TODO:
  73 ;;  * xml:base, xml:space support
  74 ;;  * more complete DOCTYPE parsing
  75 ;;  * pi support
  76
  77 ;;; Code:
  78
  79 ;; Note that buffer-substring and match-string were formerly used in
  80 ;; several places, because the -no-properties variants remove
  81 ;; composition info.  However, after some discussion on emacs-devel,
  82 ;; the consensus was that the speed of the -no-properties variants was
  83 ;; a worthwhile tradeoff especially since we're usually parsing files
  84 ;; instead of hand-crafted XML.
  85
  86 ;;*******************************************************************
  87 ;;**
  88 ;;**  Macros to parse the list
  89 ;;**
  90 ;;*******************************************************************
  91
  92 (defconst xml-undefined-entity "?"
  93   "What to substitute for undefined entities")
  94
  95 (defvar xml-entity-alist
  96   '(("lt"   . "<")
  97     ("gt"   . ">")
  98     ("apos" . "'")
  99     ("quot" . "\"")
 100     ("amp"  . "&"))
 101   "The defined entities.  Entities are added to this when the DTD is parsed.")
 102
 103 (defvar xml-sub-parser nil
 104   "Dynamically set this to a non-nil value if you want to parse an XML fragment.")
 105
 106 (defvar xml-validating-parser nil
 107   "Set to non-nil to get validity checking.")
 108
 109 (defsubst xml-node-name (node)
 110   "Return the tag associated with NODE.
 111 Without namespace-aware parsing, the tag is a symbol.
 112
 113 With namespace-aware parsing, the tag is a cons of a string
 114 representing the uri of the namespace with the local name of the
 115 tag.  For example,
 116
 117     <foo>
 118
 119 would be represented by
 120
 121     '(\"\" . \"foo\")."
 122
 123   (car node))
 124
 125 (defsubst xml-node-attributes (node)
 126   "Return the list of attributes of NODE.
 127 The list can be nil."
 128   (nth 1 node))
 129
 130 (defsubst xml-node-children (node)
 131   "Return the list of children of NODE.
 132 This is a list of nodes, and it can be nil."
 133   (cddr node))
 134
 135 (defun xml-get-children (node child-name)
 136   "Return the children of NODE whose tag is CHILD-NAME.
 137 CHILD-NAME should match the value returned by `xml-node-name'."
 138   (let ((match ()))
 139     (dolist (child (xml-node-children node))
 140       (if (and (listp child)
 141                (equal (xml-node-name child) child-name))
 142           (push child match)))
 143     (nreverse match)))
 144
 145 (defun xml-get-attribute-or-nil (node attribute)
 146   "Get from NODE the value of ATTRIBUTE.
 147 Return nil if the attribute was not found.
 148
 149 See also `xml-get-attribute'."
 150   (cdr (assoc attribute (xml-node-attributes node))))
 151
 152 (defsubst xml-get-attribute (node attribute)
 153   "Get from NODE the value of ATTRIBUTE.
 154 An empty string is returned if the attribute was not found.
 155
 156 See also `xml-get-attribute-or-nil'."
 157   (or (xml-get-attribute-or-nil node attribute) ""))
 158
 159 ;;*******************************************************************
 160 ;;**
 161 ;;**  Creating the list
 162 ;;**
 163 ;;*******************************************************************
 164
 165 ;;;###autoload
 166 (defun xml-parse-file (file &optional parse-dtd parse-ns)
 167   "Parse the well-formed XML file FILE.
 168 If FILE is already visited, use its buffer and don't kill it.
 169 Returns the top node with all its children.
 170 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
 171 If PARSE-NS is non-nil, then QNAMES are expanded."
 172   (if (get-file-buffer file)
 173       (with-current-buffer (get-file-buffer file)
 174         (save-excursion
 175           (xml-parse-region (point-min)
 176                             (point-max)
 177                             (current-buffer)
 178                             parse-dtd parse-ns)))
 179     (with-temp-buffer
 180       (insert-file-contents file)
 181       (xml-parse-region (point-min)
 182                         (point-max)
 183                         (current-buffer)
 184                         parse-dtd parse-ns))))
 185
 186
 187 (defvar xml-name-re)
 188 (defvar xml-entity-value-re)
 189 (defvar xml-att-def-re)
 190 (let* ((start-chars (concat "[:alpha:]:_"))
 191        (name-chars  (concat "-[:digit:]." start-chars))
 192        ;;[3]    S          ::=          (#x20 | #x9 | #xD | #xA)+
 193        (whitespace  "[ \t\n\r]"))
 194   ;;[4] NameStartChar ::= ":" | [A-Z] | "_" | [a-z] | [#xC0-#xD6]
 195   ;;                      | [#xD8-#xF6] | [#xF8-#x2FF] | [#x370-#x37D] | [#x37F-#x1FFF]
 196   ;;                      | [#x200C-#x200D] | [#x2070-#x218F] | [#x2C00-#x2FEF] | [#x3001-#xD7FF]
 197   ;;                      | [#xF900-#xFDCF] | [#xFDF0-#xFFFD] | [#x10000-#xEFFFF]
 198   (defvar xml-name-start-char-re (concat "[" start-chars "]"))
 199   ;;[4a] NameChar       ::= NameStartChar | "-" | "." | [0-9] | #xB7 | [#x0300-#x036F] | [#x203F-#x2040]
 200   (defvar xml-name-char-re       (concat "[" name-chars  "]"))
 201   ;;[5] Name     ::= NameStartChar (NameChar)*
 202   (defvar xml-name-re            (concat xml-name-start-char-re xml-name-char-re "*"))
 203   ;;[6] Names    ::= Name (#x20 Name)*
 204   (defvar xml-names-re           (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
 205   ;;[7] Nmtoken ::= (NameChar)+
 206   (defvar xml-nmtoken-re         (concat xml-name-char-re "+"))
 207   ;;[8] Nmtokens ::= Nmtoken (#x20 Nmtoken)*
 208   (defvar xml-nmtokens-re        (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
 209   ;;[66] CharRef ::= '&#' [0-9]+ ';' | '&#x' [0-9a-fA-F]+ ';'
 210   (defvar xml-char-ref-re        "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
 211   ;;[68] EntityRef   ::= '&' Name ';'
 212   (defvar xml-entity-ref         (concat "&" xml-name-re ";"))
 213   ;;[69] PEReference ::= '%' Name ';'
 214   (defvar xml-pe-reference-re    (concat "%" xml-name-re ";"))
 215   ;;[67] Reference   ::= EntityRef | CharRef
 216   (defvar xml-reference-re       (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
 217   ;;[10]        AttValue           ::=          '"' ([^<&"] | Reference)* '"' |  "'" ([^<&'] | Reference)* "'"
 218   (defvar xml-att-value-re    (concat "\\(?:\"\\(?:[^&\"]\\|" xml-reference-re "\\)*\"\\|"
 219                                       "'\\(?:[^&']\\|" xml-reference-re "\\)*'\\)"))
 220   ;;[56]        TokenizedType      ::=          'ID'       [VC: ID] [VC: One ID per Element Type] [VC: ID Attribute Default]
 221   ;;                                            | 'IDREF'    [VC: IDREF]
 222   ;;                                                  | 'IDREFS'   [VC: IDREF]
 223   ;;                                            | 'ENTITY'   [VC: Entity Name]
 224   ;;                                            | 'ENTITIES' [VC: Entity Name]
 225   ;;                                            | 'NMTOKEN'  [VC: Name Token]
 226   ;;                                            | 'NMTOKENS' [VC: Name Token]
 227   (defvar xml-tokenized-type-re "\\(?:ID\\|IDREF\\|IDREFS\\|ENTITY\\|ENTITIES\\|NMTOKEN\\|NMTOKENS\\)")
 228   ;;[58]        NotationType       ::=          'NOTATION' S '(' S? Name (S? '|' S? Name)* S? ')'
 229   (defvar xml-notation-type-re (concat "\\(?:NOTATION" whitespace "(" whitespace "*" xml-name-re
 230                                        "\\(?:" whitespace "*|" whitespace "*" xml-name-re "\\)*" whitespace "*)\\)"))
 231   ;;[59]        Enumeration        ::=          '(' S? Nmtoken (S? '|' S? Nmtoken)* S? ')'      [VC: Enumeration] [VC: No Duplicate Tokens]
 232   (defvar xml-enumeration-re (concat "\\(?:(" whitespace "*" xml-nmtoken-re
 233                                      "\\(?:" whitespace "*|" whitespace "*" xml-nmtoken-re "\\)*"
 234                                      whitespace ")\\)"))
 235   ;;[57]        EnumeratedType     ::=          NotationType | Enumeration
 236   (defvar xml-enumerated-type-re (concat "\\(?:" xml-notation-type-re "\\|" xml-enumeration-re "\\)"))
 237   ;;[54]        AttType    ::=          StringType | TokenizedType | EnumeratedType
 238   ;;[55]        StringType         ::=          'CDATA'
 239   (defvar xml-att-type-re (concat "\\(?:CDATA\\|" xml-tokenized-type-re "\\|" xml-notation-type-re"\\|" xml-enumerated-type-re "\\)"))
 240   ;;[60]        DefaultDecl        ::=          '#REQUIRED' | '#IMPLIED' | (('#FIXED' S)? AttValue)
 241   (defvar xml-default-decl-re (concat "\\(?:#REQUIRED\\|#IMPLIED\\|\\(?:#FIXED" whitespace "\\)*" xml-att-value-re "\\)"))
 242   ;;[53]        AttDef     ::=          S Name S AttType S DefaultDecl
 243   (defvar xml-att-def-re         (concat "\\(?:" whitespace "*" xml-name-re
 244                                          whitespace "*" xml-att-type-re
 245                                          whitespace "*" xml-default-decl-re "\\)"))
 246   ;;[9] EntityValue ::= '"' ([^%&"] | PEReference | Reference)* '"'
 247   ;;               |  "'" ([^%&'] | PEReference | Reference)* "'"
 248   (defvar xml-entity-value-re    (concat "\\(?:\"\\(?:[^%&\"]\\|" xml-pe-reference-re
 249                                          "\\|" xml-reference-re "\\)*\"\\|'\\(?:[^%&']\\|"
 250                                          xml-pe-reference-re "\\|" xml-reference-re "\\)*'\\)")))
 251 ;;[75] ExternalID ::= 'SYSTEM' S SystemLiteral
 252 ;;                 | 'PUBLIC' S PubidLiteral S SystemLiteral
 253 ;;[76] NDataDecl ::=    S 'NDATA' S
 254 ;;[73] EntityDef  ::= EntityValue| (ExternalID NDataDecl?)
 255 ;;[71] GEDecl     ::= '<!ENTITY' S Name S EntityDef S? '>'
 256 ;;[74] PEDef      ::= EntityValue | ExternalID
 257 ;;[72] PEDecl     ::= '<!ENTITY' S '%' S Name S PEDef S? '>'
 258 ;;[70] EntityDecl ::= GEDecl | PEDecl
 259
 260 ;; Note that this is setup so that we can do whitespace-skipping with
 261 ;; `(skip-syntax-forward " ")', inter alia.  Previously this was slow
 262 ;; compared with `re-search-forward', but that has been fixed.  Also
 263 ;; note that the standard syntax table contains other characters with
 264 ;; whitespace syntax, like NBSP, but they are invalid in contexts in
 265 ;; which we might skip whitespace -- specifically, they're not
 266 ;; NameChars [XML 4].
 267
 268 (defvar xml-syntax-table
 269   (let ((table (make-syntax-table)))
 270     ;; Get space syntax correct per XML [3].
 271     (dotimes (c 31)
 272       (modify-syntax-entry c "." table)) ; all are space in standard table
 273     (dolist (c '(?\t ?\n ?\r))           ; these should be space
 274       (modify-syntax-entry c " " table))
 275     ;; For skipping attributes.
 276     (modify-syntax-entry ?\" "\"" table)
 277     (modify-syntax-entry ?' "\"" table)
 278     ;; Non-alnum name chars should be symbol constituents (`-' and `_'
 279     ;; are OK by default).
 280     (modify-syntax-entry ?. "_" table)
 281     (modify-syntax-entry ?: "_" table)
 282     ;; XML [89]
 283     (unless (featurep 'xemacs)
 284       (dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
 285                           #x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
 286                           #x30FD #x30FE))
 287         (modify-syntax-entry (decode-char 'ucs c) "w" table)))
 288     ;; Fixme: rest of [4]
 289     table)
 290   "Syntax table used by `xml-parse-region'.")
 291
 292 ;; XML [5]
 293 ;; Note that [:alpha:] matches all multibyte chars with word syntax.
 294 (eval-and-compile
 295   (defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
 296
 297 ;; Fixme:  This needs re-writing to deal with the XML grammar properly, i.e.
 298 ;;   document    ::=    prolog element Misc*
 299 ;;   prolog    ::=    XMLDecl? Misc* (doctypedecl Misc*)?
 300
 301 ;;;###autoload
 302 (defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
 303   "Parse the region from BEG to END in BUFFER.
 304 If BUFFER is nil, it defaults to the current buffer.
 305 Returns the XML list for the region, or raises an error if the region
 306 is not well-formed XML.
 307 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 308 and returned as the first element of the list.
 309 If PARSE-NS is non-nil, then QNAMES are expanded."
 310   ;; Use fixed syntax table to ensure regexp char classes and syntax
 311   ;; specs DTRT.
 312   (with-syntax-table (standard-syntax-table)
 313     (let ((case-fold-search nil)        ; XML is case-sensitive.
 314           xml result dtd)
 315       (save-excursion
 316         (if buffer
 317             (set-buffer buffer))
 318         (save-restriction
 319           (narrow-to-region beg end)
 320           (goto-char (point-min))
 321           (while (not (eobp))
 322             (if (search-forward "<" nil t)
 323                 (progn
 324                   (forward-char -1)
 325                   (setq result (xml-parse-tag parse-dtd parse-ns))
 326                   (if (and xml result (not xml-sub-parser))
 327                       ;;  translation of rule [1] of XML specifications
 328                       (error "XML: (Not Well-Formed) Only one root tag allowed")
 329                     (cond
 330                      ((null result))
 331                      ((and (listp (car result))
 332                            parse-dtd)
 333                       (setq dtd (car result))
 334                       (if (cdr result)  ; possible leading comment
 335                           (add-to-list 'xml (cdr result))))
 336                      (t
 337                       (add-to-list 'xml result)))))
 338               (goto-char (point-max))))
 339           (if parse-dtd
 340               (cons dtd (nreverse xml))
 341             (nreverse xml)))))))
 342
 343 (defun xml-maybe-do-ns (name default xml-ns)
 344   "Perform any namespace expansion.
 345 NAME is the name to perform the expansion on.
 346 DEFAULT is the default namespace.  XML-NS is a cons of namespace
 347 names to uris.  When namespace-aware parsing is off, then XML-NS
 348 is nil.
 349
 350 During namespace-aware parsing, any name without a namespace is
 351 put into the namespace identified by DEFAULT.  nil is used to
 352 specify that the name shouldn't be given a namespace."
 353   (if (consp xml-ns)
 354       (let* ((nsp (string-match ":" name))
 355              (lname (if nsp (substring name (match-end 0)) name))
 356              (prefix (if nsp (substring name 0 (match-beginning 0)) default))
 357              (special (and (string-equal lname "xmlns") (not prefix)))
 358              ;; Setting default to nil will insure that there is not
 359              ;; matching cons in xml-ns.  In which case we
 360              (ns (or (cdr (assoc (if special "xmlns" prefix)
 361                                  xml-ns))
 362                      "")))
 363         (cons ns (if special "" lname)))
 364     (intern name)))
 365
 366 (defun xml-parse-fragment (&optional parse-dtd parse-ns)
 367   "Parse xml-like fragments."
 368   (let ((xml-sub-parser t)
 369         children)
 370     (while (not (eobp))
 371       (let ((bit (xml-parse-tag
 372                   parse-dtd parse-ns)))
 373         (if children
 374             (setq children (append (list bit) children))
 375           (if (stringp bit)
 376               (setq children (list bit))
 377             (setq children bit)))))
 378     (reverse children)))
 379
 380 (defun xml-parse-tag (&optional parse-dtd parse-ns)
 381   "Parse the tag at point.
 382 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 383 returned as the first element in the list.
 384 If PARSE-NS is non-nil, then QNAMES are expanded.
 385 Returns one of:
 386  - a list : the matching node
 387  - nil    : the point is not looking at a tag.
 388  - a pair : the first element is the DTD, the second is the node."
 389   (let ((xml-validating-parser (or parse-dtd xml-validating-parser))
 390         (xml-ns (if (consp parse-ns)
 391                     parse-ns
 392                   (if parse-ns
 393                       (list
 394                        ;; Default for empty prefix is no namespace
 395                        (cons ""      "")
 396                        ;; "xml" namespace
 397                        (cons "xml"   "http://www.w3.org/XML/1998/namespace")
 398                        ;; We need to seed the xmlns namespace
 399                        (cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
 400     (cond
 401      ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 402      ;; beginning of a document).
 403      ((looking-at "<\\?")
 404       (search-forward "?>")
 405       (skip-syntax-forward " ")
 406       (xml-parse-tag parse-dtd xml-ns))
 407      ;;  Character data (CDATA) sections, in which no tag should be interpreted
 408      ((looking-at "<!\\[CDATA\\[")
 409       (let ((pos (match-end 0)))
 410         (unless (search-forward "]]>" nil t)
 411           (error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
 412         (concat
 413          (buffer-substring-no-properties pos (match-beginning 0))
 414          (xml-parse-string))))
 415      ;;  DTD for the document
 416      ((looking-at "<!DOCTYPE")
 417       (let ((dtd (xml-parse-dtd parse-ns)))
 418         (skip-syntax-forward " ")
 419         (if xml-validating-parser
 420             (cons dtd (xml-parse-tag nil xml-ns))
 421           (xml-parse-tag nil xml-ns))))
 422      ;;  skip comments
 423      ((looking-at "<!--")
 424       (search-forward "-->")
 425       nil)
 426      ;;  end tag
 427      ((looking-at "</")
 428       '())
 429      ;;  opening tag
 430      ((looking-at "<\\([^/>[:space:]]+\\)")
 431       (goto-char (match-end 1))
 432
 433       ;; Parse this node
 434       (let* ((node-name (match-string-no-properties 1))
 435              ;; Parse the attribute list.
 436              (attrs (xml-parse-attlist xml-ns))
 437              children pos)
 438
 439         ;; add the xmlns:* attrs to our cache
 440         (when (consp xml-ns)
 441           (dolist (attr attrs)
 442             (when (and (consp (car attr))
 443                        (equal "http://www.w3.org/2000/xmlns/"
 444                               (caar attr)))
 445               (push (cons (cdar attr) (cdr attr))
 446                     xml-ns))))
 447
 448         (setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
 449
 450         ;; is this an empty element ?
 451         (if (looking-at "/>")
 452             (progn
 453               (forward-char 2)
 454               (nreverse children))
 455
 456           ;; is this a valid start tag ?
 457           (if (eq (char-after) ?>)
 458               (progn
 459                 (forward-char 1)
 460                 ;;  Now check that we have the right end-tag. Note that this
 461                 ;;  one might contain spaces after the tag name
 462                 (let ((end (concat "</" node-name "\\s-*>")))
 463                   (while (not (looking-at end))
 464                     (cond
 465                      ((looking-at "</")
 466                       (error "XML: (Not Well-Formed) Invalid end tag (expecting %s) at pos %d"
 467                              node-name (point)))
 468                      ((= (char-after) ?<)
 469                       (let ((tag (xml-parse-tag nil xml-ns)))
 470                         (when tag
 471                           (push tag children))))
 472                      (t
 473                       (let ((expansion (xml-parse-string)))
 474                         (setq children
 475                               (if (stringp expansion)
 476                                   (if (stringp (car children))
 477                                       ;; The two strings were separated by a comment.
 478                                       (setq children (append (list (concat (car children) expansion))
 479                                                              (cdr children)))
 480                                     (setq children (append (list expansion) children)))
 481                                 (setq children (append expansion children))))))))
 482
 483                   (goto-char (match-end 0))
 484                   (nreverse children)))
 485             ;;  This was an invalid start tag (Expected ">", but didn't see it.)
 486             (error "XML: (Well-Formed) Couldn't parse tag: %s"
 487                    (buffer-substring-no-properties (- (point) 10) (+ (point) 1)))))))
 488      (t ;; (Not one of PI, CDATA, Comment, End tag, or Start tag)
 489       (unless xml-sub-parser            ; Usually, we error out.
 490         (error "XML: (Well-Formed) Invalid character"))
 491
 492       ;; However, if we're parsing incrementally, then we need to deal
 493       ;; with stray CDATA.
 494       (xml-parse-string)))))
 495
 496 (defun xml-parse-string ()
 497   "Parse the next whatever.  Could be a string, or an element."
 498   (let* ((pos (point))
 499          (string (progn (if (search-forward "<" nil t)
 500                             (forward-char -1)
 501                           (goto-char (point-max)))
 502                         (buffer-substring-no-properties pos (point)))))
 503     ;; Clean up the string.  As per XML specifications, the XML
 504     ;; processor should always pass the whole string to the
 505     ;; application.  But \r's should be replaced:
 506     ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 507     (setq pos 0)
 508     (while (string-match "\r\n?" string pos)
 509       (setq string (replace-match "\n" t t string))
 510       (setq pos (1+ (match-beginning 0))))
 511
 512     (xml-substitute-special string)))
 513
 514 (defun xml-parse-attlist (&optional xml-ns)
 515   "Return the attribute-list after point.
 516 Leave point at the first non-blank character after the tag."
 517   (let ((attlist ())
 518         end-pos name)
 519     (skip-syntax-forward " ")
 520     (while (looking-at (eval-when-compile
 521                          (concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
 522       (setq end-pos (match-end 0))
 523       (setq name (xml-maybe-do-ns (match-string-no-properties 1) nil xml-ns))
 524       (goto-char end-pos)
 525
 526       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 527
 528       ;; Do we have a string between quotes (or double-quotes),
 529       ;;  or a simple word ?
 530       (if (looking-at "\"\\([^\"]*\\)\"")
 531           (setq end-pos (match-end 0))
 532         (if (looking-at "'\\([^']*\\)'")
 533             (setq end-pos (match-end 0))
 534           (error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
 535
 536       ;; Each attribute must be unique within a given element
 537       (if (assoc name attlist)
 538           (error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
 539
 540       ;; Multiple whitespace characters should be replaced with a single one
 541       ;; in the attributes
 542       (let ((string (match-string-no-properties 1))
 543             (pos 0))
 544         (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
 545         (let ((expansion (xml-substitute-special string)))
 546           (unless (stringp expansion)
 547                                         ; We say this is the constraint.  It is acctually that
 548                                         ; external entities nor "<" can be in an attribute value.
 549             (error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
 550           (push (cons name expansion) attlist)))
 551
 552       (goto-char end-pos)
 553       (skip-syntax-forward " "))
 554     (nreverse attlist)))
 555
 556 ;;*******************************************************************
 557 ;;**
 558 ;;**  The DTD (document type declaration)
 559 ;;**  The following functions know how to skip or parse the DTD of
 560 ;;**  a document
 561 ;;**
 562 ;;*******************************************************************
 563
 564 ;; Fixme: This fails at least if the DTD contains conditional sections.
 565
 566 (defun xml-skip-dtd ()
 567   "Skip the DTD at point.
 568 This follows the rule [28] in the XML specifications."
 569   (let ((xml-validating-parser nil))
 570     (xml-parse-dtd)))
 571
 572 (defun xml-parse-dtd (&optional parse-ns)
 573   "Parse the DTD at point."
 574   (forward-char (eval-when-compile (length "<!DOCTYPE")))
 575   (skip-syntax-forward " ")
 576   (if (and (looking-at ">")
 577            xml-validating-parser)
 578       (error "XML: (Validity) Invalid DTD (expecting name of the document)"))
 579
 580   ;;  Get the name of the document
 581   (looking-at xml-name-regexp)
 582   (let ((dtd (list (match-string-no-properties 0) 'dtd))
 583         type element end-pos)
 584     (goto-char (match-end 0))
 585
 586     (skip-syntax-forward " ")
 587     ;; XML [75]
 588     (cond ((looking-at "PUBLIC\\s-+")
 589            (goto-char (match-end 0))
 590            (unless (or (re-search-forward
 591                         "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
 592                         nil t)
 593                        (re-search-forward
 594                         "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
 595                         nil t))
 596              (error "XML: Missing Public ID"))
 597            (let ((pubid (match-string-no-properties 1)))
 598              (skip-syntax-forward " ")
 599              (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 600                          (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 601                (error "XML: Missing System ID"))
 602              (push (list pubid (match-string-no-properties 1) 'public) dtd)))
 603           ((looking-at "SYSTEM\\s-+")
 604            (goto-char (match-end 0))
 605            (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 606                        (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 607              (error "XML: Missing System ID"))
 608            (push (list (match-string-no-properties 1) 'system) dtd)))
 609     (skip-syntax-forward " ")
 610     (if (eq ?> (char-after))
 611         (forward-char)
 612       (if (not (eq (char-after) ?\[))
 613           (error "XML: Bad DTD")
 614         (forward-char)
 615         ;;  Parse the rest of the DTD
 616         ;;  Fixme: Deal with NOTATION, PIs.
 617         (while (not (looking-at "\\s-*\\]"))
 618           (skip-syntax-forward " ")
 619           (cond
 620
 621            ;;  Translation of rule [45] of XML specifications
 622            ((looking-at
 623              "<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
 624
 625             (setq element (match-string-no-properties 1)
 626                   type    (match-string-no-properties 2))
 627             (setq end-pos (match-end 0))
 628
 629             ;;  Translation of rule [46] of XML specifications
 630             (cond
 631              ((string-match "^EMPTY[ \t\n\r]*$" type) ;; empty declaration
 632               (setq type 'empty))
 633              ((string-match "^ANY[ \t\n\r]*$" type) ;; any type of contents
 634               (setq type 'any))
 635              ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 636               (setq type (xml-parse-elem-type (match-string-no-properties 1 type))))
 637              ((string-match "^%[^;]+;[ \t\n\r]*$" type) ;; substitution
 638               nil)
 639              (t
 640               (if xml-validating-parser
 641                   (error "XML: (Validity) Invalid element type in the DTD"))))
 642
 643             ;;  rule [45]: the element declaration must be unique
 644             (if (and (assoc element dtd)
 645                      xml-validating-parser)
 646                 (error "XML: (Validity) Element declarations must be unique in a DTD (<%s>)"
 647                        element))
 648
 649             ;;  Store the element in the DTD
 650             (push (list element type) dtd)
 651             (goto-char end-pos))
 652
 653            ;; Translation of rule [52] of XML specifications
 654            ((looking-at (concat "<!ATTLIST[ \t\n\r]*\\(" xml-name-re
 655                                 "\\)[ \t\n\r]*\\(" xml-att-def-re
 656                                 "\\)*[ \t\n\r]*>"))
 657
 658             ;; We don't do anything with ATTLIST currently
 659             (goto-char (match-end 0)))
 660
 661            ((looking-at "<!--")
 662             (search-forward "-->"))
 663            ((looking-at (concat "<!ENTITY[ \t\n\r]*\\(" xml-name-re
 664                                 "\\)[ \t\n\r]*\\(" xml-entity-value-re
 665                                 "\\)[ \t\n\r]*>"))
 666             (let ((name  (match-string-no-properties 1))
 667                   (value (substring (match-string-no-properties 2) 1
 668                                     (- (length (match-string-no-properties 2)) 1))))
 669               (goto-char (match-end 0))
 670               (setq xml-entity-alist
 671                     (append xml-entity-alist
 672                             (list (cons name
 673                                         (with-temp-buffer
 674                                           (insert value)
 675                                           (goto-char (point-min))
 676                                           (xml-parse-fragment
 677                                            xml-validating-parser
 678                                            parse-ns))))))))
 679            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 680                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 681                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 682                 (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 683                                     "\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
 684                                     "\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 685                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
 686                                     "[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
 687                                     "[ \t\n\r]*>")))
 688             (let ((name  (match-string-no-properties 1))
 689                   (file  (substring (match-string-no-properties 2) 1
 690                                     (- (length (match-string-no-properties 2)) 1))))
 691               (goto-char (match-end 0))
 692               (setq xml-entity-alist
 693                     (append xml-entity-alist
 694                             (list (cons name (with-temp-buffer
 695                                                (insert-file-contents file)
 696                                                (goto-char (point-min))
 697                                                (xml-parse-fragment
 698                                                 xml-validating-parser
 699                                                 parse-ns))))))))
 700            ;; skip parameter entity declarations
 701            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+%[ \t\n\r]+\\(" xml-name-re
 702                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 703                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 704                 (looking-at (concat "<!ENTITY[ \t\n\r]+"
 705                                     "%[ \t\n\r]+"
 706                                     "\\(" xml-name-re "\\)[ \t\n\r]+"
 707                                     "PUBLIC[ \t\n\r]+"
 708                                     "\\(\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 709                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'\\)[ \t\n\r]+"
 710                                     "\\(\"[^\"]+\"\\|'[^']+'\\)"
 711                                     "[ \t\n\r]*>")))
 712             (goto-char (match-end 0)))
 713            ;; skip parameter entities
 714            ((looking-at (concat "%" xml-name-re ";"))
 715             (goto-char (match-end 0)))
 716            (t
 717             (when xml-validating-parser
 718               (error "XML: (Validity) Invalid DTD item"))))))
 719       (if (looking-at "\\s-*]>")
 720           (goto-char (match-end 0))))
 721     (nreverse dtd)))
 722
 723 (defun xml-parse-elem-type (string)
 724   "Convert element type STRING into a Lisp structure."
 725
 726   (let (elem modifier)
 727     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 728         (progn
 729           (setq elem     (match-string-no-properties 1 string)
 730                 modifier (match-string-no-properties 2 string))
 731           (if (string-match "|" elem)
 732               (setq elem (cons 'choice
 733                                (mapcar 'xml-parse-elem-type
 734                                        (split-string elem "|"))))
 735             (if (string-match "," elem)
 736                 (setq elem (cons 'seq
 737                                  (mapcar 'xml-parse-elem-type
 738                                          (split-string elem ",")))))))
 739       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 740           (setq elem     (match-string-no-properties 1 string)
 741                 modifier (match-string-no-properties 2 string))))
 742
 743     (if (and (stringp elem) (string= elem "#PCDATA"))
 744         (setq elem 'pcdata))
 745
 746     (cond
 747      ((string= modifier "+")
 748       (list '+ elem))
 749      ((string= modifier "*")
 750       (list '* elem))
 751      ((string= modifier "?")
 752       (list '\? elem))
 753      (t
 754       elem))))
 755
 756 ;;*******************************************************************
 757 ;;**
 758 ;;**  Substituting special XML sequences
 759 ;;**
 760 ;;*******************************************************************
 761
 762 (defun xml-substitute-special (string)
 763   "Return STRING, after subsituting entity references."
 764   ;; This originally made repeated passes through the string from the
 765   ;; beginning, which isn't correct, since then either "&amp;amp;" or
 766   ;; "&#38;amp;" won't DTRT.
 767
 768   (let ((point 0)
 769         children end-point)
 770     (while (string-match "&\\([^;]*\\);" string point)
 771       (setq end-point (match-end 0))
 772       (let* ((this-part (match-string-no-properties 1 string))
 773              (prev-part (substring string point (match-beginning 0)))
 774              (entity (assoc this-part xml-entity-alist))
 775              (expansion
 776               (cond ((string-match "#\\([0-9]+\\)" this-part)
 777                      (let ((c (decode-char
 778                                'ucs
 779                                (string-to-number (match-string-no-properties 1 this-part)))))
 780                        (if c (string c))))
 781                     ((string-match "#x\\([[:xdigit:]]+\\)" this-part)
 782                      (let ((c (decode-char
 783                                'ucs
 784                                (string-to-number (match-string-no-properties 1 this-part) 16))))
 785                        (if c (string c))))
 786                     (entity
 787                      (cdr entity))
 788                     ((eq (length this-part) 0)
 789                      (error "XML: (Not Well-Formed) No entity given"))
 790                     (t
 791                      (if xml-validating-parser
 792                          (error "XML: (Validity) Undefined entity `%s'"
 793                                 this-part)
 794                        xml-undefined-entity)))))
 795
 796         (cond ((null children)
 797                ;; FIXME: If we have an entity that expands into XML, this won't work.
 798                (setq children
 799                      (concat prev-part expansion)))
 800               ((stringp children)
 801                (if (stringp expansion)
 802                    (setq children (concat children prev-part expansion))
 803                  (setq children (list expansion (concat prev-part children)))))
 804               ((and (stringp expansion)
 805                     (stringp (car children)))
 806                (setcar children (concat prev-part expansion (car children))))
 807               ((stringp expansion)
 808                (setq children (append (concat prev-part expansion)
 809                                       children)))
 810               ((stringp (car children))
 811                (setcar children (concat (car children) prev-part))
 812                (setq children (append expansion children)))
 813               (t
 814                (setq children (list expansion
 815                                     prev-part
 816                                     children))))
 817         (setq point end-point)))
 818     (cond ((stringp children)
 819            (concat children (substring string point)))
 820           ((stringp (car (last children)))
 821            (concat (car (last children)) (substring string point)))
 822           ((null children)
 823            string)
 824           (t
 825            (concat (mapconcat 'identity
 826                               (nreverse children)
 827                               "")
 828                    (substring string point))))))
 829
 830 ;;*******************************************************************
 831 ;;**
 832 ;;**  Printing a tree.
 833 ;;**  This function is intended mainly for debugging purposes.
 834 ;;**
 835 ;;*******************************************************************
 836
 837 (defun xml-debug-print (xml &optional indent-string)
 838   "Outputs the XML in the current buffer.
 839 XML can be a tree or a list of nodes.
 840 The first line is indented with the optional INDENT-STRING."
 841   (setq indent-string (or indent-string ""))
 842   (dolist (node xml)
 843     (xml-debug-print-internal node indent-string)))
 844
 845 (defalias 'xml-print 'xml-debug-print)
 846
 847 (defun xml-debug-print-internal (xml indent-string)
 848   "Outputs the XML tree in the current buffer.
 849 The first line is indented with INDENT-STRING."
 850   (let ((tree xml)
 851         attlist)
 852     (insert indent-string ?< (symbol-name (xml-node-name tree)))
 853
 854     ;;  output the attribute list
 855     (setq attlist (xml-node-attributes tree))
 856     (while attlist
 857       (insert ?\  (symbol-name (caar attlist)) "=\"" (cdar attlist) ?\")
 858       (setq attlist (cdr attlist)))
 859
 860     (setq tree (xml-node-children tree))
 861
 862     (if (null tree)
 863         (insert ?/ ?>)
 864       (insert ?>)
 865
 866       ;;  output the children
 867       (dolist (node tree)
 868         (cond
 869          ((listp node)
 870           (insert ?\n)
 871           (xml-debug-print-internal node (concat indent-string "  ")))
 872          ((stringp node) (insert node))
 873          (t
 874           (error "Invalid XML tree"))))
 875
 876       (when (not (and (null (cdr tree))
 877                       (stringp (car tree))))
 878         (insert ?\n indent-string))
 879       (insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
 880
 881 (provide 'xml)
 882
 883 ;; arch-tag: 5864b283-5a68-4b59-a20d-36a72b353b9b
 884 ;;; xml.el ends here