lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997-1999, 2001-2011 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Introduction:
  28 ;;
  29 ;; Whenever a file that Emacs is editing has been changed by another
  30 ;; program the user normally has to execute the command `revert-buffer'
  31 ;; to load the new content of the file into Emacs.
  32 ;;
  33 ;; This package contains two minor modes: Global Auto-Revert Mode and
  34 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  35 ;; whenever the corresponding files have been changed on disk and the
  36 ;; buffer contains no unsaved changes.
  37 ;;
  38 ;; Auto-Revert Mode can be activated for individual buffers.  Global
  39 ;; Auto-Revert Mode applies to all file buffers. (If the user option
  40 ;; `global-auto-revert-non-file-buffers' is non-nil, it also applies
  41 ;; to some non-file buffers.  This option is disabled by default.)
  42 ;; Since checking a remote file is too slow, these modes do not check
  43 ;; or revert remote files.
  44 ;;
  45 ;; Both modes operate by checking the time stamp of all files at
  46 ;; intervals of `auto-revert-interval'.  The default is every five
  47 ;; seconds.  The check is aborted whenever the user actually uses
  48 ;; Emacs.  You should never even notice that this package is active
  49 ;; (except that your buffers will be reverted, of course).
  50 ;;
  51 ;; After reverting a file buffer, Auto Revert Mode normally puts point
  52 ;; at the same position that a regular manual revert would.  However,
  53 ;; there is one exception to this rule.  If point is at the end of the
  54 ;; buffer before reverting, it stays at the end.  Similarly if point
  55 ;; is displayed at the end of a file buffer in any window, it will stay
  56 ;; at the end of the buffer in that window, even if the window is not
  57 ;; selected.  This way, you can use Auto Revert Mode to `tail' a file.
  58 ;; Just put point at the end of the buffer and it will stay there.
  59 ;; These rules apply to file buffers. For non-file buffers, the
  60 ;; behavior may be mode dependent.
  61 ;;
  62 ;; While you can use Auto Revert Mode to tail a file, this package
  63 ;; contains a third minor mode, Auto Revert Tail Mode, which does so
  64 ;; more efficiently, as long as you are sure that the file will only
  65 ;; change by growing at the end.  It only appends the new output,
  66 ;; instead of reverting the entire buffer.  It does so even if the
  67 ;; buffer contains unsaved changes.  (Because they will not be lost.)
  68 ;; Auto Revert Tail Mode works also for remote files.
  69
  70 ;; Usage:
  71 ;;
  72 ;; Go to the appropriate buffer and press either of:
  73 ;;   M-x auto-revert-mode RET
  74 ;;   M-x auto-revert-tail-mode RET
  75 ;;
  76 ;; To activate Global Auto-Revert Mode, press:
  77 ;;   M-x global-auto-revert-mode RET
  78 ;;
  79 ;; To activate Global Auto-Revert Mode every time Emacs is started
  80 ;; customise the option `global-auto-revert-mode' or the following
  81 ;; line could be added to your ~/.emacs:
  82 ;;   (global-auto-revert-mode 1)
  83 ;;
  84 ;; The function `turn-on-auto-revert-mode' could be added to any major
  85 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  86 ;; mode.  For example, the following line will activate Auto-Revert
  87 ;; Mode in all C mode buffers:
  88 ;;
  89 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  90
  91 ;;; Code:
  92
  93 ;; Dependencies:
  94
  95 (require 'timer)
  96
  97 (eval-when-compile (require 'cl))
  98
  99
 100 ;; Custom Group:
 101 ;;
 102 ;; The two modes will be placed next to Auto Save Mode under the
 103 ;; Files group under Emacs.
 104
 105 (defgroup auto-revert nil
 106   "Revert individual buffers when files on disk change.
 107
 108 Auto-Revert Mode can be activated for individual buffer.
 109 Global Auto-Revert Mode applies to all buffers."
 110   :group 'files
 111   :group 'convenience)
 112
 113
 114 ;; Variables:
 115
 116 ;;; What's this?: ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 117 ;;; What's this?: ;;;###autoload
 118 (defvar auto-revert-mode nil
 119   "Non-nil when Auto-Revert Mode is active.
 120 Never set this variable directly, use the command `auto-revert-mode' instead.")
 121 (put 'auto-revert-mode 'permanent-local t)
 122
 123 (defvar auto-revert-tail-mode nil
 124   "Non-nil when Auto-Revert Tail Mode is active.
 125 Never set this variable directly, use the command
 126 `auto-revert-tail-mode' instead.")
 127 (put 'auto-revert-tail-mode 'permanent-local t)
 128
 129 (defvar auto-revert-timer nil
 130   "Timer used by Auto-Revert Mode.")
 131
 132 (defcustom auto-revert-interval 5
 133   "Time, in seconds, between Auto-Revert Mode file checks.
 134 The value may be an integer or floating point number.
 135
 136 If a timer is already active, there are two ways to make sure
 137 that the new value will take effect immediately.  You can set
 138 this variable through Custom or you can call the command
 139 `auto-revert-set-timer' after setting the variable.  Otherwise,
 140 the new value will take effect the first time Auto Revert Mode
 141 calls `auto-revert-set-timer' for internal reasons or in your
 142 next editing session."
 143   :group 'auto-revert
 144   :type 'number
 145   :set (lambda (variable value)
 146          (set-default variable value)
 147          (and (boundp 'auto-revert-timer)
 148               auto-revert-timer
 149               (auto-revert-set-timer))))
 150
 151 (defcustom auto-revert-stop-on-user-input t
 152   "When non-nil, user input temporarily interrupts Auto-Revert Mode.
 153 With this setting, Auto-Revert Mode checks for user input after
 154 handling each buffer and does not process any further buffers
 155 \(until the next run of the timer) if user input is available.
 156 When nil, Auto-Revert Mode checks files and reverts buffers,
 157 with quitting disabled, without paying attention to user input.
 158 Thus, with this setting, Emacs might be non-responsive at times."
 159   :group 'auto-revert
 160   :type 'boolean)
 161
 162 (defcustom auto-revert-verbose t
 163   "When nil, Auto-Revert Mode does not generate any messages.
 164 When non-nil, a message is generated whenever a file is reverted."
 165   :group 'auto-revert
 166   :type 'boolean)
 167
 168 (defcustom auto-revert-mode-text " ARev"
 169   "String to display in the mode line when Auto-Revert Mode is active.
 170
 171 \(When the string is not empty, make sure that it has a leading space.)"
 172   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 173   :group 'auto-revert
 174   :type 'string)
 175
 176 (defcustom auto-revert-tail-mode-text " Tail"
 177   "String to display in the mode line when Auto-Revert Tail Mode is active.
 178
 179 \(When the string is not empty, make sure that it has a leading space.)"
 180   :group 'auto-revert
 181   :type 'string
 182   :version "22.1")
 183
 184 (defcustom auto-revert-mode-hook nil
 185   "Functions to run when Auto-Revert Mode is activated."
 186   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 187   :group 'auto-revert
 188   :type 'hook)
 189
 190 (defcustom global-auto-revert-mode-text ""
 191   "String to display when Global Auto-Revert Mode is active.
 192
 193 The default is nothing since when this mode is active this text doesn't
 194 vary over time, or between buffers.  Hence mode line text
 195 would only waste precious space."
 196   :group 'auto-revert
 197   :type 'string)
 198
 199 (defcustom global-auto-revert-mode-hook nil
 200   "Hook called when Global Auto-Revert Mode is activated."
 201   :group 'auto-revert
 202   :type 'hook)
 203
 204 (defcustom global-auto-revert-non-file-buffers nil
 205   "When nil, Global Auto-Revert mode operates only on file-visiting buffers.
 206
 207 When non-nil, both file buffers and buffers with a custom
 208 `revert-buffer-function' and a `buffer-stale-function' are
 209 reverted by Global Auto-Revert mode.  These include the Buffer
 210 List buffer displayed by `buffer-menu', and Dired buffers showing
 211 complete local directories.  The Buffer List buffer reverts every
 212 `auto-revert-interval' seconds; Dired buffers when the file list of
 213 the main directory changes.  Dired buffers do not auto-revert as
 214 a result of changes in subdirectories, or in the contents, size,
 215 modes, etc., of files.  You may still sometimes want to revert
 216 them manually.
 217
 218 Use this option with care since it could lead to excessive auto-reverts.
 219 For more information, see Info node `(emacs)Autorevert'."
 220   :group 'auto-revert
 221   :type 'boolean
 222   :link '(info-link "(emacs)Autorevert"))
 223
 224 (defcustom global-auto-revert-ignore-modes ()
 225   "List of major modes Global Auto-Revert Mode should not check."
 226   :group 'auto-revert
 227   :type '(repeat sexp))
 228
 229 (defcustom auto-revert-load-hook nil
 230   "Functions to run when Auto-Revert Mode is first loaded."
 231   :tag "Load Hook"
 232   :group 'auto-revert
 233   :type 'hook)
 234
 235 (defcustom auto-revert-check-vc-info nil
 236   "If non-nil Auto Revert Mode reliably updates version control info.
 237 Auto Revert Mode updates version control info whenever the buffer
 238 needs reverting, regardless of the value of this variable.
 239 However, the version control state can change without changes to
 240 the work file.  If the change is made from the current Emacs
 241 session, all info is updated.  But if, for instance, a new
 242 version is checked in from outside the current Emacs session, the
 243 version control number in the mode line, as well as other version
 244 control related information, may not be properly updated.  If you
 245 are worried about this, set this variable to a non-nil value.
 246
 247 This currently works by automatically updating the version
 248 control info every `auto-revert-interval' seconds.  Nevertheless,
 249 it should not cause excessive CPU usage on a reasonably fast
 250 machine, if it does not apply to too many version controlled
 251 buffers.  CPU usage depends on the version control system."
 252   :group 'auto-revert
 253   :type 'boolean
 254   :version "22.1")
 255
 256 (defvar global-auto-revert-ignore-buffer nil
 257   "When non-nil, Global Auto-Revert Mode will not revert this buffer.
 258 This variable becomes buffer local when set in any fashion.")
 259 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 260
 261 ;; Internal variables:
 262
 263 (defvar auto-revert-buffer-list ()
 264   "List of buffers in Auto-Revert Mode.
 265
 266 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 267 buffers to this list.
 268
 269 The timer function `auto-revert-buffers' is responsible for purging
 270 the list of old buffers.")
 271
 272 (defvar auto-revert-remaining-buffers ()
 273   "Buffers not checked when user input stopped execution.")
 274
 275 (defvar auto-revert-tail-pos 0
 276   "Position of last known end of file.")
 277
 278 (add-hook 'find-file-hook
 279           (lambda ()
 280             (set (make-local-variable 'auto-revert-tail-pos)
 281                  (nth 7 (file-attributes buffer-file-name)))))
 282
 283 ;; Functions:
 284
 285 ;;;###autoload
 286 (define-minor-mode auto-revert-mode
 287   "Toggle reverting buffer when file on disk changes.
 288
 289 With arg, turn Auto Revert mode on if and only if arg is positive.
 290 This is a minor mode that affects only the current buffer.
 291 Use `global-auto-revert-mode' to automatically revert all buffers.
 292 Use `auto-revert-tail-mode' if you know that the file will only grow
 293 without being changed in the part that is already in the buffer."
 294   :group 'auto-revert :lighter auto-revert-mode-text
 295   (if auto-revert-mode
 296       (if (not (memq (current-buffer) auto-revert-buffer-list))
 297           (push (current-buffer) auto-revert-buffer-list))
 298     (setq auto-revert-buffer-list
 299           (delq (current-buffer) auto-revert-buffer-list)))
 300   (auto-revert-set-timer)
 301   (when auto-revert-mode
 302     (auto-revert-buffers)
 303     (setq auto-revert-tail-mode nil)))
 304
 305
 306 ;;;###autoload
 307 (defun turn-on-auto-revert-mode ()
 308   "Turn on Auto-Revert Mode.
 309
 310 This function is designed to be added to hooks, for example:
 311   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 312   (auto-revert-mode 1))
 313
 314
 315 ;;;###autoload
 316 (define-minor-mode auto-revert-tail-mode
 317   "Toggle reverting tail of buffer when file on disk grows.
 318 With arg, turn Tail mode on if arg is positive, otherwise turn it off.
 319
 320 When Tail mode is enabled, the tail of the file is constantly
 321 followed, as with the shell command `tail -f'.  This means that
 322 whenever the file grows on disk (presumably because some
 323 background process is appending to it from time to time), this is
 324 reflected in the current buffer.
 325
 326 You can edit the buffer and turn this mode off and on again as
 327 you please.  But make sure the background process has stopped
 328 writing before you save the file!
 329
 330 Use `auto-revert-mode' for changes other than appends!"
 331   :group 'find-file :lighter auto-revert-tail-mode-text
 332   (when auto-revert-tail-mode
 333     (unless buffer-file-name
 334       (auto-revert-tail-mode 0)
 335       (error "This buffer is not visiting a file"))
 336     (if (and (buffer-modified-p)
 337              (zerop auto-revert-tail-pos) ; library was loaded only after finding file
 338              (not (y-or-n-p "Buffer is modified, so tail offset may be wrong.  Proceed? ")))
 339         (auto-revert-tail-mode 0)
 340       ;; a-r-tail-pos stores the size of the file at the time of the
 341       ;; last revert. After this package loads, it adds a
 342       ;; find-file-hook to set this variable every time a file is
 343       ;; loaded.  If the package is loaded only _after_ visiting the
 344       ;; file to be reverted, then we have no idea what the value of
 345       ;; a-r-tail-pos should have been when the file was visited.  If
 346       ;; the file has changed on disk in the meantime, all we can do
 347       ;; is offer to revert the whole thing. If you choose not to
 348       ;; revert, then you might miss some output then happened
 349       ;; between visiting the file and activating a-r-t-mode.
 350       (and (zerop auto-revert-tail-pos)
 351            (not (verify-visited-file-modtime (current-buffer)))
 352            (y-or-n-p "File changed on disk, content may be missing.  \
 353 Perform a full revert? ")
 354            ;; Use this (not just revert-buffer) for point-preservation.
 355            (auto-revert-handler))
 356       ;; else we might reappend our own end when we save
 357       (add-hook 'before-save-hook (lambda () (auto-revert-tail-mode 0)) nil t)
 358       (or (local-variable-p 'auto-revert-tail-pos) ; don't lose prior position
 359           (set (make-local-variable 'auto-revert-tail-pos)
 360                (nth 7 (file-attributes buffer-file-name))))
 361       ;; let auto-revert-mode set up the mechanism for us if it isn't already
 362       (or auto-revert-mode
 363           (let ((auto-revert-tail-mode t))
 364             (auto-revert-mode 1)))
 365       (setq auto-revert-mode nil))))
 366
 367
 368 ;;;###autoload
 369 (defun turn-on-auto-revert-tail-mode ()
 370   "Turn on Auto-Revert Tail Mode.
 371
 372 This function is designed to be added to hooks, for example:
 373   (add-hook 'my-logfile-mode-hook 'turn-on-auto-revert-tail-mode)"
 374   (auto-revert-tail-mode 1))
 375
 376
 377 ;;;###autoload
 378 (define-minor-mode global-auto-revert-mode
 379   "Toggle Global Auto Revert mode.
 380 With optional prefix argument ARG, enable Global Auto Revert Mode
 381 if ARG > 0, else disable it.
 382
 383 This is a global minor mode that reverts any buffer associated
 384 with a file when the file changes on disk.  Use `auto-revert-mode'
 385 to revert a particular buffer.
 386
 387 If `global-auto-revert-non-file-buffers' is non-nil, this mode
 388 may also revert some non-file buffers, as described in the
 389 documentation of that variable.  It ignores buffers with modes
 390 matching `global-auto-revert-ignore-modes', and buffers with a
 391 non-nil vale of `global-auto-revert-ignore-buffer'.
 392
 393 This function calls the hook `global-auto-revert-mode-hook'.
 394 It displays the text that `global-auto-revert-mode-text'
 395 specifies in the mode line."
 396   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 397   (auto-revert-set-timer)
 398   (when global-auto-revert-mode
 399     (auto-revert-buffers)))
 400
 401
 402 (defun auto-revert-set-timer ()
 403   "Restart or cancel the timer used by Auto-Revert Mode.
 404 If such a timer is active, cancel it.  Start a new timer if
 405 Global Auto-Revert Mode is active or if Auto-Revert Mode is active
 406 in some buffer.  Restarting the timer ensures that Auto-Revert Mode
 407 will use an up-to-date value of `auto-revert-interval'"
 408   (interactive)
 409   (if (timerp auto-revert-timer)
 410       (cancel-timer auto-revert-timer))
 411   (setq auto-revert-timer
 412         (if (or global-auto-revert-mode auto-revert-buffer-list)
 413             (run-with-timer auto-revert-interval
 414                             auto-revert-interval
 415                             'auto-revert-buffers))))
 416
 417 (defun auto-revert-active-p ()
 418   "Check if auto-revert is active (in current buffer or globally)."
 419   (or auto-revert-mode
 420       auto-revert-tail-mode
 421       (and
 422        global-auto-revert-mode
 423        (not global-auto-revert-ignore-buffer)
 424        (not (memq major-mode
 425                   global-auto-revert-ignore-modes)))))
 426
 427 (defun auto-revert-handler ()
 428   "Revert current buffer, if appropriate.
 429 This is an internal function used by Auto-Revert Mode."
 430   (when (or auto-revert-tail-mode (not (buffer-modified-p)))
 431     (let* ((buffer (current-buffer)) size
 432            (revert
 433             (or (and buffer-file-name
 434                      (file-readable-p buffer-file-name)
 435                      (if auto-revert-tail-mode
 436                          ;; Tramp caches the file attributes.  Setting
 437                          ;; `remote-file-name-inhibit-cache' forces Tramp
 438                          ;; to reread the values.
 439                          (let ((remote-file-name-inhibit-cache t))
 440                            (/= auto-revert-tail-pos
 441                                (setq size
 442                                      (nth 7 (file-attributes
 443                                              buffer-file-name)))))
 444                        (and (not (file-remote-p buffer-file-name))
 445                             (not (verify-visited-file-modtime buffer)))))
 446                 (and (or auto-revert-mode
 447                          global-auto-revert-non-file-buffers)
 448                      revert-buffer-function
 449                      (boundp 'buffer-stale-function)
 450                      (functionp buffer-stale-function)
 451                      (funcall buffer-stale-function t))))
 452            eob eoblist)
 453       (when revert
 454         (when (and auto-revert-verbose
 455                    (not (eq revert 'fast)))
 456           (message "Reverting buffer `%s'." (buffer-name)))
 457         ;; If point (or a window point) is at the end of the buffer,
 458         ;; we want to keep it at the end after reverting.  This allows
 459         ;; to tail a file.
 460         (when buffer-file-name
 461           (setq eob (eobp))
 462           (walk-windows
 463            (lambda (window)
 464              (and (eq (window-buffer window) buffer)
 465                   (= (window-point window) (point-max))
 466                   (push window eoblist)))
 467            'no-mini t))
 468         (if auto-revert-tail-mode
 469             (auto-revert-tail-handler size)
 470           ;; Bind buffer-read-only in case user has done C-x C-q,
 471           ;; so as not to forget that.  This gives undesirable results
 472           ;; when the file's mode changes, but that is less common.
 473           (let ((buffer-read-only buffer-read-only))
 474             (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)))
 475         (when buffer-file-name
 476           (when eob (goto-char (point-max)))
 477           (dolist (window eoblist)
 478             (set-window-point window (point-max)))))
 479       ;; `preserve-modes' avoids changing the (minor) modes.  But we
 480       ;; do want to reset the mode for VC, so we do it manually.
 481       (when (or revert auto-revert-check-vc-info)
 482         (vc-find-file-hook)))))
 483
 484 (defun auto-revert-tail-handler (size)
 485   (let ((modified (buffer-modified-p))
 486         (inhibit-read-only t)           ; Ignore.
 487         (file buffer-file-name)
 488         (buffer-file-name nil))         ; Ignore that file has changed.
 489     (when (/= auto-revert-tail-pos size)
 490       (run-hooks 'before-revert-hook)
 491       (undo-boundary)
 492       (save-restriction
 493         (widen)
 494         (save-excursion
 495           (goto-char (point-max))
 496           (insert-file-contents file nil
 497                                 (and (< auto-revert-tail-pos size)
 498                                      auto-revert-tail-pos)
 499                                 size)))
 500       (run-hooks 'after-revert-hook)
 501       (undo-boundary)
 502       (setq auto-revert-tail-pos size)
 503       (restore-buffer-modified-p modified)))
 504   (set-visited-file-modtime))
 505
 506 (defun auto-revert-buffers ()
 507   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 508
 509 Should `global-auto-revert-mode' be active all file buffers are checked.
 510
 511 Should `auto-revert-mode' be active in some buffers, those buffers
 512 are checked.
 513
 514 Non-file buffers that have a custom `revert-buffer-function' and
 515 a `buffer-stale-function' are reverted either when Auto-Revert
 516 Mode is active in that buffer, or when the variable
 517 `global-auto-revert-non-file-buffers' is non-nil and Global
 518 Auto-Revert Mode is active.
 519
 520 This function stops whenever there is user input.  The buffers not
 521 checked are stored in the variable `auto-revert-remaining-buffers'.
 522
 523 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 524 are checked first the next time this function is called.
 525
 526 This function is also responsible for removing buffers no longer in
 527 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 528 the timer when no buffers need to be checked."
 529   (save-match-data
 530     (let ((bufs (if global-auto-revert-mode
 531                     (buffer-list)
 532                   auto-revert-buffer-list))
 533           (remaining ())
 534           (new ()))
 535       ;; Partition `bufs' into two halves depending on whether or not
 536       ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 537       ;; halves are then re-joined with the "remaining" buffers at the
 538       ;; head of the list.
 539       (dolist (buf auto-revert-remaining-buffers)
 540         (if (memq buf bufs)
 541             (push buf remaining)))
 542       (dolist (buf bufs)
 543         (if (not (memq buf remaining))
 544             (push buf new)))
 545       (setq bufs (nreverse (nconc new remaining)))
 546       (while (and bufs
 547                   (not (and auto-revert-stop-on-user-input
 548                             (input-pending-p))))
 549         (let ((buf (car bufs)))
 550           (if (buffer-live-p buf)
 551               (with-current-buffer buf
 552                 ;; Test if someone has turned off Auto-Revert Mode in a
 553                 ;; non-standard way, for example by changing major mode.
 554                 (if (and (not auto-revert-mode)
 555                          (not auto-revert-tail-mode)
 556                          (memq buf auto-revert-buffer-list))
 557                     (setq auto-revert-buffer-list
 558                           (delq buf auto-revert-buffer-list)))
 559                 (when (auto-revert-active-p) (auto-revert-handler)))
 560             ;; Remove dead buffer from `auto-revert-buffer-list'.
 561             (setq auto-revert-buffer-list
 562                   (delq buf auto-revert-buffer-list))))
 563         (setq bufs (cdr bufs)))
 564       (setq auto-revert-remaining-buffers bufs)
 565       ;; Check if we should cancel the timer.
 566       (when (and (not global-auto-revert-mode)
 567                  (null auto-revert-buffer-list))
 568         (cancel-timer auto-revert-timer)
 569         (setq auto-revert-timer nil)))))
 570
 571
 572 ;; The end:
 573 (provide 'autorevert)
 574
 575 (run-hooks 'auto-revert-load-hook)
 576
 577 ;;; autorevert.el ends here