lisp/vc-bzr.el

   1 ;;; vc-bzr.el --- VC backend for the bzr revision control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008, 2009  Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Love <fx@gnu.org>
   6 ;;         Riccardo Murri <riccardo.murri@gmail.com>
   7 ;; Keywords: tools
   8 ;; Created: Sept 2006
   9 ;; Version: 2008-01-04 (Bzr revno 25)
  10 ;; URL: http://launchpad.net/vc-bzr
  11
  12 ;; This file is part of GNU Emacs.
  13
  14 ;; GNU Emacs is free software: you can redistribute it and/or modify
  15 ;; it under the terms of the GNU General Public License as published by
  16 ;; the Free Software Foundation, either version 3 of the License, or
  17 ;; (at your option) any later version.
  18
  19 ;; GNU Emacs is distributed in the hope that it will be useful,
  20 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 ;; GNU General Public License for more details.
  23
  24 ;; You should have received a copy of the GNU General Public License
  25 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  26
  27 ;;; Commentary:
  28
  29 ;; See <URL:http://bazaar-vcs.org/> concerning bzr.  See
  30 ;; <URL:http://launchpad.net/vc-bzr> for alternate development
  31 ;; branches of `vc-bzr'.
  32
  33 ;; Load this library to register bzr support in VC.
  34
  35 ;; Known bugs
  36 ;; ==========
  37
  38 ;; When edititing a symlink and *both* the symlink and its target
  39 ;; are bzr-versioned, `vc-bzr` presently runs `bzr status` on the
  40 ;; symlink, thereby not detecting whether the actual contents
  41 ;; (that is, the target contents) are changed.
  42 ;; See https://bugs.launchpad.net/vc-bzr/+bug/116607
  43
  44 ;; For an up-to-date list of bugs, please see:
  45 ;;   https://bugs.launchpad.net/vc-bzr/+bugs
  46
  47 ;;; Properties of the backend
  48
  49 (defun vc-bzr-revision-granularity () 'repository)
  50 (defun vc-bzr-checkout-model (files) 'implicit)
  51
  52 ;;; Code:
  53
  54 (eval-when-compile
  55   (require 'cl)
  56   (require 'vc)  ;; for vc-exec-after
  57   (require 'vc-dir))
  58
  59 ;; Clear up the cache to force vc-call to check again and discover
  60 ;; new functions when we reload this file.
  61 (put 'Bzr 'vc-functions nil)
  62
  63 (defgroup vc-bzr nil
  64   "VC bzr backend."
  65   :version "22.2"
  66   :group 'vc)
  67
  68 (defcustom vc-bzr-program "bzr"
  69   "Name of the bzr command (excluding any arguments)."
  70   :group 'vc-bzr
  71   :type 'string)
  72
  73 (defcustom vc-bzr-diff-switches nil
  74   "String or list of strings specifying switches for bzr diff under VC.
  75 If nil, use the value of `vc-diff-switches'.  If t, use no switches."
  76   :type '(choice (const :tag "Unspecified" nil)
  77                  (const :tag "None" t)
  78                  (string :tag "Argument String")
  79                  (repeat :tag "Argument List" :value ("") string))
  80   :group 'vc-bzr)
  81
  82 (defcustom vc-bzr-log-switches nil
  83   "String or list of strings specifying switches for bzr log under VC."
  84   :type '(choice (const :tag "None" nil)
  85                  (string :tag "Argument String")
  86                  (repeat :tag "Argument List" :value ("") string))
  87   :group 'vc-bzr)
  88
  89 ;; since v0.9, bzr supports removing the progress indicators
  90 ;; by setting environment variable BZR_PROGRESS_BAR to "none".
  91 (defun vc-bzr-command (bzr-command buffer okstatus file-or-list &rest args)
  92   "Wrapper round `vc-do-command' using `vc-bzr-program' as COMMAND.
  93 Invoke the bzr command adding `BZR_PROGRESS_BAR=none' and
  94 `LC_MESSAGES=C' to the environment."
  95   (let ((process-environment
  96          (list* "BZR_PROGRESS_BAR=none" ; Suppress progress output (bzr >=0.9)
  97                 "LC_MESSAGES=C"         ; Force English output
  98                 process-environment)))
  99     (apply 'vc-do-command (or buffer "*vc*") okstatus vc-bzr-program
 100            file-or-list bzr-command args)))
 101
 102
 103 ;;;###autoload
 104 (defconst vc-bzr-admin-dirname ".bzr"
 105   "Name of the directory containing Bzr repository status files.")
 106 ;;;###autoload
 107 (defconst vc-bzr-admin-checkout-format-file
 108   (concat vc-bzr-admin-dirname "/checkout/format"))
 109 (defconst vc-bzr-admin-dirstate
 110   (concat vc-bzr-admin-dirname "/checkout/dirstate"))
 111 (defconst vc-bzr-admin-branch-format-file
 112   (concat vc-bzr-admin-dirname "/branch/format"))
 113 (defconst vc-bzr-admin-revhistory
 114   (concat vc-bzr-admin-dirname "/branch/revision-history"))
 115 (defconst vc-bzr-admin-lastrev
 116   (concat vc-bzr-admin-dirname "/branch/last-revision"))
 117
 118 ;;;###autoload (defun vc-bzr-registered (file)
 119 ;;;###autoload   (if (vc-find-root file vc-bzr-admin-checkout-format-file)
 120 ;;;###autoload       (progn
 121 ;;;###autoload         (load "vc-bzr")
 122 ;;;###autoload         (vc-bzr-registered file))))
 123
 124 (defun vc-bzr-root (file)
 125   "Return the root directory of the bzr repository containing FILE."
 126   ;; Cache technique copied from vc-arch.el.
 127   (or (vc-file-getprop file 'bzr-root)
 128       (let ((root (vc-find-root file vc-bzr-admin-checkout-format-file)))
 129         (when root (vc-file-setprop file 'bzr-root root)))))
 130
 131 (require 'sha1)                         ;For sha1-program
 132
 133 (defun vc-bzr-sha1 (file)
 134   (with-temp-buffer
 135     (set-buffer-multibyte nil)
 136     (let ((prog sha1-program)
 137           (args nil)
 138           process-file-side-effects)
 139       (when (consp prog)
 140         (setq args (cdr prog))
 141         (setq prog (car prog)))
 142       (apply 'process-file prog (file-relative-name file) t nil args)
 143       (buffer-substring (point-min) (+ (point-min) 40)))))
 144
 145 (defun vc-bzr-state-heuristic (file)
 146   "Like `vc-bzr-state' but hopefully without running Bzr."
 147   ;; `bzr status' was excrutiatingly slow with large histories and
 148   ;; pending merges, so try to avoid using it until they fix their
 149   ;; performance problems.
 150   ;; This function tries first to parse Bzr internal file
 151   ;; `checkout/dirstate', but it may fail if Bzr internal file format
 152   ;; has changed.  As a safeguard, the `checkout/dirstate' file is
 153   ;; only parsed if it contains the string `#bazaar dirstate flat
 154   ;; format 3' in the first line.
 155   ;; If the `checkout/dirstate' file cannot be parsed, fall back to
 156   ;; running `vc-bzr-state'."
 157   (lexical-let ((root (vc-bzr-root file)))
 158     (when root    ; Short cut.
 159       ;; This looks at internal files.  May break if they change
 160       ;; their format.
 161       (lexical-let ((dirstate (expand-file-name vc-bzr-admin-dirstate root)))
 162         (condition-case nil
 163             (with-temp-buffer
 164               (insert-file-contents dirstate)
 165               (goto-char (point-min))
 166               (if (not (looking-at "#bazaar dirstate flat format 3"))
 167                   (vc-bzr-state file)   ; Some other unknown format?
 168                 (let* ((relfile (file-relative-name file root))
 169                        (reldir (file-name-directory relfile)))
 170                   (if (re-search-forward
 171                        (concat "^\0"
 172                                (if reldir (regexp-quote
 173                                            (directory-file-name reldir)))
 174                                "\0"
 175                                (regexp-quote (file-name-nondirectory relfile))
 176                                "\0"
 177                                "[^\0]*\0"     ;id?
 178                                "\\([^\0]*\\)\0" ;"a/f/d", a=removed?
 179                                "[^\0]*\0" ;sha1 (empty if conflicted)?
 180                                "\\([^\0]*\\)\0" ;size?
 181                                "[^\0]*\0"       ;"y/n", executable?
 182                                "[^\0]*\0"       ;?
 183                                "\\([^\0]*\\)\0" ;"a/f/d" a=added?
 184                                "\\([^\0]*\\)\0" ;sha1 again?
 185                                "[^\0]*\0"       ;size again?
 186                                "[^\0]*\0" ;"y/n", executable again?
 187                                "[^\0]*\0" ;last revid?
 188                                ;; There are more fields when merges are pending.
 189                                )
 190                        nil t)
 191                       ;; Apparently the second sha1 is the one we want: when
 192                       ;; there's a conflict, the first sha1 is absent (and the
 193                       ;; first size seems to correspond to the file with
 194                       ;; conflict markers).
 195                       (cond
 196                        ((eq (char-after (match-beginning 1)) ?a) 'removed)
 197                        ((eq (char-after (match-beginning 3)) ?a) 'added)
 198                        ((and (eq (string-to-number (match-string 2))
 199                                  (nth 7 (file-attributes file)))
 200                              (equal (match-string 4)
 201                                     (vc-bzr-sha1 file)))
 202                         'up-to-date)
 203                        (t 'edited))
 204                     'unregistered))))
 205           ;; Either the dirstate file can't be read, or the sha1
 206           ;; executable is missing, or ...
 207           ;; In either case, recent versions of Bzr aren't that slow
 208           ;; any more.
 209           (error (vc-bzr-state file)))))))
 210
 211
 212 (defun vc-bzr-registered (file)
 213   "Return non-nil if FILE is registered with bzr."
 214   (let ((state (vc-bzr-state-heuristic file)))
 215     (not (memq state '(nil unregistered ignored)))))
 216
 217 (defconst vc-bzr-state-words
 218   "added\\|ignored\\|kind changed\\|modified\\|removed\\|renamed\\|unknown"
 219   "Regexp matching file status words as reported in `bzr' output.")
 220
 221 (defun vc-bzr-file-name-relative (filename)
 222   "Return file name FILENAME stripped of the initial Bzr repository path."
 223   (lexical-let*
 224       ((filename* (expand-file-name filename))
 225        (rootdir (vc-bzr-root filename*)))
 226     (when rootdir
 227          (file-relative-name filename* rootdir))))
 228
 229 (defun vc-bzr-status (file)
 230   "Return FILE status according to Bzr.
 231 Return value is a cons (STATUS . WARNING), where WARNING is a
 232 string or nil, and STATUS is one of the symbols: `added',
 233 `ignored', `kindchanged', `modified', `removed', `renamed', `unknown',
 234 which directly correspond to `bzr status' output, or 'unchanged
 235 for files whose copy in the working tree is identical to the one
 236 in the branch repository, or nil for files that are not
 237 registered with Bzr.
 238
 239 If any error occurred in running `bzr status', then return nil."
 240   (with-temp-buffer
 241     (let ((ret (condition-case nil
 242                    (vc-bzr-command "status" t 0 file)
 243                  (file-error nil)))     ; vc-bzr-program not found.
 244           (status 'unchanged))
 245           ;; the only secure status indication in `bzr status' output
 246           ;; is a couple of lines following the pattern::
 247           ;;   | <status>:
 248           ;;   |   <file name>
 249           ;; if the file is up-to-date, we get no status report from `bzr',
 250           ;; so if the regexp search for the above pattern fails, we consider
 251           ;; the file to be up-to-date.
 252           (goto-char (point-min))
 253           (when (re-search-forward
 254                  ;; bzr prints paths relative to the repository root.
 255                  (concat "^\\(" vc-bzr-state-words "\\):[ \t\n]+"
 256                          (regexp-quote (vc-bzr-file-name-relative file))
 257                          ;; Bzr appends a '/' to directory names and
 258                          ;; '*' to executable files
 259                          (if (file-directory-p file) "/?" "\\*?")
 260                          "[ \t\n]*$")
 261                  nil t)
 262             (lexical-let ((statusword (match-string 1)))
 263               ;; Erase the status text that matched.
 264               (delete-region (match-beginning 0) (match-end 0))
 265               (setq status
 266                     (intern (replace-regexp-in-string " " "" statusword)))))
 267           (when status
 268             (goto-char (point-min))
 269             (skip-chars-forward " \n\t") ;Throw away spaces.
 270             (cons status
 271                   ;; "bzr" will output warnings and informational messages to
 272                   ;; stderr; due to Emacs' `vc-do-command' (and, it seems,
 273                   ;; `start-process' itself) limitations, we cannot catch stderr
 274                   ;; and stdout into different buffers.  So, if there's anything
 275                   ;; left in the buffer after removing the above status
 276                   ;; keywords, let us just presume that any other message from
 277                   ;; "bzr" is a user warning, and display it.
 278                   (unless (eobp) (buffer-substring (point) (point-max))))))))
 279
 280 (defun vc-bzr-state (file)
 281   (lexical-let ((result (vc-bzr-status file)))
 282     (when (consp result)
 283       (when (cdr result)
 284         (message "Warnings in `bzr' output: %s" (cdr result)))
 285       (cdr (assq (car result)
 286                  '((added . added)
 287                    (kindchanged . edited)
 288                    (renamed . edited)
 289                    (modified . edited)
 290                    (removed . removed)
 291                    (ignored . ignored)
 292                    (unknown . unregistered)
 293                    (unchanged . up-to-date)))))))
 294
 295 (defun vc-bzr-resolve-when-done ()
 296   "Call \"bzr resolve\" if the conflict markers have been removed."
 297   (save-excursion
 298     (goto-char (point-min))
 299     (unless (re-search-forward "^<<<<<<< " nil t)
 300       (vc-bzr-command "resolve" nil 0 buffer-file-name)
 301       ;; Remove the hook so that it is not called multiple times.
 302       (remove-hook 'after-save-hook 'vc-bzr-resolve-when-done t))))
 303
 304 (defun vc-bzr-find-file-hook ()
 305   (when (and buffer-file-name
 306              ;; FIXME: We should check that "bzr status" says "conflict".
 307              (file-exists-p (concat buffer-file-name ".BASE"))
 308              (file-exists-p (concat buffer-file-name ".OTHER"))
 309              (file-exists-p (concat buffer-file-name ".THIS"))
 310              ;; If "bzr status" says there's a conflict but there are no
 311              ;; conflict markers, it's not clear what we should do.
 312              (save-excursion
 313                (goto-char (point-min))
 314                (re-search-forward "^<<<<<<< " nil t)))
 315     ;; TODO: the merge algorithm used in `bzr merge' is nicely configurable,
 316     ;; but the one in `bzr pull' isn't, so it would be good to provide an
 317     ;; elisp function to remerge from the .BASE/OTHER/THIS files.
 318     (smerge-start-session)
 319     (add-hook 'after-save-hook 'vc-bzr-resolve-when-done nil t)
 320     (message "There are unresolved conflicts in this file")))
 321
 322 (defun vc-bzr-workfile-unchanged-p (file)
 323   (eq 'unchanged (car (vc-bzr-status file))))
 324
 325 (defun vc-bzr-working-revision (file)
 326   ;; Together with the code in vc-state-heuristic, this makes it possible
 327   ;; to get the initial VC state of a Bzr file even if Bzr is not installed.
 328   (lexical-let*
 329       ((rootdir (vc-bzr-root file))
 330        (branch-format-file (expand-file-name vc-bzr-admin-branch-format-file
 331                                              rootdir))
 332        (revhistory-file (expand-file-name vc-bzr-admin-revhistory rootdir))
 333        (lastrev-file (expand-file-name vc-bzr-admin-lastrev rootdir)))
 334     ;; This looks at internal files to avoid forking a bzr process.
 335     ;; May break if they change their format.
 336     (if (and (file-exists-p branch-format-file)
 337              ;; For lightweight checkouts (obtained with bzr checkout --lightweight)
 338              ;; the branch-format-file does not contain the revision
 339              ;; information, we need to look up the branch-format-file
 340              ;; in the place where the lightweight checkout comes
 341              ;; from.  We only do that if it's a local file.
 342              (let ((location-fname (expand-file-name
 343                                     (concat vc-bzr-admin-dirname
 344                                             "/branch/location") rootdir)))
 345                ;; The existence of this file is how we distinguish
 346                ;; lightweight checkouts.
 347                (if (file-exists-p location-fname)
 348                    (with-temp-buffer
 349                      (insert-file-contents location-fname)
 350                      (when (re-search-forward "file://\(.+\)" nil t)
 351                        (setq branch-format-file (match-string 1))
 352                        (file-exists-p branch-format-file)))
 353                  t)))
 354         (with-temp-buffer
 355           (insert-file-contents branch-format-file)
 356           (goto-char (point-min))
 357           (cond
 358            ((or
 359              (looking-at "Bazaar-NG branch, format 0.0.4")
 360              (looking-at "Bazaar-NG branch format 5"))
 361             ;; count lines in .bzr/branch/revision-history
 362             (insert-file-contents revhistory-file)
 363             (number-to-string (count-lines (line-end-position) (point-max))))
 364            ((or
 365              (looking-at "Bazaar Branch Format 6 (bzr 0.15)")
 366              (looking-at "Bazaar Branch Format 7 (needs bzr 1.6)"))
 367             ;; revno is the first number in .bzr/branch/last-revision
 368             (insert-file-contents lastrev-file)
 369             (when (re-search-forward "[0-9]+" nil t)
 370               (buffer-substring (match-beginning 0) (match-end 0))))))
 371       ;; fallback to calling "bzr revno"
 372       (lexical-let*
 373           ((result (vc-bzr-command-discarding-stderr
 374                     vc-bzr-program "revno" (file-relative-name file)))
 375            (exitcode (car result))
 376            (output (cdr result)))
 377         (cond
 378          ((eq exitcode 0) (substring output 0 -1))
 379          (t nil))))))
 380
 381 (defun vc-bzr-create-repo ()
 382   "Create a new Bzr repository."
 383   (vc-bzr-command "init" nil 0 nil))
 384
 385 (defun vc-bzr-init-revision (&optional file)
 386   "Always return nil, as Bzr cannot register explicit versions."
 387   nil)
 388
 389 (defun vc-bzr-previous-revision (file rev)
 390   (if (string-match "\\`[0-9]+\\'" rev)
 391       (number-to-string (1- (string-to-number rev)))
 392     (concat "before:" rev)))
 393
 394 (defun vc-bzr-next-revision (file rev)
 395   (if (string-match "\\`[0-9]+\\'" rev)
 396       (number-to-string (1+ (string-to-number rev)))
 397     (error "Don't know how to compute the next revision of %s" rev)))
 398
 399 (defun vc-bzr-register (files &optional rev comment)
 400   "Register FILE under bzr.
 401 Signal an error unless REV is nil.
 402 COMMENT is ignored."
 403   (if rev (error "Can't register explicit revision with bzr"))
 404   (vc-bzr-command "add" nil 0 files))
 405
 406 ;; Could run `bzr status' in the directory and see if it succeeds, but
 407 ;; that's relatively expensive.
 408 (defalias 'vc-bzr-responsible-p 'vc-bzr-root
 409   "Return non-nil if FILE is (potentially) controlled by bzr.
 410 The criterion is that there is a `.bzr' directory in the same
 411 or a superior directory.")
 412
 413 (defun vc-bzr-could-register (file)
 414   "Return non-nil if FILE could be registered under bzr."
 415   (and (vc-bzr-responsible-p file)      ; shortcut
 416        (condition-case ()
 417            (with-temp-buffer
 418              (vc-bzr-command "add" t 0 file "--dry-run")
 419              ;; The command succeeds with no output if file is
 420              ;; registered (in bzr 0.8).
 421              (goto-char (point-min))
 422              (looking-at "added "))
 423          (error))))
 424
 425 (defun vc-bzr-unregister (file)
 426   "Unregister FILE from bzr."
 427   (vc-bzr-command "remove" nil 0 file "--keep"))
 428
 429 (defun vc-bzr-checkin (files rev comment)
 430   "Check FILE in to bzr with log message COMMENT.
 431 REV non-nil gets an error."
 432   (if rev (error "Can't check in a specific revision with bzr"))
 433   (vc-bzr-command "commit" nil 0 files "-m" comment))
 434
 435 (defun vc-bzr-find-revision (file rev buffer)
 436   "Fetch revision REV of file FILE and put it into BUFFER."
 437     (with-current-buffer buffer
 438       (if (and rev (stringp rev) (not (string= rev "")))
 439           (vc-bzr-command "cat" t 0 file "-r" rev)
 440         (vc-bzr-command "cat" t 0 file))))
 441
 442 (defun vc-bzr-checkout (file &optional editable rev)
 443   (if rev (error "Operation not supported")
 444     ;; Else, there's nothing to do.
 445     nil))
 446
 447 (defun vc-bzr-revert (file &optional contents-done)
 448   (unless contents-done
 449     (with-temp-buffer (vc-bzr-command "revert" t 0 file))))
 450
 451 (defvar log-view-message-re)
 452 (defvar log-view-file-re)
 453 (defvar log-view-font-lock-keywords)
 454 (defvar log-view-current-tag-function)
 455 (defvar log-view-per-file-logs)
 456 (defvar vc-short-log)
 457
 458 (define-derived-mode vc-bzr-log-view-mode log-view-mode "Bzr-Log-View"
 459   (remove-hook 'log-view-mode-hook 'vc-bzr-log-view-mode) ;Deactivate the hack.
 460   (require 'add-log)
 461   (set (make-local-variable 'log-view-per-file-logs) nil)
 462   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 463   (set (make-local-variable 'log-view-message-re)
 464        (if vc-short-log
 465            "^ +\\([0-9]+\\) \\(.*?\\)[ \t]+\\([0-9]\\{4\\}-[0-9]\\{2\\}-[0-9]\\{2\\}\\)\\( \\[merge\\]\\)?"
 466          "^ *\\(?:revno: \\([0-9.]+\\)\\|merged: .+\\)"))
 467   (set (make-local-variable 'log-view-font-lock-keywords)
 468        ;; log-view-font-lock-keywords is careful to use the buffer-local
 469        ;; value of log-view-message-re only since Emacs-23.
 470        (if vc-short-log
 471          (append `((,log-view-message-re
 472                     (1 'log-view-message-face)
 473                     (2 'change-log-name)
 474                     (3 'change-log-date)
 475                     (4 'change-log-list))))
 476          (append `((,log-view-message-re . 'log-view-message-face))
 477                  ;; log-view-font-lock-keywords
 478                  '(("^ *committer: \
 479 \\([^<(]+?\\)[  ]*[(<]\\([[:alnum:]_.+-]+@[[:alnum:]_.-]+\\)[>)]"
 480                     (1 'change-log-name)
 481                     (2 'change-log-email))
 482                    ("^ *timestamp: \\(.*\\)" (1 'change-log-date-face)))))))
 483
 484 (defun vc-bzr-print-log (files &optional buffer shortlog) ; get buffer arg in Emacs 22
 485   "Get bzr change log for FILES into specified BUFFER."
 486   ;; `vc-do-command' creates the buffer, but we need it before running
 487   ;; the command.
 488   (vc-setup-buffer buffer)
 489   ;; If the buffer exists from a previous invocation it might be
 490   ;; read-only.
 491   ;; FIXME: `vc-bzr-command' runs `bzr log' with `LC_MESSAGES=C', so
 492   ;; the log display may not what the user wants - but I see no other
 493   ;; way of getting the above regexps working.
 494   (with-current-buffer buffer
 495     (apply 'vc-bzr-command "log" buffer 'async files
 496            (if shortlog "--short")
 497            (if (stringp vc-bzr-log-switches)
 498                (list vc-bzr-log-switches)
 499              vc-bzr-log-switches))))
 500
 501 (defun vc-bzr-show-log-entry (revision)
 502   "Find entry for patch name REVISION in bzr change log buffer."
 503   (goto-char (point-min))
 504   (when revision
 505     (let (case-fold-search)
 506       (if (re-search-forward
 507            ;; "revno:" can appear either at the beginning of a line,
 508            ;; or indented.
 509            (concat "^[ ]*-+\n[ ]*revno: "
 510                    ;; The revision can contain ".", quote it so that it
 511                    ;; does not interfere with regexp matching.
 512                    (regexp-quote revision) "$") nil t)
 513           (beginning-of-line 0)
 514         (goto-char (point-min))))))
 515
 516 (defun vc-bzr-diff (files &optional rev1 rev2 buffer)
 517   "VC bzr backend for diff."
 518   ;; `bzr diff' exits with code 1 if diff is non-empty.
 519   (apply #'vc-bzr-command "diff" (or buffer "*vc-diff*") 'async files
 520          "--diff-options" (mapconcat 'identity
 521                                      (vc-switches 'bzr 'diff)
 522                                      " ")
 523          ;; This `when' is just an optimization because bzr-1.2 is *much*
 524          ;; faster when the revision argument is not given.
 525          (when (or rev1 rev2)
 526            (list "-r" (format "%s..%s"
 527                               (or rev1 "revno:-1")
 528                               (or rev2 ""))))))
 529
 530
 531 ;; FIXME: vc-{next,previous}-revision need fixing in vc.el to deal with
 532 ;; straight integer revisions.
 533
 534 (defun vc-bzr-delete-file (file)
 535   "Delete FILE and delete it in the bzr repository."
 536   (condition-case ()
 537       (delete-file file)
 538     (file-error nil))
 539   (vc-bzr-command "remove" nil 0 file))
 540
 541 (defun vc-bzr-rename-file (old new)
 542   "Rename file from OLD to NEW using `bzr mv'."
 543   (vc-bzr-command "mv" nil 0 new old))
 544
 545 (defvar vc-bzr-annotation-table nil
 546   "Internal use.")
 547 (make-variable-buffer-local 'vc-bzr-annotation-table)
 548
 549 (defun vc-bzr-annotate-command (file buffer &optional revision)
 550   "Prepare BUFFER for `vc-annotate' on FILE.
 551 Each line is tagged with the revision number, which has a `help-echo'
 552 property containing author and date information."
 553   (apply #'vc-bzr-command "annotate" buffer 0 file "--long" "--all"
 554          (if revision (list "-r" revision)))
 555   (with-current-buffer buffer
 556     ;; Store the tags for the annotated source lines in a hash table
 557     ;; to allow saving space by sharing the text properties.
 558     (setq vc-bzr-annotation-table (make-hash-table :test 'equal))
 559     (goto-char (point-min))
 560     (while (re-search-forward "^\\( *[0-9.]+ *\\) \\([^\n ]+\\) +\\([0-9]\\{8\\}\\) |"
 561                               nil t)
 562       (let* ((rev (match-string 1))
 563              (author (match-string 2))
 564              (date (match-string 3))
 565              (key (match-string 0))
 566              (tag (gethash key vc-bzr-annotation-table)))
 567         (unless tag
 568           (setq tag (propertize rev 'help-echo (concat "Author: " author
 569                                                        ", date: " date)
 570                                 'mouse-face 'highlight))
 571           (puthash key tag vc-bzr-annotation-table))
 572         (replace-match "")
 573         (insert tag " |")))))
 574
 575 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 576
 577 (defun vc-bzr-annotate-time ()
 578   (when (re-search-forward "^ *[0-9.]+ +|" nil t)
 579     (let ((prop (get-text-property (line-beginning-position) 'help-echo)))
 580       (string-match "[0-9]+\\'" prop)
 581       (let ((str (match-string-no-properties 0 prop)))
 582       (vc-annotate-convert-time
 583        (encode-time 0 0 0
 584                       (string-to-number (substring str 6 8))
 585                       (string-to-number (substring str 4 6))
 586                       (string-to-number (substring str 0 4))))))))
 587
 588 (defun vc-bzr-annotate-extract-revision-at-line ()
 589   "Return revision for current line of annoation buffer, or nil.
 590 Return nil if current line isn't annotated."
 591   (save-excursion
 592     (beginning-of-line)
 593     (if (looking-at " *\\([0-9.]+\\) *| ")
 594         (match-string-no-properties 1))))
 595
 596 (defun vc-bzr-command-discarding-stderr (command &rest args)
 597   "Execute shell command COMMAND (with ARGS); return its output and exitcode.
 598 Return value is a cons (EXITCODE . OUTPUT), where EXITCODE is
 599 the (numerical) exit code of the process, and OUTPUT is a string
 600 containing whatever the process sent to its standard output
 601 stream.  Standard error output is discarded."
 602   (with-temp-buffer
 603     (cons
 604      (apply #'process-file command nil (list (current-buffer) nil) nil args)
 605      (buffer-substring (point-min) (point-max)))))
 606
 607 (defstruct (vc-bzr-extra-fileinfo
 608             (:copier nil)
 609             (:constructor vc-bzr-create-extra-fileinfo (extra-name))
 610             (:conc-name vc-bzr-extra-fileinfo->))
 611   extra-name)         ;; original name for rename targets, new name for
 612
 613 (defun vc-bzr-dir-printer (info)
 614   "Pretty-printer for the vc-dir-fileinfo structure."
 615   (let ((extra (vc-dir-fileinfo->extra info)))
 616     (vc-default-dir-printer 'Bzr info)
 617     (when extra
 618       (insert (propertize
 619                (format "   (renamed from %s)"
 620                        (vc-bzr-extra-fileinfo->extra-name extra))
 621                'face 'font-lock-comment-face)))))
 622
 623 ;; FIXME: this needs testing, it's probably incomplete.
 624 (defun vc-bzr-after-dir-status (update-function)
 625   (let ((status-str nil)
 626         (translation '(("+N " . added)
 627                        ("-D " . removed)
 628                        (" M " . edited) ;; file text modified
 629                        ("  *" . edited) ;; execute bit changed
 630                        (" M*" . edited) ;; text modified + execute bit changed
 631                        ;; FIXME: what about ignored files?
 632                        (" D " . missing)
 633                        ;; For conflicts, should we list the .THIS/.BASE/.OTHER?
 634                        ("C  " . conflict)
 635                        ("?  " . unregistered)
 636                        ("?  " . unregistered)
 637                        ;; No such state, but we need to distinguish this case.
 638                        ("R  " . renamed)
 639                        ;; For a non existent file FOO, the output is:
 640                        ;; bzr: ERROR: Path(s) do not exist: FOO
 641                        ("bzr" . not-found)
 642                        ;; If the tree is not up to date, bzr will print this warning:
 643                        ;; working tree is out of date, run 'bzr update'
 644                        ;; ignore it.
 645                        ;; FIXME: maybe this warning can be put in the vc-dir header...
 646                        ("wor" . not-found)
 647                        ;; Ignore "P " and "P." for pending patches.
 648                        ))
 649         (translated nil)
 650         (result nil))
 651       (goto-char (point-min))
 652       (while (not (eobp))
 653         (setq status-str
 654               (buffer-substring-no-properties (point) (+ (point) 3)))
 655         (setq translated (cdr (assoc status-str translation)))
 656         (cond
 657          ((eq translated 'conflict)
 658           ;; For conflicts the file appears twice in the listing: once
 659           ;; with the M flag and once with the C flag, so take care
 660           ;; not to add it twice to `result'.  Ugly.
 661           (let* ((file
 662                   (buffer-substring-no-properties
 663                    ;;For files with conflicts the format is:
 664                    ;;C   Text conflict in FILENAME
 665                    ;; Bah.
 666                    (+ (point) 21) (line-end-position)))
 667                  (entry (assoc file result)))
 668             (when entry
 669               (setf (nth 1 entry) 'conflict))))
 670          ((eq translated 'renamed)
 671           (re-search-forward "R   \\(.*\\) => \\(.*\\)$" (line-end-position) t)
 672           (let ((new-name (match-string 2))
 673                 (old-name (match-string 1)))
 674             (push (list new-name 'edited
 675                       (vc-bzr-create-extra-fileinfo old-name)) result)))
 676          ;; do nothing for non existent files
 677          ((eq translated 'not-found))
 678          (t
 679           (push (list (buffer-substring-no-properties
 680                        (+ (point) 4)
 681                        (line-end-position))
 682                       translated) result)))
 683         (forward-line))
 684       (funcall update-function result)))
 685
 686 (defun vc-bzr-dir-status (dir update-function)
 687   "Return a list of conses (file . state) for DIR."
 688   (vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S")
 689   (vc-exec-after
 690    `(vc-bzr-after-dir-status (quote ,update-function))))
 691
 692 (defun vc-bzr-dir-status-files (dir files default-state update-function)
 693   "Return a list of conses (file . state) for DIR."
 694   (apply 'vc-bzr-command "status" (current-buffer) 'async dir "-v" "-S" files)
 695   (vc-exec-after
 696    `(vc-bzr-after-dir-status (quote ,update-function))))
 697
 698 (defun vc-bzr-dir-extra-headers (dir)
 699   (let*
 700       ((str (with-temp-buffer
 701               (vc-bzr-command "info" t 0 dir)
 702               (buffer-string)))
 703        (light-checkout
 704         (when (string-match ".+light checkout root: \\(.+\\)$" str)
 705           (match-string 1 str)))
 706        (light-checkout-branch
 707         (when light-checkout
 708           (when (string-match ".+checkout of branch: \\(.+\\)$" str)
 709             (match-string 1 str)))))
 710     (concat
 711      (propertize "Parent branch      : " 'face 'font-lock-type-face)
 712      (propertize
 713       (if (string-match "parent branch: \\(.+\\)$" str)
 714           (match-string 1 str)
 715         "None")
 716        'face 'font-lock-variable-name-face)
 717      "\n"
 718       (when light-checkout
 719         (concat
 720          (propertize "Light checkout root: " 'face 'font-lock-type-face)
 721          (propertize light-checkout 'face 'font-lock-variable-name-face)
 722          "\n"))
 723       (when light-checkout-branch
 724         (concat
 725          (propertize "Checkout of branch : " 'face 'font-lock-type-face)
 726          (propertize light-checkout-branch 'face 'font-lock-variable-name-face)
 727          "\n")))))
 728
 729 ;;; Revision completion
 730
 731 (eval-and-compile
 732   (defconst vc-bzr-revision-keywords
 733     '("revno" "revid" "last" "before"
 734       "tag" "date" "ancestor" "branch" "submit")))
 735
 736 (defun vc-bzr-revision-completion-table (files)
 737   (lexical-let ((files files))
 738     ;; What about using `files'?!?  --Stef
 739     (lambda (string pred action)
 740       (cond
 741        ((string-match "\\`\\(ancestor\\|branch\\|\\(revno:\\)?[-0-9]+:\\):"
 742                       string)
 743         (completion-table-with-context (substring string 0 (match-end 0))
 744                                        'completion-file-name-table
 745                                        (substring string (match-end 0))
 746                                        ;; Dropping `pred' for no good reason.
 747                                        'file-directory-p
 748                                        action))
 749        ((string-match "\\`\\(before\\):" string)
 750         (completion-table-with-context (substring string 0 (match-end 0))
 751                                        (vc-bzr-revision-completion-table files)
 752                                        (substring string (match-end 0))
 753                                        pred
 754                                        action))
 755        ((string-match "\\`\\(tag\\):" string)
 756         (let ((prefix (substring string 0 (match-end 0)))
 757               (tag (substring string (match-end 0)))
 758               (table nil)
 759               process-file-side-effects)
 760           (with-temp-buffer
 761             ;; "bzr-1.2 tags" is much faster with --show-ids.
 762             (process-file vc-bzr-program nil '(t) nil "tags" "--show-ids")
 763             ;; The output is ambiguous, unless we assume that revids do not
 764             ;; contain spaces.
 765             (goto-char (point-min))
 766             (while (re-search-forward "^\\(.*[^ \n]\\) +[^ \n]*$" nil t)
 767               (push (match-string-no-properties 1) table)))
 768           (completion-table-with-context prefix table tag pred action)))
 769
 770        ((string-match "\\`\\([a-z]+\\):" string)
 771         ;; no actual completion for the remaining keywords.
 772         (completion-table-with-context (substring string 0 (match-end 0))
 773                                        (if (member (match-string 1 string)
 774                                                    vc-bzr-revision-keywords)
 775                                            ;; If it's a valid keyword,
 776                                            ;; use a non-empty table to
 777                                            ;; indicate it.
 778                                            '("") nil)
 779                                        (substring string (match-end 0))
 780                                        pred
 781                                        action))
 782        (t
 783         ;; Could use completion-table-with-terminator, except that it
 784         ;; currently doesn't work right w.r.t pcm and doesn't give
 785         ;; the *Completions* output we want.
 786         (complete-with-action action (eval-when-compile
 787                                        (mapcar (lambda (s) (concat s ":"))
 788                                                vc-bzr-revision-keywords))
 789                               string pred))))))
 790
 791 (eval-after-load "vc"
 792   '(add-to-list 'vc-directory-exclusion-list vc-bzr-admin-dirname t))
 793
 794 (provide 'vc-bzr)
 795 ;; arch-tag: 8101bad8-4e92-4e7d-85ae-d8e08b4e7c06
 796 ;;; vc-bzr.el ends here