lisp/hi-lock.el

   1 ;;; hi-lock.el --- minor mode for interactive automatic highlighting
   2
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005 Free Software Foundation, Inc.
   5
   6 ;; Author: David M. Koppelman, koppel@ee.lsu.edu
   7 ;; Keywords: faces, minor-mode, matching, display
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;;  With the hi-lock commands text matching interactively entered
  29 ;;  regexp's can be highlighted.  For example, `M-x highlight-regexp
  30 ;;  RET clearly RET RET' will highlight all occurrences of `clearly'
  31 ;;  using a yellow background face.  New occurrences of `clearly' will
  32 ;;  be highlighted as they are typed.  `M-x unhighlight-regexp RET'
  33 ;;  will remove the highlighting.  Any existing face can be used for
  34 ;;  highlighting and a set of appropriate faces is provided.  The
  35 ;;  regexps can be written into the current buffer in a form that will
  36 ;;  be recognized the next time the corresponding file is read.
  37 ;;
  38 ;;  Applications:
  39 ;;
  40 ;;    In program source code highlight a variable to quickly see all
  41 ;;    places it is modified or referenced:
  42 ;;    M-x highlight-regexp ground_contact_switches_closed RET RET
  43 ;;
  44 ;;    In a shell or other buffer that is showing lots of program
  45 ;;    output, highlight the parts of the output you're interested in:
  46 ;;    M-x highlight-regexp Total execution time [0-9]+ RET hi-blue-b RET
  47 ;;
  48 ;;    In buffers displaying tables, highlight the lines you're interested in:
  49 ;;    M-x highlight-lines-matching-regexp January 2000 RET hi-black-b RET
  50 ;;
  51 ;;    When writing text, highlight personal cliches.  This can be
  52 ;;    amusing.
  53 ;;    M-x highlight-phrase as can be seen RET RET
  54 ;;
  55 ;;  Setup:
  56 ;;
  57 ;;    Put the following code in your .emacs file.  This turns on
  58 ;;    hi-lock mode and adds a "Regexp Highlighting" entry
  59 ;;    to the edit menu.
  60 ;;
  61 ;;    (hi-lock-mode 1)
  62 ;;
  63 ;;    You might also want to bind the hi-lock commands to more
  64 ;;    finger-friendly sequences:
  65
  66 ;;    (define-key hi-lock-map "\C-z\C-h" 'highlight-lines-matching-regexp)
  67 ;;    (define-key hi-lock-map "\C-zi" 'hi-lock-find-patterns)
  68 ;;    (define-key hi-lock-map "\C-zh" 'highlight-regexp)
  69 ;;    (define-key hi-lock-map "\C-zp" 'highlight-phrase)
  70 ;;    (define-key hi-lock-map "\C-zr" 'unhighlight-regexp)
  71 ;;    (define-key hi-lock-map "\C-zb" 'hi-lock-write-interactive-patterns))
  72
  73 ;;    See the documentation for hi-lock-mode `C-h f hi-lock-mode' for
  74 ;;    additional instructions.
  75
  76 ;; Sample file patterns:
  77
  78 ; Hi-lock: (("^;;; .*" (0 (quote hi-black-hb) t)))
  79 ; Hi-lock: ( ("make-variable-buffer-\\(local\\)" (0 font-lock-keyword-face)(1 'italic append)))))
  80 ; Hi-lock: end
  81
  82 ;;; Code:
  83
  84 (eval-and-compile
  85   (require 'font-lock))
  86
  87 (defgroup hi-lock-interactive-text-highlighting nil
  88   "Interactively add and remove font-lock patterns for highlighting text."
  89   :group 'faces)
  90
  91 ;;;###autoload
  92 (defcustom hi-lock-mode nil
  93   "Toggle hi-lock, for interactively adding font-lock text-highlighting patterns."
  94   :set (lambda (symbol value)
  95          (hi-lock-mode (or value 0)))
  96   :initialize 'custom-initialize-default
  97   :type 'boolean
  98   :group 'hi-lock-interactive-text-highlighting
  99   :require 'hi-lock)
 100
 101 (defcustom hi-lock-file-patterns-range 10000
 102   "Limit of search in a buffer for hi-lock patterns.
 103 When a file is visited and hi-lock mode is on patterns starting
 104 up to this limit are added to font-lock's patterns.  See documentation
 105 of functions `hi-lock-mode' and `hi-lock-find-patterns'."
 106   :type 'integer
 107   :group 'hi-lock-interactive-text-highlighting)
 108
 109 (defcustom hi-lock-exclude-modes
 110   '(rmail-mode mime/viewer-mode gnus-article-mode)
 111   "List of major modes in which hi-lock will not run.
 112 For security reasons since font lock patterns can specify function
 113 calls."
 114   :type '(repeat symbol)
 115   :group 'hi-lock-interactive-text-highlighting)
 116
 117
 118 (defgroup hi-lock-faces nil
 119   "Faces for hi-lock."
 120   :group 'hi-lock-interactive-text-highlighting)
 121
 122 (defface hi-yellow
 123   '((((min-colors 88) (background dark))
 124      (:background "yellow1" :foreground "black"))
 125     (((background dark)) (:background "yellow" :foreground "black"))
 126     (((min-colors 88)) (:background "yellow1"))
 127     (t (:background "yellow")))
 128   "Default face for hi-lock mode."
 129   :group 'hi-lock-faces)
 130
 131 (defface hi-pink
 132   '((((background dark)) (:background "pink" :foreground "black"))
 133     (t (:background "pink")))
 134   "Face for hi-lock mode."
 135   :group 'hi-lock-faces)
 136
 137 (defface hi-green
 138   '((((min-colors 88) (background dark))
 139      (:background "green1" :foreground "black"))
 140     (((background dark)) (:background "green" :foreground "black"))
 141     (((min-colors 88)) (:background "green1"))
 142     (t (:background "green")))
 143   "Face for hi-lock mode."
 144   :group 'hi-lock-faces)
 145
 146 (defface hi-blue
 147   '((((background dark)) (:background "light blue" :foreground "black"))
 148     (t (:background "light blue")))
 149   "Face for hi-lock mode."
 150   :group 'hi-lock-faces)
 151
 152 (defface hi-black-b
 153   '((t (:weight bold)))
 154   "Face for hi-lock mode."
 155   :group 'hi-lock-faces)
 156
 157 (defface hi-blue-b
 158   '((((min-colors 88)) (:weight bold :foreground "blue1"))
 159     (t (:weight bold :foreground "blue")))
 160   "Face for hi-lock mode."
 161   :group 'hi-lock-faces)
 162
 163 (defface hi-green-b
 164   '((((min-colors 88)) (:weight bold :foreground "green1"))
 165     (t (:weight bold :foreground "green")))
 166   "Face for hi-lock mode."
 167   :group 'hi-lock-faces)
 168
 169 (defface hi-red-b
 170   '((((min-colors 88)) (:weight bold :foreground "red1"))
 171     (t (:weight bold :foreground "red")))
 172   "Face for hi-lock mode."
 173   :group 'hi-lock-faces)
 174
 175 (defface hi-black-hb
 176   '((t (:weight bold :height 1.67 :inherit variable-pitch)))
 177   "Face for hi-lock mode."
 178   :group 'hi-lock-faces)
 179
 180 (defvar hi-lock-file-patterns nil
 181   "Patterns found in file for hi-lock.  Should not be changed.")
 182
 183 (defvar hi-lock-interactive-patterns nil
 184   "Patterns provided to hi-lock by user.  Should not be changed.")
 185
 186 (defvar hi-lock-face-history
 187   (list "hi-yellow" "hi-pink" "hi-green" "hi-blue" "hi-black-b"
 188         "hi-blue-b" "hi-red-b" "hi-green-b" "hi-black-hb")
 189       "History list of faces for hi-lock interactive functions.")
 190
 191 ;(dolist (f hi-lock-face-history) (unless (facep f) (error "%s not a face" f)))
 192
 193 (defvar hi-lock-regexp-history nil
 194   "History of regexps used for interactive fontification.")
 195
 196 (defvar hi-lock-file-patterns-prefix "Hi-lock"
 197   "Regexp for finding hi-lock patterns at top of file.")
 198
 199 (make-variable-buffer-local 'hi-lock-interactive-patterns)
 200 (put 'hi-lock-interactive-patterns 'permanent-local t)
 201 (make-variable-buffer-local 'hi-lock-regexp-history)
 202 (put 'hi-lock-regexp-history 'permanent-local t)
 203 (make-variable-buffer-local 'hi-lock-file-patterns)
 204 (put 'hi-lock-file-patterns 'permanent-local t)
 205
 206 (defvar hi-lock-menu (make-sparse-keymap "Hi Lock")
 207   "Menu for hi-lock mode.")
 208
 209 (define-key-after hi-lock-menu [highlight-regexp]
 210   '(menu-item "Highlight Regexp..." highlight-regexp
 211               :help "Highlight text matching PATTERN (a regexp)."))
 212
 213 (define-key-after hi-lock-menu [highlight-phrase]
 214   '(menu-item "Highlight Phrase..." highlight-phrase
 215               :help "Highlight text matching PATTERN (a regexp processed to match phrases)."))
 216
 217 (define-key-after hi-lock-menu [highlight-lines-matching-regexp]
 218   '(menu-item "Highlight Lines..." highlight-lines-matching-regexp
 219               :help "Highlight lines containing match of PATTERN (a regexp).."))
 220
 221 (define-key-after hi-lock-menu [unhighlight-regexp]
 222   '(menu-item "Remove Highlighting..." unhighlight-regexp
 223               :help "Remove previously entered highlighting pattern."
 224               :enable hi-lock-interactive-patterns))
 225
 226 (define-key-after hi-lock-menu [hi-lock-write-interactive-patterns]
 227   '(menu-item "Patterns to Buffer" hi-lock-write-interactive-patterns
 228               :help "Insert interactively added REGEXPs into buffer at point."
 229               :enable hi-lock-interactive-patterns))
 230
 231 (define-key-after hi-lock-menu [hi-lock-find-patterns]
 232   '(menu-item "Patterns from Buffer" hi-lock-find-patterns
 233               :help "Use patterns (if any) near top of buffer."))
 234
 235 (defvar hi-lock-map (make-sparse-keymap "Hi Lock")
 236   "Key map for hi-lock.")
 237
 238 (define-key hi-lock-map "\C-xwi" 'hi-lock-find-patterns)
 239 (define-key hi-lock-map "\C-xwl" 'highlight-lines-matching-regexp)
 240 (define-key hi-lock-map "\C-xwp" 'highlight-phrase)
 241 (define-key hi-lock-map "\C-xwh" 'highlight-regexp)
 242 (define-key hi-lock-map "\C-xwr" 'unhighlight-regexp)
 243 (define-key hi-lock-map "\C-xwb" 'hi-lock-write-interactive-patterns)
 244
 245 (unless (assq 'hi-lock-mode minor-mode-map-alist)
 246   (setq minor-mode-map-alist (cons (cons 'hi-lock-mode hi-lock-map)
 247                                    minor-mode-map-alist)))
 248
 249 (unless (assq 'hi-lock-mode minor-mode-alist)
 250   (setq minor-mode-alist (cons '(hi-lock-mode " H") minor-mode-alist)))
 251
 252
 253 ;; Visible Functions
 254
 255
 256 ;;;###autoload
 257 (defun hi-lock-mode (&optional arg)
 258   "Toggle minor mode for interactively adding font-lock highlighting patterns.
 259
 260 If ARG positive turn hi-lock on.  Issuing a hi-lock command will also
 261 turn hi-lock on.  When hi-lock is turned on, a \"Regexp Highlighting\"
 262 submenu is added to the \"Edit\" menu.  The commands in the submenu,
 263 which can be called interactively, are:
 264
 265 \\[highlight-regexp] REGEXP FACE
 266   Highlight matches of pattern REGEXP in current buffer with FACE.
 267
 268 \\[highlight-phrase] PHRASE FACE
 269   Highlight matches of phrase PHRASE in current buffer with FACE.
 270   (PHRASE can be any REGEXP, but spaces will be replaced by matches
 271   to whitespace and initial lower-case letters will become case insensitive.)
 272
 273 \\[highlight-lines-matching-regexp] REGEXP FACE
 274   Highlight lines containing matches of REGEXP in current buffer with FACE.
 275
 276 \\[unhighlight-regexp] REGEXP
 277   Remove highlighting on matches of REGEXP in current buffer.
 278
 279 \\[hi-lock-write-interactive-patterns]
 280   Write active REGEXPs into buffer as comments (if possible). They will
 281   be read the next time file is loaded or when the \\[hi-lock-find-patterns] command
 282   is issued.  The inserted regexps are in the form of font lock keywords.
 283   (See `font-lock-keywords') They may be edited and re-loaded with \\[hi-lock-find-patterns],
 284   any valid `font-lock-keywords' form is acceptable.
 285
 286 \\[hi-lock-find-patterns]
 287   Re-read patterns stored in buffer (in the format produced by \\[hi-lock-write-interactive-patterns]).
 288
 289 When hi-lock is started and if the mode is not excluded, the
 290 beginning of the buffer is searched for lines of the form:
 291   Hi-lock: FOO
 292 where FOO is a list of patterns. These are added to the font lock keywords
 293 already present.  The patterns must start before position (number
 294 of characters into buffer) `hi-lock-file-patterns-range'.  Patterns
 295 will be read until
 296  Hi-lock: end
 297 is found. A mode is excluded if it's in the list `hi-lock-exclude-modes'."
 298   (interactive)
 299   (let ((hi-lock-mode-prev hi-lock-mode))
 300     (setq hi-lock-mode
 301           (if (null arg) (not hi-lock-mode)
 302             (> (prefix-numeric-value arg) 0)))
 303     ;; Turned on.
 304     (when (and (not hi-lock-mode-prev) hi-lock-mode)
 305       (add-hook 'find-file-hook 'hi-lock-find-file-hook)
 306       (add-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook)
 307       (when (eq nil font-lock-defaults)
 308         (setq font-lock-defaults '(nil)))
 309       (unless font-lock-mode
 310         (font-lock-mode 1))
 311       (define-key-after menu-bar-edit-menu [hi-lock]
 312         (cons "Regexp Highlighting" hi-lock-menu))
 313       (dolist (buffer (buffer-list))
 314         (with-current-buffer buffer (hi-lock-find-patterns))))
 315     ;; Turned off.
 316     (when (and hi-lock-mode-prev (not hi-lock-mode))
 317       (dolist (buffer (buffer-list))
 318         (with-current-buffer buffer
 319           (when (or hi-lock-interactive-patterns hi-lock-file-patterns)
 320             (font-lock-remove-keywords nil hi-lock-interactive-patterns)
 321             (font-lock-remove-keywords nil hi-lock-file-patterns)
 322             (setq hi-lock-interactive-patterns nil
 323                   hi-lock-file-patterns nil)
 324             (when font-lock-mode (hi-lock-refontify)))))
 325       (define-key-after menu-bar-edit-menu [hi-lock] nil)
 326       (remove-hook 'find-file-hook 'hi-lock-find-file-hook)
 327       (remove-hook 'font-lock-mode-hook 'hi-lock-font-lock-hook))))
 328
 329
 330 ;;;###autoload
 331 (defalias 'highlight-lines-matching-regexp 'hi-lock-line-face-buffer)
 332 ;;;###autoload
 333 (defun hi-lock-line-face-buffer (regexp &optional face)
 334   "Set face of all lines containing a match of REGEXP to FACE.
 335
 336 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 337 list maintained for regexps, global history maintained for faces.
 338 \\<minibuffer-local-map>Use \\[next-history-element] and \\[previous-history-element] to retrieve next or previous history item.
 339 \(See info node `Minibuffer History')"
 340   (interactive
 341    (list
 342     (hi-lock-regexp-okay
 343      (read-from-minibuffer "Regexp to highlight line: "
 344                            (cons (or (car hi-lock-regexp-history) "") 1 )
 345                            nil nil 'hi-lock-regexp-history))
 346     (hi-lock-read-face-name)))
 347   (unless hi-lock-mode (hi-lock-mode))
 348   (or (facep face) (setq face 'rwl-yellow))
 349   (hi-lock-set-pattern
 350    ;; The \\(?:...\\) grouping construct ensures that a leading ^, +, * or ?
 351    ;; or a trailing $ in REGEXP will be interpreted correctly.
 352    (list (concat "^.*\\(?:" regexp "\\).*$") (list 0 (list 'quote face) t))))
 353
 354
 355 ;;;###autoload
 356 (defalias 'highlight-regexp 'hi-lock-face-buffer)
 357 ;;;###autoload
 358 (defun hi-lock-face-buffer (regexp &optional face)
 359   "Set face of each match of REGEXP to FACE.
 360
 361 Interactively, prompt for REGEXP then FACE.  Buffer-local history
 362 list maintained for regexps, global history maintained for faces.
 363 \\<minibuffer-local-map>Use \\[next-history-element] and \\[previous-history-element] to retrieve next or previous history item.
 364 \(See info node `Minibuffer History')"
 365   (interactive
 366    (list
 367     (hi-lock-regexp-okay
 368      (read-from-minibuffer "Regexp to highlight: "
 369                            (cons (or (car hi-lock-regexp-history) "") 1 )
 370                            nil nil 'hi-lock-regexp-history))
 371     (hi-lock-read-face-name)))
 372   (or (facep face) (setq face 'rwl-yellow))
 373   (unless hi-lock-mode (hi-lock-mode))
 374   (hi-lock-set-pattern (list regexp (list 0 (list 'quote face) t))))
 375
 376 ;;;###autoload
 377 (defalias 'highlight-phrase 'hi-lock-face-phrase-buffer)
 378 ;;;###autoload
 379 (defun hi-lock-face-phrase-buffer (regexp &optional face)
 380   "Set face of each match of phrase REGEXP to FACE.
 381
 382 Whitespace in REGEXP converted to arbitrary whitespace and initial
 383 lower-case letters made case insensitive."
 384   (interactive
 385    (list
 386     (hi-lock-regexp-okay
 387      (hi-lock-process-phrase
 388       (read-from-minibuffer "Phrase to highlight: "
 389                             (cons (or (car hi-lock-regexp-history) "") 1 )
 390                             nil nil 'hi-lock-regexp-history)))
 391     (hi-lock-read-face-name)))
 392   (or (facep face) (setq face 'rwl-yellow))
 393   (unless hi-lock-mode (hi-lock-mode))
 394   (hi-lock-set-pattern (list regexp (list 0 (list 'quote face) t))))
 395
 396 ;;;###autoload
 397 (defalias 'unhighlight-regexp 'hi-lock-unface-buffer)
 398 ;;;###autoload
 399 (defun hi-lock-unface-buffer (regexp)
 400   "Remove highlighting of each match to REGEXP set by hi-lock.
 401
 402 Interactively, prompt for REGEXP.  Buffer-local history of inserted
 403 regexp's maintained.  Will accept only regexps inserted by hi-lock
 404 interactive functions.  \(See `hi-lock-interactive-patterns'.\)
 405 \\<minibuffer-local-must-match-map>Use \\[minibuffer-complete] to complete a partially typed regexp.
 406 \(See info node `Minibuffer History'.\)"
 407   (interactive
 408    (if (and (display-popup-menus-p) (vectorp (this-command-keys)))
 409        (catch 'snafu
 410          (or
 411           (x-popup-menu
 412            t
 413            (cons
 414             `keymap
 415             (cons "Select Pattern to Unhighlight"
 416                   (mapcar (lambda (pattern)
 417                             (list (car pattern)
 418                                   (format
 419                                    "%s (%s)" (car pattern)
 420                                    (symbol-name
 421                                     (car
 422                                      (cdr (car (cdr (car (cdr pattern))))))))
 423                                   (cons nil nil)
 424                                   (car pattern)))
 425                           hi-lock-interactive-patterns))))
 426           ;; If the user clicks outside the menu, meaning that they
 427           ;; change their mind, x-popup-menu returns nil, and
 428           ;; interactive signals a wrong number of arguments error.
 429           ;; To prevent that, we return an empty string, which will
 430           ;; effectively disable the rest of the function.
 431           (throw 'snafu '(""))))
 432      (let ((history-list (mapcar (lambda (p) (car p))
 433                                  hi-lock-interactive-patterns)))
 434        (unless hi-lock-interactive-patterns
 435          (error "No highlighting to remove"))
 436        (list
 437         (completing-read "Regexp to unhighlight: "
 438                          hi-lock-interactive-patterns nil t
 439                          (car (car hi-lock-interactive-patterns))
 440                          (cons 'history-list 1))))))
 441   (let ((keyword (assoc regexp hi-lock-interactive-patterns)))
 442     (when keyword
 443       (font-lock-remove-keywords nil (list keyword))
 444       (setq hi-lock-interactive-patterns
 445             (delq keyword hi-lock-interactive-patterns))
 446       (hi-lock-refontify))))
 447
 448 ;;;###autoload
 449 (defun hi-lock-write-interactive-patterns ()
 450   "Write interactively added patterns, if any, into buffer at point.
 451
 452 Interactively added patterns are those normally specified using
 453 `highlight-regexp' and `highlight-lines-matching-regexp'; they can
 454 be found in variable `hi-lock-interactive-patterns'."
 455   (interactive)
 456   (let ((prefix (format "%s %s:" (or comment-start "") "Hi-lock")))
 457     (when (> (+ (point) (length prefix)) hi-lock-file-patterns-range)
 458       (beep)
 459       (message
 460        "Warning, inserted keywords not close enough to top of file."))
 461     (mapcar
 462      (lambda (pattern)
 463        (insert (format "%s (%s) %s\n"
 464                        prefix (prin1-to-string pattern) (or comment-end ""))))
 465      hi-lock-interactive-patterns)))
 466
 467
 468 ;; Implementation Functions
 469
 470 (defun hi-lock-process-phrase (phrase)
 471   "Convert regexp PHRASE to a regexp that matches phrases.
 472
 473 Blanks in PHRASE replaced by regexp that matches arbitrary whitespace
 474 and initial lower-case letters made case insensitive."
 475   (let ((mod-phrase nil))
 476     (setq mod-phrase
 477           (replace-regexp-in-string
 478            "\\<[a-z]" (lambda (m) (format "[%s%s]" (upcase m) m)) phrase))
 479     (setq mod-phrase
 480           (replace-regexp-in-string
 481            "\\s-+" "[ \t\n]+" mod-phrase nil t))))
 482
 483 (defun hi-lock-regexp-okay (regexp)
 484   "Return REGEXP if it appears suitable for a font-lock pattern.
 485
 486 Otherwise signal an error.  A pattern that matches the null string is
 487 not suitable."
 488   (if (string-match regexp "")
 489       (error "Regexp cannot match an empty string")
 490     regexp))
 491
 492 (defun hi-lock-read-face-name ()
 493   "Read face name from minibuffer with completion and history."
 494   (intern (completing-read
 495            "Highlight using face: "
 496            obarray 'facep t
 497            (cons (car hi-lock-face-history)
 498                  (let ((prefix
 499                         (try-completion
 500                          (substring (car hi-lock-face-history) 0 1)
 501                          (mapcar (lambda (f) (cons f f))
 502                                  hi-lock-face-history))))
 503                    (if (and (stringp prefix)
 504                             (not (equal prefix (car hi-lock-face-history))))
 505                        (length prefix) 0)))
 506            '(hi-lock-face-history . 0))))
 507
 508 (defun hi-lock-find-file-hook ()
 509   "Add hi-lock patterns, if present."
 510   (hi-lock-find-patterns))
 511
 512 (defun hi-lock-current-line (&optional end)
 513   "Return line number of line at point.
 514 Optional argument END is maximum excursion."
 515   (interactive)
 516   (save-excursion
 517     (beginning-of-line)
 518     (1+ (count-lines 1 (or end (point))))))
 519
 520 (defun hi-lock-set-pattern (pattern)
 521   "Add PATTERN to list of interactively highlighted patterns and refontify."
 522   (hi-lock-set-patterns (list pattern)))
 523
 524 (defun hi-lock-set-patterns (patterns)
 525   "Add PATTERNS to list of interactively highlighted patterns and refontify.."
 526   (dolist (pattern patterns)
 527     (unless (member pattern hi-lock-interactive-patterns)
 528       (font-lock-add-keywords nil (list pattern))
 529       (add-to-list 'hi-lock-interactive-patterns pattern)))
 530   (hi-lock-refontify))
 531
 532 (defun hi-lock-set-file-patterns (patterns)
 533   "Replace file patterns list with PATTERNS and refontify."
 534   (when (or hi-lock-file-patterns patterns)
 535     (font-lock-remove-keywords nil hi-lock-file-patterns)
 536     (setq hi-lock-file-patterns patterns)
 537     (font-lock-add-keywords nil hi-lock-file-patterns)
 538     (hi-lock-refontify)))
 539
 540 (defun hi-lock-refontify ()
 541   "Unfontify then refontify buffer.  Used when hi-lock patterns change."
 542   (interactive)
 543   (unless font-lock-mode (font-lock-mode 1))
 544   (font-lock-fontify-buffer))
 545
 546 (defun hi-lock-find-patterns ()
 547   "Find patterns in current buffer for hi-lock."
 548   (interactive)
 549   (unless (memq major-mode hi-lock-exclude-modes)
 550     (let ((all-patterns nil)
 551           (target-regexp (concat "\\<" hi-lock-file-patterns-prefix ":")))
 552       (save-excursion
 553         (save-restriction
 554           (widen)
 555           (goto-char (point-min))
 556           (re-search-forward target-regexp
 557                              (+ (point) hi-lock-file-patterns-range) t)
 558           (beginning-of-line)
 559           (while (and (re-search-forward target-regexp (+ (point) 100) t)
 560                       (not (looking-at "\\s-*end")))
 561             (condition-case nil
 562                 (setq all-patterns (append (read (current-buffer)) all-patterns))
 563               (error (message "Invalid pattern list expression at %d"
 564                               (hi-lock-current-line)))))))
 565       (when hi-lock-mode (hi-lock-set-file-patterns all-patterns))
 566       (if (interactive-p)
 567         (message "Hi-lock added %d patterns." (length all-patterns))))))
 568
 569 (defun hi-lock-font-lock-hook ()
 570   "Add hi lock patterns to font-lock's."
 571   (when hi-lock-mode
 572     (font-lock-add-keywords nil hi-lock-file-patterns)
 573     (font-lock-add-keywords nil hi-lock-interactive-patterns)))
 574
 575 (provide 'hi-lock)
 576
 577 ;; arch-tag: d2e8fd07-4cc9-4c6f-a200-1e729bc54066
 578 ;;; hi-lock.el ends here