lisp/vc-mtn.el

   1 ;;; vc-mtn.el --- VC backend for Monotone
   2
   3 ;; Copyright (C) 2007, 2008  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords:
   7
   8 ;; This file is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 3, or (at your option)
  11 ;; any later version.
  12
  13 ;; This file is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  21 ;; Boston, MA 02110-1301, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl) (require 'vc))
  30
  31 ;; Clear up the cache to force vc-call to check again and discover
  32 ;; new functions when we reload this file.
  33 (put 'Mtn 'vc-functions nil)
  34
  35 (defvar vc-mtn-command "mtn")
  36 (unless (executable-find vc-mtn-command)
  37   ;; vc-mtn.el is 100% non-functional without the `mtn' executable.
  38   (setq vc-handled-backends (delq 'Mtn vc-handled-backends)))
  39
  40 ;;;###autoload
  41 (defconst vc-mtn-admin-dir "_MTN")
  42 ;;;###autoload
  43 (defconst vc-mtn-admin-format (concat vc-mtn-admin-dir "/format"))
  44
  45 ;;;###autoload (defun vc-mtn-registered (file)
  46 ;;;###autoload   (if (vc-find-root file vc-mtn-admin-format)
  47 ;;;###autoload       (progn
  48 ;;;###autoload         (load "vc-mtn")
  49 ;;;###autoload         (vc-mtn-registered file))))
  50
  51 (defun vc-mtn-revision-granularity () 'repository)
  52 (defun vc-mtn-checkout-model (file) 'implicit)
  53
  54 (defun vc-mtn-root (file)
  55   (setq file (if (file-directory-p file)
  56                  (file-name-as-directory file)
  57                (file-name-directory file)))
  58   (or (vc-file-getprop file 'vc-mtn-root)
  59       (vc-file-setprop file 'vc-mtn-root
  60                        (vc-find-root file vc-mtn-admin-format))))
  61
  62
  63 (defun vc-mtn-registered (file)
  64   (let ((root (vc-mtn-root file)))
  65     (when root
  66       (vc-mtn-state file))))
  67
  68 (defun vc-mtn-command (buffer okstatus files &rest flags)
  69   "A wrapper around `vc-do-command' for use in vc-mtn.el."
  70   (apply 'vc-do-command buffer okstatus vc-mtn-command files flags))
  71
  72 (defun vc-mtn-state (file)
  73   ;; If `mtn' fails or returns status>0, or if the search files, just
  74   ;; return nil.
  75   (ignore-errors
  76     (with-temp-buffer
  77       (vc-mtn-command t 0 file "status")
  78       (goto-char (point-min))
  79       (re-search-forward "^  \\(?:patched \\(.*\\)\\|no changes$\\)")
  80       (if (match-end 1)
  81           'edited
  82         'up-to-date))))
  83
  84 (defun vc-mtn-working-revision (file)
  85   ;; If `mtn' fails or returns status>0, or if the search fails, just
  86   ;; return nil.
  87   (ignore-errors
  88     (with-temp-buffer
  89       (vc-mtn-command t 0 file "status")
  90       (goto-char (point-min))
  91       (re-search-forward "Current branch: \\(.*\\)\nChanges against parent \\(.*\\)")
  92       (match-string 2))))
  93
  94 (defun vc-mtn-workfile-branch (file)
  95   ;; If `mtn' fails or returns status>0, or if the search files, just
  96   ;; return nil.
  97   (ignore-errors
  98     (with-temp-buffer
  99       (vc-mtn-command t 0 file "status")
 100       (goto-char (point-min))
 101       (re-search-forward "Current branch: \\(.*\\)\nChanges against parent \\(.*\\)")
 102       (match-string 1))))
 103
 104 (defun vc-mtn-workfile-unchanged-p (file)
 105   (not (eq (vc-mtn-state file) 'edited)))
 106
 107 ;; Mode-line rewrite code copied from vc-arch.el.
 108
 109 (defcustom vc-mtn-mode-line-rewrite
 110   '(("\\`[^:/#]*[:/#]" . ""))           ;Drop the host part.
 111   "Rewrite rules to shorten Mtn's revision names on the mode-line."
 112   :type '(repeat (cons regexp string))
 113   :group 'vc)
 114
 115 (defun vc-mtn-mode-line-string (file)
 116   "Return string for placement in modeline by `vc-mode-line' for FILE."
 117   (let ((branch (vc-mtn-workfile-branch file)))
 118     (dolist (rule vc-mtn-mode-line-rewrite)
 119       (if (string-match (car rule) branch)
 120           (setq branch (replace-match (cdr rule) t nil branch))))
 121     (format "Mtn%c%s"
 122             (case (vc-state file)
 123               ((up-to-date needs-patch) ?-)
 124               (added ?@)
 125               (t ?:))
 126             branch)))
 127
 128 (defun vc-mtn-register (files &optional rest)
 129   (vc-mtn-command nil 0 files "add"))
 130
 131 (defun vc-mtn-responsible-p (file) (vc-mtn-root file))
 132 (defun vc-mtn-could-register (file) (vc-mtn-root file))
 133
 134 (defun vc-mtn-checkin (files rev comment)
 135   (vc-mtn-command nil 0 files "commit" "-m" comment))
 136
 137 (defun vc-mtn-find-revision (file rev buffer)
 138   (vc-mtn-command buffer 0 file "cat" "-r" rev))
 139
 140 ;; (defun vc-mtn-checkout (file &optional editable rev)
 141 ;;   )
 142
 143 (defun vc-mtn-revert (file &optional contents-done)
 144   (unless contents-done
 145     (vc-mtn-command nil 0 file "revert")))
 146
 147 ;; (defun vc-mtn-roolback (files)
 148 ;;   )
 149
 150 (defun vc-mtn-print-log (files &optional buffer)
 151   (vc-mtn-command buffer 0 files "log"))
 152
 153 (defvar log-view-message-re)
 154 (defvar log-view-file-re)
 155 (defvar log-view-font-lock-keywords)
 156
 157 (define-derived-mode vc-mtn-log-view-mode log-view-mode "Mtn-Log-View"
 158   ;; TODO: Not sure what to do about file markers for now.
 159   (set (make-local-variable 'log-view-file-re) "\\'\\`")
 160   ;; TODO: Use a more precise regexp than "[ |/]+" to avoid false positives
 161   ;; in the ChangeLog text.
 162   (set (make-local-variable 'log-view-message-re)
 163        "^[ |/]+Revision: \\([0-9a-f]+\\)")
 164   (require 'add-log)                    ;For change-log faces.
 165   (set (make-local-variable 'log-view-font-lock-keywords)
 166        (append log-view-font-lock-keywords
 167                '(("^[ |]+Author: \\(.*\\)" (1 'change-log-email))
 168                  ("^[ |]+Date: \\(.*\\)" (1 'change-log-date-face))))))
 169
 170 ;; (defun vc-mtn-show-log-entry (revision)
 171 ;;   )
 172
 173 (defun vc-mtn-wash-log (file))
 174
 175 (defun vc-mtn-diff (files &optional rev1 rev2 buffer)
 176   (apply 'vc-mtn-command (or buffer "*vc-diff*") 1 files "diff"
 177          (append (if rev1 (list "-r" rev1)) (if rev2 (list "-r" rev2)))))
 178
 179 (defun vc-mtn-annotate-command (file buf &optional rev)
 180   (apply 'vc-mtn-command buf 0 file "annotate"
 181          (if rev (list "-r" rev))))
 182
 183 (defconst vc-mtn-annotate-full-re
 184   "^ *\\([0-9a-f]+\\)\\.* by [^ ]+ \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\): ")
 185 (defconst vc-mtn-annotate-any-re
 186   (concat "^\\(?: +: \\|" vc-mtn-annotate-full-re "\\)"))
 187
 188 (defun vc-mtn-annotate-time ()
 189   (when (looking-at vc-mtn-annotate-any-re)
 190     (goto-char (match-end 0))
 191     (let ((year (match-string 2)))
 192       (if (not year)
 193           ;; Look for the date on a previous line.
 194           (save-excursion
 195             (get-text-property (1- (previous-single-property-change
 196                                     (point) 'vc-mtn-time nil (point-min)))
 197                                'vc-mtn-time))
 198         (let ((time (vc-annotate-convert-time
 199                      (encode-time 0 0 0
 200                                   (string-to-number (match-string 4))
 201                                   (string-to-number (match-string 3))
 202                                   (string-to-number year)
 203                                   t))))
 204           (let ((inhibit-read-only t)
 205                 (inhibit-modification-hooks t))
 206             (put-text-property (match-beginning 0) (match-end 0)
 207                                'vc-mtn-time time))
 208           time)))))
 209
 210 (defun vc-mtn-annotate-extract-revision-at-line ()
 211   (save-excursion
 212     (when (or (looking-at vc-mtn-annotate-full-re)
 213               (re-search-backward vc-mtn-annotate-full-re nil t))
 214       (match-string 1))))
 215
 216 ;;; Revision completion.
 217
 218 (defun vc-mtn-list-tags ()
 219   (with-temp-buffer
 220     (vc-mtn-command t 0 nil "list" "tags")
 221     (goto-char (point-min))
 222     (let ((tags ()))
 223       (while (re-search-forward "^[^ ]+" nil t)
 224         (push (match-string 0) tags))
 225       tags)))
 226
 227 (defun vc-mtn-list-branches ()
 228   (with-temp-buffer
 229     (vc-mtn-command t 0 nil "list" "branches")
 230     (goto-char (point-min))
 231     (let ((branches ()))
 232       (while (re-search-forward "^.+" nil t)
 233         (push (match-string 0) branches))
 234       branches)))
 235
 236 (defun vc-mtn-list-revision-ids (prefix)
 237   (with-temp-buffer
 238     (vc-mtn-command t 0 nil "complete" "revision" prefix)
 239     (goto-char (point-min))
 240     (let ((ids ()))
 241       (while (re-search-forward "^.+" nil t)
 242         (push (match-string 0) ids))
 243       ids)))
 244
 245 (defun vc-mtn-revision-completion-table (files)
 246   ;; TODO: Implement completion for for selectors
 247   ;; TODO: Implement completion for composite selectors.
 248   (lexical-let ((files files))
 249     ;; What about using `files'?!?  --Stef
 250     (lambda (string pred action)
 251       (cond
 252        ;; "Tag" selectors.
 253        ((string-match "\\`t:" string)
 254         (complete-with-action action
 255                               (mapcar (lambda (tag) (concat "t:" tag))
 256                                       (vc-mtn-list-tags))
 257                               string pred))
 258        ;; "Branch" selectors.
 259        ((string-match "\\`b:" string)
 260         (complete-with-action action
 261                               (mapcar (lambda (tag) (concat "b:" tag))
 262                                       (vc-mtn-list-branches))
 263                               string pred))
 264        ;; "Head" selectors.  Not sure how they differ from "branch" selectors.
 265        ((string-match "\\`h:" string)
 266         (complete-with-action action
 267                               (mapcar (lambda (tag) (concat "h:" tag))
 268                                       (vc-mtn-list-branches))
 269                               string pred))
 270        ;; "ID" selectors.
 271        ((string-match "\\`i:" string)
 272         (complete-with-action action
 273                               (mapcar (lambda (tag) (concat "i:" tag))
 274                                       (vc-mtn-list-revision-ids
 275                                        (substring string (match-end 0))))
 276                               string pred))
 277        (t
 278         (complete-with-action action
 279                               '("t:" "b:" "h:" "i:"
 280                                 ;; Completion not implemented for these.
 281                                 "a:" "c:" "d:" "e:" "l:")
 282                               string pred))))))
 283
 284
 285
 286 (provide 'vc-mtn)
 287
 288 ;; arch-tag: 2b89ffbc-cbb8-405a-9080-2eafd4becb70
 289 ;;; vc-mtn.el ends here