lisp/progmodes/elisp-mode.el

   1 ;;; elisp-mode.el --- Emacs Lisp mode  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1999-2015 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Keywords: lisp, languages
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; The major mode for editing Emacs Lisp code.
  27 ;; This mode is documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (require 'lisp-mode)
  32
  33 (define-abbrev-table 'emacs-lisp-mode-abbrev-table ()
  34   "Abbrev table for Emacs Lisp mode.
  35 It has `lisp-mode-abbrev-table' as its parent."
  36   :parents (list lisp-mode-abbrev-table))
  37
  38 (defvar emacs-lisp-mode-syntax-table
  39   (let ((table (make-syntax-table lisp--mode-syntax-table)))
  40     (modify-syntax-entry ?\[ "(]  " table)
  41     (modify-syntax-entry ?\] ")[  " table)
  42     table)
  43   "Syntax table used in `emacs-lisp-mode'.")
  44
  45 (defvar emacs-lisp-mode-map
  46   (let ((map (make-sparse-keymap "Emacs-Lisp"))
  47         (menu-map (make-sparse-keymap "Emacs-Lisp"))
  48         (lint-map (make-sparse-keymap))
  49         (prof-map (make-sparse-keymap))
  50         (tracing-map (make-sparse-keymap)))
  51     (set-keymap-parent map lisp-mode-shared-map)
  52     (define-key map "\e\t" 'completion-at-point)
  53     (define-key map "\e\C-x" 'eval-defun)
  54     (define-key map "\e\C-q" 'indent-pp-sexp)
  55     (bindings--define-key map [menu-bar emacs-lisp]
  56       (cons "Emacs-Lisp" menu-map))
  57     (bindings--define-key menu-map [eldoc]
  58       '(menu-item "Auto-Display Documentation Strings" eldoc-mode
  59                   :button (:toggle . (bound-and-true-p eldoc-mode))
  60                   :help "Display the documentation string for the item under cursor"))
  61     (bindings--define-key menu-map [checkdoc]
  62       '(menu-item "Check Documentation Strings" checkdoc
  63                   :help "Check documentation strings for style requirements"))
  64     (bindings--define-key menu-map [re-builder]
  65       '(menu-item "Construct Regexp" re-builder
  66                   :help "Construct a regexp interactively"))
  67     (bindings--define-key menu-map [tracing] (cons "Tracing" tracing-map))
  68     (bindings--define-key tracing-map [tr-a]
  69       '(menu-item "Untrace All" untrace-all
  70                   :help "Untrace all currently traced functions"))
  71     (bindings--define-key tracing-map [tr-uf]
  72       '(menu-item "Untrace Function..." untrace-function
  73                   :help "Untrace function, and possibly activate all remaining advice"))
  74     (bindings--define-key tracing-map [tr-sep] menu-bar-separator)
  75     (bindings--define-key tracing-map [tr-q]
  76       '(menu-item "Trace Function Quietly..." trace-function-background
  77                   :help "Trace the function with trace output going quietly to a buffer"))
  78     (bindings--define-key tracing-map [tr-f]
  79       '(menu-item "Trace Function..." trace-function
  80                   :help "Trace the function given as an argument"))
  81     (bindings--define-key menu-map [profiling] (cons "Profiling" prof-map))
  82     (bindings--define-key prof-map [prof-restall]
  83       '(menu-item "Remove Instrumentation for All Functions" elp-restore-all
  84                   :help "Restore the original definitions of all functions being profiled"))
  85     (bindings--define-key prof-map [prof-restfunc]
  86       '(menu-item "Remove Instrumentation for Function..." elp-restore-function
  87                   :help "Restore an instrumented function to its original definition"))
  88
  89     (bindings--define-key prof-map [sep-rem] menu-bar-separator)
  90     (bindings--define-key prof-map [prof-resall]
  91       '(menu-item "Reset Counters for All Functions" elp-reset-all
  92                   :help "Reset the profiling information for all functions being profiled"))
  93     (bindings--define-key prof-map [prof-resfunc]
  94       '(menu-item "Reset Counters for Function..." elp-reset-function
  95                   :help "Reset the profiling information for a function"))
  96     (bindings--define-key prof-map [prof-res]
  97       '(menu-item "Show Profiling Results" elp-results
  98                   :help "Display current profiling results"))
  99     (bindings--define-key prof-map [prof-pack]
 100       '(menu-item "Instrument Package..." elp-instrument-package
 101                   :help "Instrument for profiling all function that start with a prefix"))
 102     (bindings--define-key prof-map [prof-func]
 103       '(menu-item "Instrument Function..." elp-instrument-function
 104                   :help "Instrument a function for profiling"))
 105     ;; Maybe this should be in a separate submenu from the ELP stuff?
 106     (bindings--define-key prof-map [sep-natprof] menu-bar-separator)
 107     (bindings--define-key prof-map [prof-natprof-stop]
 108       '(menu-item "Stop Native Profiler" profiler-stop
 109                   :help "Stop recording profiling information"
 110                   :enable (and (featurep 'profiler)
 111                                (profiler-running-p))))
 112     (bindings--define-key prof-map [prof-natprof-report]
 113       '(menu-item "Show Profiler Report" profiler-report
 114                   :help "Show the current profiler report"
 115                   :enable (and (featurep 'profiler)
 116                                (profiler-running-p))))
 117     (bindings--define-key prof-map [prof-natprof-start]
 118       '(menu-item "Start Native Profiler..." profiler-start
 119                   :help "Start recording profiling information"))
 120
 121     (bindings--define-key menu-map [lint] (cons "Linting" lint-map))
 122     (bindings--define-key lint-map [lint-di]
 123       '(menu-item "Lint Directory..." elint-directory
 124                   :help "Lint a directory"))
 125     (bindings--define-key lint-map [lint-f]
 126       '(menu-item "Lint File..." elint-file
 127                   :help "Lint a file"))
 128     (bindings--define-key lint-map [lint-b]
 129       '(menu-item "Lint Buffer" elint-current-buffer
 130                   :help "Lint the current buffer"))
 131     (bindings--define-key lint-map [lint-d]
 132       '(menu-item "Lint Defun" elint-defun
 133                   :help "Lint the function at point"))
 134     (bindings--define-key menu-map [edebug-defun]
 135       '(menu-item "Instrument Function for Debugging" edebug-defun
 136                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 137                   :keys "C-u C-M-x"))
 138     (bindings--define-key menu-map [separator-byte] menu-bar-separator)
 139     (bindings--define-key menu-map [disas]
 140       '(menu-item "Disassemble Byte Compiled Object..." disassemble
 141                   :help "Print disassembled code for OBJECT in a buffer"))
 142     (bindings--define-key menu-map [byte-recompile]
 143       '(menu-item "Byte-recompile Directory..." byte-recompile-directory
 144                   :help "Recompile every `.el' file in DIRECTORY that needs recompilation"))
 145     (bindings--define-key menu-map [emacs-byte-compile-and-load]
 146       '(menu-item "Byte-compile and Load" emacs-lisp-byte-compile-and-load
 147                   :help "Byte-compile the current file (if it has changed), then load compiled code"))
 148     (bindings--define-key menu-map [byte-compile]
 149       '(menu-item "Byte-compile This File" emacs-lisp-byte-compile
 150                   :help "Byte compile the file containing the current buffer"))
 151     (bindings--define-key menu-map [separator-eval] menu-bar-separator)
 152     (bindings--define-key menu-map [ielm]
 153       '(menu-item "Interactive Expression Evaluation" ielm
 154                   :help "Interactively evaluate Emacs Lisp expressions"))
 155     (bindings--define-key menu-map [eval-buffer]
 156       '(menu-item "Evaluate Buffer" eval-buffer
 157                   :help "Execute the current buffer as Lisp code"))
 158     (bindings--define-key menu-map [eval-region]
 159       '(menu-item "Evaluate Region" eval-region
 160                   :help "Execute the region as Lisp code"
 161                   :enable mark-active))
 162     (bindings--define-key menu-map [eval-sexp]
 163       '(menu-item "Evaluate Last S-expression" eval-last-sexp
 164                   :help "Evaluate sexp before point; print value in echo area"))
 165     (bindings--define-key menu-map [separator-format] menu-bar-separator)
 166     (bindings--define-key menu-map [comment-region]
 167       '(menu-item "Comment Out Region" comment-region
 168                   :help "Comment or uncomment each line in the region"
 169                   :enable mark-active))
 170     (bindings--define-key menu-map [indent-region]
 171       '(menu-item "Indent Region" indent-region
 172                   :help "Indent each nonblank line in the region"
 173                   :enable mark-active))
 174     (bindings--define-key menu-map [indent-line]
 175       '(menu-item "Indent Line" lisp-indent-line))
 176     map)
 177   "Keymap for Emacs Lisp mode.
 178 All commands in `lisp-mode-shared-map' are inherited by this map.")
 179
 180 (defun emacs-lisp-byte-compile ()
 181   "Byte compile the file containing the current buffer."
 182   (interactive)
 183   (if buffer-file-name
 184       (byte-compile-file buffer-file-name)
 185     (error "The buffer must be saved in a file first")))
 186
 187 (defun emacs-lisp-byte-compile-and-load ()
 188   "Byte-compile the current file (if it has changed), then load compiled code."
 189   (interactive)
 190   (or buffer-file-name
 191       (error "The buffer must be saved in a file first"))
 192   (require 'bytecomp)
 193   ;; Recompile if file or buffer has changed since last compilation.
 194   (if (and (buffer-modified-p)
 195            (y-or-n-p (format "Save buffer %s first? " (buffer-name))))
 196       (save-buffer))
 197   (byte-recompile-file buffer-file-name nil 0 t))
 198
 199 (defun emacs-lisp-macroexpand ()
 200   "Macroexpand the form after point.
 201 Comments in the form will be lost."
 202   (interactive)
 203   (let* ((start (point))
 204          (exp (read (current-buffer)))
 205          ;; Compute it before, since it may signal errors.
 206          (new (macroexpand-1 exp)))
 207     (if (equal exp new)
 208         (message "Not a macro call, nothing to expand")
 209       (delete-region start (point))
 210       (pp new (current-buffer))
 211       (if (bolp) (delete-char -1))
 212       (indent-region start (point)))))
 213
 214 (defcustom emacs-lisp-mode-hook nil
 215   "Hook run when entering Emacs Lisp mode."
 216   :options '(eldoc-mode imenu-add-menubar-index checkdoc-minor-mode)
 217   :type 'hook
 218   :group 'lisp)
 219
 220 ;;;###autoload
 221 (define-derived-mode emacs-lisp-mode prog-mode "Emacs-Lisp"
 222   "Major mode for editing Lisp code to run in Emacs.
 223 Commands:
 224 Delete converts tabs to spaces as it moves back.
 225 Blank lines separate paragraphs.  Semicolons start comments.
 226
 227 \\{emacs-lisp-mode-map}"
 228   :group 'lisp
 229   (defvar xref-find-function)
 230   (defvar xref-identifier-completion-table-function)
 231   (lisp-mode-variables nil nil 'elisp)
 232   (add-hook 'after-load-functions #'elisp--font-lock-flush-elisp-buffers)
 233   (setq-local electric-pair-text-pairs
 234               (cons '(?\` . ?\') electric-pair-text-pairs))
 235   (setq imenu-case-fold-search nil)
 236   (add-function :before-until (local 'eldoc-documentation-function)
 237                 #'elisp-eldoc-documentation-function)
 238   (setq-local xref-find-function #'elisp-xref-find)
 239   (setq-local xref-identifier-completion-table-function
 240               #'elisp--xref-identifier-completion-table)
 241   (add-hook 'completion-at-point-functions
 242             #'elisp-completion-at-point nil 'local))
 243
 244 ;; Font-locking support.
 245
 246 (defun elisp--font-lock-flush-elisp-buffers (&optional file)
 247   ;; FIXME: Aren't we only ever called from after-load-functions?
 248   ;; Don't flush during load unless called from after-load-functions.
 249   ;; In that case, FILE is non-nil.  It's somehow strange that
 250   ;; load-in-progress is t when an after-load-function is called since
 251   ;; that should run *after* the load...
 252   (when (or (not load-in-progress) file)
 253     ;; FIXME: If the loaded file did not define any macros, there shouldn't
 254     ;; be any need to font-lock-flush all the Elisp buffers.
 255     (dolist (buf (buffer-list))
 256       (with-current-buffer buf
 257         (when (derived-mode-p 'emacs-lisp-mode)
 258           ;; So as to take into account new macros that may have been defined
 259           ;; by the just-loaded file.
 260           (font-lock-flush))))))
 261
 262 ;;; Completion at point for Elisp
 263
 264 (defun elisp--local-variables-1 (vars sexp)
 265   "Return the vars locally bound around the witness, or nil if not found."
 266   (let (res)
 267     (while
 268         (unless
 269             (setq res
 270                   (pcase sexp
 271                     (`(,(or `let `let*) ,bindings)
 272                      (let ((vars vars))
 273                        (when (eq 'let* (car sexp))
 274                          (dolist (binding (cdr (reverse bindings)))
 275                            (push (or (car-safe binding) binding) vars)))
 276                        (elisp--local-variables-1
 277                         vars (car (cdr-safe (car (last bindings)))))))
 278                     (`(,(or `let `let*) ,bindings . ,body)
 279                      (let ((vars vars))
 280                        (dolist (binding bindings)
 281                          (push (or (car-safe binding) binding) vars))
 282                        (elisp--local-variables-1 vars (car (last body)))))
 283                     (`(lambda ,_args)
 284                      ;; FIXME: Look for the witness inside `args'.
 285                      (setq sexp nil))
 286                     (`(lambda ,args . ,body)
 287                      (elisp--local-variables-1
 288                       (append (remq '&optional (remq '&rest args)) vars)
 289                       (car (last body))))
 290                     (`(condition-case ,_ ,e) (elisp--local-variables-1 vars e))
 291                     (`(condition-case ,v ,_ . ,catches)
 292                      (elisp--local-variables-1
 293                       (cons v vars) (cdr (car (last catches)))))
 294                     (`(quote . ,_)
 295                      ;; FIXME: Look for the witness inside sexp.
 296                      (setq sexp nil))
 297                     ;; FIXME: Handle `cond'.
 298                     (`(,_ . ,_)
 299                      (elisp--local-variables-1 vars (car (last sexp))))
 300                     (`elisp--witness--lisp (or vars '(nil)))
 301                     (_ nil)))
 302           ;; We didn't find the witness in the last element so we try to
 303           ;; backtrack to the last-but-one.
 304           (setq sexp (ignore-errors (butlast sexp)))))
 305     res))
 306
 307 (defun elisp--local-variables ()
 308   "Return a list of locally let-bound variables at point."
 309   (save-excursion
 310     (skip-syntax-backward "w_")
 311     (let* ((ppss (syntax-ppss))
 312            (txt (buffer-substring-no-properties (or (car (nth 9 ppss)) (point))
 313                                                 (or (nth 8 ppss) (point))))
 314            (closer ()))
 315       (dolist (p (nth 9 ppss))
 316         (push (cdr (syntax-after p)) closer))
 317       (setq closer (apply #'string closer))
 318       (let* ((sexp (condition-case nil
 319                        (car (read-from-string
 320                              (concat txt "elisp--witness--lisp" closer)))
 321                      ((invalid-read-syntax end-of-file) nil)))
 322              (macroexpand-advice (lambda (expander form &rest args)
 323                                    (condition-case nil
 324                                        (apply expander form args)
 325                                      (error form))))
 326              (sexp
 327               (unwind-protect
 328                   (progn
 329                     (advice-add 'macroexpand :around macroexpand-advice)
 330                     (macroexpand-all sexp))
 331                 (advice-remove 'macroexpand macroexpand-advice)))
 332              (vars (elisp--local-variables-1 nil sexp)))
 333         (delq nil
 334               (mapcar (lambda (var)
 335                         (and (symbolp var)
 336                              (not (string-match (symbol-name var) "\\`[&_]"))
 337                              ;; Eliminate uninterned vars.
 338                              (intern-soft var)
 339                              var))
 340                       vars))))))
 341
 342 (defvar elisp--local-variables-completion-table
 343   ;; Use `defvar' rather than `defconst' since defconst would purecopy this
 344   ;; value, which would doubly fail: it would fail because purecopy can't
 345   ;; handle the recursive bytecode object, and it would fail because it would
 346   ;; move `lastpos' and `lastvars' to pure space where they'd be immutable!
 347   (let ((lastpos nil) (lastvars nil))
 348     (letrec ((hookfun (lambda ()
 349                         (setq lastpos nil)
 350                         (remove-hook 'post-command-hook hookfun))))
 351       (completion-table-dynamic
 352        (lambda (_string)
 353          (save-excursion
 354            (skip-syntax-backward "_w")
 355            (let ((newpos (cons (point) (current-buffer))))
 356              (unless (equal lastpos newpos)
 357                (add-hook 'post-command-hook hookfun)
 358                (setq lastpos newpos)
 359                (setq lastvars
 360                      (mapcar #'symbol-name (elisp--local-variables))))))
 361          lastvars)))))
 362
 363 (defun elisp--expect-function-p (pos)
 364   "Return non-nil if the symbol at point is expected to be a function."
 365   (or
 366    (and (eq (char-before pos) ?')
 367         (eq (char-before (1- pos)) ?#))
 368    (save-excursion
 369      (let ((parent (nth 1 (syntax-ppss pos))))
 370        (when parent
 371          (goto-char parent)
 372          (and
 373           (looking-at (concat "(\\(cl-\\)?"
 374                               (regexp-opt '("declare-function"
 375                                             "function" "defadvice"
 376                                             "callf" "callf2"
 377                                             "defsetf"))
 378                               "[ \t\r\n]+"))
 379           (eq (match-end 0) pos)))))))
 380
 381 (defun elisp--form-quoted-p (pos)
 382   "Return non-nil if the form at POS is not evaluated.
 383 It can be quoted, or be inside a quoted form."
 384   ;; FIXME: Do some macro expansion maybe.
 385   (save-excursion
 386     (let ((state (syntax-ppss pos)))
 387       (or (nth 8 state)   ; Code inside strings usually isn't evaluated.
 388           ;; FIXME: The 9th element is undocumented.
 389           (let ((nesting (cons (point) (reverse (nth 9 state))))
 390                 res)
 391             (while (and nesting (not res))
 392               (goto-char (pop nesting))
 393               (cond
 394                ((or (eq (char-after) ?\[)
 395                     (progn
 396                       (skip-chars-backward " ")
 397                       (memq (char-before) '(?' ?`))))
 398                 (setq res t))
 399                ((eq (char-before) ?,)
 400                 (setq nesting nil))))
 401             res)))))
 402
 403 ;; FIXME: Support for Company brings in features which straddle eldoc.
 404 ;; We should consolidate this, so that major modes can provide all that
 405 ;; data all at once:
 406 ;; - a function to extract "the reference at point" (may be more complex
 407 ;;     than a mere string, to distinguish various namespaces).
 408 ;; - a function to jump to such a reference.
 409 ;; - a function to show the signature/interface of such a reference.
 410 ;; - a function to build a help-buffer about that reference.
 411 ;; FIXME: Those functions should also be used by the normal completion code in
 412 ;; the *Completions* buffer.
 413
 414 (defun elisp--company-doc-buffer (str)
 415   (let ((symbol (intern-soft str)))
 416     ;; FIXME: we really don't want to "display-buffer and then undo it".
 417     (save-window-excursion
 418       ;; Make sure we don't display it in another frame, otherwise
 419       ;; save-window-excursion won't be able to undo it.
 420       (let ((display-buffer-overriding-action
 421              '(nil . ((inhibit-switch-frame . t)))))
 422         (ignore-errors
 423           (cond
 424            ((fboundp symbol) (describe-function symbol))
 425            ((boundp symbol) (describe-variable symbol))
 426            ((featurep symbol) (describe-package symbol))
 427            ((facep symbol) (describe-face symbol))
 428            (t (signal 'user-error nil)))
 429           (help-buffer))))))
 430
 431 (defun elisp--company-doc-string (str)
 432   (let* ((symbol (intern-soft str))
 433          (doc (if (fboundp symbol)
 434                   (documentation symbol t)
 435                 (documentation-property symbol 'variable-documentation t))))
 436     (and (stringp doc)
 437          (string-match ".*$" doc)
 438          (match-string 0 doc))))
 439
 440 (declare-function find-library-name "find-func" (library))
 441 (declare-function find-function-library "find-func" (function &optional l-o v))
 442
 443 (defun elisp--company-location (str)
 444   (let ((sym (intern-soft str)))
 445     (cond
 446      ((fboundp sym) (find-definition-noselect sym nil))
 447      ((boundp sym) (find-definition-noselect sym 'defvar))
 448      ((featurep sym)
 449       (require 'find-func)
 450       (cons (find-file-noselect (find-library-name
 451                                  (symbol-name sym)))
 452             0))
 453      ((facep sym) (find-definition-noselect sym 'defface)))))
 454
 455 (defun elisp-completion-at-point ()
 456   "Function used for `completion-at-point-functions' in `emacs-lisp-mode'."
 457   (with-syntax-table emacs-lisp-mode-syntax-table
 458     (let* ((pos (point))
 459            (beg (condition-case nil
 460                     (save-excursion
 461                       (backward-sexp 1)
 462                       (skip-syntax-forward "'")
 463                       (point))
 464                   (scan-error pos)))
 465            (end
 466             (unless (or (eq beg (point-max))
 467                         (member (char-syntax (char-after beg))
 468                                 '(?\s ?\" ?\( ?\))))
 469               (condition-case nil
 470                   (save-excursion
 471                     (goto-char beg)
 472                     (forward-sexp 1)
 473                     (skip-chars-backward "'")
 474                     (when (>= (point) pos)
 475                       (point)))
 476                 (scan-error pos))))
 477            ;; t if in function position.
 478            (funpos (eq (char-before beg) ?\())
 479            (quoted (elisp--form-quoted-p beg)))
 480       (when (and end (or (not (nth 8 (syntax-ppss)))
 481                          (eq (char-before beg) ?`)))
 482         (let ((table-etc
 483                (if (or (not funpos) quoted)
 484                    ;; FIXME: We could look at the first element of the list and
 485                    ;; use it to provide a more specific completion table in some
 486                    ;; cases.  E.g. filter out keywords that are not understood by
 487                    ;; the macro/function being called.
 488                    (cond
 489                     ((elisp--expect-function-p beg)
 490                      (list nil obarray
 491                            :predicate #'fboundp
 492                            :company-doc-buffer #'elisp--company-doc-buffer
 493                            :company-docsig #'elisp--company-doc-string
 494                            :company-location #'elisp--company-location))
 495                     (quoted
 496                      (list nil obarray
 497                            ;; Don't include all symbols (bug#16646).
 498                            :predicate (lambda (sym)
 499                                         (or (boundp sym)
 500                                             (fboundp sym)
 501                                             (featurep sym)
 502                                             (symbol-plist sym)))
 503                            :annotation-function
 504                            (lambda (str) (if (fboundp (intern-soft str)) " <f>"))
 505                            :company-doc-buffer #'elisp--company-doc-buffer
 506                            :company-docsig #'elisp--company-doc-string
 507                            :company-location #'elisp--company-location))
 508                     (t
 509                      (list nil (completion-table-merge
 510                                 elisp--local-variables-completion-table
 511                                 (apply-partially #'completion-table-with-predicate
 512                                                  obarray
 513                                                  #'boundp
 514                                                  'strict))
 515                            :company-doc-buffer #'elisp--company-doc-buffer
 516                            :company-docsig #'elisp--company-doc-string
 517                            :company-location #'elisp--company-location)))
 518                  ;; Looks like a funcall position.  Let's double check.
 519                  (save-excursion
 520                    (goto-char (1- beg))
 521                    (let ((parent
 522                           (condition-case nil
 523                               (progn (up-list -1) (forward-char 1)
 524                                      (let ((c (char-after)))
 525                                        (if (eq c ?\() ?\(
 526                                          (if (memq (char-syntax c) '(?w ?_))
 527                                              (read (current-buffer))))))
 528                             (error nil))))
 529                      (pcase parent
 530                        ;; FIXME: Rather than hardcode special cases here,
 531                        ;; we should use something like a symbol-property.
 532                        (`declare
 533                         (list t (mapcar (lambda (x) (symbol-name (car x)))
 534                                         (delete-dups
 535                                          ;; FIXME: We should include some
 536                                          ;; docstring with each entry.
 537                                          (append
 538                                           macro-declarations-alist
 539                                           defun-declarations-alist)))))
 540                        ((and (or `condition-case `condition-case-unless-debug)
 541                              (guard (save-excursion
 542                                       (ignore-errors
 543                                         (forward-sexp 2)
 544                                         (< (point) beg)))))
 545                         (list t obarray
 546                               :predicate (lambda (sym) (get sym 'error-conditions))))
 547                        ((and (or ?\( `let `let*)
 548                              (guard (save-excursion
 549                                       (goto-char (1- beg))
 550                                       (when (eq parent ?\()
 551                                         (up-list -1))
 552                                       (forward-symbol -1)
 553                                       (looking-at "\\_<let\\*?\\_>"))))
 554                         (list t obarray
 555                               :predicate #'boundp
 556                               :company-doc-buffer #'elisp--company-doc-buffer
 557                               :company-docsig #'elisp--company-doc-string
 558                               :company-location #'elisp--company-location))
 559                        (_ (list nil obarray
 560                                 :predicate #'fboundp
 561                                 :company-doc-buffer #'elisp--company-doc-buffer
 562                                 :company-docsig #'elisp--company-doc-string
 563                                 :company-location #'elisp--company-location
 564                                 ))))))))
 565           (nconc (list beg end)
 566                  (if (null (car table-etc))
 567                      (cdr table-etc)
 568                    (cons
 569                     (if (memq (char-syntax (or (char-after end) ?\s))
 570                               '(?\s ?>))
 571                         (cadr table-etc)
 572                       (apply-partially 'completion-table-with-terminator
 573                                        " " (cadr table-etc)))
 574                     (cddr table-etc)))))))))
 575
 576 (define-obsolete-function-alias
 577   'lisp-completion-at-point 'elisp-completion-at-point "25.1")
 578
 579 ;;; Xref backend
 580
 581 (declare-function xref-make-elisp-location "xref" (symbol type file))
 582 (declare-function xref-make-bogus-location "xref" (message))
 583 (declare-function xref-make "xref" (description location))
 584 (declare-function xref-collect-references "xref" (name dir))
 585
 586 (defun elisp-xref-find (action id)
 587   (require 'find-func)
 588   (pcase action
 589     (`definitions
 590       (let ((sym (intern-soft id)))
 591         (when sym
 592           (elisp--xref-find-definitions sym))))
 593     (`references
 594      (elisp--xref-find-references id))
 595     (`apropos
 596      (elisp--xref-find-apropos id))))
 597
 598 (defun elisp--xref-identifier-location (type sym)
 599   (let ((file
 600          (pcase type
 601            (`defun (when (fboundp sym)
 602                      (let ((fun-lib
 603                             (find-function-library sym)))
 604                        (setq sym (car fun-lib))
 605                        (cdr fun-lib))))
 606            (`defvar (and (boundp sym)
 607                          ;; Don't show minor modes twice.
 608                          ;; TODO: If TYPE ever becomes dependent on the
 609                          ;; context, move this check outside.
 610                          (not (fboundp sym))
 611                          (or (symbol-file sym 'defvar)
 612                              (help-C-file-name sym 'var))))
 613            (`feature (and (featurep sym)
 614                           ;; Skip when a function with the same name
 615                           ;; is defined, because it's probably in the
 616                           ;; same file.
 617                           (not (fboundp sym))
 618                           (ignore-errors
 619                             (find-library-name (symbol-name sym)))))
 620            (`defface (when (facep sym)
 621                        (symbol-file sym 'defface))))))
 622     (when file
 623       (when (string-match-p "\\.elc\\'" file)
 624         (setq file (substring file 0 -1)))
 625       (xref-make-elisp-location sym type file))))
 626
 627 (defun elisp--xref-find-definitions (symbol)
 628   (save-excursion
 629     (let ((fmt "(%s %s)")
 630           lst)
 631       (put-text-property 1 3 'face 'font-lock-keyword-face fmt)
 632       (put-text-property 4 6 'face 'font-lock-function-name-face fmt)
 633       (dolist (type '(feature defface defvar defun))
 634         (let ((loc
 635                (condition-case err
 636                    (elisp--xref-identifier-location type symbol)
 637                  (error
 638                   (xref-make-bogus-location (error-message-string err))))))
 639           (when loc
 640             (push
 641              (xref-make (format fmt type symbol)
 642                         loc)
 643              lst))))
 644       lst)))
 645
 646 (defun elisp--xref-find-references (symbol)
 647   (let* ((dirs (sort
 648                 (mapcar
 649                  (lambda (dir)
 650                    (file-name-as-directory (expand-file-name dir)))
 651                  (cons package-user-dir load-path))
 652                 #'string<))
 653          (ref dirs))
 654     ;; Delete subdirectories from the list.
 655     (while (cdr ref)
 656       (if (string-prefix-p (car ref) (cadr ref))
 657           (setcdr ref (cddr ref))
 658         (setq ref (cdr ref))))
 659     (cl-mapcan
 660      (lambda (dir)
 661        (and (file-exists-p dir)
 662             (xref-collect-references symbol dir)))
 663      dirs)))
 664
 665 (defun elisp--xref-find-apropos (regexp)
 666   (apply #'nconc
 667          (let (lst)
 668            (dolist (sym (apropos-internal regexp))
 669             (push (elisp--xref-find-definitions sym) lst))
 670            (nreverse lst))))
 671
 672 (defvar elisp--xref-identifier-completion-table
 673   (apply-partially #'completion-table-with-predicate
 674                    obarray
 675                    (lambda (sym)
 676                      (or (boundp sym)
 677                          (fboundp sym)
 678                          (featurep sym)
 679                          (facep sym)))
 680                    'strict))
 681
 682 (defun elisp--xref-identifier-completion-table ()
 683   elisp--xref-identifier-completion-table)
 684
 685 ;;; Elisp Interaction mode
 686
 687 (defvar lisp-interaction-mode-map
 688   (let ((map (make-sparse-keymap))
 689         (menu-map (make-sparse-keymap "Lisp-Interaction")))
 690     (set-keymap-parent map lisp-mode-shared-map)
 691     (define-key map "\e\C-x" 'eval-defun)
 692     (define-key map "\e\C-q" 'indent-pp-sexp)
 693     (define-key map "\e\t" 'completion-at-point)
 694     (define-key map "\n" 'eval-print-last-sexp)
 695     (bindings--define-key map [menu-bar lisp-interaction]
 696       (cons "Lisp-Interaction" menu-map))
 697     (bindings--define-key menu-map [eval-defun]
 698       '(menu-item "Evaluate Defun" eval-defun
 699                   :help "Evaluate the top-level form containing point, or after point"))
 700     (bindings--define-key menu-map [eval-print-last-sexp]
 701       '(menu-item "Evaluate and Print" eval-print-last-sexp
 702                   :help "Evaluate sexp before point; print value into current buffer"))
 703     (bindings--define-key menu-map [edebug-defun-lisp-interaction]
 704       '(menu-item "Instrument Function for Debugging" edebug-defun
 705                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 706                   :keys "C-u C-M-x"))
 707     (bindings--define-key menu-map [indent-pp-sexp]
 708       '(menu-item "Indent or Pretty-Print" indent-pp-sexp
 709                   :help "Indent each line of the list starting just after point, or prettyprint it"))
 710     (bindings--define-key menu-map [complete-symbol]
 711       '(menu-item "Complete Lisp Symbol" completion-at-point
 712                   :help "Perform completion on Lisp symbol preceding point"))
 713     map)
 714   "Keymap for Lisp Interaction mode.
 715 All commands in `lisp-mode-shared-map' are inherited by this map.")
 716
 717 (define-derived-mode lisp-interaction-mode emacs-lisp-mode "Lisp Interaction"
 718   "Major mode for typing and evaluating Lisp forms.
 719 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 720 before point, and prints its value into the buffer, advancing point.
 721 Note that printing is controlled by `eval-expression-print-length'
 722 and `eval-expression-print-level'.
 723
 724 Commands:
 725 Delete converts tabs to spaces as it moves back.
 726 Paragraphs are separated only by blank lines.
 727 Semicolons start comments.
 728
 729 \\{lisp-interaction-mode-map}"
 730   :abbrev-table nil)
 731
 732 ;;; Emacs Lisp Byte-Code mode
 733
 734 (eval-and-compile
 735   (defconst emacs-list-byte-code-comment-re
 736     (concat "\\(#\\)@\\([0-9]+\\) "
 737             ;; Make sure it's a docstring and not a lazy-loaded byte-code.
 738             "\\(?:[^(]\\|([^\"]\\)")))
 739
 740 (defun elisp--byte-code-comment (end &optional _point)
 741   "Try to syntactically mark the #@NNN ....^_ docstrings in byte-code files."
 742   (let ((ppss (syntax-ppss)))
 743     (when (and (nth 4 ppss)
 744                (eq (char-after (nth 8 ppss)) ?#))
 745       (let* ((n (save-excursion
 746                   (goto-char (nth 8 ppss))
 747                   (when (looking-at emacs-list-byte-code-comment-re)
 748                     (string-to-number (match-string 2)))))
 749              ;; `maxdiff' tries to make sure the loop below terminates.
 750              (maxdiff n))
 751         (when n
 752           (let* ((bchar (match-end 2))
 753                  (b (position-bytes bchar)))
 754             (goto-char (+ b n))
 755             (while (let ((diff (- (position-bytes (point)) b n)))
 756                      (unless (zerop diff)
 757                        (when (> diff maxdiff) (setq diff maxdiff))
 758                        (forward-char (- diff))
 759                        (setq maxdiff (if (> diff 0) diff
 760                                        (max (1- maxdiff) 1)))
 761                        t))))
 762           (if (<= (point) end)
 763               (put-text-property (1- (point)) (point)
 764                                  'syntax-table
 765                                  (string-to-syntax "> b"))
 766             (goto-char end)))))))
 767
 768 (defun elisp-byte-code-syntax-propertize (start end)
 769   (elisp--byte-code-comment end (point))
 770   (funcall
 771    (syntax-propertize-rules
 772     (emacs-list-byte-code-comment-re
 773      (1 (prog1 "< b" (elisp--byte-code-comment end (point))))))
 774    start end))
 775
 776 ;;;###autoload
 777 (add-to-list 'auto-mode-alist '("\\.elc\\'" . elisp-byte-code-mode))
 778 ;;;###autoload
 779 (define-derived-mode elisp-byte-code-mode emacs-lisp-mode
 780   "Elisp-Byte-Code"
 781   "Major mode for *.elc files."
 782   ;; TODO: Add way to disassemble byte-code under point.
 783   (setq-local open-paren-in-column-0-is-defun-start nil)
 784   (setq-local syntax-propertize-function
 785               #'elisp-byte-code-syntax-propertize))
 786
 787
 788 ;;; Globally accessible functionality
 789
 790 (defun eval-print-last-sexp (&optional eval-last-sexp-arg-internal)
 791   "Evaluate sexp before point; print value into current buffer.
 792
 793 Normally, this function truncates long output according to the value
 794 of the variables `eval-expression-print-length' and
 795 `eval-expression-print-level'.  With a prefix argument of zero,
 796 however, there is no such truncation.  Such a prefix argument
 797 also causes integers to be printed in several additional formats
 798 \(octal, hexadecimal, and character).
 799
 800 If `eval-expression-debug-on-error' is non-nil, which is the default,
 801 this command arranges for all errors to enter the debugger."
 802   (interactive "P")
 803   (let ((standard-output (current-buffer)))
 804     (terpri)
 805     (eval-last-sexp (or eval-last-sexp-arg-internal t))
 806     (terpri)))
 807
 808
 809 (defun last-sexp-setup-props (beg end value alt1 alt2)
 810   "Set up text properties for the output of `elisp--eval-last-sexp'.
 811 BEG and END are the start and end of the output in current-buffer.
 812 VALUE is the Lisp value printed, ALT1 and ALT2 are strings for the
 813 alternative printed representations that can be displayed."
 814   (let ((map (make-sparse-keymap)))
 815     (define-key map "\C-m" 'elisp-last-sexp-toggle-display)
 816     (define-key map [down-mouse-2] 'mouse-set-point)
 817     (define-key map [mouse-2] 'elisp-last-sexp-toggle-display)
 818     (add-text-properties
 819      beg end
 820      `(printed-value (,value ,alt1 ,alt2)
 821                      mouse-face highlight
 822                      keymap ,map
 823                      help-echo "RET, mouse-2: toggle abbreviated display"
 824                      rear-nonsticky (mouse-face keymap help-echo
 825                                                 printed-value)))))
 826
 827
 828 (defun elisp-last-sexp-toggle-display (&optional _arg)
 829   "Toggle between abbreviated and unabbreviated printed representations."
 830   (interactive "P")
 831   (save-restriction
 832     (widen)
 833     (let ((value (get-text-property (point) 'printed-value)))
 834       (when value
 835         (let ((beg (or (previous-single-property-change (min (point-max) (1+ (point)))
 836                                                         'printed-value)
 837                        (point)))
 838               (end (or (next-single-char-property-change (point) 'printed-value) (point)))
 839               (standard-output (current-buffer))
 840               (point (point)))
 841           (delete-region beg end)
 842           (insert (nth 1 value))
 843           (or (= beg point)
 844               (setq point (1- (point))))
 845           (last-sexp-setup-props beg (point)
 846                                  (nth 0 value)
 847                                  (nth 2 value)
 848                                  (nth 1 value))
 849           (goto-char (min (point-max) point)))))))
 850
 851 (defun prin1-char (char)                ;FIXME: Move it, e.g. to simple.el.
 852   "Return a string representing CHAR as a character rather than as an integer.
 853 If CHAR is not a character, return nil."
 854   (and (integerp char)
 855        (eventp char)
 856        (let ((c (event-basic-type char))
 857              (mods (event-modifiers char))
 858              string)
 859          ;; Prevent ?A from turning into ?\S-a.
 860          (if (and (memq 'shift mods)
 861                   (zerop (logand char ?\S-\^@))
 862                   (not (let ((case-fold-search nil))
 863                          (char-equal c (upcase c)))))
 864              (setq c (upcase c) mods nil))
 865          ;; What string are we considering using?
 866          (condition-case nil
 867              (setq string
 868                    (concat
 869                     "?"
 870                     (mapconcat
 871                      (lambda (modif)
 872                        (cond ((eq modif 'super) "\\s-")
 873                              (t (string ?\\ (upcase (aref (symbol-name modif) 0)) ?-))))
 874                      mods "")
 875                     (cond
 876                      ((memq c '(?\; ?\( ?\) ?\{ ?\} ?\[ ?\] ?\" ?\' ?\\)) (string ?\\ c))
 877                      ((eq c 127) "\\C-?")
 878                      (t
 879                       (string c)))))
 880            (error nil))
 881          ;; Verify the string reads a CHAR, not to some other character.
 882          ;; If it doesn't, return nil instead.
 883          (and string
 884               (= (car (read-from-string string)) char)
 885               string))))
 886
 887 (defun elisp--preceding-sexp ()
 888   "Return sexp before the point."
 889   (let ((opoint (point))
 890         ignore-quotes
 891         expr)
 892     (save-excursion
 893       (with-syntax-table emacs-lisp-mode-syntax-table
 894         ;; If this sexp appears to be enclosed in `...'
 895         ;; then ignore the surrounding quotes.
 896         (setq ignore-quotes
 897               (or (eq (following-char) ?\')
 898                   (eq (preceding-char) ?\')))
 899         (forward-sexp -1)
 900         ;; If we were after `?\e' (or similar case),
 901         ;; use the whole thing, not just the `e'.
 902         (when (eq (preceding-char) ?\\)
 903           (forward-char -1)
 904           (when (eq (preceding-char) ??)
 905             (forward-char -1)))
 906
 907         ;; Skip over hash table read syntax.
 908         (and (> (point) (1+ (point-min)))
 909              (looking-back "#s" (- (point) 2))
 910              (forward-char -2))
 911
 912         ;; Skip over `#N='s.
 913         (when (eq (preceding-char) ?=)
 914           (let (labeled-p)
 915             (save-excursion
 916               (skip-chars-backward "0-9#=")
 917               (setq labeled-p (looking-at "\\(#[0-9]+=\\)+")))
 918             (when labeled-p
 919               (forward-sexp -1))))
 920
 921         (save-restriction
 922           (if (and ignore-quotes (eq (following-char) ?`))
 923               ;; vladimir@cs.ualberta.ca 30-Jul-1997: Skip ` in `variable' so
 924               ;; that the value is returned, not the name.
 925               (forward-char))
 926           (when (looking-at ",@?") (goto-char (match-end 0)))
 927           (narrow-to-region (point-min) opoint)
 928           (setq expr (read (current-buffer)))
 929           ;; If it's an (interactive ...) form, it's more useful to show how an
 930           ;; interactive call would use it.
 931           ;; FIXME: Is it really the right place for this?
 932           (when (eq (car-safe expr) 'interactive)
 933                (setq expr
 934                   `(call-interactively
 935                     (lambda (&rest args) ,expr args))))
 936           expr)))))
 937 (define-obsolete-function-alias 'preceding-sexp 'elisp--preceding-sexp "25.1")
 938
 939 (defun elisp--eval-last-sexp (eval-last-sexp-arg-internal)
 940   "Evaluate sexp before point; print value in the echo area.
 941 If EVAL-LAST-SEXP-ARG-INTERNAL is non-nil, print output into
 942 current buffer.  If EVAL-LAST-SEXP-ARG-INTERNAL is `0', print
 943 output with no limit on the length and level of lists, and
 944 include additional formats for integers \(octal, hexadecimal, and
 945 character)."
 946   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t)))
 947     ;; Setup the lexical environment if lexical-binding is enabled.
 948     (elisp--eval-last-sexp-print-value
 949      (eval (eval-sexp-add-defvars (elisp--preceding-sexp)) lexical-binding)
 950      eval-last-sexp-arg-internal)))
 951
 952
 953 (defun elisp--eval-last-sexp-print-value (value &optional eval-last-sexp-arg-internal)
 954   (let ((unabbreviated (let ((print-length nil) (print-level nil))
 955                          (prin1-to-string value)))
 956         (print-length (and (not (zerop (prefix-numeric-value
 957                                         eval-last-sexp-arg-internal)))
 958                            eval-expression-print-length))
 959         (print-level (and (not (zerop (prefix-numeric-value
 960                                        eval-last-sexp-arg-internal)))
 961                           eval-expression-print-level))
 962         (beg (point))
 963         end)
 964     (prog1
 965         (prin1 value)
 966       (let ((str (eval-expression-print-format value)))
 967         (if str (princ str)))
 968       (setq end (point))
 969       (when (and (bufferp standard-output)
 970                  (or (not (null print-length))
 971                      (not (null print-level)))
 972                  (not (string= unabbreviated
 973                                (buffer-substring-no-properties beg end))))
 974         (last-sexp-setup-props beg end value
 975                                unabbreviated
 976                                (buffer-substring-no-properties beg end))
 977         ))))
 978
 979
 980 (defvar elisp--eval-last-sexp-fake-value (make-symbol "t"))
 981
 982 (defun eval-sexp-add-defvars (exp &optional pos)
 983   "Prepend EXP with all the `defvar's that precede it in the buffer.
 984 POS specifies the starting position where EXP was found and defaults to point."
 985   (setq exp (macroexpand-all exp))      ;Eager macro-expansion.
 986   (if (not lexical-binding)
 987       exp
 988     (save-excursion
 989       (unless pos (setq pos (point)))
 990       (let ((vars ()))
 991         (goto-char (point-min))
 992         (while (re-search-forward
 993                 "(def\\(?:var\\|const\\|custom\\)[ \t\n]+\\([^; '()\n\t]+\\)"
 994                 pos t)
 995           (let ((var (intern (match-string 1))))
 996             (and (not (special-variable-p var))
 997                  (save-excursion
 998                    (zerop (car (syntax-ppss (match-beginning 0)))))
 999               (push var vars))))
1000         `(progn ,@(mapcar (lambda (v) `(defvar ,v)) vars) ,exp)))))
1001
1002 (defun eval-last-sexp (eval-last-sexp-arg-internal)
1003   "Evaluate sexp before point; print value in the echo area.
1004 Interactively, with prefix argument, print output into current buffer.
1005
1006 Normally, this function truncates long output according to the value
1007 of the variables `eval-expression-print-length' and
1008 `eval-expression-print-level'.  With a prefix argument of zero,
1009 however, there is no such truncation.  Such a prefix argument
1010 also causes integers to be printed in several additional formats
1011 \(octal, hexadecimal, and character).
1012
1013 If `eval-expression-debug-on-error' is non-nil, which is the default,
1014 this command arranges for all errors to enter the debugger."
1015   (interactive "P")
1016   (if (null eval-expression-debug-on-error)
1017       (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1018     (let ((value
1019            (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1020              (cons (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1021                    debug-on-error))))
1022       (unless (eq (cdr value) elisp--eval-last-sexp-fake-value)
1023         (setq debug-on-error (cdr value)))
1024       (car value))))
1025
1026 (defun elisp--eval-defun-1 (form)
1027   "Treat some expressions specially.
1028 Reset the `defvar' and `defcustom' variables to the initial value.
1029 \(For `defcustom', use the :set function if there is one.)
1030 Reinitialize the face according to the `defface' specification."
1031   ;; The code in edebug-defun should be consistent with this, but not
1032   ;; the same, since this gets a macroexpanded form.
1033   (cond ((not (listp form))
1034          form)
1035         ((and (eq (car form) 'defvar)
1036               (cdr-safe (cdr-safe form))
1037               (boundp (cadr form)))
1038          ;; Force variable to be re-set.
1039          `(progn (defvar ,(nth 1 form) nil ,@(nthcdr 3 form))
1040                  (setq-default ,(nth 1 form) ,(nth 2 form))))
1041         ;; `defcustom' is now macroexpanded to
1042         ;; `custom-declare-variable' with a quoted value arg.
1043         ((and (eq (car form) 'custom-declare-variable)
1044               (default-boundp (eval (nth 1 form) lexical-binding)))
1045          ;; Force variable to be bound, using :set function if specified.
1046          (let ((setfunc (memq :set form)))
1047            (when setfunc
1048              (setq setfunc (car-safe (cdr-safe setfunc)))
1049              (or (functionp setfunc) (setq setfunc nil)))
1050            (funcall (or setfunc 'set-default)
1051                     (eval (nth 1 form) lexical-binding)
1052                     ;; The second arg is an expression that evaluates to
1053                     ;; an expression.  The second evaluation is the one
1054                     ;; normally performed not by normal execution but by
1055                     ;; custom-initialize-set (for example), which does not
1056                     ;; use lexical-binding.
1057                     (eval (eval (nth 2 form) lexical-binding))))
1058          form)
1059         ;; `defface' is macroexpanded to `custom-declare-face'.
1060         ((eq (car form) 'custom-declare-face)
1061          ;; Reset the face.
1062          (let ((face-symbol (eval (nth 1 form) lexical-binding)))
1063            (setq face-new-frame-defaults
1064                  (assq-delete-all face-symbol face-new-frame-defaults))
1065            (put face-symbol 'face-defface-spec nil)
1066            (put face-symbol 'face-override-spec nil))
1067          form)
1068         ((eq (car form) 'progn)
1069          (cons 'progn (mapcar #'elisp--eval-defun-1 (cdr form))))
1070         (t form)))
1071
1072 (defun elisp--eval-defun ()
1073   "Evaluate defun that point is in or before.
1074 The value is displayed in the echo area.
1075 If the current defun is actually a call to `defvar',
1076 then reset the variable using the initial value expression
1077 even if the variable already has some other value.
1078 \(Normally `defvar' does not change the variable's value
1079 if it already has a value.\)
1080
1081 Return the result of evaluation."
1082   ;; FIXME: the print-length/level bindings should only be applied while
1083   ;; printing, not while evaluating.
1084   (let ((debug-on-error eval-expression-debug-on-error)
1085         (print-length eval-expression-print-length)
1086         (print-level eval-expression-print-level))
1087     (save-excursion
1088       ;; Arrange for eval-region to "read" the (possibly) altered form.
1089       ;; eval-region handles recording which file defines a function or
1090       ;; variable.
1091       (let ((standard-output t)
1092             beg end form)
1093         ;; Read the form from the buffer, and record where it ends.
1094         (save-excursion
1095           (end-of-defun)
1096           (beginning-of-defun)
1097           (setq beg (point))
1098           (setq form (read (current-buffer)))
1099           (setq end (point)))
1100         ;; Alter the form if necessary.
1101         (let ((form (eval-sexp-add-defvars
1102                      (elisp--eval-defun-1 (macroexpand form)))))
1103           (eval-region beg end standard-output
1104                        (lambda (_ignore)
1105                          ;; Skipping to the end of the specified region
1106                          ;; will make eval-region return.
1107                          (goto-char end)
1108                          form))))))
1109   (let ((str (eval-expression-print-format (car values))))
1110     (if str (princ str)))
1111   ;; The result of evaluation has been put onto VALUES.  So return it.
1112   (car values))
1113
1114 (defun eval-defun (edebug-it)
1115   "Evaluate the top-level form containing point, or after point.
1116
1117 If the current defun is actually a call to `defvar' or `defcustom',
1118 evaluating it this way resets the variable using its initial value
1119 expression (using the defcustom's :set function if there is one), even
1120 if the variable already has some other value.  \(Normally `defvar' and
1121 `defcustom' do not alter the value if there already is one.)  In an
1122 analogous way, evaluating a `defface' overrides any customizations of
1123 the face, so that it becomes defined exactly as the `defface' expression
1124 says.
1125
1126 If `eval-expression-debug-on-error' is non-nil, which is the default,
1127 this command arranges for all errors to enter the debugger.
1128
1129 With a prefix argument, instrument the code for Edebug.
1130
1131 If acting on a `defun' for FUNCTION, and the function was
1132 instrumented, `Edebug: FUNCTION' is printed in the echo area.  If not
1133 instrumented, just FUNCTION is printed.
1134
1135 If not acting on a `defun', the result of evaluation is displayed in
1136 the echo area.  This display is controlled by the variables
1137 `eval-expression-print-length' and `eval-expression-print-level',
1138 which see."
1139   (interactive "P")
1140   (cond (edebug-it
1141          (require 'edebug)
1142          (eval-defun (not edebug-all-defs)))
1143         (t
1144          (if (null eval-expression-debug-on-error)
1145              (elisp--eval-defun)
1146            (let (new-value value)
1147              (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1148                (setq value (elisp--eval-defun))
1149                (setq new-value debug-on-error))
1150              (unless (eq elisp--eval-last-sexp-fake-value new-value)
1151                (setq debug-on-error new-value))
1152              value)))))
1153
1154 ;;; ElDoc Support
1155
1156 (defvar elisp--eldoc-last-data (make-vector 3 nil)
1157   "Bookkeeping; elements are as follows:
1158   0 - contains the last symbol read from the buffer.
1159   1 - contains the string last displayed in the echo area for variables,
1160       or argument string for functions.
1161   2 - 'function if function args, 'variable if variable documentation.")
1162
1163 (defun elisp-eldoc-documentation-function ()
1164   "`eldoc-documentation-function' (which see) for Emacs Lisp."
1165   (let ((current-symbol (elisp--current-symbol))
1166         (current-fnsym  (elisp--fnsym-in-current-sexp)))
1167     (cond ((null current-fnsym)
1168            nil)
1169           ((eq current-symbol (car current-fnsym))
1170            (or (apply #'elisp--get-fnsym-args-string current-fnsym)
1171                (elisp--get-var-docstring current-symbol)))
1172           (t
1173            (or (elisp--get-var-docstring current-symbol)
1174                (apply #'elisp--get-fnsym-args-string current-fnsym))))))
1175
1176 (defun elisp--get-fnsym-args-string (sym &optional index)
1177   "Return a string containing the parameter list of the function SYM.
1178 If SYM is a subr and no arglist is obtainable from the docstring
1179 or elsewhere, return a 1-line docstring."
1180   (let ((argstring
1181          (cond
1182           ((not (and sym (symbolp sym) (fboundp sym))) nil)
1183           ((and (eq sym (aref elisp--eldoc-last-data 0))
1184                 (eq 'function (aref elisp--eldoc-last-data 2)))
1185            (aref elisp--eldoc-last-data 1))
1186           (t
1187            (let* ((advertised (gethash (indirect-function sym)
1188                                        advertised-signature-table t))
1189                   doc
1190                   (args
1191                    (cond
1192                     ((listp advertised) advertised)
1193                     ((setq doc (help-split-fundoc
1194                                 (condition-case nil (documentation sym t)
1195                                   (invalid-function nil))
1196                                 sym))
1197                      (car doc))
1198                     (t (help-function-arglist sym)))))
1199              ;; Stringify, and store before highlighting, downcasing, etc.
1200              ;; FIXME should truncate before storing.
1201              (elisp--last-data-store sym (elisp--function-argstring args)
1202                                     'function))))))
1203     ;; Highlight, truncate.
1204     (if argstring
1205         (elisp--highlight-function-argument sym argstring index))))
1206
1207 (defun elisp--highlight-function-argument (sym args index)
1208   "Highlight argument INDEX in ARGS list for function SYM.
1209 In the absence of INDEX, just call `elisp--docstring-format-sym-doc'."
1210   ;; FIXME: This should probably work on the list representation of `args'
1211   ;; rather than its string representation.
1212   ;; FIXME: This function is much too long, we need to split it up!
1213   (let ((start          nil)
1214         (end            0)
1215         (argument-face  'eldoc-highlight-function-argument)
1216         (args-lst (mapcar (lambda (x)
1217                             (replace-regexp-in-string
1218                              "\\`[(]\\|[)]\\'" "" x))
1219                           (split-string args))))
1220     ;; Find the current argument in the argument string.  We need to
1221     ;; handle `&rest' and informal `...' properly.
1222     ;;
1223     ;; FIXME: What to do with optional arguments, like in
1224     ;;        (defun NAME ARGLIST [DOCSTRING] BODY...) case?
1225     ;;        The problem is there is no robust way to determine if
1226     ;;        the current argument is indeed a docstring.
1227
1228     ;; When `&key' is used finding position based on `index'
1229     ;; would be wrong, so find the arg at point and determine
1230     ;; position in ARGS based on this current arg.
1231     (when (string-match "&key" args)
1232       (let* (case-fold-search
1233              key-have-value
1234              (sym-name (symbol-name sym))
1235              (cur-w (current-word))
1236              (args-lst-ak (cdr (member "&key" args-lst)))
1237              (limit (save-excursion
1238                       (when (re-search-backward sym-name nil t)
1239                         (match-end 0))))
1240              (cur-a (if (and cur-w (string-match ":\\([^ ()]*\\)" cur-w))
1241                         (substring cur-w 1)
1242                       (save-excursion
1243                         (let (split)
1244                           (when (re-search-backward ":\\([^()\n]*\\)" limit t)
1245                             (setq split (split-string (match-string 1) " " t))
1246                             (prog1 (car split)
1247                               (when (cdr split)
1248                                 (setq key-have-value t))))))))
1249              ;; If `cur-a' is not one of `args-lst-ak'
1250              ;; assume user is entering an unknown key
1251              ;; referenced in last position in signature.
1252              (other-key-arg (and (stringp cur-a)
1253                                  args-lst-ak
1254                                  (not (member (upcase cur-a) args-lst-ak))
1255                                  (upcase (car (last args-lst-ak))))))
1256         (unless (string= cur-w sym-name)
1257           ;; The last keyword have already a value
1258           ;; i.e :foo a b and cursor is at b.
1259           ;; If signature have also `&rest'
1260           ;; (assume it is after the `&key' section)
1261           ;; go to the arg after `&rest'.
1262           (if (and key-have-value
1263                    (save-excursion
1264                      (not (re-search-forward ":.*" (point-at-eol) t)))
1265                    (string-match "&rest \\([^ ()]*\\)" args))
1266               (setq index nil ; Skip next block based on positional args.
1267                     start (match-beginning 1)
1268                     end   (match-end 1))
1269             ;; If `cur-a' is nil probably cursor is on a positional arg
1270             ;; before `&key', in this case, exit this block and determine
1271             ;; position with `index'.
1272             (when (and cur-a     ; A keyword arg (dot removed) or nil.
1273                        (or (string-match
1274                             (concat "\\_<" (upcase cur-a) "\\_>") args)
1275                            (string-match
1276                             (concat "\\_<" other-key-arg "\\_>") args)))
1277               (setq index nil ; Skip next block based on positional args.
1278                     start (match-beginning 0)
1279                     end   (match-end 0)))))))
1280     ;; Handle now positional arguments.
1281     (while (and index (>= index 1))
1282       (if (string-match "[^ ()]+" args end)
1283           (progn
1284             (setq start (match-beginning 0)
1285                   end   (match-end 0))
1286             (let ((argument (match-string 0 args)))
1287               (cond ((string= argument "&rest")
1288                      ;; All the rest arguments are the same.
1289                      (setq index 1))
1290                     ((string= argument "&optional"))         ; Skip.
1291                     ((string= argument "&allow-other-keys")) ; Skip.
1292                     ;; Back to index 0 in ARG1 ARG2 ARG2 ARG3 etc...
1293                     ;; like in `setq'.
1294                     ((or (and (string-match-p "\\.\\.\\.$" argument)
1295                               (string= argument (car (last args-lst))))
1296                          (and (string-match-p "\\.\\.\\.$"
1297                                               (substring args 1 (1- (length args))))
1298                               (= (length (remove "..." args-lst)) 2)
1299                               (> index 1) (eq (logand index 1) 1)))
1300                      (setq index 0))
1301                     (t
1302                      (setq index (1- index))))))
1303         (setq end           (length args)
1304               start         (1- end)
1305               argument-face 'font-lock-warning-face
1306               index         0)))
1307     (let ((doc args))
1308       (when start
1309         (setq doc (copy-sequence args))
1310         (add-text-properties start end (list 'face argument-face) doc))
1311       (setq doc (elisp--docstring-format-sym-doc
1312                  sym doc (if (functionp sym) 'font-lock-function-name-face
1313                            'font-lock-keyword-face)))
1314       doc)))
1315
1316 ;; Return a string containing a brief (one-line) documentation string for
1317 ;; the variable.
1318 (defun elisp--get-var-docstring (sym)
1319   (cond ((not sym) nil)
1320         ((and (eq sym (aref elisp--eldoc-last-data 0))
1321               (eq 'variable (aref elisp--eldoc-last-data 2)))
1322          (aref elisp--eldoc-last-data 1))
1323         (t
1324          (let ((doc (documentation-property sym 'variable-documentation t)))
1325            (when doc
1326              (let ((doc (elisp--docstring-format-sym-doc
1327                          sym (elisp--docstring-first-line doc)
1328                          'font-lock-variable-name-face)))
1329                (elisp--last-data-store sym doc 'variable)))))))
1330
1331 (defun elisp--last-data-store (symbol doc type)
1332   (aset elisp--eldoc-last-data 0 symbol)
1333   (aset elisp--eldoc-last-data 1 doc)
1334   (aset elisp--eldoc-last-data 2 type)
1335   doc)
1336
1337 ;; Note that any leading `*' in the docstring (which indicates the variable
1338 ;; is a user option) is removed.
1339 (defun elisp--docstring-first-line (doc)
1340   (and (stringp doc)
1341        (substitute-command-keys
1342         (save-match-data
1343           ;; Don't use "^" in the regexp below since it may match
1344           ;; anywhere in the doc-string.
1345           (let ((start (if (string-match "\\`\\*" doc) (match-end 0) 0)))
1346             (cond ((string-match "\n" doc)
1347                    (substring doc start (match-beginning 0)))
1348                   ((zerop start) doc)
1349                   (t (substring doc start))))))))
1350
1351 (defvar eldoc-echo-area-use-multiline-p)
1352
1353 ;; If the entire line cannot fit in the echo area, the symbol name may be
1354 ;; truncated or eliminated entirely from the output to make room for the
1355 ;; description.
1356 (defun elisp--docstring-format-sym-doc (sym doc face)
1357   (save-match-data
1358     (let* ((name (symbol-name sym))
1359            (ea-multi eldoc-echo-area-use-multiline-p)
1360            ;; Subtract 1 from window width since emacs will not write
1361            ;; any chars to the last column, or in later versions, will
1362            ;; cause a wraparound and resize of the echo area.
1363            (ea-width (1- (window-width (minibuffer-window))))
1364            (strip (- (+ (length name) (length ": ") (length doc)) ea-width)))
1365       (cond ((or (<= strip 0)
1366                  (eq ea-multi t)
1367                  (and ea-multi (> (length doc) ea-width)))
1368              (format "%s: %s" (propertize name 'face face) doc))
1369             ((> (length doc) ea-width)
1370              (substring (format "%s" doc) 0 ea-width))
1371             ((>= strip (length name))
1372              (format "%s" doc))
1373             (t
1374              ;; Show the end of the partial symbol name, rather
1375              ;; than the beginning, since the former is more likely
1376              ;; to be unique given package namespace conventions.
1377              (setq name (substring name strip))
1378              (format "%s: %s" (propertize name 'face face) doc))))))
1379
1380 \f
1381 ;; Return a list of current function name and argument index.
1382 (defun elisp--fnsym-in-current-sexp ()
1383   (save-excursion
1384     (let ((argument-index (1- (elisp--beginning-of-sexp))))
1385       ;; If we are at the beginning of function name, this will be -1.
1386       (when (< argument-index 0)
1387         (setq argument-index 0))
1388       ;; Don't do anything if current word is inside a string.
1389       (if (= (or (char-after (1- (point))) 0) ?\")
1390           nil
1391         (list (elisp--current-symbol) argument-index)))))
1392
1393 ;; Move to the beginning of current sexp.  Return the number of nested
1394 ;; sexp the point was over or after.
1395 (defun elisp--beginning-of-sexp ()
1396   (let ((parse-sexp-ignore-comments t)
1397         (num-skipped-sexps 0))
1398     (condition-case _
1399         (progn
1400           ;; First account for the case the point is directly over a
1401           ;; beginning of a nested sexp.
1402           (condition-case _
1403               (let ((p (point)))
1404                 (forward-sexp -1)
1405                 (forward-sexp 1)
1406                 (when (< (point) p)
1407                   (setq num-skipped-sexps 1)))
1408             (error))
1409           (while
1410               (let ((p (point)))
1411                 (forward-sexp -1)
1412                 (when (< (point) p)
1413                   (setq num-skipped-sexps (1+ num-skipped-sexps))))))
1414       (error))
1415     num-skipped-sexps))
1416
1417 ;; returns nil unless current word is an interned symbol.
1418 (defun elisp--current-symbol ()
1419   (let ((c (char-after (point))))
1420     (and c
1421          (memq (char-syntax c) '(?w ?_))
1422          (intern-soft (current-word)))))
1423
1424 (defun elisp--function-argstring (arglist)
1425   "Return ARGLIST as a string enclosed by ().
1426 ARGLIST is either a string, or a list of strings or symbols."
1427   (let ((str (cond ((stringp arglist) arglist)
1428                    ((not (listp arglist)) nil)
1429                    (t (format "%S" (help-make-usage 'toto arglist))))))
1430     (if (and str (string-match "\\`([^ )]+ ?" str))
1431         (replace-match "(" t t str)
1432       str)))
1433
1434 (provide 'elisp-mode)
1435 ;;; elisp-mode.el ends here