lisp/timezone.el

   1 ;;; Timezone package for GNU Emacs
   2
   3 ;; Copyright (C) 1990, 1991, 1992, 1993 Free Software Foundation, Inc.
   4
   5 ;;; Author: Masanobu Umeda
   6 ;;; Maintainer: umerin@mse.kyutech.ac.jp
   7 ;;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Code:
  26
  27 (provide 'timezone)
  28
  29 (defvar timezone-world-timezones
  30   '(("PST" .  -800)
  31     ("PDT" .  -700)
  32     ("MST" .  -700)
  33     ("MDT" .  -600)
  34     ("CST" .  -600)
  35     ("CDT" .  -500)
  36     ("EST" .  -500)
  37     ("EDT" .  -400)
  38     ("AST" .  -400)                     ;by <clamen@CS.CMU.EDU>
  39     ("NST" .  -330)                     ;by <clamen@CS.CMU.EDU>
  40     ("UT"  .  +000)
  41     ("GMT" .  +000)
  42     ("BST" .  +100)
  43     ("MET" .  +100)
  44     ("EET" .  +200)
  45     ("JST" .  +900)
  46     ("GMT+1"  .  +100) ("GMT+2"  .  +200) ("GMT+3"  .  +300)
  47     ("GMT+4"  .  +400) ("GMT+5"  .  +500) ("GMT+6"  .  +600)
  48     ("GMT+7"  .  +700) ("GMT+8"  .  +800) ("GMT+9"  .  +900)
  49     ("GMT+10" . +1000) ("GMT+11" . +1100) ("GMT+12" . +1200) ("GMT+13" . +1300)
  50     ("GMT-1"  .  -100) ("GMT-2"  .  -200) ("GMT-3"  .  -300)
  51     ("GMT-4"  .  -400) ("GMT-5"  .  -500) ("GMT-6"  .  -600)
  52     ("GMT-7"  .  -700) ("GMT-8"  .  -800) ("GMT-9"  .  -900)
  53     ("GMT-10" . -1000) ("GMT-11" . -1100) ("GMT-12" . -1200))
  54   "*Time differentials of timezone from GMT in +-HHMM form.
  55 This list is obsolescent, and is present only for backwards compatibility,
  56 because time zone names are ambiguous in practice.
  57 Use `current-time-zone' instead.")
  58
  59 (defvar timezone-months-assoc
  60   '(("JAN" .  1)("FEB" .  2)("MAR" .  3)
  61     ("APR" .  4)("MAY" .  5)("JUN" .  6)
  62     ("JUL" .  7)("AUG" .  8)("SEP" .  9)
  63     ("OCT" . 10)("NOV" . 11)("DEC" . 12))
  64   "Alist of first three letters of a month and its numerical representation.")
  65
  66 (defun timezone-make-date-arpa-standard (date &optional local timezone)
  67   "Convert DATE to an arpanet standard date.
  68 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  69 if nil, GMT is assumed.
  70 Optional 2nd argument TIMEZONE specifies a time zone to be represented in;
  71 if nil, the local time zone is assumed."
  72   (let ((new (timezone-fix-time date local timezone)))
  73     (timezone-make-arpa-date (aref new 0) (aref new 1) (aref new 2)
  74                              (timezone-make-time-string
  75                               (aref new 3) (aref new 4) (aref new 5))
  76                              (aref new 6))
  77     ))
  78
  79 (defun timezone-make-date-sortable (date &optional local timezone)
  80   "Convert DATE to a sortable date string.
  81 Optional 1st argument LOCAL specifies the default local timezone of the DATE;
  82 if nil, GMT is assumed.
  83 Optional 2nd argument TIMEZONE specifies a timezone to be represented in;
  84 if nil, the local time zone is assumed."
  85   (let ((new (timezone-fix-time date local timezone)))
  86     (timezone-make-sortable-date (aref new 0) (aref new 1) (aref new 2)
  87                                  (timezone-make-time-string
  88                                   (aref new 3) (aref new 4) (aref new 5)))
  89     ))
  90
  91 \f
  92 ;;
  93 ;; Parsers and Constructors of Date and Time
  94 ;;
  95
  96 (defun timezone-make-arpa-date (year month day time &optional timezone)
  97   "Make arpanet standard date string from YEAR, MONTH, DAY, and TIME.
  98 Optional argument TIMEZONE specifies a time zone."
  99   (let ((zone
 100          (if (listp timezone)
 101              (let* ((m (timezone-zone-to-minute timezone))
 102                     (absm (if (< m 0) (- m) m)))
 103                (format "%c%02d%02d"
 104                        (if (< m 0) ?- ?+) (/ absm 60) (% absm 60)))
 105            timezone)))
 106     (format "%02d %s %04d %s %s"
 107             day
 108             (capitalize (car (rassq month timezone-months-assoc)))
 109             year
 110             time
 111             zone)))
 112
 113 (defun timezone-make-sortable-date (year month day time)
 114   "Make sortable date string from YEAR, MONTH, DAY, and TIME."
 115   (format "%4d%02d%02d%s"
 116           year month day time))
 117
 118 (defun timezone-make-time-string (hour minute second)
 119   "Make time string from HOUR, MINUTE, and SECOND."
 120   (format "%02d:%02d:%02d" hour minute second))
 121
 122 (defun timezone-parse-date (date)
 123   "Parse DATE and return a vector [YEAR MONTH DAY TIME TIMEZONE].
 124 19 is prepended to year if necessary.  Timezone may be nil if nothing.
 125 Understands the following styles:
 126  (1) 14 Apr 89 03:20[:12] [GMT]
 127  (2) Fri, 17 Mar 89 4:01[:33] [GMT]
 128  (3) Mon Jan 16 16:12[:37] [GMT] 1989
 129  (4) 6 May 1992 1641-JST (Wednesday)
 130  (5) 22-AUG-1993 10:59:12.82
 131  (6) Thu, 11 Apr 16:17:12 91 [MET]
 132  (7) Mon, 6  Jul 16:47:20 T 1992 [MET]"
 133   ;; Get rid of any text properties.
 134   (and (stringp date)
 135        (or (text-properties-at 0 date)
 136            (next-property-change 0 date))
 137        (setq date (copy-sequence date))
 138        (set-text-properties 0 (length date) nil date))
 139   (let ((date (or date ""))
 140         (year nil)
 141         (month nil)
 142         (day nil)
 143         (time nil)
 144         (zone nil))                     ;This may be nil.
 145     (cond ((string-match
 146             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\'" date)
 147            ;; Styles: (6) and (7) without timezone
 148            (setq year 6 month 3 day 2 time 4 zone nil))
 149           ((string-match
 150             "\\([^ \t,]+\\),[ \t]+\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\(T[ \t]+\\|\\)\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 151            ;; Styles: (6) and (7) with timezone and buggy timezone
 152            (setq year 6 month 3 day 2 time 4 zone 7))
 153           ((string-match
 154             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\'" date)
 155            ;; Styles: (1) and (2) without timezone
 156            (setq year 3 month 2 day 1 time 4 zone nil))
 157           ((string-match
 158             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 159            ;; Styles: (1) and (2) with timezone and buggy timezone
 160            (setq year 3 month 2 day 1 time 4 zone 5))
 161           ((string-match
 162             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([0-9]+\\)" date)
 163            ;; Styles: (3) without timezone
 164            (setq year 4 month 1 day 2 time 3 zone nil))
 165           ((string-match
 166             "\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9:]+\\)[ \t]+\\([-+a-zA-Z0-9]+\\)[ \t]+\\([0-9]+\\)" date)
 167            ;; Styles: (3) with timezone
 168            (setq year 5 month 1 day 2 time 3 zone 4))
 169           ((string-match
 170             "\\([0-9]+\\)[ \t]+\\([^ \t,]+\\)[ \t]+\\([0-9]+\\)[ \t]+\\([0-9]+\\)[ \t]*\\([-+a-zA-Z0-9]+\\)" date)
 171            ;; Styles: (4) with timezone
 172            (setq year 3 month 2 day 1 time 4 zone 5))
 173           ((string-match
 174             "\\([0-9]+\\)-\\([A-Za-z]+\\)-\\([0-9]+\\)[ \t]+\\([0-9]+:[0-9]+:[0-9]+\\)\\.[0-9]+" date)
 175            ;; Styles: (5) without timezone.
 176            (setq year 3 month 2 day 1 time 4 zone nil))
 177           )
 178     (if year
 179         (progn
 180           (setq year
 181                 (substring date (match-beginning year) (match-end year)))
 182           ;; It is now Dec 1992.  8 years before the end of the World.
 183           (if (< (length year) 4)
 184               (setq year (concat "19" (substring year -2 nil))))
 185           (let ((string (substring date
 186                                    (match-beginning month)
 187                                    (+ (match-beginning month) 3))))
 188             (setq month
 189                   (int-to-string
 190                    (cdr (assoc (upcase string) timezone-months-assoc)))))
 191
 192           (setq day
 193                 (substring date (match-beginning day) (match-end day)))
 194           (setq time
 195                 (substring date (match-beginning time) (match-end time)))))
 196     (if zone
 197         (setq zone
 198               (substring date (match-beginning zone) (match-end zone))))
 199     ;; Return a vector.
 200     (if year
 201         (vector year month day time zone)
 202       (vector "0" "0" "0" "0" nil))
 203     ))
 204
 205 (defun timezone-parse-time (time)
 206   "Parse TIME (HH:MM:SS) and return a vector [hour minute second].
 207 Recognize HH:MM:SS, HH:MM, HHMMSS, HHMM."
 208   (let ((time (or time ""))
 209         (hour nil)
 210         (minute nil)
 211         (second nil))
 212     (cond ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 213            ;; HH:MM:SS
 214            (setq hour 1 minute 2 second 3))
 215           ((string-match "\\`\\([0-9]+\\):\\([0-9]+\\)\\'" time)
 216            ;; HH:MM
 217            (setq hour 1 minute 2 second nil))
 218           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 219            ;; HHMMSS
 220            (setq hour 1 minute 2 second 3))
 221           ((string-match "\\`\\([0-9][0-9]\\)\\([0-9][0-9]\\)\\'" time)
 222            ;; HHMM
 223            (setq hour 1 minute 2 second nil))
 224           )
 225     ;; Return [hour minute second]
 226     (vector
 227      (if hour
 228          (substring time (match-beginning hour) (match-end hour)) "0")
 229      (if minute
 230          (substring time (match-beginning minute) (match-end minute)) "0")
 231      (if second
 232          (substring time (match-beginning second) (match-end second)) "0"))
 233     ))
 234
 235 \f
 236 ;; Miscellaneous
 237
 238 (defun timezone-zone-to-minute (timezone)
 239   "Translate TIMEZONE to an integer minute offset from GMT.
 240 TIMEZONE can be a cons cell containing the output of current-time-zone,
 241 or an integer of the form +-HHMM, or a time zone name."
 242   (cond
 243      ((consp timezone)
 244       (/ (car timezone) 60))
 245      (timezone
 246       (progn
 247         (setq timezone
 248               (or (cdr (assoc (upcase timezone) timezone-world-timezones))
 249                   ;; +900
 250                   timezone))
 251         (if (stringp timezone)
 252             (setq timezone (string-to-int timezone)))
 253         ;; Taking account of minute in timezone.
 254         ;; HHMM -> MM
 255         (let* ((abszone (abs timezone))
 256                (minutes (+ (* 60 (/ abszone 100)) (% abszone 100))))
 257           (if (< timezone 0) (- minutes) minutes))))
 258      (t 0)))
 259
 260 (defun timezone-time-from-absolute (date seconds)
 261   "Compute the UTC time equivalent to DATE at time SECONDS after midnight.
 262 Return a list suitable as an argument to current-time-zone,
 263 or nil if the date cannot be thus represented.
 264 DATE is the number of days elapsed since the (imaginary)
 265 Gregorian date Sunday, December 31, 1 BC."
 266   (let* ((current-time-origin 719162)
 267             ;; (timezone-absolute-from-gregorian 1 1 1970)
 268          (days (- date current-time-origin))
 269          (seconds-per-day (float 86400))
 270          (seconds (+ seconds (* days seconds-per-day)))
 271          (current-time-arithmetic-base (float 65536))
 272          (hi (floor (/ seconds current-time-arithmetic-base)))
 273          (hibase (* hi current-time-arithmetic-base))
 274          (lo (floor (- seconds hibase))))
 275      (and (< (abs (- seconds (+ hibase lo))) 2) ;; Check for integer overflow.
 276           (cons hi lo))))
 277
 278 (defun timezone-time-zone-from-absolute (date seconds)
 279   "Compute the local time zone for DATE at time SECONDS after midnight.
 280 Return a list in the same format as current-time-zone's result,
 281 or nil if the local time zone could not be computed.
 282 DATE is the number of days elapsed since the (imaginary)
 283 Gregorian date Sunday, December 31, 1 BC."
 284    (and (fboundp 'current-time-zone)
 285         (let ((utc-time (timezone-time-from-absolute date seconds)))
 286           (and utc-time
 287                (let ((zone (current-time-zone utc-time)))
 288                  (and (car zone) zone))))))
 289
 290 (defun timezone-fix-time (date local timezone)
 291   "Convert DATE (default timezone LOCAL) to YYYY-MM-DD-HH-MM-SS-ZONE vector.
 292 If LOCAL is nil, it is assumed to be GMT.
 293 If TIMEZONE is nil, use the local time zone."
 294   (let* ((date   (timezone-parse-date date))
 295          (year   (string-to-int (aref date 0)))
 296          (year   (cond ((< year 50)
 297                         (+ year 2000))
 298                        ((< year 100)
 299                         (+ year 1900))
 300                        (t year)))
 301          (month  (string-to-int (aref date 1)))
 302          (day    (string-to-int (aref date 2)))
 303          (time   (timezone-parse-time (aref date 3)))
 304          (hour   (string-to-int (aref time 0)))
 305          (minute (string-to-int (aref time 1)))
 306          (second (string-to-int (aref time 2)))
 307          (local  (or (aref date 4) local)) ;Use original if defined
 308          (timezone
 309           (or timezone
 310               (timezone-time-zone-from-absolute
 311                (timezone-absolute-from-gregorian month day year)
 312                (+ second (* 60 (+ minute (* 60 hour)))))))
 313          (diff   (- (timezone-zone-to-minute timezone)
 314                     (timezone-zone-to-minute local)))
 315          (minute (+ minute diff))
 316          (hour-fix (floor minute 60)))
 317     (setq hour (+ hour hour-fix))
 318     (setq minute (- minute (* 60 hour-fix)))
 319     ;; HOUR may be larger than 24 or smaller than 0.
 320     (cond ((<= 24 hour)                 ;24 -> 00
 321            (setq hour (- hour 24))
 322            (setq day  (1+ day))
 323            (if (< (timezone-last-day-of-month month year) day)
 324                (progn
 325                  (setq month (1+ month))
 326                  (setq day 1)
 327                  (if (< 12 month)
 328                      (progn
 329                        (setq month 1)
 330                        (setq year (1+ year))
 331                        ))
 332                  )))
 333           ((> 0 hour)
 334            (setq hour (+ hour 24))
 335            (setq day  (1- day))
 336            (if (> 1 day)
 337                (progn
 338                  (setq month (1- month))
 339                  (if (> 1 month)
 340                      (progn
 341                        (setq month 12)
 342                        (setq year (1- year))
 343                        ))
 344                  (setq day (timezone-last-day-of-month month year))
 345                  )))
 346           )
 347     (vector year month day hour minute second timezone)))
 348
 349 ;; Partly copied from Calendar program by Edward M. Reingold.
 350 ;; Thanks a lot.
 351
 352 (defun timezone-last-day-of-month (month year)
 353   "The last day in MONTH during YEAR."
 354   (if (and (= month 2) (timezone-leap-year-p year))
 355       29
 356     (aref [31 28 31 30 31 30 31 31 30 31 30 31] (1- month))))
 357
 358 (defun timezone-leap-year-p (year)
 359   "Returns t if YEAR is a Gregorian leap year."
 360   (or (and (zerop  (% year 4))
 361            (not (zerop (% year 100))))
 362       (zerop (% year 400))))
 363
 364 (defun timezone-day-number (month day year)
 365   "Return the day number within the year of the date month/day/year."
 366   (let ((day-of-year (+ day (* 31 (1- month)))))
 367     (if (> month 2)
 368         (progn
 369           (setq day-of-year (- day-of-year (/ (+ 23 (* 4 month)) 10)))
 370           (if (timezone-leap-year-p year)
 371               (setq day-of-year (1+ day-of-year)))))
 372     day-of-year))
 373
 374 (defun timezone-absolute-from-gregorian (month day year)
 375   "The number of days between the Gregorian date 12/31/1 BC and month/day/year.
 376 The Gregorian date Sunday, December 31, 1 BC is imaginary."
 377   (+ (timezone-day-number month day year);; Days this year
 378      (* 365 (1- year));;        + Days in prior years
 379      (/ (1- year) 4);;          + Julian leap years
 380      (- (/ (1- year) 100));;    - century years
 381      (/ (1- year) 400)));;      + Gregorian leap years
 382
 383 ;;; timezone.el ends here