lisp/help.el

   1 ;;; help.el --- help commands for Emacs
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2017 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Maintainer: emacs-devel@gnu.org
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This code implements GNU Emacs's built-in help system, the one invoked by
  28 ;; `M-x help-for-help'.
  29
  30 ;;; Code:
  31
  32 ;; Get the macro make-help-screen when this is compiled,
  33 ;; or run interpreted, but not when the compiled code is loaded.
  34 (eval-when-compile (require 'help-macro))
  35
  36 ;; This makes `with-output-to-temp-buffer' buffers use `help-mode'.
  37 (add-hook 'temp-buffer-setup-hook 'help-mode-setup)
  38 (add-hook 'temp-buffer-show-hook 'help-mode-finish)
  39
  40 ;; `help-window-point-marker' is a marker you can move to a valid
  41 ;; position of the buffer shown in the help window in order to override
  42 ;; the standard positioning mechanism (`point-min') chosen by
  43 ;; `with-output-to-temp-buffer' and `with-temp-buffer-window'.
  44 ;; `with-help-window' has this point nowhere before exiting.  Currently
  45 ;; used by `view-lossage' to assert that the last keystrokes are always
  46 ;; visible.
  47 (defvar help-window-point-marker (make-marker)
  48   "Marker to override default `window-point' in help windows.")
  49
  50 (defvar help-window-old-frame nil
  51   "Frame selected at the time `with-help-window' is invoked.")
  52
  53 (defvar help-map
  54   (let ((map (make-sparse-keymap)))
  55     (define-key map (char-to-string help-char) 'help-for-help)
  56     (define-key map [help] 'help-for-help)
  57     (define-key map [f1] 'help-for-help)
  58     (define-key map "." 'display-local-help)
  59     (define-key map "?" 'help-for-help)
  60
  61     (define-key map "\C-a" 'about-emacs)
  62     (define-key map "\C-c" 'describe-copying)
  63     (define-key map "\C-d" 'view-emacs-debugging)
  64     (define-key map "\C-e" 'view-external-packages)
  65     (define-key map "\C-f" 'view-emacs-FAQ)
  66     (define-key map "\C-m" 'view-order-manuals)
  67     (define-key map "\C-n" 'view-emacs-news)
  68     (define-key map "\C-o" 'describe-distribution)
  69     (define-key map "\C-p" 'view-emacs-problems)
  70     (define-key map "\C-t" 'view-emacs-todo)
  71     (define-key map "\C-w" 'describe-no-warranty)
  72
  73     ;; This does not fit the pattern, but it is natural given the C-\ command.
  74     (define-key map "\C-\\" 'describe-input-method)
  75
  76     (define-key map "C" 'describe-coding-system)
  77     (define-key map "F" 'Info-goto-emacs-command-node)
  78     (define-key map "I" 'describe-input-method)
  79     (define-key map "K" 'Info-goto-emacs-key-command-node)
  80     (define-key map "L" 'describe-language-environment)
  81     (define-key map "S" 'info-lookup-symbol)
  82
  83     (define-key map "a" 'apropos-command)
  84     (define-key map "b" 'describe-bindings)
  85     (define-key map "c" 'describe-key-briefly)
  86     (define-key map "d" 'apropos-documentation)
  87     (define-key map "e" 'view-echo-area-messages)
  88     (define-key map "f" 'describe-function)
  89     (define-key map "g" 'describe-gnu-project)
  90     (define-key map "h" 'view-hello-file)
  91
  92     (define-key map "i" 'info)
  93     (define-key map "4i" 'info-other-window)
  94
  95     (define-key map "k" 'describe-key)
  96     (define-key map "l" 'view-lossage)
  97     (define-key map "m" 'describe-mode)
  98     (define-key map "o" 'describe-symbol)
  99     (define-key map "n" 'view-emacs-news)
 100     (define-key map "p" 'finder-by-keyword)
 101     (define-key map "P" 'describe-package)
 102     (define-key map "r" 'info-emacs-manual)
 103     (define-key map "s" 'describe-syntax)
 104     (define-key map "t" 'help-with-tutorial)
 105     (define-key map "w" 'where-is)
 106     (define-key map "v" 'describe-variable)
 107     (define-key map "q" 'help-quit)
 108     map)
 109   "Keymap for characters following the Help key.")
 110
 111 (define-key global-map (char-to-string help-char) 'help-command)
 112 (define-key global-map [help] 'help-command)
 113 (define-key global-map [f1] 'help-command)
 114 (fset 'help-command help-map)
 115
 116 ;; insert-button makes the action nil if it is not store somewhere
 117 (defvar help-button-cache nil)
 118
 119 \f
 120 (defun help-quit ()
 121   "Just exit from the Help command's command loop."
 122   (interactive)
 123   nil)
 124
 125 (defvar help-return-method nil
 126   "What to do to \"exit\" the help buffer.
 127 This is a list
 128  (WINDOW . t)              delete the selected window (and possibly its frame,
 129                            see `quit-window'), go to WINDOW.
 130  (WINDOW . quit-window)    do quit-window, then select WINDOW.
 131  (WINDOW BUF START POINT)  display BUF at START, POINT, then select WINDOW.")
 132
 133 (define-obsolete-function-alias 'print-help-return-message 'help-print-return-message "23.2")
 134 (defun help-print-return-message (&optional function)
 135   "Display or return message saying how to restore windows after help command.
 136 This function assumes that `standard-output' is the help buffer.
 137 It computes a message, and applies the optional argument FUNCTION to it.
 138 If FUNCTION is nil, it applies `message', thus displaying the message.
 139 In addition, this function sets up `help-return-method', which see, that
 140 specifies what to do when the user exits the help buffer.
 141
 142 Do not call this in the scope of `with-help-window'."
 143   (and (not (get-buffer-window standard-output))
 144        (let ((first-message
 145               (cond ((or
 146                       pop-up-frames
 147                       (special-display-p (buffer-name standard-output)))
 148                      (setq help-return-method (cons (selected-window) t))
 149                      ;; If the help output buffer is a special display buffer,
 150                      ;; don't say anything about how to get rid of it.
 151                      ;; First of all, the user will do that with the window
 152                      ;; manager, not with Emacs.
 153                      ;; Secondly, the buffer has not been displayed yet,
 154                      ;; so we don't know whether its frame will be selected.
 155                      nil)
 156                     ((not (one-window-p t))
 157                      (setq help-return-method
 158                            (cons (selected-window) 'quit-window))
 159                      "Type \\[display-buffer] RET to restore the other window.")
 160                     (pop-up-windows
 161                      (setq help-return-method (cons (selected-window) t))
 162                      "Type \\[delete-other-windows] to remove help window.")
 163                     (t
 164                      (setq help-return-method
 165                            (list (selected-window) (window-buffer)
 166                                  (window-start) (window-point)))
 167                      "Type \\[switch-to-buffer] RET to remove help window."))))
 168          (funcall (or function 'message)
 169                   (concat
 170                    (if first-message
 171                        (substitute-command-keys first-message))
 172                    (if first-message "  ")
 173                    ;; If the help buffer will go in a separate frame,
 174                    ;; it's no use mentioning a command to scroll, so don't.
 175                    (if (or pop-up-windows
 176                            (special-display-p (buffer-name standard-output)))
 177                        nil
 178                      (if (same-window-p (buffer-name standard-output))
 179                          ;; Say how to scroll this window.
 180                          (substitute-command-keys
 181                           "\\[scroll-up] to scroll the help.")
 182                        ;; Say how to scroll some other window.
 183                        (substitute-command-keys
 184                         "\\[scroll-other-window] to scroll the help."))))))))
 185
 186 ;; So keyboard macro definitions are documented correctly
 187 (fset 'defining-kbd-macro (symbol-function 'start-kbd-macro))
 188
 189 (defalias 'help 'help-for-help-internal)
 190 ;; find-function can find this.
 191 (defalias 'help-for-help 'help-for-help-internal)
 192 ;; It can't find this, but nobody will look.
 193 (make-help-screen help-for-help-internal
 194   (purecopy "Type a help option: [abcCdefFgiIkKlLmnprstvw.] C-[cdefmnoptw] or ?")
 195   ;; Don't purecopy this one, because it's not evaluated (it's
 196   ;; directly used as a docstring in a function definition, so it'll
 197   ;; be moved to the DOC file anyway: no need for purecopying it).
 198   "You have typed %THIS-KEY%, the help character.  Type a Help option:
 199 \(Use SPC or DEL to scroll through this text.  Type \\<help-map>\\[help-quit] to exit the Help command.)
 200
 201 a PATTERN   Show commands whose name matches the PATTERN (a list of words
 202               or a regexp).  See also the `apropos' command.
 203 b           Display all key bindings.
 204 c KEYS      Display the command name run by the given key sequence.
 205 C CODING    Describe the given coding system, or RET for current ones.
 206 d PATTERN   Show a list of functions, variables, and other items whose
 207               documentation matches the PATTERN (a list of words or a regexp).
 208 e           Go to the *Messages* buffer which logs echo-area messages.
 209 f FUNCTION  Display documentation for the given function.
 210 F COMMAND   Show the Emacs manual's section that describes the command.
 211 g           Display information about the GNU project.
 212 h           Display the HELLO file which illustrates various scripts.
 213 i           Start the Info documentation reader: read included manuals.
 214 I METHOD    Describe a specific input method, or RET for current.
 215 k KEYS      Display the full documentation for the key sequence.
 216 K KEYS      Show the Emacs manual's section for the command bound to KEYS.
 217 l           Show last 300 input keystrokes (lossage).
 218 L LANG-ENV  Describes a specific language environment, or RET for current.
 219 m           Display documentation of current minor modes and current major mode,
 220               including their special commands.
 221 n           Display news of recent Emacs changes.
 222 o SYMBOL    Display the given function or variable's documentation and value.
 223 p TOPIC     Find packages matching a given topic keyword.
 224 P PACKAGE   Describe the given Emacs Lisp package.
 225 r           Display the Emacs manual in Info mode.
 226 s           Display contents of current syntax table, plus explanations.
 227 S SYMBOL    Show the section for the given symbol in the Info manual
 228               for the programming language used in this buffer.
 229 t           Start the Emacs learn-by-doing tutorial.
 230 v VARIABLE  Display the given variable's documentation and value.
 231 w COMMAND   Display which keystrokes invoke the given command (where-is).
 232 .           Display any available local help at point in the echo area.
 233
 234 C-a         Information about Emacs.
 235 C-c         Emacs copying permission (GNU General Public License).
 236 C-d         Instructions for debugging GNU Emacs.
 237 C-e         External packages and information about Emacs.
 238 C-f         Emacs FAQ.
 239 C-m         How to order printed Emacs manuals.
 240 C-n         News of recent Emacs changes.
 241 C-o         Emacs ordering and distribution information.
 242 C-p         Info about known Emacs problems.
 243 C-t         Emacs TODO list.
 244 C-w         Information on absence of warranty for GNU Emacs."
 245   help-map)
 246
 247 \f
 248
 249 (defun function-called-at-point ()
 250   "Return a function around point or else called by the list containing point.
 251 If that doesn't give a function, return nil."
 252   (with-syntax-table emacs-lisp-mode-syntax-table
 253     (or (condition-case ()
 254             (save-excursion
 255               (or (not (zerop (skip-syntax-backward "_w")))
 256                   (eq (char-syntax (following-char)) ?w)
 257                   (eq (char-syntax (following-char)) ?_)
 258                   (forward-sexp -1))
 259               (skip-chars-forward "'")
 260               (let ((obj (read (current-buffer))))
 261                 (and (symbolp obj) (fboundp obj) obj)))
 262           (error nil))
 263         (condition-case ()
 264             (save-excursion
 265               (save-restriction
 266                 (narrow-to-region (max (point-min)
 267                                        (- (point) 1000)) (point-max))
 268                 ;; Move up to surrounding paren, then after the open.
 269                 (backward-up-list 1)
 270                 (forward-char 1)
 271                 ;; If there is space here, this is probably something
 272                 ;; other than a real Lisp function call, so ignore it.
 273                 (if (looking-at "[ \t]")
 274                     (error "Probably not a Lisp function call"))
 275                 (let ((obj (read (current-buffer))))
 276                   (and (symbolp obj) (fboundp obj) obj))))
 277           (error nil))
 278         (let* ((str (find-tag-default))
 279                (sym (if str (intern-soft str))))
 280           (if (and sym (fboundp sym))
 281               sym
 282             (save-match-data
 283               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 284                 (setq sym (intern-soft (match-string 1 str)))
 285                 (and (fboundp sym) sym))))))))
 286
 287 \f
 288 ;;; `User' help functions
 289
 290 (defun view-help-file (file &optional dir)
 291   (view-file (expand-file-name file (or dir data-directory)))
 292   (goto-address-mode 1)
 293   (goto-char (point-min)))
 294
 295 (defun describe-distribution ()
 296   "Display info on how to obtain the latest version of GNU Emacs."
 297   (interactive)
 298   (view-help-file "DISTRIB"))
 299
 300 (defun describe-copying ()
 301   "Display info on how you may redistribute copies of GNU Emacs."
 302   (interactive)
 303   (view-help-file "COPYING"))
 304
 305 ;; Maybe this command should just be removed.
 306 (defun describe-gnu-project ()
 307   "Browse online information on the GNU project."
 308   (interactive)
 309   (browse-url "http://www.gnu.org/gnu/thegnuproject.html"))
 310
 311 (define-obsolete-function-alias 'describe-project 'describe-gnu-project "22.2")
 312
 313 (defun describe-no-warranty ()
 314   "Display info on all the kinds of warranty Emacs does NOT have."
 315   (interactive)
 316   (describe-copying)
 317   (let (case-fold-search)
 318     (search-forward "Disclaimer of Warranty")
 319     (forward-line 0)
 320     (recenter 0)))
 321
 322 (defun describe-prefix-bindings ()
 323   "Describe the bindings of the prefix used to reach this command.
 324 The prefix described consists of all but the last event
 325 of the key sequence that ran this command."
 326   (interactive)
 327   (let ((key (this-command-keys)))
 328     (describe-bindings
 329      (if (stringp key)
 330          (substring key 0 (1- (length key)))
 331        (let ((prefix (make-vector (1- (length key)) nil))
 332              (i 0))
 333          (while (< i (length prefix))
 334            (aset prefix i (aref key i))
 335            (setq i (1+ i)))
 336          prefix)))))
 337 ;; Make C-h after a prefix, when not specifically bound,
 338 ;; run describe-prefix-bindings.
 339 (setq prefix-help-command 'describe-prefix-bindings)
 340
 341 (defun view-emacs-news (&optional version)
 342   "Display info on recent changes to Emacs.
 343 With argument, display info only for the selected version."
 344   (interactive "P")
 345   (unless version
 346     (setq version emacs-major-version))
 347   (when (consp version)
 348     (let* ((all-versions
 349             (let (res)
 350               (mapc
 351                (lambda (file)
 352                  (with-temp-buffer
 353                    (insert-file-contents
 354                     (expand-file-name file data-directory))
 355                    (while (re-search-forward
 356                            (if (member file '("NEWS.18" "NEWS.1-17"))
 357                                "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 358                              "^\\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t)
 359                      (setq res (cons (match-string-no-properties 1) res)))))
 360                (cons "NEWS"
 361                      (directory-files data-directory nil
 362                                       "^NEWS\\.[0-9][-0-9]*$" nil)))
 363               (sort (delete-dups res) #'string>)))
 364            (current (car all-versions)))
 365       (setq version (completing-read
 366                      (format "Read NEWS for the version (default %s): " current)
 367                      all-versions nil nil nil nil current))
 368       (if (integerp (string-to-number version))
 369           (setq version (string-to-number version))
 370         (unless (or (member version all-versions)
 371                     (<= (string-to-number version) (string-to-number current)))
 372           (error "No news about version %s" version)))))
 373   (when (integerp version)
 374     (cond ((<= version 12)
 375            (setq version (format "1.%d" version)))
 376           ((<= version 18)
 377            (setq version (format "%d" version)))
 378           ((> version emacs-major-version)
 379            (error "No news about Emacs %d (yet)" version))))
 380   (let* ((vn (if (stringp version)
 381                  (string-to-number version)
 382                version))
 383          (file (cond
 384                 ((>= vn emacs-major-version) "NEWS")
 385                 ((< vn 18) "NEWS.1-17")
 386                 (t (format "NEWS.%d" vn))))
 387          res)
 388     (view-file (expand-file-name file data-directory))
 389     (widen)
 390     (goto-char (point-min))
 391     (when (stringp version)
 392       (when (re-search-forward
 393              (concat (if (< vn 19)
 394                          "Changes in Emacs[ \t]*"
 395                        "^\\* [^0-9\n]*") version "$")
 396              nil t)
 397         (beginning-of-line)
 398         (narrow-to-region
 399          (point)
 400          (save-excursion
 401            (while (and (setq res
 402                              (re-search-forward
 403                               (if (< vn 19)
 404                                   "Changes in \\(?:Emacs\\|version\\)?[ \t]*\\([0-9]+\\(?:\\.[0-9]+\\)?\\)"
 405                                 "^\\* [^0-9\n]*\\([0-9]+\\.[0-9]+\\)") nil t))
 406                        (equal (match-string-no-properties 1) version)))
 407            (or res (goto-char (point-max)))
 408            (beginning-of-line)
 409            (point)))))))
 410
 411 (defun view-emacs-todo (&optional _arg)
 412   "Display the Emacs TODO list."
 413   (interactive "P")
 414   (view-help-file "TODO"))
 415
 416 (define-obsolete-function-alias 'view-todo 'view-emacs-todo "22.2")
 417
 418
 419 (defun view-echo-area-messages ()
 420   "View the log of recent echo-area messages: the `*Messages*' buffer.
 421 The number of messages retained in that buffer
 422 is specified by the variable `message-log-max'."
 423   (interactive)
 424   (with-current-buffer (messages-buffer)
 425     (goto-char (point-max))
 426     (display-buffer (current-buffer))))
 427
 428 (defun view-order-manuals ()
 429   "Display information on how to buy printed copies of Emacs manuals."
 430   (interactive)
 431 ;;  (view-help-file "ORDERS")
 432   (info "(emacs)Printed Books"))
 433
 434 (defun view-emacs-FAQ ()
 435   "Display the Emacs Frequently Asked Questions (FAQ) file."
 436   (interactive)
 437   ;; (find-file-read-only (expand-file-name "FAQ" data-directory))
 438   (info "(efaq)"))
 439
 440 (defun view-emacs-problems ()
 441   "Display info on known problems with Emacs and possible workarounds."
 442   (interactive)
 443   (view-help-file "PROBLEMS"))
 444
 445 (defun view-emacs-debugging ()
 446   "Display info on how to debug Emacs problems."
 447   (interactive)
 448   (view-help-file "DEBUG"))
 449
 450 ;; This used to visit MORE.STUFF; maybe it should just be removed.
 451 (defun view-external-packages ()
 452   "Display info on where to get more Emacs packages."
 453   (interactive)
 454   (info "(efaq)Packages that do not come with Emacs"))
 455
 456 (defun view-lossage ()
 457   "Display last few input keystrokes and the commands run.
 458
 459 To record all your input, use `open-dribble-file'."
 460   (interactive)
 461   (help-setup-xref (list #'view-lossage)
 462                    (called-interactively-p 'interactive))
 463   (with-help-window (help-buffer)
 464     (princ " ")
 465     (princ (mapconcat (lambda (key)
 466                         (cond
 467                          ((and (consp key) (null (car key)))
 468                           (format "[%s]\n" (if (symbolp (cdr key)) (cdr key)
 469                                            "anonymous-command")))
 470                          ((or (integerp key) (symbolp key) (listp key))
 471                           (single-key-description key))
 472                          (t
 473                           (prin1-to-string key nil))))
 474                       (recent-keys 'include-cmds)
 475                       " "))
 476     (with-current-buffer standard-output
 477       (goto-char (point-min))
 478       (while (not (eobp))
 479         (move-to-column 50)
 480         (unless (eolp)
 481           (fill-region (line-beginning-position) (line-end-position)))
 482         (forward-line 1))
 483       ;; jidanni wants to see the last keystrokes immediately.
 484       (set-marker help-window-point-marker (point)))))
 485
 486 \f
 487 ;; Key bindings
 488
 489 (defun describe-bindings (&optional prefix buffer)
 490   "Display a buffer showing a list of all defined keys, and their definitions.
 491 The keys are displayed in order of precedence.
 492
 493 The optional argument PREFIX, if non-nil, should be a key sequence;
 494 then we display only bindings that start with that prefix.
 495 The optional argument BUFFER specifies which buffer's bindings
 496 to display (default, the current buffer).  BUFFER can be a buffer
 497 or a buffer name."
 498   (interactive)
 499   (or buffer (setq buffer (current-buffer)))
 500   (help-setup-xref (list #'describe-bindings prefix buffer)
 501                    (called-interactively-p 'interactive))
 502   (with-help-window (help-buffer)
 503     ;; Be aware that `describe-buffer-bindings' puts its output into
 504     ;; the current buffer.
 505     (with-current-buffer (help-buffer)
 506       (describe-buffer-bindings buffer prefix))))
 507
 508 ;; This function used to be in keymap.c.
 509 (defun describe-bindings-internal (&optional menus prefix)
 510   "Show a list of all defined keys, and their definitions.
 511 We put that list in a buffer, and display the buffer.
 512
 513 The optional argument MENUS, if non-nil, says to mention menu bindings.
 514 \(Ordinarily these are omitted from the output.)
 515 The optional argument PREFIX, if non-nil, should be a key sequence;
 516 then we display only bindings that start with that prefix."
 517   (declare (obsolete describe-buffer-bindings "24.4"))
 518   (let ((buf (current-buffer)))
 519     (with-help-window (help-buffer)
 520       ;; Be aware that `describe-buffer-bindings' puts its output into
 521       ;; the current buffer.
 522       (with-current-buffer (help-buffer)
 523         (describe-buffer-bindings buf prefix menus)))))
 524
 525 (defun where-is (definition &optional insert)
 526   "Print message listing key sequences that invoke the command DEFINITION.
 527 Argument is a command definition, usually a symbol with a function definition.
 528 If INSERT (the prefix arg) is non-nil, insert the message in the buffer."
 529   (interactive
 530    (let ((fn (function-called-at-point))
 531          (enable-recursive-minibuffers t)
 532          val)
 533      (setq val (completing-read
 534                 (if fn
 535                     (format "Where is command (default %s): " fn)
 536                   "Where is command: ")
 537                 obarray 'commandp t nil nil
 538                 (and fn (symbol-name fn))))
 539      (list (unless (equal val "") (intern val))
 540            current-prefix-arg)))
 541   (unless definition (error "No command"))
 542   (let ((func (indirect-function definition))
 543         (defs nil)
 544         (standard-output (if insert (current-buffer) standard-output)))
 545     ;; In DEFS, find all symbols that are aliases for DEFINITION.
 546     (mapatoms (lambda (symbol)
 547                 (and (fboundp symbol)
 548                      (not (eq symbol definition))
 549                      (eq func (condition-case ()
 550                                   (indirect-function symbol)
 551                                 (error symbol)))
 552                      (push symbol defs))))
 553     ;; Look at all the symbols--first DEFINITION,
 554     ;; then its aliases.
 555     (dolist (symbol (cons definition defs))
 556       (let* ((remapped (command-remapping symbol))
 557              (keys (where-is-internal
 558                     symbol overriding-local-map nil nil remapped))
 559              (keys (mapconcat 'key-description keys ", "))
 560              string)
 561         (setq string
 562               (if insert
 563                   (if (> (length keys) 0)
 564                       (if remapped
 565                           (format "%s (%s) (remapped from %s)"
 566                                   keys remapped symbol)
 567                         (format "%s (%s)" keys symbol))
 568                     (format "M-x %s RET" symbol))
 569                 (if (> (length keys) 0)
 570                     (if remapped
 571                         (format "%s is remapped to %s which is on %s"
 572                                 symbol remapped keys)
 573                       (format "%s is on %s" symbol keys))
 574                   ;; If this is the command the user asked about,
 575                   ;; and it is not on any key, say so.
 576                   ;; For other symbols, its aliases, say nothing
 577                   ;; about them unless they are on keys.
 578                   (if (eq symbol definition)
 579                       (format "%s is not on any key" symbol)))))
 580         (when string
 581           (unless (eq symbol definition)
 582             (princ ";\n its alias "))
 583           (princ string)))))
 584   nil)
 585
 586 (defun help-key-description (key untranslated)
 587   (let ((string (key-description key)))
 588     (if (or (not untranslated)
 589             (and (eq (aref untranslated 0) ?\e) (not (eq (aref key 0) ?\e))))
 590         string
 591       (let ((otherstring (key-description untranslated)))
 592         (if (equal string otherstring)
 593             string
 594           (format "%s (translated from %s)" string otherstring))))))
 595
 596 (defun describe-key-briefly (&optional key insert untranslated)
 597   "Print the name of the function KEY invokes.  KEY is a string.
 598 If INSERT (the prefix arg) is non-nil, insert the message in the buffer.
 599 If non-nil, UNTRANSLATED is a vector of the untranslated events.
 600 It can also be a number in which case the untranslated events from
 601 the last key hit are used.
 602
 603 If KEY is a menu item or a tool-bar button that is disabled, this command
 604 temporarily enables it to allow getting help on disabled items and buttons."
 605   (interactive
 606    (let ((enable-disabled-menus-and-buttons t)
 607          (cursor-in-echo-area t)
 608          saved-yank-menu)
 609      (unwind-protect
 610          (let (key)
 611            ;; If yank-menu is empty, populate it temporarily, so that
 612            ;; "Select and Paste" menu can generate a complete event.
 613            (when (null (cdr yank-menu))
 614              (setq saved-yank-menu (copy-sequence yank-menu))
 615              (menu-bar-update-yank-menu "(any string)" nil))
 616            (while
 617                (progn
 618                  (setq key (read-key-sequence "Describe the following key, mouse click, or menu item: "))
 619                  (and (vectorp key)
 620                       (consp (aref key 0))
 621                       (symbolp (car (aref key 0)))
 622                       (string-match "\\(mouse\\|down\\|click\\|drag\\)"
 623                                     (symbol-name (car (aref key 0))))
 624                       (not (sit-for (/ double-click-time 1000.0) t)))))
 625            ;; Clear the echo area message (Bug#7014).
 626            (message nil)
 627            ;; If KEY is a down-event, read and discard the
 628            ;; corresponding up-event.  Note that there are also
 629            ;; down-events on scroll bars and mode lines: the actual
 630            ;; event then is in the second element of the vector.
 631            (and (vectorp key)
 632                 (let ((last-idx (1- (length key))))
 633                   (and (eventp (aref key last-idx))
 634                        (memq 'down (event-modifiers (aref key last-idx)))))
 635                 (read-event))
 636            (list
 637             key
 638             (if current-prefix-arg (prefix-numeric-value current-prefix-arg))
 639             1))
 640        ;; Put yank-menu back as it was, if we changed it.
 641        (when saved-yank-menu
 642          (setq yank-menu (copy-sequence saved-yank-menu))
 643          (fset 'yank-menu (cons 'keymap yank-menu))))))
 644   (if (numberp untranslated)
 645       (setq untranslated (this-single-command-raw-keys)))
 646   (let* ((event (if (and (symbolp (aref key 0))
 647                          (> (length key) 1)
 648                          (consp (aref key 1)))
 649                     (aref key 1)
 650                   (aref key 0)))
 651          (modifiers (event-modifiers event))
 652          (standard-output (if insert (current-buffer) standard-output))
 653          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 654                             (memq 'drag modifiers)) " at that spot" ""))
 655          (defn (key-binding key t))
 656          key-desc)
 657     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 658     (if (and (eq defn nil)
 659              (stringp (aref key (1- (length key))))
 660              (eq (key-binding (substring key 0 -1)) 'yank-menu))
 661         (setq defn 'menu-bar-select-yank))
 662     ;; Don't bother user with strings from (e.g.) the select-paste menu.
 663     (if (stringp (aref key (1- (length key))))
 664         (aset key (1- (length key)) "(any string)"))
 665     (if (and (> (length untranslated) 0)
 666              (stringp (aref untranslated (1- (length untranslated)))))
 667         (aset untranslated (1- (length untranslated)) "(any string)"))
 668     ;; Now describe the key, perhaps as changed.
 669     (setq key-desc (help-key-description key untranslated))
 670     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 671         (princ (format "%s%s is undefined" key-desc mouse-msg))
 672       (princ (format "%s%s runs the command %S" key-desc mouse-msg defn)))))
 673
 674 (defun help--key-binding-keymap (key &optional accept-default no-remap position)
 675   "Return a keymap holding a binding for KEY within current keymaps.
 676 The effect of the arguments KEY, ACCEPT-DEFAULT, NO-REMAP and
 677 POSITION is as documented in the function `key-binding'."
 678   (let* ((active-maps (current-active-maps t position))
 679          map found)
 680     ;; We loop over active maps like key-binding does.
 681     (while (and
 682             (not found)
 683             (setq map (pop active-maps)))
 684       (setq found (lookup-key map key accept-default))
 685       (when (integerp found)
 686         ;; The first `found' characters of KEY were found but not the
 687         ;; whole sequence.
 688         (setq found nil)))
 689     (when found
 690       (if (and (symbolp found)
 691                (not no-remap)
 692                (command-remapping found))
 693           ;; The user might want to know in which map the binding is
 694           ;; found, or in which map the remapping is found.  The
 695           ;; default is to show the latter.
 696           (help--key-binding-keymap (vector 'remap found))
 697         map))))
 698
 699 (defun help--binding-locus (key position)
 700   "Describe in which keymap KEY is defined.
 701 Return a symbol pointing to that keymap if one exists ; otherwise
 702 return nil.  The argument POSITION is as documented in the
 703 function `key-binding'."
 704   (let ((map (help--key-binding-keymap key t nil position)))
 705     (when map
 706       (catch 'found
 707         (let ((advertised-syms (nconc
 708                                 (list 'overriding-terminal-local-map
 709                                       'overriding-local-map)
 710                                 (delq nil
 711                                       (mapcar
 712                                        (lambda (mode-and-map)
 713                                          (let ((mode (car mode-and-map)))
 714                                            (when (symbol-value mode)
 715                                              (intern-soft
 716                                               (format "%s-map" mode)))))
 717                                        minor-mode-map-alist))
 718                                 (list 'global-map
 719                                       (intern-soft (format "%s-map" major-mode)))))
 720               found)
 721           ;; Look into these advertised symbols first.
 722           (dolist (sym advertised-syms)
 723             (when (and
 724                    (boundp sym)
 725                    (eq map (symbol-value sym)))
 726               (throw 'found sym)))
 727           ;; Only look in other symbols otherwise.
 728           (mapatoms
 729            (lambda (x)
 730              (when (and (boundp x)
 731                         ;; Avoid let-bound symbols.
 732                         (special-variable-p x)
 733                         (eq (symbol-value x) map))
 734                (throw 'found x))))
 735           nil)))))
 736
 737 (defun describe-key (&optional key untranslated up-event)
 738   "Display documentation of the function invoked by KEY.
 739 KEY can be any kind of a key sequence; it can include keyboard events,
 740 mouse events, and/or menu events.  When calling from a program,
 741 pass KEY as a string or a vector.
 742
 743 If non-nil, UNTRANSLATED is a vector of the corresponding untranslated events.
 744 It can also be a number, in which case the untranslated events from
 745 the last key sequence entered are used.
 746 UP-EVENT is the up-event that was discarded by reading KEY, or nil.
 747
 748 If KEY is a menu item or a tool-bar button that is disabled, this command
 749 temporarily enables it to allow getting help on disabled items and buttons."
 750   (interactive
 751    (let ((enable-disabled-menus-and-buttons t)
 752          (cursor-in-echo-area t)
 753          saved-yank-menu)
 754      (unwind-protect
 755          (let (key)
 756            ;; If yank-menu is empty, populate it temporarily, so that
 757            ;; "Select and Paste" menu can generate a complete event.
 758            (when (null (cdr yank-menu))
 759              (setq saved-yank-menu (copy-sequence yank-menu))
 760              (menu-bar-update-yank-menu "(any string)" nil))
 761            (while
 762                (progn
 763                  (setq key (read-key-sequence "Describe the following key, mouse click, or menu item: "))
 764                  (and (vectorp key)
 765                       (consp (aref key 0))
 766                       (symbolp (car (aref key 0)))
 767                       (string-match "\\(mouse\\|down\\|click\\|drag\\)"
 768                                     (symbol-name (car (aref key 0))))
 769                       (not (sit-for (/ double-click-time 1000.0) t)))))
 770            (list
 771             key
 772             (prefix-numeric-value current-prefix-arg)
 773             ;; If KEY is a down-event, read and include the
 774             ;; corresponding up-event.  Note that there are also
 775             ;; down-events on scroll bars and mode lines: the actual
 776             ;; event then is in the second element of the vector.
 777             (and (vectorp key)
 778                  (let ((last-idx (1- (length key))))
 779                    (and (eventp (aref key last-idx))
 780                         (memq 'down (event-modifiers (aref key last-idx)))))
 781                  (or (and (eventp (aref key 0))
 782                           (memq 'down (event-modifiers (aref key 0)))
 783                           ;; However, for the C-down-mouse-2 popup
 784                           ;; menu, there is no subsequent up-event.  In
 785                           ;; this case, the up-event is the next
 786                           ;; element in the supplied vector.
 787                           (= (length key) 1))
 788                      (and (> (length key) 1)
 789                           (eventp (aref key 1))
 790                           (memq 'down (event-modifiers (aref key 1)))))
 791                  (read-event))))
 792        ;; Put yank-menu back as it was, if we changed it.
 793        (when saved-yank-menu
 794          (setq yank-menu (copy-sequence saved-yank-menu))
 795          (fset 'yank-menu (cons 'keymap yank-menu))))))
 796   (if (numberp untranslated)
 797       (setq untranslated (this-single-command-raw-keys)))
 798   (let* ((event (aref key (if (and (symbolp (aref key 0))
 799                                    (> (length key) 1)
 800                                    (consp (aref key 1)))
 801                               1
 802                             0)))
 803          (modifiers (event-modifiers event))
 804          (mouse-msg (if (or (memq 'click modifiers) (memq 'down modifiers)
 805                             (memq 'drag modifiers)) " at that spot" ""))
 806          (defn (key-binding key t))
 807          key-locus key-locus-up key-locus-up-tricky
 808          defn-up defn-up-tricky ev-type
 809          mouse-1-remapped mouse-1-tricky)
 810
 811     ;; Handle the case where we faked an entry in "Select and Paste" menu.
 812     (when (and (eq defn nil)
 813                (stringp (aref key (1- (length key))))
 814                (eq (key-binding (substring key 0 -1)) 'yank-menu))
 815       (setq defn 'menu-bar-select-yank))
 816     (if (or (null defn) (integerp defn) (equal defn 'undefined))
 817         (message "%s%s is undefined"
 818                  (help-key-description key untranslated) mouse-msg)
 819       (help-setup-xref (list #'describe-function defn)
 820                        (called-interactively-p 'interactive))
 821       ;; Don't bother user with strings from (e.g.) the select-paste menu.
 822       (when (stringp (aref key (1- (length key))))
 823         (aset key (1- (length key)) "(any string)"))
 824       (when (and untranslated
 825                  (stringp (aref untranslated (1- (length untranslated)))))
 826         (aset untranslated (1- (length untranslated))
 827               "(any string)"))
 828       ;; Need to do this before erasing *Help* buffer in case event
 829       ;; is a mouse click in an existing *Help* buffer.
 830       (when up-event
 831         (setq ev-type (event-basic-type up-event))
 832         (let ((sequence (vector up-event)))
 833           (when (and (eq ev-type 'mouse-1)
 834                      mouse-1-click-follows-link
 835                      (not (eq mouse-1-click-follows-link 'double))
 836                      (setq mouse-1-remapped
 837                            (mouse-on-link-p (event-start up-event))))
 838             (setq mouse-1-tricky (and (integerp mouse-1-click-follows-link)
 839                                       (> mouse-1-click-follows-link 0)))
 840             (cond ((stringp mouse-1-remapped)
 841                    (setq sequence mouse-1-remapped))
 842                   ((vectorp mouse-1-remapped)
 843                    (setcar up-event (elt mouse-1-remapped 0)))
 844                   (t (setcar up-event 'mouse-2))))
 845           (setq defn-up (key-binding sequence nil nil (event-start up-event)))
 846           (setq key-locus-up (help--binding-locus sequence (event-start up-event)))
 847           (when mouse-1-tricky
 848             (setq sequence (vector up-event))
 849             (aset sequence 0 'mouse-1)
 850             (setq defn-up-tricky (key-binding sequence nil nil (event-start up-event)))
 851             (setq key-locus-up-tricky (help--binding-locus sequence (event-start up-event))))))
 852       (setq key-locus (help--binding-locus key (event-start event)))
 853       (with-help-window (help-buffer)
 854         (princ (help-key-description key untranslated))
 855         (princ (format "%s runs the command %S%s, which is "
 856                        mouse-msg defn (if key-locus
 857                                           (format " (found in %s)" key-locus)
 858                                         "")))
 859         (describe-function-1 defn)
 860         (when up-event
 861           (unless (or (null defn-up)
 862                       (integerp defn-up)
 863                       (equal defn-up 'undefined))
 864             (princ (format "
 865
 866 ----------------- up-event %s----------------
 867
 868 %s%s%s runs the command %S%s, which is "
 869                            (if mouse-1-tricky "(short click) " "")
 870                            (key-description (vector up-event))
 871                            mouse-msg
 872                            (if mouse-1-remapped
 873                                " is remapped to <mouse-2>, which" "")
 874                            defn-up (if key-locus-up
 875                                        (format " (found in %s)" key-locus-up)
 876                                      "")))
 877             (describe-function-1 defn-up))
 878           (unless (or (null defn-up-tricky)
 879                       (integerp defn-up-tricky)
 880                       (eq defn-up-tricky 'undefined))
 881             (princ (format "
 882
 883 ----------------- up-event (long click) ----------------
 884
 885 Pressing <%S>%s for longer than %d milli-seconds
 886 runs the command %S%s, which is "
 887                            ev-type mouse-msg
 888                            mouse-1-click-follows-link
 889                            defn-up-tricky (if key-locus-up-tricky
 890                                               (format " (found in %s)" key-locus-up-tricky)
 891                                             "")))
 892             (describe-function-1 defn-up-tricky)))))))
 893 \f
 894 (defun describe-mode (&optional buffer)
 895   "Display documentation of current major mode and minor modes.
 896 A brief summary of the minor modes comes first, followed by the
 897 major mode description.  This is followed by detailed
 898 descriptions of the minor modes, each on a separate page.
 899
 900 For this to work correctly for a minor mode, the mode's indicator
 901 variable \(listed in `minor-mode-alist') must also be a function
 902 whose documentation describes the minor mode.
 903
 904 If called from Lisp with a non-nil BUFFER argument, display
 905 documentation for the major and minor modes of that buffer."
 906   (interactive "@")
 907   (unless buffer (setq buffer (current-buffer)))
 908   (help-setup-xref (list #'describe-mode buffer)
 909                    (called-interactively-p 'interactive))
 910   ;; For the sake of help-do-xref and help-xref-go-back,
 911   ;; don't switch buffers before calling `help-buffer'.
 912   (with-help-window (help-buffer)
 913     (with-current-buffer buffer
 914       (let (minor-modes)
 915         ;; Older packages do not register in minor-mode-list but only in
 916         ;; minor-mode-alist.
 917         (dolist (x minor-mode-alist)
 918           (setq x (car x))
 919           (unless (memq x minor-mode-list)
 920             (push x minor-mode-list)))
 921         ;; Find enabled minor mode we will want to mention.
 922         (dolist (mode minor-mode-list)
 923           ;; Document a minor mode if it is listed in minor-mode-alist,
 924           ;; non-nil, and has a function definition.
 925           (let ((fmode (or (get mode :minor-mode-function) mode)))
 926             (and (boundp mode) (symbol-value mode)
 927                  (fboundp fmode)
 928                  (let ((pretty-minor-mode
 929                         (if (string-match "\\(\\(-minor\\)?-mode\\)?\\'"
 930                                           (symbol-name fmode))
 931                             (capitalize
 932                              (substring (symbol-name fmode)
 933                                         0 (match-beginning 0)))
 934                           fmode)))
 935                    (push (list fmode pretty-minor-mode
 936                                (format-mode-line (assq mode minor-mode-alist)))
 937                          minor-modes)))))
 938         (setq minor-modes
 939               (sort minor-modes
 940                     (lambda (a b) (string-lessp (cadr a) (cadr b)))))
 941         (when minor-modes
 942           (princ "Enabled minor modes:\n")
 943           (make-local-variable 'help-button-cache)
 944           (with-current-buffer standard-output
 945             (dolist (mode minor-modes)
 946               (let ((mode-function (nth 0 mode))
 947                     (pretty-minor-mode (nth 1 mode))
 948                     (indicator (nth 2 mode)))
 949                 (save-excursion
 950                   (goto-char (point-max))
 951                   (princ "\n\f\n")
 952                   (push (point-marker) help-button-cache)
 953                   ;; Document the minor modes fully.
 954                   (insert-text-button
 955                    pretty-minor-mode 'type 'help-function
 956                    'help-args (list mode-function)
 957                    'button '(t))
 958                   (princ (format " minor mode (%s):\n"
 959                                  (if (zerop (length indicator))
 960                                      "no indicator"
 961                                    (format "indicator%s"
 962                                            indicator))))
 963                   (princ (documentation mode-function)))
 964                 (insert-button pretty-minor-mode
 965                                'action (car help-button-cache)
 966                                'follow-link t
 967                                'help-echo "mouse-2, RET: show full information")
 968                 (newline)))
 969             (forward-line -1)
 970             (fill-paragraph nil)
 971             (forward-line 1))
 972
 973           (princ "\n(Information about these minor modes follows the major mode info.)\n\n"))
 974         ;; Document the major mode.
 975         (let ((mode mode-name))
 976           (with-current-buffer standard-output
 977             (let ((start (point)))
 978               (insert (format-mode-line mode nil nil buffer))
 979               (add-text-properties start (point) '(face bold)))))
 980         (princ " mode")
 981         (let* ((mode major-mode)
 982                (file-name (find-lisp-object-file-name mode nil)))
 983           (when file-name
 984             (princ (format-message " defined in `%s'"
 985                                    (file-name-nondirectory file-name)))
 986             ;; Make a hyperlink to the library.
 987             (with-current-buffer standard-output
 988               (save-excursion
 989                 (re-search-backward (substitute-command-keys "`\\([^`']+\\)'")
 990                                     nil t)
 991                 (help-xref-button 1 'help-function-def mode file-name)))))
 992         (princ ":\n")
 993         (princ (documentation major-mode)))))
 994   ;; For the sake of IELM and maybe others
 995   nil)
 996
 997
 998 (defun describe-minor-mode (minor-mode)
 999   "Display documentation of a minor mode given as MINOR-MODE.
1000 MINOR-MODE can be a minor mode symbol or a minor mode indicator string
1001 appeared on the mode-line."
1002   (interactive (list (completing-read
1003                       "Minor mode: "
1004                               (nconc
1005                                (describe-minor-mode-completion-table-for-symbol)
1006                                (describe-minor-mode-completion-table-for-indicator)
1007                                ))))
1008   (if (symbolp minor-mode)
1009       (setq minor-mode (symbol-name minor-mode)))
1010   (let ((symbols (describe-minor-mode-completion-table-for-symbol))
1011         (indicators (describe-minor-mode-completion-table-for-indicator)))
1012     (cond
1013      ((member minor-mode symbols)
1014       (describe-minor-mode-from-symbol (intern minor-mode)))
1015      ((member minor-mode indicators)
1016       (describe-minor-mode-from-indicator minor-mode))
1017      (t
1018       (error "No such minor mode: %s" minor-mode)))))
1019
1020 ;; symbol
1021 (defun describe-minor-mode-completion-table-for-symbol ()
1022   ;; In order to list up all minor modes, minor-mode-list
1023   ;; is used here instead of minor-mode-alist.
1024   (delq nil (mapcar 'symbol-name minor-mode-list)))
1025
1026 (defun describe-minor-mode-from-symbol (symbol)
1027   "Display documentation of a minor mode given as a symbol, SYMBOL"
1028   (interactive (list (intern (completing-read
1029                               "Minor mode symbol: "
1030                               (describe-minor-mode-completion-table-for-symbol)))))
1031   (if (fboundp symbol)
1032       (describe-function symbol)
1033     (describe-variable symbol)))
1034
1035 ;; indicator
1036 (defun describe-minor-mode-completion-table-for-indicator ()
1037   (delq nil
1038         (mapcar (lambda (x)
1039                   (let ((i (format-mode-line x)))
1040                     ;; remove first space if existed
1041                     (cond
1042                      ((= 0 (length i))
1043                       nil)
1044                      ((eq (aref i 0) ?\s)
1045                       (substring i 1))
1046                      (t
1047                       i))))
1048                 minor-mode-alist)))
1049
1050 (defun describe-minor-mode-from-indicator (indicator)
1051   "Display documentation of a minor mode specified by INDICATOR.
1052 If you call this function interactively, you can give indicator which
1053 is currently activated with completion."
1054   (interactive (list
1055                 (completing-read
1056                  "Minor mode indicator: "
1057                  (describe-minor-mode-completion-table-for-indicator))))
1058   (let ((minor-mode (lookup-minor-mode-from-indicator indicator)))
1059     (if minor-mode
1060         (describe-minor-mode-from-symbol minor-mode)
1061       (error "Cannot find minor mode for `%s'" indicator))))
1062
1063 (defun lookup-minor-mode-from-indicator (indicator)
1064   "Return a minor mode symbol from its indicator on the mode line."
1065   ;; remove first space if existed
1066   (if (and (< 0 (length indicator))
1067            (eq (aref indicator 0) ?\s))
1068       (setq indicator (substring indicator 1)))
1069   (let ((minor-modes minor-mode-alist)
1070         result)
1071     (while minor-modes
1072       (let* ((minor-mode (car (car minor-modes)))
1073              (anindicator (format-mode-line
1074                            (car (cdr (car minor-modes))))))
1075         ;; remove first space if existed
1076         (if (and (stringp anindicator)
1077                  (> (length anindicator) 0)
1078                  (eq (aref anindicator 0) ?\s))
1079             (setq anindicator (substring anindicator 1)))
1080         (if (equal indicator anindicator)
1081             (setq result minor-mode
1082                   minor-modes nil)
1083           (setq minor-modes (cdr minor-modes)))))
1084     result))
1085 \f
1086 ;;; Automatic resizing of temporary buffers.
1087 (defcustom temp-buffer-max-height
1088   (lambda (buffer)
1089     (if (and (display-graphic-p) (eq (selected-window) (frame-root-window)))
1090         (/ (x-display-pixel-height) (frame-char-height) 2)
1091       (/ (- (frame-height) 2) 2)))
1092   "Maximum height of a window displaying a temporary buffer.
1093 This is effective only when Temp Buffer Resize mode is enabled.
1094 The value is the maximum height (in lines) which
1095 `resize-temp-buffer-window' will give to a window displaying a
1096 temporary buffer.  It can also be a function to be called to
1097 choose the height for such a buffer.  It gets one argument, the
1098 buffer, and should return a positive integer.  At the time the
1099 function is called, the window to be resized is selected."
1100   :type '(choice integer function)
1101   :group 'help
1102   :version "24.3")
1103
1104 (defcustom temp-buffer-max-width
1105   (lambda (buffer)
1106     (if (and (display-graphic-p) (eq (selected-window) (frame-root-window)))
1107         (/ (x-display-pixel-width) (frame-char-width) 2)
1108       (/ (- (frame-width) 2) 2)))
1109   "Maximum width of a window displaying a temporary buffer.
1110 This is effective only when Temp Buffer Resize mode is enabled.
1111 The value is the maximum width (in columns) which
1112 `resize-temp-buffer-window' will give to a window displaying a
1113 temporary buffer.  It can also be a function to be called to
1114 choose the width for such a buffer.  It gets one argument, the
1115 buffer, and should return a positive integer.  At the time the
1116 function is called, the window to be resized is selected."
1117   :type '(choice integer function)
1118   :group 'help
1119   :version "24.4")
1120
1121 (define-minor-mode temp-buffer-resize-mode
1122   "Toggle auto-resizing temporary buffer windows (Temp Buffer Resize Mode).
1123 With a prefix argument ARG, enable Temp Buffer Resize mode if ARG
1124 is positive, and disable it otherwise.  If called from Lisp,
1125 enable the mode if ARG is omitted or nil.
1126
1127 When Temp Buffer Resize mode is enabled, the windows in which we
1128 show a temporary buffer are automatically resized in height to
1129 fit the buffer's contents, but never more than
1130 `temp-buffer-max-height' nor less than `window-min-height'.
1131
1132 A window is resized only if it has been specially created for the
1133 buffer.  Windows that have shown another buffer before are not
1134 resized.  A frame is resized only if `fit-frame-to-buffer' is
1135 non-nil.
1136
1137 This mode is used by `help', `apropos' and `completion' buffers,
1138 and some others."
1139   :global t :group 'help
1140   (if temp-buffer-resize-mode
1141       ;; `help-make-xrefs' may add a `back' button and thus increase the
1142       ;; text size, so `resize-temp-buffer-window' must be run *after* it.
1143       (add-hook 'temp-buffer-show-hook 'resize-temp-buffer-window 'append)
1144     (remove-hook 'temp-buffer-show-hook 'resize-temp-buffer-window)))
1145
1146 (defun resize-temp-buffer-window (&optional window)
1147   "Resize WINDOW to fit its contents.
1148 WINDOW must be a live window and defaults to the selected one.
1149 Do not resize if WINDOW was not created by `display-buffer'.
1150
1151 If WINDOW is part of a vertical combination, restrain its new
1152 size by `temp-buffer-max-height' and do not resize if its minimum
1153 accessible position is scrolled out of view.  If WINDOW is part
1154 of a horizontal combination, restrain its new size by
1155 `temp-buffer-max-width'.  In both cases, the value of the option
1156 `fit-window-to-buffer-horizontally' can inhibit resizing.
1157
1158 If WINDOW is the root window of its frame, resize the frame
1159 provided `fit-frame-to-buffer' is non-nil.
1160
1161 This function may call `preserve-window-size' to preserve the
1162 size of WINDOW."
1163   (setq window (window-normalize-window window t))
1164   (let ((height (if (functionp temp-buffer-max-height)
1165                     (with-selected-window window
1166                       (funcall temp-buffer-max-height (window-buffer)))
1167                   temp-buffer-max-height))
1168         (width (if (functionp temp-buffer-max-width)
1169                    (with-selected-window window
1170                      (funcall temp-buffer-max-width (window-buffer)))
1171                  temp-buffer-max-width))
1172         (quit-cadr (cadr (window-parameter window 'quit-restore))))
1173     ;; Resize WINDOW iff it was made by `display-buffer'.
1174     (when (or (and (eq quit-cadr 'window)
1175                    (or (and (window-combined-p window)
1176                             (not (eq fit-window-to-buffer-horizontally
1177                                      'only))
1178                             (pos-visible-in-window-p (point-min) window))
1179                        (and (window-combined-p window t)
1180                             fit-window-to-buffer-horizontally)))
1181               (and (eq quit-cadr 'frame)
1182                    fit-frame-to-buffer
1183                    (eq window (frame-root-window window))))
1184         (fit-window-to-buffer window height nil width nil t))))
1185
1186 ;;; Help windows.
1187 (defcustom help-window-select nil
1188   "Non-nil means select help window for viewing.
1189 Choices are:
1190
1191  never (nil) Select help window only if there is no other window
1192              on its frame.
1193
1194  other       Select help window if and only if it appears on the
1195              previously selected frame, that frame contains at
1196              least two other windows and the help window is
1197              either new or showed a different buffer before.
1198
1199  always (t)  Always select the help window.
1200
1201 If this option is non-nil and the help window appears on another
1202 frame, then give that frame input focus too.  Note also that if
1203 the help window appears on another frame, it may get selected and
1204 its frame get input focus even if this option is nil.
1205
1206 This option has effect if and only if the help window was created
1207 by `with-help-window'."
1208   :type '(choice (const :tag "never (nil)" nil)
1209                  (const :tag "other" other)
1210                  (const :tag "always (t)" t))
1211   :group 'help
1212   :version "23.1")
1213
1214 (defcustom help-enable-auto-load t
1215   "Whether Help commands can perform autoloading.
1216 If non-nil, whenever \\[describe-function] is called for an
1217 autoloaded function whose docstring contains any key substitution
1218 construct (see `substitute-command-keys'), the library is loaded,
1219 so that the documentation can show the right key bindings."
1220   :type 'boolean
1221   :group 'help
1222   :version "24.3")
1223
1224 (defun help-window-display-message (quit-part window &optional scroll)
1225   "Display message telling how to quit and scroll help window.
1226 QUIT-PART is a string telling how to quit the help window WINDOW.
1227 Optional argument SCROLL non-nil means tell how to scroll WINDOW.
1228 SCROLL equal `other' means tell how to scroll the \"other\"
1229 window."
1230   (let ((scroll-part
1231          (cond
1232           ;; If we don't have QUIT-PART we probably reuse a window
1233           ;; showing the same buffer so we don't show any message.
1234           ((not quit-part) nil)
1235           ((pos-visible-in-window-p
1236             (with-current-buffer (window-buffer window)
1237               (point-max)) window t)
1238            ;; Buffer end is at least partially visible, no need to talk
1239            ;; about scrolling.
1240            ".")
1241           ((eq scroll 'other)
1242            ", \\[scroll-other-window] to scroll help.")
1243           (scroll ", \\[scroll-up] to scroll help."))))
1244     (message "%s"
1245      (substitute-command-keys (concat quit-part scroll-part)))))
1246
1247 (defun help-window-setup (window &optional value)
1248   "Set up help window WINDOW for `with-help-window'.
1249 WINDOW is the window used for displaying the help buffer.
1250 Return VALUE."
1251   (let* ((help-buffer (when (window-live-p window)
1252                         (window-buffer window)))
1253          (help-setup (when (window-live-p window)
1254                        (car (window-parameter window 'quit-restore))))
1255          (frame (window-frame window)))
1256
1257     (when help-buffer
1258       ;; Handle `help-window-point-marker'.
1259       (when (eq (marker-buffer help-window-point-marker) help-buffer)
1260         (set-window-point window help-window-point-marker)
1261         ;; Reset `help-window-point-marker'.
1262         (set-marker help-window-point-marker nil))
1263
1264       ;; If the help window appears on another frame, select it if
1265       ;; `help-window-select' is non-nil and give that frame input focus
1266       ;; too.  See also Bug#19012.
1267       (when (and help-window-select
1268                  (frame-live-p help-window-old-frame)
1269                  (not (eq frame help-window-old-frame)))
1270         (select-window window)
1271         (select-frame-set-input-focus frame))
1272
1273       (cond
1274        ((or (eq window (selected-window))
1275             ;; If the help window is on the selected frame, select
1276             ;; it if `help-window-select' is t or `help-window-select'
1277             ;; is 'other, the frame contains at least three windows, and
1278             ;; the help window did show another buffer before.  See also
1279             ;; Bug#11039.
1280             (and (eq frame (selected-frame))
1281                  (or (eq help-window-select t)
1282                      (and (eq help-window-select 'other)
1283                           (> (length (window-list nil 'no-mini)) 2)
1284                           (not (eq help-setup 'same))))
1285                  (select-window window)))
1286         ;; The help window is or gets selected ...
1287         (help-window-display-message
1288          (cond
1289           ((eq help-setup 'window)
1290            ;; ... and is new, ...
1291            "Type \"q\" to delete help window")
1292           ((eq help-setup 'frame)
1293            ;; ... on a new frame, ...
1294            "Type \"q\" to quit the help frame")
1295           ((eq help-setup 'other)
1296            ;; ... or displayed some other buffer before.
1297            "Type \"q\" to restore previous buffer"))
1298          window t))
1299        ((and (eq (window-frame window) help-window-old-frame)
1300              (= (length (window-list nil 'no-mini)) 2))
1301         ;; There are two windows on the help window's frame and the
1302         ;; other one is the selected one.
1303         (help-window-display-message
1304          (cond
1305           ((eq help-setup 'window)
1306            "Type \\[delete-other-windows] to delete the help window")
1307           ((eq help-setup 'other)
1308            "Type \"q\" in help window to restore its previous buffer"))
1309          window 'other))
1310        (t
1311         ;; The help window is not selected ...
1312         (help-window-display-message
1313          (cond
1314           ((eq help-setup 'window)
1315            ;; ... and is new, ...
1316            "Type \"q\" in help window to delete it")
1317           ((eq help-setup 'other)
1318            ;; ... or displayed some other buffer before.
1319            "Type \"q\" in help window to restore previous buffer"))
1320          window))))
1321     ;; Return VALUE.
1322     value))
1323
1324 ;; `with-help-window' is a wrapper for `with-temp-buffer-window'
1325 ;; providing the following additional twists:
1326
1327 ;; (1) It puts the buffer in `help-mode' (via `help-mode-setup') and
1328 ;;     adds cross references (via `help-mode-finish').
1329
1330 ;; (2) It issues a message telling how to scroll and quit the help
1331 ;;     window (via `help-window-setup').
1332
1333 ;; (3) An option (customizable via `help-window-select') to select the
1334 ;;     help window automatically.
1335
1336 ;; (4) A marker (`help-window-point-marker') to move point in the help
1337 ;;     window to an arbitrary buffer position.
1338 (defmacro with-help-window (buffer-name &rest body)
1339   "Display buffer named BUFFER-NAME in a help window.
1340 Evaluate the forms in BODY with standard output bound to a buffer
1341 called BUFFER-NAME (creating it if it does not exist), put that
1342 buffer in `help-mode', display the buffer in a window (see
1343 `with-temp-buffer-window' for details) and issue a message how to
1344 deal with that \"help\" window when it's no more needed.  Select
1345 the help window if the current value of the user option
1346 `help-window-select' says so.  Return last value in BODY."
1347   (declare (indent 1) (debug t))
1348   `(progn
1349      ;; Make `help-window-point-marker' point nowhere.  The only place
1350      ;; where this should be set to a buffer position is within BODY.
1351      (set-marker help-window-point-marker nil)
1352      (let ((temp-buffer-window-setup-hook
1353             (cons 'help-mode-setup temp-buffer-window-setup-hook))
1354            (temp-buffer-window-show-hook
1355             (cons 'help-mode-finish temp-buffer-window-show-hook)))
1356        (setq help-window-old-frame (selected-frame))
1357        (with-temp-buffer-window
1358         ,buffer-name nil 'help-window-setup (progn ,@body)))))
1359
1360 ;; Called from C, on encountering `help-char' when reading a char.
1361 ;; Don't print to *Help*; that would clobber Help history.
1362 (defun help-form-show ()
1363   "Display the output of a non-nil `help-form'."
1364   (let ((msg (eval help-form)))
1365     (if (stringp msg)
1366         (with-output-to-temp-buffer " *Char Help*"
1367           (princ msg)))))
1368
1369 \f
1370 (defun help--docstring-quote (string)
1371   "Return a doc string that represents STRING.
1372 The result, when formatted by `substitute-command-keys', should equal STRING."
1373   (replace-regexp-in-string "['\\`‘’]" "\\\\=\\&" string))
1374
1375 ;; The following functions used to be in help-fns.el, which is not preloaded.
1376 ;; But for various reasons, they are more widely needed, so they were
1377 ;; moved to this file, which is preloaded.  http://debbugs.gnu.org/17001
1378
1379 (defun help-split-fundoc (docstring def)
1380   "Split a function DOCSTRING into the actual doc and the usage info.
1381 Return (USAGE . DOC) or nil if there's no usage info, where USAGE info
1382 is a string describing the argument list of DEF, such as
1383 \"(apply FUNCTION &rest ARGUMENTS)\".
1384 DEF is the function whose usage we're looking for in DOCSTRING."
1385   ;; Functions can get the calling sequence at the end of the doc string.
1386   ;; In cases where `function' has been fset to a subr we can't search for
1387   ;; function's name in the doc string so we use `fn' as the anonymous
1388   ;; function name instead.
1389   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
1390     (let ((doc (unless (zerop (match-beginning 0))
1391                  (substring docstring 0 (match-beginning 0))))
1392           (usage-tail (match-string 1 docstring)))
1393       (cons (format "(%s%s"
1394                     ;; Replace `fn' with the actual function name.
1395                     (if (symbolp def)
1396                         (help--docstring-quote (format "%S" def))
1397                       'anonymous)
1398                     usage-tail)
1399             doc))))
1400
1401 (defun help-add-fundoc-usage (docstring arglist)
1402   "Add the usage info to DOCSTRING.
1403 If DOCSTRING already has a usage info, then just return it unchanged.
1404 The usage info is built from ARGLIST.  DOCSTRING can be nil.
1405 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
1406   (unless (stringp docstring) (setq docstring ""))
1407   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring)
1408           (eq arglist t))
1409       docstring
1410     (concat docstring
1411             (if (string-match "\n?\n\\'" docstring)
1412                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
1413               "\n\n")
1414             (if (stringp arglist)
1415                 (if (string-match "\\`[^ ]+\\(.*\\))\\'" arglist)
1416                     (concat "(fn" (match-string 1 arglist) ")")
1417                   (error "Unrecognized usage format"))
1418               (help--make-usage-docstring 'fn arglist)))))
1419
1420 (defun help-function-arglist (def &optional preserve-names)
1421   "Return a formal argument list for the function DEF.
1422 IF PRESERVE-NAMES is non-nil, return a formal arglist that uses
1423 the same names as used in the original source code, when possible."
1424   ;; Handle symbols aliased to other symbols.
1425   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
1426   ;; If definition is a macro, find the function inside it.
1427   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
1428   (cond
1429    ((and (byte-code-function-p def) (listp (aref def 0))) (aref def 0))
1430    ((eq (car-safe def) 'lambda) (nth 1 def))
1431    ((eq (car-safe def) 'closure) (nth 2 def))
1432    ((or (and (byte-code-function-p def) (integerp (aref def 0)))
1433         (subrp def))
1434     (or (when preserve-names
1435           (let* ((doc (condition-case nil (documentation def) (error nil)))
1436                  (docargs (if doc (car (help-split-fundoc doc nil))))
1437                  (arglist (if docargs
1438                               (cdar (read-from-string (downcase docargs)))))
1439                  (valid t))
1440             ;; Check validity.
1441             (dolist (arg arglist)
1442               (unless (and (symbolp arg)
1443                            (let ((name (symbol-name arg)))
1444                              (if (eq (aref name 0) ?&)
1445                                  (memq arg '(&rest &optional))
1446                                (not (string-match "\\." name)))))
1447                 (setq valid nil)))
1448             (when valid arglist)))
1449         (let* ((args-desc (if (not (subrp def))
1450                               (aref def 0)
1451                             (let ((a (subr-arity def)))
1452                               (logior (car a)
1453                                       (if (numberp (cdr a))
1454                                           (lsh (cdr a) 8)
1455                                         (lsh 1 7))))))
1456                (max (lsh args-desc -8))
1457                (min (logand args-desc 127))
1458                (rest (logand args-desc 128))
1459                (arglist ()))
1460           (dotimes (i min)
1461             (push (intern (concat "arg" (number-to-string (1+ i)))) arglist))
1462           (when (> max min)
1463             (push '&optional arglist)
1464             (dotimes (i (- max min))
1465               (push (intern (concat "arg" (number-to-string (+ 1 i min))))
1466                     arglist)))
1467           (unless (zerop rest) (push '&rest arglist) (push 'rest arglist))
1468           (nreverse arglist))))
1469    ((and (autoloadp def) (not (eq (nth 4 def) 'keymap)))
1470     "[Arg list not available until function definition is loaded.]")
1471    (t t)))
1472
1473 (defun help--make-usage (function arglist)
1474   (cons (if (symbolp function) function 'anonymous)
1475         (mapcar (lambda (arg)
1476                   (if (not (symbolp arg)) arg
1477                     (let ((name (symbol-name arg)))
1478                       (cond
1479                        ((string-match "\\`&" name) arg)
1480                        ((string-match "\\`_." name)
1481                         (intern (upcase (substring name 1))))
1482                        (t (intern (upcase name)))))))
1483                 arglist)))
1484
1485 (define-obsolete-function-alias 'help-make-usage 'help--make-usage "25.1")
1486
1487 (defun help--make-usage-docstring (fn arglist)
1488   (let ((print-escape-newlines t))
1489     (help--docstring-quote (format "%S" (help--make-usage fn arglist)))))
1490
1491 \f
1492 (provide 'help)
1493
1494 ;;; help.el ends here